src/HOL/Nat.thy
author krauss
Fri Apr 25 15:30:33 2008 +0200 (2008-04-25)
changeset 26748 4d51ddd6aa5c
parent 26335 961bbcc9d85b
child 27104 791607529f6d
permissions -rw-r--r--
Merged theories about wellfoundedness into one: Wellfounded.thy
     1 (*  Title:      HOL/Nat.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     4 
     5 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     6 and * (for div, mod and dvd, see theory Divides).
     7 *)
     8 
     9 header {* Natural numbers *}
    10 
    11 theory Nat
    12 imports Inductive Ring_and_Field
    13 uses
    14   "~~/src/Tools/rat.ML"
    15   "~~/src/Provers/Arith/cancel_sums.ML"
    16   ("arith_data.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   inj_Suc_Rep:          "inj Suc_Rep" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 
    34 subsection {* Type nat *}
    35 
    36 text {* Type definition *}
    37 
    38 inductive Nat :: "ind \<Rightarrow> bool"
    39 where
    40     Zero_RepI: "Nat Zero_Rep"
    41   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    42 
    43 global
    44 
    45 typedef (open Nat)
    46   nat = "Collect Nat"
    47   by (rule exI, rule CollectI, rule Nat.Zero_RepI)
    48 
    49 constdefs
    50   Suc :: "nat => nat"
    51   Suc_def:      "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    52 
    53 local
    54 
    55 instantiation nat :: zero
    56 begin
    57 
    58 definition Zero_nat_def [code func del]:
    59   "0 = Abs_Nat Zero_Rep"
    60 
    61 instance ..
    62 
    63 end
    64 
    65 lemma nat_induct: "P 0 ==> (!!n. P n ==> P (Suc n)) ==> P n"
    66   apply (unfold Zero_nat_def Suc_def)
    67   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    68   apply (erule Rep_Nat [THEN CollectD, THEN Nat.induct])
    69   apply (iprover elim: Abs_Nat_inverse [OF CollectI, THEN subst])
    70   done
    71 
    72 lemma Suc_not_Zero [iff]: "Suc m \<noteq> 0"
    73   by (simp add: Zero_nat_def Suc_def
    74     Abs_Nat_inject Rep_Nat [THEN CollectD] Suc_RepI Zero_RepI
    75       Suc_Rep_not_Zero_Rep)
    76 
    77 lemma Zero_not_Suc [iff]: "0 \<noteq> Suc m"
    78   by (rule not_sym, rule Suc_not_Zero not_sym)
    79 
    80 lemma inj_Suc[simp]: "inj_on Suc N"
    81   by (simp add: Suc_def inj_on_def Abs_Nat_inject Rep_Nat [THEN CollectD] Suc_RepI
    82                 inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject)
    83 
    84 lemma Suc_Suc_eq [iff]: "Suc m = Suc n \<longleftrightarrow> m = n"
    85   by (rule inj_Suc [THEN inj_eq])
    86 
    87 rep_datatype nat
    88   distinct  Suc_not_Zero Zero_not_Suc
    89   inject    Suc_Suc_eq
    90   induction nat_induct
    91 
    92 declare nat.induct [case_names 0 Suc, induct type: nat]
    93 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    94 
    95 lemmas nat_rec_0 = nat.recs(1)
    96   and nat_rec_Suc = nat.recs(2)
    97 
    98 lemmas nat_case_0 = nat.cases(1)
    99   and nat_case_Suc = nat.cases(2)
   100 
   101 
   102 text {* Injectiveness and distinctness lemmas *}
   103 
   104 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   105 by (rule notE, rule Suc_not_Zero)
   106 
   107 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   108 by (rule Suc_neq_Zero, erule sym)
   109 
   110 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   111 by (rule inj_Suc [THEN injD])
   112 
   113 lemma n_not_Suc_n: "n \<noteq> Suc n"
   114 by (induct n) simp_all
   115 
   116 lemma Suc_n_not_n: "Suc n \<noteq> n"
   117 by (rule not_sym, rule n_not_Suc_n)
   118 
   119 text {* A special form of induction for reasoning
   120   about @{term "m < n"} and @{term "m - n"} *}
   121 
   122 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   123     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   124   apply (rule_tac x = m in spec)
   125   apply (induct n)
   126   prefer 2
   127   apply (rule allI)
   128   apply (induct_tac x, iprover+)
   129   done
   130 
   131 
   132 subsection {* Arithmetic operators *}
   133 
   134 instantiation nat :: "{minus, comm_monoid_add}"
   135 begin
   136 
   137 primrec plus_nat
   138 where
   139   add_0:      "0 + n = (n\<Colon>nat)"
   140   | add_Suc:  "Suc m + n = Suc (m + n)"
   141 
   142 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   143   by (induct m) simp_all
   144 
   145 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   146   by (induct m) simp_all
   147 
   148 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   149   by simp
   150 
   151 primrec minus_nat
   152 where
   153   diff_0:     "m - 0 = (m\<Colon>nat)"
   154   | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   155 
   156 declare diff_Suc [simp del, code del]
   157 
   158 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   159   by (induct n) (simp_all add: diff_Suc)
   160 
   161 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   162   by (induct n) (simp_all add: diff_Suc)
   163 
   164 instance proof
   165   fix n m q :: nat
   166   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   167   show "n + m = m + n" by (induct n) simp_all
   168   show "0 + n = n" by simp
   169 qed
   170 
   171 end
   172 
   173 instantiation nat :: comm_semiring_1_cancel
   174 begin
   175 
   176 definition
   177   One_nat_def [simp]: "1 = Suc 0"
   178 
   179 primrec times_nat
   180 where
   181   mult_0:     "0 * n = (0\<Colon>nat)"
   182   | mult_Suc: "Suc m * n = n + (m * n)"
   183 
   184 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   185   by (induct m) simp_all
   186 
   187 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   188   by (induct m) (simp_all add: add_left_commute)
   189 
   190 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   191   by (induct m) (simp_all add: add_assoc)
   192 
   193 instance proof
   194   fix n m q :: nat
   195   show "0 \<noteq> (1::nat)" by simp
   196   show "1 * n = n" by simp
   197   show "n * m = m * n" by (induct n) simp_all
   198   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   199   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   200   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   201 qed
   202 
   203 end
   204 
   205 subsubsection {* Addition *}
   206 
   207 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   208   by (rule add_assoc)
   209 
   210 lemma nat_add_commute: "m + n = n + (m::nat)"
   211   by (rule add_commute)
   212 
   213 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   214   by (rule add_left_commute)
   215 
   216 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   217   by (rule add_left_cancel)
   218 
   219 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   220   by (rule add_right_cancel)
   221 
   222 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   223 
   224 lemma add_is_0 [iff]:
   225   fixes m n :: nat
   226   shows "(m + n = 0) = (m = 0 & n = 0)"
   227   by (cases m) simp_all
   228 
   229 lemma add_is_1:
   230   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   231   by (cases m) simp_all
   232 
   233 lemma one_is_add:
   234   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   235   by (rule trans, rule eq_commute, rule add_is_1)
   236 
   237 lemma add_eq_self_zero:
   238   fixes m n :: nat
   239   shows "m + n = m \<Longrightarrow> n = 0"
   240   by (induct m) simp_all
   241 
   242 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   243   apply (induct k)
   244    apply simp
   245   apply(drule comp_inj_on[OF _ inj_Suc])
   246   apply (simp add:o_def)
   247   done
   248 
   249 
   250 subsubsection {* Difference *}
   251 
   252 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   253   by (induct m) simp_all
   254 
   255 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   256   by (induct i j rule: diff_induct) simp_all
   257 
   258 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   259   by (simp add: diff_diff_left)
   260 
   261 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   262   by (simp add: diff_diff_left add_commute)
   263 
   264 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   265   by (induct n) simp_all
   266 
   267 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   268   by (simp add: diff_add_inverse add_commute [of m n])
   269 
   270 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   271   by (induct k) simp_all
   272 
   273 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   274   by (simp add: diff_cancel add_commute)
   275 
   276 lemma diff_add_0: "n - (n + m) = (0::nat)"
   277   by (induct n) simp_all
   278 
   279 text {* Difference distributes over multiplication *}
   280 
   281 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   282 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   283 
   284 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   285 by (simp add: diff_mult_distrib mult_commute [of k])
   286   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   287 
   288 
   289 subsubsection {* Multiplication *}
   290 
   291 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   292   by (rule mult_assoc)
   293 
   294 lemma nat_mult_commute: "m * n = n * (m::nat)"
   295   by (rule mult_commute)
   296 
   297 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   298   by (rule right_distrib)
   299 
   300 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   301   by (induct m) auto
   302 
   303 lemmas nat_distrib =
   304   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   305 
   306 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = 1 & n = 1)"
   307   apply (induct m)
   308    apply simp
   309   apply (induct n)
   310    apply auto
   311   done
   312 
   313 lemma one_eq_mult_iff [simp,noatp]: "(Suc 0 = m * n) = (m = 1 & n = 1)"
   314   apply (rule trans)
   315   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   316   done
   317 
   318 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   319 proof -
   320   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   321   proof (induct n arbitrary: m)
   322     case 0 then show "m = 0" by simp
   323   next
   324     case (Suc n) then show "m = Suc n"
   325       by (cases m) (simp_all add: eq_commute [of "0"])
   326   qed
   327   then show ?thesis by auto
   328 qed
   329 
   330 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   331   by (simp add: mult_commute)
   332 
   333 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   334   by (subst mult_cancel1) simp
   335 
   336 
   337 subsection {* Orders on @{typ nat} *}
   338 
   339 subsubsection {* Operation definition *}
   340 
   341 instantiation nat :: linorder
   342 begin
   343 
   344 primrec less_eq_nat where
   345   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   346   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   347 
   348 declare less_eq_nat.simps [simp del, code del]
   349 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   350 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   351 
   352 definition less_nat where
   353   less_eq_Suc_le [code func del]: "n < m \<longleftrightarrow> Suc n \<le> m"
   354 
   355 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   356   by (simp add: less_eq_nat.simps(2))
   357 
   358 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   359   unfolding less_eq_Suc_le ..
   360 
   361 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   362   by (induct n) (simp_all add: less_eq_nat.simps(2))
   363 
   364 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   365   by (simp add: less_eq_Suc_le)
   366 
   367 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   368   by simp
   369 
   370 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   371   by (simp add: less_eq_Suc_le)
   372 
   373 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   374   by (simp add: less_eq_Suc_le)
   375 
   376 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   377   by (induct m arbitrary: n)
   378     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   379 
   380 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   381   by (cases n) (auto intro: le_SucI)
   382 
   383 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   384   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   385 
   386 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   387   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   388 
   389 instance
   390 proof
   391   fix n m :: nat
   392   have less_imp_le: "n < m \<Longrightarrow> n \<le> m"
   393     unfolding less_eq_Suc_le by (erule Suc_leD)
   394   have irrefl: "\<not> m < m" by (induct m) auto
   395   have strict: "n \<le> m \<Longrightarrow> n \<noteq> m \<Longrightarrow> n < m"
   396   proof (induct n arbitrary: m)
   397     case 0 then show ?case
   398       by (cases m) (simp_all add: less_eq_Suc_le)
   399   next
   400     case (Suc n) then show ?case
   401       by (cases m) (simp_all add: less_eq_Suc_le)
   402   qed
   403   show "n < m \<longleftrightarrow> n \<le> m \<and> n \<noteq> m"
   404     by (auto simp add: irrefl intro: less_imp_le strict)
   405 next
   406   fix n :: nat show "n \<le> n" by (induct n) simp_all
   407 next
   408   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   409   then show "n = m"
   410     by (induct n arbitrary: m)
   411       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   412 next
   413   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   414   then show "n \<le> q"
   415   proof (induct n arbitrary: m q)
   416     case 0 show ?case by simp
   417   next
   418     case (Suc n) then show ?case
   419       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   420         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   421         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   422   qed
   423 next
   424   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   425     by (induct n arbitrary: m)
   426       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   427 qed
   428 
   429 end
   430 
   431 subsubsection {* Introduction properties *}
   432 
   433 lemma lessI [iff]: "n < Suc n"
   434   by (simp add: less_Suc_eq_le)
   435 
   436 lemma zero_less_Suc [iff]: "0 < Suc n"
   437   by (simp add: less_Suc_eq_le)
   438 
   439 
   440 subsubsection {* Elimination properties *}
   441 
   442 lemma less_not_refl: "~ n < (n::nat)"
   443   by (rule order_less_irrefl)
   444 
   445 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   446   by (rule not_sym) (rule less_imp_neq) 
   447 
   448 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   449   by (rule less_imp_neq)
   450 
   451 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   452   by (rule notE, rule less_not_refl)
   453 
   454 lemma less_zeroE: "(n::nat) < 0 ==> R"
   455   by (rule notE) (rule not_less0)
   456 
   457 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   458   unfolding less_Suc_eq_le le_less ..
   459 
   460 lemma less_one [iff, noatp]: "(n < (1::nat)) = (n = 0)"
   461   by (simp add: less_Suc_eq)
   462 
   463 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   464   by (simp add: less_Suc_eq)
   465 
   466 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   467   by simp
   468 
   469 text {* "Less than" is antisymmetric, sort of *}
   470 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   471   unfolding not_less less_Suc_eq_le by (rule antisym)
   472 
   473 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   474   by (rule linorder_neq_iff)
   475 
   476 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   477   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   478   shows "P n m"
   479   apply (rule less_linear [THEN disjE])
   480   apply (erule_tac [2] disjE)
   481   apply (erule lessCase)
   482   apply (erule sym [THEN eqCase])
   483   apply (erule major)
   484   done
   485 
   486 
   487 subsubsection {* Inductive (?) properties *}
   488 
   489 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   490   unfolding less_eq_Suc_le [of m] le_less by simp 
   491 
   492 lemma lessE:
   493   assumes major: "i < k"
   494   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   495   shows P
   496 proof -
   497   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   498     unfolding less_eq_Suc_le by (induct k) simp_all
   499   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   500     by (clarsimp simp add: less_le)
   501   with p1 p2 show P by auto
   502 qed
   503 
   504 lemma less_SucE: assumes major: "m < Suc n"
   505   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   506   apply (rule major [THEN lessE])
   507   apply (rule eq, blast)
   508   apply (rule less, blast)
   509   done
   510 
   511 lemma Suc_lessE: assumes major: "Suc i < k"
   512   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   513   apply (rule major [THEN lessE])
   514   apply (erule lessI [THEN minor])
   515   apply (erule Suc_lessD [THEN minor], assumption)
   516   done
   517 
   518 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   519   by simp
   520 
   521 lemma less_trans_Suc:
   522   assumes le: "i < j" shows "j < k ==> Suc i < k"
   523   apply (induct k, simp_all)
   524   apply (insert le)
   525   apply (simp add: less_Suc_eq)
   526   apply (blast dest: Suc_lessD)
   527   done
   528 
   529 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   530 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   531   unfolding not_less less_Suc_eq_le ..
   532 
   533 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   534   unfolding not_le Suc_le_eq ..
   535 
   536 text {* Properties of "less than or equal" *}
   537 
   538 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   539   unfolding less_Suc_eq_le .
   540 
   541 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   542   unfolding not_le less_Suc_eq_le ..
   543 
   544 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   545   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   546 
   547 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   548   by (drule le_Suc_eq [THEN iffD1], iprover+)
   549 
   550 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   551   unfolding Suc_le_eq .
   552 
   553 text {* Stronger version of @{text Suc_leD} *}
   554 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   555   unfolding Suc_le_eq .
   556 
   557 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   558   unfolding less_eq_Suc_le by (rule Suc_leD)
   559 
   560 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   561 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   562 
   563 
   564 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   565 
   566 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   567   unfolding le_less .
   568 
   569 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   570   by (rule le_less)
   571 
   572 text {* Useful with @{text blast}. *}
   573 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   574   by auto
   575 
   576 lemma le_refl: "n \<le> (n::nat)"
   577   by simp
   578 
   579 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   580   by (rule order_trans)
   581 
   582 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   583   by (rule antisym)
   584 
   585 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   586   by (rule less_le)
   587 
   588 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   589   unfolding less_le ..
   590 
   591 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   592   by (rule linear)
   593 
   594 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   595 
   596 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   597   unfolding less_Suc_eq_le by auto
   598 
   599 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   600   unfolding not_less by (rule le_less_Suc_eq)
   601 
   602 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   603 
   604 text {* These two rules ease the use of primitive recursion.
   605 NOTE USE OF @{text "=="} *}
   606 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   607 by simp
   608 
   609 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   610 by simp
   611 
   612 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   613 by (cases n) simp_all
   614 
   615 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   616 by (cases n) simp_all
   617 
   618 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   619 by (cases n) simp_all
   620 
   621 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   622 by (cases n) simp_all
   623 
   624 text {* This theorem is useful with @{text blast} *}
   625 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   626 by (rule neq0_conv[THEN iffD1], iprover)
   627 
   628 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   629 by (fast intro: not0_implies_Suc)
   630 
   631 lemma not_gr0 [iff,noatp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   632 using neq0_conv by blast
   633 
   634 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   635 by (induct m') simp_all
   636 
   637 text {* Useful in certain inductive arguments *}
   638 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   639 by (cases m) simp_all
   640 
   641 
   642 subsubsection {* @{term min} and @{term max} *}
   643 
   644 lemma mono_Suc: "mono Suc"
   645 by (rule monoI) simp
   646 
   647 lemma min_0L [simp]: "min 0 n = (0::nat)"
   648 by (rule min_leastL) simp
   649 
   650 lemma min_0R [simp]: "min n 0 = (0::nat)"
   651 by (rule min_leastR) simp
   652 
   653 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   654 by (simp add: mono_Suc min_of_mono)
   655 
   656 lemma min_Suc1:
   657    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   658 by (simp split: nat.split)
   659 
   660 lemma min_Suc2:
   661    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   662 by (simp split: nat.split)
   663 
   664 lemma max_0L [simp]: "max 0 n = (n::nat)"
   665 by (rule max_leastL) simp
   666 
   667 lemma max_0R [simp]: "max n 0 = (n::nat)"
   668 by (rule max_leastR) simp
   669 
   670 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   671 by (simp add: mono_Suc max_of_mono)
   672 
   673 lemma max_Suc1:
   674    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   675 by (simp split: nat.split)
   676 
   677 lemma max_Suc2:
   678    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   679 by (simp split: nat.split)
   680 
   681 
   682 subsubsection {* Monotonicity of Addition *}
   683 
   684 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   685 by (simp add: diff_Suc split: nat.split)
   686 
   687 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   688 by (induct k) simp_all
   689 
   690 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   691 by (induct k) simp_all
   692 
   693 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   694 by(auto dest:gr0_implies_Suc)
   695 
   696 text {* strict, in 1st argument *}
   697 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   698 by (induct k) simp_all
   699 
   700 text {* strict, in both arguments *}
   701 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   702   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   703   apply (induct j, simp_all)
   704   done
   705 
   706 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   707 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   708   apply (induct n)
   709   apply (simp_all add: order_le_less)
   710   apply (blast elim!: less_SucE
   711                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   712   done
   713 
   714 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   715 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   716 apply(auto simp: gr0_conv_Suc)
   717 apply (induct_tac m)
   718 apply (simp_all add: add_less_mono)
   719 done
   720 
   721 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   722 instance nat :: ordered_semidom
   723 proof
   724   fix i j k :: nat
   725   show "0 < (1::nat)" by simp
   726   show "i \<le> j ==> k + i \<le> k + j" by simp
   727   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   728 qed
   729 
   730 lemma nat_mult_1: "(1::nat) * n = n"
   731 by simp
   732 
   733 lemma nat_mult_1_right: "n * (1::nat) = n"
   734 by simp
   735 
   736 
   737 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   738 
   739 text {* Complete induction, aka course-of-values induction *}
   740 
   741 lemma less_induct [case_names less]:
   742   fixes P :: "nat \<Rightarrow> bool"
   743   assumes step: "\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x"
   744   shows "P a"
   745 proof - 
   746   have "\<And>z. z\<le>a \<Longrightarrow> P z"
   747   proof (induct a)
   748     case (0 z)
   749     have "P 0" by (rule step) auto
   750     thus ?case using 0 by auto
   751   next
   752     case (Suc x z)
   753     then have "z \<le> x \<or> z = Suc x" by (simp add: le_Suc_eq)
   754     thus ?case
   755     proof
   756       assume "z \<le> x" thus "P z" by (rule Suc(1))
   757     next
   758       assume z: "z = Suc x"
   759       show "P z"
   760         by (rule step) (rule Suc(1), simp add: z le_simps)
   761     qed
   762   qed
   763   thus ?thesis by auto
   764 qed
   765 
   766 lemma nat_less_induct:
   767   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   768   using assms less_induct by blast
   769 
   770 lemma measure_induct_rule [case_names less]:
   771   fixes f :: "'a \<Rightarrow> nat"
   772   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   773   shows "P a"
   774 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   775 
   776 text {* old style induction rules: *}
   777 lemma measure_induct:
   778   fixes f :: "'a \<Rightarrow> nat"
   779   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   780   by (rule measure_induct_rule [of f P a]) iprover
   781 
   782 lemma full_nat_induct:
   783   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   784   shows "P n"
   785   by (rule less_induct) (auto intro: step simp:le_simps)
   786 
   787 text{*An induction rule for estabilishing binary relations*}
   788 lemma less_Suc_induct:
   789   assumes less:  "i < j"
   790      and  step:  "!!i. P i (Suc i)"
   791      and  trans: "!!i j k. P i j ==> P j k ==> P i k"
   792   shows "P i j"
   793 proof -
   794   from less obtain k where j: "j = Suc(i+k)" by (auto dest: less_imp_Suc_add)
   795   have "P i (Suc (i + k))"
   796   proof (induct k)
   797     case 0
   798     show ?case by (simp add: step)
   799   next
   800     case (Suc k)
   801     thus ?case by (auto intro: assms)
   802   qed
   803   thus "P i j" by (simp add: j)
   804 qed
   805 
   806 lemma nat_induct2: "[|P 0; P (Suc 0); !!k. P k ==> P (Suc (Suc k))|] ==> P n"
   807   apply (rule nat_less_induct)
   808   apply (case_tac n)
   809   apply (case_tac [2] nat)
   810   apply (blast intro: less_trans)+
   811   done
   812 
   813 text {* The method of infinite descent, frequently used in number theory.
   814 Provided by Roelof Oosterhuis.
   815 $P(n)$ is true for all $n\in\mathbb{N}$ if
   816 \begin{itemize}
   817   \item case ``0'': given $n=0$ prove $P(n)$,
   818   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   819         a smaller integer $m$ such that $\neg P(m)$.
   820 \end{itemize} *}
   821 
   822 text{* A compact version without explicit base case: *}
   823 lemma infinite_descent:
   824   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   825 by (induct n rule: less_induct, auto)
   826 
   827 lemma infinite_descent0[case_names 0 smaller]: 
   828   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   829 by (rule infinite_descent) (case_tac "n>0", auto)
   830 
   831 text {*
   832 Infinite descent using a mapping to $\mathbb{N}$:
   833 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   834 \begin{itemize}
   835 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   836 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   837 \end{itemize}
   838 NB: the proof also shows how to use the previous lemma. *}
   839 
   840 corollary infinite_descent0_measure [case_names 0 smaller]:
   841   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   842     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   843   shows "P x"
   844 proof -
   845   obtain n where "n = V x" by auto
   846   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   847   proof (induct n rule: infinite_descent0)
   848     case 0 -- "i.e. $V(x) = 0$"
   849     with A0 show "P x" by auto
   850   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   851     case (smaller n)
   852     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   853     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   854     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   855     then show ?case by auto
   856   qed
   857   ultimately show "P x" by auto
   858 qed
   859 
   860 text{* Again, without explicit base case: *}
   861 lemma infinite_descent_measure:
   862 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   863 proof -
   864   from assms obtain n where "n = V x" by auto
   865   moreover have "!!x. V x = n \<Longrightarrow> P x"
   866   proof (induct n rule: infinite_descent, auto)
   867     fix x assume "\<not> P x"
   868     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   869   qed
   870   ultimately show "P x" by auto
   871 qed
   872 
   873 text {* A [clumsy] way of lifting @{text "<"}
   874   monotonicity to @{text "\<le>"} monotonicity *}
   875 lemma less_mono_imp_le_mono:
   876   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   877 by (simp add: order_le_less) (blast)
   878 
   879 
   880 text {* non-strict, in 1st argument *}
   881 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   882 by (rule add_right_mono)
   883 
   884 text {* non-strict, in both arguments *}
   885 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   886 by (rule add_mono)
   887 
   888 lemma le_add2: "n \<le> ((m + n)::nat)"
   889 by (insert add_right_mono [of 0 m n], simp)
   890 
   891 lemma le_add1: "n \<le> ((n + m)::nat)"
   892 by (simp add: add_commute, rule le_add2)
   893 
   894 lemma less_add_Suc1: "i < Suc (i + m)"
   895 by (rule le_less_trans, rule le_add1, rule lessI)
   896 
   897 lemma less_add_Suc2: "i < Suc (m + i)"
   898 by (rule le_less_trans, rule le_add2, rule lessI)
   899 
   900 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   901 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   902 
   903 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   904 by (rule le_trans, assumption, rule le_add1)
   905 
   906 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   907 by (rule le_trans, assumption, rule le_add2)
   908 
   909 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   910 by (rule less_le_trans, assumption, rule le_add1)
   911 
   912 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   913 by (rule less_le_trans, assumption, rule le_add2)
   914 
   915 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   916 apply (rule le_less_trans [of _ "i+j"])
   917 apply (simp_all add: le_add1)
   918 done
   919 
   920 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   921 apply (rule notI)
   922 apply (drule add_lessD1)
   923 apply (erule less_irrefl [THEN notE])
   924 done
   925 
   926 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   927 by (simp add: add_commute)
   928 
   929 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   930 apply (rule order_trans [of _ "m+k"])
   931 apply (simp_all add: le_add1)
   932 done
   933 
   934 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   935 apply (simp add: add_commute)
   936 apply (erule add_leD1)
   937 done
   938 
   939 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   940 by (blast dest: add_leD1 add_leD2)
   941 
   942 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   943 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   944 by (force simp del: add_Suc_right
   945     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
   946 
   947 
   948 subsubsection {* More results about difference *}
   949 
   950 text {* Addition is the inverse of subtraction:
   951   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
   952 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
   953 by (induct m n rule: diff_induct) simp_all
   954 
   955 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
   956 by (simp add: add_diff_inverse linorder_not_less)
   957 
   958 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
   959 by (simp add: add_commute)
   960 
   961 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
   962 by (induct m n rule: diff_induct) simp_all
   963 
   964 lemma diff_less_Suc: "m - n < Suc m"
   965 apply (induct m n rule: diff_induct)
   966 apply (erule_tac [3] less_SucE)
   967 apply (simp_all add: less_Suc_eq)
   968 done
   969 
   970 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
   971 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
   972 
   973 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
   974   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
   975 
   976 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
   977 by (rule le_less_trans, rule diff_le_self)
   978 
   979 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
   980 by (cases n) (auto simp add: le_simps)
   981 
   982 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
   983 by (induct j k rule: diff_induct) simp_all
   984 
   985 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
   986 by (simp add: add_commute diff_add_assoc)
   987 
   988 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
   989 by (auto simp add: diff_add_inverse2)
   990 
   991 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
   992 by (induct m n rule: diff_induct) simp_all
   993 
   994 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
   995 by (rule iffD2, rule diff_is_0_eq)
   996 
   997 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
   998 by (induct m n rule: diff_induct) simp_all
   999 
  1000 lemma less_imp_add_positive:
  1001   assumes "i < j"
  1002   shows "\<exists>k::nat. 0 < k & i + k = j"
  1003 proof
  1004   from assms show "0 < j - i & i + (j - i) = j"
  1005     by (simp add: order_less_imp_le)
  1006 qed
  1007 
  1008 text {* a nice rewrite for bounded subtraction *}
  1009 lemma nat_minus_add_max:
  1010   fixes n m :: nat
  1011   shows "n - m + m = max n m"
  1012     by (simp add: max_def not_le order_less_imp_le)
  1013 
  1014 lemma nat_diff_split:
  1015   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1016     -- {* elimination of @{text -} on @{text nat} *}
  1017 by (cases "a < b")
  1018   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1019     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1020 
  1021 lemma nat_diff_split_asm:
  1022   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1023     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1024 by (auto split: nat_diff_split)
  1025 
  1026 
  1027 subsubsection {* Monotonicity of Multiplication *}
  1028 
  1029 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1030 by (simp add: mult_right_mono)
  1031 
  1032 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1033 by (simp add: mult_left_mono)
  1034 
  1035 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1036 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1037 by (simp add: mult_mono)
  1038 
  1039 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1040 by (simp add: mult_strict_right_mono)
  1041 
  1042 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1043       there are no negative numbers.*}
  1044 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1045   apply (induct m)
  1046    apply simp
  1047   apply (case_tac n)
  1048    apply simp_all
  1049   done
  1050 
  1051 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (1 \<le> m & 1 \<le> n)"
  1052   apply (induct m)
  1053    apply simp
  1054   apply (case_tac n)
  1055    apply simp_all
  1056   done
  1057 
  1058 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1059   apply (safe intro!: mult_less_mono1)
  1060   apply (case_tac k, auto)
  1061   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1062   apply (blast intro: mult_le_mono1)
  1063   done
  1064 
  1065 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1066 by (simp add: mult_commute [of k])
  1067 
  1068 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1069 by (simp add: linorder_not_less [symmetric], auto)
  1070 
  1071 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1072 by (simp add: linorder_not_less [symmetric], auto)
  1073 
  1074 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1075 by (subst mult_less_cancel1) simp
  1076 
  1077 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1078 by (subst mult_le_cancel1) simp
  1079 
  1080 lemma le_square: "m \<le> m * (m::nat)"
  1081   by (cases m) (auto intro: le_add1)
  1082 
  1083 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1084   by (cases m) (auto intro: le_add1)
  1085 
  1086 text {* Lemma for @{text gcd} *}
  1087 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1088   apply (drule sym)
  1089   apply (rule disjCI)
  1090   apply (rule nat_less_cases, erule_tac [2] _)
  1091    apply (drule_tac [2] mult_less_mono2)
  1092     apply (auto)
  1093   done
  1094 
  1095 text {* the lattice order on @{typ nat} *}
  1096 
  1097 instantiation nat :: distrib_lattice
  1098 begin
  1099 
  1100 definition
  1101   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1102 
  1103 definition
  1104   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1105 
  1106 instance by intro_classes
  1107   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1108     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1109 
  1110 end
  1111 
  1112 
  1113 subsection {* Embedding of the Naturals into any
  1114   @{text semiring_1}: @{term of_nat} *}
  1115 
  1116 context semiring_1
  1117 begin
  1118 
  1119 primrec
  1120   of_nat :: "nat \<Rightarrow> 'a"
  1121 where
  1122   of_nat_0:     "of_nat 0 = 0"
  1123   | of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1124 
  1125 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1126   by simp
  1127 
  1128 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1129   by (induct m) (simp_all add: add_ac)
  1130 
  1131 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1132   by (induct m) (simp_all add: add_ac left_distrib)
  1133 
  1134 definition
  1135   of_nat_aux :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1136 where
  1137   [code func del]: "of_nat_aux n i = of_nat n + i"
  1138 
  1139 lemma of_nat_aux_code [code]:
  1140   "of_nat_aux 0 i = i"
  1141   "of_nat_aux (Suc n) i = of_nat_aux n (i + 1)" -- {* tail recursive *}
  1142   by (simp_all add: of_nat_aux_def add_ac)
  1143 
  1144 lemma of_nat_code [code]:
  1145   "of_nat n = of_nat_aux n 0"
  1146   by (simp add: of_nat_aux_def)
  1147 
  1148 end
  1149 
  1150 text{*Class for unital semirings with characteristic zero.
  1151  Includes non-ordered rings like the complex numbers.*}
  1152 
  1153 class semiring_char_0 = semiring_1 +
  1154   assumes of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1155 begin
  1156 
  1157 text{*Special cases where either operand is zero*}
  1158 
  1159 lemma of_nat_0_eq_iff [simp, noatp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1160   by (rule of_nat_eq_iff [of 0, simplified])
  1161 
  1162 lemma of_nat_eq_0_iff [simp, noatp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1163   by (rule of_nat_eq_iff [of _ 0, simplified])
  1164 
  1165 lemma inj_of_nat: "inj of_nat"
  1166   by (simp add: inj_on_def)
  1167 
  1168 end
  1169 
  1170 context ordered_semidom
  1171 begin
  1172 
  1173 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1174   apply (induct m, simp_all)
  1175   apply (erule order_trans)
  1176   apply (rule ord_le_eq_trans [OF _ add_commute])
  1177   apply (rule less_add_one [THEN less_imp_le])
  1178   done
  1179 
  1180 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1181   apply (induct m n rule: diff_induct, simp_all)
  1182   apply (insert add_less_le_mono [OF zero_less_one zero_le_imp_of_nat], force)
  1183   done
  1184 
  1185 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1186   apply (induct m n rule: diff_induct, simp_all)
  1187   apply (insert zero_le_imp_of_nat)
  1188   apply (force simp add: not_less [symmetric])
  1189   done
  1190 
  1191 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1192   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1193 
  1194 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1195   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1196 
  1197 text{*Every @{text ordered_semidom} has characteristic zero.*}
  1198 
  1199 subclass semiring_char_0
  1200   by unfold_locales (simp add: eq_iff order_eq_iff)
  1201 
  1202 text{*Special cases where either operand is zero*}
  1203 
  1204 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1205   by (rule of_nat_le_iff [of 0, simplified])
  1206 
  1207 lemma of_nat_le_0_iff [simp, noatp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1208   by (rule of_nat_le_iff [of _ 0, simplified])
  1209 
  1210 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1211   by (rule of_nat_less_iff [of 0, simplified])
  1212 
  1213 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1214   by (rule of_nat_less_iff [of _ 0, simplified])
  1215 
  1216 end
  1217 
  1218 context ring_1
  1219 begin
  1220 
  1221 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1222   by (simp add: compare_rls of_nat_add [symmetric])
  1223 
  1224 end
  1225 
  1226 context ordered_idom
  1227 begin
  1228 
  1229 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1230   unfolding abs_if by auto
  1231 
  1232 end
  1233 
  1234 lemma of_nat_id [simp]: "of_nat n = n"
  1235   by (induct n) auto
  1236 
  1237 lemma of_nat_eq_id [simp]: "of_nat = id"
  1238   by (auto simp add: expand_fun_eq)
  1239 
  1240 
  1241 subsection {* The Set of Natural Numbers *}
  1242 
  1243 context semiring_1
  1244 begin
  1245 
  1246 definition
  1247   Nats  :: "'a set" where
  1248   "Nats = range of_nat"
  1249 
  1250 notation (xsymbols)
  1251   Nats  ("\<nat>")
  1252 
  1253 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1254   by (simp add: Nats_def)
  1255 
  1256 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1257 apply (simp add: Nats_def)
  1258 apply (rule range_eqI)
  1259 apply (rule of_nat_0 [symmetric])
  1260 done
  1261 
  1262 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1263 apply (simp add: Nats_def)
  1264 apply (rule range_eqI)
  1265 apply (rule of_nat_1 [symmetric])
  1266 done
  1267 
  1268 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1269 apply (auto simp add: Nats_def)
  1270 apply (rule range_eqI)
  1271 apply (rule of_nat_add [symmetric])
  1272 done
  1273 
  1274 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1275 apply (auto simp add: Nats_def)
  1276 apply (rule range_eqI)
  1277 apply (rule of_nat_mult [symmetric])
  1278 done
  1279 
  1280 end
  1281 
  1282 
  1283 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1284 
  1285 lemma subst_equals:
  1286   assumes 1: "t = s" and 2: "u = t"
  1287   shows "u = s"
  1288   using 2 1 by (rule trans)
  1289 
  1290 use "arith_data.ML"
  1291 declaration {* K ArithData.setup *}
  1292 
  1293 use "Tools/lin_arith.ML"
  1294 declaration {* K LinArith.setup *}
  1295 
  1296 lemmas [arith_split] = nat_diff_split split_min split_max
  1297 
  1298 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1299 
  1300 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1301 by arith
  1302 
  1303 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1304 by arith
  1305 
  1306 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1307 by arith
  1308 
  1309 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1310 by arith
  1311 
  1312 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1313 by arith
  1314 
  1315 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1316 by arith
  1317 
  1318 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1319   second premise n\<le>m*)
  1320 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1321 by arith
  1322 
  1323 text {* Simplification of relational expressions involving subtraction *}
  1324 
  1325 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1326 by (simp split add: nat_diff_split)
  1327 
  1328 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1329 by (auto split add: nat_diff_split)
  1330 
  1331 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1332 by (auto split add: nat_diff_split)
  1333 
  1334 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1335 by (auto split add: nat_diff_split)
  1336 
  1337 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1338 
  1339 (* Monotonicity of subtraction in first argument *)
  1340 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1341 by (simp split add: nat_diff_split)
  1342 
  1343 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1344 by (simp split add: nat_diff_split)
  1345 
  1346 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1347 by (simp split add: nat_diff_split)
  1348 
  1349 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1350 by (simp split add: nat_diff_split)
  1351 
  1352 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1353 unfolding min_def by auto
  1354 
  1355 lemma inj_on_diff_nat: 
  1356   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1357   shows "inj_on (\<lambda>n. n - k) N"
  1358 proof (rule inj_onI)
  1359   fix x y
  1360   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1361   with k_le_n have "x - k + k = y - k + k" by auto
  1362   with a k_le_n show "x = y" by auto
  1363 qed
  1364 
  1365 text{*Rewriting to pull differences out*}
  1366 
  1367 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1368 by arith
  1369 
  1370 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1371 by arith
  1372 
  1373 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1374 by arith
  1375 
  1376 text{*Lemmas for ex/Factorization*}
  1377 
  1378 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1379 by (cases m) auto
  1380 
  1381 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1382 by (cases m) auto
  1383 
  1384 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1385 by (cases m) auto
  1386 
  1387 text {* Specialized induction principles that work "backwards": *}
  1388 
  1389 lemma inc_induct[consumes 1, case_names base step]:
  1390   assumes less: "i <= j"
  1391   assumes base: "P j"
  1392   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1393   shows "P i"
  1394   using less
  1395 proof (induct d=="j - i" arbitrary: i)
  1396   case (0 i)
  1397   hence "i = j" by simp
  1398   with base show ?case by simp
  1399 next
  1400   case (Suc d i)
  1401   hence "i < j" "P (Suc i)"
  1402     by simp_all
  1403   thus "P i" by (rule step)
  1404 qed
  1405 
  1406 lemma strict_inc_induct[consumes 1, case_names base step]:
  1407   assumes less: "i < j"
  1408   assumes base: "!!i. j = Suc i ==> P i"
  1409   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1410   shows "P i"
  1411   using less
  1412 proof (induct d=="j - i - 1" arbitrary: i)
  1413   case (0 i)
  1414   with `i < j` have "j = Suc i" by simp
  1415   with base show ?case by simp
  1416 next
  1417   case (Suc d i)
  1418   hence "i < j" "P (Suc i)"
  1419     by simp_all
  1420   thus "P i" by (rule step)
  1421 qed
  1422 
  1423 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1424   using inc_induct[of "k - i" k P, simplified] by blast
  1425 
  1426 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1427   using inc_induct[of 0 k P] by blast
  1428 
  1429 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
  1430   by auto
  1431 
  1432 (*The others are
  1433       i - j - k = i - (j + k),
  1434       k \<le> j ==> j - k + i = j + i - k,
  1435       k \<le> j ==> i + (j - k) = i + j - k *)
  1436 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1437 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1438 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1439 
  1440 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1441 Least_Suc}, since there appears to be no need.*}
  1442 
  1443 subsection {* size of a datatype value *}
  1444 
  1445 class size = type +
  1446   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1447 
  1448 end