src/HOL/Fun.thy
author wenzelm
Tue Feb 10 14:48:26 2015 +0100 (2015-02-10)
changeset 59498 50b60f501b05
parent 58889 5b7a9633cfa8
child 59507 b468e0f8da2a
permissions -rw-r--r--
proper context for resolve_tac, eresolve_tac, dresolve_tac, forward_tac etc.;
occasionally clarified use of context;
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Author:     Andrei Popescu, TU Muenchen
     4     Copyright   1994, 2012
     5 *)
     6 
     7 section {* Notions about functions *}
     8 
     9 theory Fun
    10 imports Set
    11 keywords "functor" :: thy_goal
    12 begin
    13 
    14 lemma apply_inverse:
    15   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    16   by auto
    17 
    18 
    19 subsection {* The Identity Function @{text id} *}
    20 
    21 definition id :: "'a \<Rightarrow> 'a" where
    22   "id = (\<lambda>x. x)"
    23 
    24 lemma id_apply [simp]: "id x = x"
    25   by (simp add: id_def)
    26 
    27 lemma image_id [simp]: "image id = id"
    28   by (simp add: id_def fun_eq_iff)
    29 
    30 lemma vimage_id [simp]: "vimage id = id"
    31   by (simp add: id_def fun_eq_iff)
    32 
    33 code_printing
    34   constant id \<rightharpoonup> (Haskell) "id"
    35 
    36 
    37 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    38 
    39 definition comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55) where
    40   "f o g = (\<lambda>x. f (g x))"
    41 
    42 notation (xsymbols)
    43   comp  (infixl "\<circ>" 55)
    44 
    45 notation (HTML output)
    46   comp  (infixl "\<circ>" 55)
    47 
    48 lemma comp_apply [simp]: "(f o g) x = f (g x)"
    49   by (simp add: comp_def)
    50 
    51 lemma comp_assoc: "(f o g) o h = f o (g o h)"
    52   by (simp add: fun_eq_iff)
    53 
    54 lemma id_comp [simp]: "id o g = g"
    55   by (simp add: fun_eq_iff)
    56 
    57 lemma comp_id [simp]: "f o id = f"
    58   by (simp add: fun_eq_iff)
    59 
    60 lemma comp_eq_dest:
    61   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    62   by (simp add: fun_eq_iff)
    63 
    64 lemma comp_eq_elim:
    65   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    66   by (simp add: fun_eq_iff) 
    67 
    68 lemma comp_eq_dest_lhs: "a o b = c \<Longrightarrow> a (b v) = c v"
    69   by clarsimp
    70 
    71 lemma comp_eq_id_dest: "a o b = id o c \<Longrightarrow> a (b v) = c v"
    72   by clarsimp
    73 
    74 lemma image_comp:
    75   "f ` (g ` r) = (f o g) ` r"
    76   by auto
    77 
    78 lemma vimage_comp:
    79   "f -` (g -` x) = (g \<circ> f) -` x"
    80   by auto
    81 
    82 code_printing
    83   constant comp \<rightharpoonup> (SML) infixl 5 "o" and (Haskell) infixr 9 "."
    84 
    85 
    86 subsection {* The Forward Composition Operator @{text fcomp} *}
    87 
    88 definition fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60) where
    89   "f \<circ>> g = (\<lambda>x. g (f x))"
    90 
    91 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
    92   by (simp add: fcomp_def)
    93 
    94 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
    95   by (simp add: fcomp_def)
    96 
    97 lemma id_fcomp [simp]: "id \<circ>> g = g"
    98   by (simp add: fcomp_def)
    99 
   100 lemma fcomp_id [simp]: "f \<circ>> id = f"
   101   by (simp add: fcomp_def)
   102 
   103 code_printing
   104   constant fcomp \<rightharpoonup> (Eval) infixl 1 "#>"
   105 
   106 no_notation fcomp (infixl "\<circ>>" 60)
   107 
   108 
   109 subsection {* Mapping functions *}
   110 
   111 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   112   "map_fun f g h = g \<circ> h \<circ> f"
   113 
   114 lemma map_fun_apply [simp]:
   115   "map_fun f g h x = g (h (f x))"
   116   by (simp add: map_fun_def)
   117 
   118 
   119 subsection {* Injectivity and Bijectivity *}
   120 
   121 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   122   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   123 
   124 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   125   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   126 
   127 text{*A common special case: functions injective, surjective or bijective over
   128 the entire domain type.*}
   129 
   130 abbreviation
   131   "inj f \<equiv> inj_on f UNIV"
   132 
   133 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   134   "surj f \<equiv> (range f = UNIV)"
   135 
   136 abbreviation
   137   "bij f \<equiv> bij_betw f UNIV UNIV"
   138 
   139 text{* The negated case: *}
   140 translations
   141 "\<not> CONST surj f" <= "CONST range f \<noteq> CONST UNIV"
   142 
   143 lemma injI:
   144   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   145   shows "inj f"
   146   using assms unfolding inj_on_def by auto
   147 
   148 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   149   by (unfold inj_on_def, blast)
   150 
   151 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   152 by (simp add: inj_on_def)
   153 
   154 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   155 by (force simp add: inj_on_def)
   156 
   157 lemma inj_on_cong:
   158   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   159 unfolding inj_on_def by auto
   160 
   161 lemma inj_on_strict_subset:
   162   "inj_on f B \<Longrightarrow> A \<subset> B \<Longrightarrow> f ` A \<subset> f ` B"
   163   unfolding inj_on_def by blast
   164 
   165 lemma inj_comp:
   166   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   167   by (simp add: inj_on_def)
   168 
   169 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   170   by (simp add: inj_on_def fun_eq_iff)
   171 
   172 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   173 by (simp add: inj_on_eq_iff)
   174 
   175 lemma inj_on_id[simp]: "inj_on id A"
   176   by (simp add: inj_on_def)
   177 
   178 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   179 by (simp add: inj_on_def)
   180 
   181 lemma inj_on_Int: "inj_on f A \<or> inj_on f B \<Longrightarrow> inj_on f (A \<inter> B)"
   182 unfolding inj_on_def by blast
   183 
   184 lemma surj_id: "surj id"
   185 by simp
   186 
   187 lemma bij_id[simp]: "bij id"
   188 by (simp add: bij_betw_def)
   189 
   190 lemma inj_onI:
   191     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   192 by (simp add: inj_on_def)
   193 
   194 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   195 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   196 
   197 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   198 by (unfold inj_on_def, blast)
   199 
   200 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   201   by (fact inj_on_eq_iff)
   202 
   203 lemma comp_inj_on:
   204      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   205 by (simp add: comp_def inj_on_def)
   206 
   207 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   208   by (simp add: inj_on_def) blast
   209 
   210 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   211   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   212 apply(unfold inj_on_def)
   213 apply blast
   214 done
   215 
   216 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   217 by (unfold inj_on_def, blast)
   218 
   219 lemma inj_singleton: "inj (%s. {s})"
   220 by (simp add: inj_on_def)
   221 
   222 lemma inj_on_empty[iff]: "inj_on f {}"
   223 by(simp add: inj_on_def)
   224 
   225 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   226 by (unfold inj_on_def, blast)
   227 
   228 lemma inj_on_Un:
   229  "inj_on f (A Un B) =
   230   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   231 apply(unfold inj_on_def)
   232 apply (blast intro:sym)
   233 done
   234 
   235 lemma inj_on_insert[iff]:
   236   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   237 apply(unfold inj_on_def)
   238 apply (blast intro:sym)
   239 done
   240 
   241 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   242 apply(unfold inj_on_def)
   243 apply (blast)
   244 done
   245 
   246 lemma comp_inj_on_iff:
   247   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   248 by(auto simp add: comp_inj_on inj_on_def)
   249 
   250 lemma inj_on_imageI2:
   251   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   252 by(auto simp add: comp_inj_on inj_on_def)
   253 
   254 lemma inj_img_insertE:
   255   assumes "inj_on f A"
   256   assumes "x \<notin> B" and "insert x B = f ` A"
   257   obtains x' A' where "x' \<notin> A'" and "A = insert x' A'"
   258     and "x = f x'" and "B = f ` A'"
   259 proof -
   260   from assms have "x \<in> f ` A" by auto
   261   then obtain x' where *: "x' \<in> A" "x = f x'" by auto
   262   then have "A = insert x' (A - {x'})" by auto
   263   with assms * have "B = f ` (A - {x'})"
   264     by (auto dest: inj_on_contraD)
   265   have "x' \<notin> A - {x'}" by simp
   266   from `x' \<notin> A - {x'}` `A = insert x' (A - {x'})` `x = f x'` `B = image f (A - {x'})`
   267   show ?thesis ..
   268 qed
   269 
   270 lemma linorder_injI:
   271   assumes hyp: "\<And>x y. x < (y::'a::linorder) \<Longrightarrow> f x \<noteq> f y"
   272   shows "inj f"
   273   -- {* Courtesy of Stephan Merz *}
   274 proof (rule inj_onI)
   275   fix x y
   276   assume f_eq: "f x = f y"
   277   show "x = y" by (rule linorder_cases) (auto dest: hyp simp: f_eq)
   278 qed
   279 
   280 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   281   by auto
   282 
   283 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   284   using *[symmetric] by auto
   285 
   286 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   287   by (simp add: surj_def)
   288 
   289 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   290   by (simp add: surj_def, blast)
   291 
   292 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   293 apply (simp add: comp_def surj_def, clarify)
   294 apply (drule_tac x = y in spec, clarify)
   295 apply (drule_tac x = x in spec, blast)
   296 done
   297 
   298 lemma bij_betw_imageI:
   299   "\<lbrakk> inj_on f A; f ` A = B \<rbrakk> \<Longrightarrow> bij_betw f A B"
   300 unfolding bij_betw_def by clarify
   301 
   302 lemma bij_betw_imp_surj_on: "bij_betw f A B \<Longrightarrow> f ` A = B"
   303   unfolding bij_betw_def by clarify
   304 
   305 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   306   unfolding bij_betw_def by auto
   307 
   308 lemma bij_betw_empty1:
   309   assumes "bij_betw f {} A"
   310   shows "A = {}"
   311 using assms unfolding bij_betw_def by blast
   312 
   313 lemma bij_betw_empty2:
   314   assumes "bij_betw f A {}"
   315   shows "A = {}"
   316 using assms unfolding bij_betw_def by blast
   317 
   318 lemma inj_on_imp_bij_betw:
   319   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   320 unfolding bij_betw_def by simp
   321 
   322 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   323   unfolding bij_betw_def ..
   324 
   325 lemma bijI: "[| inj f; surj f |] ==> bij f"
   326 by (simp add: bij_def)
   327 
   328 lemma bij_is_inj: "bij f ==> inj f"
   329 by (simp add: bij_def)
   330 
   331 lemma bij_is_surj: "bij f ==> surj f"
   332 by (simp add: bij_def)
   333 
   334 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   335 by (simp add: bij_betw_def)
   336 
   337 lemma bij_betw_trans:
   338   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   339 by(auto simp add:bij_betw_def comp_inj_on)
   340 
   341 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   342   by (rule bij_betw_trans)
   343 
   344 lemma bij_betw_comp_iff:
   345   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   346 by(auto simp add: bij_betw_def inj_on_def)
   347 
   348 lemma bij_betw_comp_iff2:
   349   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   350   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   351 using assms
   352 proof(auto simp add: bij_betw_comp_iff)
   353   assume *: "bij_betw (f' \<circ> f) A A''"
   354   thus "bij_betw f A A'"
   355   using IM
   356   proof(auto simp add: bij_betw_def)
   357     assume "inj_on (f' \<circ> f) A"
   358     thus "inj_on f A" using inj_on_imageI2 by blast
   359   next
   360     fix a' assume **: "a' \<in> A'"
   361     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   362     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   363     unfolding bij_betw_def by force
   364     hence "f a \<in> A'" using IM by auto
   365     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   366     thus "a' \<in> f ` A" using 1 by auto
   367   qed
   368 qed
   369 
   370 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   371 proof -
   372   have i: "inj_on f A" and s: "f ` A = B"
   373     using assms by(auto simp:bij_betw_def)
   374   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   375   { fix a b assume P: "?P b a"
   376     hence ex1: "\<exists>a. ?P b a" using s by blast
   377     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   378     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   379   } note g = this
   380   have "inj_on ?g B"
   381   proof(rule inj_onI)
   382     fix x y assume "x:B" "y:B" "?g x = ?g y"
   383     from s `x:B` obtain a1 where a1: "?P x a1" by blast
   384     from s `y:B` obtain a2 where a2: "?P y a2" by blast
   385     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   386   qed
   387   moreover have "?g ` B = A"
   388   proof(auto simp: image_def)
   389     fix b assume "b:B"
   390     with s obtain a where P: "?P b a" by blast
   391     thus "?g b \<in> A" using g[OF P] by auto
   392   next
   393     fix a assume "a:A"
   394     then obtain b where P: "?P b a" using s by blast
   395     then have "b:B" using s by blast
   396     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   397   qed
   398   ultimately show ?thesis by(auto simp:bij_betw_def)
   399 qed
   400 
   401 lemma bij_betw_cong:
   402   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   403 unfolding bij_betw_def inj_on_def by force
   404 
   405 lemma bij_betw_id[intro, simp]:
   406   "bij_betw id A A"
   407 unfolding bij_betw_def id_def by auto
   408 
   409 lemma bij_betw_id_iff:
   410   "bij_betw id A B \<longleftrightarrow> A = B"
   411 by(auto simp add: bij_betw_def)
   412 
   413 lemma bij_betw_combine:
   414   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   415   shows "bij_betw f (A \<union> C) (B \<union> D)"
   416   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   417 
   418 lemma bij_betw_subset:
   419   assumes BIJ: "bij_betw f A A'" and
   420           SUB: "B \<le> A" and IM: "f ` B = B'"
   421   shows "bij_betw f B B'"
   422 using assms
   423 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   424 
   425 lemma bij_pointE:
   426   assumes "bij f"
   427   obtains x where "y = f x" and "\<And>x'. y = f x' \<Longrightarrow> x' = x"
   428 proof -
   429   from assms have "inj f" by (rule bij_is_inj)
   430   moreover from assms have "surj f" by (rule bij_is_surj)
   431   then have "y \<in> range f" by simp
   432   ultimately have "\<exists>!x. y = f x" by (simp add: range_ex1_eq)
   433   with that show thesis by blast
   434 qed
   435 
   436 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   437 by simp
   438 
   439 lemma surj_vimage_empty:
   440   assumes "surj f" shows "f -` A = {} \<longleftrightarrow> A = {}"
   441   using surj_image_vimage_eq[OF `surj f`, of A]
   442   by (intro iffI) fastforce+
   443 
   444 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   445 by (simp add: inj_on_def, blast)
   446 
   447 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   448 by (blast intro: sym)
   449 
   450 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   451 by (unfold inj_on_def, blast)
   452 
   453 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   454 apply (unfold bij_def)
   455 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   456 done
   457 
   458 lemma inj_on_image_eq_iff: "\<lbrakk> inj_on f C; A \<subseteq> C; B \<subseteq> C \<rbrakk> \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   459 by(fastforce simp add: inj_on_def)
   460 
   461 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   462 by(erule inj_on_image_eq_iff) simp_all
   463 
   464 lemma inj_on_image_Int:
   465    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   466 apply (simp add: inj_on_def, blast)
   467 done
   468 
   469 lemma inj_on_image_set_diff:
   470    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   471 apply (simp add: inj_on_def, blast)
   472 done
   473 
   474 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   475 by (simp add: inj_on_def, blast)
   476 
   477 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   478 by (simp add: inj_on_def, blast)
   479 
   480 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   481 by (blast dest: injD)
   482 
   483 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   484 by (simp add: inj_on_def, blast)
   485 
   486 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   487 by (blast dest: injD)
   488 
   489 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   490 by auto
   491 
   492 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   493 by (auto simp add: inj_on_def)
   494 
   495 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   496 apply (simp add: bij_def)
   497 apply (rule equalityI)
   498 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   499 done
   500 
   501 lemma inj_vimage_singleton: "inj f \<Longrightarrow> f -` {a} \<subseteq> {THE x. f x = a}"
   502   -- {* The inverse image of a singleton under an injective function
   503          is included in a singleton. *}
   504   apply (auto simp add: inj_on_def)
   505   apply (blast intro: the_equality [symmetric])
   506   done
   507 
   508 lemma inj_on_vimage_singleton:
   509   "inj_on f A \<Longrightarrow> f -` {a} \<inter> A \<subseteq> {THE x. x \<in> A \<and> f x = a}"
   510   by (auto simp add: inj_on_def intro: the_equality [symmetric])
   511 
   512 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   513   by (auto intro!: inj_onI)
   514 
   515 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   516   by (auto intro!: inj_onI dest: strict_mono_eq)
   517 
   518 lemma bij_betw_byWitness:
   519 assumes LEFT: "\<forall>a \<in> A. f'(f a) = a" and
   520         RIGHT: "\<forall>a' \<in> A'. f(f' a') = a'" and
   521         IM1: "f ` A \<le> A'" and IM2: "f' ` A' \<le> A"
   522 shows "bij_betw f A A'"
   523 using assms
   524 proof(unfold bij_betw_def inj_on_def, safe)
   525   fix a b assume *: "a \<in> A" "b \<in> A" and **: "f a = f b"
   526   have "a = f'(f a) \<and> b = f'(f b)" using * LEFT by simp
   527   with ** show "a = b" by simp
   528 next
   529   fix a' assume *: "a' \<in> A'"
   530   hence "f' a' \<in> A" using IM2 by blast
   531   moreover
   532   have "a' = f(f' a')" using * RIGHT by simp
   533   ultimately show "a' \<in> f ` A" by blast
   534 qed
   535 
   536 corollary notIn_Un_bij_betw:
   537 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'" and
   538        BIJ: "bij_betw f A A'"
   539 shows "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   540 proof-
   541   have "bij_betw f {b} {f b}"
   542   unfolding bij_betw_def inj_on_def by simp
   543   with assms show ?thesis
   544   using bij_betw_combine[of f A A' "{b}" "{f b}"] by blast
   545 qed
   546 
   547 lemma notIn_Un_bij_betw3:
   548 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'"
   549 shows "bij_betw f A A' = bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   550 proof
   551   assume "bij_betw f A A'"
   552   thus "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   553   using assms notIn_Un_bij_betw[of b A f A'] by blast
   554 next
   555   assume *: "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   556   have "f ` A = A'"
   557   proof(auto)
   558     fix a assume **: "a \<in> A"
   559     hence "f a \<in> A' \<union> {f b}" using * unfolding bij_betw_def by blast
   560     moreover
   561     {assume "f a = f b"
   562      hence "a = b" using * ** unfolding bij_betw_def inj_on_def by blast
   563      with NIN ** have False by blast
   564     }
   565     ultimately show "f a \<in> A'" by blast
   566   next
   567     fix a' assume **: "a' \<in> A'"
   568     hence "a' \<in> f`(A \<union> {b})"
   569     using * by (auto simp add: bij_betw_def)
   570     then obtain a where 1: "a \<in> A \<union> {b} \<and> f a = a'" by blast
   571     moreover
   572     {assume "a = b" with 1 ** NIN' have False by blast
   573     }
   574     ultimately have "a \<in> A" by blast
   575     with 1 show "a' \<in> f ` A" by blast
   576   qed
   577   thus "bij_betw f A A'" using * bij_betw_subset[of f "A \<union> {b}" _ A] by blast
   578 qed
   579 
   580 
   581 subsection{*Function Updating*}
   582 
   583 definition fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   584   "fun_upd f a b == % x. if x=a then b else f x"
   585 
   586 nonterminal updbinds and updbind
   587 
   588 syntax
   589   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   590   ""         :: "updbind => updbinds"             ("_")
   591   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   592   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   593 
   594 translations
   595   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   596   "f(x:=y)" == "CONST fun_upd f x y"
   597 
   598 (* Hint: to define the sum of two functions (or maps), use case_sum.
   599          A nice infix syntax could be defined by
   600 notation
   601   case_sum  (infixr "'(+')"80)
   602 *)
   603 
   604 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   605 apply (simp add: fun_upd_def, safe)
   606 apply (erule subst)
   607 apply (rule_tac [2] ext, auto)
   608 done
   609 
   610 lemma fun_upd_idem: "f x = y ==> f(x:=y) = f"
   611   by (simp only: fun_upd_idem_iff)
   612 
   613 lemma fun_upd_triv [iff]: "f(x := f x) = f"
   614   by (simp only: fun_upd_idem)
   615 
   616 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   617 by (simp add: fun_upd_def)
   618 
   619 (* fun_upd_apply supersedes these two,   but they are useful
   620    if fun_upd_apply is intentionally removed from the simpset *)
   621 lemma fun_upd_same: "(f(x:=y)) x = y"
   622 by simp
   623 
   624 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   625 by simp
   626 
   627 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   628 by (simp add: fun_eq_iff)
   629 
   630 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   631 by (rule ext, auto)
   632 
   633 lemma inj_on_fun_updI:
   634   "inj_on f A \<Longrightarrow> y \<notin> f ` A \<Longrightarrow> inj_on (f(x := y)) A"
   635   by (fastforce simp: inj_on_def)
   636 
   637 lemma fun_upd_image:
   638      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   639 by auto
   640 
   641 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   642   by auto
   643 
   644 
   645 subsection {* @{text override_on} *}
   646 
   647 definition override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b" where
   648   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   649 
   650 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   651 by(simp add:override_on_def)
   652 
   653 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   654 by(simp add:override_on_def)
   655 
   656 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   657 by(simp add:override_on_def)
   658 
   659 
   660 subsection {* @{text swap} *}
   661 
   662 definition swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   663 where
   664   "swap a b f = f (a := f b, b:= f a)"
   665 
   666 lemma swap_apply [simp]:
   667   "swap a b f a = f b"
   668   "swap a b f b = f a"
   669   "c \<noteq> a \<Longrightarrow> c \<noteq> b \<Longrightarrow> swap a b f c = f c"
   670   by (simp_all add: swap_def)
   671 
   672 lemma swap_self [simp]:
   673   "swap a a f = f"
   674   by (simp add: swap_def)
   675 
   676 lemma swap_commute:
   677   "swap a b f = swap b a f"
   678   by (simp add: fun_upd_def swap_def fun_eq_iff)
   679 
   680 lemma swap_nilpotent [simp]:
   681   "swap a b (swap a b f) = f"
   682   by (rule ext, simp add: fun_upd_def swap_def)
   683 
   684 lemma swap_comp_involutory [simp]:
   685   "swap a b \<circ> swap a b = id"
   686   by (rule ext) simp
   687 
   688 lemma swap_triple:
   689   assumes "a \<noteq> c" and "b \<noteq> c"
   690   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   691   using assms by (simp add: fun_eq_iff swap_def)
   692 
   693 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   694   by (rule ext, simp add: fun_upd_def swap_def)
   695 
   696 lemma swap_image_eq [simp]:
   697   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   698 proof -
   699   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   700     using assms by (auto simp: image_iff swap_def)
   701   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   702   with subset[of f] show ?thesis by auto
   703 qed
   704 
   705 lemma inj_on_imp_inj_on_swap:
   706   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   707   by (simp add: inj_on_def swap_def, blast)
   708 
   709 lemma inj_on_swap_iff [simp]:
   710   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   711 proof
   712   assume "inj_on (swap a b f) A"
   713   with A have "inj_on (swap a b (swap a b f)) A"
   714     by (iprover intro: inj_on_imp_inj_on_swap)
   715   thus "inj_on f A" by simp
   716 next
   717   assume "inj_on f A"
   718   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   719 qed
   720 
   721 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   722   by simp
   723 
   724 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   725   by simp
   726 
   727 lemma bij_betw_swap_iff [simp]:
   728   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   729   by (auto simp: bij_betw_def)
   730 
   731 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   732   by simp
   733 
   734 hide_const (open) swap
   735 
   736 
   737 subsection {* Inversion of injective functions *}
   738 
   739 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   740   "the_inv_into A f == %x. THE y. y : A & f y = x"
   741 
   742 lemma the_inv_into_f_f:
   743   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   744 apply (simp add: the_inv_into_def inj_on_def)
   745 apply blast
   746 done
   747 
   748 lemma f_the_inv_into_f:
   749   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   750 apply (simp add: the_inv_into_def)
   751 apply (rule the1I2)
   752  apply(blast dest: inj_onD)
   753 apply blast
   754 done
   755 
   756 lemma the_inv_into_into:
   757   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   758 apply (simp add: the_inv_into_def)
   759 apply (rule the1I2)
   760  apply(blast dest: inj_onD)
   761 apply blast
   762 done
   763 
   764 lemma the_inv_into_onto[simp]:
   765   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   766 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   767 
   768 lemma the_inv_into_f_eq:
   769   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   770   apply (erule subst)
   771   apply (erule the_inv_into_f_f, assumption)
   772   done
   773 
   774 lemma the_inv_into_comp:
   775   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   776   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   777 apply (rule the_inv_into_f_eq)
   778   apply (fast intro: comp_inj_on)
   779  apply (simp add: f_the_inv_into_f the_inv_into_into)
   780 apply (simp add: the_inv_into_into)
   781 done
   782 
   783 lemma inj_on_the_inv_into:
   784   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   785 by (auto intro: inj_onI simp: the_inv_into_f_f)
   786 
   787 lemma bij_betw_the_inv_into:
   788   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   789 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   790 
   791 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   792   "the_inv f \<equiv> the_inv_into UNIV f"
   793 
   794 lemma the_inv_f_f:
   795   assumes "inj f"
   796   shows "the_inv f (f x) = x" using assms UNIV_I
   797   by (rule the_inv_into_f_f)
   798 
   799 
   800 subsection {* Cantor's Paradox *}
   801 
   802 lemma Cantors_paradox:
   803   "\<not>(\<exists>f. f ` A = Pow A)"
   804 proof clarify
   805   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   806   let ?X = "{a \<in> A. a \<notin> f a}"
   807   have "?X \<in> Pow A" unfolding Pow_def by auto
   808   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   809   thus False by best
   810 qed
   811 
   812 subsection {* Setup *} 
   813 
   814 subsubsection {* Proof tools *}
   815 
   816 text {* simplifies terms of the form
   817   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   818 
   819 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   820 let
   821   fun gen_fun_upd NONE T _ _ = NONE
   822     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   823   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   824   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   825     let
   826       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   827             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   828         | find t = NONE
   829     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   830 
   831   val ss = simpset_of @{context}
   832 
   833   fun proc ctxt ct =
   834     let
   835       val t = Thm.term_of ct
   836     in
   837       case find_double t of
   838         (T, NONE) => NONE
   839       | (T, SOME rhs) =>
   840           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   841             (fn _ =>
   842               resolve_tac ctxt [eq_reflection] 1 THEN
   843               resolve_tac ctxt @{thms ext} 1 THEN
   844               simp_tac (put_simpset ss ctxt) 1))
   845     end
   846 in proc end
   847 *}
   848 
   849 
   850 subsubsection {* Functorial structure of types *}
   851 
   852 ML_file "Tools/functor.ML"
   853 
   854 functor map_fun: map_fun
   855   by (simp_all add: fun_eq_iff)
   856 
   857 functor vimage
   858   by (simp_all add: fun_eq_iff vimage_comp)
   859 
   860 text {* Legacy theorem names *}
   861 
   862 lemmas o_def = comp_def
   863 lemmas o_apply = comp_apply
   864 lemmas o_assoc = comp_assoc [symmetric]
   865 lemmas id_o = id_comp
   866 lemmas o_id = comp_id
   867 lemmas o_eq_dest = comp_eq_dest
   868 lemmas o_eq_elim = comp_eq_elim
   869 lemmas o_eq_dest_lhs = comp_eq_dest_lhs
   870 lemmas o_eq_id_dest = comp_eq_id_dest
   871 
   872 end
   873