src/HOL/Tools/SMT/smt_translate.ML
author blanchet
Tue Aug 29 18:30:23 2017 +0200 (21 months ago)
changeset 66551 4df6b0ae900d
parent 66136 dd006934a719
child 66738 793e7a9c30c5
permissions -rw-r--r--
towards support for HO SMT-LIB
     1 (*  Title:      HOL/Tools/SMT/smt_translate.ML
     2     Author:     Sascha Boehme, TU Muenchen
     3 
     4 Translate theorems into an SMT intermediate format and serialize them.
     5 *)
     6 
     7 signature SMT_TRANSLATE =
     8 sig
     9   (*intermediate term structure*)
    10   datatype squant = SForall | SExists
    11   datatype 'a spattern = SPat of 'a list | SNoPat of 'a list
    12   datatype sterm =
    13     SVar of int * sterm list |
    14     SConst of string * sterm list |
    15     SQua of squant * string list * sterm spattern list * sterm
    16 
    17   (*translation configuration*)
    18   type sign = {
    19     logic: string,
    20     sorts: string list,
    21     dtyps: (BNF_Util.fp_kind * (string * (string * (string * string) list) list)) list,
    22     funcs: (string * (string list * string)) list }
    23   type config = {
    24     order: SMT_Util.order,
    25     logic: term list -> string,
    26     fp_kinds: BNF_Util.fp_kind list,
    27     serialize: (string * string) list -> string list -> sign -> sterm list -> string }
    28   type replay_data = {
    29     context: Proof.context,
    30     typs: typ Symtab.table,
    31     terms: term Symtab.table,
    32     ll_defs: term list,
    33     rewrite_rules: thm list,
    34     assms: (int * thm) list }
    35 
    36   (*translation*)
    37   val add_config: SMT_Util.class * (Proof.context -> config) -> Context.generic -> Context.generic
    38   val translate: Proof.context -> (string * string) list -> string list -> (int * thm) list ->
    39     string * replay_data
    40 end;
    41 
    42 structure SMT_Translate: SMT_TRANSLATE =
    43 struct
    44 
    45 
    46 (* intermediate term structure *)
    47 
    48 datatype squant = SForall | SExists
    49 
    50 datatype 'a spattern =
    51   SPat of 'a list | SNoPat of 'a list
    52 
    53 datatype sterm =
    54   SVar of int * sterm list |
    55   SConst of string * sterm list |
    56   SQua of squant * string list * sterm spattern list * sterm
    57 
    58 
    59 (* translation configuration *)
    60 
    61 type sign = {
    62   logic: string,
    63   sorts: string list,
    64   dtyps: (BNF_Util.fp_kind * (string * (string * (string * string) list) list)) list,
    65   funcs: (string * (string list * string)) list }
    66 
    67 type config = {
    68   order: SMT_Util.order,
    69   logic: term list -> string,
    70   fp_kinds: BNF_Util.fp_kind list,
    71   serialize: (string * string) list -> string list -> sign -> sterm list -> string }
    72 
    73 type replay_data = {
    74   context: Proof.context,
    75   typs: typ Symtab.table,
    76   terms: term Symtab.table,
    77   ll_defs: term list,
    78   rewrite_rules: thm list,
    79   assms: (int * thm) list }
    80 
    81 
    82 (* translation context *)
    83 
    84 fun add_components_of_typ (Type (s, Ts)) =
    85     cons (Long_Name.base_name s) #> fold_rev add_components_of_typ Ts
    86   | add_components_of_typ (TFree (s, _)) = cons (perhaps (try (unprefix "'")) s)
    87   | add_components_of_typ _ = I;
    88 
    89 fun suggested_name_of_typ T = space_implode "_" (add_components_of_typ T []);
    90 
    91 fun suggested_name_of_term (Const (s, _)) = Long_Name.base_name s
    92   | suggested_name_of_term (Free (s, _)) = s
    93   | suggested_name_of_term _ = Name.uu
    94 
    95 val empty_tr_context = (Name.context, Typtab.empty, Termtab.empty)
    96 val safe_suffix = "$"
    97 
    98 fun add_typ T proper (cx as (names, typs, terms)) =
    99   (case Typtab.lookup typs T of
   100     SOME (name, _) => (name, cx)
   101   | NONE =>
   102       let
   103         val sugg = Name.desymbolize (SOME true) (suggested_name_of_typ T) ^ safe_suffix
   104         val (name, names') = Name.variant sugg names
   105         val typs' = Typtab.update (T, (name, proper)) typs
   106       in (name, (names', typs', terms)) end)
   107 
   108 fun add_fun t sort (cx as (names, typs, terms)) =
   109   (case Termtab.lookup terms t of
   110     SOME (name, _) => (name, cx)
   111   | NONE =>
   112       let
   113         val sugg = Name.desymbolize (SOME false) (suggested_name_of_term t) ^ safe_suffix
   114         val (name, names') = Name.variant sugg names
   115         val terms' = Termtab.update (t, (name, sort)) terms
   116       in (name, (names', typs, terms')) end)
   117 
   118 fun sign_of logic dtyps (_, typs, terms) = {
   119   logic = logic,
   120   sorts = Typtab.fold (fn (_, (n, true)) => cons n | _ => I) typs [],
   121   dtyps = dtyps,
   122   funcs = Termtab.fold (fn (_, (n, SOME ss)) => cons (n,ss) | _ => I) terms []}
   123 
   124 fun replay_data_of ctxt ll_defs rules assms (_, typs, terms) =
   125   let
   126     fun add_typ (T, (n, _)) = Symtab.update (n, T)
   127     val typs' = Typtab.fold add_typ typs Symtab.empty
   128 
   129     fun add_fun (t, (n, _)) = Symtab.update (n, t)
   130     val terms' = Termtab.fold add_fun terms Symtab.empty
   131   in
   132     {context = ctxt, typs = typs', terms = terms', ll_defs = ll_defs, rewrite_rules = rules,
   133      assms = assms}
   134   end
   135 
   136 
   137 (* preprocessing *)
   138 
   139 (** (co)datatype declarations **)
   140 
   141 fun collect_co_datatypes fp_kinds (tr_context, ctxt) ts =
   142   let
   143     val (fp_decls, ctxt') =
   144       ([], ctxt)
   145       |> fold (Term.fold_types (SMT_Datatypes.add_decls fp_kinds)) ts
   146       |>> flat
   147 
   148     fun is_decl_typ T = exists (equal T o fst o snd) fp_decls
   149 
   150     fun add_typ' T proper =
   151       (case SMT_Builtin.dest_builtin_typ ctxt' T of
   152         SOME (n, Ts) => pair n (* FIXME HO: Consider Ts *)
   153       | NONE => add_typ T proper)
   154 
   155     fun tr_select sel =
   156       let val T = Term.range_type (Term.fastype_of sel)
   157       in add_fun sel NONE ##>> add_typ' T (not (is_decl_typ T)) end
   158     fun tr_constr (constr, selects) =
   159       add_fun constr NONE ##>> fold_map tr_select selects
   160     fun tr_typ (fp, (T, cases)) =
   161       add_typ' T false ##>> fold_map tr_constr cases #>> pair fp
   162 
   163     val (fp_decls', tr_context') = fold_map tr_typ fp_decls tr_context
   164 
   165     fun add (constr, selects) =
   166       Termtab.update (constr, length selects) #>
   167       fold (Termtab.update o rpair 1) selects
   168 
   169     val funcs = fold (fold add o snd o snd) fp_decls Termtab.empty
   170 
   171   in ((funcs, fp_decls', tr_context', ctxt'), ts) end
   172     (* FIXME: also return necessary (co)datatype theorems *)
   173 
   174 
   175 (** eta-expand quantifiers, let expressions and built-ins *)
   176 
   177 local
   178   fun eta f T t = Abs (Name.uu, T, f (Term.incr_boundvars 1 t $ Bound 0))
   179 
   180   fun exp f T = eta f (Term.domain_type (Term.domain_type T))
   181 
   182   fun exp2 T q =
   183     let val U = Term.domain_type T
   184     in Abs (Name.uu, U, q $ eta I (Term.domain_type U) (Bound 0)) end
   185 
   186   fun expf k i T t =
   187     let val Ts = drop i (fst (SMT_Util.dest_funT k T))
   188     in
   189       Term.incr_boundvars (length Ts) t
   190       |> fold_rev (fn i => fn u => u $ Bound i) (0 upto length Ts - 1)
   191       |> fold_rev (fn T => fn u => Abs (Name.uu, T, u)) Ts
   192     end
   193 in
   194 
   195 fun eta_expand ctxt funcs =
   196   let
   197     fun exp_func t T ts =
   198       (case Termtab.lookup funcs t of
   199         SOME k => Term.list_comb (t, ts) |> k <> length ts ? expf k (length ts) T
   200       | NONE => Term.list_comb (t, ts))
   201 
   202     fun expand ((q as Const (@{const_name All}, _)) $ Abs a) = q $ abs_expand a
   203       | expand ((q as Const (@{const_name All}, T)) $ t) = q $ exp expand T t
   204       | expand (q as Const (@{const_name All}, T)) = exp2 T q
   205       | expand ((q as Const (@{const_name Ex}, _)) $ Abs a) = q $ abs_expand a
   206       | expand ((q as Const (@{const_name Ex}, T)) $ t) = q $ exp expand T t
   207       | expand (q as Const (@{const_name Ex}, T)) = exp2 T q
   208       | expand (Const (@{const_name Let}, T) $ t) =
   209           let val U = Term.domain_type (Term.range_type T)
   210           in Abs (Name.uu, U, Bound 0 $ Term.incr_boundvars 1 t) end
   211       | expand (Const (@{const_name Let}, T)) =
   212           let val U = Term.domain_type (Term.range_type T)
   213           in Abs (Name.uu, Term.domain_type T, Abs (Name.uu, U, Bound 0 $ Bound 1)) end
   214       | expand t =
   215           (case Term.strip_comb t of
   216             (Const (@{const_name Let}, _), t1 :: t2 :: ts) =>
   217             Term.betapplys (Term.betapply (expand t2, expand t1), map expand ts)
   218           | (u as Const (c as (_, T)), ts) =>
   219               (case SMT_Builtin.dest_builtin ctxt c ts of
   220                 SOME (_, k, us, mk) =>
   221                   if k = length us then mk (map expand us)
   222                   else if k < length us then chop k (map expand us) |>> mk |> Term.list_comb
   223                   else expf k (length ts) T (mk (map expand us))
   224               | NONE => exp_func u T (map expand ts))
   225           | (u as Free (_, T), ts) => exp_func u T (map expand ts)
   226           | (Abs a, ts) => Term.list_comb (abs_expand a, map expand ts)
   227           | (u, ts) => Term.list_comb (u, map expand ts))
   228 
   229     and abs_expand (n, T, t) = Abs (n, T, expand t)
   230 
   231   in map expand end
   232 
   233 end
   234 
   235 
   236 (** introduce explicit applications **)
   237 
   238 local
   239   (*
   240     Make application explicit for functions with varying number of arguments.
   241   *)
   242 
   243   fun add t i = apfst (Termtab.map_default (t, i) (Integer.min i))
   244   fun add_type T = apsnd (Typtab.update (T, ()))
   245 
   246   fun min_arities t =
   247     (case Term.strip_comb t of
   248       (u as Const _, ts) => add u (length ts) #> fold min_arities ts
   249     | (u as Free _, ts) => add u (length ts) #> fold min_arities ts
   250     | (Abs (_, T, u), ts) => (can dest_funT T ? add_type T) #> min_arities u #> fold min_arities ts
   251     | (_, ts) => fold min_arities ts)
   252 
   253   fun minimize types t i =
   254     let
   255       fun find_min j [] _ = j
   256         | find_min j (U :: Us) T =
   257             if Typtab.defined types T then j else find_min (j + 1) Us (U --> T)
   258 
   259       val (Ts, T) = Term.strip_type (Term.type_of t)
   260     in find_min 0 (take i (rev Ts)) T end
   261 
   262   fun app u (t, T) = (Const (@{const_name fun_app}, T --> T) $ t $ u, Term.range_type T)
   263 
   264   fun apply i t T ts =
   265     let
   266       val (ts1, ts2) = chop i ts
   267       val (_, U) = SMT_Util.dest_funT i T
   268     in fst (fold app ts2 (Term.list_comb (t, ts1), U)) end
   269 in
   270 
   271 fun intro_explicit_application ctxt funcs ts =
   272   let
   273     val (arities, types) = fold min_arities ts (Termtab.empty, Typtab.empty)
   274     val arities' = Termtab.map (minimize types) arities (* FIXME: highly suspicious *)
   275 
   276     fun app_func t T ts =
   277       if is_some (Termtab.lookup funcs t) then Term.list_comb (t, ts)
   278       else apply (the (Termtab.lookup arities' t)) t T ts
   279 
   280     fun in_list T f t = SMT_Util.mk_symb_list T (map f (SMT_Util.dest_symb_list t))
   281 
   282     fun traverse Ts t =
   283       (case Term.strip_comb t of
   284         (q as Const (@{const_name All}, _), [Abs (x, T, u)]) =>
   285           q $ Abs (x, T, in_trigger (T :: Ts) u)
   286       | (q as Const (@{const_name Ex}, _), [Abs (x, T, u)]) =>
   287           q $ Abs (x, T, in_trigger (T :: Ts) u)
   288       | (q as Const (@{const_name Let}, _), [u1, u2 as Abs _]) =>
   289           q $ traverse Ts u1 $ traverse Ts u2
   290       | (u as Const (c as (_, T)), ts) =>
   291           (case SMT_Builtin.dest_builtin ctxt c ts of
   292             SOME (_, k, us, mk) =>
   293               let
   294                 val (ts1, ts2) = chop k (map (traverse Ts) us)
   295                 val U = Term.strip_type T |>> snd o chop k |> (op --->)
   296               in apply 0 (mk ts1) U ts2 end
   297           | NONE => app_func u T (map (traverse Ts) ts))
   298       | (u as Free (_, T), ts) => app_func u T (map (traverse Ts) ts)
   299       | (u as Bound i, ts) => apply 0 u (nth Ts i) (map (traverse Ts) ts)
   300       | (Abs (n, T, u), ts) => traverses Ts (Abs (n, T, traverse (T::Ts) u)) ts
   301       | (u, ts) => traverses Ts u ts)
   302     and in_trigger Ts ((c as @{const trigger}) $ p $ t) = c $ in_pats Ts p $ traverse Ts t
   303       | in_trigger Ts t = traverse Ts t
   304     and in_pats Ts ps =
   305       in_list @{typ "pattern symb_list"} (in_list @{typ pattern} (in_pat Ts)) ps
   306     and in_pat Ts ((p as Const (@{const_name pat}, _)) $ t) = p $ traverse Ts t
   307       | in_pat Ts ((p as Const (@{const_name nopat}, _)) $ t) = p $ traverse Ts t
   308       | in_pat _ t = raise TERM ("bad pattern", [t])
   309     and traverses Ts t ts = Term.list_comb (t, map (traverse Ts) ts)
   310   in map (traverse []) ts end
   311 
   312 val fun_app_eq = mk_meta_eq @{thm fun_app_def}
   313 
   314 end
   315 
   316 
   317 (** map HOL formulas to FOL formulas (i.e., separate formulas froms terms) **)
   318 
   319 local
   320   val is_quant = member (op =) [@{const_name All}, @{const_name Ex}]
   321 
   322   val fol_rules = [
   323     Let_def,
   324     @{lemma "P = True == P" by (rule eq_reflection) simp}]
   325 
   326   exception BAD_PATTERN of unit
   327 
   328   fun is_builtin_conn_or_pred ctxt c ts =
   329     is_some (SMT_Builtin.dest_builtin_conn ctxt c ts) orelse
   330     is_some (SMT_Builtin.dest_builtin_pred ctxt c ts)
   331 in
   332 
   333 fun folify ctxt =
   334   let
   335     fun in_list T f t = SMT_Util.mk_symb_list T (map_filter f (SMT_Util.dest_symb_list t))
   336 
   337     fun in_term pat t =
   338       (case Term.strip_comb t of
   339         (@{const True}, []) => t
   340       | (@{const False}, []) => t
   341       | (u as Const (@{const_name If}, _), [t1, t2, t3]) =>
   342           if pat then raise BAD_PATTERN () else u $ in_form t1 $ in_term pat t2 $ in_term pat t3
   343       | (Const (c as (n, _)), ts) =>
   344           if is_builtin_conn_or_pred ctxt c ts orelse is_quant n then
   345             if pat then raise BAD_PATTERN () else in_form t
   346           else
   347             Term.list_comb (Const c, map (in_term pat) ts)
   348       | (Free c, ts) => Term.list_comb (Free c, map (in_term pat) ts)
   349       | _ => t)
   350 
   351     and in_pat ((p as Const (@{const_name pat}, _)) $ t) =
   352           p $ in_term true t
   353       | in_pat ((p as Const (@{const_name nopat}, _)) $ t) =
   354           p $ in_term true t
   355       | in_pat t = raise TERM ("bad pattern", [t])
   356 
   357     and in_pats ps =
   358       in_list @{typ "pattern symb_list"} (SOME o in_list @{typ pattern} (try in_pat)) ps
   359 
   360     and in_trigger ((c as @{const trigger}) $ p $ t) = c $ in_pats p $ in_form t
   361       | in_trigger t = in_form t
   362 
   363     and in_form t =
   364       (case Term.strip_comb t of
   365         (q as Const (qn, _), [Abs (n, T, u)]) =>
   366           if is_quant qn then q $ Abs (n, T, in_trigger u)
   367           else in_term false t
   368       | (Const c, ts) =>
   369           (case SMT_Builtin.dest_builtin_conn ctxt c ts of
   370             SOME (_, _, us, mk) => mk (map in_form us)
   371           | NONE =>
   372               (case SMT_Builtin.dest_builtin_pred ctxt c ts of
   373                 SOME (_, _, us, mk) => mk (map (in_term false) us)
   374               | NONE => in_term false t))
   375       | _ => in_term false t)
   376   in
   377     map in_form #>
   378     pair (fol_rules, I)
   379   end
   380 
   381 end
   382 
   383 
   384 (* translation into intermediate format *)
   385 
   386 (** utility functions **)
   387 
   388 val quantifier = (fn
   389     @{const_name All} => SOME SForall
   390   | @{const_name Ex} => SOME SExists
   391   | _ => NONE)
   392 
   393 fun group_quant qname Ts (t as Const (q, _) $ Abs (_, T, u)) =
   394       if q = qname then group_quant qname (T :: Ts) u else (Ts, t)
   395   | group_quant _ Ts t = (Ts, t)
   396 
   397 fun dest_pat (Const (@{const_name pat}, _) $ t) = (t, true)
   398   | dest_pat (Const (@{const_name nopat}, _) $ t) = (t, false)
   399   | dest_pat t = raise TERM ("bad pattern", [t])
   400 
   401 fun dest_pats [] = I
   402   | dest_pats ts =
   403       (case map dest_pat ts |> split_list ||> distinct (op =) of
   404         (ps, [true]) => cons (SPat ps)
   405       | (ps, [false]) => cons (SNoPat ps)
   406       | _ => raise TERM ("bad multi-pattern", ts))
   407 
   408 fun dest_trigger (@{const trigger} $ tl $ t) =
   409       (rev (fold (dest_pats o SMT_Util.dest_symb_list) (SMT_Util.dest_symb_list tl) []), t)
   410   | dest_trigger t = ([], t)
   411 
   412 fun dest_quant qn T t = quantifier qn |> Option.map (fn q =>
   413   let
   414     val (Ts, u) = group_quant qn [T] t
   415     val (ps, p) = dest_trigger u
   416   in (q, rev Ts, ps, p) end)
   417 
   418 fun fold_map_pat f (SPat ts) = fold_map f ts #>> SPat
   419   | fold_map_pat f (SNoPat ts) = fold_map f ts #>> SNoPat
   420 
   421 
   422 (** translation from Isabelle terms into SMT intermediate terms **)
   423 
   424 fun intermediate logic dtyps builtin ctxt ts trx =
   425   let
   426     fun transT (T as TFree _) = add_typ T true
   427       | transT (T as TVar _) = (fn _ => raise TYPE ("bad SMT type", [T], []))
   428       | transT (T as Type _) =
   429           (case SMT_Builtin.dest_builtin_typ ctxt T of
   430             SOME (n, []) => pair n
   431           | SOME (n, Ts) =>
   432             fold_map transT Ts
   433             #>> (fn ns => enclose "(" ")" (space_implode " " (n :: ns)))
   434           | NONE => add_typ T true)
   435 
   436     fun trans t =
   437       (case Term.strip_comb t of
   438         (Const (qn, _), [Abs (_, T, t1)]) =>
   439           (case dest_quant qn T t1 of
   440             SOME (q, Ts, ps, b) =>
   441               fold_map transT Ts ##>> fold_map (fold_map_pat trans) ps ##>>
   442               trans b #>> (fn ((Ts', ps'), b') => SQua (q, Ts', ps', b'))
   443           | NONE => raise TERM ("unsupported quantifier", [t]))
   444       | (u as Const (c as (_, T)), ts) =>
   445           (case builtin ctxt c ts of
   446             SOME (n, _, us, _) => fold_map trans us #>> curry SConst n
   447           | NONE => trans_applied_fun u T ts)
   448       | (u as Free (_, T), ts) => trans_applied_fun u T ts
   449       | (Bound i, ts) => pair i ##>> fold_map trans ts #>> SVar
   450       | _ => raise TERM ("bad SMT term", [t]))
   451 
   452     and trans_applied_fun t T ts =
   453       let val (Us, U) = SMT_Util.dest_funT (length ts) T
   454       in
   455         fold_map transT Us ##>> transT U #-> (fn Up =>
   456           add_fun t (SOME Up) ##>> fold_map trans ts #>> SConst)
   457       end
   458 
   459     val (us, trx') = fold_map trans ts trx
   460   in ((sign_of (logic ts) dtyps trx', us), trx') end
   461 
   462 
   463 (* translation *)
   464 
   465 structure Configs = Generic_Data
   466 (
   467   type T = (Proof.context -> config) SMT_Util.dict
   468   val empty = []
   469   val extend = I
   470   fun merge data = SMT_Util.dict_merge fst data
   471 )
   472 
   473 fun add_config (cs, cfg) = Configs.map (SMT_Util.dict_update (cs, cfg))
   474 
   475 fun get_config ctxt =
   476   let val cs = SMT_Config.solver_class_of ctxt
   477   in
   478     (case SMT_Util.dict_get (Configs.get (Context.Proof ctxt)) cs of
   479       SOME cfg => cfg ctxt
   480     | NONE => error ("SMT: no translation configuration found " ^
   481         "for solver class " ^ quote (SMT_Util.string_of_class cs)))
   482   end
   483 
   484 fun translate ctxt smt_options comments ithms =
   485   let
   486     val {order, logic, fp_kinds, serialize} = get_config ctxt
   487 
   488     fun no_dtyps (tr_context, ctxt) ts =
   489       ((Termtab.empty, [], tr_context, ctxt), ts)
   490 
   491     val ts1 = map (Envir.beta_eta_contract o SMT_Util.prop_of o snd) ithms
   492 
   493     val ((funcs, dtyps, tr_context, ctxt1), ts2) =
   494       ((empty_tr_context, ctxt), ts1)
   495       |-> (if null fp_kinds then no_dtyps else collect_co_datatypes fp_kinds)
   496 
   497     fun is_binder (Const (@{const_name Let}, _) $ _) = true
   498       | is_binder t = Lambda_Lifting.is_quantifier t
   499 
   500     fun mk_trigger ((q as Const (@{const_name All}, _)) $ Abs (n, T, t)) =
   501           q $ Abs (n, T, mk_trigger t)
   502       | mk_trigger (eq as (Const (@{const_name HOL.eq}, T) $ lhs $ _)) =
   503           Term.domain_type T --> @{typ pattern}
   504           |> (fn T => Const (@{const_name pat}, T) $ lhs)
   505           |> SMT_Util.mk_symb_list @{typ pattern} o single
   506           |> SMT_Util.mk_symb_list @{typ "pattern symb_list"} o single
   507           |> (fn t => @{const trigger} $ t $ eq)
   508       | mk_trigger t = t
   509 
   510     val (ctxt2, (ts3, ll_defs)) =
   511       ts2
   512       |> eta_expand ctxt1 funcs
   513       |> rpair ctxt1
   514       |-> Lambda_Lifting.lift_lambdas NONE is_binder
   515       |-> (fn (ts', ll_defs) => fn ctxt' =>
   516         let
   517           val ts'' = map mk_trigger ll_defs @ ts'
   518             |> order = SMT_Util.First_Order ? intro_explicit_application ctxt' funcs
   519         in
   520           (ctxt', (ts'', ll_defs))
   521         end)
   522     val ((rewrite_rules, builtin), ts4) = folify ctxt2 ts3
   523       |>> order = SMT_Util.First_Order ? apfst (cons fun_app_eq)
   524   in
   525     (ts4, tr_context)
   526     |-> intermediate logic dtyps (builtin SMT_Builtin.dest_builtin) ctxt2
   527     |>> uncurry (serialize smt_options comments)
   528     ||> replay_data_of ctxt2 ll_defs rewrite_rules ithms
   529   end
   530 
   531 end;