src/HOL/HOL.thy
author wenzelm
Sat May 14 13:32:33 2011 +0200 (2011-05-14)
changeset 42802 51d7e74f6899
parent 42799 4e33894aec6d
child 43560 d1650e3720fd
permissions -rw-r--r--
simplified BLAST_DATA;
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* The basis of Higher-Order Logic *}
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 uses
    10   ("Tools/hologic.ML")
    11   "~~/src/Tools/IsaPlanner/zipper.ML"
    12   "~~/src/Tools/IsaPlanner/isand.ML"
    13   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    14   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    15   "~~/src/Tools/intuitionistic.ML"
    16   "~~/src/Tools/project_rule.ML"
    17   "~~/src/Tools/cong_tac.ML"
    18   "~~/src/Tools/misc_legacy.ML"
    19   "~~/src/Provers/hypsubst.ML"
    20   "~~/src/Provers/splitter.ML"
    21   "~~/src/Provers/classical.ML"
    22   "~~/src/Provers/blast.ML"
    23   "~~/src/Provers/clasimp.ML"
    24   "~~/src/Tools/coherent.ML"
    25   "~~/src/Tools/eqsubst.ML"
    26   "~~/src/Provers/quantifier1.ML"
    27   ("Tools/simpdata.ML")
    28   "~~/src/Tools/atomize_elim.ML"
    29   "~~/src/Tools/induct.ML"
    30   ("~~/src/Tools/induct_tacs.ML")
    31   ("Tools/recfun_codegen.ML")
    32   ("Tools/cnf_funcs.ML")
    33   "~~/src/Tools/subtyping.ML"
    34   "~~/src/Tools/case_product.ML"
    35 begin
    36 
    37 setup {* Intuitionistic.method_setup @{binding iprover} *}
    38 setup Subtyping.setup
    39 setup Case_Product.setup
    40 
    41 
    42 subsection {* Primitive logic *}
    43 
    44 subsubsection {* Core syntax *}
    45 
    46 classes type
    47 default_sort type
    48 setup {* Object_Logic.add_base_sort @{sort type} *}
    49 
    50 arities
    51   "fun" :: (type, type) type
    52   itself :: (type) type
    53 
    54 typedecl bool
    55 
    56 judgment
    57   Trueprop      :: "bool => prop"                   ("(_)" 5)
    58 
    59 consts
    60   True          :: bool
    61   False         :: bool
    62   Not           :: "bool => bool"                   ("~ _" [40] 40)
    63 
    64   conj          :: "[bool, bool] => bool"           (infixr "&" 35)
    65   disj          :: "[bool, bool] => bool"           (infixr "|" 30)
    66   implies       :: "[bool, bool] => bool"           (infixr "-->" 25)
    67 
    68   eq            :: "['a, 'a] => bool"               (infixl "=" 50)
    69 
    70   The           :: "('a => bool) => 'a"
    71   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    72   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    73   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    74 
    75 
    76 subsubsection {* Additional concrete syntax *}
    77 
    78 notation (output)
    79   eq  (infix "=" 50)
    80 
    81 abbreviation
    82   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    83   "x ~= y == ~ (x = y)"
    84 
    85 notation (output)
    86   not_equal  (infix "~=" 50)
    87 
    88 notation (xsymbols)
    89   Not  ("\<not> _" [40] 40) and
    90   conj  (infixr "\<and>" 35) and
    91   disj  (infixr "\<or>" 30) and
    92   implies  (infixr "\<longrightarrow>" 25) and
    93   not_equal  (infix "\<noteq>" 50)
    94 
    95 notation (HTML output)
    96   Not  ("\<not> _" [40] 40) and
    97   conj  (infixr "\<and>" 35) and
    98   disj  (infixr "\<or>" 30) and
    99   not_equal  (infix "\<noteq>" 50)
   100 
   101 abbreviation (iff)
   102   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   103   "A <-> B == A = B"
   104 
   105 notation (xsymbols)
   106   iff  (infixr "\<longleftrightarrow>" 25)
   107 
   108 nonterminal letbinds and letbind
   109 nonterminal case_pat and case_syn and cases_syn
   110 
   111 syntax
   112   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   113 
   114   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   115   ""            :: "letbind => letbinds"                 ("_")
   116   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   117   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" [0, 10] 10)
   118 
   119   "_case_syntax"      :: "['a, cases_syn] => 'b"              ("(case _ of/ _)" 10)
   120   "_case1"            :: "[case_pat, 'b] => case_syn"         ("(2_ =>/ _)" 10)
   121   ""                  :: "case_syn => cases_syn"              ("_")
   122   "_case2"            :: "[case_syn, cases_syn] => cases_syn" ("_/ | _")
   123   "_strip_positions"  :: "'a => case_pat"                     ("_")
   124 
   125 syntax (xsymbols)
   126   "_case1" :: "[case_pat, 'b] => case_syn"  ("(2_ \<Rightarrow>/ _)" 10)
   127 
   128 translations
   129   "THE x. P"              == "CONST The (%x. P)"
   130 
   131 print_translation {*
   132   [(@{const_syntax The}, fn [Abs abs] =>
   133       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
   134       in Syntax.const @{syntax_const "_The"} $ x $ t end)]
   135 *}  -- {* To avoid eta-contraction of body *}
   136 
   137 notation (xsymbols)
   138   All  (binder "\<forall>" 10) and
   139   Ex  (binder "\<exists>" 10) and
   140   Ex1  (binder "\<exists>!" 10)
   141 
   142 notation (HTML output)
   143   All  (binder "\<forall>" 10) and
   144   Ex  (binder "\<exists>" 10) and
   145   Ex1  (binder "\<exists>!" 10)
   146 
   147 notation (HOL)
   148   All  (binder "! " 10) and
   149   Ex  (binder "? " 10) and
   150   Ex1  (binder "?! " 10)
   151 
   152 
   153 subsubsection {* Axioms and basic definitions *}
   154 
   155 axioms
   156   refl:           "t = (t::'a)"
   157   subst:          "s = t \<Longrightarrow> P s \<Longrightarrow> P t"
   158   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   159     -- {*Extensionality is built into the meta-logic, and this rule expresses
   160          a related property.  It is an eta-expanded version of the traditional
   161          rule, and similar to the ABS rule of HOL*}
   162 
   163   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   164 
   165   impI:           "(P ==> Q) ==> P-->Q"
   166   mp:             "[| P-->Q;  P |] ==> Q"
   167 
   168 
   169 defs
   170   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   171   All_def:      "All(P)    == (P = (%x. True))"
   172   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   173   False_def:    "False     == (!P. P)"
   174   not_def:      "~ P       == P-->False"
   175   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   176   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   177   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   178 
   179 axioms
   180   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   181   True_or_False:  "(P=True) | (P=False)"
   182 
   183 finalconsts
   184   eq
   185   implies
   186   The
   187 
   188 definition If :: "bool \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a" ("(if (_)/ then (_)/ else (_))" [0, 0, 10] 10) where
   189   "If P x y \<equiv> (THE z::'a. (P=True --> z=x) & (P=False --> z=y))"
   190 
   191 definition Let :: "'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b" where
   192   "Let s f \<equiv> f s"
   193 
   194 translations
   195   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   196   "let x = a in e"        == "CONST Let a (%x. e)"
   197 
   198 axiomatization
   199   undefined :: 'a
   200 
   201 class default =
   202   fixes default :: 'a
   203 
   204 
   205 subsection {* Fundamental rules *}
   206 
   207 subsubsection {* Equality *}
   208 
   209 lemma sym: "s = t ==> t = s"
   210   by (erule subst) (rule refl)
   211 
   212 lemma ssubst: "t = s ==> P s ==> P t"
   213   by (drule sym) (erule subst)
   214 
   215 lemma trans: "[| r=s; s=t |] ==> r=t"
   216   by (erule subst)
   217 
   218 lemma trans_sym [Pure.elim?]: "r = s ==> t = s ==> r = t"
   219   by (rule trans [OF _ sym])
   220 
   221 lemma meta_eq_to_obj_eq: 
   222   assumes meq: "A == B"
   223   shows "A = B"
   224   by (unfold meq) (rule refl)
   225 
   226 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   227      (* a = b
   228         |   |
   229         c = d   *)
   230 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   231 apply (rule trans)
   232 apply (rule trans)
   233 apply (rule sym)
   234 apply assumption+
   235 done
   236 
   237 text {* For calculational reasoning: *}
   238 
   239 lemma forw_subst: "a = b ==> P b ==> P a"
   240   by (rule ssubst)
   241 
   242 lemma back_subst: "P a ==> a = b ==> P b"
   243   by (rule subst)
   244 
   245 
   246 subsubsection {* Congruence rules for application *}
   247 
   248 text {* Similar to @{text AP_THM} in Gordon's HOL. *}
   249 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   250 apply (erule subst)
   251 apply (rule refl)
   252 done
   253 
   254 text {* Similar to @{text AP_TERM} in Gordon's HOL and FOL's @{text subst_context}. *}
   255 lemma arg_cong: "x=y ==> f(x)=f(y)"
   256 apply (erule subst)
   257 apply (rule refl)
   258 done
   259 
   260 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   261 apply (erule ssubst)+
   262 apply (rule refl)
   263 done
   264 
   265 lemma cong: "[| f = g; (x::'a) = y |] ==> f x = g y"
   266 apply (erule subst)+
   267 apply (rule refl)
   268 done
   269 
   270 ML {* val cong_tac = Cong_Tac.cong_tac @{thm cong} *}
   271 
   272 
   273 subsubsection {* Equality of booleans -- iff *}
   274 
   275 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   276   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   277 
   278 lemma iffD2: "[| P=Q; Q |] ==> P"
   279   by (erule ssubst)
   280 
   281 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   282   by (erule iffD2)
   283 
   284 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   285   by (drule sym) (rule iffD2)
   286 
   287 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   288   by (drule sym) (rule rev_iffD2)
   289 
   290 lemma iffE:
   291   assumes major: "P=Q"
   292     and minor: "[| P --> Q; Q --> P |] ==> R"
   293   shows R
   294   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   295 
   296 
   297 subsubsection {*True*}
   298 
   299 lemma TrueI: "True"
   300   unfolding True_def by (rule refl)
   301 
   302 lemma eqTrueI: "P ==> P = True"
   303   by (iprover intro: iffI TrueI)
   304 
   305 lemma eqTrueE: "P = True ==> P"
   306   by (erule iffD2) (rule TrueI)
   307 
   308 
   309 subsubsection {*Universal quantifier*}
   310 
   311 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   312   unfolding All_def by (iprover intro: ext eqTrueI assms)
   313 
   314 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   315 apply (unfold All_def)
   316 apply (rule eqTrueE)
   317 apply (erule fun_cong)
   318 done
   319 
   320 lemma allE:
   321   assumes major: "ALL x. P(x)"
   322     and minor: "P(x) ==> R"
   323   shows R
   324   by (iprover intro: minor major [THEN spec])
   325 
   326 lemma all_dupE:
   327   assumes major: "ALL x. P(x)"
   328     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   329   shows R
   330   by (iprover intro: minor major major [THEN spec])
   331 
   332 
   333 subsubsection {* False *}
   334 
   335 text {*
   336   Depends upon @{text spec}; it is impossible to do propositional
   337   logic before quantifiers!
   338 *}
   339 
   340 lemma FalseE: "False ==> P"
   341   apply (unfold False_def)
   342   apply (erule spec)
   343   done
   344 
   345 lemma False_neq_True: "False = True ==> P"
   346   by (erule eqTrueE [THEN FalseE])
   347 
   348 
   349 subsubsection {* Negation *}
   350 
   351 lemma notI:
   352   assumes "P ==> False"
   353   shows "~P"
   354   apply (unfold not_def)
   355   apply (iprover intro: impI assms)
   356   done
   357 
   358 lemma False_not_True: "False ~= True"
   359   apply (rule notI)
   360   apply (erule False_neq_True)
   361   done
   362 
   363 lemma True_not_False: "True ~= False"
   364   apply (rule notI)
   365   apply (drule sym)
   366   apply (erule False_neq_True)
   367   done
   368 
   369 lemma notE: "[| ~P;  P |] ==> R"
   370   apply (unfold not_def)
   371   apply (erule mp [THEN FalseE])
   372   apply assumption
   373   done
   374 
   375 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   376   by (erule notE [THEN notI]) (erule meta_mp)
   377 
   378 
   379 subsubsection {*Implication*}
   380 
   381 lemma impE:
   382   assumes "P-->Q" "P" "Q ==> R"
   383   shows "R"
   384 by (iprover intro: assms mp)
   385 
   386 (* Reduces Q to P-->Q, allowing substitution in P. *)
   387 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   388 by (iprover intro: mp)
   389 
   390 lemma contrapos_nn:
   391   assumes major: "~Q"
   392       and minor: "P==>Q"
   393   shows "~P"
   394 by (iprover intro: notI minor major [THEN notE])
   395 
   396 (*not used at all, but we already have the other 3 combinations *)
   397 lemma contrapos_pn:
   398   assumes major: "Q"
   399       and minor: "P ==> ~Q"
   400   shows "~P"
   401 by (iprover intro: notI minor major notE)
   402 
   403 lemma not_sym: "t ~= s ==> s ~= t"
   404   by (erule contrapos_nn) (erule sym)
   405 
   406 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   407   by (erule subst, erule ssubst, assumption)
   408 
   409 (*still used in HOLCF*)
   410 lemma rev_contrapos:
   411   assumes pq: "P ==> Q"
   412       and nq: "~Q"
   413   shows "~P"
   414 apply (rule nq [THEN contrapos_nn])
   415 apply (erule pq)
   416 done
   417 
   418 subsubsection {*Existential quantifier*}
   419 
   420 lemma exI: "P x ==> EX x::'a. P x"
   421 apply (unfold Ex_def)
   422 apply (iprover intro: allI allE impI mp)
   423 done
   424 
   425 lemma exE:
   426   assumes major: "EX x::'a. P(x)"
   427       and minor: "!!x. P(x) ==> Q"
   428   shows "Q"
   429 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   430 apply (iprover intro: impI [THEN allI] minor)
   431 done
   432 
   433 
   434 subsubsection {*Conjunction*}
   435 
   436 lemma conjI: "[| P; Q |] ==> P&Q"
   437 apply (unfold and_def)
   438 apply (iprover intro: impI [THEN allI] mp)
   439 done
   440 
   441 lemma conjunct1: "[| P & Q |] ==> P"
   442 apply (unfold and_def)
   443 apply (iprover intro: impI dest: spec mp)
   444 done
   445 
   446 lemma conjunct2: "[| P & Q |] ==> Q"
   447 apply (unfold and_def)
   448 apply (iprover intro: impI dest: spec mp)
   449 done
   450 
   451 lemma conjE:
   452   assumes major: "P&Q"
   453       and minor: "[| P; Q |] ==> R"
   454   shows "R"
   455 apply (rule minor)
   456 apply (rule major [THEN conjunct1])
   457 apply (rule major [THEN conjunct2])
   458 done
   459 
   460 lemma context_conjI:
   461   assumes "P" "P ==> Q" shows "P & Q"
   462 by (iprover intro: conjI assms)
   463 
   464 
   465 subsubsection {*Disjunction*}
   466 
   467 lemma disjI1: "P ==> P|Q"
   468 apply (unfold or_def)
   469 apply (iprover intro: allI impI mp)
   470 done
   471 
   472 lemma disjI2: "Q ==> P|Q"
   473 apply (unfold or_def)
   474 apply (iprover intro: allI impI mp)
   475 done
   476 
   477 lemma disjE:
   478   assumes major: "P|Q"
   479       and minorP: "P ==> R"
   480       and minorQ: "Q ==> R"
   481   shows "R"
   482 by (iprover intro: minorP minorQ impI
   483                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   484 
   485 
   486 subsubsection {*Classical logic*}
   487 
   488 lemma classical:
   489   assumes prem: "~P ==> P"
   490   shows "P"
   491 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   492 apply assumption
   493 apply (rule notI [THEN prem, THEN eqTrueI])
   494 apply (erule subst)
   495 apply assumption
   496 done
   497 
   498 lemmas ccontr = FalseE [THEN classical, standard]
   499 
   500 (*notE with premises exchanged; it discharges ~R so that it can be used to
   501   make elimination rules*)
   502 lemma rev_notE:
   503   assumes premp: "P"
   504       and premnot: "~R ==> ~P"
   505   shows "R"
   506 apply (rule ccontr)
   507 apply (erule notE [OF premnot premp])
   508 done
   509 
   510 (*Double negation law*)
   511 lemma notnotD: "~~P ==> P"
   512 apply (rule classical)
   513 apply (erule notE)
   514 apply assumption
   515 done
   516 
   517 lemma contrapos_pp:
   518   assumes p1: "Q"
   519       and p2: "~P ==> ~Q"
   520   shows "P"
   521 by (iprover intro: classical p1 p2 notE)
   522 
   523 
   524 subsubsection {*Unique existence*}
   525 
   526 lemma ex1I:
   527   assumes "P a" "!!x. P(x) ==> x=a"
   528   shows "EX! x. P(x)"
   529 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   530 
   531 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   532 lemma ex_ex1I:
   533   assumes ex_prem: "EX x. P(x)"
   534       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   535   shows "EX! x. P(x)"
   536 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   537 
   538 lemma ex1E:
   539   assumes major: "EX! x. P(x)"
   540       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   541   shows "R"
   542 apply (rule major [unfolded Ex1_def, THEN exE])
   543 apply (erule conjE)
   544 apply (iprover intro: minor)
   545 done
   546 
   547 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   548 apply (erule ex1E)
   549 apply (rule exI)
   550 apply assumption
   551 done
   552 
   553 
   554 subsubsection {*THE: definite description operator*}
   555 
   556 lemma the_equality:
   557   assumes prema: "P a"
   558       and premx: "!!x. P x ==> x=a"
   559   shows "(THE x. P x) = a"
   560 apply (rule trans [OF _ the_eq_trivial])
   561 apply (rule_tac f = "The" in arg_cong)
   562 apply (rule ext)
   563 apply (rule iffI)
   564  apply (erule premx)
   565 apply (erule ssubst, rule prema)
   566 done
   567 
   568 lemma theI:
   569   assumes "P a" and "!!x. P x ==> x=a"
   570   shows "P (THE x. P x)"
   571 by (iprover intro: assms the_equality [THEN ssubst])
   572 
   573 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   574 apply (erule ex1E)
   575 apply (erule theI)
   576 apply (erule allE)
   577 apply (erule mp)
   578 apply assumption
   579 done
   580 
   581 (*Easier to apply than theI: only one occurrence of P*)
   582 lemma theI2:
   583   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   584   shows "Q (THE x. P x)"
   585 by (iprover intro: assms theI)
   586 
   587 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   588 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   589            elim:allE impE)
   590 
   591 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   592 apply (rule the_equality)
   593 apply  assumption
   594 apply (erule ex1E)
   595 apply (erule all_dupE)
   596 apply (drule mp)
   597 apply  assumption
   598 apply (erule ssubst)
   599 apply (erule allE)
   600 apply (erule mp)
   601 apply assumption
   602 done
   603 
   604 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   605 apply (rule the_equality)
   606 apply (rule refl)
   607 apply (erule sym)
   608 done
   609 
   610 
   611 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   612 
   613 lemma disjCI:
   614   assumes "~Q ==> P" shows "P|Q"
   615 apply (rule classical)
   616 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   617 done
   618 
   619 lemma excluded_middle: "~P | P"
   620 by (iprover intro: disjCI)
   621 
   622 text {*
   623   case distinction as a natural deduction rule.
   624   Note that @{term "~P"} is the second case, not the first
   625 *}
   626 lemma case_split [case_names True False]:
   627   assumes prem1: "P ==> Q"
   628       and prem2: "~P ==> Q"
   629   shows "Q"
   630 apply (rule excluded_middle [THEN disjE])
   631 apply (erule prem2)
   632 apply (erule prem1)
   633 done
   634 
   635 (*Classical implies (-->) elimination. *)
   636 lemma impCE:
   637   assumes major: "P-->Q"
   638       and minor: "~P ==> R" "Q ==> R"
   639   shows "R"
   640 apply (rule excluded_middle [of P, THEN disjE])
   641 apply (iprover intro: minor major [THEN mp])+
   642 done
   643 
   644 (*This version of --> elimination works on Q before P.  It works best for
   645   those cases in which P holds "almost everywhere".  Can't install as
   646   default: would break old proofs.*)
   647 lemma impCE':
   648   assumes major: "P-->Q"
   649       and minor: "Q ==> R" "~P ==> R"
   650   shows "R"
   651 apply (rule excluded_middle [of P, THEN disjE])
   652 apply (iprover intro: minor major [THEN mp])+
   653 done
   654 
   655 (*Classical <-> elimination. *)
   656 lemma iffCE:
   657   assumes major: "P=Q"
   658       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   659   shows "R"
   660 apply (rule major [THEN iffE])
   661 apply (iprover intro: minor elim: impCE notE)
   662 done
   663 
   664 lemma exCI:
   665   assumes "ALL x. ~P(x) ==> P(a)"
   666   shows "EX x. P(x)"
   667 apply (rule ccontr)
   668 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   669 done
   670 
   671 
   672 subsubsection {* Intuitionistic Reasoning *}
   673 
   674 lemma impE':
   675   assumes 1: "P --> Q"
   676     and 2: "Q ==> R"
   677     and 3: "P --> Q ==> P"
   678   shows R
   679 proof -
   680   from 3 and 1 have P .
   681   with 1 have Q by (rule impE)
   682   with 2 show R .
   683 qed
   684 
   685 lemma allE':
   686   assumes 1: "ALL x. P x"
   687     and 2: "P x ==> ALL x. P x ==> Q"
   688   shows Q
   689 proof -
   690   from 1 have "P x" by (rule spec)
   691   from this and 1 show Q by (rule 2)
   692 qed
   693 
   694 lemma notE':
   695   assumes 1: "~ P"
   696     and 2: "~ P ==> P"
   697   shows R
   698 proof -
   699   from 2 and 1 have P .
   700   with 1 show R by (rule notE)
   701 qed
   702 
   703 lemma TrueE: "True ==> P ==> P" .
   704 lemma notFalseE: "~ False ==> P ==> P" .
   705 
   706 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   707   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   708   and [Pure.elim 2] = allE notE' impE'
   709   and [Pure.intro] = exI disjI2 disjI1
   710 
   711 lemmas [trans] = trans
   712   and [sym] = sym not_sym
   713   and [Pure.elim?] = iffD1 iffD2 impE
   714 
   715 use "Tools/hologic.ML"
   716 
   717 
   718 subsubsection {* Atomizing meta-level connectives *}
   719 
   720 axiomatization where
   721   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   722 
   723 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   724 proof
   725   assume "!!x. P x"
   726   then show "ALL x. P x" ..
   727 next
   728   assume "ALL x. P x"
   729   then show "!!x. P x" by (rule allE)
   730 qed
   731 
   732 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   733 proof
   734   assume r: "A ==> B"
   735   show "A --> B" by (rule impI) (rule r)
   736 next
   737   assume "A --> B" and A
   738   then show B by (rule mp)
   739 qed
   740 
   741 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   742 proof
   743   assume r: "A ==> False"
   744   show "~A" by (rule notI) (rule r)
   745 next
   746   assume "~A" and A
   747   then show False by (rule notE)
   748 qed
   749 
   750 lemma atomize_eq [atomize, code]: "(x == y) == Trueprop (x = y)"
   751 proof
   752   assume "x == y"
   753   show "x = y" by (unfold `x == y`) (rule refl)
   754 next
   755   assume "x = y"
   756   then show "x == y" by (rule eq_reflection)
   757 qed
   758 
   759 lemma atomize_conj [atomize]: "(A &&& B) == Trueprop (A & B)"
   760 proof
   761   assume conj: "A &&& B"
   762   show "A & B"
   763   proof (rule conjI)
   764     from conj show A by (rule conjunctionD1)
   765     from conj show B by (rule conjunctionD2)
   766   qed
   767 next
   768   assume conj: "A & B"
   769   show "A &&& B"
   770   proof -
   771     from conj show A ..
   772     from conj show B ..
   773   qed
   774 qed
   775 
   776 lemmas [symmetric, rulify] = atomize_all atomize_imp
   777   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   778 
   779 
   780 subsubsection {* Atomizing elimination rules *}
   781 
   782 setup AtomizeElim.setup
   783 
   784 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   785   by rule iprover+
   786 
   787 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   788   by rule iprover+
   789 
   790 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   791   by rule iprover+
   792 
   793 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   794 
   795 
   796 subsection {* Package setup *}
   797 
   798 subsubsection {* Sledgehammer setup *}
   799 
   800 text {*
   801 Theorems blacklisted to Sledgehammer. These theorems typically produce clauses
   802 that are prolific (match too many equality or membership literals) and relate to
   803 seldom-used facts. Some duplicate other rules.
   804 *}
   805 
   806 ML {*
   807 structure No_ATPs = Named_Thms
   808 (
   809   val name = "no_atp"
   810   val description = "theorems that should be filtered out by Sledgehammer"
   811 )
   812 *}
   813 
   814 setup {* No_ATPs.setup *}
   815 
   816 
   817 subsubsection {* Classical Reasoner setup *}
   818 
   819 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   820   by (rule classical) iprover
   821 
   822 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   823   by (rule classical) iprover
   824 
   825 lemma thin_refl:
   826   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   827 
   828 ML {*
   829 structure Hypsubst = Hypsubst
   830 (
   831   val dest_eq = HOLogic.dest_eq
   832   val dest_Trueprop = HOLogic.dest_Trueprop
   833   val dest_imp = HOLogic.dest_imp
   834   val eq_reflection = @{thm eq_reflection}
   835   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   836   val imp_intr = @{thm impI}
   837   val rev_mp = @{thm rev_mp}
   838   val subst = @{thm subst}
   839   val sym = @{thm sym}
   840   val thin_refl = @{thm thin_refl};
   841 );
   842 open Hypsubst;
   843 
   844 structure Classical = Classical
   845 (
   846   val imp_elim = @{thm imp_elim}
   847   val not_elim = @{thm notE}
   848   val swap = @{thm swap}
   849   val classical = @{thm classical}
   850   val sizef = Drule.size_of_thm
   851   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   852 );
   853 
   854 structure Basic_Classical: BASIC_CLASSICAL = Classical; 
   855 open Basic_Classical;
   856 
   857 ML_Antiquote.value "claset"
   858   (Scan.succeed "Classical.claset_of (ML_Context.the_local_context ())");
   859 *}
   860 
   861 setup Classical.setup
   862 
   863 setup {*
   864 let
   865   fun non_bool_eq (@{const_name HOL.eq}, Type (_, [T, _])) = T <> @{typ bool}
   866     | non_bool_eq _ = false;
   867   val hyp_subst_tac' =
   868     SUBGOAL (fn (goal, i) =>
   869       if Term.exists_Const non_bool_eq goal
   870       then Hypsubst.hyp_subst_tac i
   871       else no_tac);
   872 in
   873   Hypsubst.hypsubst_setup
   874   (*prevent substitution on bool*)
   875   #> Context_Rules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   876 end
   877 *}
   878 
   879 declare iffI [intro!]
   880   and notI [intro!]
   881   and impI [intro!]
   882   and disjCI [intro!]
   883   and conjI [intro!]
   884   and TrueI [intro!]
   885   and refl [intro!]
   886 
   887 declare iffCE [elim!]
   888   and FalseE [elim!]
   889   and impCE [elim!]
   890   and disjE [elim!]
   891   and conjE [elim!]
   892 
   893 declare ex_ex1I [intro!]
   894   and allI [intro!]
   895   and the_equality [intro]
   896   and exI [intro]
   897 
   898 declare exE [elim!]
   899   allE [elim]
   900 
   901 ML {* val HOL_cs = @{claset} *}
   902 
   903 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   904   apply (erule swap)
   905   apply (erule (1) meta_mp)
   906   done
   907 
   908 declare ex_ex1I [rule del, intro! 2]
   909   and ex1I [intro]
   910 
   911 declare ext [intro]
   912 
   913 lemmas [intro?] = ext
   914   and [elim?] = ex1_implies_ex
   915 
   916 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   917 lemma alt_ex1E [elim!]:
   918   assumes major: "\<exists>!x. P x"
   919       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   920   shows R
   921 apply (rule ex1E [OF major])
   922 apply (rule prem)
   923 apply (tactic {* ares_tac @{thms allI} 1 *})+
   924 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
   925 apply iprover
   926 done
   927 
   928 ML {*
   929   structure Blast = Blast
   930   (
   931     structure Classical = Classical
   932     val Trueprop_const = dest_Const @{const Trueprop}
   933     val equality_name = @{const_name HOL.eq}
   934     val not_name = @{const_name Not}
   935     val notE = @{thm notE}
   936     val ccontr = @{thm ccontr}
   937     val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   938   );
   939   val blast_tac = Blast.blast_tac;
   940 *}
   941 
   942 setup Blast.setup
   943 
   944 
   945 subsubsection {* Simplifier *}
   946 
   947 lemma eta_contract_eq: "(%s. f s) = f" ..
   948 
   949 lemma simp_thms:
   950   shows not_not: "(~ ~ P) = P"
   951   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
   952   and
   953     "(P ~= Q) = (P = (~Q))"
   954     "(P | ~P) = True"    "(~P | P) = True"
   955     "(x = x) = True"
   956   and not_True_eq_False [code]: "(\<not> True) = False"
   957   and not_False_eq_True [code]: "(\<not> False) = True"
   958   and
   959     "(~P) ~= P"  "P ~= (~P)"
   960     "(True=P) = P"
   961   and eq_True: "(P = True) = P"
   962   and "(False=P) = (~P)"
   963   and eq_False: "(P = False) = (\<not> P)"
   964   and
   965     "(True --> P) = P"  "(False --> P) = True"
   966     "(P --> True) = True"  "(P --> P) = True"
   967     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
   968     "(P & True) = P"  "(True & P) = P"
   969     "(P & False) = False"  "(False & P) = False"
   970     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
   971     "(P & ~P) = False"    "(~P & P) = False"
   972     "(P | True) = True"  "(True | P) = True"
   973     "(P | False) = P"  "(False | P) = P"
   974     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
   975     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
   976   and
   977     "!!P. (EX x. x=t & P(x)) = P(t)"
   978     "!!P. (EX x. t=x & P(x)) = P(t)"
   979     "!!P. (ALL x. x=t --> P(x)) = P(t)"
   980     "!!P. (ALL x. t=x --> P(x)) = P(t)"
   981   by (blast, blast, blast, blast, blast, iprover+)
   982 
   983 lemma disj_absorb: "(A | A) = A"
   984   by blast
   985 
   986 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
   987   by blast
   988 
   989 lemma conj_absorb: "(A & A) = A"
   990   by blast
   991 
   992 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
   993   by blast
   994 
   995 lemma eq_ac:
   996   shows eq_commute: "(a=b) = (b=a)"
   997     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
   998     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
   999 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1000 
  1001 lemma conj_comms:
  1002   shows conj_commute: "(P&Q) = (Q&P)"
  1003     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1004 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1005 
  1006 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1007 
  1008 lemma disj_comms:
  1009   shows disj_commute: "(P|Q) = (Q|P)"
  1010     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1011 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1012 
  1013 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1014 
  1015 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1016 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1017 
  1018 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1019 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1020 
  1021 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1022 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1023 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1024 
  1025 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1026 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1027 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1028 
  1029 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1030 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1031 
  1032 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1033   by iprover
  1034 
  1035 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1036 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1037 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1038 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1039 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1040 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1041   by blast
  1042 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1043 
  1044 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1045 
  1046 
  1047 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1048   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1049   -- {* cases boil down to the same thing. *}
  1050   by blast
  1051 
  1052 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1053 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1054 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1055 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1056 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1057 
  1058 declare All_def [no_atp]
  1059 
  1060 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1061 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1062 
  1063 text {*
  1064   \medskip The @{text "&"} congruence rule: not included by default!
  1065   May slow rewrite proofs down by as much as 50\% *}
  1066 
  1067 lemma conj_cong:
  1068     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1069   by iprover
  1070 
  1071 lemma rev_conj_cong:
  1072     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1073   by iprover
  1074 
  1075 text {* The @{text "|"} congruence rule: not included by default! *}
  1076 
  1077 lemma disj_cong:
  1078     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1079   by blast
  1080 
  1081 
  1082 text {* \medskip if-then-else rules *}
  1083 
  1084 lemma if_True [code]: "(if True then x else y) = x"
  1085   by (unfold If_def) blast
  1086 
  1087 lemma if_False [code]: "(if False then x else y) = y"
  1088   by (unfold If_def) blast
  1089 
  1090 lemma if_P: "P ==> (if P then x else y) = x"
  1091   by (unfold If_def) blast
  1092 
  1093 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1094   by (unfold If_def) blast
  1095 
  1096 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1097   apply (rule case_split [of Q])
  1098    apply (simplesubst if_P)
  1099     prefer 3 apply (simplesubst if_not_P, blast+)
  1100   done
  1101 
  1102 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1103 by (simplesubst split_if, blast)
  1104 
  1105 lemmas if_splits [no_atp] = split_if split_if_asm
  1106 
  1107 lemma if_cancel: "(if c then x else x) = x"
  1108 by (simplesubst split_if, blast)
  1109 
  1110 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1111 by (simplesubst split_if, blast)
  1112 
  1113 lemma if_bool_eq_conj:
  1114 "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1115   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1116   by (rule split_if)
  1117 
  1118 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1119   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1120   apply (simplesubst split_if, blast)
  1121   done
  1122 
  1123 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1124 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1125 
  1126 text {* \medskip let rules for simproc *}
  1127 
  1128 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1129   by (unfold Let_def)
  1130 
  1131 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1132   by (unfold Let_def)
  1133 
  1134 text {*
  1135   The following copy of the implication operator is useful for
  1136   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1137   its premise.
  1138 *}
  1139 
  1140 definition simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1) where
  1141   "simp_implies \<equiv> op ==>"
  1142 
  1143 lemma simp_impliesI:
  1144   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1145   shows "PROP P =simp=> PROP Q"
  1146   apply (unfold simp_implies_def)
  1147   apply (rule PQ)
  1148   apply assumption
  1149   done
  1150 
  1151 lemma simp_impliesE:
  1152   assumes PQ: "PROP P =simp=> PROP Q"
  1153   and P: "PROP P"
  1154   and QR: "PROP Q \<Longrightarrow> PROP R"
  1155   shows "PROP R"
  1156   apply (rule QR)
  1157   apply (rule PQ [unfolded simp_implies_def])
  1158   apply (rule P)
  1159   done
  1160 
  1161 lemma simp_implies_cong:
  1162   assumes PP' :"PROP P == PROP P'"
  1163   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1164   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1165 proof (unfold simp_implies_def, rule equal_intr_rule)
  1166   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1167   and P': "PROP P'"
  1168   from PP' [symmetric] and P' have "PROP P"
  1169     by (rule equal_elim_rule1)
  1170   then have "PROP Q" by (rule PQ)
  1171   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1172 next
  1173   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1174   and P: "PROP P"
  1175   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1176   then have "PROP Q'" by (rule P'Q')
  1177   with P'QQ' [OF P', symmetric] show "PROP Q"
  1178     by (rule equal_elim_rule1)
  1179 qed
  1180 
  1181 lemma uncurry:
  1182   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1183   shows "P \<and> Q \<longrightarrow> R"
  1184   using assms by blast
  1185 
  1186 lemma iff_allI:
  1187   assumes "\<And>x. P x = Q x"
  1188   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1189   using assms by blast
  1190 
  1191 lemma iff_exI:
  1192   assumes "\<And>x. P x = Q x"
  1193   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1194   using assms by blast
  1195 
  1196 lemma all_comm:
  1197   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1198   by blast
  1199 
  1200 lemma ex_comm:
  1201   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1202   by blast
  1203 
  1204 use "Tools/simpdata.ML"
  1205 ML {* open Simpdata *}
  1206 
  1207 setup {* Simplifier.map_simpset_global (K HOL_basic_ss) *}
  1208 
  1209 simproc_setup defined_Ex ("EX x. P x") = {* fn _ => Quantifier1.rearrange_ex *}
  1210 simproc_setup defined_All ("ALL x. P x") = {* fn _ => Quantifier1.rearrange_all *}
  1211 
  1212 setup {*
  1213   Simplifier.method_setup Splitter.split_modifiers
  1214   #> Splitter.setup
  1215   #> clasimp_setup
  1216   #> EqSubst.setup
  1217 *}
  1218 
  1219 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1220 
  1221 simproc_setup neq ("x = y") = {* fn _ =>
  1222 let
  1223   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1224   fun is_neq eq lhs rhs thm =
  1225     (case Thm.prop_of thm of
  1226       _ $ (Not $ (eq' $ l' $ r')) =>
  1227         Not = HOLogic.Not andalso eq' = eq andalso
  1228         r' aconv lhs andalso l' aconv rhs
  1229     | _ => false);
  1230   fun proc ss ct =
  1231     (case Thm.term_of ct of
  1232       eq $ lhs $ rhs =>
  1233         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1234           SOME thm => SOME (thm RS neq_to_EQ_False)
  1235         | NONE => NONE)
  1236      | _ => NONE);
  1237 in proc end;
  1238 *}
  1239 
  1240 simproc_setup let_simp ("Let x f") = {*
  1241 let
  1242   val (f_Let_unfold, x_Let_unfold) =
  1243     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_unfold}
  1244     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1245   val (f_Let_folded, x_Let_folded) =
  1246     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_folded}
  1247     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1248   val g_Let_folded =
  1249     let val [(_ $ _ $ (g $ _))] = prems_of @{thm Let_folded}
  1250     in cterm_of @{theory} g end;
  1251   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1252     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1253     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1254     | count_loose _ _ = 0;
  1255   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1256    case t
  1257     of Abs (_, _, t') => count_loose t' 0 <= 1
  1258      | _ => true;
  1259 in fn _ => fn ss => fn ct => if is_trivial_let (Thm.term_of ct)
  1260   then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1261   else let (*Norbert Schirmer's case*)
  1262     val ctxt = Simplifier.the_context ss;
  1263     val thy = Proof_Context.theory_of ctxt;
  1264     val t = Thm.term_of ct;
  1265     val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1266   in Option.map (hd o Variable.export ctxt' ctxt o single)
  1267     (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1268       if is_Free x orelse is_Bound x orelse is_Const x
  1269       then SOME @{thm Let_def}
  1270       else
  1271         let
  1272           val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1273           val cx = cterm_of thy x;
  1274           val {T = xT, ...} = rep_cterm cx;
  1275           val cf = cterm_of thy f;
  1276           val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1277           val (_ $ _ $ g) = prop_of fx_g;
  1278           val g' = abstract_over (x,g);
  1279         in (if (g aconv g')
  1280              then
  1281                 let
  1282                   val rl =
  1283                     cterm_instantiate [(f_Let_unfold, cf), (x_Let_unfold, cx)] @{thm Let_unfold};
  1284                 in SOME (rl OF [fx_g]) end
  1285              else if Term.betapply (f, x) aconv g then NONE (*avoid identity conversion*)
  1286              else let
  1287                    val abs_g'= Abs (n,xT,g');
  1288                    val g'x = abs_g'$x;
  1289                    val g_g'x = Thm.symmetric (Thm.beta_conversion false (cterm_of thy g'x));
  1290                    val rl = cterm_instantiate
  1291                              [(f_Let_folded, cterm_of thy f), (x_Let_folded, cx),
  1292                               (g_Let_folded, cterm_of thy abs_g')]
  1293                              @{thm Let_folded};
  1294                  in SOME (rl OF [Thm.transitive fx_g g_g'x])
  1295                  end)
  1296         end
  1297     | _ => NONE)
  1298   end
  1299 end *}
  1300 
  1301 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1302 proof
  1303   assume "True \<Longrightarrow> PROP P"
  1304   from this [OF TrueI] show "PROP P" .
  1305 next
  1306   assume "PROP P"
  1307   then show "PROP P" .
  1308 qed
  1309 
  1310 lemma ex_simps:
  1311   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1312   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1313   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1314   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1315   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1316   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1317   -- {* Miniscoping: pushing in existential quantifiers. *}
  1318   by (iprover | blast)+
  1319 
  1320 lemma all_simps:
  1321   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1322   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1323   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1324   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1325   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1326   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1327   -- {* Miniscoping: pushing in universal quantifiers. *}
  1328   by (iprover | blast)+
  1329 
  1330 lemmas [simp] =
  1331   triv_forall_equality (*prunes params*)
  1332   True_implies_equals  (*prune asms `True'*)
  1333   if_True
  1334   if_False
  1335   if_cancel
  1336   if_eq_cancel
  1337   imp_disjL
  1338   (*In general it seems wrong to add distributive laws by default: they
  1339     might cause exponential blow-up.  But imp_disjL has been in for a while
  1340     and cannot be removed without affecting existing proofs.  Moreover,
  1341     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1342     grounds that it allows simplification of R in the two cases.*)
  1343   conj_assoc
  1344   disj_assoc
  1345   de_Morgan_conj
  1346   de_Morgan_disj
  1347   imp_disj1
  1348   imp_disj2
  1349   not_imp
  1350   disj_not1
  1351   not_all
  1352   not_ex
  1353   cases_simp
  1354   the_eq_trivial
  1355   the_sym_eq_trivial
  1356   ex_simps
  1357   all_simps
  1358   simp_thms
  1359 
  1360 lemmas [cong] = imp_cong simp_implies_cong
  1361 lemmas [split] = split_if
  1362 
  1363 ML {* val HOL_ss = @{simpset} *}
  1364 
  1365 text {* Simplifies x assuming c and y assuming ~c *}
  1366 lemma if_cong:
  1367   assumes "b = c"
  1368       and "c \<Longrightarrow> x = u"
  1369       and "\<not> c \<Longrightarrow> y = v"
  1370   shows "(if b then x else y) = (if c then u else v)"
  1371   using assms by simp
  1372 
  1373 text {* Prevents simplification of x and y:
  1374   faster and allows the execution of functional programs. *}
  1375 lemma if_weak_cong [cong]:
  1376   assumes "b = c"
  1377   shows "(if b then x else y) = (if c then x else y)"
  1378   using assms by (rule arg_cong)
  1379 
  1380 text {* Prevents simplification of t: much faster *}
  1381 lemma let_weak_cong:
  1382   assumes "a = b"
  1383   shows "(let x = a in t x) = (let x = b in t x)"
  1384   using assms by (rule arg_cong)
  1385 
  1386 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1387 lemma eq_cong2:
  1388   assumes "u = u'"
  1389   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1390   using assms by simp
  1391 
  1392 lemma if_distrib:
  1393   "f (if c then x else y) = (if c then f x else f y)"
  1394   by simp
  1395 
  1396 
  1397 subsubsection {* Generic cases and induction *}
  1398 
  1399 text {* Rule projections: *}
  1400 
  1401 ML {*
  1402 structure Project_Rule = Project_Rule
  1403 (
  1404   val conjunct1 = @{thm conjunct1}
  1405   val conjunct2 = @{thm conjunct2}
  1406   val mp = @{thm mp}
  1407 )
  1408 *}
  1409 
  1410 definition induct_forall where
  1411   "induct_forall P == \<forall>x. P x"
  1412 
  1413 definition induct_implies where
  1414   "induct_implies A B == A \<longrightarrow> B"
  1415 
  1416 definition induct_equal where
  1417   "induct_equal x y == x = y"
  1418 
  1419 definition induct_conj where
  1420   "induct_conj A B == A \<and> B"
  1421 
  1422 definition induct_true where
  1423   "induct_true == True"
  1424 
  1425 definition induct_false where
  1426   "induct_false == False"
  1427 
  1428 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1429   by (unfold atomize_all induct_forall_def)
  1430 
  1431 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1432   by (unfold atomize_imp induct_implies_def)
  1433 
  1434 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1435   by (unfold atomize_eq induct_equal_def)
  1436 
  1437 lemma induct_conj_eq: "(A &&& B) == Trueprop (induct_conj A B)"
  1438   by (unfold atomize_conj induct_conj_def)
  1439 
  1440 lemmas induct_atomize' = induct_forall_eq induct_implies_eq induct_conj_eq
  1441 lemmas induct_atomize = induct_atomize' induct_equal_eq
  1442 lemmas induct_rulify' [symmetric, standard] = induct_atomize'
  1443 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1444 lemmas induct_rulify_fallback =
  1445   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1446   induct_true_def induct_false_def
  1447 
  1448 
  1449 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1450     induct_conj (induct_forall A) (induct_forall B)"
  1451   by (unfold induct_forall_def induct_conj_def) iprover
  1452 
  1453 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1454     induct_conj (induct_implies C A) (induct_implies C B)"
  1455   by (unfold induct_implies_def induct_conj_def) iprover
  1456 
  1457 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1458 proof
  1459   assume r: "induct_conj A B ==> PROP C" and A B
  1460   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1461 next
  1462   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1463   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1464 qed
  1465 
  1466 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1467 
  1468 lemma induct_trueI: "induct_true"
  1469   by (simp add: induct_true_def)
  1470 
  1471 text {* Method setup. *}
  1472 
  1473 ML {*
  1474 structure Induct = Induct
  1475 (
  1476   val cases_default = @{thm case_split}
  1477   val atomize = @{thms induct_atomize}
  1478   val rulify = @{thms induct_rulify'}
  1479   val rulify_fallback = @{thms induct_rulify_fallback}
  1480   val equal_def = @{thm induct_equal_def}
  1481   fun dest_def (Const (@{const_name induct_equal}, _) $ t $ u) = SOME (t, u)
  1482     | dest_def _ = NONE
  1483   val trivial_tac = match_tac @{thms induct_trueI}
  1484 )
  1485 *}
  1486 
  1487 setup {*
  1488   Induct.setup #>
  1489   Context.theory_map (Induct.map_simpset (fn ss => ss
  1490     setmksimps (fn ss => Simpdata.mksimps Simpdata.mksimps_pairs ss #>
  1491       map (Simplifier.rewrite_rule (map Thm.symmetric
  1492         @{thms induct_rulify_fallback})))
  1493     addsimprocs
  1494       [Simplifier.simproc_global @{theory} "swap_induct_false"
  1495          ["induct_false ==> PROP P ==> PROP Q"]
  1496          (fn _ => fn _ =>
  1497             (fn _ $ (P as _ $ @{const induct_false}) $ (_ $ Q $ _) =>
  1498                   if P <> Q then SOME Drule.swap_prems_eq else NONE
  1499               | _ => NONE)),
  1500        Simplifier.simproc_global @{theory} "induct_equal_conj_curry"
  1501          ["induct_conj P Q ==> PROP R"]
  1502          (fn _ => fn _ =>
  1503             (fn _ $ (_ $ P) $ _ =>
  1504                 let
  1505                   fun is_conj (@{const induct_conj} $ P $ Q) =
  1506                         is_conj P andalso is_conj Q
  1507                     | is_conj (Const (@{const_name induct_equal}, _) $ _ $ _) = true
  1508                     | is_conj @{const induct_true} = true
  1509                     | is_conj @{const induct_false} = true
  1510                     | is_conj _ = false
  1511                 in if is_conj P then SOME @{thm induct_conj_curry} else NONE end
  1512               | _ => NONE))]))
  1513 *}
  1514 
  1515 text {* Pre-simplification of induction and cases rules *}
  1516 
  1517 lemma [induct_simp]: "(!!x. induct_equal x t ==> PROP P x) == PROP P t"
  1518   unfolding induct_equal_def
  1519 proof
  1520   assume R: "!!x. x = t ==> PROP P x"
  1521   show "PROP P t" by (rule R [OF refl])
  1522 next
  1523   fix x assume "PROP P t" "x = t"
  1524   then show "PROP P x" by simp
  1525 qed
  1526 
  1527 lemma [induct_simp]: "(!!x. induct_equal t x ==> PROP P x) == PROP P t"
  1528   unfolding induct_equal_def
  1529 proof
  1530   assume R: "!!x. t = x ==> PROP P x"
  1531   show "PROP P t" by (rule R [OF refl])
  1532 next
  1533   fix x assume "PROP P t" "t = x"
  1534   then show "PROP P x" by simp
  1535 qed
  1536 
  1537 lemma [induct_simp]: "(induct_false ==> P) == Trueprop induct_true"
  1538   unfolding induct_false_def induct_true_def
  1539   by (iprover intro: equal_intr_rule)
  1540 
  1541 lemma [induct_simp]: "(induct_true ==> PROP P) == PROP P"
  1542   unfolding induct_true_def
  1543 proof
  1544   assume R: "True \<Longrightarrow> PROP P"
  1545   from TrueI show "PROP P" by (rule R)
  1546 next
  1547   assume "PROP P"
  1548   then show "PROP P" .
  1549 qed
  1550 
  1551 lemma [induct_simp]: "(PROP P ==> induct_true) == Trueprop induct_true"
  1552   unfolding induct_true_def
  1553   by (iprover intro: equal_intr_rule)
  1554 
  1555 lemma [induct_simp]: "(!!x. induct_true) == Trueprop induct_true"
  1556   unfolding induct_true_def
  1557   by (iprover intro: equal_intr_rule)
  1558 
  1559 lemma [induct_simp]: "induct_implies induct_true P == P"
  1560   by (simp add: induct_implies_def induct_true_def)
  1561 
  1562 lemma [induct_simp]: "(x = x) = True" 
  1563   by (rule simp_thms)
  1564 
  1565 hide_const induct_forall induct_implies induct_equal induct_conj induct_true induct_false
  1566 
  1567 use "~~/src/Tools/induct_tacs.ML"
  1568 setup InductTacs.setup
  1569 
  1570 
  1571 subsubsection {* Coherent logic *}
  1572 
  1573 ML {*
  1574 structure Coherent = Coherent
  1575 (
  1576   val atomize_elimL = @{thm atomize_elimL}
  1577   val atomize_exL = @{thm atomize_exL}
  1578   val atomize_conjL = @{thm atomize_conjL}
  1579   val atomize_disjL = @{thm atomize_disjL}
  1580   val operator_names =
  1581     [@{const_name HOL.disj}, @{const_name HOL.conj}, @{const_name Ex}]
  1582 );
  1583 *}
  1584 
  1585 setup Coherent.setup
  1586 
  1587 
  1588 subsubsection {* Reorienting equalities *}
  1589 
  1590 ML {*
  1591 signature REORIENT_PROC =
  1592 sig
  1593   val add : (term -> bool) -> theory -> theory
  1594   val proc : morphism -> simpset -> cterm -> thm option
  1595 end;
  1596 
  1597 structure Reorient_Proc : REORIENT_PROC =
  1598 struct
  1599   structure Data = Theory_Data
  1600   (
  1601     type T = ((term -> bool) * stamp) list;
  1602     val empty = [];
  1603     val extend = I;
  1604     fun merge data : T = Library.merge (eq_snd op =) data;
  1605   );
  1606   fun add m = Data.map (cons (m, stamp ()));
  1607   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
  1608 
  1609   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1610   fun proc phi ss ct =
  1611     let
  1612       val ctxt = Simplifier.the_context ss;
  1613       val thy = Proof_Context.theory_of ctxt;
  1614     in
  1615       case Thm.term_of ct of
  1616         (_ $ t $ u) => if matches thy u then NONE else SOME meta_reorient
  1617       | _ => NONE
  1618     end;
  1619 end;
  1620 *}
  1621 
  1622 
  1623 subsection {* Other simple lemmas and lemma duplicates *}
  1624 
  1625 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1626   by blast+
  1627 
  1628 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1629   apply (rule iffI)
  1630   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1631   apply (fast dest!: theI')
  1632   apply (fast intro: ext the1_equality [symmetric])
  1633   apply (erule ex1E)
  1634   apply (rule allI)
  1635   apply (rule ex1I)
  1636   apply (erule spec)
  1637   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1638   apply (erule impE)
  1639   apply (rule allI)
  1640   apply (case_tac "xa = x")
  1641   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1642   done
  1643 
  1644 lemmas eq_sym_conv = eq_commute
  1645 
  1646 lemma nnf_simps:
  1647   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1648   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1649   "(\<not> \<not>(P)) = P"
  1650 by blast+
  1651 
  1652 subsection {* Basic ML bindings *}
  1653 
  1654 ML {*
  1655 val FalseE = @{thm FalseE}
  1656 val Let_def = @{thm Let_def}
  1657 val TrueI = @{thm TrueI}
  1658 val allE = @{thm allE}
  1659 val allI = @{thm allI}
  1660 val all_dupE = @{thm all_dupE}
  1661 val arg_cong = @{thm arg_cong}
  1662 val box_equals = @{thm box_equals}
  1663 val ccontr = @{thm ccontr}
  1664 val classical = @{thm classical}
  1665 val conjE = @{thm conjE}
  1666 val conjI = @{thm conjI}
  1667 val conjunct1 = @{thm conjunct1}
  1668 val conjunct2 = @{thm conjunct2}
  1669 val disjCI = @{thm disjCI}
  1670 val disjE = @{thm disjE}
  1671 val disjI1 = @{thm disjI1}
  1672 val disjI2 = @{thm disjI2}
  1673 val eq_reflection = @{thm eq_reflection}
  1674 val ex1E = @{thm ex1E}
  1675 val ex1I = @{thm ex1I}
  1676 val ex1_implies_ex = @{thm ex1_implies_ex}
  1677 val exE = @{thm exE}
  1678 val exI = @{thm exI}
  1679 val excluded_middle = @{thm excluded_middle}
  1680 val ext = @{thm ext}
  1681 val fun_cong = @{thm fun_cong}
  1682 val iffD1 = @{thm iffD1}
  1683 val iffD2 = @{thm iffD2}
  1684 val iffI = @{thm iffI}
  1685 val impE = @{thm impE}
  1686 val impI = @{thm impI}
  1687 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1688 val mp = @{thm mp}
  1689 val notE = @{thm notE}
  1690 val notI = @{thm notI}
  1691 val not_all = @{thm not_all}
  1692 val not_ex = @{thm not_ex}
  1693 val not_iff = @{thm not_iff}
  1694 val not_not = @{thm not_not}
  1695 val not_sym = @{thm not_sym}
  1696 val refl = @{thm refl}
  1697 val rev_mp = @{thm rev_mp}
  1698 val spec = @{thm spec}
  1699 val ssubst = @{thm ssubst}
  1700 val subst = @{thm subst}
  1701 val sym = @{thm sym}
  1702 val trans = @{thm trans}
  1703 *}
  1704 
  1705 use "Tools/cnf_funcs.ML"
  1706 
  1707 subsection {* Code generator setup *}
  1708 
  1709 subsubsection {* SML code generator setup *}
  1710 
  1711 use "Tools/recfun_codegen.ML"
  1712 
  1713 setup {*
  1714   Codegen.setup
  1715   #> RecfunCodegen.setup
  1716   #> Codegen.map_unfold (K HOL_basic_ss)
  1717 *}
  1718 
  1719 types_code
  1720   "bool"  ("bool")
  1721 attach (term_of) {*
  1722 fun term_of_bool b = if b then HOLogic.true_const else HOLogic.false_const;
  1723 *}
  1724 attach (test) {*
  1725 fun gen_bool i =
  1726   let val b = one_of [false, true]
  1727   in (b, fn () => term_of_bool b) end;
  1728 *}
  1729   "prop"  ("bool")
  1730 attach (term_of) {*
  1731 fun term_of_prop b =
  1732   HOLogic.mk_Trueprop (if b then HOLogic.true_const else HOLogic.false_const);
  1733 *}
  1734 
  1735 consts_code
  1736   "Trueprop" ("(_)")
  1737   "True"    ("true")
  1738   "False"   ("false")
  1739   "Not"     ("Bool.not")
  1740   HOL.disj    ("(_ orelse/ _)")
  1741   HOL.conj    ("(_ andalso/ _)")
  1742   "If"      ("(if _/ then _/ else _)")
  1743 
  1744 setup {*
  1745 let
  1746 
  1747 fun eq_codegen thy mode defs dep thyname b t gr =
  1748     (case strip_comb t of
  1749        (Const (@{const_name HOL.eq}, Type (_, [Type ("fun", _), _])), _) => NONE
  1750      | (Const (@{const_name HOL.eq}, _), [t, u]) =>
  1751           let
  1752             val (pt, gr') = Codegen.invoke_codegen thy mode defs dep thyname false t gr;
  1753             val (pu, gr'') = Codegen.invoke_codegen thy mode defs dep thyname false u gr';
  1754             val (_, gr''') =
  1755               Codegen.invoke_tycodegen thy mode defs dep thyname false HOLogic.boolT gr'';
  1756           in
  1757             SOME (Codegen.parens
  1758               (Pretty.block [pt, Codegen.str " =", Pretty.brk 1, pu]), gr''')
  1759           end
  1760      | (t as Const (@{const_name HOL.eq}, _), ts) => SOME (Codegen.invoke_codegen
  1761          thy mode defs dep thyname b (Codegen.eta_expand t ts 2) gr)
  1762      | _ => NONE);
  1763 
  1764 in
  1765   Codegen.add_codegen "eq_codegen" eq_codegen
  1766 end
  1767 *}
  1768 
  1769 subsubsection {* Generic code generator preprocessor setup *}
  1770 
  1771 setup {*
  1772   Code_Preproc.map_pre (K HOL_basic_ss)
  1773   #> Code_Preproc.map_post (K HOL_basic_ss)
  1774   #> Code_Simp.map_ss (K HOL_basic_ss)
  1775 *}
  1776 
  1777 subsubsection {* Equality *}
  1778 
  1779 class equal =
  1780   fixes equal :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1781   assumes equal_eq: "equal x y \<longleftrightarrow> x = y"
  1782 begin
  1783 
  1784 lemma equal [code_unfold, code_inline del]: "equal = (op =)"
  1785   by (rule ext equal_eq)+
  1786 
  1787 lemma equal_refl: "equal x x \<longleftrightarrow> True"
  1788   unfolding equal by rule+
  1789 
  1790 lemma eq_equal: "(op =) \<equiv> equal"
  1791   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule equal_eq)
  1792 
  1793 end
  1794 
  1795 declare eq_equal [symmetric, code_post]
  1796 declare eq_equal [code]
  1797 
  1798 setup {*
  1799   Code_Preproc.map_pre (fn simpset =>
  1800     simpset addsimprocs [Simplifier.simproc_global_i @{theory} "equal" [@{term HOL.eq}]
  1801       (fn thy => fn _ =>
  1802         fn Const (_, Type ("fun", [Type _, _])) => SOME @{thm eq_equal} | _ => NONE)])
  1803 *}
  1804 
  1805 
  1806 subsubsection {* Generic code generator foundation *}
  1807 
  1808 text {* Datatype @{typ bool} *}
  1809 
  1810 code_datatype True False
  1811 
  1812 lemma [code]:
  1813   shows "False \<and> P \<longleftrightarrow> False"
  1814     and "True \<and> P \<longleftrightarrow> P"
  1815     and "P \<and> False \<longleftrightarrow> False"
  1816     and "P \<and> True \<longleftrightarrow> P" by simp_all
  1817 
  1818 lemma [code]:
  1819   shows "False \<or> P \<longleftrightarrow> P"
  1820     and "True \<or> P \<longleftrightarrow> True"
  1821     and "P \<or> False \<longleftrightarrow> P"
  1822     and "P \<or> True \<longleftrightarrow> True" by simp_all
  1823 
  1824 lemma [code]:
  1825   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
  1826     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
  1827     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
  1828     and "(P \<longrightarrow> True) \<longleftrightarrow> True" by simp_all
  1829 
  1830 text {* More about @{typ prop} *}
  1831 
  1832 lemma [code nbe]:
  1833   shows "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q" 
  1834     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True"
  1835     and "(P \<Longrightarrow> R) \<equiv> Trueprop (P \<longrightarrow> R)" by (auto intro!: equal_intr_rule)
  1836 
  1837 lemma Trueprop_code [code]:
  1838   "Trueprop True \<equiv> Code_Generator.holds"
  1839   by (auto intro!: equal_intr_rule holds)
  1840 
  1841 declare Trueprop_code [symmetric, code_post]
  1842 
  1843 text {* Equality *}
  1844 
  1845 declare simp_thms(6) [code nbe]
  1846 
  1847 instantiation itself :: (type) equal
  1848 begin
  1849 
  1850 definition equal_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool" where
  1851   "equal_itself x y \<longleftrightarrow> x = y"
  1852 
  1853 instance proof
  1854 qed (fact equal_itself_def)
  1855 
  1856 end
  1857 
  1858 lemma equal_itself_code [code]:
  1859   "equal TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1860   by (simp add: equal)
  1861 
  1862 setup {*
  1863   Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>type \<Rightarrow> 'a \<Rightarrow> bool"})
  1864 *}
  1865 
  1866 lemma equal_alias_cert: "OFCLASS('a, equal_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> equal)" (is "?ofclass \<equiv> ?equal")
  1867 proof
  1868   assume "PROP ?ofclass"
  1869   show "PROP ?equal"
  1870     by (tactic {* ALLGOALS (rtac (Thm.unconstrainT @{thm eq_equal})) *})
  1871       (fact `PROP ?ofclass`)
  1872 next
  1873   assume "PROP ?equal"
  1874   show "PROP ?ofclass" proof
  1875   qed (simp add: `PROP ?equal`)
  1876 qed
  1877   
  1878 setup {*
  1879   Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>equal \<Rightarrow> 'a \<Rightarrow> bool"})
  1880 *}
  1881 
  1882 setup {*
  1883   Nbe.add_const_alias @{thm equal_alias_cert}
  1884 *}
  1885 
  1886 text {* Cases *}
  1887 
  1888 lemma Let_case_cert:
  1889   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1890   shows "CASE x \<equiv> f x"
  1891   using assms by simp_all
  1892 
  1893 lemma If_case_cert:
  1894   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
  1895   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
  1896   using assms by simp_all
  1897 
  1898 setup {*
  1899   Code.add_case @{thm Let_case_cert}
  1900   #> Code.add_case @{thm If_case_cert}
  1901   #> Code.add_undefined @{const_name undefined}
  1902 *}
  1903 
  1904 code_abort undefined
  1905 
  1906 
  1907 subsubsection {* Generic code generator target languages *}
  1908 
  1909 text {* type @{typ bool} *}
  1910 
  1911 code_type bool
  1912   (SML "bool")
  1913   (OCaml "bool")
  1914   (Haskell "Bool")
  1915   (Scala "Boolean")
  1916 
  1917 code_const True and False and Not and HOL.conj and HOL.disj and HOL.implies and If 
  1918   (SML "true" and "false" and "not"
  1919     and infixl 1 "andalso" and infixl 0 "orelse"
  1920     and "!(if (_)/ then (_)/ else true)"
  1921     and "!(if (_)/ then (_)/ else (_))")
  1922   (OCaml "true" and "false" and "not"
  1923     and infixl 3 "&&" and infixl 2 "||"
  1924     and "!(if (_)/ then (_)/ else true)"
  1925     and "!(if (_)/ then (_)/ else (_))")
  1926   (Haskell "True" and "False" and "not"
  1927     and infixr 3 "&&" and infixr 2 "||"
  1928     and "!(if (_)/ then (_)/ else True)"
  1929     and "!(if (_)/ then (_)/ else (_))")
  1930   (Scala "true" and "false" and "'! _"
  1931     and infixl 3 "&&" and infixl 1 "||"
  1932     and "!(if ((_))/ (_)/ else true)"
  1933     and "!(if ((_))/ (_)/ else (_))")
  1934 
  1935 code_reserved SML
  1936   bool true false not
  1937 
  1938 code_reserved OCaml
  1939   bool not
  1940 
  1941 code_reserved Scala
  1942   Boolean
  1943 
  1944 code_modulename SML Pure HOL
  1945 code_modulename OCaml Pure HOL
  1946 code_modulename Haskell Pure HOL
  1947 
  1948 text {* using built-in Haskell equality *}
  1949 
  1950 code_class equal
  1951   (Haskell "Eq")
  1952 
  1953 code_const "HOL.equal"
  1954   (Haskell infix 4 "==")
  1955 
  1956 code_const HOL.eq
  1957   (Haskell infix 4 "==")
  1958 
  1959 text {* undefined *}
  1960 
  1961 code_const undefined
  1962   (SML "!(raise/ Fail/ \"undefined\")")
  1963   (OCaml "failwith/ \"undefined\"")
  1964   (Haskell "error/ \"undefined\"")
  1965   (Scala "!error(\"undefined\")")
  1966 
  1967 subsubsection {* Evaluation and normalization by evaluation *}
  1968 
  1969 setup {*
  1970   Value.add_evaluator ("SML", Codegen.eval_term)
  1971 *}
  1972 
  1973 ML {*
  1974 fun gen_eval_method conv ctxt = SIMPLE_METHOD'
  1975   (CONVERSION (Conv.params_conv ~1 (K (Conv.concl_conv ~1 (conv ctxt))) ctxt)
  1976     THEN' rtac TrueI)
  1977 *}
  1978 
  1979 method_setup eval = {*
  1980   Scan.succeed (gen_eval_method (Code_Runtime.dynamic_holds_conv o Proof_Context.theory_of))
  1981 *} "solve goal by evaluation"
  1982 
  1983 method_setup evaluation = {*
  1984   Scan.succeed (gen_eval_method Codegen.evaluation_conv)
  1985 *} "solve goal by evaluation"
  1986 
  1987 method_setup normalization = {*
  1988   Scan.succeed (fn ctxt => SIMPLE_METHOD'
  1989     (CHANGED_PROP o (CONVERSION (Nbe.dynamic_conv (Proof_Context.theory_of ctxt))
  1990       THEN' (fn k => TRY (rtac TrueI k)))))
  1991 *} "solve goal by normalization"
  1992 
  1993 
  1994 subsection {* Counterexample Search Units *}
  1995 
  1996 subsubsection {* Quickcheck *}
  1997 
  1998 quickcheck_params [size = 5, iterations = 50]
  1999 
  2000 
  2001 subsubsection {* Nitpick setup *}
  2002 
  2003 ML {*
  2004 structure Nitpick_Unfolds = Named_Thms
  2005 (
  2006   val name = "nitpick_unfold"
  2007   val description = "alternative definitions of constants as needed by Nitpick"
  2008 )
  2009 structure Nitpick_Simps = Named_Thms
  2010 (
  2011   val name = "nitpick_simp"
  2012   val description = "equational specification of constants as needed by Nitpick"
  2013 )
  2014 structure Nitpick_Psimps = Named_Thms
  2015 (
  2016   val name = "nitpick_psimp"
  2017   val description = "partial equational specification of constants as needed by Nitpick"
  2018 )
  2019 structure Nitpick_Choice_Specs = Named_Thms
  2020 (
  2021   val name = "nitpick_choice_spec"
  2022   val description = "choice specification of constants as needed by Nitpick"
  2023 )
  2024 *}
  2025 
  2026 setup {*
  2027   Nitpick_Unfolds.setup
  2028   #> Nitpick_Simps.setup
  2029   #> Nitpick_Psimps.setup
  2030   #> Nitpick_Choice_Specs.setup
  2031 *}
  2032 
  2033 declare if_bool_eq_conj [nitpick_unfold, no_atp]
  2034         if_bool_eq_disj [no_atp]
  2035 
  2036 
  2037 subsection {* Preprocessing for the predicate compiler *}
  2038 
  2039 ML {*
  2040 structure Predicate_Compile_Alternative_Defs = Named_Thms
  2041 (
  2042   val name = "code_pred_def"
  2043   val description = "alternative definitions of constants for the Predicate Compiler"
  2044 )
  2045 structure Predicate_Compile_Inline_Defs = Named_Thms
  2046 (
  2047   val name = "code_pred_inline"
  2048   val description = "inlining definitions for the Predicate Compiler"
  2049 )
  2050 structure Predicate_Compile_Simps = Named_Thms
  2051 (
  2052   val name = "code_pred_simp"
  2053   val description = "simplification rules for the optimisations in the Predicate Compiler"
  2054 )
  2055 *}
  2056 
  2057 setup {*
  2058   Predicate_Compile_Alternative_Defs.setup
  2059   #> Predicate_Compile_Inline_Defs.setup
  2060   #> Predicate_Compile_Simps.setup
  2061 *}
  2062 
  2063 
  2064 subsection {* Legacy tactics and ML bindings *}
  2065 
  2066 ML {*
  2067 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  2068 
  2069 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  2070 local
  2071   fun wrong_prem (Const (@{const_name All}, _) $ Abs (_, _, t)) = wrong_prem t
  2072     | wrong_prem (Bound _) = true
  2073     | wrong_prem _ = false;
  2074   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  2075 in
  2076   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  2077   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  2078 end;
  2079 
  2080 val all_conj_distrib = @{thm all_conj_distrib};
  2081 val all_simps = @{thms all_simps};
  2082 val atomize_not = @{thm atomize_not};
  2083 val case_split = @{thm case_split};
  2084 val cases_simp = @{thm cases_simp};
  2085 val choice_eq = @{thm choice_eq};
  2086 val cong = @{thm cong};
  2087 val conj_comms = @{thms conj_comms};
  2088 val conj_cong = @{thm conj_cong};
  2089 val de_Morgan_conj = @{thm de_Morgan_conj};
  2090 val de_Morgan_disj = @{thm de_Morgan_disj};
  2091 val disj_assoc = @{thm disj_assoc};
  2092 val disj_comms = @{thms disj_comms};
  2093 val disj_cong = @{thm disj_cong};
  2094 val eq_ac = @{thms eq_ac};
  2095 val eq_cong2 = @{thm eq_cong2}
  2096 val Eq_FalseI = @{thm Eq_FalseI};
  2097 val Eq_TrueI = @{thm Eq_TrueI};
  2098 val Ex1_def = @{thm Ex1_def};
  2099 val ex_disj_distrib = @{thm ex_disj_distrib};
  2100 val ex_simps = @{thms ex_simps};
  2101 val if_cancel = @{thm if_cancel};
  2102 val if_eq_cancel = @{thm if_eq_cancel};
  2103 val if_False = @{thm if_False};
  2104 val iff_conv_conj_imp = @{thm iff_conv_conj_imp};
  2105 val iff = @{thm iff};
  2106 val if_splits = @{thms if_splits};
  2107 val if_True = @{thm if_True};
  2108 val if_weak_cong = @{thm if_weak_cong};
  2109 val imp_all = @{thm imp_all};
  2110 val imp_cong = @{thm imp_cong};
  2111 val imp_conjL = @{thm imp_conjL};
  2112 val imp_conjR = @{thm imp_conjR};
  2113 val imp_conv_disj = @{thm imp_conv_disj};
  2114 val simp_implies_def = @{thm simp_implies_def};
  2115 val simp_thms = @{thms simp_thms};
  2116 val split_if = @{thm split_if};
  2117 val the1_equality = @{thm the1_equality};
  2118 val theI = @{thm theI};
  2119 val theI' = @{thm theI'};
  2120 val True_implies_equals = @{thm True_implies_equals};
  2121 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  2122 
  2123 *}
  2124 
  2125 hide_const (open) eq equal
  2126 
  2127 end