src/HOL/Transfer.thy
author Andreas Lochbihler
Fri Sep 27 09:07:45 2013 +0200 (2013-09-27)
changeset 53944 50c8f7f21327
parent 53927 abe2b313f0e5
child 53952 b2781a3ce958
permissions -rw-r--r--
add lemmas
     1 (*  Title:      HOL/Transfer.thy
     2     Author:     Brian Huffman, TU Muenchen
     3     Author:     Ondrej Kuncar, TU Muenchen
     4 *)
     5 
     6 header {* Generic theorem transfer using relations *}
     7 
     8 theory Transfer
     9 imports Hilbert_Choice
    10 begin
    11 
    12 subsection {* Relator for function space *}
    13 
    14 definition
    15   fun_rel :: "('a \<Rightarrow> 'c \<Rightarrow> bool) \<Rightarrow> ('b \<Rightarrow> 'd \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('c \<Rightarrow> 'd) \<Rightarrow> bool"
    16 where
    17   "fun_rel A B = (\<lambda>f g. \<forall>x y. A x y \<longrightarrow> B (f x) (g y))"
    18 
    19 locale lifting_syntax
    20 begin
    21   notation fun_rel (infixr "===>" 55)
    22   notation map_fun (infixr "--->" 55)
    23 end
    24 
    25 context
    26 begin
    27 interpretation lifting_syntax .
    28 
    29 lemma fun_relI [intro]:
    30   assumes "\<And>x y. A x y \<Longrightarrow> B (f x) (g y)"
    31   shows "(A ===> B) f g"
    32   using assms by (simp add: fun_rel_def)
    33 
    34 lemma fun_relD:
    35   assumes "(A ===> B) f g" and "A x y"
    36   shows "B (f x) (g y)"
    37   using assms by (simp add: fun_rel_def)
    38 
    39 lemma fun_relD2:
    40   assumes "(A ===> B) f g" and "A x x"
    41   shows "B (f x) (g x)"
    42   using assms unfolding fun_rel_def by auto
    43 
    44 lemma fun_relE:
    45   assumes "(A ===> B) f g" and "A x y"
    46   obtains "B (f x) (g y)"
    47   using assms by (simp add: fun_rel_def)
    48 
    49 lemma fun_rel_eq:
    50   shows "((op =) ===> (op =)) = (op =)"
    51   by (auto simp add: fun_eq_iff elim: fun_relE)
    52 
    53 lemma fun_rel_eq_rel:
    54   shows "((op =) ===> R) = (\<lambda>f g. \<forall>x. R (f x) (g x))"
    55   by (simp add: fun_rel_def)
    56 
    57 
    58 subsection {* Transfer method *}
    59 
    60 text {* Explicit tag for relation membership allows for
    61   backward proof methods. *}
    62 
    63 definition Rel :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
    64   where "Rel r \<equiv> r"
    65 
    66 text {* Handling of equality relations *}
    67 
    68 definition is_equality :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
    69   where "is_equality R \<longleftrightarrow> R = (op =)"
    70 
    71 lemma is_equality_eq: "is_equality (op =)"
    72   unfolding is_equality_def by simp
    73 
    74 text {* Reverse implication for monotonicity rules *}
    75 
    76 definition rev_implies where
    77   "rev_implies x y \<longleftrightarrow> (y \<longrightarrow> x)"
    78 
    79 text {* Handling of meta-logic connectives *}
    80 
    81 definition transfer_forall where
    82   "transfer_forall \<equiv> All"
    83 
    84 definition transfer_implies where
    85   "transfer_implies \<equiv> op \<longrightarrow>"
    86 
    87 definition transfer_bforall :: "('a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool"
    88   where "transfer_bforall \<equiv> (\<lambda>P Q. \<forall>x. P x \<longrightarrow> Q x)"
    89 
    90 lemma transfer_forall_eq: "(\<And>x. P x) \<equiv> Trueprop (transfer_forall (\<lambda>x. P x))"
    91   unfolding atomize_all transfer_forall_def ..
    92 
    93 lemma transfer_implies_eq: "(A \<Longrightarrow> B) \<equiv> Trueprop (transfer_implies A B)"
    94   unfolding atomize_imp transfer_implies_def ..
    95 
    96 lemma transfer_bforall_unfold:
    97   "Trueprop (transfer_bforall P (\<lambda>x. Q x)) \<equiv> (\<And>x. P x \<Longrightarrow> Q x)"
    98   unfolding transfer_bforall_def atomize_imp atomize_all ..
    99 
   100 lemma transfer_start: "\<lbrakk>P; Rel (op =) P Q\<rbrakk> \<Longrightarrow> Q"
   101   unfolding Rel_def by simp
   102 
   103 lemma transfer_start': "\<lbrakk>P; Rel (op \<longrightarrow>) P Q\<rbrakk> \<Longrightarrow> Q"
   104   unfolding Rel_def by simp
   105 
   106 lemma transfer_prover_start: "\<lbrakk>x = x'; Rel R x' y\<rbrakk> \<Longrightarrow> Rel R x y"
   107   by simp
   108 
   109 lemma untransfer_start: "\<lbrakk>Q; Rel (op =) P Q\<rbrakk> \<Longrightarrow> P"
   110   unfolding Rel_def by simp
   111 
   112 lemma Rel_eq_refl: "Rel (op =) x x"
   113   unfolding Rel_def ..
   114 
   115 lemma Rel_app:
   116   assumes "Rel (A ===> B) f g" and "Rel A x y"
   117   shows "Rel B (f x) (g y)"
   118   using assms unfolding Rel_def fun_rel_def by fast
   119 
   120 lemma Rel_abs:
   121   assumes "\<And>x y. Rel A x y \<Longrightarrow> Rel B (f x) (g y)"
   122   shows "Rel (A ===> B) (\<lambda>x. f x) (\<lambda>y. g y)"
   123   using assms unfolding Rel_def fun_rel_def by fast
   124 
   125 end
   126 
   127 ML_file "Tools/transfer.ML"
   128 setup Transfer.setup
   129 
   130 declare refl [transfer_rule]
   131 
   132 declare fun_rel_eq [relator_eq]
   133 
   134 hide_const (open) Rel
   135 
   136 context
   137 begin
   138 interpretation lifting_syntax .
   139 
   140 text {* Handling of domains *}
   141 
   142 lemma Domaimp_refl[transfer_domain_rule]:
   143   "Domainp T = Domainp T" ..
   144 
   145 subsection {* Predicates on relations, i.e. ``class constraints'' *}
   146 
   147 definition right_total :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   148   where "right_total R \<longleftrightarrow> (\<forall>y. \<exists>x. R x y)"
   149 
   150 definition right_unique :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   151   where "right_unique R \<longleftrightarrow> (\<forall>x y z. R x y \<longrightarrow> R x z \<longrightarrow> y = z)"
   152 
   153 definition bi_total :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   154   where "bi_total R \<longleftrightarrow> (\<forall>x. \<exists>y. R x y) \<and> (\<forall>y. \<exists>x. R x y)"
   155 
   156 definition bi_unique :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   157   where "bi_unique R \<longleftrightarrow>
   158     (\<forall>x y z. R x y \<longrightarrow> R x z \<longrightarrow> y = z) \<and>
   159     (\<forall>x y z. R x z \<longrightarrow> R y z \<longrightarrow> x = y)"
   160 
   161 lemma bi_uniqueDr: "\<lbrakk> bi_unique A; A x y; A x z \<rbrakk> \<Longrightarrow> y = z"
   162 by(simp add: bi_unique_def)
   163 
   164 lemma bi_uniqueDl: "\<lbrakk> bi_unique A; A x y; A z y \<rbrakk> \<Longrightarrow> x = z"
   165 by(simp add: bi_unique_def)
   166 
   167 lemma right_uniqueI: "(\<And>x y z. \<lbrakk> A x y; A x z \<rbrakk> \<Longrightarrow> y = z) \<Longrightarrow> right_unique A"
   168 unfolding right_unique_def by blast
   169 
   170 lemma right_uniqueD: "\<lbrakk> right_unique A; A x y; A x z \<rbrakk> \<Longrightarrow> y = z"
   171 unfolding right_unique_def by blast
   172 
   173 lemma right_total_alt_def:
   174   "right_total R \<longleftrightarrow> ((R ===> op \<longrightarrow>) ===> op \<longrightarrow>) All All"
   175   unfolding right_total_def fun_rel_def
   176   apply (rule iffI, fast)
   177   apply (rule allI)
   178   apply (drule_tac x="\<lambda>x. True" in spec)
   179   apply (drule_tac x="\<lambda>y. \<exists>x. R x y" in spec)
   180   apply fast
   181   done
   182 
   183 lemma right_unique_alt_def:
   184   "right_unique R \<longleftrightarrow> (R ===> R ===> op \<longrightarrow>) (op =) (op =)"
   185   unfolding right_unique_def fun_rel_def by auto
   186 
   187 lemma bi_total_alt_def:
   188   "bi_total R \<longleftrightarrow> ((R ===> op =) ===> op =) All All"
   189   unfolding bi_total_def fun_rel_def
   190   apply (rule iffI, fast)
   191   apply safe
   192   apply (drule_tac x="\<lambda>x. \<exists>y. R x y" in spec)
   193   apply (drule_tac x="\<lambda>y. True" in spec)
   194   apply fast
   195   apply (drule_tac x="\<lambda>x. True" in spec)
   196   apply (drule_tac x="\<lambda>y. \<exists>x. R x y" in spec)
   197   apply fast
   198   done
   199 
   200 lemma bi_unique_alt_def:
   201   "bi_unique R \<longleftrightarrow> (R ===> R ===> op =) (op =) (op =)"
   202   unfolding bi_unique_def fun_rel_def by auto
   203 
   204 lemma bi_unique_conversep [simp]: "bi_unique R\<inverse>\<inverse> = bi_unique R"
   205 by(auto simp add: bi_unique_def)
   206 
   207 lemma bi_total_conversep [simp]: "bi_total R\<inverse>\<inverse> = bi_total R"
   208 by(auto simp add: bi_total_def)
   209 
   210 text {* Properties are preserved by relation composition. *}
   211 
   212 lemma OO_def: "R OO S = (\<lambda>x z. \<exists>y. R x y \<and> S y z)"
   213   by auto
   214 
   215 lemma bi_total_OO: "\<lbrakk>bi_total A; bi_total B\<rbrakk> \<Longrightarrow> bi_total (A OO B)"
   216   unfolding bi_total_def OO_def by metis
   217 
   218 lemma bi_unique_OO: "\<lbrakk>bi_unique A; bi_unique B\<rbrakk> \<Longrightarrow> bi_unique (A OO B)"
   219   unfolding bi_unique_def OO_def by metis
   220 
   221 lemma right_total_OO:
   222   "\<lbrakk>right_total A; right_total B\<rbrakk> \<Longrightarrow> right_total (A OO B)"
   223   unfolding right_total_def OO_def by metis
   224 
   225 lemma right_unique_OO:
   226   "\<lbrakk>right_unique A; right_unique B\<rbrakk> \<Longrightarrow> right_unique (A OO B)"
   227   unfolding right_unique_def OO_def by metis
   228 
   229 
   230 subsection {* Properties of relators *}
   231 
   232 lemma right_total_eq [transfer_rule]: "right_total (op =)"
   233   unfolding right_total_def by simp
   234 
   235 lemma right_unique_eq [transfer_rule]: "right_unique (op =)"
   236   unfolding right_unique_def by simp
   237 
   238 lemma bi_total_eq [transfer_rule]: "bi_total (op =)"
   239   unfolding bi_total_def by simp
   240 
   241 lemma bi_unique_eq [transfer_rule]: "bi_unique (op =)"
   242   unfolding bi_unique_def by simp
   243 
   244 lemma right_total_fun [transfer_rule]:
   245   "\<lbrakk>right_unique A; right_total B\<rbrakk> \<Longrightarrow> right_total (A ===> B)"
   246   unfolding right_total_def fun_rel_def
   247   apply (rule allI, rename_tac g)
   248   apply (rule_tac x="\<lambda>x. SOME z. B z (g (THE y. A x y))" in exI)
   249   apply clarify
   250   apply (subgoal_tac "(THE y. A x y) = y", simp)
   251   apply (rule someI_ex)
   252   apply (simp)
   253   apply (rule the_equality)
   254   apply assumption
   255   apply (simp add: right_unique_def)
   256   done
   257 
   258 lemma right_unique_fun [transfer_rule]:
   259   "\<lbrakk>right_total A; right_unique B\<rbrakk> \<Longrightarrow> right_unique (A ===> B)"
   260   unfolding right_total_def right_unique_def fun_rel_def
   261   by (clarify, rule ext, fast)
   262 
   263 lemma bi_total_fun [transfer_rule]:
   264   "\<lbrakk>bi_unique A; bi_total B\<rbrakk> \<Longrightarrow> bi_total (A ===> B)"
   265   unfolding bi_total_def fun_rel_def
   266   apply safe
   267   apply (rename_tac f)
   268   apply (rule_tac x="\<lambda>y. SOME z. B (f (THE x. A x y)) z" in exI)
   269   apply clarify
   270   apply (subgoal_tac "(THE x. A x y) = x", simp)
   271   apply (rule someI_ex)
   272   apply (simp)
   273   apply (rule the_equality)
   274   apply assumption
   275   apply (simp add: bi_unique_def)
   276   apply (rename_tac g)
   277   apply (rule_tac x="\<lambda>x. SOME z. B z (g (THE y. A x y))" in exI)
   278   apply clarify
   279   apply (subgoal_tac "(THE y. A x y) = y", simp)
   280   apply (rule someI_ex)
   281   apply (simp)
   282   apply (rule the_equality)
   283   apply assumption
   284   apply (simp add: bi_unique_def)
   285   done
   286 
   287 lemma bi_unique_fun [transfer_rule]:
   288   "\<lbrakk>bi_total A; bi_unique B\<rbrakk> \<Longrightarrow> bi_unique (A ===> B)"
   289   unfolding bi_total_def bi_unique_def fun_rel_def fun_eq_iff
   290   by (safe, metis, fast)
   291 
   292 
   293 subsection {* Transfer rules *}
   294 
   295 text {* Transfer rules using implication instead of equality on booleans. *}
   296 
   297 lemma transfer_forall_transfer [transfer_rule]:
   298   "bi_total A \<Longrightarrow> ((A ===> op =) ===> op =) transfer_forall transfer_forall"
   299   "right_total A \<Longrightarrow> ((A ===> op =) ===> implies) transfer_forall transfer_forall"
   300   "right_total A \<Longrightarrow> ((A ===> implies) ===> implies) transfer_forall transfer_forall"
   301   "bi_total A \<Longrightarrow> ((A ===> op =) ===> rev_implies) transfer_forall transfer_forall"
   302   "bi_total A \<Longrightarrow> ((A ===> rev_implies) ===> rev_implies) transfer_forall transfer_forall"
   303   unfolding transfer_forall_def rev_implies_def fun_rel_def right_total_def bi_total_def
   304   by metis+
   305 
   306 lemma transfer_implies_transfer [transfer_rule]:
   307   "(op =        ===> op =        ===> op =       ) transfer_implies transfer_implies"
   308   "(rev_implies ===> implies     ===> implies    ) transfer_implies transfer_implies"
   309   "(rev_implies ===> op =        ===> implies    ) transfer_implies transfer_implies"
   310   "(op =        ===> implies     ===> implies    ) transfer_implies transfer_implies"
   311   "(op =        ===> op =        ===> implies    ) transfer_implies transfer_implies"
   312   "(implies     ===> rev_implies ===> rev_implies) transfer_implies transfer_implies"
   313   "(implies     ===> op =        ===> rev_implies) transfer_implies transfer_implies"
   314   "(op =        ===> rev_implies ===> rev_implies) transfer_implies transfer_implies"
   315   "(op =        ===> op =        ===> rev_implies) transfer_implies transfer_implies"
   316   unfolding transfer_implies_def rev_implies_def fun_rel_def by auto
   317 
   318 lemma eq_imp_transfer [transfer_rule]:
   319   "right_unique A \<Longrightarrow> (A ===> A ===> op \<longrightarrow>) (op =) (op =)"
   320   unfolding right_unique_alt_def .
   321 
   322 lemma eq_transfer [transfer_rule]:
   323   assumes "bi_unique A"
   324   shows "(A ===> A ===> op =) (op =) (op =)"
   325   using assms unfolding bi_unique_def fun_rel_def by auto
   326 
   327 lemma Domainp_iff: "Domainp T x \<longleftrightarrow> (\<exists>y. T x y)"
   328   by auto
   329 
   330 lemma right_total_Ex_transfer[transfer_rule]:
   331   assumes "right_total A"
   332   shows "((A ===> op=) ===> op=) (Bex (Collect (Domainp A))) Ex"
   333 using assms unfolding right_total_def Bex_def fun_rel_def Domainp_iff[abs_def]
   334 by blast
   335 
   336 lemma right_total_All_transfer[transfer_rule]:
   337   assumes "right_total A"
   338   shows "((A ===> op =) ===> op =) (Ball (Collect (Domainp A))) All"
   339 using assms unfolding right_total_def Ball_def fun_rel_def Domainp_iff[abs_def]
   340 by blast
   341 
   342 lemma All_transfer [transfer_rule]:
   343   assumes "bi_total A"
   344   shows "((A ===> op =) ===> op =) All All"
   345   using assms unfolding bi_total_def fun_rel_def by fast
   346 
   347 lemma Ex_transfer [transfer_rule]:
   348   assumes "bi_total A"
   349   shows "((A ===> op =) ===> op =) Ex Ex"
   350   using assms unfolding bi_total_def fun_rel_def by fast
   351 
   352 lemma If_transfer [transfer_rule]: "(op = ===> A ===> A ===> A) If If"
   353   unfolding fun_rel_def by simp
   354 
   355 lemma Let_transfer [transfer_rule]: "(A ===> (A ===> B) ===> B) Let Let"
   356   unfolding fun_rel_def by simp
   357 
   358 lemma id_transfer [transfer_rule]: "(A ===> A) id id"
   359   unfolding fun_rel_def by simp
   360 
   361 lemma comp_transfer [transfer_rule]:
   362   "((B ===> C) ===> (A ===> B) ===> (A ===> C)) (op \<circ>) (op \<circ>)"
   363   unfolding fun_rel_def by simp
   364 
   365 lemma fun_upd_transfer [transfer_rule]:
   366   assumes [transfer_rule]: "bi_unique A"
   367   shows "((A ===> B) ===> A ===> B ===> A ===> B) fun_upd fun_upd"
   368   unfolding fun_upd_def [abs_def] by transfer_prover
   369 
   370 lemma nat_case_transfer [transfer_rule]:
   371   "(A ===> (op = ===> A) ===> op = ===> A) nat_case nat_case"
   372   unfolding fun_rel_def by (simp split: nat.split)
   373 
   374 lemma nat_rec_transfer [transfer_rule]:
   375   "(A ===> (op = ===> A ===> A) ===> op = ===> A) nat_rec nat_rec"
   376   unfolding fun_rel_def by (clarsimp, rename_tac n, induct_tac n, simp_all)
   377 
   378 lemma funpow_transfer [transfer_rule]:
   379   "(op = ===> (A ===> A) ===> (A ===> A)) compow compow"
   380   unfolding funpow_def by transfer_prover
   381 
   382 lemma Domainp_forall_transfer [transfer_rule]:
   383   assumes "right_total A"
   384   shows "((A ===> op =) ===> op =)
   385     (transfer_bforall (Domainp A)) transfer_forall"
   386   using assms unfolding right_total_def
   387   unfolding transfer_forall_def transfer_bforall_def fun_rel_def Domainp_iff
   388   by metis
   389 
   390 lemma forall_transfer [transfer_rule]:
   391   "bi_total A \<Longrightarrow> ((A ===> op =) ===> op =) transfer_forall transfer_forall"
   392   unfolding transfer_forall_def by (rule All_transfer)
   393 
   394 end
   395 
   396 end