src/HOL/Polynomial.thy
author huffman
Thu Jan 15 09:17:15 2009 -0800 (2009-01-15)
changeset 29537 50345a0f9df8
parent 29480 4e08ee896e81
child 29539 abfe2af6883e
permissions -rw-r--r--
rename divmod_poly to pdivmod
     1 (*  Title:      HOL/Polynomial.thy
     2     Author:     Brian Huffman
     3                 Based on an earlier development by Clemens Ballarin
     4 *)
     5 
     6 header {* Univariate Polynomials *}
     7 
     8 theory Polynomial
     9 imports Plain SetInterval
    10 begin
    11 
    12 subsection {* Definition of type @{text poly} *}
    13 
    14 typedef (Poly) 'a poly = "{f::nat \<Rightarrow> 'a::zero. \<exists>n. \<forall>i>n. f i = 0}"
    15   morphisms coeff Abs_poly
    16   by auto
    17 
    18 lemma expand_poly_eq: "p = q \<longleftrightarrow> (\<forall>n. coeff p n = coeff q n)"
    19 by (simp add: coeff_inject [symmetric] expand_fun_eq)
    20 
    21 lemma poly_ext: "(\<And>n. coeff p n = coeff q n) \<Longrightarrow> p = q"
    22 by (simp add: expand_poly_eq)
    23 
    24 
    25 subsection {* Degree of a polynomial *}
    26 
    27 definition
    28   degree :: "'a::zero poly \<Rightarrow> nat" where
    29   "degree p = (LEAST n. \<forall>i>n. coeff p i = 0)"
    30 
    31 lemma coeff_eq_0: "degree p < n \<Longrightarrow> coeff p n = 0"
    32 proof -
    33   have "coeff p \<in> Poly"
    34     by (rule coeff)
    35   hence "\<exists>n. \<forall>i>n. coeff p i = 0"
    36     unfolding Poly_def by simp
    37   hence "\<forall>i>degree p. coeff p i = 0"
    38     unfolding degree_def by (rule LeastI_ex)
    39   moreover assume "degree p < n"
    40   ultimately show ?thesis by simp
    41 qed
    42 
    43 lemma le_degree: "coeff p n \<noteq> 0 \<Longrightarrow> n \<le> degree p"
    44   by (erule contrapos_np, rule coeff_eq_0, simp)
    45 
    46 lemma degree_le: "\<forall>i>n. coeff p i = 0 \<Longrightarrow> degree p \<le> n"
    47   unfolding degree_def by (erule Least_le)
    48 
    49 lemma less_degree_imp: "n < degree p \<Longrightarrow> \<exists>i>n. coeff p i \<noteq> 0"
    50   unfolding degree_def by (drule not_less_Least, simp)
    51 
    52 
    53 subsection {* The zero polynomial *}
    54 
    55 instantiation poly :: (zero) zero
    56 begin
    57 
    58 definition
    59   zero_poly_def: "0 = Abs_poly (\<lambda>n. 0)"
    60 
    61 instance ..
    62 end
    63 
    64 lemma coeff_0 [simp]: "coeff 0 n = 0"
    65   unfolding zero_poly_def
    66   by (simp add: Abs_poly_inverse Poly_def)
    67 
    68 lemma degree_0 [simp]: "degree 0 = 0"
    69   by (rule order_antisym [OF degree_le le0]) simp
    70 
    71 lemma leading_coeff_neq_0:
    72   assumes "p \<noteq> 0" shows "coeff p (degree p) \<noteq> 0"
    73 proof (cases "degree p")
    74   case 0
    75   from `p \<noteq> 0` have "\<exists>n. coeff p n \<noteq> 0"
    76     by (simp add: expand_poly_eq)
    77   then obtain n where "coeff p n \<noteq> 0" ..
    78   hence "n \<le> degree p" by (rule le_degree)
    79   with `coeff p n \<noteq> 0` and `degree p = 0`
    80   show "coeff p (degree p) \<noteq> 0" by simp
    81 next
    82   case (Suc n)
    83   from `degree p = Suc n` have "n < degree p" by simp
    84   hence "\<exists>i>n. coeff p i \<noteq> 0" by (rule less_degree_imp)
    85   then obtain i where "n < i" and "coeff p i \<noteq> 0" by fast
    86   from `degree p = Suc n` and `n < i` have "degree p \<le> i" by simp
    87   also from `coeff p i \<noteq> 0` have "i \<le> degree p" by (rule le_degree)
    88   finally have "degree p = i" .
    89   with `coeff p i \<noteq> 0` show "coeff p (degree p) \<noteq> 0" by simp
    90 qed
    91 
    92 lemma leading_coeff_0_iff [simp]: "coeff p (degree p) = 0 \<longleftrightarrow> p = 0"
    93   by (cases "p = 0", simp, simp add: leading_coeff_neq_0)
    94 
    95 
    96 subsection {* List-style constructor for polynomials *}
    97 
    98 definition
    99   pCons :: "'a::zero \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
   100 where
   101   [code del]: "pCons a p = Abs_poly (nat_case a (coeff p))"
   102 
   103 syntax
   104   "_poly" :: "args \<Rightarrow> 'a poly"  ("[:(_):]")
   105 
   106 translations
   107   "[:x, xs:]" == "CONST pCons x [:xs:]"
   108   "[:x:]" == "CONST pCons x 0"
   109 
   110 lemma Poly_nat_case: "f \<in> Poly \<Longrightarrow> nat_case a f \<in> Poly"
   111   unfolding Poly_def by (auto split: nat.split)
   112 
   113 lemma coeff_pCons:
   114   "coeff (pCons a p) = nat_case a (coeff p)"
   115   unfolding pCons_def
   116   by (simp add: Abs_poly_inverse Poly_nat_case coeff)
   117 
   118 lemma coeff_pCons_0 [simp]: "coeff (pCons a p) 0 = a"
   119   by (simp add: coeff_pCons)
   120 
   121 lemma coeff_pCons_Suc [simp]: "coeff (pCons a p) (Suc n) = coeff p n"
   122   by (simp add: coeff_pCons)
   123 
   124 lemma degree_pCons_le: "degree (pCons a p) \<le> Suc (degree p)"
   125 by (rule degree_le, simp add: coeff_eq_0 coeff_pCons split: nat.split)
   126 
   127 lemma degree_pCons_eq:
   128   "p \<noteq> 0 \<Longrightarrow> degree (pCons a p) = Suc (degree p)"
   129 apply (rule order_antisym [OF degree_pCons_le])
   130 apply (rule le_degree, simp)
   131 done
   132 
   133 lemma degree_pCons_0: "degree (pCons a 0) = 0"
   134 apply (rule order_antisym [OF _ le0])
   135 apply (rule degree_le, simp add: coeff_pCons split: nat.split)
   136 done
   137 
   138 lemma degree_pCons_eq_if [simp]:
   139   "degree (pCons a p) = (if p = 0 then 0 else Suc (degree p))"
   140 apply (cases "p = 0", simp_all)
   141 apply (rule order_antisym [OF _ le0])
   142 apply (rule degree_le, simp add: coeff_pCons split: nat.split)
   143 apply (rule order_antisym [OF degree_pCons_le])
   144 apply (rule le_degree, simp)
   145 done
   146 
   147 lemma pCons_0_0 [simp]: "pCons 0 0 = 0"
   148 by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   149 
   150 lemma pCons_eq_iff [simp]:
   151   "pCons a p = pCons b q \<longleftrightarrow> a = b \<and> p = q"
   152 proof (safe)
   153   assume "pCons a p = pCons b q"
   154   then have "coeff (pCons a p) 0 = coeff (pCons b q) 0" by simp
   155   then show "a = b" by simp
   156 next
   157   assume "pCons a p = pCons b q"
   158   then have "\<forall>n. coeff (pCons a p) (Suc n) =
   159                  coeff (pCons b q) (Suc n)" by simp
   160   then show "p = q" by (simp add: expand_poly_eq)
   161 qed
   162 
   163 lemma pCons_eq_0_iff [simp]: "pCons a p = 0 \<longleftrightarrow> a = 0 \<and> p = 0"
   164   using pCons_eq_iff [of a p 0 0] by simp
   165 
   166 lemma Poly_Suc: "f \<in> Poly \<Longrightarrow> (\<lambda>n. f (Suc n)) \<in> Poly"
   167   unfolding Poly_def
   168   by (clarify, rule_tac x=n in exI, simp)
   169 
   170 lemma pCons_cases [cases type: poly]:
   171   obtains (pCons) a q where "p = pCons a q"
   172 proof
   173   show "p = pCons (coeff p 0) (Abs_poly (\<lambda>n. coeff p (Suc n)))"
   174     by (rule poly_ext)
   175        (simp add: Abs_poly_inverse Poly_Suc coeff coeff_pCons
   176              split: nat.split)
   177 qed
   178 
   179 lemma pCons_induct [case_names 0 pCons, induct type: poly]:
   180   assumes zero: "P 0"
   181   assumes pCons: "\<And>a p. P p \<Longrightarrow> P (pCons a p)"
   182   shows "P p"
   183 proof (induct p rule: measure_induct_rule [where f=degree])
   184   case (less p)
   185   obtain a q where "p = pCons a q" by (rule pCons_cases)
   186   have "P q"
   187   proof (cases "q = 0")
   188     case True
   189     then show "P q" by (simp add: zero)
   190   next
   191     case False
   192     then have "degree (pCons a q) = Suc (degree q)"
   193       by (rule degree_pCons_eq)
   194     then have "degree q < degree p"
   195       using `p = pCons a q` by simp
   196     then show "P q"
   197       by (rule less.hyps)
   198   qed
   199   then have "P (pCons a q)"
   200     by (rule pCons)
   201   then show ?case
   202     using `p = pCons a q` by simp
   203 qed
   204 
   205 
   206 subsection {* Recursion combinator for polynomials *}
   207 
   208 function
   209   poly_rec :: "'b \<Rightarrow> ('a::zero \<Rightarrow> 'a poly \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a poly \<Rightarrow> 'b"
   210 where
   211   poly_rec_pCons_eq_if [simp del, code del]:
   212     "poly_rec z f (pCons a p) = f a p (if p = 0 then z else poly_rec z f p)"
   213 by (case_tac x, rename_tac q, case_tac q, auto)
   214 
   215 termination poly_rec
   216 by (relation "measure (degree \<circ> snd \<circ> snd)", simp)
   217    (simp add: degree_pCons_eq)
   218 
   219 lemma poly_rec_0:
   220   "f 0 0 z = z \<Longrightarrow> poly_rec z f 0 = z"
   221   using poly_rec_pCons_eq_if [of z f 0 0] by simp
   222 
   223 lemma poly_rec_pCons:
   224   "f 0 0 z = z \<Longrightarrow> poly_rec z f (pCons a p) = f a p (poly_rec z f p)"
   225   by (simp add: poly_rec_pCons_eq_if poly_rec_0)
   226 
   227 
   228 subsection {* Monomials *}
   229 
   230 definition
   231   monom :: "'a \<Rightarrow> nat \<Rightarrow> 'a::zero poly" where
   232   "monom a m = Abs_poly (\<lambda>n. if m = n then a else 0)"
   233 
   234 lemma coeff_monom [simp]: "coeff (monom a m) n = (if m=n then a else 0)"
   235   unfolding monom_def
   236   by (subst Abs_poly_inverse, auto simp add: Poly_def)
   237 
   238 lemma monom_0: "monom a 0 = pCons a 0"
   239   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   240 
   241 lemma monom_Suc: "monom a (Suc n) = pCons 0 (monom a n)"
   242   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   243 
   244 lemma monom_eq_0 [simp]: "monom 0 n = 0"
   245   by (rule poly_ext) simp
   246 
   247 lemma monom_eq_0_iff [simp]: "monom a n = 0 \<longleftrightarrow> a = 0"
   248   by (simp add: expand_poly_eq)
   249 
   250 lemma monom_eq_iff [simp]: "monom a n = monom b n \<longleftrightarrow> a = b"
   251   by (simp add: expand_poly_eq)
   252 
   253 lemma degree_monom_le: "degree (monom a n) \<le> n"
   254   by (rule degree_le, simp)
   255 
   256 lemma degree_monom_eq: "a \<noteq> 0 \<Longrightarrow> degree (monom a n) = n"
   257   apply (rule order_antisym [OF degree_monom_le])
   258   apply (rule le_degree, simp)
   259   done
   260 
   261 
   262 subsection {* Addition and subtraction *}
   263 
   264 instantiation poly :: (comm_monoid_add) comm_monoid_add
   265 begin
   266 
   267 definition
   268   plus_poly_def [code del]:
   269     "p + q = Abs_poly (\<lambda>n. coeff p n + coeff q n)"
   270 
   271 lemma Poly_add:
   272   fixes f g :: "nat \<Rightarrow> 'a"
   273   shows "\<lbrakk>f \<in> Poly; g \<in> Poly\<rbrakk> \<Longrightarrow> (\<lambda>n. f n + g n) \<in> Poly"
   274   unfolding Poly_def
   275   apply (clarify, rename_tac m n)
   276   apply (rule_tac x="max m n" in exI, simp)
   277   done
   278 
   279 lemma coeff_add [simp]:
   280   "coeff (p + q) n = coeff p n + coeff q n"
   281   unfolding plus_poly_def
   282   by (simp add: Abs_poly_inverse coeff Poly_add)
   283 
   284 instance proof
   285   fix p q r :: "'a poly"
   286   show "(p + q) + r = p + (q + r)"
   287     by (simp add: expand_poly_eq add_assoc)
   288   show "p + q = q + p"
   289     by (simp add: expand_poly_eq add_commute)
   290   show "0 + p = p"
   291     by (simp add: expand_poly_eq)
   292 qed
   293 
   294 end
   295 
   296 instantiation poly :: (ab_group_add) ab_group_add
   297 begin
   298 
   299 definition
   300   uminus_poly_def [code del]:
   301     "- p = Abs_poly (\<lambda>n. - coeff p n)"
   302 
   303 definition
   304   minus_poly_def [code del]:
   305     "p - q = Abs_poly (\<lambda>n. coeff p n - coeff q n)"
   306 
   307 lemma Poly_minus:
   308   fixes f :: "nat \<Rightarrow> 'a"
   309   shows "f \<in> Poly \<Longrightarrow> (\<lambda>n. - f n) \<in> Poly"
   310   unfolding Poly_def by simp
   311 
   312 lemma Poly_diff:
   313   fixes f g :: "nat \<Rightarrow> 'a"
   314   shows "\<lbrakk>f \<in> Poly; g \<in> Poly\<rbrakk> \<Longrightarrow> (\<lambda>n. f n - g n) \<in> Poly"
   315   unfolding diff_minus by (simp add: Poly_add Poly_minus)
   316 
   317 lemma coeff_minus [simp]: "coeff (- p) n = - coeff p n"
   318   unfolding uminus_poly_def
   319   by (simp add: Abs_poly_inverse coeff Poly_minus)
   320 
   321 lemma coeff_diff [simp]:
   322   "coeff (p - q) n = coeff p n - coeff q n"
   323   unfolding minus_poly_def
   324   by (simp add: Abs_poly_inverse coeff Poly_diff)
   325 
   326 instance proof
   327   fix p q :: "'a poly"
   328   show "- p + p = 0"
   329     by (simp add: expand_poly_eq)
   330   show "p - q = p + - q"
   331     by (simp add: expand_poly_eq diff_minus)
   332 qed
   333 
   334 end
   335 
   336 lemma add_pCons [simp]:
   337   "pCons a p + pCons b q = pCons (a + b) (p + q)"
   338   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   339 
   340 lemma minus_pCons [simp]:
   341   "- pCons a p = pCons (- a) (- p)"
   342   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   343 
   344 lemma diff_pCons [simp]:
   345   "pCons a p - pCons b q = pCons (a - b) (p - q)"
   346   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   347 
   348 lemma degree_add_le: "degree (p + q) \<le> max (degree p) (degree q)"
   349   by (rule degree_le, auto simp add: coeff_eq_0)
   350 
   351 lemma degree_add_less:
   352   "\<lbrakk>degree p < n; degree q < n\<rbrakk> \<Longrightarrow> degree (p + q) < n"
   353   by (auto intro: le_less_trans degree_add_le)
   354 
   355 lemma degree_add_eq_right:
   356   "degree p < degree q \<Longrightarrow> degree (p + q) = degree q"
   357   apply (cases "q = 0", simp)
   358   apply (rule order_antisym)
   359   apply (rule ord_le_eq_trans [OF degree_add_le])
   360   apply simp
   361   apply (rule le_degree)
   362   apply (simp add: coeff_eq_0)
   363   done
   364 
   365 lemma degree_add_eq_left:
   366   "degree q < degree p \<Longrightarrow> degree (p + q) = degree p"
   367   using degree_add_eq_right [of q p]
   368   by (simp add: add_commute)
   369 
   370 lemma degree_minus [simp]: "degree (- p) = degree p"
   371   unfolding degree_def by simp
   372 
   373 lemma degree_diff_le: "degree (p - q) \<le> max (degree p) (degree q)"
   374   using degree_add_le [where p=p and q="-q"]
   375   by (simp add: diff_minus)
   376 
   377 lemma degree_diff_less:
   378   "\<lbrakk>degree p < n; degree q < n\<rbrakk> \<Longrightarrow> degree (p - q) < n"
   379   by (auto intro: le_less_trans degree_diff_le)
   380 
   381 lemma add_monom: "monom a n + monom b n = monom (a + b) n"
   382   by (rule poly_ext) simp
   383 
   384 lemma diff_monom: "monom a n - monom b n = monom (a - b) n"
   385   by (rule poly_ext) simp
   386 
   387 lemma minus_monom: "- monom a n = monom (-a) n"
   388   by (rule poly_ext) simp
   389 
   390 lemma coeff_setsum: "coeff (\<Sum>x\<in>A. p x) i = (\<Sum>x\<in>A. coeff (p x) i)"
   391   by (cases "finite A", induct set: finite, simp_all)
   392 
   393 lemma monom_setsum: "monom (\<Sum>x\<in>A. a x) n = (\<Sum>x\<in>A. monom (a x) n)"
   394   by (rule poly_ext) (simp add: coeff_setsum)
   395 
   396 
   397 subsection {* Multiplication by a constant *}
   398 
   399 definition
   400   smult :: "'a::comm_semiring_0 \<Rightarrow> 'a poly \<Rightarrow> 'a poly" where
   401   "smult a p = Abs_poly (\<lambda>n. a * coeff p n)"
   402 
   403 lemma Poly_smult:
   404   fixes f :: "nat \<Rightarrow> 'a::comm_semiring_0"
   405   shows "f \<in> Poly \<Longrightarrow> (\<lambda>n. a * f n) \<in> Poly"
   406   unfolding Poly_def
   407   by (clarify, rule_tac x=n in exI, simp)
   408 
   409 lemma coeff_smult [simp]: "coeff (smult a p) n = a * coeff p n"
   410   unfolding smult_def
   411   by (simp add: Abs_poly_inverse Poly_smult coeff)
   412 
   413 lemma degree_smult_le: "degree (smult a p) \<le> degree p"
   414   by (rule degree_le, simp add: coeff_eq_0)
   415 
   416 lemma smult_smult [simp]: "smult a (smult b p) = smult (a * b) p"
   417   by (rule poly_ext, simp add: mult_assoc)
   418 
   419 lemma smult_0_right [simp]: "smult a 0 = 0"
   420   by (rule poly_ext, simp)
   421 
   422 lemma smult_0_left [simp]: "smult 0 p = 0"
   423   by (rule poly_ext, simp)
   424 
   425 lemma smult_1_left [simp]: "smult (1::'a::comm_semiring_1) p = p"
   426   by (rule poly_ext, simp)
   427 
   428 lemma smult_add_right:
   429   "smult a (p + q) = smult a p + smult a q"
   430   by (rule poly_ext, simp add: ring_simps)
   431 
   432 lemma smult_add_left:
   433   "smult (a + b) p = smult a p + smult b p"
   434   by (rule poly_ext, simp add: ring_simps)
   435 
   436 lemma smult_minus_right [simp]:
   437   "smult (a::'a::comm_ring) (- p) = - smult a p"
   438   by (rule poly_ext, simp)
   439 
   440 lemma smult_minus_left [simp]:
   441   "smult (- a::'a::comm_ring) p = - smult a p"
   442   by (rule poly_ext, simp)
   443 
   444 lemma smult_diff_right:
   445   "smult (a::'a::comm_ring) (p - q) = smult a p - smult a q"
   446   by (rule poly_ext, simp add: ring_simps)
   447 
   448 lemma smult_diff_left:
   449   "smult (a - b::'a::comm_ring) p = smult a p - smult b p"
   450   by (rule poly_ext, simp add: ring_simps)
   451 
   452 lemmas smult_distribs =
   453   smult_add_left smult_add_right
   454   smult_diff_left smult_diff_right
   455 
   456 lemma smult_pCons [simp]:
   457   "smult a (pCons b p) = pCons (a * b) (smult a p)"
   458   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   459 
   460 lemma smult_monom: "smult a (monom b n) = monom (a * b) n"
   461   by (induct n, simp add: monom_0, simp add: monom_Suc)
   462 
   463 
   464 subsection {* Multiplication of polynomials *}
   465 
   466 text {* TODO: move to SetInterval.thy *}
   467 lemma setsum_atMost_Suc_shift:
   468   fixes f :: "nat \<Rightarrow> 'a::comm_monoid_add"
   469   shows "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
   470 proof (induct n)
   471   case 0 show ?case by simp
   472 next
   473   case (Suc n) note IH = this
   474   have "(\<Sum>i\<le>Suc (Suc n). f i) = (\<Sum>i\<le>Suc n. f i) + f (Suc (Suc n))"
   475     by (rule setsum_atMost_Suc)
   476   also have "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
   477     by (rule IH)
   478   also have "f 0 + (\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) =
   479              f 0 + ((\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)))"
   480     by (rule add_assoc)
   481   also have "(\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) = (\<Sum>i\<le>Suc n. f (Suc i))"
   482     by (rule setsum_atMost_Suc [symmetric])
   483   finally show ?case .
   484 qed
   485 
   486 instantiation poly :: (comm_semiring_0) comm_semiring_0
   487 begin
   488 
   489 definition
   490   times_poly_def [code del]:
   491     "p * q = poly_rec 0 (\<lambda>a p pq. smult a q + pCons 0 pq) p"
   492 
   493 lemma mult_poly_0_left: "(0::'a poly) * q = 0"
   494   unfolding times_poly_def by (simp add: poly_rec_0)
   495 
   496 lemma mult_pCons_left [simp]:
   497   "pCons a p * q = smult a q + pCons 0 (p * q)"
   498   unfolding times_poly_def by (simp add: poly_rec_pCons)
   499 
   500 lemma mult_poly_0_right: "p * (0::'a poly) = 0"
   501   by (induct p, simp add: mult_poly_0_left, simp)
   502 
   503 lemma mult_pCons_right [simp]:
   504   "p * pCons a q = smult a p + pCons 0 (p * q)"
   505   by (induct p, simp add: mult_poly_0_left, simp add: ring_simps)
   506 
   507 lemmas mult_poly_0 = mult_poly_0_left mult_poly_0_right
   508 
   509 lemma mult_smult_left [simp]: "smult a p * q = smult a (p * q)"
   510   by (induct p, simp add: mult_poly_0, simp add: smult_add_right)
   511 
   512 lemma mult_smult_right [simp]: "p * smult a q = smult a (p * q)"
   513   by (induct q, simp add: mult_poly_0, simp add: smult_add_right)
   514 
   515 lemma mult_poly_add_left:
   516   fixes p q r :: "'a poly"
   517   shows "(p + q) * r = p * r + q * r"
   518   by (induct r, simp add: mult_poly_0,
   519                 simp add: smult_distribs group_simps)
   520 
   521 instance proof
   522   fix p q r :: "'a poly"
   523   show 0: "0 * p = 0"
   524     by (rule mult_poly_0_left)
   525   show "p * 0 = 0"
   526     by (rule mult_poly_0_right)
   527   show "(p + q) * r = p * r + q * r"
   528     by (rule mult_poly_add_left)
   529   show "(p * q) * r = p * (q * r)"
   530     by (induct p, simp add: mult_poly_0, simp add: mult_poly_add_left)
   531   show "p * q = q * p"
   532     by (induct p, simp add: mult_poly_0, simp)
   533 qed
   534 
   535 end
   536 
   537 lemma coeff_mult:
   538   "coeff (p * q) n = (\<Sum>i\<le>n. coeff p i * coeff q (n-i))"
   539 proof (induct p arbitrary: n)
   540   case 0 show ?case by simp
   541 next
   542   case (pCons a p n) thus ?case
   543     by (cases n, simp, simp add: setsum_atMost_Suc_shift
   544                             del: setsum_atMost_Suc)
   545 qed
   546 
   547 lemma degree_mult_le: "degree (p * q) \<le> degree p + degree q"
   548 apply (rule degree_le)
   549 apply (induct p)
   550 apply simp
   551 apply (simp add: coeff_eq_0 coeff_pCons split: nat.split)
   552 done
   553 
   554 lemma mult_monom: "monom a m * monom b n = monom (a * b) (m + n)"
   555   by (induct m, simp add: monom_0 smult_monom, simp add: monom_Suc)
   556 
   557 
   558 subsection {* The unit polynomial and exponentiation *}
   559 
   560 instantiation poly :: (comm_semiring_1) comm_semiring_1
   561 begin
   562 
   563 definition
   564   one_poly_def:
   565     "1 = pCons 1 0"
   566 
   567 instance proof
   568   fix p :: "'a poly" show "1 * p = p"
   569     unfolding one_poly_def
   570     by simp
   571 next
   572   show "0 \<noteq> (1::'a poly)"
   573     unfolding one_poly_def by simp
   574 qed
   575 
   576 end
   577 
   578 lemma coeff_1 [simp]: "coeff 1 n = (if n = 0 then 1 else 0)"
   579   unfolding one_poly_def
   580   by (simp add: coeff_pCons split: nat.split)
   581 
   582 lemma degree_1 [simp]: "degree 1 = 0"
   583   unfolding one_poly_def
   584   by (rule degree_pCons_0)
   585 
   586 instantiation poly :: (comm_semiring_1) recpower
   587 begin
   588 
   589 primrec power_poly where
   590   power_poly_0: "(p::'a poly) ^ 0 = 1"
   591 | power_poly_Suc: "(p::'a poly) ^ (Suc n) = p * p ^ n"
   592 
   593 instance
   594   by default simp_all
   595 
   596 end
   597 
   598 instance poly :: (comm_ring) comm_ring ..
   599 
   600 instance poly :: (comm_ring_1) comm_ring_1 ..
   601 
   602 instantiation poly :: (comm_ring_1) number_ring
   603 begin
   604 
   605 definition
   606   "number_of k = (of_int k :: 'a poly)"
   607 
   608 instance
   609   by default (rule number_of_poly_def)
   610 
   611 end
   612 
   613 
   614 subsection {* Polynomials form an integral domain *}
   615 
   616 lemma coeff_mult_degree_sum:
   617   "coeff (p * q) (degree p + degree q) =
   618    coeff p (degree p) * coeff q (degree q)"
   619   by (induct p, simp, simp add: coeff_eq_0)
   620 
   621 instance poly :: (idom) idom
   622 proof
   623   fix p q :: "'a poly"
   624   assume "p \<noteq> 0" and "q \<noteq> 0"
   625   have "coeff (p * q) (degree p + degree q) =
   626         coeff p (degree p) * coeff q (degree q)"
   627     by (rule coeff_mult_degree_sum)
   628   also have "coeff p (degree p) * coeff q (degree q) \<noteq> 0"
   629     using `p \<noteq> 0` and `q \<noteq> 0` by simp
   630   finally have "\<exists>n. coeff (p * q) n \<noteq> 0" ..
   631   thus "p * q \<noteq> 0" by (simp add: expand_poly_eq)
   632 qed
   633 
   634 lemma degree_mult_eq:
   635   fixes p q :: "'a::idom poly"
   636   shows "\<lbrakk>p \<noteq> 0; q \<noteq> 0\<rbrakk> \<Longrightarrow> degree (p * q) = degree p + degree q"
   637 apply (rule order_antisym [OF degree_mult_le le_degree])
   638 apply (simp add: coeff_mult_degree_sum)
   639 done
   640 
   641 lemma dvd_imp_degree_le:
   642   fixes p q :: "'a::idom poly"
   643   shows "\<lbrakk>p dvd q; q \<noteq> 0\<rbrakk> \<Longrightarrow> degree p \<le> degree q"
   644   by (erule dvdE, simp add: degree_mult_eq)
   645 
   646 
   647 subsection {* Long division of polynomials *}
   648 
   649 definition
   650   pdivmod_rel :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<Rightarrow> bool"
   651 where
   652   [code del]:
   653   "pdivmod_rel x y q r \<longleftrightarrow>
   654     x = q * y + r \<and> (if y = 0 then q = 0 else r = 0 \<or> degree r < degree y)"
   655 
   656 lemma pdivmod_rel_0:
   657   "pdivmod_rel 0 y 0 0"
   658   unfolding pdivmod_rel_def by simp
   659 
   660 lemma pdivmod_rel_by_0:
   661   "pdivmod_rel x 0 0 x"
   662   unfolding pdivmod_rel_def by simp
   663 
   664 lemma eq_zero_or_degree_less:
   665   assumes "degree p \<le> n" and "coeff p n = 0"
   666   shows "p = 0 \<or> degree p < n"
   667 proof (cases n)
   668   case 0
   669   with `degree p \<le> n` and `coeff p n = 0`
   670   have "coeff p (degree p) = 0" by simp
   671   then have "p = 0" by simp
   672   then show ?thesis ..
   673 next
   674   case (Suc m)
   675   have "\<forall>i>n. coeff p i = 0"
   676     using `degree p \<le> n` by (simp add: coeff_eq_0)
   677   then have "\<forall>i\<ge>n. coeff p i = 0"
   678     using `coeff p n = 0` by (simp add: le_less)
   679   then have "\<forall>i>m. coeff p i = 0"
   680     using `n = Suc m` by (simp add: less_eq_Suc_le)
   681   then have "degree p \<le> m"
   682     by (rule degree_le)
   683   then have "degree p < n"
   684     using `n = Suc m` by (simp add: less_Suc_eq_le)
   685   then show ?thesis ..
   686 qed
   687 
   688 lemma pdivmod_rel_pCons:
   689   assumes rel: "pdivmod_rel x y q r"
   690   assumes y: "y \<noteq> 0"
   691   assumes b: "b = coeff (pCons a r) (degree y) / coeff y (degree y)"
   692   shows "pdivmod_rel (pCons a x) y (pCons b q) (pCons a r - smult b y)"
   693     (is "pdivmod_rel ?x y ?q ?r")
   694 proof -
   695   have x: "x = q * y + r" and r: "r = 0 \<or> degree r < degree y"
   696     using assms unfolding pdivmod_rel_def by simp_all
   697 
   698   have 1: "?x = ?q * y + ?r"
   699     using b x by simp
   700 
   701   have 2: "?r = 0 \<or> degree ?r < degree y"
   702   proof (rule eq_zero_or_degree_less)
   703     have "degree ?r \<le> max (degree (pCons a r)) (degree (smult b y))"
   704       by (rule degree_diff_le)
   705     also have "\<dots> \<le> degree y"
   706     proof (rule min_max.le_supI)
   707       show "degree (pCons a r) \<le> degree y"
   708         using r by auto
   709       show "degree (smult b y) \<le> degree y"
   710         by (rule degree_smult_le)
   711     qed
   712     finally show "degree ?r \<le> degree y" .
   713   next
   714     show "coeff ?r (degree y) = 0"
   715       using `y \<noteq> 0` unfolding b by simp
   716   qed
   717 
   718   from 1 2 show ?thesis
   719     unfolding pdivmod_rel_def
   720     using `y \<noteq> 0` by simp
   721 qed
   722 
   723 lemma pdivmod_rel_exists: "\<exists>q r. pdivmod_rel x y q r"
   724 apply (cases "y = 0")
   725 apply (fast intro!: pdivmod_rel_by_0)
   726 apply (induct x)
   727 apply (fast intro!: pdivmod_rel_0)
   728 apply (fast intro!: pdivmod_rel_pCons)
   729 done
   730 
   731 lemma pdivmod_rel_unique:
   732   assumes 1: "pdivmod_rel x y q1 r1"
   733   assumes 2: "pdivmod_rel x y q2 r2"
   734   shows "q1 = q2 \<and> r1 = r2"
   735 proof (cases "y = 0")
   736   assume "y = 0" with assms show ?thesis
   737     by (simp add: pdivmod_rel_def)
   738 next
   739   assume [simp]: "y \<noteq> 0"
   740   from 1 have q1: "x = q1 * y + r1" and r1: "r1 = 0 \<or> degree r1 < degree y"
   741     unfolding pdivmod_rel_def by simp_all
   742   from 2 have q2: "x = q2 * y + r2" and r2: "r2 = 0 \<or> degree r2 < degree y"
   743     unfolding pdivmod_rel_def by simp_all
   744   from q1 q2 have q3: "(q1 - q2) * y = r2 - r1"
   745     by (simp add: ring_simps)
   746   from r1 r2 have r3: "(r2 - r1) = 0 \<or> degree (r2 - r1) < degree y"
   747     by (auto intro: degree_diff_less)
   748 
   749   show "q1 = q2 \<and> r1 = r2"
   750   proof (rule ccontr)
   751     assume "\<not> (q1 = q2 \<and> r1 = r2)"
   752     with q3 have "q1 \<noteq> q2" and "r1 \<noteq> r2" by auto
   753     with r3 have "degree (r2 - r1) < degree y" by simp
   754     also have "degree y \<le> degree (q1 - q2) + degree y" by simp
   755     also have "\<dots> = degree ((q1 - q2) * y)"
   756       using `q1 \<noteq> q2` by (simp add: degree_mult_eq)
   757     also have "\<dots> = degree (r2 - r1)"
   758       using q3 by simp
   759     finally have "degree (r2 - r1) < degree (r2 - r1)" .
   760     then show "False" by simp
   761   qed
   762 qed
   763 
   764 lemmas pdivmod_rel_unique_div =
   765   pdivmod_rel_unique [THEN conjunct1, standard]
   766 
   767 lemmas pdivmod_rel_unique_mod =
   768   pdivmod_rel_unique [THEN conjunct2, standard]
   769 
   770 instantiation poly :: (field) ring_div
   771 begin
   772 
   773 definition div_poly where
   774   [code del]: "x div y = (THE q. \<exists>r. pdivmod_rel x y q r)"
   775 
   776 definition mod_poly where
   777   [code del]: "x mod y = (THE r. \<exists>q. pdivmod_rel x y q r)"
   778 
   779 lemma div_poly_eq:
   780   "pdivmod_rel x y q r \<Longrightarrow> x div y = q"
   781 unfolding div_poly_def
   782 by (fast elim: pdivmod_rel_unique_div)
   783 
   784 lemma mod_poly_eq:
   785   "pdivmod_rel x y q r \<Longrightarrow> x mod y = r"
   786 unfolding mod_poly_def
   787 by (fast elim: pdivmod_rel_unique_mod)
   788 
   789 lemma pdivmod_rel:
   790   "pdivmod_rel x y (x div y) (x mod y)"
   791 proof -
   792   from pdivmod_rel_exists
   793     obtain q r where "pdivmod_rel x y q r" by fast
   794   thus ?thesis
   795     by (simp add: div_poly_eq mod_poly_eq)
   796 qed
   797 
   798 instance proof
   799   fix x y :: "'a poly"
   800   show "x div y * y + x mod y = x"
   801     using pdivmod_rel [of x y]
   802     by (simp add: pdivmod_rel_def)
   803 next
   804   fix x :: "'a poly"
   805   have "pdivmod_rel x 0 0 x"
   806     by (rule pdivmod_rel_by_0)
   807   thus "x div 0 = 0"
   808     by (rule div_poly_eq)
   809 next
   810   fix y :: "'a poly"
   811   have "pdivmod_rel 0 y 0 0"
   812     by (rule pdivmod_rel_0)
   813   thus "0 div y = 0"
   814     by (rule div_poly_eq)
   815 next
   816   fix x y z :: "'a poly"
   817   assume "y \<noteq> 0"
   818   hence "pdivmod_rel (x + z * y) y (z + x div y) (x mod y)"
   819     using pdivmod_rel [of x y]
   820     by (simp add: pdivmod_rel_def left_distrib)
   821   thus "(x + z * y) div y = z + x div y"
   822     by (rule div_poly_eq)
   823 qed
   824 
   825 end
   826 
   827 lemma degree_mod_less:
   828   "y \<noteq> 0 \<Longrightarrow> x mod y = 0 \<or> degree (x mod y) < degree y"
   829   using pdivmod_rel [of x y]
   830   unfolding pdivmod_rel_def by simp
   831 
   832 lemma div_poly_less: "degree x < degree y \<Longrightarrow> x div y = 0"
   833 proof -
   834   assume "degree x < degree y"
   835   hence "pdivmod_rel x y 0 x"
   836     by (simp add: pdivmod_rel_def)
   837   thus "x div y = 0" by (rule div_poly_eq)
   838 qed
   839 
   840 lemma mod_poly_less: "degree x < degree y \<Longrightarrow> x mod y = x"
   841 proof -
   842   assume "degree x < degree y"
   843   hence "pdivmod_rel x y 0 x"
   844     by (simp add: pdivmod_rel_def)
   845   thus "x mod y = x" by (rule mod_poly_eq)
   846 qed
   847 
   848 lemma mod_pCons:
   849   fixes a and x
   850   assumes y: "y \<noteq> 0"
   851   defines b: "b \<equiv> coeff (pCons a (x mod y)) (degree y) / coeff y (degree y)"
   852   shows "(pCons a x) mod y = (pCons a (x mod y) - smult b y)"
   853 unfolding b
   854 apply (rule mod_poly_eq)
   855 apply (rule pdivmod_rel_pCons [OF pdivmod_rel y refl])
   856 done
   857 
   858 
   859 subsection {* Evaluation of polynomials *}
   860 
   861 definition
   862   poly :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a" where
   863   "poly = poly_rec (\<lambda>x. 0) (\<lambda>a p f x. a + x * f x)"
   864 
   865 lemma poly_0 [simp]: "poly 0 x = 0"
   866   unfolding poly_def by (simp add: poly_rec_0)
   867 
   868 lemma poly_pCons [simp]: "poly (pCons a p) x = a + x * poly p x"
   869   unfolding poly_def by (simp add: poly_rec_pCons)
   870 
   871 lemma poly_1 [simp]: "poly 1 x = 1"
   872   unfolding one_poly_def by simp
   873 
   874 lemma poly_monom:
   875   fixes a x :: "'a::{comm_semiring_1,recpower}"
   876   shows "poly (monom a n) x = a * x ^ n"
   877   by (induct n, simp add: monom_0, simp add: monom_Suc power_Suc mult_ac)
   878 
   879 lemma poly_add [simp]: "poly (p + q) x = poly p x + poly q x"
   880   apply (induct p arbitrary: q, simp)
   881   apply (case_tac q, simp, simp add: ring_simps)
   882   done
   883 
   884 lemma poly_minus [simp]:
   885   fixes x :: "'a::comm_ring"
   886   shows "poly (- p) x = - poly p x"
   887   by (induct p, simp_all)
   888 
   889 lemma poly_diff [simp]:
   890   fixes x :: "'a::comm_ring"
   891   shows "poly (p - q) x = poly p x - poly q x"
   892   by (simp add: diff_minus)
   893 
   894 lemma poly_setsum: "poly (\<Sum>k\<in>A. p k) x = (\<Sum>k\<in>A. poly (p k) x)"
   895   by (cases "finite A", induct set: finite, simp_all)
   896 
   897 lemma poly_smult [simp]: "poly (smult a p) x = a * poly p x"
   898   by (induct p, simp, simp add: ring_simps)
   899 
   900 lemma poly_mult [simp]: "poly (p * q) x = poly p x * poly q x"
   901   by (induct p, simp_all, simp add: ring_simps)
   902 
   903 lemma poly_power [simp]:
   904   fixes p :: "'a::{comm_semiring_1,recpower} poly"
   905   shows "poly (p ^ n) x = poly p x ^ n"
   906   by (induct n, simp, simp add: power_Suc)
   907 
   908 
   909 subsection {* Synthetic division *}
   910 
   911 definition
   912   synthetic_divmod :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a poly \<times> 'a"
   913 where [code del]:
   914   "synthetic_divmod p c =
   915     poly_rec (0, 0) (\<lambda>a p (q, r). (pCons r q, a + c * r)) p"
   916 
   917 definition
   918   synthetic_div :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a poly"
   919 where
   920   "synthetic_div p c = fst (synthetic_divmod p c)"
   921 
   922 lemma synthetic_divmod_0 [simp]:
   923   "synthetic_divmod 0 c = (0, 0)"
   924   unfolding synthetic_divmod_def
   925   by (simp add: poly_rec_0)
   926 
   927 lemma synthetic_divmod_pCons [simp]:
   928   "synthetic_divmod (pCons a p) c =
   929     (\<lambda>(q, r). (pCons r q, a + c * r)) (synthetic_divmod p c)"
   930   unfolding synthetic_divmod_def
   931   by (simp add: poly_rec_pCons)
   932 
   933 lemma snd_synthetic_divmod: "snd (synthetic_divmod p c) = poly p c"
   934   by (induct p, simp, simp add: split_def)
   935 
   936 lemma synthetic_div_0 [simp]: "synthetic_div 0 c = 0"
   937   unfolding synthetic_div_def by simp
   938 
   939 lemma synthetic_div_pCons [simp]:
   940   "synthetic_div (pCons a p) c = pCons (poly p c) (synthetic_div p c)"
   941   unfolding synthetic_div_def
   942   by (simp add: split_def snd_synthetic_divmod)
   943 
   944 lemma synthetic_div_eq_0_iff:
   945   "synthetic_div p c = 0 \<longleftrightarrow> degree p = 0"
   946   by (induct p, simp, case_tac p, simp)
   947 
   948 lemma degree_synthetic_div:
   949   "degree (synthetic_div p c) = degree p - 1"
   950   by (induct p, simp, simp add: synthetic_div_eq_0_iff)
   951 
   952 lemma synthetic_div_correct:
   953   "p + smult c (synthetic_div p c) = pCons (poly p c) (synthetic_div p c)"
   954   by (induct p) simp_all
   955 
   956 lemma synthetic_div_unique_lemma: "smult c p = pCons a p \<Longrightarrow> p = 0"
   957 by (induct p arbitrary: a) simp_all
   958 
   959 lemma synthetic_div_unique:
   960   "p + smult c q = pCons r q \<Longrightarrow> r = poly p c \<and> q = synthetic_div p c"
   961 apply (induct p arbitrary: q r)
   962 apply (simp, frule synthetic_div_unique_lemma, simp)
   963 apply (case_tac q, force)
   964 done
   965 
   966 lemma synthetic_div_correct':
   967   fixes c :: "'a::comm_ring_1"
   968   shows "[:-c, 1:] * synthetic_div p c + [:poly p c:] = p"
   969   using synthetic_div_correct [of p c]
   970   by (simp add: group_simps)
   971 
   972 lemma poly_eq_0_iff_dvd:
   973   fixes c :: "'a::idom"
   974   shows "poly p c = 0 \<longleftrightarrow> [:-c, 1:] dvd p"
   975 proof
   976   assume "poly p c = 0"
   977   with synthetic_div_correct' [of c p]
   978   have "p = [:-c, 1:] * synthetic_div p c" by simp
   979   then show "[:-c, 1:] dvd p" ..
   980 next
   981   assume "[:-c, 1:] dvd p"
   982   then obtain k where "p = [:-c, 1:] * k" by (rule dvdE)
   983   then show "poly p c = 0" by simp
   984 qed
   985 
   986 lemma dvd_iff_poly_eq_0:
   987   fixes c :: "'a::idom"
   988   shows "[:c, 1:] dvd p \<longleftrightarrow> poly p (-c) = 0"
   989   by (simp add: poly_eq_0_iff_dvd)
   990 
   991 lemma poly_roots_finite:
   992   fixes p :: "'a::idom poly"
   993   shows "p \<noteq> 0 \<Longrightarrow> finite {x. poly p x = 0}"
   994 proof (induct n \<equiv> "degree p" arbitrary: p)
   995   case (0 p)
   996   then obtain a where "a \<noteq> 0" and "p = [:a:]"
   997     by (cases p, simp split: if_splits)
   998   then show "finite {x. poly p x = 0}" by simp
   999 next
  1000   case (Suc n p)
  1001   show "finite {x. poly p x = 0}"
  1002   proof (cases "\<exists>x. poly p x = 0")
  1003     case False
  1004     then show "finite {x. poly p x = 0}" by simp
  1005   next
  1006     case True
  1007     then obtain a where "poly p a = 0" ..
  1008     then have "[:-a, 1:] dvd p" by (simp only: poly_eq_0_iff_dvd)
  1009     then obtain k where k: "p = [:-a, 1:] * k" ..
  1010     with `p \<noteq> 0` have "k \<noteq> 0" by auto
  1011     with k have "degree p = Suc (degree k)"
  1012       by (simp add: degree_mult_eq del: mult_pCons_left)
  1013     with `Suc n = degree p` have "n = degree k" by simp
  1014     with `k \<noteq> 0` have "finite {x. poly k x = 0}" by (rule Suc.hyps)
  1015     then have "finite (insert a {x. poly k x = 0})" by simp
  1016     then show "finite {x. poly p x = 0}"
  1017       by (simp add: k uminus_add_conv_diff Collect_disj_eq
  1018                del: mult_pCons_left)
  1019   qed
  1020 qed
  1021 
  1022 
  1023 subsection {* Configuration of the code generator *}
  1024 
  1025 code_datatype "0::'a::zero poly" pCons
  1026 
  1027 declare pCons_0_0 [code post]
  1028 
  1029 instantiation poly :: ("{zero,eq}") eq
  1030 begin
  1031 
  1032 definition [code del]:
  1033   "eq_class.eq (p::'a poly) q \<longleftrightarrow> p = q"
  1034 
  1035 instance
  1036   by default (rule eq_poly_def)
  1037 
  1038 end
  1039 
  1040 lemma eq_poly_code [code]:
  1041   "eq_class.eq (0::_ poly) (0::_ poly) \<longleftrightarrow> True"
  1042   "eq_class.eq (0::_ poly) (pCons b q) \<longleftrightarrow> eq_class.eq 0 b \<and> eq_class.eq 0 q"
  1043   "eq_class.eq (pCons a p) (0::_ poly) \<longleftrightarrow> eq_class.eq a 0 \<and> eq_class.eq p 0"
  1044   "eq_class.eq (pCons a p) (pCons b q) \<longleftrightarrow> eq_class.eq a b \<and> eq_class.eq p q"
  1045 unfolding eq by simp_all
  1046 
  1047 lemmas coeff_code [code] =
  1048   coeff_0 coeff_pCons_0 coeff_pCons_Suc
  1049 
  1050 lemmas degree_code [code] =
  1051   degree_0 degree_pCons_eq_if
  1052 
  1053 lemmas monom_poly_code [code] =
  1054   monom_0 monom_Suc
  1055 
  1056 lemma add_poly_code [code]:
  1057   "0 + q = (q :: _ poly)"
  1058   "p + 0 = (p :: _ poly)"
  1059   "pCons a p + pCons b q = pCons (a + b) (p + q)"
  1060 by simp_all
  1061 
  1062 lemma minus_poly_code [code]:
  1063   "- 0 = (0 :: _ poly)"
  1064   "- pCons a p = pCons (- a) (- p)"
  1065 by simp_all
  1066 
  1067 lemma diff_poly_code [code]:
  1068   "0 - q = (- q :: _ poly)"
  1069   "p - 0 = (p :: _ poly)"
  1070   "pCons a p - pCons b q = pCons (a - b) (p - q)"
  1071 by simp_all
  1072 
  1073 lemmas smult_poly_code [code] =
  1074   smult_0_right smult_pCons
  1075 
  1076 lemma mult_poly_code [code]:
  1077   "0 * q = (0 :: _ poly)"
  1078   "pCons a p * q = smult a q + pCons 0 (p * q)"
  1079 by simp_all
  1080 
  1081 lemmas poly_code [code] =
  1082   poly_0 poly_pCons
  1083 
  1084 lemmas synthetic_divmod_code [code] =
  1085   synthetic_divmod_0 synthetic_divmod_pCons
  1086 
  1087 text {* code generator setup for div and mod *}
  1088 
  1089 definition
  1090   pdivmod :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<times> 'a poly"
  1091 where
  1092   [code del]: "pdivmod x y = (x div y, x mod y)"
  1093 
  1094 lemma div_poly_code [code]: "x div y = fst (pdivmod x y)"
  1095   unfolding pdivmod_def by simp
  1096 
  1097 lemma mod_poly_code [code]: "x mod y = snd (pdivmod x y)"
  1098   unfolding pdivmod_def by simp
  1099 
  1100 lemma pdivmod_0 [code]: "pdivmod 0 y = (0, 0)"
  1101   unfolding pdivmod_def by simp
  1102 
  1103 lemma pdivmod_pCons [code]:
  1104   "pdivmod (pCons a x) y =
  1105     (if y = 0 then (0, pCons a x) else
  1106       (let (q, r) = pdivmod x y;
  1107            b = coeff (pCons a r) (degree y) / coeff y (degree y)
  1108         in (pCons b q, pCons a r - smult b y)))"
  1109 apply (simp add: pdivmod_def Let_def, safe)
  1110 apply (rule div_poly_eq)
  1111 apply (erule pdivmod_rel_pCons [OF pdivmod_rel _ refl])
  1112 apply (rule mod_poly_eq)
  1113 apply (erule pdivmod_rel_pCons [OF pdivmod_rel _ refl])
  1114 done
  1115 
  1116 end