src/Pure/sign.ML
author wenzelm
Tue Mar 11 22:49:28 2014 +0100 (2014-03-11)
changeset 56056 4d46d53566e6
parent 56026 893fe12639bc
child 56057 ad6bd8030d88
permissions -rw-r--r--
more efficient local theory operations, by imposing a linear change discipline on the main types/consts tables, in order to speed-up Proof_Context.transfer_syntax required for Local_Theory.raw_theory_result;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val change_begin: theory -> theory
    11   val change_end: theory -> theory
    12   val change_end_local: Proof.context -> Proof.context
    13   val syn_of: theory -> Syntax.syntax
    14   val tsig_of: theory -> Type.tsig
    15   val classes_of: theory -> Sorts.algebra
    16   val all_classes: theory -> class list
    17   val super_classes: theory -> class -> class list
    18   val minimize_sort: theory -> sort -> sort
    19   val complete_sort: theory -> sort -> sort
    20   val set_defsort: sort -> theory -> theory
    21   val defaultS: theory -> sort
    22   val subsort: theory -> sort * sort -> bool
    23   val of_sort: theory -> typ * sort -> bool
    24   val inter_sort: theory -> sort * sort -> sort
    25   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    26   val is_logtype: theory -> string -> bool
    27   val typ_instance: theory -> typ * typ -> bool
    28   val typ_equiv: theory -> typ * typ -> bool
    29   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    30   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    31   val consts_of: theory -> Consts.T
    32   val the_const_constraint: theory -> string -> typ
    33   val const_type: theory -> string -> typ option
    34   val the_const_type: theory -> string -> typ
    35   val declared_tyname: theory -> string -> bool
    36   val declared_const: theory -> string -> bool
    37   val naming_of: theory -> Name_Space.naming
    38   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    39   val restore_naming: theory -> theory -> theory
    40   val inherit_naming: theory -> Proof.context -> Context.generic
    41   val full_name: theory -> binding -> string
    42   val full_name_path: theory -> string -> binding -> string
    43   val full_bname: theory -> bstring -> string
    44   val full_bname_path: theory -> string -> bstring -> string
    45   val const_monomorphic: theory -> string -> bool
    46   val const_typargs: theory -> string * typ -> typ list
    47   val const_instance: theory -> string * typ list -> typ
    48   val mk_const: theory -> string * typ list -> term
    49   val class_space: theory -> Name_Space.T
    50   val type_space: theory -> Name_Space.T
    51   val const_space: theory -> Name_Space.T
    52   val intern_class: theory -> xstring -> string
    53   val intern_type: theory -> xstring -> string
    54   val intern_const: theory -> xstring -> string
    55   val class_alias: binding -> class -> theory -> theory
    56   val type_alias: binding -> string -> theory -> theory
    57   val const_alias: binding -> string -> theory -> theory
    58   val arity_number: theory -> string -> int
    59   val arity_sorts: theory -> string -> sort -> sort list
    60   val certify_class: theory -> class -> class
    61   val certify_sort: theory -> sort -> sort
    62   val certify_typ: theory -> typ -> typ
    63   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    64   val certify': bool -> Context.pretty -> bool -> Consts.T -> theory -> term -> term * typ * int
    65   val certify_term: theory -> term -> term * typ * int
    66   val cert_term: theory -> term -> term
    67   val cert_prop: theory -> term -> term
    68   val no_frees: Proof.context -> term -> term
    69   val no_vars: Proof.context -> term -> term
    70   val add_type: Proof.context -> binding * int * mixfix -> theory -> theory
    71   val add_types_global: (binding * int * mixfix) list -> theory -> theory
    72   val add_nonterminals: Proof.context -> binding list -> theory -> theory
    73   val add_nonterminals_global: binding list -> theory -> theory
    74   val add_type_abbrev: Proof.context -> binding * string list * typ -> theory -> theory
    75   val add_syntax: (string * string * mixfix) list -> theory -> theory
    76   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    77   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    78   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    79   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    80   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    81   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    82   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    83   val declare_const: Proof.context -> (binding * typ) * mixfix -> theory -> term * theory
    84   val declare_const_global: (binding * typ) * mixfix -> theory -> term * theory
    85   val add_consts: (binding * string * mixfix) list -> theory -> theory
    86   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    87   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    88   val revert_abbrev: string -> string -> theory -> theory
    89   val add_const_constraint: string * typ option -> theory -> theory
    90   val primitive_class: binding * class list -> theory -> theory
    91   val primitive_classrel: class * class -> theory -> theory
    92   val primitive_arity: arity -> theory -> theory
    93   val parse_ast_translation:
    94     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
    95   val parse_translation:
    96     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    97   val print_translation:
    98     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    99   val typed_print_translation:
   100     (string * (Proof.context -> typ -> term list -> term)) list -> theory -> theory
   101   val print_ast_translation:
   102     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
   103   val add_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   104   val del_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   105   val new_group: theory -> theory
   106   val reset_group: theory -> theory
   107   val add_path: string -> theory -> theory
   108   val root_path: theory -> theory
   109   val parent_path: theory -> theory
   110   val mandatory_path: string -> theory -> theory
   111   val qualified_path: bool -> binding -> theory -> theory
   112   val local_path: theory -> theory
   113   val hide_class: bool -> string -> theory -> theory
   114   val hide_type: bool -> string -> theory -> theory
   115   val hide_const: bool -> string -> theory -> theory
   116 end
   117 
   118 structure Sign: SIGN =
   119 struct
   120 
   121 (** datatype sign **)
   122 
   123 datatype sign = Sign of
   124  {syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   125   tsig: Type.tsig,              (*order-sorted signature of types*)
   126   consts: Consts.T};            (*polymorphic constants*)
   127 
   128 fun make_sign (syn, tsig, consts) = Sign {syn = syn, tsig = tsig, consts = consts};
   129 
   130 structure Data = Theory_Data_PP
   131 (
   132   type T = sign;
   133   fun extend (Sign {syn, tsig, consts, ...}) = make_sign (syn, tsig, consts);
   134 
   135   val empty = make_sign (Syntax.empty_syntax, Type.empty_tsig, Consts.empty);
   136 
   137   fun merge pp (sign1, sign2) =
   138     let
   139       val Sign {syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   140       val Sign {syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   141 
   142       val syn = Syntax.merge_syntax (syn1, syn2);
   143       val tsig = Type.merge_tsig pp (tsig1, tsig2);
   144       val consts = Consts.merge (consts1, consts2);
   145     in make_sign (syn, tsig, consts) end;
   146 );
   147 
   148 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   149 
   150 fun map_sign f = Data.map (fn Sign {syn, tsig, consts} => make_sign (f (syn, tsig, consts)));
   151 
   152 fun map_syn f = map_sign (fn (syn, tsig, consts) => (f syn, tsig, consts));
   153 fun map_tsig f = map_sign (fn (syn, tsig, consts) => (syn, f tsig, consts));
   154 fun map_consts f = map_sign (fn (syn, tsig, consts) => (syn, tsig, f consts));
   155 
   156 
   157 (* linear change discipline *)
   158 
   159 fun change_base begin = map_sign (fn (syn, tsig, consts) =>
   160   (syn, Type.change_base begin tsig, Consts.change_base begin consts));
   161 
   162 val change_begin = change_base true;
   163 val change_end = change_base false;
   164 
   165 fun change_end_local ctxt =
   166   Context.raw_transfer (change_end (Proof_Context.theory_of ctxt)) ctxt;
   167 
   168 
   169 (* syntax *)
   170 
   171 val syn_of = #syn o rep_sg;
   172 
   173 
   174 (* type signature *)
   175 
   176 val tsig_of = #tsig o rep_sg;
   177 
   178 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   179 val all_classes = Sorts.all_classes o classes_of;
   180 val super_classes = Sorts.super_classes o classes_of;
   181 val minimize_sort = Sorts.minimize_sort o classes_of;
   182 val complete_sort = Sorts.complete_sort o classes_of;
   183 
   184 val set_defsort = map_tsig o Type.set_defsort;
   185 val defaultS = Type.defaultS o tsig_of;
   186 val subsort = Type.subsort o tsig_of;
   187 val of_sort = Type.of_sort o tsig_of;
   188 val inter_sort = Type.inter_sort o tsig_of;
   189 val witness_sorts = Type.witness_sorts o tsig_of;
   190 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   191 
   192 val typ_instance = Type.typ_instance o tsig_of;
   193 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   194 val typ_match = Type.typ_match o tsig_of;
   195 val typ_unify = Type.unify o tsig_of;
   196 
   197 
   198 (* polymorphic constants *)
   199 
   200 val consts_of = #consts o rep_sg;
   201 val the_const_constraint = Consts.the_constraint o consts_of;
   202 val the_const_type = #2 oo (Consts.the_const o consts_of);
   203 val const_type = try o the_const_type;
   204 val const_monomorphic = Consts.is_monomorphic o consts_of;
   205 val const_typargs = Consts.typargs o consts_of;
   206 val const_instance = Consts.instance o consts_of;
   207 
   208 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   209 
   210 fun declared_tyname ctxt c = can (Type.the_decl (tsig_of ctxt)) (c, Position.none);
   211 val declared_const = can o the_const_constraint;
   212 
   213 
   214 (* naming *)
   215 
   216 val naming_of = Name_Space.naming_of o Context.Theory;
   217 val map_naming = Context.theory_map o Name_Space.map_naming;
   218 val restore_naming = map_naming o K o naming_of;
   219 fun inherit_naming thy = Name_Space.map_naming (K (naming_of thy)) o Context.Proof;
   220 
   221 val full_name = Name_Space.full_name o naming_of;
   222 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   223 
   224 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   225 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   226 
   227 
   228 
   229 (** name spaces **)
   230 
   231 val class_space = Type.class_space o tsig_of;
   232 val type_space = Type.type_space o tsig_of;
   233 val const_space = Consts.space_of o consts_of;
   234 
   235 val intern_class = Name_Space.intern o class_space;
   236 val intern_type = Name_Space.intern o type_space;
   237 val intern_const = Name_Space.intern o const_space;
   238 
   239 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   240 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   241 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   242 
   243 
   244 
   245 (** certify entities **)    (*exception TYPE*)
   246 
   247 (* certify wrt. type signature *)
   248 
   249 val arity_number = Type.arity_number o tsig_of;
   250 fun arity_sorts thy = Type.arity_sorts (Context.pretty_global thy) (tsig_of thy);
   251 
   252 val certify_class = Type.cert_class o tsig_of;
   253 val certify_sort = Type.cert_sort o tsig_of;
   254 val certify_typ = Type.cert_typ o tsig_of;
   255 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   256 
   257 
   258 (* certify term/prop *)
   259 
   260 local
   261 
   262 fun type_check pp tm =
   263   let
   264     fun err_appl bs t T u U =
   265       let
   266         val xs = map Free bs;           (*we do not rename here*)
   267         val t' = subst_bounds (xs, t);
   268         val u' = subst_bounds (xs, u);
   269         val msg = Type.appl_error (Syntax.init_pretty pp) t' T u' U;
   270       in raise TYPE (msg, [T, U], [t', u']) end;
   271 
   272     fun typ_of (_, Const (_, T)) = T
   273       | typ_of (_, Free  (_, T)) = T
   274       | typ_of (_, Var (_, T)) = T
   275       | typ_of (bs, Bound i) = snd (nth bs i handle General.Subscript =>
   276           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   277       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   278       | typ_of (bs, t $ u) =
   279           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   280             (case T of
   281               Type ("fun", [T1, T2]) =>
   282                 if T1 = U then T2 else err_appl bs t T u U
   283             | _ => err_appl bs t T u U)
   284           end;
   285   in typ_of ([], tm) end;
   286 
   287 fun err msg = raise TYPE (msg, [], []);
   288 
   289 fun check_vars (t $ u) = (check_vars t; check_vars u)
   290   | check_vars (Abs (_, _, t)) = check_vars t
   291   | check_vars (Free (x, _)) =
   292       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   293   | check_vars (Var (xi as (_, i), _)) =
   294       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   295   | check_vars _ = ();
   296 
   297 in
   298 
   299 fun certify' prop pp do_expand consts thy tm =
   300   let
   301     val _ = check_vars tm;
   302     val tm' = Term.map_types (certify_typ thy) tm;
   303     val T = type_check pp tm';
   304     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   305     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   306   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   307 
   308 fun certify_term thy = certify' false (Context.pretty_global thy) true (consts_of thy) thy;
   309 fun cert_term_abbrev thy =
   310   #1 o certify' false (Context.pretty_global thy) false (consts_of thy) thy;
   311 val cert_term = #1 oo certify_term;
   312 fun cert_prop thy = #1 o certify' true (Context.pretty_global thy) true (consts_of thy) thy;
   313 
   314 end;
   315 
   316 
   317 (* specifications *)
   318 
   319 fun no_variables kind add addT mk mkT ctxt tm =
   320   (case (add tm [], addT tm []) of
   321     ([], []) => tm
   322   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   323       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   324        Pretty.commas
   325         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   326 
   327 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   328 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   329 
   330 
   331 
   332 (** signature extension functions **)  (*exception ERROR/TYPE*)
   333 
   334 (* add type constructors *)
   335 
   336 fun add_type ctxt (b, n, mx) thy = thy |> map_sign (fn (syn, tsig, consts) =>
   337   let
   338     val type_syntax = (Lexicon.mark_type (full_name thy b), Mixfix.make_type n, mx);
   339     val syn' = Syntax.update_type_gram true Syntax.mode_default [type_syntax] syn;
   340     val tsig' = Type.add_type (inherit_naming thy ctxt) (b, n) tsig;
   341   in (syn', tsig', consts) end);
   342 
   343 fun add_types_global types thy =
   344   fold (add_type (Syntax.init_pretty_global thy)) types thy;
   345 
   346 
   347 (* add nonterminals *)
   348 
   349 fun add_nonterminals ctxt ns thy = thy |> map_sign (fn (syn, tsig, consts) =>
   350   (syn, fold (Type.add_nonterminal (inherit_naming thy ctxt)) ns tsig, consts));
   351 
   352 fun add_nonterminals_global ns thy =
   353   add_nonterminals (Syntax.init_pretty_global thy) ns thy;
   354 
   355 
   356 (* add type abbreviations *)
   357 
   358 fun add_type_abbrev ctxt abbr thy = thy |> map_sign (fn (syn, tsig, consts) =>
   359   (syn, Type.add_abbrev (inherit_naming thy ctxt) abbr tsig, consts));
   360 
   361 
   362 (* modify syntax *)
   363 
   364 fun gen_syntax change_gram parse_typ mode args thy =
   365   let
   366     val ctxt = Type.set_mode Type.mode_syntax (Proof_Context.init_global thy);
   367     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   368       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   369   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   370 
   371 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   372 
   373 val add_modesyntax = gen_add_syntax Syntax.read_typ;
   374 val add_modesyntax_i = gen_add_syntax (K I);
   375 val add_syntax = add_modesyntax Syntax.mode_default;
   376 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   377 val del_modesyntax = gen_syntax (Syntax.update_const_gram false) Syntax.read_typ;
   378 val del_modesyntax_i = gen_syntax (Syntax.update_const_gram false) (K I);
   379 
   380 fun type_notation add mode args =
   381   let
   382     fun type_syntax (Type (c, args), mx) =
   383           SOME (Lexicon.mark_type c, Mixfix.make_type (length args), mx)
   384       | type_syntax _ = NONE;
   385   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   386 
   387 fun notation add mode args thy =
   388   let
   389     fun const_syntax (Const (c, _), mx) =
   390           (case try (Consts.type_scheme (consts_of thy)) c of
   391             SOME T => SOME (Lexicon.mark_const c, T, mx)
   392           | NONE => NONE)
   393       | const_syntax _ = NONE;
   394   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   395 
   396 
   397 (* add constants *)
   398 
   399 local
   400 
   401 fun gen_add_consts prep_typ ctxt raw_args thy =
   402   let
   403     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o prep_typ ctxt;
   404     fun prep (b, raw_T, mx) =
   405       let
   406         val c = full_name thy b;
   407         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   408           cat_error msg ("in declaration of constant " ^ Binding.print b);
   409         val T' = Logic.varifyT_global T;
   410       in ((b, T'), (Lexicon.mark_const c, T', mx), Const (c, T)) end;
   411     val args = map prep raw_args;
   412   in
   413     thy
   414     |> map_consts (fold (Consts.declare (inherit_naming thy ctxt) o #1) args)
   415     |> add_syntax_i (map #2 args)
   416     |> pair (map #3 args)
   417   end;
   418 
   419 in
   420 
   421 fun add_consts args thy =
   422   #2 (gen_add_consts Syntax.read_typ (Proof_Context.init_global thy) args thy);
   423 
   424 fun add_consts_i args thy =
   425   #2 (gen_add_consts (K I) (Proof_Context.init_global thy) args thy);
   426 
   427 fun declare_const ctxt ((b, T), mx) = yield_singleton (gen_add_consts (K I) ctxt) (b, T, mx);
   428 fun declare_const_global arg thy = declare_const (Proof_Context.init_global thy) arg thy;
   429 
   430 end;
   431 
   432 
   433 (* abbreviations *)
   434 
   435 fun add_abbrev mode (b, raw_t) thy =  (* FIXME proper ctxt (?) *)
   436   let
   437     val ctxt = Syntax.init_pretty_global thy;
   438     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   439     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   440       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ Binding.print b);
   441     val (res, consts') = consts_of thy
   442       |> Consts.abbreviate (inherit_naming thy ctxt) (tsig_of thy) mode (b, t);
   443   in (res, thy |> map_consts (K consts')) end;
   444 
   445 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   446 
   447 
   448 (* add constraints *)
   449 
   450 fun add_const_constraint (c, opt_T) thy =
   451   let
   452     fun prepT raw_T =
   453       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   454       in cert_term thy (Const (c, T)); T end
   455       handle TYPE (msg, _, _) => error msg;
   456   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   457 
   458 
   459 (* primitive classes and arities *)
   460 
   461 fun primitive_class (bclass, classes) thy =
   462   thy
   463   |> map_sign (fn (syn, tsig, consts) =>
   464       let val tsig' = Type.add_class (Context.Theory thy) (bclass, classes) tsig;
   465       in (syn, tsig', consts) end)
   466   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   467 
   468 fun primitive_classrel arg thy =
   469   thy |> map_tsig (Type.add_classrel (Context.pretty_global thy) arg);
   470 
   471 fun primitive_arity arg thy =
   472   thy |> map_tsig (Type.add_arity (Context.pretty_global thy) arg);
   473 
   474 
   475 (* add translation functions *)
   476 
   477 local
   478 
   479 fun mk trs = map Syntax_Ext.mk_trfun trs;
   480 
   481 in
   482 
   483 fun parse_ast_translation atrs = map_syn (Syntax.update_trfuns (mk atrs, [], [], []));
   484 fun parse_translation trs = map_syn (Syntax.update_trfuns ([], mk trs, [], []));
   485 fun print_translation tr's =
   486   map_syn (Syntax.update_trfuns ([], [], mk (map (apsnd Syntax_Trans.non_typed_tr') tr's), []));
   487 fun typed_print_translation tr's = map_syn (Syntax.update_trfuns ([], [], mk tr's, []));
   488 fun print_ast_translation atr's = map_syn (Syntax.update_trfuns ([], [], [], mk atr's));
   489 
   490 end;
   491 
   492 
   493 (* translation rules *)
   494 
   495 val add_trrules = map_syn o Syntax.update_trrules;
   496 val del_trrules = map_syn o Syntax.remove_trrules;
   497 
   498 
   499 (* naming *)
   500 
   501 val new_group = map_naming Name_Space.new_group;
   502 val reset_group = map_naming Name_Space.reset_group;
   503 
   504 val add_path = map_naming o Name_Space.add_path;
   505 val root_path = map_naming Name_Space.root_path;
   506 val parent_path = map_naming Name_Space.parent_path;
   507 val mandatory_path = map_naming o Name_Space.mandatory_path;
   508 val qualified_path = map_naming oo Name_Space.qualified_path;
   509 
   510 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   511 
   512 
   513 (* hide names *)
   514 
   515 val hide_class = map_tsig oo Type.hide_class;
   516 val hide_type = map_tsig oo Type.hide_type;
   517 val hide_const = map_consts oo Consts.hide;
   518 
   519 end;