src/Pure/Thy/thy_output.ML
author Christian Urban <urbanc@in.tum.de>
Thu Jan 15 12:55:38 2009 +0000 (2009-01-15)
changeset 29491 4f864f851f4d
parent 28644 e2ae4a6cf166
child 29606 fedb8be05f24
permissions -rw-r--r--
exported break reference
     1 (*  Title:      Pure/Thy/thy_output.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Theory document output.
     6 *)
     7 
     8 signature THY_OUTPUT =
     9 sig
    10   val display: bool ref
    11   val quotes: bool ref
    12   val indent: int ref
    13   val source: bool ref
    14   val break: bool ref
    15   val add_commands: (string * (Args.src -> Toplevel.node option -> string)) list -> unit
    16   val add_options: (string * (string -> (unit -> string) -> unit -> string)) list -> unit
    17   val defined_command: string -> bool
    18   val defined_option: string -> bool
    19   val print_antiquotations: unit -> unit
    20   val boolean: string -> bool
    21   val integer: string -> int
    22   val args: (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list)) ->
    23     (Args.src -> Proof.context -> 'a -> string) -> Args.src -> Toplevel.node option -> string
    24   datatype markup = Markup | MarkupEnv | Verbatim
    25   val modes: string list ref
    26   val eval_antiquote: Scan.lexicon -> Toplevel.node option -> SymbolPos.text * Position.T -> string
    27   val present_thy: Scan.lexicon -> (string -> string list) -> (markup -> string -> bool) ->
    28     (Toplevel.transition * Toplevel.state) list -> (OuterLex.token, 'a) Source.source -> Buffer.T
    29   val str_of_source: Args.src -> string
    30   val pretty_text: string -> Pretty.T
    31   val pretty_term: Proof.context -> term -> Pretty.T
    32   val pretty_thm: Proof.context -> thm -> Pretty.T
    33   val output_list: (Proof.context -> 'a -> Pretty.T) -> Args.src ->
    34     Proof.context -> 'a list -> string
    35   val output: (Proof.context -> 'a -> Pretty.T) -> Args.src -> Proof.context -> 'a -> string
    36 end;
    37 
    38 structure ThyOutput: THY_OUTPUT =
    39 struct
    40 
    41 structure T = OuterLex;
    42 structure P = OuterParse;
    43 
    44 
    45 (** global options **)
    46 
    47 val locale = ref "";
    48 val display = ref false;
    49 val quotes = ref false;
    50 val indent = ref 0;
    51 val source = ref false;
    52 val break = ref false;
    53 
    54 
    55 
    56 (** maintain global commands **)
    57 
    58 local
    59 
    60 val global_commands =
    61   ref (Symtab.empty: (Args.src -> Toplevel.node option -> string) Symtab.table);
    62 
    63 val global_options =
    64   ref (Symtab.empty: (string -> (unit -> string) -> unit -> string) Symtab.table);
    65 
    66 fun add_item kind (name, x) tab =
    67  (if not (Symtab.defined tab name) then ()
    68   else warning ("Redefined document antiquotation " ^ kind ^ ": " ^ quote name);
    69   Symtab.update (name, x) tab);
    70 
    71 in
    72 
    73 fun add_commands xs = CRITICAL (fn () => change global_commands (fold (add_item "command") xs));
    74 fun add_options xs = CRITICAL (fn () => change global_options (fold (add_item "option") xs));
    75 
    76 fun defined_command name = Symtab.defined (! global_commands) name;
    77 fun defined_option name = Symtab.defined (! global_options) name;
    78 
    79 fun command src =
    80   let val ((name, _), pos) = Args.dest_src src in
    81     (case Symtab.lookup (! global_commands) name of
    82       NONE => error ("Unknown document antiquotation command: " ^ quote name ^ Position.str_of pos)
    83     | SOME f => (Position.report (Markup.doc_antiq name) pos; f src))
    84   end;
    85 
    86 fun option (name, s) f () =
    87   (case Symtab.lookup (! global_options) name of
    88     NONE => error ("Unknown document antiquotation option: " ^ quote name)
    89   | SOME opt => opt s f ());
    90 
    91 fun options [] f = f
    92   | options (opt :: opts) f = option opt (options opts f);
    93 
    94 
    95 fun print_antiquotations () =
    96  [Pretty.big_list "document antiquotation commands:"
    97     (map Pretty.str (sort_strings (Symtab.keys (! global_commands)))),
    98   Pretty.big_list "document antiquotation options:"
    99     (map Pretty.str (sort_strings (Symtab.keys (! global_options))))]
   100  |> Pretty.chunks |> Pretty.writeln;
   101 
   102 end;
   103 
   104 
   105 
   106 (** syntax of antiquotations **)
   107 
   108 (* option values *)
   109 
   110 fun boolean "" = true
   111   | boolean "true" = true
   112   | boolean "false" = false
   113   | boolean s = error ("Bad boolean value: " ^ quote s);
   114 
   115 fun integer s =
   116   let
   117     fun int ss =
   118       (case Library.read_int ss of (i, []) => i
   119       | _ => error ("Bad integer value: " ^ quote s));
   120   in (case Symbol.explode s of "-" :: ss => ~ (int ss) | ss => int ss) end;
   121 
   122 
   123 (* args syntax *)
   124 
   125 fun syntax scan = Args.context_syntax "document antiquotation" scan;
   126 
   127 fun args scan f src node : string =
   128   let
   129     val loc = if ! locale = "" then NONE else SOME (! locale);
   130     val (x, ctxt) = syntax scan src (Toplevel.presentation_context node loc);
   131   in f src ctxt x end;
   132 
   133 
   134 (* outer syntax *)
   135 
   136 local
   137 
   138 val property = P.xname -- Scan.optional (P.$$$ "=" |-- P.!!! P.xname) "";
   139 val properties = Scan.optional (P.$$$ "[" |-- P.!!! (P.enum "," property --| P.$$$ "]")) [];
   140 
   141 in
   142 
   143 val antiq = P.!!! (P.position P.xname -- properties -- Args.parse --| Scan.ahead P.eof)
   144   >> (fn (((x, pos), y), z) => (y, Args.src ((x, z), pos)));
   145 
   146 end;
   147 
   148 
   149 (* eval_antiquote *)
   150 
   151 val modes = ref ([]: string list);
   152 
   153 fun eval_antiquote lex node (txt, pos) =
   154   let
   155     fun expand (Antiquote.Text s) = s
   156       | expand (Antiquote.Antiq x) =
   157           let val (opts, src) = Antiquote.read_antiq lex antiq x in
   158             options opts (fn () => command src node) ();  (*preview errors!*)
   159             PrintMode.with_modes (! modes @ Latex.modes)
   160               (Output.no_warnings (options opts (fn () => command src node))) ()
   161           end
   162       | expand (Antiquote.Open _) = ""
   163       | expand (Antiquote.Close _) = "";
   164     val ants = Antiquote.read (SymbolPos.explode (txt, pos), pos);
   165   in
   166     if is_none node andalso exists Antiquote.is_antiq ants then
   167       error ("Unknown context -- cannot expand document antiquotations" ^ Position.str_of pos)
   168     else implode (map expand ants)
   169   end;
   170 
   171 
   172 
   173 (** present theory source **)
   174 
   175 (*NB: arranging white space around command spans is a black art.*)
   176 
   177 (* presentation tokens *)
   178 
   179 datatype token =
   180     NoToken
   181   | BasicToken of T.token
   182   | MarkupToken of string * (string * Position.T)
   183   | MarkupEnvToken of string * (string * Position.T)
   184   | VerbatimToken of string * Position.T;
   185 
   186 fun output_token lex state =
   187   let
   188     val eval = eval_antiquote lex (try Toplevel.node_of state)
   189   in
   190     fn NoToken => ""
   191      | BasicToken tok => Latex.output_basic tok
   192      | MarkupToken (cmd, txt) => Latex.output_markup cmd (eval txt)
   193      | MarkupEnvToken (cmd, txt) => Latex.output_markup_env cmd (eval txt)
   194      | VerbatimToken txt => Latex.output_verbatim (eval txt)
   195   end;
   196 
   197 fun basic_token pred (BasicToken tok) = pred tok
   198   | basic_token _ _ = false;
   199 
   200 val improper_token = basic_token (not o T.is_proper);
   201 val comment_token = basic_token T.is_comment;
   202 val blank_token = basic_token T.is_blank;
   203 val newline_token = basic_token T.is_newline;
   204 
   205 
   206 (* command spans *)
   207 
   208 type command = string * Position.T * string list;   (*name, position, tags*)
   209 type source = (token * (string * int)) list;        (*token, markup flag, meta-comment depth*)
   210 
   211 datatype span = Span of command * (source * source * source * source) * bool;
   212 
   213 fun make_span cmd src =
   214   let
   215     fun take_newline (tok :: toks) =
   216           if newline_token (fst tok) then ([tok], toks, true)
   217           else ([], tok :: toks, false)
   218       | take_newline [] = ([], [], false);
   219     val (((src_prefix, src_main), src_suffix1), (src_suffix2, src_appendix, newline)) =
   220       src
   221       |> take_prefix (improper_token o fst)
   222       ||>> take_suffix (improper_token o fst)
   223       ||>> take_prefix (comment_token o fst)
   224       ||> take_newline;
   225   in Span (cmd, (src_prefix, src_main, src_suffix1 @ src_suffix2, src_appendix), newline) end;
   226 
   227 
   228 (* present spans *)
   229 
   230 local
   231 
   232 fun err_bad_nesting pos =
   233   error ("Bad nesting of commands in presentation" ^ pos);
   234 
   235 fun edge which f (x: string option, y) =
   236   if x = y then I
   237   else (case which (x, y) of NONE => I | SOME txt => Buffer.add (f txt));
   238 
   239 val begin_tag = edge #2 Latex.begin_tag;
   240 val end_tag = edge #1 Latex.end_tag;
   241 fun open_delim delim e = edge #2 Latex.begin_delim e #> delim #> edge #2 Latex.end_delim e;
   242 fun close_delim delim e = edge #1 Latex.begin_delim e #> delim #> edge #1 Latex.end_delim e;
   243 
   244 in
   245 
   246 fun present_span lex default_tags span state state'
   247     (tag_stack, active_tag, newline, buffer, present_cont) =
   248   let
   249     val present = fold (fn (tok, (flag, 0)) =>
   250         Buffer.add (output_token lex state' tok)
   251         #> Buffer.add flag
   252       | _ => I);
   253 
   254     val Span ((cmd_name, cmd_pos, cmd_tags), srcs, span_newline) = span;
   255 
   256     val (tag, tags) = tag_stack;
   257     val tag' = try hd (fold OuterKeyword.update_tags cmd_tags (the_list tag));
   258 
   259     val active_tag' =
   260       if is_some tag' then tag'
   261       else if cmd_name = "end" andalso not (Toplevel.is_toplevel state') then NONE
   262       else try hd (default_tags cmd_name);
   263     val edge = (active_tag, active_tag');
   264 
   265     val newline' =
   266       if is_none active_tag' then span_newline else newline;
   267 
   268     val nesting = Toplevel.level state' - Toplevel.level state;
   269     val tag_stack' =
   270       if nesting = 0 andalso not (Toplevel.is_proof state) then tag_stack
   271       else if nesting >= 0 then (tag', replicate nesting tag @ tags)
   272       else
   273         (case Library.drop (~ nesting - 1, tags) of
   274           tgs :: tgss => (tgs, tgss)
   275         | [] => err_bad_nesting (Position.str_of cmd_pos));
   276 
   277     val buffer' =
   278       buffer
   279       |> end_tag edge
   280       |> close_delim (fst present_cont) edge
   281       |> snd present_cont
   282       |> open_delim (present (#1 srcs)) edge
   283       |> begin_tag edge
   284       |> present (#2 srcs);
   285     val present_cont' =
   286       if newline then (present (#3 srcs), present (#4 srcs))
   287       else (I, present (#3 srcs) #> present (#4 srcs));
   288   in (tag_stack', active_tag', newline', buffer', present_cont') end;
   289 
   290 fun present_trailer ((_, tags), active_tag, _, buffer, present_cont) =
   291   if not (null tags) then err_bad_nesting " at end of theory"
   292   else
   293     buffer
   294     |> end_tag (active_tag, NONE)
   295     |> close_delim (fst present_cont) (active_tag, NONE)
   296     |> snd present_cont;
   297 
   298 end;
   299 
   300 
   301 (* present_thy *)
   302 
   303 datatype markup = Markup | MarkupEnv | Verbatim;
   304 
   305 local
   306 
   307 val space_proper =
   308   Scan.one T.is_blank -- Scan.many T.is_comment -- Scan.one T.is_proper;
   309 
   310 val is_improper = not o (T.is_proper orf T.is_begin_ignore orf T.is_end_ignore);
   311 val improper = Scan.many is_improper;
   312 val improper_end = Scan.repeat (Scan.unless space_proper (Scan.one is_improper));
   313 val blank_end = Scan.repeat (Scan.unless space_proper (Scan.one T.is_blank));
   314 
   315 val opt_newline = Scan.option (Scan.one T.is_newline);
   316 
   317 val ignore =
   318   Scan.depend (fn d => opt_newline |-- Scan.one T.is_begin_ignore
   319     >> pair (d + 1)) ||
   320   Scan.depend (fn d => Scan.one T.is_end_ignore --|
   321     (if d = 0 then Scan.fail_with (K "Bad nesting of meta-comments") else opt_newline)
   322     >> pair (d - 1));
   323 
   324 val tag = (improper -- P.$$$ "%" -- improper) |-- P.!!! (P.tag_name --| blank_end);
   325 
   326 val locale =
   327   Scan.option ((P.$$$ "(" -- improper -- P.$$$ "in") |--
   328     P.!!! (improper |-- P.xname --| (improper -- P.$$$ ")")));
   329 
   330 in
   331 
   332 fun present_thy lex default_tags is_markup command_results src =
   333   let
   334     (* tokens *)
   335 
   336     val ignored = Scan.state --| ignore
   337       >> (fn d => (NONE, (NoToken, ("", d))));
   338 
   339     fun markup mark mk flag = Scan.peek (fn d =>
   340       improper |-- P.position (Scan.one (T.is_kind T.Command andf is_markup mark o T.content_of)) --
   341       Scan.repeat tag --
   342       P.!!!! ((improper -- locale -- improper) |-- P.doc_source --| improper_end)
   343       >> (fn (((tok, pos), tags), txt) =>
   344         let val name = T.content_of tok
   345         in (SOME (name, pos, tags), (mk (name, txt), (flag, d))) end));
   346 
   347     val command = Scan.peek (fn d =>
   348       P.position (Scan.one (T.is_kind T.Command)) --
   349       Scan.repeat tag
   350       >> (fn ((tok, pos), tags) =>
   351         let val name = T.content_of tok
   352         in (SOME (name, pos, tags), (BasicToken tok, (Latex.markup_false, d))) end));
   353 
   354     val cmt = Scan.peek (fn d =>
   355       P.$$$ "--" |-- P.!!!! (improper |-- P.doc_source)
   356       >> (fn txt => (NONE, (MarkupToken ("cmt", txt), ("", d)))));
   357 
   358     val other = Scan.peek (fn d =>
   359        P.not_eof >> (fn tok => (NONE, (BasicToken tok, ("", d)))));
   360 
   361     val token =
   362       ignored ||
   363       markup Markup MarkupToken Latex.markup_true ||
   364       markup MarkupEnv MarkupEnvToken Latex.markup_true ||
   365       markup Verbatim (VerbatimToken o #2) "" ||
   366       command || cmt || other;
   367 
   368 
   369     (* spans *)
   370 
   371     val is_eof = fn (_, (BasicToken x, _)) => T.is_eof x | _ => false;
   372     val stopper = Scan.stopper (K (NONE, (BasicToken T.eof, ("", 0)))) is_eof;
   373 
   374     val cmd = Scan.one (is_some o fst);
   375     val non_cmd = Scan.one (is_none o fst andf not o is_eof) >> #2;
   376 
   377     val comments = Scan.many (comment_token o fst o snd);
   378     val blank = Scan.one (blank_token o fst o snd);
   379     val newline = Scan.one (newline_token o fst o snd);
   380     val before_cmd =
   381       Scan.option (newline -- comments) --
   382       Scan.option (newline -- comments) --
   383       Scan.option (blank -- comments) -- cmd;
   384 
   385     val span =
   386       Scan.repeat non_cmd -- cmd --
   387         Scan.repeat (Scan.unless before_cmd non_cmd) --
   388         Scan.option (newline >> (single o snd))
   389       >> (fn (((toks1, (cmd, tok2)), toks3), tok4) =>
   390           make_span (the cmd) (toks1 @ (tok2 :: (toks3 @ the_default [] tok4))));
   391 
   392     val spans =
   393       src
   394       |> Source.filter (not o T.is_semicolon)
   395       |> Source.source' 0 T.stopper (Scan.error (Scan.bulk token)) NONE
   396       |> Source.source stopper (Scan.error (Scan.bulk span)) NONE
   397       |> Source.exhaust;
   398 
   399 
   400     (* present commands *)
   401 
   402     fun present_command tr span st st' =
   403       Toplevel.setmp_thread_position tr (present_span lex default_tags span st st');
   404 
   405     fun present _ [] = I
   406       | present st (((tr, st'), span) :: rest) = present_command tr span st st' #> present st' rest;
   407   in
   408     if length command_results = length spans then
   409       ((NONE, []), NONE, true, Buffer.empty, (I, I))
   410       |> present Toplevel.toplevel (command_results ~~ spans)
   411       |> present_trailer
   412     else error "Messed-up outer syntax for presentation"
   413   end;
   414 
   415 end;
   416 
   417 
   418 
   419 (** setup default output **)
   420 
   421 (* options *)
   422 
   423 val _ = add_options
   424  [("show_types", Library.setmp Syntax.show_types o boolean),
   425   ("show_sorts", Library.setmp Syntax.show_sorts o boolean),
   426   ("show_structs", Library.setmp show_structs o boolean),
   427   ("show_question_marks", Library.setmp show_question_marks o boolean),
   428   ("long_names", Library.setmp NameSpace.long_names o boolean),
   429   ("short_names", Library.setmp NameSpace.short_names o boolean),
   430   ("unique_names", Library.setmp NameSpace.unique_names o boolean),
   431   ("eta_contract", Library.setmp Syntax.eta_contract o boolean),
   432   ("locale", Library.setmp locale),
   433   ("display", Library.setmp display o boolean),
   434   ("break", Library.setmp break o boolean),
   435   ("quotes", Library.setmp quotes o boolean),
   436   ("mode", fn s => fn f => PrintMode.with_modes [s] f),
   437   ("margin", Pretty.setmp_margin o integer),
   438   ("indent", Library.setmp indent o integer),
   439   ("source", Library.setmp source o boolean),
   440   ("goals_limit", Library.setmp goals_limit o integer)];
   441 
   442 
   443 (* basic pretty printing *)
   444 
   445 val str_of_source = space_implode " " o map T.unparse o #2 o #1 o Args.dest_src;
   446 
   447 fun tweak_line s =
   448   if ! display then s else Symbol.strip_blanks s;
   449 
   450 val pretty_text = Pretty.chunks o map Pretty.str o map tweak_line o Library.split_lines;
   451 
   452 fun pretty_term ctxt t = Syntax.pretty_term (Variable.auto_fixes t ctxt) t;
   453 
   454 fun pretty_term_abbrev ctxt t = ProofContext.pretty_term_abbrev (Variable.auto_fixes t ctxt) t;
   455 
   456 fun pretty_term_typ ctxt t =
   457   Syntax.pretty_term ctxt (TypeInfer.constrain (Term.fastype_of t) t);
   458 
   459 fun pretty_term_typeof ctxt = Syntax.pretty_typ ctxt o Term.fastype_of;
   460 
   461 fun pretty_const ctxt c =
   462   let
   463     val t = Const (c, Consts.type_scheme (ProofContext.consts_of ctxt) c)
   464       handle TYPE (msg, _, _) => error msg;
   465     val ([t'], _) = Variable.import_terms true [t] ctxt;
   466   in pretty_term ctxt t' end;
   467 
   468 fun pretty_abbrev ctxt s =
   469   let
   470     val t = Syntax.parse_term ctxt s |> singleton (ProofContext.standard_infer_types ctxt);
   471     fun err () = error ("Abbreviated constant expected: " ^ Syntax.string_of_term ctxt t);
   472     val (head, args) = Term.strip_comb t;
   473     val (c, T) = Term.dest_Const head handle TERM _ => err ();
   474     val (U, u) = Consts.the_abbreviation (ProofContext.consts_of ctxt) c
   475       handle TYPE _ => err ();
   476     val t' = Term.betapplys (Envir.expand_atom T (U, u), args);
   477   in pretty_term_abbrev ctxt (Logic.mk_equals (t, t')) end;
   478 
   479 fun pretty_thm ctxt = pretty_term ctxt o Thm.full_prop_of;
   480 
   481 fun pretty_term_style ctxt (name, t) =
   482   pretty_term ctxt (TermStyle.the_style (ProofContext.theory_of ctxt) name ctxt t);
   483 
   484 fun pretty_thm_style ctxt (name, th) =
   485   pretty_term_style ctxt (name, Thm.full_prop_of th);
   486 
   487 fun pretty_prf full ctxt thms =
   488   Pretty.chunks (map (ProofSyntax.pretty_proof_of ctxt full) thms);
   489 
   490 fun pretty_theory ctxt name =
   491   (Theory.requires (ProofContext.theory_of ctxt) name "presentation"; Pretty.str name);
   492 
   493 
   494 (* Isar output *)
   495 
   496 fun output_list pretty src ctxt xs =
   497   map (pretty ctxt) xs        (*always pretty in order to exhibit errors!*)
   498   |> (if ! source then K [pretty_text (str_of_source src)] else I)
   499   |> (if ! quotes then map Pretty.quote else I)
   500   |> (if ! display then
   501     map (Output.output o Pretty.string_of o Pretty.indent (! indent))
   502     #> space_implode "\\isasep\\isanewline%\n"
   503     #> enclose "\\begin{isabelle}%\n" "%\n\\end{isabelle}"
   504   else
   505     map (Output.output o (if ! break then Pretty.string_of else Pretty.str_of))
   506     #> space_implode "\\isasep\\isanewline%\n"
   507     #> enclose "\\isa{" "}");
   508 
   509 fun output pretty src ctxt = output_list pretty src ctxt o single;
   510 
   511 fun proof_state node =
   512   (case Option.map Toplevel.proof_node node of
   513     SOME (SOME prf) => ProofNode.current prf
   514   | _ => error "No proof state");
   515 
   516 fun output_goals main_goal src node = args (Scan.succeed ()) (output (fn _ => fn _ =>
   517   Pretty.chunks (Proof.pretty_goals main_goal (proof_state node)))) src node;
   518 
   519 fun ml_val txt = "fn _ => (" ^ txt ^ ");";
   520 fun ml_type txt = "val _ = NONE : (" ^ txt ^ ") option;";
   521 fun ml_struct txt = "functor DUMMY_FUNCTOR() = struct structure DUMMY = " ^ txt ^ " end;"
   522 
   523 fun output_ml ml src ctxt (txt, pos) =
   524  (ML_Context.eval_in (SOME ctxt) false pos (ml txt);
   525   (if ! source then str_of_source src else SymbolPos.content (SymbolPos.explode (txt, pos)))
   526   |> (if ! quotes then quote else I)
   527   |> (if ! display then enclose "\\begin{verbatim}\n" "\n\\end{verbatim}"
   528   else
   529     split_lines
   530     #> map (space_implode "\\verb,|," o map (enclose "\\verb|" "|") o space_explode "|")
   531     #> space_implode "\\isasep\\isanewline%\n"));
   532 
   533 
   534 (* embedded lemmas *)
   535 
   536 fun pretty_lemma ctxt (prop, methods) =
   537   let
   538     val _ = ctxt
   539       |> Proof.theorem_i NONE (K I) [[(prop, [])]]
   540       |> Proof.global_terminal_proof methods;
   541   in pretty_term ctxt prop end;
   542 
   543 val embedded_lemma =
   544   args (Args.prop -- Scan.lift (Args.$$$ "by" |-- Method.parse -- Scan.option Method.parse))
   545     (output pretty_lemma o (fn ((a, arg :: _), p) => (Args.src ((a, [arg]), p))) o Args.dest_src);
   546 
   547 
   548 (* commands *)
   549 
   550 val _ = OuterKeyword.keyword "by";
   551 
   552 val _ = add_commands
   553  [("thm", args Attrib.thms (output_list pretty_thm)),
   554   ("thm_style", args (Scan.lift Args.liberal_name -- Attrib.thm) (output pretty_thm_style)),
   555   ("prop", args Args.prop (output pretty_term)),
   556   ("lemma", embedded_lemma),
   557   ("term", args Args.term (output pretty_term)),
   558   ("term_style", args (Scan.lift Args.liberal_name -- Args.term) (output pretty_term_style)),
   559   ("term_type", args Args.term (output pretty_term_typ)),
   560   ("typeof", args Args.term (output pretty_term_typeof)),
   561   ("const", args Args.const_proper (output pretty_const)),
   562   ("abbrev", args (Scan.lift Args.name_source) (output pretty_abbrev)),
   563   ("typ", args Args.typ_abbrev (output Syntax.pretty_typ)),
   564   ("text", args (Scan.lift Args.name) (output (K pretty_text))),
   565   ("goals", output_goals true),
   566   ("subgoals", output_goals false),
   567   ("prf", args Attrib.thms (output (pretty_prf false))),
   568   ("full_prf", args Attrib.thms (output (pretty_prf true))),
   569   ("theory", args (Scan.lift Args.name) (output pretty_theory)),
   570   ("ML", args (Scan.lift Args.name_source_position) (output_ml ml_val)),
   571   ("ML_type", args (Scan.lift Args.name_source_position) (output_ml ml_type)),
   572   ("ML_struct", args (Scan.lift Args.name_source_position) (output_ml ml_struct))];
   573 
   574 end;