src/Pure/General/symbol_pos.ML
author wenzelm
Mon Feb 24 10:48:34 2014 +0100 (2014-02-24)
changeset 55709 4e5a83a46ded
parent 55107 1a29ea173bf9
child 55828 42ac3cfb89f6
permissions -rw-r--r--
clarified Token.range_of in accordance to Symbol_Pos.range;
eliminated redundant Position.set_range, which is already included in Position.range;
     1 (*  Title:      Pure/General/symbol_pos.ML
     2     Author:     Makarius
     3 
     4 Symbols with explicit position information.
     5 *)
     6 
     7 signature SYMBOL_POS =
     8 sig
     9   type T = Symbol.symbol * Position.T
    10   val symbol: T -> Symbol.symbol
    11   val $$ : Symbol.symbol -> T list -> T * T list
    12   val ~$$ : Symbol.symbol -> T list -> T * T list
    13   val $$$ : Symbol.symbol -> T list -> T list * T list
    14   val ~$$$ : Symbol.symbol -> T list -> T list * T list
    15   val content: T list -> string
    16   val range: T list -> Position.range
    17   val is_eof: T -> bool
    18   val stopper: T Scan.stopper
    19   val !!! : Scan.message -> (T list -> 'a) -> T list -> 'a
    20   val change_prompt: ('a -> 'b) -> 'a -> 'b
    21   val scan_pos: T list -> Position.T * T list
    22   val scan_string_q: string -> T list -> (Position.T * (T list * Position.T)) * T list
    23   val scan_string_qq: string -> T list -> (Position.T * (T list * Position.T)) * T list
    24   val scan_string_bq: string -> T list -> (Position.T * (T list * Position.T)) * T list
    25   val recover_string_q: T list -> T list * T list
    26   val recover_string_qq: T list -> T list * T list
    27   val recover_string_bq: T list -> T list * T list
    28   val quote_string_q: string -> string
    29   val quote_string_qq: string -> string
    30   val quote_string_bq: string -> string
    31   val scan_cartouche: string -> T list -> T list * T list
    32   val recover_cartouche: T list -> T list * T list
    33   val cartouche_content: T list -> T list
    34   val scan_comment: string -> T list -> T list * T list
    35   val scan_comment_body: string -> T list -> T list * T list
    36   val recover_comment: T list -> T list * T list
    37   val source: Position.T -> (Symbol.symbol, 'a) Source.source ->
    38     (T, Position.T * (Symbol.symbol, 'a) Source.source) Source.source
    39   type text = string
    40   val implode: T list -> text
    41   val implode_range: Position.T -> Position.T -> T list -> text * Position.range
    42   val explode: text * Position.T -> T list
    43   val scan_ident: T list -> T list * T list
    44   val is_identifier: string -> bool
    45 end;
    46 
    47 structure Symbol_Pos: SYMBOL_POS =
    48 struct
    49 
    50 (* type T *)
    51 
    52 type T = Symbol.symbol * Position.T;
    53 
    54 fun symbol ((s, _): T) = s;
    55 
    56 val content = implode o map symbol;
    57 
    58 fun range (syms as (_, pos) :: _) =
    59       let val pos' = List.last syms |-> Position.advance
    60       in Position.range pos pos' end
    61   | range [] = Position.no_range;
    62 
    63 
    64 (* stopper *)
    65 
    66 fun mk_eof pos = (Symbol.eof, pos);
    67 val eof = mk_eof Position.none;
    68 
    69 val is_eof = Symbol.is_eof o symbol;
    70 
    71 val stopper =
    72   Scan.stopper (fn [] => eof | inp => mk_eof (List.last inp |-> Position.advance)) is_eof;
    73 
    74 
    75 (* basic scanners *)
    76 
    77 fun !!! text scan =
    78   let
    79     fun get_pos [] = " (end-of-input)"
    80       | get_pos ((_, pos) :: _) = Position.here pos;
    81 
    82     fun err (syms, msg) = fn () =>
    83       text () ^ get_pos syms ^
    84       Markup.markup Markup.no_report (" at " ^ Symbol.beginning 10 (map symbol syms)) ^
    85       (case msg of NONE => "" | SOME m => "\n" ^ m ());
    86   in Scan.!! err scan end;
    87 
    88 fun change_prompt scan = Scan.prompt "# " scan;
    89 
    90 fun $$ s = Scan.one (fn x => symbol x = s);
    91 fun ~$$ s = Scan.one (fn x => symbol x <> s);
    92 
    93 fun $$$ s = Scan.one (fn x => symbol x = s) >> single;
    94 fun ~$$$ s = Scan.one (fn x => symbol x <> s) >> single;
    95 
    96 val scan_pos = Scan.ahead (Scan.one (K true)) >> (fn (_, pos): T => pos);
    97 
    98 
    99 (* scan string literals *)
   100 
   101 local
   102 
   103 val char_code =
   104   Scan.one (Symbol.is_ascii_digit o symbol) --
   105   Scan.one (Symbol.is_ascii_digit o symbol) --
   106   Scan.one (Symbol.is_ascii_digit o symbol) :|--
   107   (fn (((a, pos), (b, _)), (c, _)) =>
   108     let val (n, _) = Library.read_int [a, b, c]
   109     in if n <= 255 then Scan.succeed [(chr n, pos)] else Scan.fail end);
   110 
   111 fun scan_str q err_prefix =
   112   $$$ "\\" |-- !!! (fn () => err_prefix ^ "bad escape character in string")
   113     ($$$ q || $$$ "\\" || char_code) ||
   114   Scan.one (fn (s, _) => s <> q andalso s <> "\\" andalso Symbol.is_regular s) >> single;
   115 
   116 fun scan_strs q err_prefix =
   117   Scan.ahead ($$ q) |--
   118     !!! (fn () => err_prefix ^ "unclosed string literal")
   119       ((scan_pos --| $$$ q) --
   120         (change_prompt ((Scan.repeat (scan_str q err_prefix) >> flat) -- ($$$ q |-- scan_pos))));
   121 
   122 fun recover_strs q =
   123   $$$ q @@@ (Scan.repeat (Scan.permissive (scan_str q "")) >> flat);
   124 
   125 in
   126 
   127 val scan_string_q = scan_strs "'";
   128 val scan_string_qq = scan_strs "\"";
   129 val scan_string_bq = scan_strs "`";
   130 
   131 val recover_string_q = recover_strs "'";
   132 val recover_string_qq = recover_strs "\"";
   133 val recover_string_bq = recover_strs "`";
   134 
   135 end;
   136 
   137 
   138 (* quote string literals *)
   139 
   140 local
   141 
   142 fun char_code i =
   143   (if i < 10 then "00" else if i < 100 then "0" else "") ^ string_of_int i;
   144 
   145 fun quote_str q s =
   146   if Symbol.is_ascii_control s then "\\" ^ char_code (ord s)
   147   else if s = q orelse s = "\\" then "\\" ^ s
   148   else s;
   149 
   150 fun quote_string q = enclose q q o implode o map (quote_str q) o Symbol.explode;
   151 
   152 in
   153 
   154 val quote_string_q = quote_string "'";
   155 val quote_string_qq = quote_string "\"";
   156 val quote_string_bq = quote_string "`";
   157 
   158 end;
   159 
   160 
   161 (* nested text cartouches *)
   162 
   163 val scan_cartouche_depth =
   164   Scan.repeat1 (Scan.depend (fn (d: int) =>
   165     $$ "\\<open>" >> pair (d + 1) ||
   166       (if d > 0 then
   167         Scan.one (fn (s, _) => s <> "\\<close>" andalso Symbol.is_regular s) >> pair d ||
   168         $$ "\\<close>" >> pair (d - 1)
   169       else Scan.fail)));
   170 
   171 fun scan_cartouche err_prefix =
   172   Scan.ahead ($$ "\\<open>") |--
   173     !!! (fn () => err_prefix ^ "unclosed text cartouche")
   174       (change_prompt (Scan.provide (fn d => d = 0) 0 scan_cartouche_depth));
   175 
   176 val recover_cartouche = Scan.pass 0 scan_cartouche_depth;
   177 
   178 fun cartouche_content syms =
   179   let
   180     fun err () =
   181       error ("Malformed text cartouche: "
   182         ^ quote (content syms) ^ Position.here (#1 (range syms)));
   183   in
   184     (case syms of
   185       ("\\<open>", _) :: rest =>
   186         (case rev rest of
   187           ("\\<close>", _) :: rrest => rev rrest
   188         | _ => err ())
   189     | _ => err ())
   190   end;
   191 
   192 
   193 (* ML-style comments *)
   194 
   195 local
   196 
   197 val scan_cmt =
   198   Scan.depend (fn (d: int) => $$$ "(" @@@ $$$ "*" >> pair (d + 1)) ||
   199   Scan.depend (fn 0 => Scan.fail | d => $$$ "*" @@@ $$$ ")" >> pair (d - 1)) ||
   200   Scan.lift ($$$ "*" --| Scan.ahead (~$$$ ")")) ||
   201   Scan.lift (Scan.one (fn (s, _) => s <> "*" andalso Symbol.is_regular s)) >> single;
   202 
   203 val scan_cmts = Scan.pass 0 (Scan.repeat scan_cmt >> flat);
   204 
   205 val scan_body = change_prompt scan_cmts;
   206 
   207 in
   208 
   209 fun scan_comment err_prefix =
   210   Scan.ahead ($$ "(" -- $$ "*") |--
   211     !!! (fn () => err_prefix ^ "unclosed comment")
   212       ($$$ "(" @@@ $$$ "*" @@@ scan_body @@@ $$$ "*" @@@ $$$ ")");
   213 
   214 fun scan_comment_body err_prefix =
   215   Scan.ahead ($$ "(" -- $$ "*") |--
   216     !!! (fn () => err_prefix ^ "unclosed comment")
   217       ($$ "(" |-- $$ "*" |-- scan_body --| $$ "*" --| $$ ")");
   218 
   219 val recover_comment =
   220   $$$ "(" @@@ $$$ "*" @@@ scan_cmts;
   221 
   222 end;
   223 
   224 
   225 (* source *)
   226 
   227 fun source pos =
   228   Source.source' pos Symbol.stopper (Scan.bulk (Scan.depend (fn pos =>
   229     Scan.one Symbol.not_eof >> (fn s => (Position.advance s pos, (s, pos)))))) NONE;
   230 
   231 
   232 (* compact representation -- with Symbol.DEL padding *)
   233 
   234 type text = string;
   235 
   236 fun pad [] = []
   237   | pad [(s, _)] = [s]
   238   | pad ((s1, pos1) :: (rest as (_, pos2) :: _)) =
   239       let
   240         val end_pos1 = Position.advance s1 pos1;
   241         val d = Int.max (0, Position.distance_of end_pos1 pos2);
   242       in s1 :: replicate d Symbol.DEL @ pad rest end;
   243 
   244 val implode = implode o pad;
   245 
   246 fun implode_range pos1 pos2 syms =
   247   let val syms' = (("", pos1) :: syms @ [("", pos2)])
   248   in (implode syms', range syms') end;
   249 
   250 fun explode (str, pos) =
   251   let
   252     val (res, _) =
   253       fold (fn s => fn (res, p) => ((s, p) :: res, Position.advance s p))
   254         (Symbol.explode str) ([], Position.reset_range pos);
   255   in fold (fn (s, p) => if s = Symbol.DEL then I else cons (s, p)) res [] end;
   256 
   257 
   258 (* identifiers *)
   259 
   260 local
   261 
   262 val letter = Scan.one (symbol #> Symbol.is_letter);
   263 val letdigs1 = Scan.many1 (symbol #> Symbol.is_letdig);
   264 
   265 val sub = Scan.one (symbol #> (fn s => s = "\\<^sub>"));
   266 
   267 in
   268 
   269 val scan_ident = letter ::: (Scan.repeat (letdigs1 || sub ::: letdigs1) >> flat);
   270 
   271 end;
   272 
   273 fun is_identifier s =
   274   Symbol.is_ascii_identifier s orelse
   275     (case try (Scan.finite stopper scan_ident) (explode (s, Position.none)) of
   276       SOME (_, []) => true
   277     | _ => false);
   278 
   279 end;
   280 
   281 structure Basic_Symbol_Pos =   (*not open by default*)
   282 struct
   283   val $$ = Symbol_Pos.$$;
   284   val ~$$ = Symbol_Pos.~$$;
   285   val $$$ = Symbol_Pos.$$$;
   286   val ~$$$ = Symbol_Pos.~$$$;
   287 end;
   288