src/Pure/raw_simplifier.ML
author wenzelm
Tue Apr 05 20:03:24 2016 +0200 (2016-04-05)
changeset 62876 507c90523113
parent 61354 1727d7d14d76
child 62913 13252110a6fe
permissions -rw-r--r--
clarified modules -- simplified bootstrap;
     1 (*  Title:      Pure/raw_simplifier.ML
     2     Author:     Tobias Nipkow and Stefan Berghofer, TU Muenchen
     3 
     4 Higher-order Simplification.
     5 *)
     6 
     7 infix 4
     8   addsimps delsimps addsimprocs delsimprocs
     9   setloop addloop delloop
    10   setSSolver addSSolver setSolver addSolver;
    11 
    12 signature BASIC_RAW_SIMPLIFIER =
    13 sig
    14   val simp_depth_limit: int Config.T
    15   val simp_trace_depth_limit: int Config.T
    16   val simp_debug: bool Config.T
    17   val simp_trace: bool Config.T
    18   type cong_name = bool * string
    19   type rrule
    20   val mk_rrules: Proof.context -> thm list -> rrule list
    21   val eq_rrule: rrule * rrule -> bool
    22   type proc
    23   type solver
    24   val mk_solver: string -> (Proof.context -> int -> tactic) -> solver
    25   type simpset
    26   val empty_ss: simpset
    27   val merge_ss: simpset * simpset -> simpset
    28   val dest_ss: simpset ->
    29    {simps: (string * thm) list,
    30     procs: (string * term list) list,
    31     congs: (cong_name * thm) list,
    32     weak_congs: cong_name list,
    33     loopers: string list,
    34     unsafe_solvers: string list,
    35     safe_solvers: string list}
    36   type simproc
    37   val eq_simproc: simproc * simproc -> bool
    38   val cert_simproc: theory -> string ->
    39     {lhss: term list, proc: morphism -> Proof.context -> cterm -> thm option, identifier: thm list}
    40     -> simproc
    41   val transform_simproc: morphism -> simproc -> simproc
    42   val simpset_of: Proof.context -> simpset
    43   val put_simpset: simpset -> Proof.context -> Proof.context
    44   val simpset_map: Proof.context -> (Proof.context -> Proof.context) -> simpset -> simpset
    45   val map_theory_simpset: (Proof.context -> Proof.context) -> theory -> theory
    46   val empty_simpset: Proof.context -> Proof.context
    47   val clear_simpset: Proof.context -> Proof.context
    48   val addsimps: Proof.context * thm list -> Proof.context
    49   val delsimps: Proof.context * thm list -> Proof.context
    50   val addsimprocs: Proof.context * simproc list -> Proof.context
    51   val delsimprocs: Proof.context * simproc list -> Proof.context
    52   val setloop: Proof.context * (Proof.context -> int -> tactic) -> Proof.context
    53   val addloop: Proof.context * (string * (Proof.context -> int -> tactic)) -> Proof.context
    54   val delloop: Proof.context * string -> Proof.context
    55   val setSSolver: Proof.context * solver -> Proof.context
    56   val addSSolver: Proof.context * solver -> Proof.context
    57   val setSolver: Proof.context * solver -> Proof.context
    58   val addSolver: Proof.context * solver -> Proof.context
    59 
    60   val rewrite_rule: Proof.context -> thm list -> thm -> thm
    61   val rewrite_goals_rule: Proof.context -> thm list -> thm -> thm
    62   val rewrite_goals_tac: Proof.context -> thm list -> tactic
    63   val rewrite_goal_tac: Proof.context -> thm list -> int -> tactic
    64   val prune_params_tac: Proof.context -> tactic
    65   val fold_rule: Proof.context -> thm list -> thm -> thm
    66   val fold_goals_tac: Proof.context -> thm list -> tactic
    67   val norm_hhf: Proof.context -> thm -> thm
    68   val norm_hhf_protect: Proof.context -> thm -> thm
    69 end;
    70 
    71 signature RAW_SIMPLIFIER =
    72 sig
    73   include BASIC_RAW_SIMPLIFIER
    74   exception SIMPLIFIER of string * thm list
    75   type trace_ops
    76   val set_trace_ops: trace_ops -> theory -> theory
    77   val internal_ss: simpset ->
    78    {congs: (cong_name * thm) list * cong_name list,
    79     procs: proc Net.net,
    80     mk_rews:
    81      {mk: Proof.context -> thm -> thm list,
    82       mk_cong: Proof.context -> thm -> thm,
    83       mk_sym: Proof.context -> thm -> thm option,
    84       mk_eq_True: Proof.context -> thm -> thm option,
    85       reorient: Proof.context -> term list -> term -> term -> bool},
    86     termless: term * term -> bool,
    87     subgoal_tac: Proof.context -> int -> tactic,
    88     loop_tacs: (string * (Proof.context -> int -> tactic)) list,
    89     solvers: solver list * solver list}
    90   val map_ss: (Proof.context -> Proof.context) -> Context.generic -> Context.generic
    91   val prems_of: Proof.context -> thm list
    92   val add_simp: thm -> Proof.context -> Proof.context
    93   val del_simp: thm -> Proof.context -> Proof.context
    94   val add_eqcong: thm -> Proof.context -> Proof.context
    95   val del_eqcong: thm -> Proof.context -> Proof.context
    96   val add_cong: thm -> Proof.context -> Proof.context
    97   val del_cong: thm -> Proof.context -> Proof.context
    98   val mksimps: Proof.context -> thm -> thm list
    99   val set_mksimps: (Proof.context -> thm -> thm list) -> Proof.context -> Proof.context
   100   val set_mkcong: (Proof.context -> thm -> thm) -> Proof.context -> Proof.context
   101   val set_mksym: (Proof.context -> thm -> thm option) -> Proof.context -> Proof.context
   102   val set_mkeqTrue: (Proof.context -> thm -> thm option) -> Proof.context -> Proof.context
   103   val set_termless: (term * term -> bool) -> Proof.context -> Proof.context
   104   val set_subgoaler: (Proof.context -> int -> tactic) -> Proof.context -> Proof.context
   105   val solver: Proof.context -> solver -> int -> tactic
   106   val simp_depth_limit_raw: Config.raw
   107   val default_mk_sym: Proof.context -> thm -> thm option
   108   val simp_trace_depth_limit_raw: Config.raw
   109   val simp_trace_raw: Config.raw
   110   val simp_debug_raw: Config.raw
   111   val add_prems: thm list -> Proof.context -> Proof.context
   112   val set_reorient: (Proof.context -> term list -> term -> term -> bool) ->
   113     Proof.context -> Proof.context
   114   val set_solvers: solver list -> Proof.context -> Proof.context
   115   val rewrite_cterm: bool * bool * bool ->
   116     (Proof.context -> thm -> thm option) -> Proof.context -> conv
   117   val rewrite_term: theory -> thm list -> (term -> term option) list -> term -> term
   118   val rewrite_thm: bool * bool * bool ->
   119     (Proof.context -> thm -> thm option) -> Proof.context -> thm -> thm
   120   val generic_rewrite_goal_tac: bool * bool * bool ->
   121     (Proof.context -> tactic) -> Proof.context -> int -> tactic
   122   val rewrite: Proof.context -> bool -> thm list -> conv
   123 end;
   124 
   125 structure Raw_Simplifier: RAW_SIMPLIFIER =
   126 struct
   127 
   128 (** datatype simpset **)
   129 
   130 (* congruence rules *)
   131 
   132 type cong_name = bool * string;
   133 
   134 fun cong_name (Const (a, _)) = SOME (true, a)
   135   | cong_name (Free (a, _)) = SOME (false, a)
   136   | cong_name _ = NONE;
   137 
   138 
   139 (* rewrite rules *)
   140 
   141 type rrule =
   142  {thm: thm,         (*the rewrite rule*)
   143   name: string,     (*name of theorem from which rewrite rule was extracted*)
   144   lhs: term,        (*the left-hand side*)
   145   elhs: cterm,      (*the eta-contracted lhs*)
   146   extra: bool,      (*extra variables outside of elhs*)
   147   fo: bool,         (*use first-order matching*)
   148   perm: bool};      (*the rewrite rule is permutative*)
   149 
   150 fun trim_context_rrule ({thm, name, lhs, elhs, extra, fo, perm}: rrule) =
   151   {thm = Thm.trim_context thm, name = name, lhs = lhs, elhs = Thm.trim_context_cterm elhs,
   152     extra = extra, fo = fo, perm = perm};
   153 
   154 (*
   155 Remarks:
   156   - elhs is used for matching,
   157     lhs only for preservation of bound variable names;
   158   - fo is set iff
   159     either elhs is first-order (no Var is applied),
   160       in which case fo-matching is complete,
   161     or elhs is not a pattern,
   162       in which case there is nothing better to do;
   163 *)
   164 
   165 fun eq_rrule ({thm = thm1, ...}: rrule, {thm = thm2, ...}: rrule) =
   166   Thm.eq_thm_prop (thm1, thm2);
   167 
   168 (* FIXME: it seems that the conditions on extra variables are too liberal if
   169 prems are nonempty: does solving the prems really guarantee instantiation of
   170 all its Vars? Better: a dynamic check each time a rule is applied.
   171 *)
   172 fun rewrite_rule_extra_vars prems elhs erhs =
   173   let
   174     val elhss = elhs :: prems;
   175     val tvars = fold Term.add_tvars elhss [];
   176     val vars = fold Term.add_vars elhss [];
   177   in
   178     erhs |> Term.exists_type (Term.exists_subtype
   179       (fn TVar v => not (member (op =) tvars v) | _ => false)) orelse
   180     erhs |> Term.exists_subterm
   181       (fn Var v => not (member (op =) vars v) | _ => false)
   182   end;
   183 
   184 fun rrule_extra_vars elhs thm =
   185   rewrite_rule_extra_vars [] (Thm.term_of elhs) (Thm.full_prop_of thm);
   186 
   187 fun mk_rrule2 {thm, name, lhs, elhs, perm} =
   188   let
   189     val t = Thm.term_of elhs;
   190     val fo = Pattern.first_order t orelse not (Pattern.pattern t);
   191     val extra = rrule_extra_vars elhs thm;
   192   in {thm = thm, name = name, lhs = lhs, elhs = elhs, extra = extra, fo = fo, perm = perm} end;
   193 
   194 (*simple test for looping rewrite rules and stupid orientations*)
   195 fun default_reorient ctxt prems lhs rhs =
   196   rewrite_rule_extra_vars prems lhs rhs
   197     orelse
   198   is_Var (head_of lhs)
   199     orelse
   200 (* turns t = x around, which causes a headache if x is a local variable -
   201    usually it is very useful :-(
   202   is_Free rhs andalso not(is_Free lhs) andalso not(Logic.occs(rhs,lhs))
   203   andalso not(exists_subterm is_Var lhs)
   204     orelse
   205 *)
   206   exists (fn t => Logic.occs (lhs, t)) (rhs :: prems)
   207     orelse
   208   null prems andalso Pattern.matches (Proof_Context.theory_of ctxt) (lhs, rhs)
   209     (*the condition "null prems" is necessary because conditional rewrites
   210       with extra variables in the conditions may terminate although
   211       the rhs is an instance of the lhs; example: ?m < ?n ==> f(?n) == f(?m)*)
   212     orelse
   213   is_Const lhs andalso not (is_Const rhs);
   214 
   215 
   216 (* simplification procedures *)
   217 
   218 datatype proc =
   219   Proc of
   220    {name: string,
   221     lhs: term,
   222     proc: Proof.context -> cterm -> thm option,
   223     id: stamp * thm list};
   224 
   225 fun eq_procid ((s1: stamp, ths1: thm list), (s2, ths2)) =
   226   s1 = s2 andalso eq_list Thm.eq_thm (ths1, ths2);
   227 
   228 fun eq_proc (Proc {id = id1, ...}, Proc {id = id2, ...}) = eq_procid (id1, id2);
   229 
   230 
   231 (* solvers *)
   232 
   233 datatype solver =
   234   Solver of
   235    {name: string,
   236     solver: Proof.context -> int -> tactic,
   237     id: stamp};
   238 
   239 fun mk_solver name solver = Solver {name = name, solver = solver, id = stamp ()};
   240 
   241 fun solver_name (Solver {name, ...}) = name;
   242 fun solver ctxt (Solver {solver = tac, ...}) = tac ctxt;
   243 fun eq_solver (Solver {id = id1, ...}, Solver {id = id2, ...}) = (id1 = id2);
   244 
   245 
   246 (* simplification sets *)
   247 
   248 (*A simpset contains data required during conversion:
   249     rules: discrimination net of rewrite rules;
   250     prems: current premises;
   251     depth: simp_depth and exceeded flag;
   252     congs: association list of congruence rules and
   253            a list of `weak' congruence constants.
   254            A congruence is `weak' if it avoids normalization of some argument.
   255     procs: discrimination net of simplification procedures
   256       (functions that prove rewrite rules on the fly);
   257     mk_rews:
   258       mk: turn simplification thms into rewrite rules;
   259       mk_cong: prepare congruence rules;
   260       mk_sym: turn == around;
   261       mk_eq_True: turn P into P == True;
   262     termless: relation for ordered rewriting;*)
   263 
   264 datatype simpset =
   265   Simpset of
   266    {rules: rrule Net.net,
   267     prems: thm list,
   268     depth: int * bool Unsynchronized.ref} *
   269    {congs: (cong_name * thm) list * cong_name list,
   270     procs: proc Net.net,
   271     mk_rews:
   272      {mk: Proof.context -> thm -> thm list,
   273       mk_cong: Proof.context -> thm -> thm,
   274       mk_sym: Proof.context -> thm -> thm option,
   275       mk_eq_True: Proof.context -> thm -> thm option,
   276       reorient: Proof.context -> term list -> term -> term -> bool},
   277     termless: term * term -> bool,
   278     subgoal_tac: Proof.context -> int -> tactic,
   279     loop_tacs: (string * (Proof.context -> int -> tactic)) list,
   280     solvers: solver list * solver list};
   281 
   282 fun internal_ss (Simpset (_, ss2)) = ss2;
   283 
   284 fun make_ss1 (rules, prems, depth) = {rules = rules, prems = prems, depth = depth};
   285 
   286 fun map_ss1 f {rules, prems, depth} = make_ss1 (f (rules, prems, depth));
   287 
   288 fun make_ss2 (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =
   289   {congs = congs, procs = procs, mk_rews = mk_rews, termless = termless,
   290     subgoal_tac = subgoal_tac, loop_tacs = loop_tacs, solvers = solvers};
   291 
   292 fun map_ss2 f {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers} =
   293   make_ss2 (f (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   294 
   295 fun make_simpset (args1, args2) = Simpset (make_ss1 args1, make_ss2 args2);
   296 
   297 fun dest_ss (Simpset ({rules, ...}, {congs, procs, loop_tacs, solvers, ...})) =
   298  {simps = Net.entries rules
   299     |> map (fn {name, thm, ...} => (name, thm)),
   300   procs = Net.entries procs
   301     |> map (fn Proc {name, lhs, id, ...} => ((name, lhs), id))
   302     |> partition_eq (eq_snd eq_procid)
   303     |> map (fn ps => (fst (fst (hd ps)), map (snd o fst) ps)),
   304   congs = #1 congs,
   305   weak_congs = #2 congs,
   306   loopers = map fst loop_tacs,
   307   unsafe_solvers = map solver_name (#1 solvers),
   308   safe_solvers = map solver_name (#2 solvers)};
   309 
   310 
   311 (* empty *)
   312 
   313 fun init_ss depth mk_rews termless subgoal_tac solvers =
   314   make_simpset ((Net.empty, [], depth),
   315     (([], []), Net.empty, mk_rews, termless, subgoal_tac, [], solvers));
   316 
   317 fun default_mk_sym _ th = SOME (th RS Drule.symmetric_thm);
   318 
   319 val empty_ss =
   320   init_ss (0, Unsynchronized.ref false)
   321     {mk = fn _ => fn th => if can Logic.dest_equals (Thm.concl_of th) then [th] else [],
   322       mk_cong = K I,
   323       mk_sym = default_mk_sym,
   324       mk_eq_True = K (K NONE),
   325       reorient = default_reorient}
   326     Term_Ord.termless (K (K no_tac)) ([], []);
   327 
   328 
   329 (* merge *)  (*NOTE: ignores some fields of 2nd simpset*)
   330 
   331 fun merge_ss (ss1, ss2) =
   332   if pointer_eq (ss1, ss2) then ss1
   333   else
   334     let
   335       val Simpset ({rules = rules1, prems = prems1, depth = depth1},
   336        {congs = (congs1, weak1), procs = procs1, mk_rews, termless, subgoal_tac,
   337         loop_tacs = loop_tacs1, solvers = (unsafe_solvers1, solvers1)}) = ss1;
   338       val Simpset ({rules = rules2, prems = prems2, depth = depth2},
   339        {congs = (congs2, weak2), procs = procs2, mk_rews = _, termless = _, subgoal_tac = _,
   340         loop_tacs = loop_tacs2, solvers = (unsafe_solvers2, solvers2)}) = ss2;
   341 
   342       val rules' = Net.merge eq_rrule (rules1, rules2);
   343       val prems' = Thm.merge_thms (prems1, prems2);
   344       val depth' = if #1 depth1 < #1 depth2 then depth2 else depth1;
   345       val congs' = merge (Thm.eq_thm_prop o apply2 #2) (congs1, congs2);
   346       val weak' = merge (op =) (weak1, weak2);
   347       val procs' = Net.merge eq_proc (procs1, procs2);
   348       val loop_tacs' = AList.merge (op =) (K true) (loop_tacs1, loop_tacs2);
   349       val unsafe_solvers' = merge eq_solver (unsafe_solvers1, unsafe_solvers2);
   350       val solvers' = merge eq_solver (solvers1, solvers2);
   351     in
   352       make_simpset ((rules', prems', depth'), ((congs', weak'), procs',
   353         mk_rews, termless, subgoal_tac, loop_tacs', (unsafe_solvers', solvers')))
   354     end;
   355 
   356 
   357 
   358 (** context data **)
   359 
   360 structure Simpset = Generic_Data
   361 (
   362   type T = simpset;
   363   val empty = empty_ss;
   364   val extend = I;
   365   val merge = merge_ss;
   366 );
   367 
   368 val simpset_of = Simpset.get o Context.Proof;
   369 
   370 fun map_simpset f = Context.proof_map (Simpset.map f);
   371 fun map_simpset1 f = map_simpset (fn Simpset (ss1, ss2) => Simpset (map_ss1 f ss1, ss2));
   372 fun map_simpset2 f = map_simpset (fn Simpset (ss1, ss2) => Simpset (ss1, map_ss2 f ss2));
   373 
   374 fun simpset_map ctxt f ss = ctxt |> map_simpset (K ss) |> f |> Context.Proof |> Simpset.get;
   375 
   376 fun put_simpset ss = map_simpset (K ss);
   377 
   378 val empty_simpset = put_simpset empty_ss;
   379 
   380 fun map_theory_simpset f thy =
   381   let
   382     val ctxt' = f (Proof_Context.init_global thy);
   383     val thy' = Proof_Context.theory_of ctxt';
   384   in Context.theory_map (Simpset.map (K (simpset_of ctxt'))) thy' end;
   385 
   386 fun map_ss f = Context.mapping (map_theory_simpset (f o Context_Position.not_really)) f;
   387 
   388 val clear_simpset =
   389   map_simpset (fn Simpset ({depth, ...}, {mk_rews, termless, subgoal_tac, solvers, ...}) =>
   390     init_ss depth mk_rews termless subgoal_tac solvers);
   391 
   392 
   393 (* simp depth *)
   394 
   395 val simp_depth_limit_raw = Config.declare ("simp_depth_limit", @{here}) (K (Config.Int 100));
   396 val simp_depth_limit = Config.int simp_depth_limit_raw;
   397 
   398 val simp_trace_depth_limit_raw =
   399   Config.declare ("simp_trace_depth_limit", @{here}) (fn _ => Config.Int 1);
   400 val simp_trace_depth_limit = Config.int simp_trace_depth_limit_raw;
   401 
   402 fun inc_simp_depth ctxt =
   403   ctxt |> map_simpset1 (fn (rules, prems, (depth, exceeded)) =>
   404     (rules, prems,
   405       (depth + 1,
   406         if depth = Config.get ctxt simp_trace_depth_limit
   407         then Unsynchronized.ref false else exceeded)));
   408 
   409 fun simp_depth ctxt =
   410   let val Simpset ({depth = (depth, _), ...}, _) = simpset_of ctxt
   411   in depth end;
   412 
   413 
   414 (* diagnostics *)
   415 
   416 exception SIMPLIFIER of string * thm list;
   417 
   418 val simp_debug_raw = Config.declare ("simp_debug", @{here}) (K (Config.Bool false));
   419 val simp_debug = Config.bool simp_debug_raw;
   420 
   421 val simp_trace_raw = Config.declare ("simp_trace", @{here}) (fn _ => Config.Bool false);
   422 val simp_trace = Config.bool simp_trace_raw;
   423 
   424 fun cond_warning ctxt msg =
   425   if Context_Position.is_really_visible ctxt then warning (msg ()) else ();
   426 
   427 fun cond_tracing' ctxt flag msg =
   428   if Config.get ctxt flag then
   429     let
   430       val Simpset ({depth = (depth, exceeded), ...}, _) = simpset_of ctxt;
   431       val depth_limit = Config.get ctxt simp_trace_depth_limit;
   432     in
   433       if depth > depth_limit then
   434         if ! exceeded then () else (tracing "simp_trace_depth_limit exceeded!"; exceeded := true)
   435       else (tracing (enclose "[" "]" (string_of_int depth) ^ msg ()); exceeded := false)
   436     end
   437   else ();
   438 
   439 fun cond_tracing ctxt = cond_tracing' ctxt simp_trace;
   440 
   441 fun print_term ctxt s t =
   442   s ^ "\n" ^ Syntax.string_of_term ctxt t;
   443 
   444 fun print_thm ctxt s (name, th) =
   445   print_term ctxt (if name = "" then s else s ^ " " ^ quote name ^ ":") (Thm.full_prop_of th);
   446 
   447 
   448 
   449 (** simpset operations **)
   450 
   451 (* prems *)
   452 
   453 fun prems_of ctxt =
   454   let val Simpset ({prems, ...}, _) = simpset_of ctxt in prems end;
   455 
   456 fun add_prems ths =
   457   map_simpset1 (fn (rules, prems, depth) => (rules, ths @ prems, depth));
   458 
   459 
   460 (* maintain simp rules *)
   461 
   462 fun del_rrule (rrule as {thm, elhs, ...}) ctxt =
   463   ctxt |> map_simpset1 (fn (rules, prems, depth) =>
   464     (Net.delete_term eq_rrule (Thm.term_of elhs, rrule) rules, prems, depth))
   465   handle Net.DELETE =>
   466     (cond_warning ctxt (fn () => print_thm ctxt "Rewrite rule not in simpset:" ("", thm)); ctxt);
   467 
   468 fun insert_rrule (rrule as {thm, name, ...}) ctxt =
   469  (cond_tracing ctxt (fn () => print_thm ctxt "Adding rewrite rule" (name, thm));
   470   ctxt |> map_simpset1 (fn (rules, prems, depth) =>
   471     let
   472       val rrule2 as {elhs, ...} = mk_rrule2 rrule;
   473       val rules' = Net.insert_term eq_rrule (Thm.term_of elhs, trim_context_rrule rrule2) rules;
   474     in (rules', prems, depth) end)
   475   handle Net.INSERT =>
   476     (cond_warning ctxt (fn () => print_thm ctxt "Ignoring duplicate rewrite rule:" ("", thm));
   477       ctxt));
   478 
   479 local
   480 
   481 fun vperm (Var _, Var _) = true
   482   | vperm (Abs (_, _, s), Abs (_, _, t)) = vperm (s, t)
   483   | vperm (t1 $ t2, u1 $ u2) = vperm (t1, u1) andalso vperm (t2, u2)
   484   | vperm (t, u) = (t = u);
   485 
   486 fun var_perm (t, u) =
   487   vperm (t, u) andalso eq_set (op =) (Term.add_vars t [], Term.add_vars u []);
   488 
   489 in
   490 
   491 fun decomp_simp thm =
   492   let
   493     val prop = Thm.prop_of thm;
   494     val prems = Logic.strip_imp_prems prop;
   495     val concl = Drule.strip_imp_concl (Thm.cprop_of thm);
   496     val (lhs, rhs) = Thm.dest_equals concl handle TERM _ =>
   497       raise SIMPLIFIER ("Rewrite rule not a meta-equality", [thm]);
   498     val elhs = Thm.dest_arg (Thm.cprop_of (Thm.eta_conversion lhs));
   499     val erhs = Envir.eta_contract (Thm.term_of rhs);
   500     val perm =
   501       var_perm (Thm.term_of elhs, erhs) andalso
   502       not (Thm.term_of elhs aconv erhs) andalso
   503       not (is_Var (Thm.term_of elhs));
   504   in (prems, Thm.term_of lhs, elhs, Thm.term_of rhs, perm) end;
   505 
   506 end;
   507 
   508 fun decomp_simp' thm =
   509   let val (_, lhs, _, rhs, _) = decomp_simp thm in
   510     if Thm.nprems_of thm > 0 then raise SIMPLIFIER ("Bad conditional rewrite rule", [thm])
   511     else (lhs, rhs)
   512   end;
   513 
   514 fun mk_eq_True ctxt (thm, name) =
   515   let val Simpset (_, {mk_rews = {mk_eq_True, ...}, ...}) = simpset_of ctxt in
   516     (case mk_eq_True ctxt thm of
   517       NONE => []
   518     | SOME eq_True =>
   519         let val (_, lhs, elhs, _, _) = decomp_simp eq_True;
   520         in [{thm = eq_True, name = name, lhs = lhs, elhs = elhs, perm = false}] end)
   521   end;
   522 
   523 (*create the rewrite rule and possibly also the eq_True variant,
   524   in case there are extra vars on the rhs*)
   525 fun rrule_eq_True ctxt thm name lhs elhs rhs thm2 =
   526   let val rrule = {thm = thm, name = name, lhs = lhs, elhs = elhs, perm = false} in
   527     if rewrite_rule_extra_vars [] lhs rhs then
   528       mk_eq_True ctxt (thm2, name) @ [rrule]
   529     else [rrule]
   530   end;
   531 
   532 fun mk_rrule ctxt (thm, name) =
   533   let val (prems, lhs, elhs, rhs, perm) = decomp_simp thm in
   534     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   535     else
   536       (*weak test for loops*)
   537       if rewrite_rule_extra_vars prems lhs rhs orelse is_Var (Thm.term_of elhs)
   538       then mk_eq_True ctxt (thm, name)
   539       else rrule_eq_True ctxt thm name lhs elhs rhs thm
   540   end;
   541 
   542 fun orient_rrule ctxt (thm, name) =
   543   let
   544     val (prems, lhs, elhs, rhs, perm) = decomp_simp thm;
   545     val Simpset (_, {mk_rews = {reorient, mk_sym, ...}, ...}) = simpset_of ctxt;
   546   in
   547     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   548     else if reorient ctxt prems lhs rhs then
   549       if reorient ctxt prems rhs lhs
   550       then mk_eq_True ctxt (thm, name)
   551       else
   552         (case mk_sym ctxt thm of
   553           NONE => []
   554         | SOME thm' =>
   555             let val (_, lhs', elhs', rhs', _) = decomp_simp thm'
   556             in rrule_eq_True ctxt thm' name lhs' elhs' rhs' thm end)
   557     else rrule_eq_True ctxt thm name lhs elhs rhs thm
   558   end;
   559 
   560 fun extract_rews ctxt thms =
   561   let val Simpset (_, {mk_rews = {mk, ...}, ...}) = simpset_of ctxt
   562   in maps (fn thm => map (rpair (Thm.get_name_hint thm)) (mk ctxt thm)) thms end;
   563 
   564 fun extract_safe_rrules ctxt thm =
   565   maps (orient_rrule ctxt) (extract_rews ctxt [thm]);
   566 
   567 fun mk_rrules ctxt thms =
   568   let
   569     val rews = extract_rews ctxt thms
   570     val raw_rrules = flat (map (mk_rrule ctxt) rews)
   571   in map mk_rrule2 raw_rrules end
   572 
   573 
   574 (* add/del rules explicitly *)
   575 
   576 local
   577 
   578 fun comb_simps ctxt comb mk_rrule thms =
   579   let
   580     val rews = extract_rews ctxt (map (Thm.transfer (Proof_Context.theory_of ctxt)) thms);
   581   in fold (fold comb o mk_rrule) rews ctxt end;
   582 
   583 in
   584 
   585 fun ctxt addsimps thms =
   586   comb_simps ctxt insert_rrule (mk_rrule ctxt) thms;
   587 
   588 fun ctxt delsimps thms =
   589   comb_simps ctxt del_rrule (map mk_rrule2 o mk_rrule ctxt) thms;
   590 
   591 fun add_simp thm ctxt = ctxt addsimps [thm];
   592 fun del_simp thm ctxt = ctxt delsimps [thm];
   593 
   594 end;
   595 
   596 
   597 (* congs *)
   598 
   599 local
   600 
   601 fun is_full_cong_prems [] [] = true
   602   | is_full_cong_prems [] _ = false
   603   | is_full_cong_prems (p :: prems) varpairs =
   604       (case Logic.strip_assums_concl p of
   605         Const ("Pure.eq", _) $ lhs $ rhs =>
   606           let val (x, xs) = strip_comb lhs and (y, ys) = strip_comb rhs in
   607             is_Var x andalso forall is_Bound xs andalso
   608             not (has_duplicates (op =) xs) andalso xs = ys andalso
   609             member (op =) varpairs (x, y) andalso
   610             is_full_cong_prems prems (remove (op =) (x, y) varpairs)
   611           end
   612       | _ => false);
   613 
   614 fun is_full_cong thm =
   615   let
   616     val prems = Thm.prems_of thm and concl = Thm.concl_of thm;
   617     val (lhs, rhs) = Logic.dest_equals concl;
   618     val (f, xs) = strip_comb lhs and (g, ys) = strip_comb rhs;
   619   in
   620     f = g andalso not (has_duplicates (op =) (xs @ ys)) andalso length xs = length ys andalso
   621     is_full_cong_prems prems (xs ~~ ys)
   622   end;
   623 
   624 fun mk_cong ctxt =
   625   let val Simpset (_, {mk_rews = {mk_cong = f, ...}, ...}) = simpset_of ctxt
   626   in f ctxt end;
   627 
   628 in
   629 
   630 fun add_eqcong thm ctxt = ctxt |> map_simpset2
   631   (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   632     let
   633       val (lhs, _) = Logic.dest_equals (Thm.concl_of thm)
   634         handle TERM _ => raise SIMPLIFIER ("Congruence not a meta-equality", [thm]);
   635     (*val lhs = Envir.eta_contract lhs;*)
   636       val a = the (cong_name (head_of lhs)) handle Option.Option =>
   637         raise SIMPLIFIER ("Congruence must start with a constant or free variable", [thm]);
   638       val (xs, weak) = congs;
   639       val xs' = AList.update (op =) (a, Thm.trim_context thm) xs;
   640       val weak' = if is_full_cong thm then weak else a :: weak;
   641     in ((xs', weak'), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   642 
   643 fun del_eqcong thm ctxt = ctxt |> map_simpset2
   644   (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   645     let
   646       val (lhs, _) = Logic.dest_equals (Thm.concl_of thm)
   647         handle TERM _ => raise SIMPLIFIER ("Congruence not a meta-equality", [thm]);
   648     (*val lhs = Envir.eta_contract lhs;*)
   649       val a = the (cong_name (head_of lhs)) handle Option.Option =>
   650         raise SIMPLIFIER ("Congruence must start with a constant", [thm]);
   651       val (xs, _) = congs;
   652       val xs' = filter_out (fn (x : cong_name, _) => x = a) xs;
   653       val weak' = xs' |> map_filter (fn (a, thm) =>
   654         if is_full_cong thm then NONE else SOME a);
   655     in ((xs', weak'), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   656 
   657 fun add_cong thm ctxt = add_eqcong (mk_cong ctxt thm) ctxt;
   658 fun del_cong thm ctxt = del_eqcong (mk_cong ctxt thm) ctxt;
   659 
   660 end;
   661 
   662 
   663 (* simprocs *)
   664 
   665 datatype simproc =
   666   Simproc of
   667     {name: string,
   668      lhss: term list,
   669      proc: morphism -> Proof.context -> cterm -> thm option,
   670      id: stamp * thm list};
   671 
   672 fun eq_simproc (Simproc {id = id1, ...}, Simproc {id = id2, ...}) = eq_procid (id1, id2);
   673 
   674 fun cert_simproc thy name {lhss, proc, identifier} =
   675   Simproc {name = name, lhss = map (Sign.cert_term thy) lhss, proc = proc,
   676     id = (stamp (), map Thm.trim_context identifier)};
   677 
   678 fun transform_simproc phi (Simproc {name, lhss, proc, id = (s, ths)}) =
   679   Simproc
   680    {name = name,
   681     lhss = map (Morphism.term phi) lhss,
   682     proc = Morphism.transform phi proc,
   683     id = (s, Morphism.fact phi ths)};
   684 
   685 local
   686 
   687 fun add_proc (proc as Proc {name, lhs, ...}) ctxt =
   688  (cond_tracing ctxt (fn () =>
   689     print_term ctxt ("Adding simplification procedure " ^ quote name ^ " for") lhs);
   690   ctxt |> map_simpset2
   691     (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   692       (congs, Net.insert_term eq_proc (lhs, proc) procs,
   693         mk_rews, termless, subgoal_tac, loop_tacs, solvers))
   694   handle Net.INSERT =>
   695     (cond_warning ctxt (fn () => "Ignoring duplicate simplification procedure " ^ quote name);
   696       ctxt));
   697 
   698 fun del_proc (proc as Proc {name, lhs, ...}) ctxt =
   699   ctxt |> map_simpset2
   700     (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   701       (congs, Net.delete_term eq_proc (lhs, proc) procs,
   702         mk_rews, termless, subgoal_tac, loop_tacs, solvers))
   703   handle Net.DELETE =>
   704     (cond_warning ctxt (fn () => "Simplification procedure " ^ quote name ^ " not in simpset");
   705       ctxt);
   706 
   707 fun prep_procs (Simproc {name, lhss, proc, id}) =
   708   lhss |> map (fn lhs => Proc {name = name, lhs = lhs, proc = Morphism.form proc, id = id});
   709 
   710 in
   711 
   712 fun ctxt addsimprocs ps = fold (fold add_proc o prep_procs) ps ctxt;
   713 fun ctxt delsimprocs ps = fold (fold del_proc o prep_procs) ps ctxt;
   714 
   715 end;
   716 
   717 
   718 (* mk_rews *)
   719 
   720 local
   721 
   722 fun map_mk_rews f =
   723   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   724     let
   725       val {mk, mk_cong, mk_sym, mk_eq_True, reorient} = mk_rews;
   726       val (mk', mk_cong', mk_sym', mk_eq_True', reorient') =
   727         f (mk, mk_cong, mk_sym, mk_eq_True, reorient);
   728       val mk_rews' = {mk = mk', mk_cong = mk_cong', mk_sym = mk_sym', mk_eq_True = mk_eq_True',
   729         reorient = reorient'};
   730     in (congs, procs, mk_rews', termless, subgoal_tac, loop_tacs, solvers) end);
   731 
   732 in
   733 
   734 fun mksimps ctxt =
   735   let val Simpset (_, {mk_rews = {mk, ...}, ...}) = simpset_of ctxt
   736   in mk ctxt end;
   737 
   738 fun set_mksimps mk = map_mk_rews (fn (_, mk_cong, mk_sym, mk_eq_True, reorient) =>
   739   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   740 
   741 fun set_mkcong mk_cong = map_mk_rews (fn (mk, _, mk_sym, mk_eq_True, reorient) =>
   742   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   743 
   744 fun set_mksym mk_sym = map_mk_rews (fn (mk, mk_cong, _, mk_eq_True, reorient) =>
   745   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   746 
   747 fun set_mkeqTrue mk_eq_True = map_mk_rews (fn (mk, mk_cong, mk_sym, _, reorient) =>
   748   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   749 
   750 fun set_reorient reorient = map_mk_rews (fn (mk, mk_cong, mk_sym, mk_eq_True, _) =>
   751   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   752 
   753 end;
   754 
   755 
   756 (* termless *)
   757 
   758 fun set_termless termless =
   759   map_simpset2 (fn (congs, procs, mk_rews, _, subgoal_tac, loop_tacs, solvers) =>
   760    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   761 
   762 
   763 (* tactics *)
   764 
   765 fun set_subgoaler subgoal_tac =
   766   map_simpset2 (fn (congs, procs, mk_rews, termless, _, loop_tacs, solvers) =>
   767    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   768 
   769 fun ctxt setloop tac = ctxt |>
   770   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, _, solvers) =>
   771    (congs, procs, mk_rews, termless, subgoal_tac, [("", tac)], solvers));
   772 
   773 fun ctxt addloop (name, tac) = ctxt |>
   774   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   775     (congs, procs, mk_rews, termless, subgoal_tac,
   776      AList.update (op =) (name, tac) loop_tacs, solvers));
   777 
   778 fun ctxt delloop name = ctxt |>
   779   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   780     (congs, procs, mk_rews, termless, subgoal_tac,
   781      (if AList.defined (op =) loop_tacs name then ()
   782       else cond_warning ctxt (fn () => "No such looper in simpset: " ^ quote name);
   783       AList.delete (op =) name loop_tacs), solvers));
   784 
   785 fun ctxt setSSolver solver = ctxt |> map_simpset2
   786   (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, (unsafe_solvers, _)) =>
   787     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, (unsafe_solvers, [solver])));
   788 
   789 fun ctxt addSSolver solver = ctxt |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   790   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   791     subgoal_tac, loop_tacs, (unsafe_solvers, insert eq_solver solver solvers)));
   792 
   793 fun ctxt setSolver solver = ctxt |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   794   subgoal_tac, loop_tacs, (_, solvers)) => (congs, procs, mk_rews, termless,
   795     subgoal_tac, loop_tacs, ([solver], solvers)));
   796 
   797 fun ctxt addSolver solver = ctxt |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   798   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   799     subgoal_tac, loop_tacs, (insert eq_solver solver unsafe_solvers, solvers)));
   800 
   801 fun set_solvers solvers = map_simpset2 (fn (congs, procs, mk_rews, termless,
   802   subgoal_tac, loop_tacs, _) => (congs, procs, mk_rews, termless,
   803   subgoal_tac, loop_tacs, (solvers, solvers)));
   804 
   805 
   806 (* trace operations *)
   807 
   808 type trace_ops =
   809  {trace_invoke: {depth: int, term: term} -> Proof.context -> Proof.context,
   810   trace_apply: {unconditional: bool, term: term, thm: thm, rrule: rrule} ->
   811     Proof.context -> (Proof.context -> (thm * term) option) -> (thm * term) option};
   812 
   813 structure Trace_Ops = Theory_Data
   814 (
   815   type T = trace_ops;
   816   val empty: T =
   817    {trace_invoke = fn _ => fn ctxt => ctxt,
   818     trace_apply = fn _ => fn ctxt => fn cont => cont ctxt};
   819   val extend = I;
   820   fun merge (trace_ops, _) = trace_ops;
   821 );
   822 
   823 val set_trace_ops = Trace_Ops.put;
   824 
   825 val trace_ops = Trace_Ops.get o Proof_Context.theory_of;
   826 fun trace_invoke args ctxt = #trace_invoke (trace_ops ctxt) args ctxt;
   827 fun trace_apply args ctxt = #trace_apply (trace_ops ctxt) args ctxt;
   828 
   829 
   830 
   831 (** rewriting **)
   832 
   833 (*
   834   Uses conversions, see:
   835     L C Paulson, A higher-order implementation of rewriting,
   836     Science of Computer Programming 3 (1983), pages 119-149.
   837 *)
   838 
   839 fun check_conv ctxt msg thm thm' =
   840   let
   841     val thm'' = Thm.transitive thm thm' handle THM _ =>
   842       let
   843         val nthm' =
   844           Thm.transitive (Thm.symmetric (Drule.beta_eta_conversion (Thm.lhs_of thm'))) thm'
   845       in Thm.transitive thm nthm' handle THM _ =>
   846            let
   847              val nthm =
   848                Thm.transitive thm (Drule.beta_eta_conversion (Thm.rhs_of thm))
   849            in Thm.transitive nthm nthm' end
   850       end
   851     val _ =
   852       if msg then cond_tracing ctxt (fn () => print_thm ctxt "SUCCEEDED" ("", thm'))
   853       else ();
   854   in SOME thm'' end
   855   handle THM _ =>
   856     let
   857       val _ $ _ $ prop0 = Thm.prop_of thm;
   858       val _ =
   859         cond_tracing ctxt (fn () =>
   860           print_thm ctxt "Proved wrong theorem (bad subgoaler?)" ("", thm') ^ "\n" ^
   861           print_term ctxt "Should have proved:" prop0);
   862     in NONE end;
   863 
   864 
   865 (* mk_procrule *)
   866 
   867 fun mk_procrule ctxt thm =
   868   let val (prems, lhs, elhs, rhs, _) = decomp_simp thm in
   869     if rewrite_rule_extra_vars prems lhs rhs
   870     then (cond_warning ctxt (fn () => print_thm ctxt "Extra vars on rhs:" ("", thm)); [])
   871     else [mk_rrule2 {thm = thm, name = "", lhs = lhs, elhs = elhs, perm = false}]
   872   end;
   873 
   874 
   875 (* rewritec: conversion to apply the meta simpset to a term *)
   876 
   877 (*Since the rewriting strategy is bottom-up, we avoid re-normalizing already
   878   normalized terms by carrying around the rhs of the rewrite rule just
   879   applied. This is called the `skeleton'. It is decomposed in parallel
   880   with the term. Once a Var is encountered, the corresponding term is
   881   already in normal form.
   882   skel0 is a dummy skeleton that is to enforce complete normalization.*)
   883 
   884 val skel0 = Bound 0;
   885 
   886 (*Use rhs as skeleton only if the lhs does not contain unnormalized bits.
   887   The latter may happen iff there are weak congruence rules for constants
   888   in the lhs.*)
   889 
   890 fun uncond_skel ((_, weak), (lhs, rhs)) =
   891   if null weak then rhs  (*optimization*)
   892   else if exists_subterm
   893     (fn Const (a, _) => member (op =) weak (true, a)
   894       | Free (a, _) => member (op =) weak (false, a)
   895       | _ => false) lhs then skel0
   896   else rhs;
   897 
   898 (*Behaves like unconditional rule if rhs does not contain vars not in the lhs.
   899   Otherwise those vars may become instantiated with unnormalized terms
   900   while the premises are solved.*)
   901 
   902 fun cond_skel (args as (_, (lhs, rhs))) =
   903   if subset (op =) (Term.add_vars rhs [], Term.add_vars lhs []) then uncond_skel args
   904   else skel0;
   905 
   906 (*
   907   Rewriting -- we try in order:
   908     (1) beta reduction
   909     (2) unconditional rewrite rules
   910     (3) conditional rewrite rules
   911     (4) simplification procedures
   912 
   913   IMPORTANT: rewrite rules must not introduce new Vars or TVars!
   914 *)
   915 
   916 fun rewritec (prover, maxt) ctxt t =
   917   let
   918     val thy = Proof_Context.theory_of ctxt;
   919     val Simpset ({rules, ...}, {congs, procs, termless, ...}) = simpset_of ctxt;
   920     val eta_thm = Thm.eta_conversion t;
   921     val eta_t' = Thm.rhs_of eta_thm;
   922     val eta_t = Thm.term_of eta_t';
   923     fun rew rrule =
   924       let
   925         val {thm = thm0, name, lhs, elhs = elhs0, extra, fo, perm} = rrule;
   926         val thm = Thm.transfer thy thm0;
   927         val elhs = Thm.transfer_cterm thy elhs0;
   928         val prop = Thm.prop_of thm;
   929         val (rthm, elhs') =
   930           if maxt = ~1 orelse not extra then (thm, elhs)
   931           else (Thm.incr_indexes (maxt + 1) thm, Thm.incr_indexes_cterm (maxt + 1) elhs);
   932 
   933         val insts =
   934           if fo then Thm.first_order_match (elhs', eta_t')
   935           else Thm.match (elhs', eta_t');
   936         val thm' = Thm.instantiate insts (Thm.rename_boundvars lhs eta_t rthm);
   937         val prop' = Thm.prop_of thm';
   938         val unconditional = (Logic.count_prems prop' = 0);
   939         val (lhs', rhs') = Logic.dest_equals (Logic.strip_imp_concl prop');
   940         val trace_args = {unconditional = unconditional, term = eta_t, thm = thm', rrule = rrule};
   941       in
   942         if perm andalso not (termless (rhs', lhs'))
   943         then
   944          (cond_tracing ctxt (fn () =>
   945             print_thm ctxt "Cannot apply permutative rewrite rule" (name, thm) ^ "\n" ^
   946             print_thm ctxt "Term does not become smaller:" ("", thm'));
   947           NONE)
   948         else
   949          (cond_tracing ctxt (fn () =>
   950             print_thm ctxt "Applying instance of rewrite rule" (name, thm));
   951           if unconditional
   952           then
   953            (cond_tracing ctxt (fn () => print_thm ctxt "Rewriting:" ("", thm'));
   954             trace_apply trace_args ctxt (fn ctxt' =>
   955               let
   956                 val lr = Logic.dest_equals prop;
   957                 val SOME thm'' = check_conv ctxt' false eta_thm thm';
   958               in SOME (thm'', uncond_skel (congs, lr)) end))
   959           else
   960            (cond_tracing ctxt (fn () => print_thm ctxt "Trying to rewrite:" ("", thm'));
   961             if simp_depth ctxt > Config.get ctxt simp_depth_limit
   962             then (cond_tracing ctxt (fn () => "simp_depth_limit exceeded - giving up"); NONE)
   963             else
   964               trace_apply trace_args ctxt (fn ctxt' =>
   965                 (case prover ctxt' thm' of
   966                   NONE => (cond_tracing ctxt' (fn () => print_thm ctxt' "FAILED" ("", thm')); NONE)
   967                 | SOME thm2 =>
   968                     (case check_conv ctxt' true eta_thm thm2 of
   969                       NONE => NONE
   970                     | SOME thm2' =>
   971                         let
   972                           val concl = Logic.strip_imp_concl prop;
   973                           val lr = Logic.dest_equals concl;
   974                         in SOME (thm2', cond_skel (congs, lr)) end)))))
   975       end;
   976 
   977     fun rews [] = NONE
   978       | rews (rrule :: rrules) =
   979           let val opt = rew rrule handle Pattern.MATCH => NONE
   980           in (case opt of NONE => rews rrules | some => some) end;
   981 
   982     fun sort_rrules rrs =
   983       let
   984         fun is_simple ({thm, ...}: rrule) =
   985           (case Thm.prop_of thm of
   986             Const ("Pure.eq", _) $ _ $ _ => true
   987           | _ => false);
   988         fun sort [] (re1, re2) = re1 @ re2
   989           | sort (rr :: rrs) (re1, re2) =
   990               if is_simple rr
   991               then sort rrs (rr :: re1, re2)
   992               else sort rrs (re1, rr :: re2);
   993       in sort rrs ([], []) end;
   994 
   995     fun proc_rews [] = NONE
   996       | proc_rews (Proc {name, proc, lhs, ...} :: ps) =
   997           if Pattern.matches (Proof_Context.theory_of ctxt) (lhs, Thm.term_of t) then
   998             (cond_tracing' ctxt simp_debug (fn () =>
   999               print_term ctxt ("Trying procedure " ^ quote name ^ " on:") eta_t);
  1000              (case proc ctxt eta_t' of
  1001                NONE => (cond_tracing' ctxt simp_debug (fn () => "FAILED"); proc_rews ps)
  1002              | SOME raw_thm =>
  1003                  (cond_tracing ctxt (fn () =>
  1004                     print_thm ctxt ("Procedure " ^ quote name ^ " produced rewrite rule:")
  1005                       ("", raw_thm));
  1006                   (case rews (mk_procrule ctxt raw_thm) of
  1007                     NONE =>
  1008                      (cond_tracing ctxt (fn () =>
  1009                         print_term ctxt ("IGNORED result of simproc " ^ quote name ^
  1010                             " -- does not match") (Thm.term_of t));
  1011                       proc_rews ps)
  1012                   | some => some))))
  1013           else proc_rews ps;
  1014   in
  1015     (case eta_t of
  1016       Abs _ $ _ => SOME (Thm.transitive eta_thm (Thm.beta_conversion false eta_t'), skel0)
  1017     | _ =>
  1018       (case rews (sort_rrules (Net.match_term rules eta_t)) of
  1019         NONE => proc_rews (Net.match_term procs eta_t)
  1020       | some => some))
  1021   end;
  1022 
  1023 
  1024 (* conversion to apply a congruence rule to a term *)
  1025 
  1026 fun congc prover ctxt maxt cong t =
  1027   let
  1028     val rthm = Thm.incr_indexes (maxt + 1) cong;
  1029     val rlhs = fst (Thm.dest_equals (Drule.strip_imp_concl (Thm.cprop_of rthm)));
  1030     val insts = Thm.match (rlhs, t)
  1031     (* Thm.match can raise Pattern.MATCH;
  1032        is handled when congc is called *)
  1033     val thm' =
  1034       Thm.instantiate insts (Thm.rename_boundvars (Thm.term_of rlhs) (Thm.term_of t) rthm);
  1035     val _ =
  1036       cond_tracing ctxt (fn () => print_thm ctxt "Applying congruence rule:" ("", thm'));
  1037     fun err (msg, thm) = (cond_tracing ctxt (fn () => print_thm ctxt msg ("", thm)); NONE);
  1038   in
  1039     (case prover thm' of
  1040       NONE => err ("Congruence proof failed.  Could not prove", thm')
  1041     | SOME thm2 =>
  1042         (case check_conv ctxt true (Drule.beta_eta_conversion t) thm2 of
  1043           NONE => err ("Congruence proof failed.  Should not have proved", thm2)
  1044         | SOME thm2' =>
  1045             if op aconv (apply2 Thm.term_of (Thm.dest_equals (Thm.cprop_of thm2')))
  1046             then NONE else SOME thm2'))
  1047   end;
  1048 
  1049 val vA = (("A", 0), propT);
  1050 val vB = (("B", 0), propT);
  1051 val vC = (("C", 0), propT);
  1052 
  1053 fun transitive1 NONE NONE = NONE
  1054   | transitive1 (SOME thm1) NONE = SOME thm1
  1055   | transitive1 NONE (SOME thm2) = SOME thm2
  1056   | transitive1 (SOME thm1) (SOME thm2) = SOME (Thm.transitive thm1 thm2);
  1057 
  1058 fun transitive2 thm = transitive1 (SOME thm);
  1059 fun transitive3 thm = transitive1 thm o SOME;
  1060 
  1061 fun bottomc ((simprem, useprem, mutsimp), prover, maxidx) =
  1062   let
  1063     fun botc skel ctxt t =
  1064       if is_Var skel then NONE
  1065       else
  1066         (case subc skel ctxt t of
  1067            some as SOME thm1 =>
  1068              (case rewritec (prover, maxidx) ctxt (Thm.rhs_of thm1) of
  1069                 SOME (thm2, skel2) =>
  1070                   transitive2 (Thm.transitive thm1 thm2)
  1071                     (botc skel2 ctxt (Thm.rhs_of thm2))
  1072               | NONE => some)
  1073          | NONE =>
  1074              (case rewritec (prover, maxidx) ctxt t of
  1075                 SOME (thm2, skel2) => transitive2 thm2
  1076                   (botc skel2 ctxt (Thm.rhs_of thm2))
  1077               | NONE => NONE))
  1078 
  1079     and try_botc ctxt t =
  1080       (case botc skel0 ctxt t of
  1081         SOME trec1 => trec1
  1082       | NONE => Thm.reflexive t)
  1083 
  1084     and subc skel ctxt t0 =
  1085         let val Simpset (_, {congs, ...}) = simpset_of ctxt in
  1086           (case Thm.term_of t0 of
  1087               Abs (a, T, _) =>
  1088                 let
  1089                     val (v, ctxt') = Variable.next_bound (a, T) ctxt;
  1090                     val b = #1 (Term.dest_Free v);
  1091                     val (v', t') = Thm.dest_abs (SOME b) t0;
  1092                     val b' = #1 (Term.dest_Free (Thm.term_of v'));
  1093                     val _ =
  1094                       if b <> b' then
  1095                         warning ("Bad Simplifier context: renamed bound variable " ^
  1096                           quote b ^ " to " ^ quote b' ^ Position.here (Position.thread_data ()))
  1097                       else ();
  1098                     val skel' = (case skel of Abs (_, _, sk) => sk | _ => skel0);
  1099                 in
  1100                   (case botc skel' ctxt' t' of
  1101                     SOME thm => SOME (Thm.abstract_rule a v' thm)
  1102                   | NONE => NONE)
  1103                 end
  1104             | t $ _ =>
  1105               (case t of
  1106                 Const ("Pure.imp", _) $ _  => impc t0 ctxt
  1107               | Abs _ =>
  1108                   let val thm = Thm.beta_conversion false t0
  1109                   in
  1110                     (case subc skel0 ctxt (Thm.rhs_of thm) of
  1111                       NONE => SOME thm
  1112                     | SOME thm' => SOME (Thm.transitive thm thm'))
  1113                   end
  1114               | _  =>
  1115                   let
  1116                     fun appc () =
  1117                       let
  1118                         val (tskel, uskel) =
  1119                           (case skel of
  1120                             tskel $ uskel => (tskel, uskel)
  1121                           | _ => (skel0, skel0));
  1122                         val (ct, cu) = Thm.dest_comb t0;
  1123                       in
  1124                         (case botc tskel ctxt ct of
  1125                           SOME thm1 =>
  1126                             (case botc uskel ctxt cu of
  1127                               SOME thm2 => SOME (Thm.combination thm1 thm2)
  1128                             | NONE => SOME (Thm.combination thm1 (Thm.reflexive cu)))
  1129                         | NONE =>
  1130                             (case botc uskel ctxt cu of
  1131                               SOME thm1 => SOME (Thm.combination (Thm.reflexive ct) thm1)
  1132                             | NONE => NONE))
  1133                       end;
  1134                     val (h, ts) = strip_comb t;
  1135                   in
  1136                     (case cong_name h of
  1137                       SOME a =>
  1138                         (case AList.lookup (op =) (fst congs) a of
  1139                           NONE => appc ()
  1140                         | SOME cong =>
  1141      (*post processing: some partial applications h t1 ... tj, j <= length ts,
  1142        may be a redex. Example: map (%x. x) = (%xs. xs) wrt map_cong*)
  1143                            (let
  1144                               val thm = congc (prover ctxt) ctxt maxidx cong t0;
  1145                               val t = the_default t0 (Option.map Thm.rhs_of thm);
  1146                               val (cl, cr) = Thm.dest_comb t
  1147                               val dVar = Var(("", 0), dummyT)
  1148                               val skel =
  1149                                 list_comb (h, replicate (length ts) dVar)
  1150                             in
  1151                               (case botc skel ctxt cl of
  1152                                 NONE => thm
  1153                               | SOME thm' =>
  1154                                   transitive3 thm (Thm.combination thm' (Thm.reflexive cr)))
  1155                             end handle Pattern.MATCH => appc ()))
  1156                      | _ => appc ())
  1157                   end)
  1158             | _ => NONE)
  1159         end
  1160     and impc ct ctxt =
  1161       if mutsimp then mut_impc0 [] ct [] [] ctxt
  1162       else nonmut_impc ct ctxt
  1163 
  1164     and rules_of_prem prem ctxt =
  1165       if maxidx_of_term (Thm.term_of prem) <> ~1
  1166       then
  1167        (cond_tracing ctxt (fn () =>
  1168           print_term ctxt "Cannot add premise as rewrite rule because it contains (type) unknowns:"
  1169             (Thm.term_of prem));
  1170         (([], NONE), ctxt))
  1171       else
  1172         let val (asm, ctxt') = Thm.assume_hyps prem ctxt
  1173         in ((extract_safe_rrules ctxt' asm, SOME asm), ctxt') end
  1174 
  1175     and add_rrules (rrss, asms) ctxt =
  1176       (fold o fold) insert_rrule rrss ctxt |> add_prems (map_filter I asms)
  1177 
  1178     and disch r prem eq =
  1179       let
  1180         val (lhs, rhs) = Thm.dest_equals (Thm.cprop_of eq);
  1181         val eq' =
  1182           Thm.implies_elim
  1183             (Thm.instantiate ([], [(vA, prem), (vB, lhs), (vC, rhs)]) Drule.imp_cong)
  1184             (Thm.implies_intr prem eq);
  1185       in
  1186         if not r then eq'
  1187         else
  1188           let
  1189             val (prem', concl) = Thm.dest_implies lhs;
  1190             val (prem'', _) = Thm.dest_implies rhs;
  1191           in
  1192             Thm.transitive
  1193               (Thm.transitive
  1194                 (Thm.instantiate ([], [(vA, prem'), (vB, prem), (vC, concl)]) Drule.swap_prems_eq)
  1195                 eq')
  1196               (Thm.instantiate ([], [(vA, prem), (vB, prem''), (vC, concl)]) Drule.swap_prems_eq)
  1197           end
  1198       end
  1199 
  1200     and rebuild [] _ _ _ _ eq = eq
  1201       | rebuild (prem :: prems) concl (_ :: rrss) (_ :: asms) ctxt eq =
  1202           let
  1203             val ctxt' = add_rrules (rev rrss, rev asms) ctxt;
  1204             val concl' =
  1205               Drule.mk_implies (prem, the_default concl (Option.map Thm.rhs_of eq));
  1206             val dprem = Option.map (disch false prem);
  1207           in
  1208             (case rewritec (prover, maxidx) ctxt' concl' of
  1209               NONE => rebuild prems concl' rrss asms ctxt (dprem eq)
  1210             | SOME (eq', _) =>
  1211                 transitive2 (fold (disch false) prems (the (transitive3 (dprem eq) eq')))
  1212                   (mut_impc0 (rev prems) (Thm.rhs_of eq') (rev rrss) (rev asms) ctxt))
  1213           end
  1214 
  1215     and mut_impc0 prems concl rrss asms ctxt =
  1216       let
  1217         val prems' = strip_imp_prems concl;
  1218         val ((rrss', asms'), ctxt') = fold_map rules_of_prem prems' ctxt |>> split_list;
  1219       in
  1220         mut_impc (prems @ prems') (strip_imp_concl concl) (rrss @ rrss')
  1221           (asms @ asms') [] [] [] [] ctxt' ~1 ~1
  1222       end
  1223 
  1224     and mut_impc [] concl [] [] prems' rrss' asms' eqns ctxt changed k =
  1225         transitive1 (fold (fn (eq1, prem) => fn eq2 => transitive1 eq1
  1226             (Option.map (disch false prem) eq2)) (eqns ~~ prems') NONE)
  1227           (if changed > 0 then
  1228              mut_impc (rev prems') concl (rev rrss') (rev asms')
  1229                [] [] [] [] ctxt ~1 changed
  1230            else rebuild prems' concl rrss' asms' ctxt
  1231              (botc skel0 (add_rrules (rev rrss', rev asms') ctxt) concl))
  1232 
  1233       | mut_impc (prem :: prems) concl (rrs :: rrss) (asm :: asms)
  1234           prems' rrss' asms' eqns ctxt changed k =
  1235         (case (if k = 0 then NONE else botc skel0 (add_rrules
  1236           (rev rrss' @ rrss, rev asms' @ asms) ctxt) prem) of
  1237             NONE => mut_impc prems concl rrss asms (prem :: prems')
  1238               (rrs :: rrss') (asm :: asms') (NONE :: eqns) ctxt changed
  1239               (if k = 0 then 0 else k - 1)
  1240         | SOME eqn =>
  1241             let
  1242               val prem' = Thm.rhs_of eqn;
  1243               val tprems = map Thm.term_of prems;
  1244               val i = 1 + fold Integer.max (map (fn p =>
  1245                 find_index (fn q => q aconv p) tprems) (Thm.hyps_of eqn)) ~1;
  1246               val ((rrs', asm'), ctxt') = rules_of_prem prem' ctxt;
  1247             in
  1248               mut_impc prems concl rrss asms (prem' :: prems')
  1249                 (rrs' :: rrss') (asm' :: asms')
  1250                 (SOME (fold_rev (disch true)
  1251                   (take i prems)
  1252                   (Drule.imp_cong_rule eqn (Thm.reflexive (Drule.list_implies
  1253                     (drop i prems, concl))))) :: eqns)
  1254                 ctxt' (length prems') ~1
  1255             end)
  1256 
  1257     (*legacy code -- only for backwards compatibility*)
  1258     and nonmut_impc ct ctxt =
  1259       let
  1260         val (prem, conc) = Thm.dest_implies ct;
  1261         val thm1 = if simprem then botc skel0 ctxt prem else NONE;
  1262         val prem1 = the_default prem (Option.map Thm.rhs_of thm1);
  1263         val ctxt1 =
  1264           if not useprem then ctxt
  1265           else
  1266             let val ((rrs, asm), ctxt') = rules_of_prem prem1 ctxt
  1267             in add_rrules ([rrs], [asm]) ctxt' end;
  1268       in
  1269         (case botc skel0 ctxt1 conc of
  1270           NONE =>
  1271             (case thm1 of
  1272               NONE => NONE
  1273             | SOME thm1' => SOME (Drule.imp_cong_rule thm1' (Thm.reflexive conc)))
  1274         | SOME thm2 =>
  1275             let val thm2' = disch false prem1 thm2 in
  1276               (case thm1 of
  1277                 NONE => SOME thm2'
  1278               | SOME thm1' =>
  1279                  SOME (Thm.transitive (Drule.imp_cong_rule thm1' (Thm.reflexive conc)) thm2'))
  1280             end)
  1281       end;
  1282 
  1283   in try_botc end;
  1284 
  1285 
  1286 (* Meta-rewriting: rewrites t to u and returns the theorem t==u *)
  1287 
  1288 (*
  1289   Parameters:
  1290     mode = (simplify A,
  1291             use A in simplifying B,
  1292             use prems of B (if B is again a meta-impl.) to simplify A)
  1293            when simplifying A ==> B
  1294     prover: how to solve premises in conditional rewrites and congruences
  1295 *)
  1296 
  1297 fun rewrite_cterm mode prover raw_ctxt raw_ct =
  1298   let
  1299     val thy = Proof_Context.theory_of raw_ctxt;
  1300 
  1301     val ct = raw_ct
  1302       |> Thm.transfer_cterm thy
  1303       |> Thm.adjust_maxidx_cterm ~1;
  1304     val maxidx = Thm.maxidx_of_cterm ct;
  1305 
  1306     val ctxt =
  1307       raw_ctxt
  1308       |> Context_Position.set_visible false
  1309       |> inc_simp_depth
  1310       |> (fn ctxt => trace_invoke {depth = simp_depth ctxt, term = Thm.term_of ct} ctxt);
  1311 
  1312     val _ =
  1313       cond_tracing ctxt (fn () =>
  1314         print_term ctxt "SIMPLIFIER INVOKED ON THE FOLLOWING TERM:" (Thm.term_of ct));
  1315   in bottomc (mode, Option.map (Drule.flexflex_unique (SOME ctxt)) oo prover, maxidx) ctxt ct end;
  1316 
  1317 val simple_prover =
  1318   SINGLE o (fn ctxt => ALLGOALS (resolve_tac ctxt (prems_of ctxt)));
  1319 
  1320 fun rewrite _ _ [] = Thm.reflexive
  1321   | rewrite ctxt full thms =
  1322       rewrite_cterm (full, false, false) simple_prover
  1323         (empty_simpset ctxt addsimps thms);
  1324 
  1325 fun rewrite_rule ctxt = Conv.fconv_rule o rewrite ctxt true;
  1326 
  1327 (*simple term rewriting -- no proof*)
  1328 fun rewrite_term thy rules procs =
  1329   Pattern.rewrite_term thy (map decomp_simp' rules) procs;
  1330 
  1331 fun rewrite_thm mode prover ctxt = Conv.fconv_rule (rewrite_cterm mode prover ctxt);
  1332 
  1333 (*Rewrite the subgoals of a proof state (represented by a theorem)*)
  1334 fun rewrite_goals_rule ctxt thms th =
  1335   Conv.fconv_rule (Conv.prems_conv ~1 (rewrite_cterm (true, true, true) simple_prover
  1336     (empty_simpset ctxt addsimps thms))) th;
  1337 
  1338 
  1339 (** meta-rewriting tactics **)
  1340 
  1341 (*Rewrite all subgoals*)
  1342 fun rewrite_goals_tac ctxt defs = PRIMITIVE (rewrite_goals_rule ctxt defs);
  1343 
  1344 (*Rewrite one subgoal*)
  1345 fun generic_rewrite_goal_tac mode prover_tac ctxt i thm =
  1346   if 0 < i andalso i <= Thm.nprems_of thm then
  1347     Seq.single (Conv.gconv_rule (rewrite_cterm mode (SINGLE o prover_tac) ctxt) i thm)
  1348   else Seq.empty;
  1349 
  1350 fun rewrite_goal_tac ctxt rews =
  1351   generic_rewrite_goal_tac (true, false, false) (K no_tac)
  1352     (empty_simpset ctxt addsimps rews);
  1353 
  1354 (*Prunes all redundant parameters from the proof state by rewriting.*)
  1355 fun prune_params_tac ctxt = rewrite_goals_tac ctxt [Drule.triv_forall_equality];
  1356 
  1357 
  1358 (* for folding definitions, handling critical pairs *)
  1359 
  1360 (*The depth of nesting in a term*)
  1361 fun term_depth (Abs (_, _, t)) = 1 + term_depth t
  1362   | term_depth (f $ t) = 1 + Int.max (term_depth f, term_depth t)
  1363   | term_depth _ = 0;
  1364 
  1365 val lhs_of_thm = #1 o Logic.dest_equals o Thm.prop_of;
  1366 
  1367 (*folding should handle critical pairs!  E.g. K == Inl(0),  S == Inr(Inl(0))
  1368   Returns longest lhs first to avoid folding its subexpressions.*)
  1369 fun sort_lhs_depths defs =
  1370   let val keylist = AList.make (term_depth o lhs_of_thm) defs
  1371       val keys = sort_distinct (rev_order o int_ord) (map #2 keylist)
  1372   in map (AList.find (op =) keylist) keys end;
  1373 
  1374 val rev_defs = sort_lhs_depths o map Thm.symmetric;
  1375 
  1376 fun fold_rule ctxt defs = fold (rewrite_rule ctxt) (rev_defs defs);
  1377 fun fold_goals_tac ctxt defs = EVERY (map (rewrite_goals_tac ctxt) (rev_defs defs));
  1378 
  1379 
  1380 (* HHF normal form: !! before ==>, outermost !! generalized *)
  1381 
  1382 local
  1383 
  1384 fun gen_norm_hhf ss ctxt =
  1385   Thm.transfer (Proof_Context.theory_of ctxt) #>
  1386   (fn th =>
  1387     if Drule.is_norm_hhf (Thm.prop_of th) then th
  1388     else
  1389       Conv.fconv_rule
  1390         (rewrite_cterm (true, false, false) (K (K NONE)) (put_simpset ss ctxt)) th) #>
  1391   Thm.adjust_maxidx_thm ~1 #>
  1392   Variable.gen_all ctxt;
  1393 
  1394 val hhf_ss =
  1395   simpset_of (empty_simpset (Context.the_local_context ()) addsimps Drule.norm_hhf_eqs);
  1396 
  1397 val hhf_protect_ss =
  1398   simpset_of (empty_simpset (Context.the_local_context ())
  1399     addsimps Drule.norm_hhf_eqs |> add_eqcong Drule.protect_cong);
  1400 
  1401 in
  1402 
  1403 val norm_hhf = gen_norm_hhf hhf_ss;
  1404 val norm_hhf_protect = gen_norm_hhf hhf_protect_ss;
  1405 
  1406 end;
  1407 
  1408 end;
  1409 
  1410 structure Basic_Meta_Simplifier: BASIC_RAW_SIMPLIFIER = Raw_Simplifier;
  1411 open Basic_Meta_Simplifier;