src/HOL/Library/Float.thy
author haftmann
Thu Apr 09 09:12:47 2015 +0200 (2015-04-09)
changeset 59984 4f1eccec320c
parent 59554 4044f53326c9
child 60017 b785d6d06430
permissions -rw-r--r--
conversion between division on nat/int and division in archmedean fields
     1 (*  Title:      HOL/Library/Float.thy
     2     Author:     Johannes Hölzl, Fabian Immler
     3     Copyright   2012  TU München
     4 *)
     5 
     6 section {* Floating-Point Numbers *}
     7 
     8 theory Float
     9 imports Complex_Main Lattice_Algebras
    10 begin
    11 
    12 definition "float = {m * 2 powr e | (m :: int) (e :: int). True}"
    13 
    14 typedef float = float
    15   morphisms real_of_float float_of
    16   unfolding float_def by auto
    17 
    18 instantiation float :: real_of
    19 begin
    20 
    21 definition real_float :: "float \<Rightarrow> real" where
    22   real_of_float_def[code_unfold]: "real \<equiv> real_of_float"
    23 
    24 instance ..
    25 end
    26 
    27 lemma type_definition_float': "type_definition real float_of float"
    28   using type_definition_float unfolding real_of_float_def .
    29 
    30 setup_lifting type_definition_float'
    31 
    32 lemmas float_of_inject[simp]
    33 
    34 declare [[coercion "real :: float \<Rightarrow> real"]]
    35 
    36 lemma real_of_float_eq:
    37   fixes f1 f2 :: float shows "f1 = f2 \<longleftrightarrow> real f1 = real f2"
    38   unfolding real_of_float_def real_of_float_inject ..
    39 
    40 lemma float_of_real[simp]: "float_of (real x) = x"
    41   unfolding real_of_float_def by (rule real_of_float_inverse)
    42 
    43 lemma real_float[simp]: "x \<in> float \<Longrightarrow> real (float_of x) = x"
    44   unfolding real_of_float_def by (rule float_of_inverse)
    45 
    46 subsection {* Real operations preserving the representation as floating point number *}
    47 
    48 lemma floatI: fixes m e :: int shows "m * 2 powr e = x \<Longrightarrow> x \<in> float"
    49   by (auto simp: float_def)
    50 
    51 lemma zero_float[simp]: "0 \<in> float" by (auto simp: float_def)
    52 lemma one_float[simp]: "1 \<in> float" by (intro floatI[of 1 0]) simp
    53 lemma numeral_float[simp]: "numeral i \<in> float" by (intro floatI[of "numeral i" 0]) simp
    54 lemma neg_numeral_float[simp]: "- numeral i \<in> float" by (intro floatI[of "- numeral i" 0]) simp
    55 lemma real_of_int_float[simp]: "real (x :: int) \<in> float" by (intro floatI[of x 0]) simp
    56 lemma real_of_nat_float[simp]: "real (x :: nat) \<in> float" by (intro floatI[of x 0]) simp
    57 lemma two_powr_int_float[simp]: "2 powr (real (i::int)) \<in> float" by (intro floatI[of 1 i]) simp
    58 lemma two_powr_nat_float[simp]: "2 powr (real (i::nat)) \<in> float" by (intro floatI[of 1 i]) simp
    59 lemma two_powr_minus_int_float[simp]: "2 powr - (real (i::int)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    60 lemma two_powr_minus_nat_float[simp]: "2 powr - (real (i::nat)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    61 lemma two_powr_numeral_float[simp]: "2 powr numeral i \<in> float" by (intro floatI[of 1 "numeral i"]) simp
    62 lemma two_powr_neg_numeral_float[simp]: "2 powr - numeral i \<in> float" by (intro floatI[of 1 "- numeral i"]) simp
    63 lemma two_pow_float[simp]: "2 ^ n \<in> float" by (intro floatI[of 1 "n"]) (simp add: powr_realpow)
    64 lemma real_of_float_float[simp]: "real (f::float) \<in> float" by (cases f) simp
    65 
    66 lemma plus_float[simp]: "r \<in> float \<Longrightarrow> p \<in> float \<Longrightarrow> r + p \<in> float"
    67   unfolding float_def
    68 proof (safe, simp)
    69   fix e1 m1 e2 m2 :: int
    70   { fix e1 m1 e2 m2 :: int assume "e1 \<le> e2"
    71     then have "m1 * 2 powr e1 + m2 * 2 powr e2 = (m1 + m2 * 2 ^ nat (e2 - e1)) * 2 powr e1"
    72       by (simp add: powr_realpow[symmetric] powr_divide2[symmetric] field_simps)
    73     then have "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    74       by blast }
    75   note * = this
    76   show "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    77   proof (cases e1 e2 rule: linorder_le_cases)
    78     assume "e2 \<le> e1" from *[OF this, of m2 m1] show ?thesis by (simp add: ac_simps)
    79   qed (rule *)
    80 qed
    81 
    82 lemma uminus_float[simp]: "x \<in> float \<Longrightarrow> -x \<in> float"
    83   apply (auto simp: float_def)
    84   apply hypsubst_thin
    85   apply (rule_tac x="-x" in exI)
    86   apply (rule_tac x="xa" in exI)
    87   apply (simp add: field_simps)
    88   done
    89 
    90 lemma times_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x * y \<in> float"
    91   apply (auto simp: float_def)
    92   apply hypsubst_thin
    93   apply (rule_tac x="x * xa" in exI)
    94   apply (rule_tac x="xb + xc" in exI)
    95   apply (simp add: powr_add)
    96   done
    97 
    98 lemma minus_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x - y \<in> float"
    99   using plus_float [of x "- y"] by simp
   100 
   101 lemma abs_float[simp]: "x \<in> float \<Longrightarrow> abs x \<in> float"
   102   by (cases x rule: linorder_cases[of 0]) auto
   103 
   104 lemma sgn_of_float[simp]: "x \<in> float \<Longrightarrow> sgn x \<in> float"
   105   by (cases x rule: linorder_cases[of 0]) (auto intro!: uminus_float)
   106 
   107 lemma div_power_2_float[simp]: "x \<in> float \<Longrightarrow> x / 2^d \<in> float"
   108   apply (auto simp add: float_def)
   109   apply hypsubst_thin
   110   apply (rule_tac x="x" in exI)
   111   apply (rule_tac x="xa - d" in exI)
   112   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   113   done
   114 
   115 lemma div_power_2_int_float[simp]: "x \<in> float \<Longrightarrow> x / (2::int)^d \<in> float"
   116   apply (auto simp add: float_def)
   117   apply hypsubst_thin
   118   apply (rule_tac x="x" in exI)
   119   apply (rule_tac x="xa - d" in exI)
   120   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   121   done
   122 
   123 lemma div_numeral_Bit0_float[simp]:
   124   assumes x: "x / numeral n \<in> float" shows "x / (numeral (Num.Bit0 n)) \<in> float"
   125 proof -
   126   have "(x / numeral n) / 2^1 \<in> float"
   127     by (intro x div_power_2_float)
   128   also have "(x / numeral n) / 2^1 = x / (numeral (Num.Bit0 n))"
   129     by (induct n) auto
   130   finally show ?thesis .
   131 qed
   132 
   133 lemma div_neg_numeral_Bit0_float[simp]:
   134   assumes x: "x / numeral n \<in> float" shows "x / (- numeral (Num.Bit0 n)) \<in> float"
   135 proof -
   136   have "- (x / numeral (Num.Bit0 n)) \<in> float" using x by simp
   137   also have "- (x / numeral (Num.Bit0 n)) = x / - numeral (Num.Bit0 n)"
   138     by simp
   139   finally show ?thesis .
   140 qed
   141 
   142 lemma power_float[simp]: assumes "a \<in> float" shows "a ^ b \<in> float"
   143 proof -
   144   from assms obtain m e::int where "a = m * 2 powr e"
   145     by (auto simp: float_def)
   146   thus ?thesis
   147     by (auto intro!: floatI[where m="m^b" and e = "e*b"]
   148       simp: power_mult_distrib powr_realpow[symmetric] powr_powr)
   149 qed
   150 
   151 lift_definition Float :: "int \<Rightarrow> int \<Rightarrow> float" is "\<lambda>(m::int) (e::int). m * 2 powr e" by simp
   152 declare Float.rep_eq[simp]
   153 
   154 lemma compute_real_of_float[code]:
   155   "real_of_float (Float m e) = (if e \<ge> 0 then m * 2 ^ nat e else m / 2 ^ (nat (-e)))"
   156 by (simp add: real_of_float_def[symmetric] powr_int)
   157 
   158 code_datatype Float
   159 
   160 subsection {* Arithmetic operations on floating point numbers *}
   161 
   162 instantiation float :: "{ring_1, linorder, linordered_ring, linordered_idom, numeral, equal}"
   163 begin
   164 
   165 lift_definition zero_float :: float is 0 by simp
   166 declare zero_float.rep_eq[simp]
   167 lift_definition one_float :: float is 1 by simp
   168 declare one_float.rep_eq[simp]
   169 lift_definition plus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op +" by simp
   170 declare plus_float.rep_eq[simp]
   171 lift_definition times_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op *" by simp
   172 declare times_float.rep_eq[simp]
   173 lift_definition minus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op -" by simp
   174 declare minus_float.rep_eq[simp]
   175 lift_definition uminus_float :: "float \<Rightarrow> float" is "uminus" by simp
   176 declare uminus_float.rep_eq[simp]
   177 
   178 lift_definition abs_float :: "float \<Rightarrow> float" is abs by simp
   179 declare abs_float.rep_eq[simp]
   180 lift_definition sgn_float :: "float \<Rightarrow> float" is sgn by simp
   181 declare sgn_float.rep_eq[simp]
   182 
   183 lift_definition equal_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op = :: real \<Rightarrow> real \<Rightarrow> bool" .
   184 
   185 lift_definition less_eq_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op \<le>" .
   186 declare less_eq_float.rep_eq[simp]
   187 lift_definition less_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op <" .
   188 declare less_float.rep_eq[simp]
   189 
   190 instance
   191   proof qed (transfer, fastforce simp add: field_simps intro: mult_left_mono mult_right_mono)+
   192 end
   193 
   194 lemma Float_0_eq_0[simp]: "Float 0 e = 0"
   195   by transfer simp
   196 
   197 lemma real_of_float_power[simp]: fixes f::float shows "real (f^n) = real f^n"
   198   by (induct n) simp_all
   199 
   200 lemma fixes x y::float
   201   shows real_of_float_min: "real (min x y) = min (real x) (real y)"
   202     and real_of_float_max: "real (max x y) = max (real x) (real y)"
   203   by (simp_all add: min_def max_def)
   204 
   205 instance float :: unbounded_dense_linorder
   206 proof
   207   fix a b :: float
   208   show "\<exists>c. a < c"
   209     apply (intro exI[of _ "a + 1"])
   210     apply transfer
   211     apply simp
   212     done
   213   show "\<exists>c. c < a"
   214     apply (intro exI[of _ "a - 1"])
   215     apply transfer
   216     apply simp
   217     done
   218   assume "a < b"
   219   then show "\<exists>c. a < c \<and> c < b"
   220     apply (intro exI[of _ "(a + b) * Float 1 (- 1)"])
   221     apply transfer
   222     apply (simp add: powr_minus)
   223     done
   224 qed
   225 
   226 instantiation float :: lattice_ab_group_add
   227 begin
   228 
   229 definition inf_float::"float\<Rightarrow>float\<Rightarrow>float"
   230 where "inf_float a b = min a b"
   231 
   232 definition sup_float::"float\<Rightarrow>float\<Rightarrow>float"
   233 where "sup_float a b = max a b"
   234 
   235 instance
   236   by default
   237      (transfer, simp_all add: inf_float_def sup_float_def real_of_float_min real_of_float_max)+
   238 end
   239 
   240 lemma float_numeral[simp]: "real (numeral x :: float) = numeral x"
   241   apply (induct x)
   242   apply simp
   243   apply (simp_all only: numeral_Bit0 numeral_Bit1 real_of_float_eq real_float
   244                   plus_float.rep_eq one_float.rep_eq plus_float numeral_float one_float)
   245   done
   246 
   247 lemma transfer_numeral [transfer_rule]:
   248   "rel_fun (op =) pcr_float (numeral :: _ \<Rightarrow> real) (numeral :: _ \<Rightarrow> float)"
   249   unfolding rel_fun_def float.pcr_cr_eq  cr_float_def by simp
   250 
   251 lemma float_neg_numeral[simp]: "real (- numeral x :: float) = - numeral x"
   252   by simp
   253 
   254 lemma transfer_neg_numeral [transfer_rule]:
   255   "rel_fun (op =) pcr_float (- numeral :: _ \<Rightarrow> real) (- numeral :: _ \<Rightarrow> float)"
   256   unfolding rel_fun_def float.pcr_cr_eq cr_float_def by simp
   257 
   258 lemma
   259   shows float_of_numeral[simp]: "numeral k = float_of (numeral k)"
   260     and float_of_neg_numeral[simp]: "- numeral k = float_of (- numeral k)"
   261   unfolding real_of_float_eq by simp_all
   262 
   263 subsection {* Quickcheck *}
   264 
   265 instantiation float :: exhaustive
   266 begin
   267 
   268 definition exhaustive_float where
   269   "exhaustive_float f d =
   270     Quickcheck_Exhaustive.exhaustive (%x. Quickcheck_Exhaustive.exhaustive (%y. f (Float x y)) d) d"
   271 
   272 instance ..
   273 
   274 end
   275 
   276 definition (in term_syntax) [code_unfold]:
   277   "valtermify_float x y = Code_Evaluation.valtermify Float {\<cdot>} x {\<cdot>} y"
   278 
   279 instantiation float :: full_exhaustive
   280 begin
   281 
   282 definition full_exhaustive_float where
   283   "full_exhaustive_float f d =
   284     Quickcheck_Exhaustive.full_exhaustive
   285       (\<lambda>x. Quickcheck_Exhaustive.full_exhaustive (\<lambda>y. f (valtermify_float x y)) d) d"
   286 
   287 instance ..
   288 
   289 end
   290 
   291 instantiation float :: random
   292 begin
   293 
   294 definition "Quickcheck_Random.random i =
   295   scomp (Quickcheck_Random.random (2 ^ nat_of_natural i))
   296     (\<lambda>man. scomp (Quickcheck_Random.random i) (\<lambda>exp. Pair (valtermify_float man exp)))"
   297 
   298 instance ..
   299 
   300 end
   301 
   302 
   303 subsection {* Represent floats as unique mantissa and exponent *}
   304 
   305 lemma int_induct_abs[case_names less]:
   306   fixes j :: int
   307   assumes H: "\<And>n. (\<And>i. \<bar>i\<bar> < \<bar>n\<bar> \<Longrightarrow> P i) \<Longrightarrow> P n"
   308   shows "P j"
   309 proof (induct "nat \<bar>j\<bar>" arbitrary: j rule: less_induct)
   310   case less show ?case by (rule H[OF less]) simp
   311 qed
   312 
   313 lemma int_cancel_factors:
   314   fixes n :: int assumes "1 < r" shows "n = 0 \<or> (\<exists>k i. n = k * r ^ i \<and> \<not> r dvd k)"
   315 proof (induct n rule: int_induct_abs)
   316   case (less n)
   317   { fix m assume n: "n \<noteq> 0" "n = m * r"
   318     then have "\<bar>m \<bar> < \<bar>n\<bar>"
   319       using `1 < r` by (simp add: abs_mult)
   320     from less[OF this] n have "\<exists>k i. n = k * r ^ Suc i \<and> \<not> r dvd k" by auto }
   321   then show ?case
   322     by (metis dvd_def monoid_mult_class.mult.right_neutral mult.commute power_0)
   323 qed
   324 
   325 lemma mult_powr_eq_mult_powr_iff_asym:
   326   fixes m1 m2 e1 e2 :: int
   327   assumes m1: "\<not> 2 dvd m1" and "e1 \<le> e2"
   328   shows "m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   329 proof
   330   have "m1 \<noteq> 0" using m1 unfolding dvd_def by auto
   331   assume eq: "m1 * 2 powr e1 = m2 * 2 powr e2"
   332   with `e1 \<le> e2` have "m1 = m2 * 2 powr nat (e2 - e1)"
   333     by (simp add: powr_divide2[symmetric] field_simps)
   334   also have "\<dots> = m2 * 2^nat (e2 - e1)"
   335     by (simp add: powr_realpow)
   336   finally have m1_eq: "m1 = m2 * 2^nat (e2 - e1)"
   337     unfolding real_of_int_inject .
   338   with m1 have "m1 = m2"
   339     by (cases "nat (e2 - e1)") (auto simp add: dvd_def)
   340   then show "m1 = m2 \<and> e1 = e2"
   341     using eq `m1 \<noteq> 0` by (simp add: powr_inj)
   342 qed simp
   343 
   344 lemma mult_powr_eq_mult_powr_iff:
   345   fixes m1 m2 e1 e2 :: int
   346   shows "\<not> 2 dvd m1 \<Longrightarrow> \<not> 2 dvd m2 \<Longrightarrow> m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   347   using mult_powr_eq_mult_powr_iff_asym[of m1 e1 e2 m2]
   348   using mult_powr_eq_mult_powr_iff_asym[of m2 e2 e1 m1]
   349   by (cases e1 e2 rule: linorder_le_cases) auto
   350 
   351 lemma floatE_normed:
   352   assumes x: "x \<in> float"
   353   obtains (zero) "x = 0"
   354    | (powr) m e :: int where "x = m * 2 powr e" "\<not> 2 dvd m" "x \<noteq> 0"
   355 proof atomize_elim
   356   { assume "x \<noteq> 0"
   357     from x obtain m e :: int where x: "x = m * 2 powr e" by (auto simp: float_def)
   358     with `x \<noteq> 0` int_cancel_factors[of 2 m] obtain k i where "m = k * 2 ^ i" "\<not> 2 dvd k"
   359       by auto
   360     with `\<not> 2 dvd k` x have "\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m"
   361       by (rule_tac exI[of _ "k"], rule_tac exI[of _ "e + int i"])
   362          (simp add: powr_add powr_realpow) }
   363   then show "x = 0 \<or> (\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m \<and> x \<noteq> 0)"
   364     by blast
   365 qed
   366 
   367 lemma float_normed_cases:
   368   fixes f :: float
   369   obtains (zero) "f = 0"
   370    | (powr) m e :: int where "real f = m * 2 powr e" "\<not> 2 dvd m" "f \<noteq> 0"
   371 proof (atomize_elim, induct f)
   372   case (float_of y) then show ?case
   373     by (cases rule: floatE_normed) (auto simp: zero_float_def)
   374 qed
   375 
   376 definition mantissa :: "float \<Rightarrow> int" where
   377   "mantissa f = fst (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   378    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   379 
   380 definition exponent :: "float \<Rightarrow> int" where
   381   "exponent f = snd (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   382    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   383 
   384 lemma
   385   shows exponent_0[simp]: "exponent (float_of 0) = 0" (is ?E)
   386     and mantissa_0[simp]: "mantissa (float_of 0) = 0" (is ?M)
   387 proof -
   388   have "\<And>p::int \<times> int. fst p = 0 \<and> snd p = 0 \<longleftrightarrow> p = (0, 0)" by auto
   389   then show ?E ?M
   390     by (auto simp add: mantissa_def exponent_def zero_float_def)
   391 qed
   392 
   393 lemma
   394   shows mantissa_exponent: "real f = mantissa f * 2 powr exponent f" (is ?E)
   395     and mantissa_not_dvd: "f \<noteq> (float_of 0) \<Longrightarrow> \<not> 2 dvd mantissa f" (is "_ \<Longrightarrow> ?D")
   396 proof cases
   397   assume [simp]: "f \<noteq> (float_of 0)"
   398   have "f = mantissa f * 2 powr exponent f \<and> \<not> 2 dvd mantissa f"
   399   proof (cases f rule: float_normed_cases)
   400     case (powr m e)
   401     then have "\<exists>p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   402      \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p)"
   403       by auto
   404     then show ?thesis
   405       unfolding exponent_def mantissa_def
   406       by (rule someI2_ex) (simp add: zero_float_def)
   407   qed (simp add: zero_float_def)
   408   then show ?E ?D by auto
   409 qed simp
   410 
   411 lemma mantissa_noteq_0: "f \<noteq> float_of 0 \<Longrightarrow> mantissa f \<noteq> 0"
   412   using mantissa_not_dvd[of f] by auto
   413 
   414 lemma
   415   fixes m e :: int
   416   defines "f \<equiv> float_of (m * 2 powr e)"
   417   assumes dvd: "\<not> 2 dvd m"
   418   shows mantissa_float: "mantissa f = m" (is "?M")
   419     and exponent_float: "m \<noteq> 0 \<Longrightarrow> exponent f = e" (is "_ \<Longrightarrow> ?E")
   420 proof cases
   421   assume "m = 0" with dvd show "mantissa f = m" by auto
   422 next
   423   assume "m \<noteq> 0"
   424   then have f_not_0: "f \<noteq> float_of 0" by (simp add: f_def)
   425   from mantissa_exponent[of f]
   426   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   427     by (auto simp add: f_def)
   428   then show "?M" "?E"
   429     using mantissa_not_dvd[OF f_not_0] dvd
   430     by (auto simp: mult_powr_eq_mult_powr_iff)
   431 qed
   432 
   433 subsection {* Compute arithmetic operations *}
   434 
   435 lemma Float_mantissa_exponent: "Float (mantissa f) (exponent f) = f"
   436   unfolding real_of_float_eq mantissa_exponent[of f] by simp
   437 
   438 lemma Float_cases[case_names Float, cases type: float]:
   439   fixes f :: float
   440   obtains (Float) m e :: int where "f = Float m e"
   441   using Float_mantissa_exponent[symmetric]
   442   by (atomize_elim) auto
   443 
   444 lemma denormalize_shift:
   445   assumes f_def: "f \<equiv> Float m e" and not_0: "f \<noteq> float_of 0"
   446   obtains i where "m = mantissa f * 2 ^ i" "e = exponent f - i"
   447 proof
   448   from mantissa_exponent[of f] f_def
   449   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   450     by simp
   451   then have eq: "m = mantissa f * 2 powr (exponent f - e)"
   452     by (simp add: powr_divide2[symmetric] field_simps)
   453   moreover
   454   have "e \<le> exponent f"
   455   proof (rule ccontr)
   456     assume "\<not> e \<le> exponent f"
   457     then have pos: "exponent f < e" by simp
   458     then have "2 powr (exponent f - e) = 2 powr - real (e - exponent f)"
   459       by simp
   460     also have "\<dots> = 1 / 2^nat (e - exponent f)"
   461       using pos by (simp add: powr_realpow[symmetric] powr_divide2[symmetric])
   462     finally have "m * 2^nat (e - exponent f) = real (mantissa f)"
   463       using eq by simp
   464     then have "mantissa f = m * 2^nat (e - exponent f)"
   465       unfolding real_of_int_inject by simp
   466     with `exponent f < e` have "2 dvd mantissa f"
   467       apply (intro dvdI[where k="m * 2^(nat (e-exponent f)) div 2"])
   468       apply (cases "nat (e - exponent f)")
   469       apply auto
   470       done
   471     then show False using mantissa_not_dvd[OF not_0] by simp
   472   qed
   473   ultimately have "real m = mantissa f * 2^nat (exponent f - e)"
   474     by (simp add: powr_realpow[symmetric])
   475   with `e \<le> exponent f`
   476   show "m = mantissa f * 2 ^ nat (exponent f - e)" "e = exponent f - nat (exponent f - e)"
   477     unfolding real_of_int_inject by auto
   478 qed
   479 
   480 lemma compute_float_zero[code_unfold, code]: "0 = Float 0 0"
   481   by transfer simp
   482 hide_fact (open) compute_float_zero
   483 
   484 lemma compute_float_one[code_unfold, code]: "1 = Float 1 0"
   485   by transfer simp
   486 hide_fact (open) compute_float_one
   487 
   488 lift_definition normfloat :: "float \<Rightarrow> float" is "\<lambda>x. x" .
   489 lemma normloat_id[simp]: "normfloat x = x" by transfer rule
   490 
   491 lemma compute_normfloat[code]: "normfloat (Float m e) =
   492   (if m mod 2 = 0 \<and> m \<noteq> 0 then normfloat (Float (m div 2) (e + 1))
   493                            else if m = 0 then 0 else Float m e)"
   494   by transfer (auto simp add: powr_add zmod_eq_0_iff)
   495 hide_fact (open) compute_normfloat
   496 
   497 lemma compute_float_numeral[code_abbrev]: "Float (numeral k) 0 = numeral k"
   498   by transfer simp
   499 hide_fact (open) compute_float_numeral
   500 
   501 lemma compute_float_neg_numeral[code_abbrev]: "Float (- numeral k) 0 = - numeral k"
   502   by transfer simp
   503 hide_fact (open) compute_float_neg_numeral
   504 
   505 lemma compute_float_uminus[code]: "- Float m1 e1 = Float (- m1) e1"
   506   by transfer simp
   507 hide_fact (open) compute_float_uminus
   508 
   509 lemma compute_float_times[code]: "Float m1 e1 * Float m2 e2 = Float (m1 * m2) (e1 + e2)"
   510   by transfer (simp add: field_simps powr_add)
   511 hide_fact (open) compute_float_times
   512 
   513 lemma compute_float_plus[code]: "Float m1 e1 + Float m2 e2 =
   514   (if m1 = 0 then Float m2 e2 else if m2 = 0 then Float m1 e1 else
   515   if e1 \<le> e2 then Float (m1 + m2 * 2^nat (e2 - e1)) e1
   516               else Float (m2 + m1 * 2^nat (e1 - e2)) e2)"
   517   by transfer (simp add: field_simps powr_realpow[symmetric] powr_divide2[symmetric])
   518 hide_fact (open) compute_float_plus
   519 
   520 lemma compute_float_minus[code]: fixes f g::float shows "f - g = f + (-g)"
   521   by simp
   522 hide_fact (open) compute_float_minus
   523 
   524 lemma compute_float_sgn[code]: "sgn (Float m1 e1) = (if 0 < m1 then 1 else if m1 < 0 then -1 else 0)"
   525   by transfer (simp add: sgn_times)
   526 hide_fact (open) compute_float_sgn
   527 
   528 lift_definition is_float_pos :: "float \<Rightarrow> bool" is "op < 0 :: real \<Rightarrow> bool" .
   529 
   530 lemma compute_is_float_pos[code]: "is_float_pos (Float m e) \<longleftrightarrow> 0 < m"
   531   by transfer (auto simp add: zero_less_mult_iff not_le[symmetric, of _ 0])
   532 hide_fact (open) compute_is_float_pos
   533 
   534 lemma compute_float_less[code]: "a < b \<longleftrightarrow> is_float_pos (b - a)"
   535   by transfer (simp add: field_simps)
   536 hide_fact (open) compute_float_less
   537 
   538 lift_definition is_float_nonneg :: "float \<Rightarrow> bool" is "op \<le> 0 :: real \<Rightarrow> bool" .
   539 
   540 lemma compute_is_float_nonneg[code]: "is_float_nonneg (Float m e) \<longleftrightarrow> 0 \<le> m"
   541   by transfer (auto simp add: zero_le_mult_iff not_less[symmetric, of _ 0])
   542 hide_fact (open) compute_is_float_nonneg
   543 
   544 lemma compute_float_le[code]: "a \<le> b \<longleftrightarrow> is_float_nonneg (b - a)"
   545   by transfer (simp add: field_simps)
   546 hide_fact (open) compute_float_le
   547 
   548 lift_definition is_float_zero :: "float \<Rightarrow> bool"  is "op = 0 :: real \<Rightarrow> bool" .
   549 
   550 lemma compute_is_float_zero[code]: "is_float_zero (Float m e) \<longleftrightarrow> 0 = m"
   551   by transfer (auto simp add: is_float_zero_def)
   552 hide_fact (open) compute_is_float_zero
   553 
   554 lemma compute_float_abs[code]: "abs (Float m e) = Float (abs m) e"
   555   by transfer (simp add: abs_mult)
   556 hide_fact (open) compute_float_abs
   557 
   558 lemma compute_float_eq[code]: "equal_class.equal f g = is_float_zero (f - g)"
   559   by transfer simp
   560 hide_fact (open) compute_float_eq
   561 
   562 
   563 subsection {* Lemmas for types @{typ real}, @{typ nat}, @{typ int}*}
   564 
   565 lemmas real_of_ints =
   566   real_of_int_zero
   567   real_of_one
   568   real_of_int_add
   569   real_of_int_minus
   570   real_of_int_diff
   571   real_of_int_mult
   572   real_of_int_power
   573   real_numeral
   574 lemmas real_of_nats =
   575   real_of_nat_zero
   576   real_of_nat_one
   577   real_of_nat_1
   578   real_of_nat_add
   579   real_of_nat_mult
   580   real_of_nat_power
   581   real_of_nat_numeral
   582 
   583 lemmas int_of_reals = real_of_ints[symmetric]
   584 lemmas nat_of_reals = real_of_nats[symmetric]
   585 
   586 
   587 subsection {* Rounding Real Numbers *}
   588 
   589 definition round_down :: "int \<Rightarrow> real \<Rightarrow> real" where
   590   "round_down prec x = floor (x * 2 powr prec) * 2 powr -prec"
   591 
   592 definition round_up :: "int \<Rightarrow> real \<Rightarrow> real" where
   593   "round_up prec x = ceiling (x * 2 powr prec) * 2 powr -prec"
   594 
   595 lemma round_down_float[simp]: "round_down prec x \<in> float"
   596   unfolding round_down_def
   597   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   598 
   599 lemma round_up_float[simp]: "round_up prec x \<in> float"
   600   unfolding round_up_def
   601   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   602 
   603 lemma round_up: "x \<le> round_up prec x"
   604   by (simp add: powr_minus_divide le_divide_eq round_up_def)
   605 
   606 lemma round_down: "round_down prec x \<le> x"
   607   by (simp add: powr_minus_divide divide_le_eq round_down_def)
   608 
   609 lemma round_up_0[simp]: "round_up p 0 = 0"
   610   unfolding round_up_def by simp
   611 
   612 lemma round_down_0[simp]: "round_down p 0 = 0"
   613   unfolding round_down_def by simp
   614 
   615 lemma round_up_diff_round_down:
   616   "round_up prec x - round_down prec x \<le> 2 powr -prec"
   617 proof -
   618   have "round_up prec x - round_down prec x =
   619     (ceiling (x * 2 powr prec) - floor (x * 2 powr prec)) * 2 powr -prec"
   620     by (simp add: round_up_def round_down_def field_simps)
   621   also have "\<dots> \<le> 1 * 2 powr -prec"
   622     by (rule mult_mono)
   623        (auto simp del: real_of_int_diff
   624              simp: real_of_int_diff[symmetric] real_of_int_le_one_cancel_iff ceiling_diff_floor_le_1)
   625   finally show ?thesis by simp
   626 qed
   627 
   628 lemma round_down_shift: "round_down p (x * 2 powr k) = 2 powr k * round_down (p + k) x"
   629   unfolding round_down_def
   630   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   631     (simp add: powr_add[symmetric])
   632 
   633 lemma round_up_shift: "round_up p (x * 2 powr k) = 2 powr k * round_up (p + k) x"
   634   unfolding round_up_def
   635   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   636     (simp add: powr_add[symmetric])
   637 
   638 lemma round_up_uminus_eq: "round_up p (-x) = - round_down p x"
   639   and round_down_uminus_eq: "round_down p (-x) = - round_up p x"
   640   by (auto simp: round_up_def round_down_def ceiling_def)
   641 
   642 lemma round_up_mono: "x \<le> y \<Longrightarrow> round_up p x \<le> round_up p y"
   643   by (auto intro!: ceiling_mono simp: round_up_def)
   644 
   645 lemma round_up_le1:
   646   assumes "x \<le> 1" "prec \<ge> 0"
   647   shows "round_up prec x \<le> 1"
   648 proof -
   649   have "real \<lceil>x * 2 powr prec\<rceil> \<le> real \<lceil>2 powr real prec\<rceil>"
   650     using assms by (auto intro!: ceiling_mono)
   651   also have "\<dots> = 2 powr prec" using assms by (auto simp: powr_int intro!: exI[where x="2^nat prec"])
   652   finally show ?thesis
   653     by (simp add: round_up_def) (simp add: powr_minus inverse_eq_divide)
   654 qed
   655 
   656 lemma round_up_less1:
   657   assumes "x < 1 / 2" "p > 0"
   658   shows "round_up p x < 1"
   659 proof -
   660   have "x * 2 powr p < 1 / 2 * 2 powr p"
   661     using assms by simp
   662   also have "\<dots> \<le> 2 powr p - 1" using `p > 0`
   663     by (auto simp: powr_divide2[symmetric] powr_int field_simps self_le_power)
   664   finally show ?thesis using `p > 0`
   665     by (simp add: round_up_def field_simps powr_minus powr_int ceiling_less_eq)
   666 qed
   667 
   668 lemma round_down_ge1:
   669   assumes x: "x \<ge> 1"
   670   assumes prec: "p \<ge> - log 2 x"
   671   shows "1 \<le> round_down p x"
   672 proof cases
   673   assume nonneg: "0 \<le> p"
   674   have "2 powr p = real \<lfloor>2 powr real p\<rfloor>"
   675     using nonneg by (auto simp: powr_int)
   676   also have "\<dots> \<le> real \<lfloor>x * 2 powr p\<rfloor>"
   677     using assms by (auto intro!: floor_mono)
   678   finally show ?thesis
   679     by (simp add: round_down_def) (simp add: powr_minus inverse_eq_divide)
   680 next
   681   assume neg: "\<not> 0 \<le> p"
   682   have "x = 2 powr (log 2 x)"
   683     using x by simp
   684   also have "2 powr (log 2 x) \<ge> 2 powr - p"
   685     using prec by auto
   686   finally have x_le: "x \<ge> 2 powr -p" .
   687 
   688   from neg have "2 powr real p \<le> 2 powr 0"
   689     by (intro powr_mono) auto
   690   also have "\<dots> \<le> \<lfloor>2 powr 0\<rfloor>" by simp
   691   also have "\<dots> \<le> \<lfloor>x * 2 powr real p\<rfloor>" unfolding real_of_int_le_iff
   692     using x x_le by (intro floor_mono) (simp add: powr_minus_divide field_simps)
   693   finally show ?thesis
   694     using prec x
   695     by (simp add: round_down_def powr_minus_divide pos_le_divide_eq)
   696 qed
   697 
   698 lemma round_up_le0: "x \<le> 0 \<Longrightarrow> round_up p x \<le> 0"
   699   unfolding round_up_def
   700   by (auto simp: field_simps mult_le_0_iff zero_le_mult_iff)
   701 
   702 
   703 subsection {* Rounding Floats *}
   704 
   705 definition div_twopow::"int \<Rightarrow> nat \<Rightarrow> int" where [simp]: "div_twopow x n = x div (2 ^ n)"
   706 
   707 definition mod_twopow::"int \<Rightarrow> nat \<Rightarrow> int" where [simp]: "mod_twopow x n = x mod (2 ^ n)"
   708 
   709 lemma compute_div_twopow[code]:
   710   "div_twopow x n = (if x = 0 \<or> x = -1 \<or> n = 0 then x else div_twopow (x div 2) (n - 1))"
   711   by (cases n) (auto simp: zdiv_zmult2_eq div_eq_minus1)
   712 
   713 lemma compute_mod_twopow[code]:
   714   "mod_twopow x n = (if n = 0 then 0 else x mod 2 + 2 * mod_twopow (x div 2) (n - 1))"
   715   by (cases n) (auto simp: zmod_zmult2_eq)
   716 
   717 lift_definition float_up :: "int \<Rightarrow> float \<Rightarrow> float" is round_up by simp
   718 declare float_up.rep_eq[simp]
   719 
   720 lemma round_up_correct:
   721   shows "round_up e f - f \<in> {0..2 powr -e}"
   722 unfolding atLeastAtMost_iff
   723 proof
   724   have "round_up e f - f \<le> round_up e f - round_down e f" using round_down by simp
   725   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   726   finally show "round_up e f - f \<le> 2 powr real (- e)"
   727     by simp
   728 qed (simp add: algebra_simps round_up)
   729 
   730 lemma float_up_correct:
   731   shows "real (float_up e f) - real f \<in> {0..2 powr -e}"
   732   by transfer (rule round_up_correct)
   733 
   734 lift_definition float_down :: "int \<Rightarrow> float \<Rightarrow> float" is round_down by simp
   735 declare float_down.rep_eq[simp]
   736 
   737 lemma round_down_correct:
   738   shows "f - (round_down e f) \<in> {0..2 powr -e}"
   739 unfolding atLeastAtMost_iff
   740 proof
   741   have "f - round_down e f \<le> round_up e f - round_down e f" using round_up by simp
   742   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   743   finally show "f - round_down e f \<le> 2 powr real (- e)"
   744     by simp
   745 qed (simp add: algebra_simps round_down)
   746 
   747 lemma float_down_correct:
   748   shows "real f - real (float_down e f) \<in> {0..2 powr -e}"
   749   by transfer (rule round_down_correct)
   750 
   751 lemma compute_float_down[code]:
   752   "float_down p (Float m e) =
   753     (if p + e < 0 then Float (div_twopow m (nat (-(p + e)))) (-p) else Float m e)"
   754 proof cases
   755   assume "p + e < 0"
   756   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   757     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   758   also have "... = 1 / 2 powr p / 2 powr e"
   759     unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   760   finally show ?thesis
   761     using `p + e < 0`
   762     by transfer (simp add: ac_simps round_down_def floor_divide_eq_div[symmetric])
   763 next
   764   assume "\<not> p + e < 0"
   765   then have r: "real e + real p = real (nat (e + p))" by simp
   766   have r: "\<lfloor>(m * 2 powr e) * 2 powr real p\<rfloor> = (m * 2 powr e) * 2 powr real p"
   767     by (auto intro: exI[where x="m*2^nat (e+p)"]
   768              simp add: ac_simps powr_add[symmetric] r powr_realpow)
   769   with `\<not> p + e < 0` show ?thesis
   770     by transfer (auto simp add: round_down_def field_simps powr_add powr_minus)
   771 qed
   772 hide_fact (open) compute_float_down
   773 
   774 lemma abs_round_down_le: "\<bar>f - (round_down e f)\<bar> \<le> 2 powr -e"
   775   using round_down_correct[of f e] by simp
   776 
   777 lemma abs_round_up_le: "\<bar>f - (round_up e f)\<bar> \<le> 2 powr -e"
   778   using round_up_correct[of e f] by simp
   779 
   780 lemma round_down_nonneg: "0 \<le> s \<Longrightarrow> 0 \<le> round_down p s"
   781   by (auto simp: round_down_def)
   782 
   783 lemma ceil_divide_floor_conv:
   784 assumes "b \<noteq> 0"
   785 shows "\<lceil>real a / real b\<rceil> = (if b dvd a then a div b else \<lfloor>real a / real b\<rfloor> + 1)"
   786 proof cases
   787   assume "\<not> b dvd a"
   788   hence "a mod b \<noteq> 0" by auto
   789   hence ne: "real (a mod b) / real b \<noteq> 0" using `b \<noteq> 0` by auto
   790   have "\<lceil>real a / real b\<rceil> = \<lfloor>real a / real b\<rfloor> + 1"
   791   apply (rule ceiling_eq) apply (auto simp: floor_divide_eq_div[symmetric])
   792   proof -
   793     have "real \<lfloor>real a / real b\<rfloor> \<le> real a / real b" by simp
   794     moreover have "real \<lfloor>real a / real b\<rfloor> \<noteq> real a / real b"
   795     apply (subst (2) real_of_int_div_aux) unfolding floor_divide_eq_div using ne `b \<noteq> 0` by auto
   796     ultimately show "real \<lfloor>real a / real b\<rfloor> < real a / real b" by arith
   797   qed
   798   thus ?thesis using `\<not> b dvd a` by simp
   799 qed (simp add: ceiling_def real_of_int_minus[symmetric] divide_minus_left[symmetric]
   800   floor_divide_eq_div dvd_neg_div del: divide_minus_left real_of_int_minus)
   801 
   802 lemma compute_float_up[code]:
   803   "float_up p x = - float_down p (-x)"
   804   by transfer (simp add: round_down_uminus_eq)
   805 hide_fact (open) compute_float_up
   806 
   807 
   808 subsection {* Compute bitlen of integers *}
   809 
   810 definition bitlen :: "int \<Rightarrow> int" where
   811   "bitlen a = (if a > 0 then \<lfloor>log 2 a\<rfloor> + 1 else 0)"
   812 
   813 lemma bitlen_nonneg: "0 \<le> bitlen x"
   814 proof -
   815   {
   816     assume "0 > x"
   817     have "-1 = log 2 (inverse 2)" by (subst log_inverse) simp_all
   818     also have "... < log 2 (-x)" using `0 > x` by auto
   819     finally have "-1 < log 2 (-x)" .
   820   } thus "0 \<le> bitlen x" unfolding bitlen_def by (auto intro!: add_nonneg_nonneg)
   821 qed
   822 
   823 lemma bitlen_bounds:
   824   assumes "x > 0"
   825   shows "2 ^ nat (bitlen x - 1) \<le> x \<and> x < 2 ^ nat (bitlen x)"
   826 proof
   827   have "(2::real) ^ nat \<lfloor>log 2 (real x)\<rfloor> = 2 powr real (floor (log 2 (real x)))"
   828     using powr_realpow[symmetric, of 2 "nat \<lfloor>log 2 (real x)\<rfloor>"] `x > 0`
   829     using real_nat_eq_real[of "floor (log 2 (real x))"]
   830     by simp
   831   also have "... \<le> 2 powr log 2 (real x)"
   832     by simp
   833   also have "... = real x"
   834     using `0 < x` by simp
   835   finally have "2 ^ nat \<lfloor>log 2 (real x)\<rfloor> \<le> real x" by simp
   836   thus "2 ^ nat (bitlen x - 1) \<le> x" using `x > 0`
   837     by (simp add: bitlen_def)
   838 next
   839   have "x \<le> 2 powr (log 2 x)" using `x > 0` by simp
   840   also have "... < 2 ^ nat (\<lfloor>log 2 (real x)\<rfloor> + 1)"
   841     apply (simp add: powr_realpow[symmetric])
   842     using `x > 0` by simp
   843   finally show "x < 2 ^ nat (bitlen x)" using `x > 0`
   844     by (simp add: bitlen_def ac_simps)
   845 qed
   846 
   847 lemma bitlen_pow2[simp]:
   848   assumes "b > 0"
   849   shows "bitlen (b * 2 ^ c) = bitlen b + c"
   850 proof -
   851   from assms have "b * 2 ^ c > 0" by auto
   852   thus ?thesis
   853     using floor_add[of "log 2 b" c] assms
   854     by (auto simp add: log_mult log_nat_power bitlen_def)
   855 qed
   856 
   857 lemma bitlen_Float:
   858   fixes m e
   859   defines "f \<equiv> Float m e"
   860   shows "bitlen (\<bar>mantissa f\<bar>) + exponent f = (if m = 0 then 0 else bitlen \<bar>m\<bar> + e)"
   861 proof (cases "m = 0")
   862   case True
   863   then show ?thesis by (simp add: f_def bitlen_def Float_def)
   864 next
   865   case False
   866   hence "f \<noteq> float_of 0"
   867     unfolding real_of_float_eq by (simp add: f_def)
   868   hence "mantissa f \<noteq> 0"
   869     by (simp add: mantissa_noteq_0)
   870   moreover
   871   obtain i where "m = mantissa f * 2 ^ i" "e = exponent f - int i"
   872     by (rule f_def[THEN denormalize_shift, OF `f \<noteq> float_of 0`])
   873   ultimately show ?thesis by (simp add: abs_mult)
   874 qed
   875 
   876 lemma compute_bitlen[code]:
   877   shows "bitlen x = (if x > 0 then bitlen (x div 2) + 1 else 0)"
   878 proof -
   879   { assume "2 \<le> x"
   880     then have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 (x - x mod 2)\<rfloor>"
   881       by (simp add: log_mult zmod_zdiv_equality')
   882     also have "\<dots> = \<lfloor>log 2 (real x)\<rfloor>"
   883     proof cases
   884       assume "x mod 2 = 0" then show ?thesis by simp
   885     next
   886       def n \<equiv> "\<lfloor>log 2 (real x)\<rfloor>"
   887       then have "0 \<le> n"
   888         using `2 \<le> x` by simp
   889       assume "x mod 2 \<noteq> 0"
   890       with `2 \<le> x` have "x mod 2 = 1" "\<not> 2 dvd x" by (auto simp add: dvd_eq_mod_eq_0)
   891       with `2 \<le> x` have "x \<noteq> 2^nat n" by (cases "nat n") auto
   892       moreover
   893       { have "real (2^nat n :: int) = 2 powr (nat n)"
   894           by (simp add: powr_realpow)
   895         also have "\<dots> \<le> 2 powr (log 2 x)"
   896           using `2 \<le> x` by (simp add: n_def del: powr_log_cancel)
   897         finally have "2^nat n \<le> x" using `2 \<le> x` by simp }
   898       ultimately have "2^nat n \<le> x - 1" by simp
   899       then have "2^nat n \<le> real (x - 1)"
   900         unfolding real_of_int_le_iff[symmetric] by simp
   901       { have "n = \<lfloor>log 2 (2^nat n)\<rfloor>"
   902           using `0 \<le> n` by (simp add: log_nat_power)
   903         also have "\<dots> \<le> \<lfloor>log 2 (x - 1)\<rfloor>"
   904           using `2^nat n \<le> real (x - 1)` `0 \<le> n` `2 \<le> x` by (auto intro: floor_mono)
   905         finally have "n \<le> \<lfloor>log 2 (x - 1)\<rfloor>" . }
   906       moreover have "\<lfloor>log 2 (x - 1)\<rfloor> \<le> n"
   907         using `2 \<le> x` by (auto simp add: n_def intro!: floor_mono)
   908       ultimately show "\<lfloor>log 2 (x - x mod 2)\<rfloor> = \<lfloor>log 2 x\<rfloor>"
   909         unfolding n_def `x mod 2 = 1` by auto
   910     qed
   911     finally have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 x\<rfloor>" . }
   912   moreover
   913   { assume "x < 2" "0 < x"
   914     then have "x = 1" by simp
   915     then have "\<lfloor>log 2 (real x)\<rfloor> = 0" by simp }
   916   ultimately show ?thesis
   917     unfolding bitlen_def
   918     by (auto simp: pos_imp_zdiv_pos_iff not_le)
   919 qed
   920 hide_fact (open) compute_bitlen
   921 
   922 lemma float_gt1_scale: assumes "1 \<le> Float m e"
   923   shows "0 \<le> e + (bitlen m - 1)"
   924 proof -
   925   have "0 < Float m e" using assms by auto
   926   hence "0 < m" using powr_gt_zero[of 2 e]
   927     by (auto simp: zero_less_mult_iff)
   928   hence "m \<noteq> 0" by auto
   929   show ?thesis
   930   proof (cases "0 \<le> e")
   931     case True thus ?thesis using `0 < m`  by (simp add: bitlen_def)
   932   next
   933     have "(1::int) < 2" by simp
   934     case False let ?S = "2^(nat (-e))"
   935     have "inverse (2 ^ nat (- e)) = 2 powr e" using assms False powr_realpow[of 2 "nat (-e)"]
   936       by (auto simp: powr_minus field_simps)
   937     hence "1 \<le> real m * inverse ?S" using assms False powr_realpow[of 2 "nat (-e)"]
   938       by (auto simp: powr_minus)
   939     hence "1 * ?S \<le> real m * inverse ?S * ?S" by (rule mult_right_mono, auto)
   940     hence "?S \<le> real m" unfolding mult.assoc by auto
   941     hence "?S \<le> m" unfolding real_of_int_le_iff[symmetric] by auto
   942     from this bitlen_bounds[OF `0 < m`, THEN conjunct2]
   943     have "nat (-e) < (nat (bitlen m))" unfolding power_strict_increasing_iff[OF `1 < 2`, symmetric]
   944       by (rule order_le_less_trans)
   945     hence "-e < bitlen m" using False by auto
   946     thus ?thesis by auto
   947   qed
   948 qed
   949 
   950 lemma bitlen_div:
   951   assumes "0 < m"
   952   shows "1 \<le> real m / 2^nat (bitlen m - 1)" and "real m / 2^nat (bitlen m - 1) < 2"
   953 proof -
   954   let ?B = "2^nat(bitlen m - 1)"
   955 
   956   have "?B \<le> m" using bitlen_bounds[OF `0 <m`] ..
   957   hence "1 * ?B \<le> real m" unfolding real_of_int_le_iff[symmetric] by auto
   958   thus "1 \<le> real m / ?B" by auto
   959 
   960   have "m \<noteq> 0" using assms by auto
   961   have "0 \<le> bitlen m - 1" using `0 < m` by (auto simp: bitlen_def)
   962 
   963   have "m < 2^nat(bitlen m)" using bitlen_bounds[OF `0 <m`] ..
   964   also have "\<dots> = 2^nat(bitlen m - 1 + 1)" using `0 < m` by (auto simp: bitlen_def)
   965   also have "\<dots> = ?B * 2" unfolding nat_add_distrib[OF `0 \<le> bitlen m - 1` zero_le_one] by auto
   966   finally have "real m < 2 * ?B" unfolding real_of_int_less_iff[symmetric] by auto
   967   hence "real m / ?B < 2 * ?B / ?B" by (rule divide_strict_right_mono, auto)
   968   thus "real m / ?B < 2" by auto
   969 qed
   970 
   971 subsection {* Truncating Real Numbers*}
   972 
   973 definition truncate_down::"nat \<Rightarrow> real \<Rightarrow> real" where
   974   "truncate_down prec x = round_down (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x"
   975 
   976 lemma truncate_down: "truncate_down prec x \<le> x"
   977   using round_down by (simp add: truncate_down_def)
   978 
   979 lemma truncate_down_le: "x \<le> y \<Longrightarrow> truncate_down prec x \<le> y"
   980   by (rule order_trans[OF truncate_down])
   981 
   982 lemma truncate_down_zero[simp]: "truncate_down prec 0 = 0"
   983   by (simp add: truncate_down_def)
   984 
   985 lemma truncate_down_float[simp]: "truncate_down p x \<in> float"
   986   by (auto simp: truncate_down_def)
   987 
   988 definition truncate_up::"nat \<Rightarrow> real \<Rightarrow> real" where
   989   "truncate_up prec x = round_up (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x"
   990 
   991 lemma truncate_up: "x \<le> truncate_up prec x"
   992   using round_up by (simp add: truncate_up_def)
   993 
   994 lemma truncate_up_le: "x \<le> y \<Longrightarrow> x \<le> truncate_up prec y"
   995   by (rule order_trans[OF _ truncate_up])
   996 
   997 lemma truncate_up_zero[simp]: "truncate_up prec 0 = 0"
   998   by (simp add: truncate_up_def)
   999 
  1000 lemma truncate_up_uminus_eq: "truncate_up prec (-x) = - truncate_down prec x"
  1001   and truncate_down_uminus_eq: "truncate_down prec (-x) = - truncate_up prec x"
  1002   by (auto simp: truncate_up_def round_up_def truncate_down_def round_down_def ceiling_def)
  1003 
  1004 lemma truncate_up_float[simp]: "truncate_up p x \<in> float"
  1005   by (auto simp: truncate_up_def)
  1006 
  1007 lemma mult_powr_eq: "0 < b \<Longrightarrow> b \<noteq> 1 \<Longrightarrow> 0 < x \<Longrightarrow> x * b powr y = b powr (y + log b x)"
  1008   by (simp_all add: powr_add)
  1009 
  1010 lemma truncate_down_pos:
  1011   assumes "x > 0" "p > 0"
  1012   shows "truncate_down p x > 0"
  1013 proof -
  1014   have "0 \<le> log 2 x - real \<lfloor>log 2 x\<rfloor>"
  1015     by (simp add: algebra_simps)
  1016   from this assms
  1017   show ?thesis
  1018     by (auto simp: truncate_down_def round_down_def mult_powr_eq
  1019       intro!: ge_one_powr_ge_zero mult_pos_pos)
  1020 qed
  1021 
  1022 lemma truncate_down_nonneg: "0 \<le> y \<Longrightarrow> 0 \<le> truncate_down prec y"
  1023   by (auto simp: truncate_down_def round_down_def)
  1024 
  1025 lemma truncate_down_ge1: "1 \<le> x \<Longrightarrow> 1 \<le> p \<Longrightarrow> 1 \<le> truncate_down p x"
  1026   by (auto simp: truncate_down_def algebra_simps intro!: round_down_ge1 add_mono)
  1027 
  1028 lemma truncate_up_nonpos: "x \<le> 0 \<Longrightarrow> truncate_up prec x \<le> 0"
  1029   by (auto simp: truncate_up_def round_up_def intro!: mult_nonpos_nonneg)
  1030 
  1031 lemma truncate_up_le1:
  1032   assumes "x \<le> 1" "1 \<le> p" shows "truncate_up p x \<le> 1"
  1033 proof -
  1034   {
  1035     assume "x \<le> 0"
  1036     with truncate_up_nonpos[OF this, of p] have ?thesis by simp
  1037   } moreover {
  1038     assume "x > 0"
  1039     hence le: "\<lfloor>log 2 \<bar>x\<bar>\<rfloor> \<le> 0"
  1040       using assms by (auto simp: log_less_iff)
  1041     from assms have "1 \<le> int p" by simp
  1042     from add_mono[OF this le]
  1043     have ?thesis using assms
  1044       by (simp add: truncate_up_def round_up_le1 add_mono)
  1045   } ultimately show ?thesis by arith
  1046 qed
  1047 
  1048 subsection {* Truncating Floats*}
  1049 
  1050 lift_definition float_round_up :: "nat \<Rightarrow> float \<Rightarrow> float" is truncate_up
  1051   by (simp add: truncate_up_def)
  1052 
  1053 lemma float_round_up: "real x \<le> real (float_round_up prec x)"
  1054   using truncate_up by transfer simp
  1055 
  1056 lemma float_round_up_zero[simp]: "float_round_up prec 0 = 0"
  1057   by transfer simp
  1058 
  1059 lift_definition float_round_down :: "nat \<Rightarrow> float \<Rightarrow> float" is truncate_down
  1060   by (simp add: truncate_down_def)
  1061 
  1062 lemma float_round_down: "real (float_round_down prec x) \<le> real x"
  1063   using truncate_down by transfer simp
  1064 
  1065 lemma float_round_down_zero[simp]: "float_round_down prec 0 = 0"
  1066   by transfer simp
  1067 
  1068 lemmas float_round_up_le = order_trans[OF _ float_round_up]
  1069   and float_round_down_le = order_trans[OF float_round_down]
  1070 
  1071 lemma minus_float_round_up_eq: "- float_round_up prec x = float_round_down prec (- x)"
  1072   and minus_float_round_down_eq: "- float_round_down prec x = float_round_up prec (- x)"
  1073   by (transfer, simp add: truncate_down_uminus_eq truncate_up_uminus_eq)+
  1074 
  1075 lemma compute_float_round_down[code]:
  1076   "float_round_down prec (Float m e) = (let d = bitlen (abs m) - int prec in
  1077     if 0 < d then Float (div_twopow m (nat d)) (e + d)
  1078              else Float m e)"
  1079   using Float.compute_float_down[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1080   by transfer (simp add: field_simps abs_mult log_mult bitlen_def truncate_down_def
  1081     cong del: if_weak_cong)
  1082 hide_fact (open) compute_float_round_down
  1083 
  1084 lemma compute_float_round_up[code]:
  1085   "float_round_up prec x = - float_round_down prec (-x)"
  1086   by transfer (simp add: truncate_down_uminus_eq)
  1087 hide_fact (open) compute_float_round_up
  1088 
  1089 
  1090 subsection {* Approximation of positive rationals *}
  1091 
  1092 lemma div_mult_twopow_eq: fixes a b::nat shows "a div ((2::nat) ^ n) div b = a div (b * 2 ^ n)"
  1093   by (cases "b=0") (simp_all add: div_mult2_eq[symmetric] ac_simps)
  1094 
  1095 lemma real_div_nat_eq_floor_of_divide:
  1096   fixes a b :: nat
  1097   shows "a div b = real \<lfloor>a / b\<rfloor>"
  1098   by (simp add: floor_divide_of_nat_eq [of a b] real_eq_of_nat)
  1099 
  1100 definition "rat_precision prec x y = int prec - (bitlen x - bitlen y)"
  1101 
  1102 lift_definition lapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
  1103   is "\<lambda>prec (x::nat) (y::nat). round_down (rat_precision prec x y) (x / y)" by simp
  1104 
  1105 lemma compute_lapprox_posrat[code]:
  1106   fixes prec x y
  1107   shows "lapprox_posrat prec x y =
  1108    (let
  1109        l = rat_precision prec x y;
  1110        d = if 0 \<le> l then x * 2^nat l div y else x div 2^nat (- l) div y
  1111     in normfloat (Float d (- l)))"
  1112     unfolding div_mult_twopow_eq
  1113     by transfer
  1114        (simp add: round_down_def powr_int real_div_nat_eq_floor_of_divide field_simps Let_def
  1115              del: two_powr_minus_int_float)
  1116 hide_fact (open) compute_lapprox_posrat
  1117 
  1118 lift_definition rapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
  1119   is "\<lambda>prec (x::nat) (y::nat). round_up (rat_precision prec x y) (x / y)" by simp
  1120 
  1121 lemma compute_rapprox_posrat[code]:
  1122   fixes prec x y
  1123   notes divmod_int_mod_div[simp]
  1124   defines "l \<equiv> rat_precision prec x y"
  1125   shows "rapprox_posrat prec x y = (let
  1126      l = l ;
  1127      X = if 0 \<le> l then (x * 2^nat l, y) else (x, y * 2^nat(-l)) ;
  1128      (d, m) = divmod_int (fst X) (snd X)
  1129    in normfloat (Float (d + (if m = 0 \<or> y = 0 then 0 else 1)) (- l)))"
  1130 proof (cases "y = 0")
  1131   assume "y = 0" thus ?thesis by transfer simp
  1132 next
  1133   assume "y \<noteq> 0"
  1134   show ?thesis
  1135   proof (cases "0 \<le> l")
  1136     assume "0 \<le> l"
  1137     def x' \<equiv> "x * 2 ^ nat l"
  1138     have "int x * 2 ^ nat l = x'" by (simp add: x'_def int_mult int_power)
  1139     moreover have "real x * 2 powr real l = real x'"
  1140       by (simp add: powr_realpow[symmetric] `0 \<le> l` x'_def)
  1141     ultimately show ?thesis
  1142       using ceil_divide_floor_conv[of y x'] powr_realpow[of 2 "nat l"] `0 \<le> l` `y \<noteq> 0`
  1143         l_def[symmetric, THEN meta_eq_to_obj_eq]
  1144       by transfer (auto simp add: floor_divide_eq_div [symmetric] round_up_def)
  1145    next
  1146     assume "\<not> 0 \<le> l"
  1147     def y' \<equiv> "y * 2 ^ nat (- l)"
  1148     from `y \<noteq> 0` have "y' \<noteq> 0" by (simp add: y'_def)
  1149     have "int y * 2 ^ nat (- l) = y'" by (simp add: y'_def int_mult int_power)
  1150     moreover have "real x * real (2::int) powr real l / real y = x / real y'"
  1151       using `\<not> 0 \<le> l`
  1152       by (simp add: powr_realpow[symmetric] powr_minus y'_def field_simps)
  1153     ultimately show ?thesis
  1154       using ceil_divide_floor_conv[of y' x] `\<not> 0 \<le> l` `y' \<noteq> 0` `y \<noteq> 0`
  1155         l_def[symmetric, THEN meta_eq_to_obj_eq]
  1156       by transfer
  1157          (auto simp add: round_up_def ceil_divide_floor_conv floor_divide_eq_div [symmetric])
  1158   qed
  1159 qed
  1160 hide_fact (open) compute_rapprox_posrat
  1161 
  1162 lemma rat_precision_pos:
  1163   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
  1164   shows "rat_precision n (int x) (int y) > 0"
  1165 proof -
  1166   { assume "0 < x" hence "log 2 x + 1 = log 2 (2 * x)" by (simp add: log_mult) }
  1167   hence "bitlen (int x) < bitlen (int y)" using assms
  1168     by (simp add: bitlen_def del: floor_add_one)
  1169       (auto intro!: floor_mono simp add: floor_add_one[symmetric] simp del: floor_add floor_add_one)
  1170   thus ?thesis
  1171     using assms by (auto intro!: pos_add_strict simp add: field_simps rat_precision_def)
  1172 qed
  1173 
  1174 lemma rapprox_posrat_less1:
  1175   shows "0 \<le> x \<Longrightarrow> 0 < y \<Longrightarrow> 2 * x < y \<Longrightarrow> 0 < n \<Longrightarrow> real (rapprox_posrat n x y) < 1"
  1176   by transfer (simp add: rat_precision_pos round_up_less1)
  1177 
  1178 lift_definition lapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
  1179   "\<lambda>prec (x::int) (y::int). round_down (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
  1180 
  1181 lemma compute_lapprox_rat[code]:
  1182   "lapprox_rat prec x y =
  1183     (if y = 0 then 0
  1184     else if 0 \<le> x then
  1185       (if 0 < y then lapprox_posrat prec (nat x) (nat y)
  1186       else - (rapprox_posrat prec (nat x) (nat (-y))))
  1187       else (if 0 < y
  1188         then - (rapprox_posrat prec (nat (-x)) (nat y))
  1189         else lapprox_posrat prec (nat (-x)) (nat (-y))))"
  1190   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
  1191 hide_fact (open) compute_lapprox_rat
  1192 
  1193 lift_definition rapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
  1194   "\<lambda>prec (x::int) (y::int). round_up (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
  1195 
  1196 lemma "rapprox_rat = rapprox_posrat"
  1197   by transfer auto
  1198 
  1199 lemma "lapprox_rat = lapprox_posrat"
  1200   by transfer auto
  1201 
  1202 lemma compute_rapprox_rat[code]:
  1203   "rapprox_rat prec x y = - lapprox_rat prec (-x) y"
  1204   by transfer (simp add: round_down_uminus_eq)
  1205 hide_fact (open) compute_rapprox_rat
  1206 
  1207 subsection {* Division *}
  1208 
  1209 definition "real_divl prec a b = round_down (int prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)"
  1210 
  1211 definition "real_divr prec a b = round_up (int prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)"
  1212 
  1213 lift_definition float_divl :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is real_divl
  1214   by (simp add: real_divl_def)
  1215 
  1216 lemma compute_float_divl[code]:
  1217   "float_divl prec (Float m1 s1) (Float m2 s2) = lapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
  1218 proof cases
  1219   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
  1220   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
  1221   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
  1222   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
  1223     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
  1224   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
  1225     by (simp add: field_simps powr_divide2[symmetric])
  1226 
  1227   show ?thesis
  1228     using not_0
  1229     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_down_shift real_divl_def,
  1230       simp add: field_simps)
  1231 qed (transfer, auto simp: real_divl_def)
  1232 hide_fact (open) compute_float_divl
  1233 
  1234 lift_definition float_divr :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is real_divr
  1235   by (simp add: real_divr_def)
  1236 
  1237 lemma compute_float_divr[code]:
  1238   "float_divr prec x y = - float_divl prec (-x) y"
  1239   by transfer (simp add: real_divr_def real_divl_def round_down_uminus_eq)
  1240 hide_fact (open) compute_float_divr
  1241 
  1242 
  1243 subsection {* Approximate Power *}
  1244 
  1245 lemma div2_less_self[termination_simp]: fixes n::nat shows "odd n \<Longrightarrow> n div 2 < n"
  1246   by (simp add: odd_pos)
  1247 
  1248 fun power_down :: "nat \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> real" where
  1249   "power_down p x 0 = 1"
  1250 | "power_down p x (Suc n) =
  1251     (if odd n then truncate_down (Suc p) ((power_down p x (Suc n div 2))\<^sup>2) else truncate_down (Suc p) (x * power_down p x n))"
  1252 
  1253 fun power_up :: "nat \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> real" where
  1254   "power_up p x 0 = 1"
  1255 | "power_up p x (Suc n) =
  1256     (if odd n then truncate_up p ((power_up p x (Suc n div 2))\<^sup>2) else truncate_up p (x * power_up p x n))"
  1257 
  1258 lift_definition power_up_fl :: "nat \<Rightarrow> float \<Rightarrow> nat \<Rightarrow> float" is power_up
  1259   by (induct_tac rule: power_up.induct) simp_all
  1260 
  1261 lift_definition power_down_fl :: "nat \<Rightarrow> float \<Rightarrow> nat \<Rightarrow> float" is power_down
  1262   by (induct_tac rule: power_down.induct) simp_all
  1263 
  1264 lemma power_float_transfer[transfer_rule]:
  1265   "(rel_fun pcr_float (rel_fun op = pcr_float)) op ^ op ^"
  1266   unfolding power_def
  1267   by transfer_prover
  1268 
  1269 lemma compute_power_up_fl[code]:
  1270   "power_up_fl p x 0 = 1"
  1271   "power_up_fl p x (Suc n) =
  1272     (if odd n then float_round_up p ((power_up_fl p x (Suc n div 2))\<^sup>2) else float_round_up p (x * power_up_fl p x n))"
  1273   and compute_power_down_fl[code]:
  1274   "power_down_fl p x 0 = 1"
  1275   "power_down_fl p x (Suc n) =
  1276     (if odd n then float_round_down (Suc p) ((power_down_fl p x (Suc n div 2))\<^sup>2) else float_round_down (Suc p) (x * power_down_fl p x n))"
  1277   unfolding atomize_conj
  1278   by transfer simp
  1279 
  1280 lemma power_down_pos: "0 < x \<Longrightarrow> 0 < power_down p x n"
  1281   by (induct p x n rule: power_down.induct)
  1282     (auto simp del: odd_Suc_div_two intro!: truncate_down_pos)
  1283 
  1284 lemma power_down_nonneg: "0 \<le> x \<Longrightarrow> 0 \<le> power_down p x n"
  1285   by (induct p x n rule: power_down.induct)
  1286     (auto simp del: odd_Suc_div_two intro!: truncate_down_nonneg mult_nonneg_nonneg)
  1287 
  1288 lemma power_down: "0 \<le> x \<Longrightarrow> power_down p x n \<le> x ^ n"
  1289 proof (induct p x n rule: power_down.induct)
  1290   case (2 p x n)
  1291   {
  1292     assume "odd n"
  1293     hence "(power_down p x (Suc n div 2)) ^ 2 \<le> (x ^ (Suc n div 2)) ^ 2"
  1294       using 2
  1295       by (auto intro: power_mono power_down_nonneg simp del: odd_Suc_div_two)
  1296     also have "\<dots> = x ^ (Suc n div 2 * 2)"
  1297       by (simp add: power_mult[symmetric])
  1298     also have "Suc n div 2 * 2 = Suc n"
  1299       using `odd n` by presburger
  1300     finally have ?case
  1301       using `odd n`
  1302       by (auto intro!: truncate_down_le simp del: odd_Suc_div_two)
  1303   } thus ?case
  1304     by (auto intro!: truncate_down_le mult_left_mono 2 mult_nonneg_nonneg power_down_nonneg)
  1305 qed simp
  1306 
  1307 lemma power_up: "0 \<le> x \<Longrightarrow> x ^ n \<le> power_up p x n"
  1308 proof (induct p x n rule: power_up.induct)
  1309   case (2 p x n)
  1310   {
  1311     assume "odd n"
  1312     hence "Suc n = Suc n div 2 * 2"
  1313       using `odd n` even_Suc by presburger
  1314     hence "x ^ Suc n \<le> (x ^ (Suc n div 2))\<^sup>2"
  1315       by (simp add: power_mult[symmetric])
  1316     also have "\<dots> \<le> (power_up p x (Suc n div 2))\<^sup>2"
  1317       using 2 `odd n`
  1318       by (auto intro: power_mono simp del: odd_Suc_div_two )
  1319     finally have ?case
  1320       using `odd n`
  1321       by (auto intro!: truncate_up_le simp del: odd_Suc_div_two )
  1322   } thus ?case
  1323     by (auto intro!: truncate_up_le mult_left_mono 2)
  1324 qed simp
  1325 
  1326 lemmas power_up_le = order_trans[OF _ power_up]
  1327   and power_up_less = less_le_trans[OF _ power_up]
  1328   and power_down_le = order_trans[OF power_down]
  1329 
  1330 lemma power_down_fl: "0 \<le> x \<Longrightarrow> power_down_fl p x n \<le> x ^ n"
  1331   by transfer (rule power_down)
  1332 
  1333 lemma power_up_fl: "0 \<le> x \<Longrightarrow> x ^ n \<le> power_up_fl p x n"
  1334   by transfer (rule power_up)
  1335 
  1336 lemma real_power_up_fl: "real (power_up_fl p x n) = power_up p x n"
  1337   by transfer simp
  1338 
  1339 lemma real_power_down_fl: "real (power_down_fl p x n) = power_down p x n"
  1340   by transfer simp
  1341 
  1342 
  1343 subsection {* Approximate Addition *}
  1344 
  1345 definition "plus_down prec x y = truncate_down prec (x + y)"
  1346 
  1347 definition "plus_up prec x y = truncate_up prec (x + y)"
  1348 
  1349 lemma float_plus_down_float[intro, simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> plus_down p x y \<in> float"
  1350   by (simp add: plus_down_def)
  1351 
  1352 lemma float_plus_up_float[intro, simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> plus_up p x y \<in> float"
  1353   by (simp add: plus_up_def)
  1354 
  1355 lift_definition float_plus_down::"nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is plus_down ..
  1356 
  1357 lift_definition float_plus_up::"nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is plus_up ..
  1358 
  1359 lemma plus_down: "plus_down prec x y \<le> x + y"
  1360   and plus_up: "x + y \<le> plus_up prec x y"
  1361   by (auto simp: plus_down_def truncate_down plus_up_def truncate_up)
  1362 
  1363 lemma float_plus_down: "real (float_plus_down prec x y) \<le> x + y"
  1364   and float_plus_up: "x + y \<le> real (float_plus_up prec x y)"
  1365   by (transfer, rule plus_down plus_up)+
  1366 
  1367 lemmas plus_down_le = order_trans[OF plus_down]
  1368   and plus_up_le = order_trans[OF _ plus_up]
  1369   and float_plus_down_le = order_trans[OF float_plus_down]
  1370   and float_plus_up_le = order_trans[OF _ float_plus_up]
  1371 
  1372 lemma compute_plus_up[code]: "plus_up p x y = - plus_down p (-x) (-y)"
  1373   using truncate_down_uminus_eq[of p "x + y"]
  1374   by (auto simp: plus_down_def plus_up_def)
  1375 
  1376 lemma
  1377   truncate_down_log2_eqI:
  1378   assumes "\<lfloor>log 2 \<bar>x\<bar>\<rfloor> = \<lfloor>log 2 \<bar>y\<bar>\<rfloor>"
  1379   assumes "\<lfloor>x * 2 powr (p - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1)\<rfloor> = \<lfloor>y * 2 powr (p - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1)\<rfloor>"
  1380   shows "truncate_down p x = truncate_down p y"
  1381   using assms by (auto simp: truncate_down_def round_down_def)
  1382 
  1383 lemma bitlen_eq_zero_iff: "bitlen x = 0 \<longleftrightarrow> x \<le> 0"
  1384   by (clarsimp simp add: bitlen_def)
  1385     (metis Float.compute_bitlen add.commute bitlen_def bitlen_nonneg less_add_same_cancel2 not_less
  1386       zero_less_one)
  1387 
  1388 lemma
  1389   sum_neq_zeroI:
  1390   fixes a k::real
  1391   shows "abs a \<ge> k \<Longrightarrow> abs b < k \<Longrightarrow> a + b \<noteq> 0"
  1392     and "abs a > k \<Longrightarrow> abs b \<le> k \<Longrightarrow> a + b \<noteq> 0"
  1393   by auto
  1394 
  1395 lemma
  1396   abs_real_le_2_powr_bitlen[simp]:
  1397   "\<bar>real m2\<bar> < 2 powr real (bitlen \<bar>m2\<bar>)"
  1398 proof cases
  1399   assume "m2 \<noteq> 0"
  1400   hence "\<bar>m2\<bar> < 2 ^ nat (bitlen \<bar>m2\<bar>)"
  1401     using bitlen_bounds[of "\<bar>m2\<bar>"]
  1402     by (auto simp: powr_add bitlen_nonneg)
  1403   thus ?thesis
  1404     by (simp add: powr_int bitlen_nonneg real_of_int_less_iff[symmetric])
  1405 qed simp
  1406 
  1407 lemma floor_sum_times_2_powr_sgn_eq:
  1408   fixes ai p q::int
  1409   and a b::real
  1410   assumes "a * 2 powr p = ai"
  1411   assumes b_le_1: "abs (b * 2 powr (p + 1)) \<le> 1"
  1412   assumes leqp: "q \<le> p"
  1413   shows "\<lfloor>(a + b) * 2 powr q\<rfloor> = \<lfloor>(2 * ai + sgn b) * 2 powr (q - p - 1)\<rfloor>"
  1414 proof -
  1415   {
  1416     assume "b = 0"
  1417     hence ?thesis
  1418       by (simp add: assms(1)[symmetric] powr_add[symmetric] algebra_simps powr_mult_base)
  1419   } moreover {
  1420     assume "b > 0"
  1421     hence "b * 2 powr p < abs (b * 2 powr (p + 1))" by simp
  1422     also note b_le_1
  1423     finally have b_less_1: "b * 2 powr real p < 1" .
  1424 
  1425     from b_less_1 `b > 0` have floor_eq: "\<lfloor>b * 2 powr real p\<rfloor> = 0" "\<lfloor>sgn b / 2\<rfloor> = 0"
  1426       by (simp_all add: floor_eq_iff)
  1427 
  1428     have "\<lfloor>(a + b) * 2 powr q\<rfloor> = \<lfloor>(a + b) * 2 powr p * 2 powr (q - p)\<rfloor>"
  1429       by (simp add: algebra_simps powr_realpow[symmetric] powr_add[symmetric])
  1430     also have "\<dots> = \<lfloor>(ai + b * 2 powr p) * 2 powr (q - p)\<rfloor>"
  1431       by (simp add: assms algebra_simps)
  1432     also have "\<dots> = \<lfloor>(ai + b * 2 powr p) / real ((2::int) ^ nat (p - q))\<rfloor>"
  1433       using assms
  1434       by (simp add: algebra_simps powr_realpow[symmetric] divide_powr_uminus powr_add[symmetric])
  1435     also have "\<dots> = \<lfloor>ai / real ((2::int) ^ nat (p - q))\<rfloor>"
  1436       by (simp del: real_of_int_power add: floor_divide_real_eq_div floor_eq)
  1437     finally have "\<lfloor>(a + b) * 2 powr real q\<rfloor> = \<lfloor>real ai / real ((2::int) ^ nat (p - q))\<rfloor>" .
  1438     moreover
  1439     {
  1440       have "\<lfloor>(2 * ai + sgn b) * 2 powr (real (q - p) - 1)\<rfloor> = \<lfloor>(ai + sgn b / 2) * 2 powr (q - p)\<rfloor>"
  1441         by (subst powr_divide2[symmetric]) (simp add: field_simps)
  1442       also have "\<dots> = \<lfloor>(ai + sgn b / 2) / real ((2::int) ^ nat (p - q))\<rfloor>"
  1443         using leqp by (simp add: powr_realpow[symmetric] powr_divide2[symmetric])
  1444       also have "\<dots> = \<lfloor>ai / real ((2::int) ^ nat (p - q))\<rfloor>"
  1445         by (simp del: real_of_int_power add: floor_divide_real_eq_div floor_eq)
  1446       finally
  1447       have "\<lfloor>(2 * ai + (sgn b)) * 2 powr (real (q - p) - 1)\<rfloor> =
  1448           \<lfloor>real ai / real ((2::int) ^ nat (p - q))\<rfloor>"
  1449         .
  1450     } ultimately have ?thesis by simp
  1451   } moreover {
  1452     assume "\<not> 0 \<le> b"
  1453     hence "0 > b" by simp
  1454     hence floor_eq: "\<lfloor>b * 2 powr (real p + 1)\<rfloor> = -1"
  1455       using b_le_1
  1456       by (auto simp: floor_eq_iff algebra_simps pos_divide_le_eq[symmetric] abs_if divide_powr_uminus
  1457         intro!: mult_neg_pos split: split_if_asm)
  1458     have "\<lfloor>(a + b) * 2 powr q\<rfloor> = \<lfloor>(2*a + 2*b) * 2 powr p * 2 powr (q - p - 1)\<rfloor>"
  1459       by (simp add: algebra_simps powr_realpow[symmetric] powr_add[symmetric] powr_mult_base)
  1460     also have "\<dots> = \<lfloor>(2 * (a * 2 powr p) + 2 * b * 2 powr p) * 2 powr (q - p - 1)\<rfloor>"
  1461       by (simp add: algebra_simps)
  1462     also have "\<dots> = \<lfloor>(2 * ai + b * 2 powr (p + 1)) / 2 powr (1 - q + p)\<rfloor>"
  1463       using assms by (simp add: algebra_simps powr_mult_base divide_powr_uminus)
  1464     also have "\<dots> = \<lfloor>(2 * ai + b * 2 powr (p + 1)) / real ((2::int) ^ nat (p - q + 1))\<rfloor>"
  1465       using assms by (simp add: algebra_simps powr_realpow[symmetric])
  1466     also have "\<dots> = \<lfloor>(2 * ai - 1) / real ((2::int) ^ nat (p - q + 1))\<rfloor>"
  1467       using `b < 0` assms
  1468       by (simp add: floor_divide_eq_div floor_eq floor_divide_real_eq_div
  1469         del: real_of_int_mult real_of_int_power real_of_int_diff)
  1470     also have "\<dots> = \<lfloor>(2 * ai - 1) * 2 powr (q - p - 1)\<rfloor>"
  1471       using assms by (simp add: algebra_simps divide_powr_uminus powr_realpow[symmetric])
  1472     finally have ?thesis using `b < 0` by simp
  1473   } ultimately show ?thesis by arith
  1474 qed
  1475 
  1476 lemma
  1477   log2_abs_int_add_less_half_sgn_eq:
  1478   fixes ai::int and b::real
  1479   assumes "abs b \<le> 1/2" "ai \<noteq> 0"
  1480   shows "\<lfloor>log 2 \<bar>real ai + b\<bar>\<rfloor> = \<lfloor>log 2 \<bar>ai + sgn b / 2\<bar>\<rfloor>"
  1481 proof cases
  1482   assume "b = 0" thus ?thesis by simp
  1483 next
  1484   assume "b \<noteq> 0"
  1485   def k \<equiv> "\<lfloor>log 2 \<bar>ai\<bar>\<rfloor>"
  1486   hence "\<lfloor>log 2 \<bar>ai\<bar>\<rfloor> = k" by simp
  1487   hence k: "2 powr k \<le> \<bar>ai\<bar>" "\<bar>ai\<bar> < 2 powr (k + 1)"
  1488     by (simp_all add: floor_log_eq_powr_iff `ai \<noteq> 0`)
  1489   have "k \<ge> 0"
  1490     using assms by (auto simp: k_def)
  1491   def r \<equiv> "\<bar>ai\<bar> - 2 ^ nat k"
  1492   have r: "0 \<le> r" "r < 2 powr k"
  1493     using `k \<ge> 0` k
  1494     by (auto simp: r_def k_def algebra_simps powr_add abs_if powr_int)
  1495   hence "r \<le> (2::int) ^ nat k - 1"
  1496     using `k \<ge> 0` by (auto simp: powr_int)
  1497   from this[simplified real_of_int_le_iff[symmetric]] `0 \<le> k`
  1498   have r_le: "r \<le> 2 powr k - 1"
  1499     by (auto simp: algebra_simps powr_int simp del: real_of_int_le_iff)
  1500 
  1501   have "\<bar>ai\<bar> = 2 powr k + r"
  1502     using `k \<ge> 0` by (auto simp: k_def r_def powr_realpow[symmetric])
  1503 
  1504   have pos: "\<And>b::real. abs b < 1 \<Longrightarrow> 0 < 2 powr k + (r + b)"
  1505     using `0 \<le> k` `ai \<noteq> 0`
  1506     by (auto simp add: r_def powr_realpow[symmetric] abs_if sgn_if algebra_simps
  1507       split: split_if_asm)
  1508   have less: "\<bar>sgn ai * b\<bar> < 1"
  1509     and less': "\<bar>sgn (sgn ai * b) / 2\<bar> < 1"
  1510     using `abs b \<le> _` by (auto simp: abs_if sgn_if split: split_if_asm)
  1511 
  1512   have floor_eq: "\<And>b::real. abs b \<le> 1 / 2 \<Longrightarrow>
  1513       \<lfloor>log 2 (1 + (r + b) / 2 powr k)\<rfloor> = (if r = 0 \<and> b < 0 then -1 else 0)"
  1514     using `k \<ge> 0` r r_le
  1515     by (auto simp: floor_log_eq_powr_iff powr_minus_divide field_simps sgn_if)
  1516 
  1517   from `real \<bar>ai\<bar> = _` have "\<bar>ai + b\<bar> = 2 powr k + (r + sgn ai * b)"
  1518     using `abs b <= _` `0 \<le> k` r
  1519     by (auto simp add: sgn_if abs_if)
  1520   also have "\<lfloor>log 2 \<dots>\<rfloor> = \<lfloor>log 2 (2 powr k + r + sgn (sgn ai * b) / 2)\<rfloor>"
  1521   proof -
  1522     have "2 powr k + (r + (sgn ai) * b) = 2 powr k * (1 + (r + sgn ai * b) / 2 powr k)"
  1523       by (simp add: field_simps)
  1524     also have "\<lfloor>log 2 \<dots>\<rfloor> = k + \<lfloor>log 2 (1 + (r + sgn ai * b) / 2 powr k)\<rfloor>"
  1525       using pos[OF less]
  1526       by (subst log_mult) (simp_all add: log_mult powr_mult field_simps)
  1527     also
  1528     let ?if = "if r = 0 \<and> sgn ai * b < 0 then -1 else 0"
  1529     have "\<lfloor>log 2 (1 + (r + sgn ai * b) / 2 powr k)\<rfloor> = ?if"
  1530       using `abs b <= _`
  1531       by (intro floor_eq) (auto simp: abs_mult sgn_if)
  1532     also
  1533     have "\<dots> = \<lfloor>log 2 (1 + (r + sgn (sgn ai * b) / 2) / 2 powr k)\<rfloor>"
  1534       by (subst floor_eq) (auto simp: sgn_if)
  1535     also have "k + \<dots> = \<lfloor>log 2 (2 powr k * (1 + (r + sgn (sgn ai * b) / 2) / 2 powr k))\<rfloor>"
  1536       unfolding floor_add2[symmetric]
  1537       using pos[OF less'] `abs b \<le> _`
  1538       by (simp add: field_simps add_log_eq_powr)
  1539     also have "2 powr k * (1 + (r + sgn (sgn ai * b) / 2) / 2 powr k) =
  1540         2 powr k + r + sgn (sgn ai * b) / 2"
  1541       by (simp add: sgn_if field_simps)
  1542     finally show ?thesis .
  1543   qed
  1544   also have "2 powr k + r + sgn (sgn ai * b) / 2 = \<bar>ai + sgn b / 2\<bar>"
  1545     unfolding `real \<bar>ai\<bar> = _`[symmetric] using `ai \<noteq> 0`
  1546     by (auto simp: abs_if sgn_if algebra_simps)
  1547   finally show ?thesis .
  1548 qed
  1549 
  1550 lemma compute_far_float_plus_down:
  1551   fixes m1 e1 m2 e2::int and p::nat
  1552   defines "k1 \<equiv> p - nat (bitlen \<bar>m1\<bar>)"
  1553   assumes H: "bitlen \<bar>m2\<bar> \<le> e1 - e2 - k1 - 2" "m1 \<noteq> 0" "m2 \<noteq> 0" "e1 \<ge> e2"
  1554   shows "float_plus_down p (Float m1 e1) (Float m2 e2) =
  1555     float_round_down p (Float (m1 * 2 ^ (Suc (Suc k1)) + sgn m2) (e1 - int k1 - 2))"
  1556 proof -
  1557   let ?a = "real (Float m1 e1)"
  1558   let ?b = "real (Float m2 e2)"
  1559   let ?sum = "?a + ?b"
  1560   let ?shift = "real e2 - real e1 + real k1 + 1"
  1561   let ?m1 = "m1 * 2 ^ Suc k1"
  1562   let ?m2 = "m2 * 2 powr ?shift"
  1563   let ?m2' = "sgn m2 / 2"
  1564   let ?e = "e1 - int k1 - 1"
  1565 
  1566   have sum_eq: "?sum = (?m1 + ?m2) * 2 powr ?e"
  1567     by (auto simp: powr_add[symmetric] powr_mult[symmetric] algebra_simps
  1568       powr_realpow[symmetric] powr_mult_base)
  1569 
  1570   have "\<bar>?m2\<bar> * 2 < 2 powr (bitlen \<bar>m2\<bar> + ?shift + 1)"
  1571     by (auto simp: field_simps powr_add powr_mult_base powr_numeral powr_divide2[symmetric] abs_mult)
  1572   also have "\<dots> \<le> 2 powr 0"
  1573     using H by (intro powr_mono) auto
  1574   finally have abs_m2_less_half: "\<bar>?m2\<bar> < 1 / 2"
  1575     by simp
  1576 
  1577   hence "\<bar>real m2\<bar> < 2 powr -(?shift + 1)"
  1578     unfolding powr_minus_divide by (auto simp: bitlen_def field_simps powr_mult_base abs_mult)
  1579   also have "\<dots> \<le> 2 powr real (e1 - e2 - 2)"
  1580     by simp
  1581   finally have b_less_quarter: "\<bar>?b\<bar> < 1/4 * 2 powr real e1"
  1582     by (simp add: powr_add field_simps powr_divide2[symmetric] powr_numeral abs_mult)
  1583   also have "1/4 < \<bar>real m1\<bar> / 2" using `m1 \<noteq> 0` by simp
  1584   finally have b_less_half_a: "\<bar>?b\<bar> < 1/2 * \<bar>?a\<bar>"
  1585     by (simp add: algebra_simps powr_mult_base abs_mult)
  1586   hence a_half_less_sum: "\<bar>?a\<bar> / 2 < \<bar>?sum\<bar>"
  1587     by (auto simp: field_simps abs_if split: split_if_asm)
  1588 
  1589   from b_less_half_a have "\<bar>?b\<bar> < \<bar>?a\<bar>" "\<bar>?b\<bar> \<le> \<bar>?a\<bar>"
  1590     by simp_all
  1591 
  1592   have "\<bar>real (Float m1 e1)\<bar> \<ge> 1/4 * 2 powr real e1"
  1593     using `m1 \<noteq> 0`
  1594     by (auto simp: powr_add powr_int bitlen_nonneg divide_right_mono abs_mult)
  1595   hence "?sum \<noteq> 0" using b_less_quarter
  1596     by (rule sum_neq_zeroI)
  1597   hence "?m1 + ?m2 \<noteq> 0"
  1598     unfolding sum_eq by (simp add: abs_mult zero_less_mult_iff)
  1599 
  1600   have "\<bar>real ?m1\<bar> \<ge> 2 ^ Suc k1" "\<bar>?m2'\<bar> < 2 ^ Suc k1"
  1601     using `m1 \<noteq> 0` `m2 \<noteq> 0` by (auto simp: sgn_if less_1_mult abs_mult simp del: power.simps)
  1602   hence sum'_nz: "?m1 + ?m2' \<noteq> 0"
  1603     by (intro sum_neq_zeroI)
  1604 
  1605   have "\<lfloor>log 2 \<bar>real (Float m1 e1) + real (Float m2 e2)\<bar>\<rfloor> = \<lfloor>log 2 \<bar>?m1 + ?m2\<bar>\<rfloor> + ?e"
  1606     using `?m1 + ?m2 \<noteq> 0`
  1607     unfolding floor_add[symmetric] sum_eq
  1608     by (simp add: abs_mult log_mult)
  1609   also have "\<lfloor>log 2 \<bar>?m1 + ?m2\<bar>\<rfloor> = \<lfloor>log 2 \<bar>?m1 + sgn (real m2 * 2 powr ?shift) / 2\<bar>\<rfloor>"
  1610     using abs_m2_less_half `m1 \<noteq> 0`
  1611     by (intro log2_abs_int_add_less_half_sgn_eq) (auto simp: abs_mult)
  1612   also have "sgn (real m2 * 2 powr ?shift) = sgn m2"
  1613     by (auto simp: sgn_if zero_less_mult_iff less_not_sym)
  1614   also
  1615   have "\<bar>?m1 + ?m2'\<bar> * 2 powr ?e = \<bar>?m1 * 2 + sgn m2\<bar> * 2 powr (?e - 1)"
  1616     by (auto simp: field_simps powr_minus[symmetric] powr_divide2[symmetric] powr_mult_base)
  1617   hence "\<lfloor>log 2 \<bar>?m1 + ?m2'\<bar>\<rfloor> + ?e = \<lfloor>log 2 \<bar>real (Float (?m1 * 2 + sgn m2) (?e - 1))\<bar>\<rfloor>"
  1618     using `?m1 + ?m2' \<noteq> 0`
  1619     unfolding floor_add[symmetric]
  1620     by (simp add: log_add_eq_powr abs_mult_pos)
  1621   finally
  1622   have "\<lfloor>log 2 \<bar>?sum\<bar>\<rfloor> = \<lfloor>log 2 \<bar>real (Float (?m1*2 + sgn m2) (?e - 1))\<bar>\<rfloor>" .
  1623   hence "plus_down p (Float m1 e1) (Float m2 e2) =
  1624       truncate_down p (Float (?m1*2 + sgn m2) (?e - 1))"
  1625     unfolding plus_down_def
  1626   proof (rule truncate_down_log2_eqI)
  1627     let ?f = "(int p - \<lfloor>log 2 \<bar>real (Float m1 e1) + real (Float m2 e2)\<bar>\<rfloor> - 1)"
  1628     let ?ai = "m1 * 2 ^ (Suc k1)"
  1629     have "\<lfloor>(?a + ?b) * 2 powr real ?f\<rfloor> = \<lfloor>(real (2 * ?ai) + sgn ?b) * 2 powr real (?f - - ?e - 1)\<rfloor>"
  1630     proof (rule floor_sum_times_2_powr_sgn_eq)
  1631       show "?a * 2 powr real (-?e) = real ?ai"
  1632         by (simp add: powr_add powr_realpow[symmetric] powr_divide2[symmetric])
  1633       show "\<bar>?b * 2 powr real (-?e + 1)\<bar> \<le> 1"
  1634         using abs_m2_less_half
  1635         by (simp add: abs_mult powr_add[symmetric] algebra_simps powr_mult_base)
  1636     next
  1637       have "e1 + \<lfloor>log 2 \<bar>real m1\<bar>\<rfloor> - 1 = \<lfloor>log 2 \<bar>?a\<bar>\<rfloor> - 1"
  1638         using `m1 \<noteq> 0`
  1639         by (simp add: floor_add2[symmetric] algebra_simps log_mult abs_mult del: floor_add2)
  1640       also have "\<dots> \<le> \<lfloor>log 2 \<bar>?a + ?b\<bar>\<rfloor>"
  1641         using a_half_less_sum `m1 \<noteq> 0` `?sum \<noteq> 0`
  1642         unfolding floor_subtract[symmetric]
  1643         by (auto simp add: log_minus_eq_powr powr_minus_divide
  1644           intro!: floor_mono)
  1645       finally
  1646       have "int p - \<lfloor>log 2 \<bar>?a + ?b\<bar>\<rfloor> \<le> p - (bitlen \<bar>m1\<bar>) - e1 + 2"
  1647         by (auto simp: algebra_simps bitlen_def `m1 \<noteq> 0`)
  1648       also have "\<dots> \<le> 1 - ?e"
  1649         using bitlen_nonneg[of "\<bar>m1\<bar>"] by (simp add: k1_def)
  1650       finally show "?f \<le> - ?e" by simp
  1651     qed
  1652     also have "sgn ?b = sgn m2"
  1653       using powr_gt_zero[of 2 e2]
  1654       by (auto simp add: sgn_if zero_less_mult_iff simp del: powr_gt_zero)
  1655     also have "\<lfloor>(real (2 * ?m1) + real (sgn m2)) * 2 powr real (?f - - ?e - 1)\<rfloor> =
  1656         \<lfloor>Float (?m1 * 2 + sgn m2) (?e - 1) * 2 powr ?f\<rfloor>"
  1657       by (simp add: powr_add[symmetric] algebra_simps powr_realpow[symmetric])
  1658     finally
  1659     show "\<lfloor>(?a + ?b) * 2 powr ?f\<rfloor> = \<lfloor>real (Float (?m1 * 2 + sgn m2) (?e - 1)) * 2 powr ?f\<rfloor>" .
  1660   qed
  1661   thus ?thesis
  1662     by transfer (simp add: plus_down_def ac_simps Let_def)
  1663 qed
  1664 
  1665 lemma compute_float_plus_down_naive[code]: "float_plus_down p x y = float_round_down p (x + y)"
  1666   by transfer (auto simp: plus_down_def)
  1667 
  1668 lemma compute_float_plus_down[code]:
  1669   fixes p::nat and m1 e1 m2 e2::int
  1670   shows "float_plus_down p (Float m1 e1) (Float m2 e2) =
  1671     (if m1 = 0 then float_round_down p (Float m2 e2)
  1672     else if m2 = 0 then float_round_down p (Float m1 e1)
  1673     else (if e1 \<ge> e2 then
  1674       (let
  1675         k1 = p - nat (bitlen \<bar>m1\<bar>)
  1676       in
  1677         if bitlen \<bar>m2\<bar> > e1 - e2 - k1 - 2 then float_round_down p ((Float m1 e1) + (Float m2 e2))
  1678         else float_round_down p (Float (m1 * 2 ^ (Suc (Suc k1)) + sgn m2) (e1 - int k1 - 2)))
  1679     else float_plus_down p (Float m2 e2) (Float m1 e1)))"
  1680 proof -
  1681   {
  1682     assume H: "bitlen \<bar>m2\<bar> \<le> e1 - e2 - (p - nat (bitlen \<bar>m1\<bar>)) - 2" "m1 \<noteq> 0" "m2 \<noteq> 0" "e1 \<ge> e2"
  1683     note compute_far_float_plus_down[OF H]
  1684   }
  1685   thus ?thesis
  1686     by transfer (simp add: Let_def plus_down_def ac_simps)
  1687 qed
  1688 hide_fact (open) compute_far_float_plus_down
  1689 hide_fact (open) compute_float_plus_down
  1690 
  1691 lemma compute_float_plus_up[code]: "float_plus_up p x y = - float_plus_down p (-x) (-y)"
  1692   using truncate_down_uminus_eq[of p "x + y"]
  1693   by transfer (simp add: plus_down_def plus_up_def ac_simps)
  1694 hide_fact (open) compute_float_plus_up
  1695 
  1696 lemma mantissa_zero[simp]: "mantissa 0 = 0"
  1697 by (metis mantissa_0 zero_float.abs_eq)
  1698 
  1699 
  1700 subsection {* Lemmas needed by Approximate *}
  1701 
  1702 lemma Float_num[simp]: shows
  1703    "real (Float 1 0) = 1" and "real (Float 1 1) = 2" and "real (Float 1 2) = 4" and
  1704    "real (Float 1 (- 1)) = 1/2" and "real (Float 1 (- 2)) = 1/4" and "real (Float 1 (- 3)) = 1/8" and
  1705    "real (Float (- 1) 0) = -1" and "real (Float (number_of n) 0) = number_of n"
  1706 using two_powr_int_float[of 2] two_powr_int_float[of "-1"] two_powr_int_float[of "-2"] two_powr_int_float[of "-3"]
  1707 using powr_realpow[of 2 2] powr_realpow[of 2 3]
  1708 using powr_minus[of 2 1] powr_minus[of 2 2] powr_minus[of 2 3]
  1709 by auto
  1710 
  1711 lemma real_of_Float_int[simp]: "real (Float n 0) = real n" by simp
  1712 
  1713 lemma float_zero[simp]: "real (Float 0 e) = 0" by simp
  1714 
  1715 lemma abs_div_2_less: "a \<noteq> 0 \<Longrightarrow> a \<noteq> -1 \<Longrightarrow> abs((a::int) div 2) < abs a"
  1716 by arith
  1717 
  1718 lemma lapprox_rat:
  1719   shows "real (lapprox_rat prec x y) \<le> real x / real y"
  1720   using round_down by (simp add: lapprox_rat_def)
  1721 
  1722 lemma mult_div_le: fixes a b:: int assumes "b > 0" shows "a \<ge> b * (a div b)"
  1723 proof -
  1724   from zmod_zdiv_equality'[of a b]
  1725   have "a = b * (a div b) + a mod b" by simp
  1726   also have "... \<ge> b * (a div b) + 0" apply (rule add_left_mono) apply (rule pos_mod_sign)
  1727   using assms by simp
  1728   finally show ?thesis by simp
  1729 qed
  1730 
  1731 lemma lapprox_rat_nonneg:
  1732   fixes n x y
  1733   assumes "0 \<le> x" and "0 \<le> y"
  1734   shows "0 \<le> real (lapprox_rat n x y)"
  1735   using assms by (auto simp: lapprox_rat_def simp: round_down_nonneg)
  1736 
  1737 lemma rapprox_rat: "real x / real y \<le> real (rapprox_rat prec x y)"
  1738   using round_up by (simp add: rapprox_rat_def)
  1739 
  1740 lemma rapprox_rat_le1:
  1741   fixes n x y
  1742   assumes xy: "0 \<le> x" "0 < y" "x \<le> y"
  1743   shows "real (rapprox_rat n x y) \<le> 1"
  1744 proof -
  1745   have "bitlen \<bar>x\<bar> \<le> bitlen \<bar>y\<bar>"
  1746     using xy unfolding bitlen_def by (auto intro!: floor_mono)
  1747   from this assms show ?thesis
  1748     by transfer (auto intro!: round_up_le1 simp: rat_precision_def)
  1749 qed
  1750 
  1751 lemma rapprox_rat_nonneg_nonpos:
  1752   "0 \<le> x \<Longrightarrow> y \<le> 0 \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1753   by transfer (simp add: round_up_le0 divide_nonneg_nonpos)
  1754 
  1755 lemma rapprox_rat_nonpos_nonneg:
  1756   "x \<le> 0 \<Longrightarrow> 0 \<le> y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1757   by transfer (simp add: round_up_le0 divide_nonpos_nonneg)
  1758 
  1759 lemma real_divl: "real_divl prec x y \<le> x / y"
  1760   by (simp add: real_divl_def round_down)
  1761 
  1762 lemma real_divr: "x / y \<le> real_divr prec x y"
  1763   using round_up by (simp add: real_divr_def)
  1764 
  1765 lemma float_divl: "real (float_divl prec x y) \<le> real x / real y"
  1766   by transfer (rule real_divl)
  1767 
  1768 lemma real_divl_lower_bound:
  1769   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> 0 \<le> real_divl prec x y"
  1770   by (simp add: real_divl_def round_down_nonneg)
  1771 
  1772 lemma float_divl_lower_bound:
  1773   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> 0 \<le> real (float_divl prec x y)"
  1774   by transfer (rule real_divl_lower_bound)
  1775 
  1776 lemma exponent_1: "exponent 1 = 0"
  1777   using exponent_float[of 1 0] by (simp add: one_float_def)
  1778 
  1779 lemma mantissa_1: "mantissa 1 = 1"
  1780   using mantissa_float[of 1 0] by (simp add: one_float_def)
  1781 
  1782 lemma bitlen_1: "bitlen 1 = 1"
  1783   by (simp add: bitlen_def)
  1784 
  1785 lemma mantissa_eq_zero_iff: "mantissa x = 0 \<longleftrightarrow> x = 0"
  1786 proof
  1787   assume "mantissa x = 0" hence z: "0 = real x" using mantissa_exponent by simp
  1788   show "x = 0" by (simp add: zero_float_def z)
  1789 qed (simp add: zero_float_def)
  1790 
  1791 lemma float_upper_bound: "x \<le> 2 powr (bitlen \<bar>mantissa x\<bar> + exponent x)"
  1792 proof (cases "x = 0", simp)
  1793   assume "x \<noteq> 0" hence "mantissa x \<noteq> 0" using mantissa_eq_zero_iff by auto
  1794   have "x = mantissa x * 2 powr (exponent x)" by (rule mantissa_exponent)
  1795   also have "mantissa x \<le> \<bar>mantissa x\<bar>" by simp
  1796   also have "... \<le> 2 powr (bitlen \<bar>mantissa x\<bar>)"
  1797     using bitlen_bounds[of "\<bar>mantissa x\<bar>"] bitlen_nonneg `mantissa x \<noteq> 0`
  1798     by (auto simp del: real_of_int_abs simp add: powr_int)
  1799   finally show ?thesis by (simp add: powr_add)
  1800 qed
  1801 
  1802 lemma real_divl_pos_less1_bound:
  1803   assumes "0 < x" "x \<le> 1" "prec \<ge> 1"
  1804   shows "1 \<le> real_divl prec 1 x"
  1805 proof -
  1806   have "log 2 x \<le> real prec + real \<lfloor>log 2 x\<rfloor>" using `prec \<ge> 1` by arith
  1807   from this assms show ?thesis
  1808     by (simp add: real_divl_def log_divide round_down_ge1)
  1809 qed
  1810 
  1811 lemma float_divl_pos_less1_bound:
  1812   "0 < real x \<Longrightarrow> real x \<le> 1 \<Longrightarrow> prec \<ge> 1 \<Longrightarrow> 1 \<le> real (float_divl prec 1 x)"
  1813   by (transfer, rule real_divl_pos_less1_bound)
  1814 
  1815 lemma float_divr: "real x / real y \<le> real (float_divr prec x y)"
  1816   by transfer (rule real_divr)
  1817 
  1818 lemma real_divr_pos_less1_lower_bound: assumes "0 < x" and "x \<le> 1" shows "1 \<le> real_divr prec 1 x"
  1819 proof -
  1820   have "1 \<le> 1 / x" using `0 < x` and `x <= 1` by auto
  1821   also have "\<dots> \<le> real_divr prec 1 x" using real_divr[where x=1 and y=x] by auto
  1822   finally show ?thesis by auto
  1823 qed
  1824 
  1825 lemma float_divr_pos_less1_lower_bound: "0 < x \<Longrightarrow> x \<le> 1 \<Longrightarrow> 1 \<le> float_divr prec 1 x"
  1826   by transfer (rule real_divr_pos_less1_lower_bound)
  1827 
  1828 lemma real_divr_nonpos_pos_upper_bound:
  1829   "x \<le> 0 \<Longrightarrow> 0 \<le> y \<Longrightarrow> real_divr prec x y \<le> 0"
  1830   by (simp add: real_divr_def round_up_le0 divide_le_0_iff)
  1831 
  1832 lemma float_divr_nonpos_pos_upper_bound:
  1833   "real x \<le> 0 \<Longrightarrow> 0 \<le> real y \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1834   by transfer (rule real_divr_nonpos_pos_upper_bound)
  1835 
  1836 lemma real_divr_nonneg_neg_upper_bound:
  1837   "0 \<le> x \<Longrightarrow> y \<le> 0 \<Longrightarrow> real_divr prec x y \<le> 0"
  1838   by (simp add: real_divr_def round_up_le0 divide_le_0_iff)
  1839 
  1840 lemma float_divr_nonneg_neg_upper_bound:
  1841   "0 \<le> real x \<Longrightarrow> real y \<le> 0 \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1842   by transfer (rule real_divr_nonneg_neg_upper_bound)
  1843 
  1844 lemma truncate_up_nonneg_mono:
  1845   assumes "0 \<le> x" "x \<le> y"
  1846   shows "truncate_up prec x \<le> truncate_up prec y"
  1847 proof -
  1848   {
  1849     assume "\<lfloor>log 2 x\<rfloor> = \<lfloor>log 2 y\<rfloor>"
  1850     hence ?thesis
  1851       using assms
  1852       by (auto simp: truncate_up_def round_up_def intro!: ceiling_mono)
  1853   } moreover {
  1854     assume "0 < x"
  1855     hence "log 2 x \<le> log 2 y" using assms by auto
  1856     moreover
  1857     assume "\<lfloor>log 2 x\<rfloor> \<noteq> \<lfloor>log 2 y\<rfloor>"
  1858     ultimately have logless: "log 2 x < log 2 y" and flogless: "\<lfloor>log 2 x\<rfloor> < \<lfloor>log 2 y\<rfloor>"
  1859       unfolding atomize_conj
  1860       by (metis floor_less_cancel linorder_cases not_le)
  1861     have "truncate_up prec x =
  1862       real \<lceil>x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1)\<rceil> * 2 powr - real (int prec - \<lfloor>log 2 x\<rfloor> - 1)"
  1863       using assms by (simp add: truncate_up_def round_up_def)
  1864     also have "\<lceil>x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1)\<rceil> \<le> (2 ^ prec)"
  1865     proof (unfold ceiling_le_eq)
  1866       have "x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1) \<le> x * (2 powr real prec / (2 powr log 2 x))"
  1867         using real_of_int_floor_add_one_ge[of "log 2 x"] assms
  1868         by (auto simp add: algebra_simps powr_divide2 intro!: mult_left_mono)
  1869       thus "x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1) \<le> real ((2::int) ^ prec)"
  1870         using `0 < x` by (simp add: powr_realpow)
  1871     qed
  1872     hence "real \<lceil>x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1)\<rceil> \<le> 2 powr int prec"
  1873       by (auto simp: powr_realpow)
  1874     also
  1875     have "2 powr - real (int prec - \<lfloor>log 2 x\<rfloor> - 1) \<le> 2 powr - real (int prec - \<lfloor>log 2 y\<rfloor>)"
  1876       using logless flogless by (auto intro!: floor_mono)
  1877     also have "2 powr real (int prec) \<le> 2 powr (log 2 y + real (int prec - \<lfloor>log 2 y\<rfloor>))"
  1878       using assms `0 < x`
  1879       by (auto simp: algebra_simps)
  1880     finally have "truncate_up prec x \<le> 2 powr (log 2 y + real (int prec - \<lfloor>log 2 y\<rfloor>)) * 2 powr - real (int prec - \<lfloor>log 2 y\<rfloor>)"
  1881       by simp
  1882     also have "\<dots> = 2 powr (log 2 y + real (int prec - \<lfloor>log 2 y\<rfloor>) - real (int prec - \<lfloor>log 2 y\<rfloor>))"
  1883       by (subst powr_add[symmetric]) simp
  1884     also have "\<dots> = y"
  1885       using `0 < x` assms
  1886       by (simp add: powr_add)
  1887     also have "\<dots> \<le> truncate_up prec y"
  1888       by (rule truncate_up)
  1889     finally have ?thesis .
  1890   } moreover {
  1891     assume "~ 0 < x"
  1892     hence ?thesis
  1893       using assms
  1894       by (auto intro!: truncate_up_le)
  1895   } ultimately show ?thesis
  1896     by blast
  1897 qed
  1898 
  1899 lemma truncate_up_switch_sign_mono:
  1900   assumes "x \<le> 0" "0 \<le> y"
  1901   shows "truncate_up prec x \<le> truncate_up prec y"
  1902 proof -
  1903   note truncate_up_nonpos[OF `x \<le> 0`]
  1904   also note truncate_up_le[OF `0 \<le> y`]
  1905   finally show ?thesis .
  1906 qed
  1907 
  1908 lemma truncate_down_zeroprec_mono:
  1909   assumes "0 < x" "x \<le> y"
  1910   shows "truncate_down 0 x \<le> truncate_down 0 y"
  1911 proof -
  1912   have "x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1) = x * inverse (2 powr ((real \<lfloor>log 2 x\<rfloor> + 1)))"
  1913     by (simp add: powr_divide2[symmetric] powr_add powr_minus inverse_eq_divide)
  1914   also have "\<dots> = 2 powr (log 2 x - (real \<lfloor>log 2 x\<rfloor>) - 1)"
  1915     using `0 < x`
  1916     by (auto simp: field_simps powr_add powr_divide2[symmetric])
  1917   also have "\<dots> < 2 powr 0"
  1918     using real_of_int_floor_add_one_gt
  1919     unfolding neg_less_iff_less
  1920     by (intro powr_less_mono) (auto simp: algebra_simps)
  1921   finally have "\<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor> < 1"
  1922     unfolding less_ceiling_eq real_of_int_minus real_of_one
  1923     by simp
  1924   moreover
  1925   have "0 \<le> \<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor>"
  1926     using `x > 0` by auto
  1927   ultimately have "\<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor> \<in> {0 ..< 1}"
  1928     by simp
  1929   also have "\<dots> \<subseteq> {0}" by auto
  1930   finally have "\<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor> = 0" by simp
  1931   with assms show ?thesis
  1932     by (auto simp: truncate_down_def round_down_def)
  1933 qed
  1934 
  1935 lemma truncate_down_switch_sign_mono:
  1936   assumes "x \<le> 0" "0 \<le> y"
  1937   assumes "x \<le> y"
  1938   shows "truncate_down prec x \<le> truncate_down prec y"
  1939 proof -
  1940   note truncate_down_le[OF `x \<le> 0`]
  1941   also note truncate_down_nonneg[OF `0 \<le> y`]
  1942   finally show ?thesis .
  1943 qed
  1944 
  1945 lemma truncate_down_nonneg_mono:
  1946   assumes "0 \<le> x" "x \<le> y"
  1947   shows "truncate_down prec x \<le> truncate_down prec y"
  1948 proof -
  1949   {
  1950     assume "0 < x" "prec = 0"
  1951     with assms have ?thesis
  1952       by (simp add: truncate_down_zeroprec_mono)
  1953   } moreover {
  1954     assume "~ 0 < x"
  1955     with assms have "x = 0" "0 \<le> y" by simp_all
  1956     hence ?thesis
  1957       by (auto intro!: truncate_down_nonneg)
  1958   } moreover {
  1959     assume "\<lfloor>log 2 \<bar>x\<bar>\<rfloor> = \<lfloor>log 2 \<bar>y\<bar>\<rfloor>"
  1960     hence ?thesis
  1961       using assms
  1962       by (auto simp: truncate_down_def round_down_def intro!: floor_mono)
  1963   } moreover {
  1964     assume "0 < x"
  1965     hence "log 2 x \<le> log 2 y" "0 < y" "0 \<le> y" using assms by auto
  1966     moreover
  1967     assume "\<lfloor>log 2 \<bar>x\<bar>\<rfloor> \<noteq> \<lfloor>log 2 \<bar>y\<bar>\<rfloor>"
  1968     ultimately have logless: "log 2 x < log 2 y" and flogless: "\<lfloor>log 2 x\<rfloor> < \<lfloor>log 2 y\<rfloor>"
  1969       unfolding atomize_conj abs_of_pos[OF `0 < x`] abs_of_pos[OF `0 < y`]
  1970       by (metis floor_less_cancel linorder_cases not_le)
  1971     assume "prec \<noteq> 0" hence [simp]: "prec \<ge> Suc 0" by auto
  1972     have "2 powr (prec - 1) \<le> y * 2 powr real (prec - 1) / (2 powr log 2 y)"
  1973       using `0 < y`
  1974       by simp
  1975     also have "\<dots> \<le> y * 2 powr real prec / (2 powr (real \<lfloor>log 2 y\<rfloor> + 1))"
  1976       using `0 \<le> y` `0 \<le> x` assms(2)
  1977       by (auto intro!: powr_mono divide_left_mono
  1978         simp: real_of_nat_diff powr_add
  1979         powr_divide2[symmetric])
  1980     also have "\<dots> = y * 2 powr real prec / (2 powr real \<lfloor>log 2 y\<rfloor> * 2)"
  1981       by (auto simp: powr_add)
  1982     finally have "(2 ^ (prec - 1)) \<le> \<lfloor>y * 2 powr real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor> - 1)\<rfloor>"
  1983       using `0 \<le> y`
  1984       by (auto simp: powr_divide2[symmetric] le_floor_eq powr_realpow)
  1985     hence "(2 ^ (prec - 1)) * 2 powr - real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor> - 1) \<le> truncate_down prec y"
  1986       by (auto simp: truncate_down_def round_down_def)
  1987     moreover
  1988     {
  1989       have "x = 2 powr (log 2 \<bar>x\<bar>)" using `0 < x` by simp
  1990       also have "\<dots> \<le> (2 ^ (prec )) * 2 powr - real (int prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1)"
  1991         using real_of_int_floor_add_one_ge[of "log 2 \<bar>x\<bar>"]
  1992         by (auto simp: powr_realpow[symmetric] powr_add[symmetric] algebra_simps)
  1993       also
  1994       have "2 powr - real (int prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) \<le> 2 powr - real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor>)"
  1995         using logless flogless `x > 0` `y > 0`
  1996         by (auto intro!: floor_mono)
  1997       finally have "x \<le> (2 ^ (prec - 1)) * 2 powr - real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor> - 1)"
  1998         by (auto simp: powr_realpow[symmetric] powr_divide2[symmetric] assms real_of_nat_diff)
  1999     } ultimately have ?thesis
  2000       by (metis dual_order.trans truncate_down)
  2001   } ultimately show ?thesis by blast
  2002 qed
  2003 
  2004 lemma truncate_down_eq_truncate_up: "truncate_down p x = - truncate_up p (-x)"
  2005   and truncate_up_eq_truncate_down: "truncate_up p x = - truncate_down p (-x)"
  2006   by (auto simp: truncate_up_uminus_eq truncate_down_uminus_eq)
  2007 
  2008 lemma truncate_down_mono: "x \<le> y \<Longrightarrow> truncate_down p x \<le> truncate_down p y"
  2009   apply (cases "0 \<le> x")
  2010   apply (rule truncate_down_nonneg_mono, assumption+)
  2011   apply (simp add: truncate_down_eq_truncate_up)
  2012   apply (cases "0 \<le> y")
  2013   apply (auto intro: truncate_up_nonneg_mono truncate_up_switch_sign_mono)
  2014   done
  2015 
  2016 lemma truncate_up_mono: "x \<le> y \<Longrightarrow> truncate_up p x \<le> truncate_up p y"
  2017   by (simp add: truncate_up_eq_truncate_down truncate_down_mono)
  2018 
  2019 lemma Float_le_zero_iff: "Float a b \<le> 0 \<longleftrightarrow> a \<le> 0"
  2020  apply (auto simp: zero_float_def mult_le_0_iff)
  2021  using powr_gt_zero[of 2 b] by simp
  2022 
  2023 lemma real_of_float_pprt[simp]: fixes a::float shows "real (pprt a) = pprt (real a)"
  2024   unfolding pprt_def sup_float_def max_def sup_real_def by auto
  2025 
  2026 lemma real_of_float_nprt[simp]: fixes a::float shows "real (nprt a) = nprt (real a)"
  2027   unfolding nprt_def inf_float_def min_def inf_real_def by auto
  2028 
  2029 lift_definition int_floor_fl :: "float \<Rightarrow> int" is floor .
  2030 
  2031 lemma compute_int_floor_fl[code]:
  2032   "int_floor_fl (Float m e) = (if 0 \<le> e then m * 2 ^ nat e else m div (2 ^ (nat (-e))))"
  2033   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  2034 hide_fact (open) compute_int_floor_fl
  2035 
  2036 lift_definition floor_fl :: "float \<Rightarrow> float" is "\<lambda>x. real (floor x)" by simp
  2037 
  2038 lemma compute_floor_fl[code]:
  2039   "floor_fl (Float m e) = (if 0 \<le> e then Float m e else Float (m div (2 ^ (nat (-e)))) 0)"
  2040   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  2041 hide_fact (open) compute_floor_fl
  2042 
  2043 lemma floor_fl: "real (floor_fl x) \<le> real x" by transfer simp
  2044 
  2045 lemma int_floor_fl: "real (int_floor_fl x) \<le> real x" by transfer simp
  2046 
  2047 lemma floor_pos_exp: "exponent (floor_fl x) \<ge> 0"
  2048 proof (cases "floor_fl x = float_of 0")
  2049   case True
  2050   then show ?thesis by (simp add: floor_fl_def)
  2051 next
  2052   case False
  2053   have eq: "floor_fl x = Float \<lfloor>real x\<rfloor> 0" by transfer simp
  2054   obtain i where "\<lfloor>real x\<rfloor> = mantissa (floor_fl x) * 2 ^ i" "0 = exponent (floor_fl x) - int i"
  2055     by (rule denormalize_shift[OF eq[THEN eq_reflection] False])
  2056   then show ?thesis by simp
  2057 qed
  2058 
  2059 lemma compute_mantissa[code]:
  2060   "mantissa (Float m e) = (if m = 0 then 0 else if 2 dvd m then mantissa (normfloat (Float m e)) else m)"
  2061   by (auto simp: mantissa_float Float.abs_eq)
  2062 
  2063 lemma compute_exponent[code]:
  2064   "exponent (Float m e) = (if m = 0 then 0 else if 2 dvd m then exponent (normfloat (Float m e)) else e)"
  2065   by (auto simp: exponent_float Float.abs_eq)
  2066 
  2067 end
  2068