src/HOL/Limits.thy
author wenzelm
Sun Sep 13 22:56:52 2015 +0200 (2015-09-13)
changeset 61169 4de9ff3ea29a
parent 61076 bdc1e2f0a86a
child 61524 f2e51e704a96
permissions -rw-r--r--
tuned proofs -- less legacy;
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 *)
     7 
     8 section \<open>Limits on Real Vector Spaces\<close>
     9 
    10 theory Limits
    11 imports Real_Vector_Spaces
    12 begin
    13 
    14 subsection \<open>Filter going to infinity norm\<close>
    15 
    16 definition at_infinity :: "'a::real_normed_vector filter" where
    17   "at_infinity = (INF r. principal {x. r \<le> norm x})"
    18 
    19 lemma eventually_at_infinity: "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    20   unfolding at_infinity_def
    21   by (subst eventually_INF_base)
    22      (auto simp: subset_eq eventually_principal intro!: exI[of _ "max a b" for a b])
    23 
    24 lemma at_infinity_eq_at_top_bot:
    25   "(at_infinity :: real filter) = sup at_top at_bot"
    26   apply (simp add: filter_eq_iff eventually_sup eventually_at_infinity
    27                    eventually_at_top_linorder eventually_at_bot_linorder)
    28   apply safe
    29   apply (rule_tac x="b" in exI, simp)
    30   apply (rule_tac x="- b" in exI, simp)
    31   apply (rule_tac x="max (- Na) N" in exI, auto simp: abs_real_def)
    32   done
    33 
    34 lemma at_top_le_at_infinity: "at_top \<le> (at_infinity :: real filter)"
    35   unfolding at_infinity_eq_at_top_bot by simp
    36 
    37 lemma at_bot_le_at_infinity: "at_bot \<le> (at_infinity :: real filter)"
    38   unfolding at_infinity_eq_at_top_bot by simp
    39 
    40 lemma filterlim_at_top_imp_at_infinity:
    41   fixes f :: "_ \<Rightarrow> real"
    42   shows "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
    43   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
    44 
    45 lemma lim_infinity_imp_sequentially:
    46   "(f ---> l) at_infinity \<Longrightarrow> ((\<lambda>n. f(n)) ---> l) sequentially"
    47 by (simp add: filterlim_at_top_imp_at_infinity filterlim_compose filterlim_real_sequentially)
    48 
    49 
    50 subsubsection \<open>Boundedness\<close>
    51 
    52 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool" where
    53   Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    54 
    55 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    56   "Bseq X \<equiv> Bfun X sequentially"
    57 
    58 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    59 
    60 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    61   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    62 
    63 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    64   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    65 
    66 lemma Bfun_def:
    67   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    68   unfolding Bfun_metric_def norm_conv_dist
    69 proof safe
    70   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    71   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    72     by (intro always_eventually) (metis dist_commute dist_triangle)
    73   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    74     by eventually_elim auto
    75   with \<open>0 < K\<close> show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    76     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    77 qed auto
    78 
    79 lemma BfunI:
    80   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    81 unfolding Bfun_def
    82 proof (intro exI conjI allI)
    83   show "0 < max K 1" by simp
    84 next
    85   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    86     using K by (rule eventually_elim1, simp)
    87 qed
    88 
    89 lemma BfunE:
    90   assumes "Bfun f F"
    91   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
    92 using assms unfolding Bfun_def by fast
    93 
    94 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
    95   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
    96   apply (erule_tac x=1 in allE)
    97   apply simp
    98   apply safe
    99   apply (rule_tac x="X M" in exI)
   100   apply (rule_tac x=1 in exI)
   101   apply (erule_tac x=M in allE)
   102   apply simp
   103   apply (rule_tac x=M in exI)
   104   apply (auto simp: dist_commute)
   105   done
   106 
   107 
   108 subsubsection \<open>Bounded Sequences\<close>
   109 
   110 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   111   by (intro BfunI) (auto simp: eventually_sequentially)
   112 
   113 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   114   by (intro BfunI) (auto simp: eventually_sequentially)
   115 
   116 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   117   unfolding Bfun_def eventually_sequentially
   118 proof safe
   119   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   120   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   121     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   122        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   123 qed auto
   124 
   125 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   126 unfolding Bseq_def by auto
   127 
   128 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   129 by (simp add: Bseq_def)
   130 
   131 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   132 by (auto simp add: Bseq_def)
   133 
   134 lemma Bseq_bdd_above: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_above (range X)"
   135 proof (elim BseqE, intro bdd_aboveI2)
   136   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "X n \<le> K"
   137     by (auto elim!: allE[of _ n])
   138 qed
   139 
   140 lemma Bseq_bdd_below: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_below (range X)"
   141 proof (elim BseqE, intro bdd_belowI2)
   142   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "- K \<le> X n"
   143     by (auto elim!: allE[of _ n])
   144 qed
   145 
   146 lemma lemma_NBseq_def:
   147   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   148 proof safe
   149   fix K :: real
   150   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   151   then have "K \<le> real (Suc n)" by auto
   152   moreover assume "\<forall>m. norm (X m) \<le> K"
   153   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   154     by (blast intro: order_trans)
   155   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   156 qed (force simp add: real_of_nat_Suc)
   157 
   158 text\<open>alternative definition for Bseq\<close>
   159 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   160 apply (simp add: Bseq_def)
   161 apply (simp (no_asm) add: lemma_NBseq_def)
   162 done
   163 
   164 lemma lemma_NBseq_def2:
   165      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   166 apply (subst lemma_NBseq_def, auto)
   167 apply (rule_tac x = "Suc N" in exI)
   168 apply (rule_tac [2] x = N in exI)
   169 apply (auto simp add: real_of_nat_Suc)
   170  prefer 2 apply (blast intro: order_less_imp_le)
   171 apply (drule_tac x = n in spec, simp)
   172 done
   173 
   174 (* yet another definition for Bseq *)
   175 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   176 by (simp add: Bseq_def lemma_NBseq_def2)
   177 
   178 subsubsection\<open>A Few More Equivalence Theorems for Boundedness\<close>
   179 
   180 text\<open>alternative formulation for boundedness\<close>
   181 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   182 apply (unfold Bseq_def, safe)
   183 apply (rule_tac [2] x = "k + norm x" in exI)
   184 apply (rule_tac x = K in exI, simp)
   185 apply (rule exI [where x = 0], auto)
   186 apply (erule order_less_le_trans, simp)
   187 apply (drule_tac x=n in spec)
   188 apply (drule order_trans [OF norm_triangle_ineq2])
   189 apply simp
   190 done
   191 
   192 text\<open>alternative formulation for boundedness\<close>
   193 lemma Bseq_iff3:
   194   "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)" (is "?P \<longleftrightarrow> ?Q")
   195 proof
   196   assume ?P
   197   then obtain K
   198     where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K" by (auto simp add: Bseq_def)
   199   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   200   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   201     by (auto intro: order_trans norm_triangle_ineq4)
   202   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   203     by simp
   204   with \<open>0 < K + norm (X 0)\<close> show ?Q by blast
   205 next
   206   assume ?Q then show ?P by (auto simp add: Bseq_iff2)
   207 qed
   208 
   209 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   210 apply (simp add: Bseq_def)
   211 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   212 apply (drule_tac x = n in spec, arith)
   213 done
   214 
   215 
   216 subsubsection\<open>Upper Bounds and Lubs of Bounded Sequences\<close>
   217 
   218 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
   219   by (simp add: Bseq_def)
   220 
   221 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
   222   apply (simp add: subset_eq)
   223   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   224   apply (erule_tac x=n in allE)
   225   apply auto
   226   done
   227 
   228 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
   229   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   230 
   231 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
   232   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   233 
   234 subsection \<open>Bounded Monotonic Sequences\<close>
   235 
   236 subsubsection\<open>A Bounded and Monotonic Sequence Converges\<close>
   237 
   238 (* TODO: delete *)
   239 (* FIXME: one use in NSA/HSEQ.thy *)
   240 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   241   apply (rule_tac x="X m" in exI)
   242   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   243   unfolding eventually_sequentially
   244   apply blast
   245   done
   246 
   247 subsection \<open>Convergence to Zero\<close>
   248 
   249 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   250   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   251 
   252 lemma ZfunI:
   253   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   254   unfolding Zfun_def by simp
   255 
   256 lemma ZfunD:
   257   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   258   unfolding Zfun_def by simp
   259 
   260 lemma Zfun_ssubst:
   261   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   262   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   263 
   264 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   265   unfolding Zfun_def by simp
   266 
   267 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   268   unfolding Zfun_def by simp
   269 
   270 lemma Zfun_imp_Zfun:
   271   assumes f: "Zfun f F"
   272   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   273   shows "Zfun (\<lambda>x. g x) F"
   274 proof (cases)
   275   assume K: "0 < K"
   276   show ?thesis
   277   proof (rule ZfunI)
   278     fix r::real assume "0 < r"
   279     hence "0 < r / K" using K by simp
   280     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   281       using ZfunD [OF f] by fast
   282     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   283     proof eventually_elim
   284       case (elim x)
   285       hence "norm (f x) * K < r"
   286         by (simp add: pos_less_divide_eq K)
   287       thus ?case
   288         by (simp add: order_le_less_trans [OF elim(1)])
   289     qed
   290   qed
   291 next
   292   assume "\<not> 0 < K"
   293   hence K: "K \<le> 0" by (simp only: not_less)
   294   show ?thesis
   295   proof (rule ZfunI)
   296     fix r :: real
   297     assume "0 < r"
   298     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   299     proof eventually_elim
   300       case (elim x)
   301       also have "norm (f x) * K \<le> norm (f x) * 0"
   302         using K norm_ge_zero by (rule mult_left_mono)
   303       finally show ?case
   304         using \<open>0 < r\<close> by simp
   305     qed
   306   qed
   307 qed
   308 
   309 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   310   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   311 
   312 lemma Zfun_add:
   313   assumes f: "Zfun f F" and g: "Zfun g F"
   314   shows "Zfun (\<lambda>x. f x + g x) F"
   315 proof (rule ZfunI)
   316   fix r::real assume "0 < r"
   317   hence r: "0 < r / 2" by simp
   318   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   319     using f r by (rule ZfunD)
   320   moreover
   321   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   322     using g r by (rule ZfunD)
   323   ultimately
   324   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   325   proof eventually_elim
   326     case (elim x)
   327     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   328       by (rule norm_triangle_ineq)
   329     also have "\<dots> < r/2 + r/2"
   330       using elim by (rule add_strict_mono)
   331     finally show ?case
   332       by simp
   333   qed
   334 qed
   335 
   336 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   337   unfolding Zfun_def by simp
   338 
   339 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   340   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   341 
   342 lemma (in bounded_linear) Zfun:
   343   assumes g: "Zfun g F"
   344   shows "Zfun (\<lambda>x. f (g x)) F"
   345 proof -
   346   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   347     using bounded by fast
   348   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   349     by simp
   350   with g show ?thesis
   351     by (rule Zfun_imp_Zfun)
   352 qed
   353 
   354 lemma (in bounded_bilinear) Zfun:
   355   assumes f: "Zfun f F"
   356   assumes g: "Zfun g F"
   357   shows "Zfun (\<lambda>x. f x ** g x) F"
   358 proof (rule ZfunI)
   359   fix r::real assume r: "0 < r"
   360   obtain K where K: "0 < K"
   361     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   362     using pos_bounded by fast
   363   from K have K': "0 < inverse K"
   364     by (rule positive_imp_inverse_positive)
   365   have "eventually (\<lambda>x. norm (f x) < r) F"
   366     using f r by (rule ZfunD)
   367   moreover
   368   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   369     using g K' by (rule ZfunD)
   370   ultimately
   371   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   372   proof eventually_elim
   373     case (elim x)
   374     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   375       by (rule norm_le)
   376     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   377       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   378     also from K have "r * inverse K * K = r"
   379       by simp
   380     finally show ?case .
   381   qed
   382 qed
   383 
   384 lemma (in bounded_bilinear) Zfun_left:
   385   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   386   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   387 
   388 lemma (in bounded_bilinear) Zfun_right:
   389   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   390   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   391 
   392 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   393 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   394 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   395 
   396 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   397   by (simp only: tendsto_iff Zfun_def dist_norm)
   398 
   399 lemma tendsto_0_le: "\<lbrakk>(f ---> 0) F; eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F\<rbrakk>
   400                      \<Longrightarrow> (g ---> 0) F"
   401   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
   402 
   403 subsubsection \<open>Distance and norms\<close>
   404 
   405 lemma tendsto_dist [tendsto_intros]:
   406   fixes l m :: "'a :: metric_space"
   407   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   408   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   409 proof (rule tendstoI)
   410   fix e :: real assume "0 < e"
   411   hence e2: "0 < e/2" by simp
   412   from tendstoD [OF f e2] tendstoD [OF g e2]
   413   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   414   proof (eventually_elim)
   415     case (elim x)
   416     then show "dist (dist (f x) (g x)) (dist l m) < e"
   417       unfolding dist_real_def
   418       using dist_triangle2 [of "f x" "g x" "l"]
   419       using dist_triangle2 [of "g x" "l" "m"]
   420       using dist_triangle3 [of "l" "m" "f x"]
   421       using dist_triangle [of "f x" "m" "g x"]
   422       by arith
   423   qed
   424 qed
   425 
   426 lemma continuous_dist[continuous_intros]:
   427   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   428   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   429   unfolding continuous_def by (rule tendsto_dist)
   430 
   431 lemma continuous_on_dist[continuous_intros]:
   432   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   433   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   434   unfolding continuous_on_def by (auto intro: tendsto_dist)
   435 
   436 lemma tendsto_norm [tendsto_intros]:
   437   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   438   unfolding norm_conv_dist by (intro tendsto_intros)
   439 
   440 lemma continuous_norm [continuous_intros]:
   441   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   442   unfolding continuous_def by (rule tendsto_norm)
   443 
   444 lemma continuous_on_norm [continuous_intros]:
   445   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   446   unfolding continuous_on_def by (auto intro: tendsto_norm)
   447 
   448 lemma tendsto_norm_zero:
   449   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   450   by (drule tendsto_norm, simp)
   451 
   452 lemma tendsto_norm_zero_cancel:
   453   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   454   unfolding tendsto_iff dist_norm by simp
   455 
   456 lemma tendsto_norm_zero_iff:
   457   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   458   unfolding tendsto_iff dist_norm by simp
   459 
   460 lemma tendsto_rabs [tendsto_intros]:
   461   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   462   by (fold real_norm_def, rule tendsto_norm)
   463 
   464 lemma continuous_rabs [continuous_intros]:
   465   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   466   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   467 
   468 lemma continuous_on_rabs [continuous_intros]:
   469   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   470   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   471 
   472 lemma tendsto_rabs_zero:
   473   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   474   by (fold real_norm_def, rule tendsto_norm_zero)
   475 
   476 lemma tendsto_rabs_zero_cancel:
   477   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   478   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   479 
   480 lemma tendsto_rabs_zero_iff:
   481   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   482   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   483 
   484 subsubsection \<open>Addition and subtraction\<close>
   485 
   486 lemma tendsto_add [tendsto_intros]:
   487   fixes a b :: "'a::real_normed_vector"
   488   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   489   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   490 
   491 lemma continuous_add [continuous_intros]:
   492   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   493   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   494   unfolding continuous_def by (rule tendsto_add)
   495 
   496 lemma continuous_on_add [continuous_intros]:
   497   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   498   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   499   unfolding continuous_on_def by (auto intro: tendsto_add)
   500 
   501 lemma tendsto_add_zero:
   502   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   503   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   504   by (drule (1) tendsto_add, simp)
   505 
   506 lemma tendsto_minus [tendsto_intros]:
   507   fixes a :: "'a::real_normed_vector"
   508   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   509   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   510 
   511 lemma continuous_minus [continuous_intros]:
   512   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   513   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   514   unfolding continuous_def by (rule tendsto_minus)
   515 
   516 lemma continuous_on_minus [continuous_intros]:
   517   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   518   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   519   unfolding continuous_on_def by (auto intro: tendsto_minus)
   520 
   521 lemma tendsto_minus_cancel:
   522   fixes a :: "'a::real_normed_vector"
   523   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   524   by (drule tendsto_minus, simp)
   525 
   526 lemma tendsto_minus_cancel_left:
   527     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
   528   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   529   by auto
   530 
   531 lemma tendsto_diff [tendsto_intros]:
   532   fixes a b :: "'a::real_normed_vector"
   533   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   534   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   535 
   536 lemma continuous_diff [continuous_intros]:
   537   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   538   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   539   unfolding continuous_def by (rule tendsto_diff)
   540 
   541 lemma continuous_on_diff [continuous_intros]:
   542   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   543   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   544   unfolding continuous_on_def by (auto intro: tendsto_diff)
   545 
   546 lemma tendsto_setsum [tendsto_intros]:
   547   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   548   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   549   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   550 proof (cases "finite S")
   551   assume "finite S" thus ?thesis using assms
   552     by (induct, simp, simp add: tendsto_add)
   553 qed simp
   554 
   555 lemma continuous_setsum [continuous_intros]:
   556   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   557   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   558   unfolding continuous_def by (rule tendsto_setsum)
   559 
   560 lemma continuous_on_setsum [continuous_intros]:
   561   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   562   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   563   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   564 
   565 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   566 
   567 subsubsection \<open>Linear operators and multiplication\<close>
   568 
   569 lemma (in bounded_linear) tendsto:
   570   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   571   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   572 
   573 lemma (in bounded_linear) continuous:
   574   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   575   using tendsto[of g _ F] by (auto simp: continuous_def)
   576 
   577 lemma (in bounded_linear) continuous_on:
   578   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   579   using tendsto[of g] by (auto simp: continuous_on_def)
   580 
   581 lemma (in bounded_linear) tendsto_zero:
   582   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   583   by (drule tendsto, simp only: zero)
   584 
   585 lemma (in bounded_bilinear) tendsto:
   586   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   587   by (simp only: tendsto_Zfun_iff prod_diff_prod
   588                  Zfun_add Zfun Zfun_left Zfun_right)
   589 
   590 lemma (in bounded_bilinear) continuous:
   591   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   592   using tendsto[of f _ F g] by (auto simp: continuous_def)
   593 
   594 lemma (in bounded_bilinear) continuous_on:
   595   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   596   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   597 
   598 lemma (in bounded_bilinear) tendsto_zero:
   599   assumes f: "(f ---> 0) F"
   600   assumes g: "(g ---> 0) F"
   601   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   602   using tendsto [OF f g] by (simp add: zero_left)
   603 
   604 lemma (in bounded_bilinear) tendsto_left_zero:
   605   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   606   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   607 
   608 lemma (in bounded_bilinear) tendsto_right_zero:
   609   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   610   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   611 
   612 lemmas tendsto_of_real [tendsto_intros] =
   613   bounded_linear.tendsto [OF bounded_linear_of_real]
   614 
   615 lemmas tendsto_scaleR [tendsto_intros] =
   616   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   617 
   618 lemmas tendsto_mult [tendsto_intros] =
   619   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   620 
   621 lemmas continuous_of_real [continuous_intros] =
   622   bounded_linear.continuous [OF bounded_linear_of_real]
   623 
   624 lemmas continuous_scaleR [continuous_intros] =
   625   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   626 
   627 lemmas continuous_mult [continuous_intros] =
   628   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   629 
   630 lemmas continuous_on_of_real [continuous_intros] =
   631   bounded_linear.continuous_on [OF bounded_linear_of_real]
   632 
   633 lemmas continuous_on_scaleR [continuous_intros] =
   634   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   635 
   636 lemmas continuous_on_mult [continuous_intros] =
   637   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   638 
   639 lemmas tendsto_mult_zero =
   640   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   641 
   642 lemmas tendsto_mult_left_zero =
   643   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   644 
   645 lemmas tendsto_mult_right_zero =
   646   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   647 
   648 lemma tendsto_power [tendsto_intros]:
   649   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   650   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   651   by (induct n) (simp_all add: tendsto_mult)
   652 
   653 lemma continuous_power [continuous_intros]:
   654   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   655   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   656   unfolding continuous_def by (rule tendsto_power)
   657 
   658 lemma continuous_on_power [continuous_intros]:
   659   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   660   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   661   unfolding continuous_on_def by (auto intro: tendsto_power)
   662 
   663 lemma tendsto_setprod [tendsto_intros]:
   664   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   665   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   666   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   667 proof (cases "finite S")
   668   assume "finite S" thus ?thesis using assms
   669     by (induct, simp, simp add: tendsto_mult)
   670 qed simp
   671 
   672 lemma continuous_setprod [continuous_intros]:
   673   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   674   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   675   unfolding continuous_def by (rule tendsto_setprod)
   676 
   677 lemma continuous_on_setprod [continuous_intros]:
   678   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   679   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   680   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   681 
   682 subsubsection \<open>Inverse and division\<close>
   683 
   684 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   685   assumes f: "Zfun f F"
   686   assumes g: "Bfun g F"
   687   shows "Zfun (\<lambda>x. f x ** g x) F"
   688 proof -
   689   obtain K where K: "0 \<le> K"
   690     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   691     using nonneg_bounded by fast
   692   obtain B where B: "0 < B"
   693     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   694     using g by (rule BfunE)
   695   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   696   using norm_g proof eventually_elim
   697     case (elim x)
   698     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   699       by (rule norm_le)
   700     also have "\<dots> \<le> norm (f x) * B * K"
   701       by (intro mult_mono' order_refl norm_g norm_ge_zero
   702                 mult_nonneg_nonneg K elim)
   703     also have "\<dots> = norm (f x) * (B * K)"
   704       by (rule mult.assoc)
   705     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   706   qed
   707   with f show ?thesis
   708     by (rule Zfun_imp_Zfun)
   709 qed
   710 
   711 lemma (in bounded_bilinear) flip:
   712   "bounded_bilinear (\<lambda>x y. y ** x)"
   713   apply standard
   714   apply (rule add_right)
   715   apply (rule add_left)
   716   apply (rule scaleR_right)
   717   apply (rule scaleR_left)
   718   apply (subst mult.commute)
   719   using bounded
   720   apply fast
   721   done
   722 
   723 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   724   assumes f: "Bfun f F"
   725   assumes g: "Zfun g F"
   726   shows "Zfun (\<lambda>x. f x ** g x) F"
   727   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   728 
   729 lemma Bfun_inverse_lemma:
   730   fixes x :: "'a::real_normed_div_algebra"
   731   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   732   apply (subst nonzero_norm_inverse, clarsimp)
   733   apply (erule (1) le_imp_inverse_le)
   734   done
   735 
   736 lemma Bfun_inverse:
   737   fixes a :: "'a::real_normed_div_algebra"
   738   assumes f: "(f ---> a) F"
   739   assumes a: "a \<noteq> 0"
   740   shows "Bfun (\<lambda>x. inverse (f x)) F"
   741 proof -
   742   from a have "0 < norm a" by simp
   743   hence "\<exists>r>0. r < norm a" by (rule dense)
   744   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   745   have "eventually (\<lambda>x. dist (f x) a < r) F"
   746     using tendstoD [OF f r1] by fast
   747   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   748   proof eventually_elim
   749     case (elim x)
   750     hence 1: "norm (f x - a) < r"
   751       by (simp add: dist_norm)
   752     hence 2: "f x \<noteq> 0" using r2 by auto
   753     hence "norm (inverse (f x)) = inverse (norm (f x))"
   754       by (rule nonzero_norm_inverse)
   755     also have "\<dots> \<le> inverse (norm a - r)"
   756     proof (rule le_imp_inverse_le)
   757       show "0 < norm a - r" using r2 by simp
   758     next
   759       have "norm a - norm (f x) \<le> norm (a - f x)"
   760         by (rule norm_triangle_ineq2)
   761       also have "\<dots> = norm (f x - a)"
   762         by (rule norm_minus_commute)
   763       also have "\<dots> < r" using 1 .
   764       finally show "norm a - r \<le> norm (f x)" by simp
   765     qed
   766     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   767   qed
   768   thus ?thesis by (rule BfunI)
   769 qed
   770 
   771 lemma tendsto_inverse [tendsto_intros]:
   772   fixes a :: "'a::real_normed_div_algebra"
   773   assumes f: "(f ---> a) F"
   774   assumes a: "a \<noteq> 0"
   775   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   776 proof -
   777   from a have "0 < norm a" by simp
   778   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   779     by (rule tendstoD)
   780   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   781     unfolding dist_norm by (auto elim!: eventually_elim1)
   782   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   783     - (inverse (f x) * (f x - a) * inverse a)) F"
   784     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   785   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   786     by (intro Zfun_minus Zfun_mult_left
   787       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   788       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   789   ultimately show ?thesis
   790     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   791 qed
   792 
   793 lemma continuous_inverse:
   794   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   795   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   796   shows "continuous F (\<lambda>x. inverse (f x))"
   797   using assms unfolding continuous_def by (rule tendsto_inverse)
   798 
   799 lemma continuous_at_within_inverse[continuous_intros]:
   800   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   801   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   802   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   803   using assms unfolding continuous_within by (rule tendsto_inverse)
   804 
   805 lemma isCont_inverse[continuous_intros, simp]:
   806   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   807   assumes "isCont f a" and "f a \<noteq> 0"
   808   shows "isCont (\<lambda>x. inverse (f x)) a"
   809   using assms unfolding continuous_at by (rule tendsto_inverse)
   810 
   811 lemma continuous_on_inverse[continuous_intros]:
   812   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   813   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   814   shows "continuous_on s (\<lambda>x. inverse (f x))"
   815   using assms unfolding continuous_on_def by (fast intro: tendsto_inverse)
   816 
   817 lemma tendsto_divide [tendsto_intros]:
   818   fixes a b :: "'a::real_normed_field"
   819   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
   820     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
   821   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   822 
   823 lemma continuous_divide:
   824   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   825   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   826   shows "continuous F (\<lambda>x. (f x) / (g x))"
   827   using assms unfolding continuous_def by (rule tendsto_divide)
   828 
   829 lemma continuous_at_within_divide[continuous_intros]:
   830   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   831   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   832   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   833   using assms unfolding continuous_within by (rule tendsto_divide)
   834 
   835 lemma isCont_divide[continuous_intros, simp]:
   836   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   837   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   838   shows "isCont (\<lambda>x. (f x) / g x) a"
   839   using assms unfolding continuous_at by (rule tendsto_divide)
   840 
   841 lemma continuous_on_divide[continuous_intros]:
   842   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   843   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   844   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   845   using assms unfolding continuous_on_def by (fast intro: tendsto_divide)
   846 
   847 lemma tendsto_sgn [tendsto_intros]:
   848   fixes l :: "'a::real_normed_vector"
   849   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
   850   unfolding sgn_div_norm by (simp add: tendsto_intros)
   851 
   852 lemma continuous_sgn:
   853   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   854   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   855   shows "continuous F (\<lambda>x. sgn (f x))"
   856   using assms unfolding continuous_def by (rule tendsto_sgn)
   857 
   858 lemma continuous_at_within_sgn[continuous_intros]:
   859   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   860   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   861   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   862   using assms unfolding continuous_within by (rule tendsto_sgn)
   863 
   864 lemma isCont_sgn[continuous_intros]:
   865   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   866   assumes "isCont f a" and "f a \<noteq> 0"
   867   shows "isCont (\<lambda>x. sgn (f x)) a"
   868   using assms unfolding continuous_at by (rule tendsto_sgn)
   869 
   870 lemma continuous_on_sgn[continuous_intros]:
   871   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   872   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   873   shows "continuous_on s (\<lambda>x. sgn (f x))"
   874   using assms unfolding continuous_on_def by (fast intro: tendsto_sgn)
   875 
   876 lemma filterlim_at_infinity:
   877   fixes f :: "_ \<Rightarrow> 'a::real_normed_vector"
   878   assumes "0 \<le> c"
   879   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   880   unfolding filterlim_iff eventually_at_infinity
   881 proof safe
   882   fix P :: "'a \<Rightarrow> bool" and b
   883   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   884     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   885   have "max b (c + 1) > c" by auto
   886   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   887     by auto
   888   then show "eventually (\<lambda>x. P (f x)) F"
   889   proof eventually_elim
   890     fix x assume "max b (c + 1) \<le> norm (f x)"
   891     with P show "P (f x)" by auto
   892   qed
   893 qed force
   894 
   895 subsection \<open>Relate @{const at}, @{const at_left} and @{const at_right}\<close>
   896 
   897 text \<open>
   898 
   899 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
   900 @{term "at_right x"} and also @{term "at_right 0"}.
   901 
   902 \<close>
   903 
   904 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
   905 
   906 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::'a::real_normed_vector)"
   907   by (rule filtermap_fun_inverse[where g="\<lambda>x. x + d"])
   908      (auto intro!: tendsto_eq_intros filterlim_ident)
   909 
   910 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::'a::real_normed_vector)"
   911   by (rule filtermap_fun_inverse[where g=uminus])
   912      (auto intro!: tendsto_eq_intros filterlim_ident)
   913 
   914 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::'a::real_normed_vector)"
   915   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   916 
   917 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
   918   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   919 
   920 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
   921   using filtermap_at_right_shift[of "-a" 0] by simp
   922 
   923 lemma filterlim_at_right_to_0:
   924   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
   925   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
   926 
   927 lemma eventually_at_right_to_0:
   928   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
   929   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
   930 
   931 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::'a::real_normed_vector)"
   932   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   933 
   934 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
   935   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   936 
   937 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
   938   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   939 
   940 lemma filterlim_at_left_to_right:
   941   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
   942   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
   943 
   944 lemma eventually_at_left_to_right:
   945   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
   946   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
   947 
   948 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
   949   unfolding filterlim_at_top eventually_at_bot_dense
   950   by (metis leI minus_less_iff order_less_asym)
   951 
   952 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
   953   unfolding filterlim_at_bot eventually_at_top_dense
   954   by (metis leI less_minus_iff order_less_asym)
   955 
   956 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
   957   by (rule filtermap_fun_inverse[symmetric, of uminus])
   958      (auto intro: filterlim_uminus_at_bot_at_top filterlim_uminus_at_top_at_bot)
   959 
   960 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
   961   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
   962 
   963 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
   964   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
   965 
   966 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
   967   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
   968 
   969 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
   970   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
   971   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
   972   by auto
   973 
   974 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
   975   unfolding filterlim_uminus_at_top by simp
   976 
   977 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
   978   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
   979 proof safe
   980   fix Z :: real assume [arith]: "0 < Z"
   981   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
   982     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
   983   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
   984     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
   985 qed
   986 
   987 lemma tendsto_inverse_0:
   988   fixes x :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
   989   shows "(inverse ---> (0::'a)) at_infinity"
   990   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
   991 proof safe
   992   fix r :: real assume "0 < r"
   993   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
   994   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
   995     fix x :: 'a
   996     from \<open>0 < r\<close> have "0 < inverse (r / 2)" by simp
   997     also assume *: "inverse (r / 2) \<le> norm x"
   998     finally show "norm (inverse x) < r"
   999       using * \<open>0 < r\<close> by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1000   qed
  1001 qed
  1002 
  1003 lemma filterlim_inverse_at_right_top: "LIM x at_top. inverse x :> at_right (0::real)"
  1004   unfolding filterlim_at
  1005   by (auto simp: eventually_at_top_dense)
  1006      (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1007 
  1008 lemma filterlim_inverse_at_top:
  1009   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1010   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1011      (simp add: filterlim_def eventually_filtermap eventually_elim1 at_within_def le_principal)
  1012 
  1013 lemma filterlim_inverse_at_bot_neg:
  1014   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1015   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1016 
  1017 lemma filterlim_inverse_at_bot:
  1018   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1019   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1020   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1021 
  1022 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1023   by (intro filtermap_fun_inverse[symmetric, where g=inverse])
  1024      (auto intro: filterlim_inverse_at_top_right filterlim_inverse_at_right_top)
  1025 
  1026 lemma eventually_at_right_to_top:
  1027   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1028   unfolding at_right_to_top eventually_filtermap ..
  1029 
  1030 lemma filterlim_at_right_to_top:
  1031   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1032   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1033 
  1034 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1035   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1036 
  1037 lemma eventually_at_top_to_right:
  1038   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1039   unfolding at_top_to_right eventually_filtermap ..
  1040 
  1041 lemma filterlim_at_top_to_right:
  1042   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1043   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1044 
  1045 lemma filterlim_inverse_at_infinity:
  1046   fixes x :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1047   shows "filterlim inverse at_infinity (at (0::'a))"
  1048   unfolding filterlim_at_infinity[OF order_refl]
  1049 proof safe
  1050   fix r :: real assume "0 < r"
  1051   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1052     unfolding eventually_at norm_inverse
  1053     by (intro exI[of _ "inverse r"])
  1054        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1055 qed
  1056 
  1057 lemma filterlim_inverse_at_iff:
  1058   fixes g :: "'a \<Rightarrow> 'b::{real_normed_div_algebra, division_ring}"
  1059   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1060   unfolding filterlim_def filtermap_filtermap[symmetric]
  1061 proof
  1062   assume "filtermap g F \<le> at_infinity"
  1063   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1064     by (rule filtermap_mono)
  1065   also have "\<dots> \<le> at 0"
  1066     using tendsto_inverse_0[where 'a='b]
  1067     by (auto intro!: exI[of _ 1]
  1068              simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1069   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1070 next
  1071   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1072   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1073     by (rule filtermap_mono)
  1074   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1075     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1076 qed
  1077 
  1078 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
  1079  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1080 
  1081 
  1082 lemma at_to_infinity:
  1083   fixes x :: "'a :: {real_normed_field,field}"
  1084   shows "(at (0::'a)) = filtermap inverse at_infinity"
  1085 proof (rule antisym)
  1086   have "(inverse ---> (0::'a)) at_infinity"
  1087     by (fact tendsto_inverse_0)
  1088   then show "filtermap inverse at_infinity \<le> at (0::'a)"
  1089     apply (simp add: le_principal eventually_filtermap eventually_at_infinity filterlim_def at_within_def)
  1090     apply (rule_tac x="1" in exI, auto)
  1091     done
  1092 next
  1093   have "filtermap inverse (filtermap inverse (at (0::'a))) \<le> filtermap inverse at_infinity"
  1094     using filterlim_inverse_at_infinity unfolding filterlim_def
  1095     by (rule filtermap_mono)
  1096   then show "at (0::'a) \<le> filtermap inverse at_infinity"
  1097     by (simp add: filtermap_ident filtermap_filtermap)
  1098 qed
  1099 
  1100 lemma lim_at_infinity_0:
  1101   fixes l :: "'a :: {real_normed_field,field}"
  1102   shows "(f ---> l) at_infinity \<longleftrightarrow> ((f o inverse) ---> l) (at (0::'a))"
  1103 by (simp add: tendsto_compose_filtermap at_to_infinity filtermap_filtermap)
  1104 
  1105 lemma lim_zero_infinity:
  1106   fixes l :: "'a :: {real_normed_field,field}"
  1107   shows "((\<lambda>x. f(1 / x)) ---> l) (at (0::'a)) \<Longrightarrow> (f ---> l) at_infinity"
  1108 by (simp add: inverse_eq_divide lim_at_infinity_0 comp_def)
  1109 
  1110 
  1111 text \<open>
  1112 
  1113 We only show rules for multiplication and addition when the functions are either against a real
  1114 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1115 
  1116 \<close>
  1117 
  1118 lemma filterlim_tendsto_pos_mult_at_top:
  1119   assumes f: "(f ---> c) F" and c: "0 < c"
  1120   assumes g: "LIM x F. g x :> at_top"
  1121   shows "LIM x F. (f x * g x :: real) :> at_top"
  1122   unfolding filterlim_at_top_gt[where c=0]
  1123 proof safe
  1124   fix Z :: real assume "0 < Z"
  1125   from f \<open>0 < c\<close> have "eventually (\<lambda>x. c / 2 < f x) F"
  1126     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
  1127              simp: dist_real_def abs_real_def split: split_if_asm)
  1128   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1129     unfolding filterlim_at_top by auto
  1130   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1131   proof eventually_elim
  1132     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1133     with \<open>0 < Z\<close> \<open>0 < c\<close> have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1134       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1135     with \<open>0 < c\<close> show "Z \<le> f x * g x"
  1136        by simp
  1137   qed
  1138 qed
  1139 
  1140 lemma filterlim_at_top_mult_at_top:
  1141   assumes f: "LIM x F. f x :> at_top"
  1142   assumes g: "LIM x F. g x :> at_top"
  1143   shows "LIM x F. (f x * g x :: real) :> at_top"
  1144   unfolding filterlim_at_top_gt[where c=0]
  1145 proof safe
  1146   fix Z :: real assume "0 < Z"
  1147   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1148     unfolding filterlim_at_top by auto
  1149   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1150     unfolding filterlim_at_top by auto
  1151   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1152   proof eventually_elim
  1153     fix x assume "1 \<le> f x" "Z \<le> g x"
  1154     with \<open>0 < Z\<close> have "1 * Z \<le> f x * g x"
  1155       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1156     then show "Z \<le> f x * g x"
  1157        by simp
  1158   qed
  1159 qed
  1160 
  1161 lemma filterlim_tendsto_pos_mult_at_bot:
  1162   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1163   shows "LIM x F. f x * g x :> at_bot"
  1164   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1165   unfolding filterlim_uminus_at_bot by simp
  1166 
  1167 lemma filterlim_tendsto_neg_mult_at_bot:
  1168   assumes c: "(f ---> c) F" "(c::real) < 0" and g: "filterlim g at_top F"
  1169   shows "LIM x F. f x * g x :> at_bot"
  1170   using c filterlim_tendsto_pos_mult_at_top[of "\<lambda>x. - f x" "- c" F, OF _ _ g]
  1171   unfolding filterlim_uminus_at_bot tendsto_minus_cancel_left by simp
  1172 
  1173 lemma filterlim_pow_at_top:
  1174   fixes f :: "real \<Rightarrow> real"
  1175   assumes "0 < n" and f: "LIM x F. f x :> at_top"
  1176   shows "LIM x F. (f x)^n :: real :> at_top"
  1177 using \<open>0 < n\<close> proof (induct n)
  1178   case (Suc n) with f show ?case
  1179     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
  1180 qed simp
  1181 
  1182 lemma filterlim_pow_at_bot_even:
  1183   fixes f :: "real \<Rightarrow> real"
  1184   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
  1185   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
  1186 
  1187 lemma filterlim_pow_at_bot_odd:
  1188   fixes f :: "real \<Rightarrow> real"
  1189   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
  1190   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
  1191 
  1192 lemma filterlim_tendsto_add_at_top:
  1193   assumes f: "(f ---> c) F"
  1194   assumes g: "LIM x F. g x :> at_top"
  1195   shows "LIM x F. (f x + g x :: real) :> at_top"
  1196   unfolding filterlim_at_top_gt[where c=0]
  1197 proof safe
  1198   fix Z :: real assume "0 < Z"
  1199   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1200     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
  1201   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1202     unfolding filterlim_at_top by auto
  1203   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1204     by eventually_elim simp
  1205 qed
  1206 
  1207 lemma LIM_at_top_divide:
  1208   fixes f g :: "'a \<Rightarrow> real"
  1209   assumes f: "(f ---> a) F" "0 < a"
  1210   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1211   shows "LIM x F. f x / g x :> at_top"
  1212   unfolding divide_inverse
  1213   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1214 
  1215 lemma filterlim_at_top_add_at_top:
  1216   assumes f: "LIM x F. f x :> at_top"
  1217   assumes g: "LIM x F. g x :> at_top"
  1218   shows "LIM x F. (f x + g x :: real) :> at_top"
  1219   unfolding filterlim_at_top_gt[where c=0]
  1220 proof safe
  1221   fix Z :: real assume "0 < Z"
  1222   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1223     unfolding filterlim_at_top by auto
  1224   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1225     unfolding filterlim_at_top by auto
  1226   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1227     by eventually_elim simp
  1228 qed
  1229 
  1230 lemma tendsto_divide_0:
  1231   fixes f :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1232   assumes f: "(f ---> c) F"
  1233   assumes g: "LIM x F. g x :> at_infinity"
  1234   shows "((\<lambda>x. f x / g x) ---> 0) F"
  1235   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1236 
  1237 lemma linear_plus_1_le_power:
  1238   fixes x :: real
  1239   assumes x: "0 \<le> x"
  1240   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1241 proof (induct n)
  1242   case (Suc n)
  1243   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1244     by (simp add: field_simps real_of_nat_Suc x)
  1245   also have "\<dots> \<le> (x + 1)^Suc n"
  1246     using Suc x by (simp add: mult_left_mono)
  1247   finally show ?case .
  1248 qed simp
  1249 
  1250 lemma filterlim_realpow_sequentially_gt1:
  1251   fixes x :: "'a :: real_normed_div_algebra"
  1252   assumes x[arith]: "1 < norm x"
  1253   shows "LIM n sequentially. x ^ n :> at_infinity"
  1254 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1255   fix y :: real assume "0 < y"
  1256   have "0 < norm x - 1" by simp
  1257   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1258   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1259   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1260   also have "\<dots> = norm x ^ N" by simp
  1261   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1262     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1263   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1264     unfolding eventually_sequentially
  1265     by (auto simp: norm_power)
  1266 qed simp
  1267 
  1268 
  1269 subsection \<open>Limits of Sequences\<close>
  1270 
  1271 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
  1272   by simp
  1273 
  1274 lemma LIMSEQ_iff:
  1275   fixes L :: "'a::real_normed_vector"
  1276   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1277 unfolding lim_sequentially dist_norm ..
  1278 
  1279 lemma LIMSEQ_I:
  1280   fixes L :: "'a::real_normed_vector"
  1281   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
  1282 by (simp add: LIMSEQ_iff)
  1283 
  1284 lemma LIMSEQ_D:
  1285   fixes L :: "'a::real_normed_vector"
  1286   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1287 by (simp add: LIMSEQ_iff)
  1288 
  1289 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
  1290   unfolding tendsto_def eventually_sequentially
  1291   by (metis div_le_dividend div_mult_self1_is_m le_trans mult.commute)
  1292 
  1293 lemma Bseq_inverse_lemma:
  1294   fixes x :: "'a::real_normed_div_algebra"
  1295   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1296 apply (subst nonzero_norm_inverse, clarsimp)
  1297 apply (erule (1) le_imp_inverse_le)
  1298 done
  1299 
  1300 lemma Bseq_inverse:
  1301   fixes a :: "'a::real_normed_div_algebra"
  1302   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1303   by (rule Bfun_inverse)
  1304 
  1305 text\<open>Transformation of limit.\<close>
  1306 
  1307 lemma eventually_at2:
  1308   "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
  1309   unfolding eventually_at dist_nz by auto
  1310 
  1311 lemma Lim_transform:
  1312   fixes a b :: "'a::real_normed_vector"
  1313   shows "\<lbrakk>(g ---> a) F; ((\<lambda>x. f x - g x) ---> 0) F\<rbrakk> \<Longrightarrow> (f ---> a) F"
  1314   using tendsto_add [of g a F "\<lambda>x. f x - g x" 0] by simp
  1315 
  1316 lemma Lim_transform2:
  1317   fixes a b :: "'a::real_normed_vector"
  1318   shows "\<lbrakk>(f ---> a) F; ((\<lambda>x. f x - g x) ---> 0) F\<rbrakk> \<Longrightarrow> (g ---> a) F"
  1319   by (erule Lim_transform) (simp add: tendsto_minus_cancel)
  1320 
  1321 lemma Lim_transform_eventually:
  1322   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f ---> l) net \<Longrightarrow> (g ---> l) net"
  1323   apply (rule topological_tendstoI)
  1324   apply (drule (2) topological_tendstoD)
  1325   apply (erule (1) eventually_elim2, simp)
  1326   done
  1327 
  1328 lemma Lim_transform_within:
  1329   assumes "0 < d"
  1330     and "\<forall>x'\<in>S. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1331     and "(f ---> l) (at x within S)"
  1332   shows "(g ---> l) (at x within S)"
  1333 proof (rule Lim_transform_eventually)
  1334   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1335     using assms(1,2) by (auto simp: dist_nz eventually_at)
  1336   show "(f ---> l) (at x within S)" by fact
  1337 qed
  1338 
  1339 lemma Lim_transform_at:
  1340   assumes "0 < d"
  1341     and "\<forall>x'. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1342     and "(f ---> l) (at x)"
  1343   shows "(g ---> l) (at x)"
  1344   using _ assms(3)
  1345 proof (rule Lim_transform_eventually)
  1346   show "eventually (\<lambda>x. f x = g x) (at x)"
  1347     unfolding eventually_at2
  1348     using assms(1,2) by auto
  1349 qed
  1350 
  1351 text\<open>Common case assuming being away from some crucial point like 0.\<close>
  1352 
  1353 lemma Lim_transform_away_within:
  1354   fixes a b :: "'a::t1_space"
  1355   assumes "a \<noteq> b"
  1356     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1357     and "(f ---> l) (at a within S)"
  1358   shows "(g ---> l) (at a within S)"
  1359 proof (rule Lim_transform_eventually)
  1360   show "(f ---> l) (at a within S)" by fact
  1361   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1362     unfolding eventually_at_topological
  1363     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  1364 qed
  1365 
  1366 lemma Lim_transform_away_at:
  1367   fixes a b :: "'a::t1_space"
  1368   assumes ab: "a\<noteq>b"
  1369     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1370     and fl: "(f ---> l) (at a)"
  1371   shows "(g ---> l) (at a)"
  1372   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
  1373 
  1374 text\<open>Alternatively, within an open set.\<close>
  1375 
  1376 lemma Lim_transform_within_open:
  1377   assumes "open S" and "a \<in> S"
  1378     and "\<forall>x\<in>S. x \<noteq> a \<longrightarrow> f x = g x"
  1379     and "(f ---> l) (at a)"
  1380   shows "(g ---> l) (at a)"
  1381 proof (rule Lim_transform_eventually)
  1382   show "eventually (\<lambda>x. f x = g x) (at a)"
  1383     unfolding eventually_at_topological
  1384     using assms(1,2,3) by auto
  1385   show "(f ---> l) (at a)" by fact
  1386 qed
  1387 
  1388 text\<open>A congruence rule allowing us to transform limits assuming not at point.\<close>
  1389 
  1390 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1391 
  1392 lemma Lim_cong_within(*[cong add]*):
  1393   assumes "a = b"
  1394     and "x = y"
  1395     and "S = T"
  1396     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1397   shows "(f ---> x) (at a within S) \<longleftrightarrow> (g ---> y) (at b within T)"
  1398   unfolding tendsto_def eventually_at_topological
  1399   using assms by simp
  1400 
  1401 lemma Lim_cong_at(*[cong add]*):
  1402   assumes "a = b" "x = y"
  1403     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1404   shows "((\<lambda>x. f x) ---> x) (at a) \<longleftrightarrow> ((g ---> y) (at a))"
  1405   unfolding tendsto_def eventually_at_topological
  1406   using assms by simp
  1407 text\<open>An unbounded sequence's inverse tends to 0\<close>
  1408 
  1409 lemma LIMSEQ_inverse_zero:
  1410   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
  1411   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1412   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1413   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1414   done
  1415 
  1416 text\<open>The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity\<close>
  1417 
  1418 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
  1419   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1420             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1421 
  1422 text\<open>The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1423 infinity is now easily proved\<close>
  1424 
  1425 lemma LIMSEQ_inverse_real_of_nat_add:
  1426      "(%n. r + inverse(real(Suc n))) ----> r"
  1427   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1428 
  1429 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1430      "(%n. r + -inverse(real(Suc n))) ----> r"
  1431   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1432   by auto
  1433 
  1434 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1435      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
  1436   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1437   by auto
  1438 
  1439 subsection \<open>Convergence on sequences\<close>
  1440 
  1441 lemma convergent_add:
  1442   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1443   assumes "convergent (\<lambda>n. X n)"
  1444   assumes "convergent (\<lambda>n. Y n)"
  1445   shows "convergent (\<lambda>n. X n + Y n)"
  1446   using assms unfolding convergent_def by (fast intro: tendsto_add)
  1447 
  1448 lemma convergent_setsum:
  1449   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1450   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1451   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1452 proof (cases "finite A")
  1453   case True from this and assms show ?thesis
  1454     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1455 qed (simp add: convergent_const)
  1456 
  1457 lemma (in bounded_linear) convergent:
  1458   assumes "convergent (\<lambda>n. X n)"
  1459   shows "convergent (\<lambda>n. f (X n))"
  1460   using assms unfolding convergent_def by (fast intro: tendsto)
  1461 
  1462 lemma (in bounded_bilinear) convergent:
  1463   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1464   shows "convergent (\<lambda>n. X n ** Y n)"
  1465   using assms unfolding convergent_def by (fast intro: tendsto)
  1466 
  1467 lemma convergent_minus_iff:
  1468   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1469   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1470 apply (simp add: convergent_def)
  1471 apply (auto dest: tendsto_minus)
  1472 apply (drule tendsto_minus, auto)
  1473 done
  1474 
  1475 
  1476 text \<open>A monotone sequence converges to its least upper bound.\<close>
  1477 
  1478 lemma LIMSEQ_incseq_SUP:
  1479   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1480   assumes u: "bdd_above (range X)"
  1481   assumes X: "incseq X"
  1482   shows "X ----> (SUP i. X i)"
  1483   by (rule order_tendstoI)
  1484      (auto simp: eventually_sequentially u less_cSUP_iff intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  1485 
  1486 lemma LIMSEQ_decseq_INF:
  1487   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1488   assumes u: "bdd_below (range X)"
  1489   assumes X: "decseq X"
  1490   shows "X ----> (INF i. X i)"
  1491   by (rule order_tendstoI)
  1492      (auto simp: eventually_sequentially u cINF_less_iff intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  1493 
  1494 text\<open>Main monotonicity theorem\<close>
  1495 
  1496 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1497   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP dest: Bseq_bdd_above Bseq_bdd_below)
  1498 
  1499 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1500   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  1501 
  1502 lemma Cauchy_iff:
  1503   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1504   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1505   unfolding Cauchy_def dist_norm ..
  1506 
  1507 lemma CauchyI:
  1508   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1509   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1510 by (simp add: Cauchy_iff)
  1511 
  1512 lemma CauchyD:
  1513   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1514   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1515 by (simp add: Cauchy_iff)
  1516 
  1517 lemma incseq_convergent:
  1518   fixes X :: "nat \<Rightarrow> real"
  1519   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1520   obtains L where "X ----> L" "\<forall>i. X i \<le> L"
  1521 proof atomize_elim
  1522   from incseq_bounded[OF assms] \<open>incseq X\<close> Bseq_monoseq_convergent[of X]
  1523   obtain L where "X ----> L"
  1524     by (auto simp: convergent_def monoseq_def incseq_def)
  1525   with \<open>incseq X\<close> show "\<exists>L. X ----> L \<and> (\<forall>i. X i \<le> L)"
  1526     by (auto intro!: exI[of _ L] incseq_le)
  1527 qed
  1528 
  1529 lemma decseq_convergent:
  1530   fixes X :: "nat \<Rightarrow> real"
  1531   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1532   obtains L where "X ----> L" "\<forall>i. L \<le> X i"
  1533 proof atomize_elim
  1534   from decseq_bounded[OF assms] \<open>decseq X\<close> Bseq_monoseq_convergent[of X]
  1535   obtain L where "X ----> L"
  1536     by (auto simp: convergent_def monoseq_def decseq_def)
  1537   with \<open>decseq X\<close> show "\<exists>L. X ----> L \<and> (\<forall>i. L \<le> X i)"
  1538     by (auto intro!: exI[of _ L] decseq_le)
  1539 qed
  1540 
  1541 subsubsection \<open>Cauchy Sequences are Bounded\<close>
  1542 
  1543 text\<open>A Cauchy sequence is bounded -- this is the standard
  1544   proof mechanization rather than the nonstandard proof\<close>
  1545 
  1546 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1547           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1548 apply (clarify, drule spec, drule (1) mp)
  1549 apply (simp only: norm_minus_commute)
  1550 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1551 apply simp
  1552 done
  1553 
  1554 subsection \<open>Power Sequences\<close>
  1555 
  1556 text\<open>The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1557 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1558   also fact that bounded and monotonic sequence converges.\<close>
  1559 
  1560 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1561 apply (simp add: Bseq_def)
  1562 apply (rule_tac x = 1 in exI)
  1563 apply (simp add: power_abs)
  1564 apply (auto dest: power_mono)
  1565 done
  1566 
  1567 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1568 apply (clarify intro!: mono_SucI2)
  1569 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1570 done
  1571 
  1572 lemma convergent_realpow:
  1573   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1574 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1575 
  1576 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1577   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1578 
  1579 lemma LIMSEQ_realpow_zero:
  1580   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1581 proof cases
  1582   assume "0 \<le> x" and "x \<noteq> 0"
  1583   hence x0: "0 < x" by simp
  1584   assume x1: "x < 1"
  1585   from x0 x1 have "1 < inverse x"
  1586     by (rule one_less_inverse)
  1587   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1588     by (rule LIMSEQ_inverse_realpow_zero)
  1589   thus ?thesis by (simp add: power_inverse)
  1590 qed (rule LIMSEQ_imp_Suc, simp)
  1591 
  1592 lemma LIMSEQ_power_zero:
  1593   fixes x :: "'a::{real_normed_algebra_1}"
  1594   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1595 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1596 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1597 apply (simp add: power_abs norm_power_ineq)
  1598 done
  1599 
  1600 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) ----> 0"
  1601   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1602 
  1603 text\<open>Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}\<close>
  1604 
  1605 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) ----> 0"
  1606   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1607 
  1608 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) ----> 0"
  1609   by (rule LIMSEQ_power_zero) simp
  1610 
  1611 
  1612 subsection \<open>Limits of Functions\<close>
  1613 
  1614 lemma LIM_eq:
  1615   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1616   shows "f -- a --> L =
  1617      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1618 by (simp add: LIM_def dist_norm)
  1619 
  1620 lemma LIM_I:
  1621   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1622   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1623       ==> f -- a --> L"
  1624 by (simp add: LIM_eq)
  1625 
  1626 lemma LIM_D:
  1627   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1628   shows "[| f -- a --> L; 0<r |]
  1629       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1630 by (simp add: LIM_eq)
  1631 
  1632 lemma LIM_offset:
  1633   fixes a :: "'a::real_normed_vector"
  1634   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
  1635   unfolding filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap by simp
  1636 
  1637 lemma LIM_offset_zero:
  1638   fixes a :: "'a::real_normed_vector"
  1639   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1640 by (drule_tac k="a" in LIM_offset, simp add: add.commute)
  1641 
  1642 lemma LIM_offset_zero_cancel:
  1643   fixes a :: "'a::real_normed_vector"
  1644   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
  1645 by (drule_tac k="- a" in LIM_offset, simp)
  1646 
  1647 lemma LIM_offset_zero_iff:
  1648   fixes f :: "'a :: real_normed_vector \<Rightarrow> _"
  1649   shows  "f -- a --> L \<longleftrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1650   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  1651 
  1652 lemma LIM_zero:
  1653   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1654   shows "(f ---> l) F \<Longrightarrow> ((\<lambda>x. f x - l) ---> 0) F"
  1655 unfolding tendsto_iff dist_norm by simp
  1656 
  1657 lemma LIM_zero_cancel:
  1658   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1659   shows "((\<lambda>x. f x - l) ---> 0) F \<Longrightarrow> (f ---> l) F"
  1660 unfolding tendsto_iff dist_norm by simp
  1661 
  1662 lemma LIM_zero_iff:
  1663   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  1664   shows "((\<lambda>x. f x - l) ---> 0) F = (f ---> l) F"
  1665 unfolding tendsto_iff dist_norm by simp
  1666 
  1667 lemma LIM_imp_LIM:
  1668   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1669   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  1670   assumes f: "f -- a --> l"
  1671   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  1672   shows "g -- a --> m"
  1673   by (rule metric_LIM_imp_LIM [OF f],
  1674     simp add: dist_norm le)
  1675 
  1676 lemma LIM_equal2:
  1677   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1678   assumes 1: "0 < R"
  1679   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  1680   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
  1681 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  1682 
  1683 lemma LIM_compose2:
  1684   fixes a :: "'a::real_normed_vector"
  1685   assumes f: "f -- a --> b"
  1686   assumes g: "g -- b --> c"
  1687   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  1688   shows "(\<lambda>x. g (f x)) -- a --> c"
  1689 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  1690 
  1691 lemma real_LIM_sandwich_zero:
  1692   fixes f g :: "'a::topological_space \<Rightarrow> real"
  1693   assumes f: "f -- a --> 0"
  1694   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  1695   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  1696   shows "g -- a --> 0"
  1697 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  1698   fix x assume x: "x \<noteq> a"
  1699   have "norm (g x - 0) = g x" by (simp add: 1 x)
  1700   also have "g x \<le> f x" by (rule 2 [OF x])
  1701   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  1702   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  1703   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  1704 qed
  1705 
  1706 
  1707 subsection \<open>Continuity\<close>
  1708 
  1709 lemma LIM_isCont_iff:
  1710   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1711   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
  1712 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  1713 
  1714 lemma isCont_iff:
  1715   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1716   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
  1717 by (simp add: isCont_def LIM_isCont_iff)
  1718 
  1719 lemma isCont_LIM_compose2:
  1720   fixes a :: "'a::real_normed_vector"
  1721   assumes f [unfolded isCont_def]: "isCont f a"
  1722   assumes g: "g -- f a --> l"
  1723   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  1724   shows "(\<lambda>x. g (f x)) -- a --> l"
  1725 by (rule LIM_compose2 [OF f g inj])
  1726 
  1727 
  1728 lemma isCont_norm [simp]:
  1729   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1730   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  1731   by (fact continuous_norm)
  1732 
  1733 lemma isCont_rabs [simp]:
  1734   fixes f :: "'a::t2_space \<Rightarrow> real"
  1735   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  1736   by (fact continuous_rabs)
  1737 
  1738 lemma isCont_add [simp]:
  1739   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1740   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  1741   by (fact continuous_add)
  1742 
  1743 lemma isCont_minus [simp]:
  1744   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1745   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  1746   by (fact continuous_minus)
  1747 
  1748 lemma isCont_diff [simp]:
  1749   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1750   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  1751   by (fact continuous_diff)
  1752 
  1753 lemma isCont_mult [simp]:
  1754   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  1755   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  1756   by (fact continuous_mult)
  1757 
  1758 lemma (in bounded_linear) isCont:
  1759   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  1760   by (fact continuous)
  1761 
  1762 lemma (in bounded_bilinear) isCont:
  1763   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  1764   by (fact continuous)
  1765 
  1766 lemmas isCont_scaleR [simp] =
  1767   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  1768 
  1769 lemmas isCont_of_real [simp] =
  1770   bounded_linear.isCont [OF bounded_linear_of_real]
  1771 
  1772 lemma isCont_power [simp]:
  1773   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  1774   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  1775   by (fact continuous_power)
  1776 
  1777 lemma isCont_setsum [simp]:
  1778   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
  1779   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  1780   by (auto intro: continuous_setsum)
  1781 
  1782 subsection \<open>Uniform Continuity\<close>
  1783 
  1784 definition
  1785   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
  1786   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  1787 
  1788 lemma isUCont_isCont: "isUCont f ==> isCont f x"
  1789 by (simp add: isUCont_def isCont_def LIM_def, force)
  1790 
  1791 lemma isUCont_Cauchy:
  1792   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1793 unfolding isUCont_def
  1794 apply (rule metric_CauchyI)
  1795 apply (drule_tac x=e in spec, safe)
  1796 apply (drule_tac e=s in metric_CauchyD, safe)
  1797 apply (rule_tac x=M in exI, simp)
  1798 done
  1799 
  1800 lemma (in bounded_linear) isUCont: "isUCont f"
  1801 unfolding isUCont_def dist_norm
  1802 proof (intro allI impI)
  1803   fix r::real assume r: "0 < r"
  1804   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  1805     using pos_bounded by fast
  1806   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  1807   proof (rule exI, safe)
  1808     from r K show "0 < r / K" by simp
  1809   next
  1810     fix x y :: 'a
  1811     assume xy: "norm (x - y) < r / K"
  1812     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  1813     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  1814     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  1815     finally show "norm (f x - f y) < r" .
  1816   qed
  1817 qed
  1818 
  1819 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1820 by (rule isUCont [THEN isUCont_Cauchy])
  1821 
  1822 lemma LIM_less_bound:
  1823   fixes f :: "real \<Rightarrow> real"
  1824   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  1825   shows "0 \<le> f x"
  1826 proof (rule tendsto_le_const)
  1827   show "(f ---> f x) (at_left x)"
  1828     using \<open>isCont f x\<close> by (simp add: filterlim_at_split isCont_def)
  1829   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  1830     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  1831 qed simp
  1832 
  1833 
  1834 subsection \<open>Nested Intervals and Bisection -- Needed for Compactness\<close>
  1835 
  1836 lemma nested_sequence_unique:
  1837   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) ----> 0"
  1838   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f ----> l) \<and> ((\<forall>n. l \<le> g n) \<and> g ----> l)"
  1839 proof -
  1840   have "incseq f" unfolding incseq_Suc_iff by fact
  1841   have "decseq g" unfolding decseq_Suc_iff by fact
  1842 
  1843   { fix n
  1844     from \<open>decseq g\<close> have "g n \<le> g 0" by (rule decseqD) simp
  1845     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] have "f n \<le> g 0" by auto }
  1846   then obtain u where "f ----> u" "\<forall>i. f i \<le> u"
  1847     using incseq_convergent[OF \<open>incseq f\<close>] by auto
  1848   moreover
  1849   { fix n
  1850     from \<open>incseq f\<close> have "f 0 \<le> f n" by (rule incseqD) simp
  1851     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] have "f 0 \<le> g n" by simp }
  1852   then obtain l where "g ----> l" "\<forall>i. l \<le> g i"
  1853     using decseq_convergent[OF \<open>decseq g\<close>] by auto
  1854   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF \<open>f ----> u\<close> \<open>g ----> l\<close>]]
  1855   ultimately show ?thesis by auto
  1856 qed
  1857 
  1858 lemma Bolzano[consumes 1, case_names trans local]:
  1859   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  1860   assumes [arith]: "a \<le> b"
  1861   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  1862   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  1863   shows "P a b"
  1864 proof -
  1865   def bisect \<equiv> "rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  1866   def l \<equiv> "\<lambda>n. fst (bisect n)" and u \<equiv> "\<lambda>n. snd (bisect n)"
  1867   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  1868     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  1869     by (simp_all add: l_def u_def bisect_def split: prod.split)
  1870 
  1871   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  1872 
  1873   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l ----> x) \<and> ((\<forall>n. x \<le> u n) \<and> u ----> x)"
  1874   proof (safe intro!: nested_sequence_unique)
  1875     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  1876   next
  1877     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  1878     then show "(\<lambda>n. l n - u n) ----> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  1879   qed fact
  1880   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l ----> x" "u ----> x" by auto
  1881   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  1882     using \<open>l 0 \<le> x\<close> \<open>x \<le> u 0\<close> local[of x] by auto
  1883 
  1884   show "P a b"
  1885   proof (rule ccontr)
  1886     assume "\<not> P a b"
  1887     { fix n have "\<not> P (l n) (u n)"
  1888       proof (induct n)
  1889         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  1890       qed (simp add: \<open>\<not> P a b\<close>) }
  1891     moreover
  1892     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  1893         using \<open>0 < d\<close> \<open>l ----> x\<close> by (intro order_tendstoD[of _ x]) auto
  1894       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  1895         using \<open>0 < d\<close> \<open>u ----> x\<close> by (intro order_tendstoD[of _ x]) auto
  1896       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  1897       proof eventually_elim
  1898         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  1899         from add_strict_mono[OF this] have "u n - l n < d" by simp
  1900         with x show "P (l n) (u n)" by (rule d)
  1901       qed }
  1902     ultimately show False by simp
  1903   qed
  1904 qed
  1905 
  1906 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  1907 proof (cases "a \<le> b", rule compactI)
  1908   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  1909   def T == "{a .. b}"
  1910   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  1911   proof (induct rule: Bolzano)
  1912     case (trans a b c)
  1913     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  1914     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  1915       by (auto simp: *)
  1916     with trans show ?case
  1917       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  1918   next
  1919     case (local x)
  1920     then have "x \<in> \<Union>C" using C by auto
  1921     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  1922     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  1923       by (auto simp: open_real_def dist_real_def subset_eq Ball_def abs_less_iff)
  1924     with \<open>c \<in> C\<close> show ?case
  1925       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  1926   qed
  1927 qed simp
  1928 
  1929 
  1930 lemma continuous_image_closed_interval:
  1931   fixes a b and f :: "real \<Rightarrow> real"
  1932   defines "S \<equiv> {a..b}"
  1933   assumes "a \<le> b" and f: "continuous_on S f"
  1934   shows "\<exists>c d. f`S = {c..d} \<and> c \<le> d"
  1935 proof -
  1936   have S: "compact S" "S \<noteq> {}"
  1937     using \<open>a \<le> b\<close> by (auto simp: S_def)
  1938   obtain c where "c \<in> S" "\<forall>d\<in>S. f d \<le> f c"
  1939     using continuous_attains_sup[OF S f] by auto
  1940   moreover obtain d where "d \<in> S" "\<forall>c\<in>S. f d \<le> f c"
  1941     using continuous_attains_inf[OF S f] by auto
  1942   moreover have "connected (f`S)"
  1943     using connected_continuous_image[OF f] connected_Icc by (auto simp: S_def)
  1944   ultimately have "f ` S = {f d .. f c} \<and> f d \<le> f c"
  1945     by (auto simp: connected_iff_interval)
  1946   then show ?thesis
  1947     by auto
  1948 qed
  1949 
  1950 lemma open_Collect_positive:
  1951  fixes f :: "'a::t2_space \<Rightarrow> real"
  1952  assumes f: "continuous_on s f"
  1953  shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. 0 < f x}"
  1954  using continuous_on_open_invariant[THEN iffD1, OF f, rule_format, of "{0 <..}"]
  1955  by (auto simp: Int_def field_simps)
  1956 
  1957 lemma open_Collect_less_Int:
  1958  fixes f g :: "'a::t2_space \<Rightarrow> real"
  1959  assumes f: "continuous_on s f" and g: "continuous_on s g"
  1960  shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. f x < g x}"
  1961  using open_Collect_positive[OF continuous_on_diff[OF g f]] by (simp add: field_simps)
  1962 
  1963 
  1964 subsection \<open>Boundedness of continuous functions\<close>
  1965 
  1966 text\<open>By bisection, function continuous on closed interval is bounded above\<close>
  1967 
  1968 lemma isCont_eq_Ub:
  1969   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1970   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1971     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1972   using continuous_attains_sup[of "{a .. b}" f]
  1973   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1974 
  1975 lemma isCont_eq_Lb:
  1976   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1977   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1978     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1979   using continuous_attains_inf[of "{a .. b}" f]
  1980   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1981 
  1982 lemma isCont_bounded:
  1983   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1984   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  1985   using isCont_eq_Ub[of a b f] by auto
  1986 
  1987 lemma isCont_has_Ub:
  1988   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1989   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1990     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  1991   using isCont_eq_Ub[of a b f] by auto
  1992 
  1993 (*HOL style here: object-level formulations*)
  1994 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  1995       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1996       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1997   by (blast intro: IVT)
  1998 
  1999 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  2000       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  2001       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  2002   by (blast intro: IVT2)
  2003 
  2004 lemma isCont_Lb_Ub:
  2005   fixes f :: "real \<Rightarrow> real"
  2006   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  2007   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and>
  2008                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  2009 proof -
  2010   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  2011     using isCont_eq_Ub[OF assms] by auto
  2012   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  2013     using isCont_eq_Lb[OF assms] by auto
  2014   show ?thesis
  2015     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  2016     apply (rule_tac x="f L" in exI)
  2017     apply (rule_tac x="f M" in exI)
  2018     apply (cases "L \<le> M")
  2019     apply (simp, metis order_trans)
  2020     apply (simp, metis order_trans)
  2021     done
  2022 qed
  2023 
  2024 
  2025 text\<open>Continuity of inverse function\<close>
  2026 
  2027 lemma isCont_inverse_function:
  2028   fixes f g :: "real \<Rightarrow> real"
  2029   assumes d: "0 < d"
  2030       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  2031       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  2032   shows "isCont g (f x)"
  2033 proof -
  2034   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  2035 
  2036   have f: "continuous_on ?D f"
  2037     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  2038   then have g: "continuous_on (f`?D) g"
  2039     using inj by (intro continuous_on_inv) auto
  2040 
  2041   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  2042     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  2043   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  2044     by (rule continuous_on_subset)
  2045   moreover
  2046   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  2047     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  2048   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  2049     by auto
  2050   ultimately
  2051   show ?thesis
  2052     by (simp add: continuous_on_eq_continuous_at)
  2053 qed
  2054 
  2055 lemma isCont_inverse_function2:
  2056   fixes f g :: "real \<Rightarrow> real" shows
  2057   "\<lbrakk>a < x; x < b;
  2058     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2059     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2060    \<Longrightarrow> isCont g (f x)"
  2061 apply (rule isCont_inverse_function
  2062        [where f=f and d="min (x - a) (b - x)"])
  2063 apply (simp_all add: abs_le_iff)
  2064 done
  2065 
  2066 (* need to rename second isCont_inverse *)
  2067 
  2068 lemma isCont_inv_fun:
  2069   fixes f g :: "real \<Rightarrow> real"
  2070   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;
  2071          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]
  2072       ==> isCont g (f x)"
  2073 by (rule isCont_inverse_function)
  2074 
  2075 text\<open>Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110\<close>
  2076 lemma LIM_fun_gt_zero:
  2077   fixes f :: "real \<Rightarrow> real"
  2078   shows "f -- c --> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  2079 apply (drule (1) LIM_D, clarify)
  2080 apply (rule_tac x = s in exI)
  2081 apply (simp add: abs_less_iff)
  2082 done
  2083 
  2084 lemma LIM_fun_less_zero:
  2085   fixes f :: "real \<Rightarrow> real"
  2086   shows "f -- c --> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  2087 apply (drule LIM_D [where r="-l"], simp, clarify)
  2088 apply (rule_tac x = s in exI)
  2089 apply (simp add: abs_less_iff)
  2090 done
  2091 
  2092 lemma LIM_fun_not_zero:
  2093   fixes f :: "real \<Rightarrow> real"
  2094   shows "f -- c --> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  2095   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  2096 
  2097 end
  2098