src/HOL/Deriv.thy
author huffman
Fri Mar 30 12:32:35 2012 +0200 (2012-03-30)
changeset 47220 52426c62b5d0
parent 47108 2a1953f0d20d
child 50327 bbea2e82871c
permissions -rw-r--r--
replace lemmas eval_nat_numeral with a simpler reformulation
     1 (*  Title       : Deriv.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     5     GMVT by Benjamin Porter, 2005
     6 *)
     7 
     8 header{* Differentiation *}
     9 
    10 theory Deriv
    11 imports Lim
    12 begin
    13 
    14 text{*Standard Definitions*}
    15 
    16 definition
    17   deriv :: "['a::real_normed_field \<Rightarrow> 'a, 'a, 'a] \<Rightarrow> bool"
    18     --{*Differentiation: D is derivative of function f at x*}
    19           ("(DERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60) where
    20   "DERIV f x :> D = ((%h. (f(x + h) - f x) / h) -- 0 --> D)"
    21 
    22 primrec
    23   Bolzano_bisect :: "(real \<times> real \<Rightarrow> bool) \<Rightarrow> real \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> real \<times> real" where
    24   "Bolzano_bisect P a b 0 = (a, b)"
    25   | "Bolzano_bisect P a b (Suc n) =
    26       (let (x, y) = Bolzano_bisect P a b n
    27        in if P (x, (x+y) / 2) then ((x+y)/2, y)
    28                               else (x, (x+y)/2))"
    29 
    30 
    31 subsection {* Derivatives *}
    32 
    33 lemma DERIV_iff: "(DERIV f x :> D) = ((%h. (f(x + h) - f(x))/h) -- 0 --> D)"
    34 by (simp add: deriv_def)
    35 
    36 lemma DERIV_D: "DERIV f x :> D ==> (%h. (f(x + h) - f(x))/h) -- 0 --> D"
    37 by (simp add: deriv_def)
    38 
    39 lemma DERIV_const [simp]: "DERIV (\<lambda>x. k) x :> 0"
    40   by (simp add: deriv_def tendsto_const)
    41 
    42 lemma DERIV_ident [simp]: "DERIV (\<lambda>x. x) x :> 1"
    43   by (simp add: deriv_def tendsto_const cong: LIM_cong)
    44 
    45 lemma DERIV_add:
    46   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x + g x) x :> D + E"
    47   by (simp only: deriv_def add_diff_add add_divide_distrib tendsto_add)
    48 
    49 lemma DERIV_minus:
    50   "DERIV f x :> D \<Longrightarrow> DERIV (\<lambda>x. - f x) x :> - D"
    51   by (simp only: deriv_def minus_diff_minus divide_minus_left tendsto_minus)
    52 
    53 lemma DERIV_diff:
    54   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x - g x) x :> D - E"
    55 by (simp only: diff_minus DERIV_add DERIV_minus)
    56 
    57 lemma DERIV_add_minus:
    58   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x + - g x) x :> D + - E"
    59 by (simp only: DERIV_add DERIV_minus)
    60 
    61 lemma DERIV_isCont: "DERIV f x :> D \<Longrightarrow> isCont f x"
    62 proof (unfold isCont_iff)
    63   assume "DERIV f x :> D"
    64   hence "(\<lambda>h. (f(x+h) - f(x)) / h) -- 0 --> D"
    65     by (rule DERIV_D)
    66   hence "(\<lambda>h. (f(x+h) - f(x)) / h * h) -- 0 --> D * 0"
    67     by (intro tendsto_mult tendsto_ident_at)
    68   hence "(\<lambda>h. (f(x+h) - f(x)) * (h / h)) -- 0 --> 0"
    69     by simp
    70   hence "(\<lambda>h. f(x+h) - f(x)) -- 0 --> 0"
    71     by (simp cong: LIM_cong)
    72   thus "(\<lambda>h. f(x+h)) -- 0 --> f(x)"
    73     by (simp add: LIM_def dist_norm)
    74 qed
    75 
    76 lemma DERIV_mult_lemma:
    77   fixes a b c d :: "'a::real_field"
    78   shows "(a * b - c * d) / h = a * ((b - d) / h) + ((a - c) / h) * d"
    79 by (simp add: diff_minus add_divide_distrib [symmetric] ring_distribs)
    80 
    81 lemma DERIV_mult':
    82   assumes f: "DERIV f x :> D"
    83   assumes g: "DERIV g x :> E"
    84   shows "DERIV (\<lambda>x. f x * g x) x :> f x * E + D * g x"
    85 proof (unfold deriv_def)
    86   from f have "isCont f x"
    87     by (rule DERIV_isCont)
    88   hence "(\<lambda>h. f(x+h)) -- 0 --> f x"
    89     by (simp only: isCont_iff)
    90   hence "(\<lambda>h. f(x+h) * ((g(x+h) - g x) / h) +
    91               ((f(x+h) - f x) / h) * g x)
    92           -- 0 --> f x * E + D * g x"
    93     by (intro tendsto_intros DERIV_D f g)
    94   thus "(\<lambda>h. (f(x+h) * g(x+h) - f x * g x) / h)
    95          -- 0 --> f x * E + D * g x"
    96     by (simp only: DERIV_mult_lemma)
    97 qed
    98 
    99 lemma DERIV_mult:
   100      "[| DERIV f x :> Da; DERIV g x :> Db |]
   101       ==> DERIV (%x. f x * g x) x :> (Da * g(x)) + (Db * f(x))"
   102 by (drule (1) DERIV_mult', simp only: mult_commute add_commute)
   103 
   104 lemma DERIV_unique:
   105       "[| DERIV f x :> D; DERIV f x :> E |] ==> D = E"
   106 apply (simp add: deriv_def)
   107 apply (blast intro: LIM_unique)
   108 done
   109 
   110 text{*Differentiation of finite sum*}
   111 
   112 lemma DERIV_setsum:
   113   assumes "finite S"
   114   and "\<And> n. n \<in> S \<Longrightarrow> DERIV (%x. f x n) x :> (f' x n)"
   115   shows "DERIV (%x. setsum (f x) S) x :> setsum (f' x) S"
   116   using assms by induct (auto intro!: DERIV_add)
   117 
   118 lemma DERIV_sumr [rule_format (no_asm)]:
   119      "(\<forall>r. m \<le> r & r < (m + n) --> DERIV (%x. f r x) x :> (f' r x))
   120       --> DERIV (%x. \<Sum>n=m..<n::nat. f n x :: real) x :> (\<Sum>r=m..<n. f' r x)"
   121   by (auto intro: DERIV_setsum)
   122 
   123 text{*Alternative definition for differentiability*}
   124 
   125 lemma DERIV_LIM_iff:
   126   fixes f :: "'a::{real_normed_vector,inverse} \<Rightarrow> 'a" shows
   127      "((%h. (f(a + h) - f(a)) / h) -- 0 --> D) =
   128       ((%x. (f(x)-f(a)) / (x-a)) -- a --> D)"
   129 apply (rule iffI)
   130 apply (drule_tac k="- a" in LIM_offset)
   131 apply (simp add: diff_minus)
   132 apply (drule_tac k="a" in LIM_offset)
   133 apply (simp add: add_commute)
   134 done
   135 
   136 lemma DERIV_iff2: "(DERIV f x :> D) = ((%z. (f(z) - f(x)) / (z-x)) -- x --> D)"
   137 by (simp add: deriv_def diff_minus [symmetric] DERIV_LIM_iff)
   138 
   139 lemma DERIV_inverse_lemma:
   140   "\<lbrakk>a \<noteq> 0; b \<noteq> (0::'a::real_normed_field)\<rbrakk>
   141    \<Longrightarrow> (inverse a - inverse b) / h
   142      = - (inverse a * ((a - b) / h) * inverse b)"
   143 by (simp add: inverse_diff_inverse)
   144 
   145 lemma DERIV_inverse':
   146   assumes der: "DERIV f x :> D"
   147   assumes neq: "f x \<noteq> 0"
   148   shows "DERIV (\<lambda>x. inverse (f x)) x :> - (inverse (f x) * D * inverse (f x))"
   149     (is "DERIV _ _ :> ?E")
   150 proof (unfold DERIV_iff2)
   151   from der have lim_f: "f -- x --> f x"
   152     by (rule DERIV_isCont [unfolded isCont_def])
   153 
   154   from neq have "0 < norm (f x)" by simp
   155   with LIM_D [OF lim_f] obtain s
   156     where s: "0 < s"
   157     and less_fx: "\<And>z. \<lbrakk>z \<noteq> x; norm (z - x) < s\<rbrakk>
   158                   \<Longrightarrow> norm (f z - f x) < norm (f x)"
   159     by fast
   160 
   161   show "(\<lambda>z. (inverse (f z) - inverse (f x)) / (z - x)) -- x --> ?E"
   162   proof (rule LIM_equal2 [OF s])
   163     fix z
   164     assume "z \<noteq> x" "norm (z - x) < s"
   165     hence "norm (f z - f x) < norm (f x)" by (rule less_fx)
   166     hence "f z \<noteq> 0" by auto
   167     thus "(inverse (f z) - inverse (f x)) / (z - x) =
   168           - (inverse (f z) * ((f z - f x) / (z - x)) * inverse (f x))"
   169       using neq by (rule DERIV_inverse_lemma)
   170   next
   171     from der have "(\<lambda>z. (f z - f x) / (z - x)) -- x --> D"
   172       by (unfold DERIV_iff2)
   173     thus "(\<lambda>z. - (inverse (f z) * ((f z - f x) / (z - x)) * inverse (f x)))
   174           -- x --> ?E"
   175       by (intro tendsto_intros lim_f neq)
   176   qed
   177 qed
   178 
   179 lemma DERIV_divide:
   180   "\<lbrakk>DERIV f x :> D; DERIV g x :> E; g x \<noteq> 0\<rbrakk>
   181    \<Longrightarrow> DERIV (\<lambda>x. f x / g x) x :> (D * g x - f x * E) / (g x * g x)"
   182 apply (subgoal_tac "f x * - (inverse (g x) * E * inverse (g x)) +
   183           D * inverse (g x) = (D * g x - f x * E) / (g x * g x)")
   184 apply (erule subst)
   185 apply (unfold divide_inverse)
   186 apply (erule DERIV_mult')
   187 apply (erule (1) DERIV_inverse')
   188 apply (simp add: ring_distribs nonzero_inverse_mult_distrib)
   189 done
   190 
   191 lemma DERIV_power_Suc:
   192   fixes f :: "'a \<Rightarrow> 'a::{real_normed_field}"
   193   assumes f: "DERIV f x :> D"
   194   shows "DERIV (\<lambda>x. f x ^ Suc n) x :> (1 + of_nat n) * (D * f x ^ n)"
   195 proof (induct n)
   196 case 0
   197   show ?case by (simp add: f)
   198 case (Suc k)
   199   from DERIV_mult' [OF f Suc] show ?case
   200     apply (simp only: of_nat_Suc ring_distribs mult_1_left)
   201     apply (simp only: power_Suc algebra_simps)
   202     done
   203 qed
   204 
   205 lemma DERIV_power:
   206   fixes f :: "'a \<Rightarrow> 'a::{real_normed_field}"
   207   assumes f: "DERIV f x :> D"
   208   shows "DERIV (\<lambda>x. f x ^ n) x :> of_nat n * (D * f x ^ (n - Suc 0))"
   209 by (cases "n", simp, simp add: DERIV_power_Suc f del: power_Suc)
   210 
   211 text {* Caratheodory formulation of derivative at a point *}
   212 
   213 lemma CARAT_DERIV:
   214      "(DERIV f x :> l) =
   215       (\<exists>g. (\<forall>z. f z - f x = g z * (z-x)) & isCont g x & g x = l)"
   216       (is "?lhs = ?rhs")
   217 proof
   218   assume der: "DERIV f x :> l"
   219   show "\<exists>g. (\<forall>z. f z - f x = g z * (z-x)) \<and> isCont g x \<and> g x = l"
   220   proof (intro exI conjI)
   221     let ?g = "(%z. if z = x then l else (f z - f x) / (z-x))"
   222     show "\<forall>z. f z - f x = ?g z * (z-x)" by simp
   223     show "isCont ?g x" using der
   224       by (simp add: isCont_iff DERIV_iff diff_minus
   225                cong: LIM_equal [rule_format])
   226     show "?g x = l" by simp
   227   qed
   228 next
   229   assume "?rhs"
   230   then obtain g where
   231     "(\<forall>z. f z - f x = g z * (z-x))" and "isCont g x" and "g x = l" by blast
   232   thus "(DERIV f x :> l)"
   233      by (auto simp add: isCont_iff DERIV_iff cong: LIM_cong)
   234 qed
   235 
   236 lemma DERIV_chain':
   237   assumes f: "DERIV f x :> D"
   238   assumes g: "DERIV g (f x) :> E"
   239   shows "DERIV (\<lambda>x. g (f x)) x :> E * D"
   240 proof (unfold DERIV_iff2)
   241   obtain d where d: "\<forall>y. g y - g (f x) = d y * (y - f x)"
   242     and cont_d: "isCont d (f x)" and dfx: "d (f x) = E"
   243     using CARAT_DERIV [THEN iffD1, OF g] by fast
   244   from f have "f -- x --> f x"
   245     by (rule DERIV_isCont [unfolded isCont_def])
   246   with cont_d have "(\<lambda>z. d (f z)) -- x --> d (f x)"
   247     by (rule isCont_tendsto_compose)
   248   hence "(\<lambda>z. d (f z) * ((f z - f x) / (z - x)))
   249           -- x --> d (f x) * D"
   250     by (rule tendsto_mult [OF _ f [unfolded DERIV_iff2]])
   251   thus "(\<lambda>z. (g (f z) - g (f x)) / (z - x)) -- x --> E * D"
   252     by (simp add: d dfx)
   253 qed
   254 
   255 text {*
   256  Let's do the standard proof, though theorem
   257  @{text "LIM_mult2"} follows from a NS proof
   258 *}
   259 
   260 lemma DERIV_cmult:
   261       "DERIV f x :> D ==> DERIV (%x. c * f x) x :> c*D"
   262 by (drule DERIV_mult' [OF DERIV_const], simp)
   263 
   264 lemma DERIV_cdivide: "DERIV f x :> D ==> DERIV (%x. f x / c) x :> D / c"
   265   apply (subgoal_tac "DERIV (%x. (1 / c) * f x) x :> (1 / c) * D", force)
   266   apply (erule DERIV_cmult)
   267   done
   268 
   269 text {* Standard version *}
   270 lemma DERIV_chain: "[| DERIV f (g x) :> Da; DERIV g x :> Db |] ==> DERIV (f o g) x :> Da * Db"
   271 by (drule (1) DERIV_chain', simp add: o_def mult_commute)
   272 
   273 lemma DERIV_chain2: "[| DERIV f (g x) :> Da; DERIV g x :> Db |] ==> DERIV (%x. f (g x)) x :> Da * Db"
   274 by (auto dest: DERIV_chain simp add: o_def)
   275 
   276 text {* Derivative of linear multiplication *}
   277 lemma DERIV_cmult_Id [simp]: "DERIV (op * c) x :> c"
   278 by (cut_tac c = c and x = x in DERIV_ident [THEN DERIV_cmult], simp)
   279 
   280 lemma DERIV_pow: "DERIV (%x. x ^ n) x :> real n * (x ^ (n - Suc 0))"
   281 apply (cut_tac DERIV_power [OF DERIV_ident])
   282 apply (simp add: real_of_nat_def)
   283 done
   284 
   285 text {* Power of @{text "-1"} *}
   286 
   287 lemma DERIV_inverse:
   288   fixes x :: "'a::{real_normed_field}"
   289   shows "x \<noteq> 0 ==> DERIV (%x. inverse(x)) x :> (-(inverse x ^ Suc (Suc 0)))"
   290 by (drule DERIV_inverse' [OF DERIV_ident]) simp
   291 
   292 text {* Derivative of inverse *}
   293 lemma DERIV_inverse_fun:
   294   fixes x :: "'a::{real_normed_field}"
   295   shows "[| DERIV f x :> d; f(x) \<noteq> 0 |]
   296       ==> DERIV (%x. inverse(f x)) x :> (- (d * inverse(f(x) ^ Suc (Suc 0))))"
   297 by (drule (1) DERIV_inverse') (simp add: mult_ac nonzero_inverse_mult_distrib)
   298 
   299 text {* Derivative of quotient *}
   300 lemma DERIV_quotient:
   301   fixes x :: "'a::{real_normed_field}"
   302   shows "[| DERIV f x :> d; DERIV g x :> e; g(x) \<noteq> 0 |]
   303        ==> DERIV (%y. f(y) / (g y)) x :> (d*g(x) - (e*f(x))) / (g(x) ^ Suc (Suc 0))"
   304 by (drule (2) DERIV_divide) (simp add: mult_commute)
   305 
   306 text {* @{text "DERIV_intros"} *}
   307 ML {*
   308 structure Deriv_Intros = Named_Thms
   309 (
   310   val name = @{binding DERIV_intros}
   311   val description = "DERIV introduction rules"
   312 )
   313 *}
   314 
   315 setup Deriv_Intros.setup
   316 
   317 lemma DERIV_cong: "\<lbrakk> DERIV f x :> X ; X = Y \<rbrakk> \<Longrightarrow> DERIV f x :> Y"
   318   by simp
   319 
   320 declare
   321   DERIV_const[THEN DERIV_cong, DERIV_intros]
   322   DERIV_ident[THEN DERIV_cong, DERIV_intros]
   323   DERIV_add[THEN DERIV_cong, DERIV_intros]
   324   DERIV_minus[THEN DERIV_cong, DERIV_intros]
   325   DERIV_mult[THEN DERIV_cong, DERIV_intros]
   326   DERIV_diff[THEN DERIV_cong, DERIV_intros]
   327   DERIV_inverse'[THEN DERIV_cong, DERIV_intros]
   328   DERIV_divide[THEN DERIV_cong, DERIV_intros]
   329   DERIV_power[where 'a=real, THEN DERIV_cong,
   330               unfolded real_of_nat_def[symmetric], DERIV_intros]
   331   DERIV_setsum[THEN DERIV_cong, DERIV_intros]
   332 
   333 
   334 subsection {* Differentiability predicate *}
   335 
   336 definition
   337   differentiable :: "['a::real_normed_field \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
   338     (infixl "differentiable" 60) where
   339   "f differentiable x = (\<exists>D. DERIV f x :> D)"
   340 
   341 lemma differentiableE [elim?]:
   342   assumes "f differentiable x"
   343   obtains df where "DERIV f x :> df"
   344   using assms unfolding differentiable_def ..
   345 
   346 lemma differentiableD: "f differentiable x ==> \<exists>D. DERIV f x :> D"
   347 by (simp add: differentiable_def)
   348 
   349 lemma differentiableI: "DERIV f x :> D ==> f differentiable x"
   350 by (force simp add: differentiable_def)
   351 
   352 lemma differentiable_ident [simp]: "(\<lambda>x. x) differentiable x"
   353   by (rule DERIV_ident [THEN differentiableI])
   354 
   355 lemma differentiable_const [simp]: "(\<lambda>z. a) differentiable x"
   356   by (rule DERIV_const [THEN differentiableI])
   357 
   358 lemma differentiable_compose:
   359   assumes f: "f differentiable (g x)"
   360   assumes g: "g differentiable x"
   361   shows "(\<lambda>x. f (g x)) differentiable x"
   362 proof -
   363   from `f differentiable (g x)` obtain df where "DERIV f (g x) :> df" ..
   364   moreover
   365   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   366   ultimately
   367   have "DERIV (\<lambda>x. f (g x)) x :> df * dg" by (rule DERIV_chain2)
   368   thus ?thesis by (rule differentiableI)
   369 qed
   370 
   371 lemma differentiable_sum [simp]:
   372   assumes "f differentiable x"
   373   and "g differentiable x"
   374   shows "(\<lambda>x. f x + g x) differentiable x"
   375 proof -
   376   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   377   moreover
   378   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   379   ultimately
   380   have "DERIV (\<lambda>x. f x + g x) x :> df + dg" by (rule DERIV_add)
   381   thus ?thesis by (rule differentiableI)
   382 qed
   383 
   384 lemma differentiable_minus [simp]:
   385   assumes "f differentiable x"
   386   shows "(\<lambda>x. - f x) differentiable x"
   387 proof -
   388   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   389   hence "DERIV (\<lambda>x. - f x) x :> - df" by (rule DERIV_minus)
   390   thus ?thesis by (rule differentiableI)
   391 qed
   392 
   393 lemma differentiable_diff [simp]:
   394   assumes "f differentiable x"
   395   assumes "g differentiable x"
   396   shows "(\<lambda>x. f x - g x) differentiable x"
   397   unfolding diff_minus using assms by simp
   398 
   399 lemma differentiable_mult [simp]:
   400   assumes "f differentiable x"
   401   assumes "g differentiable x"
   402   shows "(\<lambda>x. f x * g x) differentiable x"
   403 proof -
   404   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   405   moreover
   406   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   407   ultimately
   408   have "DERIV (\<lambda>x. f x * g x) x :> df * g x + dg * f x" by (rule DERIV_mult)
   409   thus ?thesis by (rule differentiableI)
   410 qed
   411 
   412 lemma differentiable_inverse [simp]:
   413   assumes "f differentiable x" and "f x \<noteq> 0"
   414   shows "(\<lambda>x. inverse (f x)) differentiable x"
   415 proof -
   416   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   417   hence "DERIV (\<lambda>x. inverse (f x)) x :> - (inverse (f x) * df * inverse (f x))"
   418     using `f x \<noteq> 0` by (rule DERIV_inverse')
   419   thus ?thesis by (rule differentiableI)
   420 qed
   421 
   422 lemma differentiable_divide [simp]:
   423   assumes "f differentiable x"
   424   assumes "g differentiable x" and "g x \<noteq> 0"
   425   shows "(\<lambda>x. f x / g x) differentiable x"
   426   unfolding divide_inverse using assms by simp
   427 
   428 lemma differentiable_power [simp]:
   429   fixes f :: "'a::{real_normed_field} \<Rightarrow> 'a"
   430   assumes "f differentiable x"
   431   shows "(\<lambda>x. f x ^ n) differentiable x"
   432   apply (induct n)
   433   apply simp
   434   apply (simp add: assms)
   435   done
   436 
   437 
   438 subsection {* Nested Intervals and Bisection *}
   439 
   440 text{*Lemmas about nested intervals and proof by bisection (cf.Harrison).
   441      All considerably tidied by lcp.*}
   442 
   443 lemma lemma_f_mono_add [rule_format (no_asm)]: "(\<forall>n. (f::nat=>real) n \<le> f (Suc n)) --> f m \<le> f(m + no)"
   444 apply (induct "no")
   445 apply (auto intro: order_trans)
   446 done
   447 
   448 lemma f_inc_g_dec_Beq_f: "[| \<forall>n. f(n) \<le> f(Suc n);
   449          \<forall>n. g(Suc n) \<le> g(n);
   450          \<forall>n. f(n) \<le> g(n) |]
   451       ==> Bseq (f :: nat \<Rightarrow> real)"
   452 apply (rule_tac k = "f 0" and K = "g 0" in BseqI2, rule allI)
   453 apply (rule conjI)
   454 apply (induct_tac "n")
   455 apply (auto intro: order_trans)
   456 apply (rule_tac y = "g n" in order_trans)
   457 apply (induct_tac [2] "n")
   458 apply (auto intro: order_trans)
   459 done
   460 
   461 lemma f_inc_g_dec_Beq_g: "[| \<forall>n. f(n) \<le> f(Suc n);
   462          \<forall>n. g(Suc n) \<le> g(n);
   463          \<forall>n. f(n) \<le> g(n) |]
   464       ==> Bseq (g :: nat \<Rightarrow> real)"
   465 apply (subst Bseq_minus_iff [symmetric])
   466 apply (rule_tac g = "%x. - (f x)" in f_inc_g_dec_Beq_f)
   467 apply auto
   468 done
   469 
   470 lemma f_inc_imp_le_lim:
   471   fixes f :: "nat \<Rightarrow> real"
   472   shows "\<lbrakk>\<forall>n. f n \<le> f (Suc n); convergent f\<rbrakk> \<Longrightarrow> f n \<le> lim f"
   473   by (rule incseq_le, simp add: incseq_SucI, simp add: convergent_LIMSEQ_iff)
   474 
   475 lemma lim_uminus:
   476   fixes g :: "nat \<Rightarrow> 'a::real_normed_vector"
   477   shows "convergent g ==> lim (%x. - g x) = - (lim g)"
   478 apply (rule tendsto_minus [THEN limI])
   479 apply (simp add: convergent_LIMSEQ_iff)
   480 done
   481 
   482 lemma g_dec_imp_lim_le:
   483   fixes g :: "nat \<Rightarrow> real"
   484   shows "\<lbrakk>\<forall>n. g (Suc n) \<le> g(n); convergent g\<rbrakk> \<Longrightarrow> lim g \<le> g n"
   485   by (rule decseq_le, simp add: decseq_SucI, simp add: convergent_LIMSEQ_iff)
   486 
   487 lemma lemma_nest: "[| \<forall>n. f(n) \<le> f(Suc n);
   488          \<forall>n. g(Suc n) \<le> g(n);
   489          \<forall>n. f(n) \<le> g(n) |]
   490       ==> \<exists>l m :: real. l \<le> m &  ((\<forall>n. f(n) \<le> l) & f ----> l) &
   491                             ((\<forall>n. m \<le> g(n)) & g ----> m)"
   492 apply (subgoal_tac "monoseq f & monoseq g")
   493 prefer 2 apply (force simp add: LIMSEQ_iff monoseq_Suc)
   494 apply (subgoal_tac "Bseq f & Bseq g")
   495 prefer 2 apply (blast intro: f_inc_g_dec_Beq_f f_inc_g_dec_Beq_g)
   496 apply (auto dest!: Bseq_monoseq_convergent simp add: convergent_LIMSEQ_iff)
   497 apply (rule_tac x = "lim f" in exI)
   498 apply (rule_tac x = "lim g" in exI)
   499 apply (auto intro: LIMSEQ_le)
   500 apply (auto simp add: f_inc_imp_le_lim g_dec_imp_lim_le convergent_LIMSEQ_iff)
   501 done
   502 
   503 lemma lemma_nest_unique: "[| \<forall>n. f(n) \<le> f(Suc n);
   504          \<forall>n. g(Suc n) \<le> g(n);
   505          \<forall>n. f(n) \<le> g(n);
   506          (%n. f(n) - g(n)) ----> 0 |]
   507       ==> \<exists>l::real. ((\<forall>n. f(n) \<le> l) & f ----> l) &
   508                 ((\<forall>n. l \<le> g(n)) & g ----> l)"
   509 apply (drule lemma_nest, auto)
   510 apply (subgoal_tac "l = m")
   511 apply (drule_tac [2] f = f in tendsto_diff)
   512 apply (auto intro: LIMSEQ_unique)
   513 done
   514 
   515 text{*The universal quantifiers below are required for the declaration
   516   of @{text Bolzano_nest_unique} below.*}
   517 
   518 lemma Bolzano_bisect_le:
   519  "a \<le> b ==> \<forall>n. fst (Bolzano_bisect P a b n) \<le> snd (Bolzano_bisect P a b n)"
   520 apply (rule allI)
   521 apply (induct_tac "n")
   522 apply (auto simp add: Let_def split_def)
   523 done
   524 
   525 lemma Bolzano_bisect_fst_le_Suc: "a \<le> b ==>
   526    \<forall>n. fst(Bolzano_bisect P a b n) \<le> fst (Bolzano_bisect P a b (Suc n))"
   527 apply (rule allI)
   528 apply (induct_tac "n")
   529 apply (auto simp add: Bolzano_bisect_le Let_def split_def)
   530 done
   531 
   532 lemma Bolzano_bisect_Suc_le_snd: "a \<le> b ==>
   533    \<forall>n. snd(Bolzano_bisect P a b (Suc n)) \<le> snd (Bolzano_bisect P a b n)"
   534 apply (rule allI)
   535 apply (induct_tac "n")
   536 apply (auto simp add: Bolzano_bisect_le Let_def split_def)
   537 done
   538 
   539 lemma eq_divide_2_times_iff: "((x::real) = y / (2 * z)) = (2 * x = y/z)"
   540 apply (auto)
   541 apply (drule_tac f = "%u. (1/2) *u" in arg_cong)
   542 apply (simp)
   543 done
   544 
   545 lemma Bolzano_bisect_diff:
   546      "a \<le> b ==>
   547       snd(Bolzano_bisect P a b n) - fst(Bolzano_bisect P a b n) =
   548       (b-a) / (2 ^ n)"
   549 apply (induct "n")
   550 apply (auto simp add: eq_divide_2_times_iff add_divide_distrib Let_def split_def)
   551 done
   552 
   553 lemmas Bolzano_nest_unique =
   554     lemma_nest_unique
   555     [OF Bolzano_bisect_fst_le_Suc Bolzano_bisect_Suc_le_snd Bolzano_bisect_le]
   556 
   557 
   558 lemma not_P_Bolzano_bisect:
   559   assumes P:    "!!a b c. [| P(a,b); P(b,c); a \<le> b; b \<le> c|] ==> P(a,c)"
   560       and notP: "~ P(a,b)"
   561       and le:   "a \<le> b"
   562   shows "~ P(fst(Bolzano_bisect P a b n), snd(Bolzano_bisect P a b n))"
   563 proof (induct n)
   564   case 0 show ?case using notP by simp
   565  next
   566   case (Suc n)
   567   thus ?case
   568  by (auto simp del: surjective_pairing [symmetric]
   569              simp add: Let_def split_def Bolzano_bisect_le [OF le]
   570      P [of "fst (Bolzano_bisect P a b n)" _ "snd (Bolzano_bisect P a b n)"])
   571 qed
   572 
   573 (*Now we re-package P_prem as a formula*)
   574 lemma not_P_Bolzano_bisect':
   575      "[| \<forall>a b c. P(a,b) & P(b,c) & a \<le> b & b \<le> c --> P(a,c);
   576          ~ P(a,b);  a \<le> b |] ==>
   577       \<forall>n. ~ P(fst(Bolzano_bisect P a b n), snd(Bolzano_bisect P a b n))"
   578 by (blast elim!: not_P_Bolzano_bisect [THEN [2] rev_notE])
   579 
   580 
   581 
   582 lemma lemma_BOLZANO:
   583      "[| \<forall>a b c. P(a,b) & P(b,c) & a \<le> b & b \<le> c --> P(a,c);
   584          \<forall>x. \<exists>d::real. 0 < d &
   585                 (\<forall>a b. a \<le> x & x \<le> b & (b-a) < d --> P(a,b));
   586          a \<le> b |]
   587       ==> P(a,b)"
   588 apply (rule Bolzano_nest_unique [where P=P, THEN exE], assumption+)
   589 apply (rule tendsto_minus_cancel)
   590 apply (simp (no_asm_simp) add: Bolzano_bisect_diff LIMSEQ_divide_realpow_zero)
   591 apply (rule ccontr)
   592 apply (drule not_P_Bolzano_bisect', assumption+)
   593 apply (rename_tac "l")
   594 apply (drule_tac x = l in spec, clarify)
   595 apply (simp add: LIMSEQ_iff)
   596 apply (drule_tac P = "%r. 0<r --> ?Q r" and x = "d/2" in spec)
   597 apply (drule_tac P = "%r. 0<r --> ?Q r" and x = "d/2" in spec)
   598 apply (drule real_less_half_sum, auto)
   599 apply (drule_tac x = "fst (Bolzano_bisect P a b (no + noa))" in spec)
   600 apply (drule_tac x = "snd (Bolzano_bisect P a b (no + noa))" in spec)
   601 apply safe
   602 apply (simp_all (no_asm_simp))
   603 apply (rule_tac y = "abs (fst (Bolzano_bisect P a b (no + noa)) - l) + abs (snd (Bolzano_bisect P a b (no + noa)) - l)" in order_le_less_trans)
   604 apply (simp (no_asm_simp) add: abs_if)
   605 apply (rule real_sum_of_halves [THEN subst])
   606 apply (rule add_strict_mono)
   607 apply (simp_all add: diff_minus [symmetric])
   608 done
   609 
   610 
   611 lemma lemma_BOLZANO2: "((\<forall>a b c. (a \<le> b & b \<le> c & P(a,b) & P(b,c)) --> P(a,c)) &
   612        (\<forall>x. \<exists>d::real. 0 < d &
   613                 (\<forall>a b. a \<le> x & x \<le> b & (b-a) < d --> P(a,b))))
   614       --> (\<forall>a b. a \<le> b --> P(a,b))"
   615 apply clarify
   616 apply (blast intro: lemma_BOLZANO)
   617 done
   618 
   619 
   620 subsection {* Intermediate Value Theorem *}
   621 
   622 text {*Prove Contrapositive by Bisection*}
   623 
   624 lemma IVT: "[| f(a::real) \<le> (y::real); y \<le> f(b);
   625          a \<le> b;
   626          (\<forall>x. a \<le> x & x \<le> b --> isCont f x) |]
   627       ==> \<exists>x. a \<le> x & x \<le> b & f(x) = y"
   628 apply (rule contrapos_pp, assumption)
   629 apply (cut_tac P = "% (u,v) . a \<le> u & u \<le> v & v \<le> b --> ~ (f (u) \<le> y & y \<le> f (v))" in lemma_BOLZANO2)
   630 apply safe
   631 apply simp_all
   632 apply (simp add: isCont_iff LIM_eq)
   633 apply (rule ccontr)
   634 apply (subgoal_tac "a \<le> x & x \<le> b")
   635  prefer 2
   636  apply simp
   637  apply (drule_tac P = "%d. 0<d --> ?P d" and x = 1 in spec, arith)
   638 apply (drule_tac x = x in spec)+
   639 apply simp
   640 apply (drule_tac P = "%r. ?P r --> (\<exists>s>0. ?Q r s) " and x = "\<bar>y - f x\<bar>" in spec)
   641 apply safe
   642 apply simp
   643 apply (drule_tac x = s in spec, clarify)
   644 apply (cut_tac x = "f x" and y = y in linorder_less_linear, safe)
   645 apply (drule_tac x = "ba-x" in spec)
   646 apply (simp_all add: abs_if)
   647 apply (drule_tac x = "aa-x" in spec)
   648 apply (case_tac "x \<le> aa", simp_all)
   649 done
   650 
   651 lemma IVT2: "[| f(b::real) \<le> (y::real); y \<le> f(a);
   652          a \<le> b;
   653          (\<forall>x. a \<le> x & x \<le> b --> isCont f x)
   654       |] ==> \<exists>x. a \<le> x & x \<le> b & f(x) = y"
   655 apply (subgoal_tac "- f a \<le> -y & -y \<le> - f b", clarify)
   656 apply (drule IVT [where f = "%x. - f x"], assumption)
   657 apply simp_all
   658 done
   659 
   660 (*HOL style here: object-level formulations*)
   661 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
   662       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
   663       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
   664 apply (blast intro: IVT)
   665 done
   666 
   667 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
   668       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
   669       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
   670 apply (blast intro: IVT2)
   671 done
   672 
   673 
   674 subsection {* Boundedness of continuous functions *}
   675 
   676 text{*By bisection, function continuous on closed interval is bounded above*}
   677 
   678 lemma isCont_bounded:
   679      "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   680       ==> \<exists>M::real. \<forall>x::real. a \<le> x & x \<le> b --> f(x) \<le> M"
   681 apply (cut_tac P = "% (u,v) . a \<le> u & u \<le> v & v \<le> b --> (\<exists>M. \<forall>x. u \<le> x & x \<le> v --> f x \<le> M)" in lemma_BOLZANO2)
   682 apply safe
   683 apply simp_all
   684 apply (rename_tac x xa ya M Ma)
   685 apply (metis linorder_not_less order_le_less order_trans)
   686 apply (case_tac "a \<le> x & x \<le> b")
   687  prefer 2
   688  apply (rule_tac x = 1 in exI, force)
   689 apply (simp add: LIM_eq isCont_iff)
   690 apply (drule_tac x = x in spec, auto)
   691 apply (erule_tac V = "\<forall>M. \<exists>x. a \<le> x & x \<le> b & ~ f x \<le> M" in thin_rl)
   692 apply (drule_tac x = 1 in spec, auto)
   693 apply (rule_tac x = s in exI, clarify)
   694 apply (rule_tac x = "\<bar>f x\<bar> + 1" in exI, clarify)
   695 apply (drule_tac x = "xa-x" in spec)
   696 apply (auto simp add: abs_ge_self)
   697 done
   698 
   699 text{*Refine the above to existence of least upper bound*}
   700 
   701 lemma lemma_reals_complete: "((\<exists>x. x \<in> S) & (\<exists>y. isUb UNIV S (y::real))) -->
   702       (\<exists>t. isLub UNIV S t)"
   703 by (blast intro: reals_complete)
   704 
   705 lemma isCont_has_Ub: "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   706          ==> \<exists>M::real. (\<forall>x::real. a \<le> x & x \<le> b --> f(x) \<le> M) &
   707                    (\<forall>N. N < M --> (\<exists>x. a \<le> x & x \<le> b & N < f(x)))"
   708 apply (cut_tac S = "Collect (%y. \<exists>x. a \<le> x & x \<le> b & y = f x)"
   709         in lemma_reals_complete)
   710 apply auto
   711 apply (drule isCont_bounded, assumption)
   712 apply (auto simp add: isUb_def leastP_def isLub_def setge_def setle_def)
   713 apply (rule exI, auto)
   714 apply (auto dest!: spec simp add: linorder_not_less)
   715 done
   716 
   717 text{*Now show that it attains its upper bound*}
   718 
   719 lemma isCont_eq_Ub:
   720   assumes le: "a \<le> b"
   721       and con: "\<forall>x::real. a \<le> x & x \<le> b --> isCont f x"
   722   shows "\<exists>M::real. (\<forall>x. a \<le> x & x \<le> b --> f(x) \<le> M) &
   723              (\<exists>x. a \<le> x & x \<le> b & f(x) = M)"
   724 proof -
   725   from isCont_has_Ub [OF le con]
   726   obtain M where M1: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
   727              and M2: "!!N. N<M ==> \<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x"  by blast
   728   show ?thesis
   729   proof (intro exI, intro conjI)
   730     show " \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M" by (rule M1)
   731     show "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M"
   732     proof (rule ccontr)
   733       assume "\<not> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
   734       with M1 have M3: "\<forall>x. a \<le> x & x \<le> b --> f x < M"
   735         by (fastforce simp add: linorder_not_le [symmetric])
   736       hence "\<forall>x. a \<le> x & x \<le> b --> isCont (%x. inverse (M - f x)) x"
   737         by (auto simp add: con)
   738       from isCont_bounded [OF le this]
   739       obtain k where k: "!!x. a \<le> x & x \<le> b --> inverse (M - f x) \<le> k" by auto
   740       have Minv: "!!x. a \<le> x & x \<le> b --> 0 < inverse (M - f (x))"
   741         by (simp add: M3 algebra_simps)
   742       have "!!x. a \<le> x & x \<le> b --> inverse (M - f x) < k+1" using k
   743         by (auto intro: order_le_less_trans [of _ k])
   744       with Minv
   745       have "!!x. a \<le> x & x \<le> b --> inverse(k+1) < inverse(inverse(M - f x))"
   746         by (intro strip less_imp_inverse_less, simp_all)
   747       hence invlt: "!!x. a \<le> x & x \<le> b --> inverse(k+1) < M - f x"
   748         by simp
   749       have "M - inverse (k+1) < M" using k [of a] Minv [of a] le
   750         by (simp, arith)
   751       from M2 [OF this]
   752       obtain x where ax: "a \<le> x & x \<le> b & M - inverse(k+1) < f x" ..
   753       thus False using invlt [of x] by force
   754     qed
   755   qed
   756 qed
   757 
   758 
   759 text{*Same theorem for lower bound*}
   760 
   761 lemma isCont_eq_Lb: "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   762          ==> \<exists>M::real. (\<forall>x::real. a \<le> x & x \<le> b --> M \<le> f(x)) &
   763                    (\<exists>x. a \<le> x & x \<le> b & f(x) = M)"
   764 apply (subgoal_tac "\<forall>x. a \<le> x & x \<le> b --> isCont (%x. - (f x)) x")
   765 prefer 2 apply (blast intro: isCont_minus)
   766 apply (drule_tac f = "(%x. - (f x))" in isCont_eq_Ub)
   767 apply safe
   768 apply auto
   769 done
   770 
   771 
   772 text{*Another version.*}
   773 
   774 lemma isCont_Lb_Ub: "[|a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   775       ==> \<exists>L M::real. (\<forall>x::real. a \<le> x & x \<le> b --> L \<le> f(x) & f(x) \<le> M) &
   776           (\<forall>y. L \<le> y & y \<le> M --> (\<exists>x. a \<le> x & x \<le> b & (f(x) = y)))"
   777 apply (frule isCont_eq_Lb)
   778 apply (frule_tac [2] isCont_eq_Ub)
   779 apply (assumption+, safe)
   780 apply (rule_tac x = "f x" in exI)
   781 apply (rule_tac x = "f xa" in exI, simp, safe)
   782 apply (cut_tac x = x and y = xa in linorder_linear, safe)
   783 apply (cut_tac f = f and a = x and b = xa and y = y in IVT_objl)
   784 apply (cut_tac [2] f = f and a = xa and b = x and y = y in IVT2_objl, safe)
   785 apply (rule_tac [2] x = xb in exI)
   786 apply (rule_tac [4] x = xb in exI, simp_all)
   787 done
   788 
   789 
   790 subsection {* Local extrema *}
   791 
   792 text{*If @{term "0 < f'(x)"} then @{term x} is Locally Strictly Increasing At The Right*}
   793 
   794 lemma DERIV_pos_inc_right:
   795   fixes f :: "real => real"
   796   assumes der: "DERIV f x :> l"
   797       and l:   "0 < l"
   798   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x + h)"
   799 proof -
   800   from l der [THEN DERIV_D, THEN LIM_D [where r = "l"]]
   801   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l)"
   802     by (simp add: diff_minus)
   803   then obtain s
   804         where s:   "0 < s"
   805           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l"
   806     by auto
   807   thus ?thesis
   808   proof (intro exI conjI strip)
   809     show "0<s" using s .
   810     fix h::real
   811     assume "0 < h" "h < s"
   812     with all [of h] show "f x < f (x+h)"
   813     proof (simp add: abs_if pos_less_divide_eq diff_minus [symmetric]
   814     split add: split_if_asm)
   815       assume "~ (f (x+h) - f x) / h < l" and h: "0 < h"
   816       with l
   817       have "0 < (f (x+h) - f x) / h" by arith
   818       thus "f x < f (x+h)"
   819   by (simp add: pos_less_divide_eq h)
   820     qed
   821   qed
   822 qed
   823 
   824 lemma DERIV_neg_dec_left:
   825   fixes f :: "real => real"
   826   assumes der: "DERIV f x :> l"
   827       and l:   "l < 0"
   828   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x-h)"
   829 proof -
   830   from l der [THEN DERIV_D, THEN LIM_D [where r = "-l"]]
   831   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l)"
   832     by (simp add: diff_minus)
   833   then obtain s
   834         where s:   "0 < s"
   835           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l"
   836     by auto
   837   thus ?thesis
   838   proof (intro exI conjI strip)
   839     show "0<s" using s .
   840     fix h::real
   841     assume "0 < h" "h < s"
   842     with all [of "-h"] show "f x < f (x-h)"
   843     proof (simp add: abs_if pos_less_divide_eq diff_minus [symmetric]
   844     split add: split_if_asm)
   845       assume " - ((f (x-h) - f x) / h) < l" and h: "0 < h"
   846       with l
   847       have "0 < (f (x-h) - f x) / h" by arith
   848       thus "f x < f (x-h)"
   849   by (simp add: pos_less_divide_eq h)
   850     qed
   851   qed
   852 qed
   853 
   854 
   855 lemma DERIV_pos_inc_left:
   856   fixes f :: "real => real"
   857   shows "DERIV f x :> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x - h) < f(x)"
   858   apply (rule DERIV_neg_dec_left [of "%x. - f x" x "-l", simplified])
   859   apply (auto simp add: DERIV_minus)
   860   done
   861 
   862 lemma DERIV_neg_dec_right:
   863   fixes f :: "real => real"
   864   shows "DERIV f x :> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x) > f(x + h)"
   865   apply (rule DERIV_pos_inc_right [of "%x. - f x" x "-l", simplified])
   866   apply (auto simp add: DERIV_minus)
   867   done
   868 
   869 lemma DERIV_local_max:
   870   fixes f :: "real => real"
   871   assumes der: "DERIV f x :> l"
   872       and d:   "0 < d"
   873       and le:  "\<forall>y. \<bar>x-y\<bar> < d --> f(y) \<le> f(x)"
   874   shows "l = 0"
   875 proof (cases rule: linorder_cases [of l 0])
   876   case equal thus ?thesis .
   877 next
   878   case less
   879   from DERIV_neg_dec_left [OF der less]
   880   obtain d' where d': "0 < d'"
   881              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x-h)" by blast
   882   from real_lbound_gt_zero [OF d d']
   883   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
   884   with lt le [THEN spec [where x="x-e"]]
   885   show ?thesis by (auto simp add: abs_if)
   886 next
   887   case greater
   888   from DERIV_pos_inc_right [OF der greater]
   889   obtain d' where d': "0 < d'"
   890              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x + h)" by blast
   891   from real_lbound_gt_zero [OF d d']
   892   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
   893   with lt le [THEN spec [where x="x+e"]]
   894   show ?thesis by (auto simp add: abs_if)
   895 qed
   896 
   897 
   898 text{*Similar theorem for a local minimum*}
   899 lemma DERIV_local_min:
   900   fixes f :: "real => real"
   901   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) \<le> f(y) |] ==> l = 0"
   902 by (drule DERIV_minus [THEN DERIV_local_max], auto)
   903 
   904 
   905 text{*In particular, if a function is locally flat*}
   906 lemma DERIV_local_const:
   907   fixes f :: "real => real"
   908   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) = f(y) |] ==> l = 0"
   909 by (auto dest!: DERIV_local_max)
   910 
   911 
   912 subsection {* Rolle's Theorem *}
   913 
   914 text{*Lemma about introducing open ball in open interval*}
   915 lemma lemma_interval_lt:
   916      "[| a < x;  x < b |]
   917       ==> \<exists>d::real. 0 < d & (\<forall>y. \<bar>x-y\<bar> < d --> a < y & y < b)"
   918 
   919 apply (simp add: abs_less_iff)
   920 apply (insert linorder_linear [of "x-a" "b-x"], safe)
   921 apply (rule_tac x = "x-a" in exI)
   922 apply (rule_tac [2] x = "b-x" in exI, auto)
   923 done
   924 
   925 lemma lemma_interval: "[| a < x;  x < b |] ==>
   926         \<exists>d::real. 0 < d &  (\<forall>y. \<bar>x-y\<bar> < d --> a \<le> y & y \<le> b)"
   927 apply (drule lemma_interval_lt, auto)
   928 apply force
   929 done
   930 
   931 text{*Rolle's Theorem.
   932    If @{term f} is defined and continuous on the closed interval
   933    @{text "[a,b]"} and differentiable on the open interval @{text "(a,b)"},
   934    and @{term "f(a) = f(b)"},
   935    then there exists @{text "x0 \<in> (a,b)"} such that @{term "f'(x0) = 0"}*}
   936 theorem Rolle:
   937   assumes lt: "a < b"
   938       and eq: "f(a) = f(b)"
   939       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
   940       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable x"
   941   shows "\<exists>z::real. a < z & z < b & DERIV f z :> 0"
   942 proof -
   943   have le: "a \<le> b" using lt by simp
   944   from isCont_eq_Ub [OF le con]
   945   obtain x where x_max: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f z \<le> f x"
   946              and alex: "a \<le> x" and xleb: "x \<le> b"
   947     by blast
   948   from isCont_eq_Lb [OF le con]
   949   obtain x' where x'_min: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f x' \<le> f z"
   950               and alex': "a \<le> x'" and x'leb: "x' \<le> b"
   951     by blast
   952   show ?thesis
   953   proof cases
   954     assume axb: "a < x & x < b"
   955         --{*@{term f} attains its maximum within the interval*}
   956     hence ax: "a<x" and xb: "x<b" by arith + 
   957     from lemma_interval [OF ax xb]
   958     obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
   959       by blast
   960     hence bound': "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> f y \<le> f x" using x_max
   961       by blast
   962     from differentiableD [OF dif [OF axb]]
   963     obtain l where der: "DERIV f x :> l" ..
   964     have "l=0" by (rule DERIV_local_max [OF der d bound'])
   965         --{*the derivative at a local maximum is zero*}
   966     thus ?thesis using ax xb der by auto
   967   next
   968     assume notaxb: "~ (a < x & x < b)"
   969     hence xeqab: "x=a | x=b" using alex xleb by arith
   970     hence fb_eq_fx: "f b = f x" by (auto simp add: eq)
   971     show ?thesis
   972     proof cases
   973       assume ax'b: "a < x' & x' < b"
   974         --{*@{term f} attains its minimum within the interval*}
   975       hence ax': "a<x'" and x'b: "x'<b" by arith+ 
   976       from lemma_interval [OF ax' x'b]
   977       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
   978   by blast
   979       hence bound': "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> f x' \<le> f y" using x'_min
   980   by blast
   981       from differentiableD [OF dif [OF ax'b]]
   982       obtain l where der: "DERIV f x' :> l" ..
   983       have "l=0" by (rule DERIV_local_min [OF der d bound'])
   984         --{*the derivative at a local minimum is zero*}
   985       thus ?thesis using ax' x'b der by auto
   986     next
   987       assume notax'b: "~ (a < x' & x' < b)"
   988         --{*@{term f} is constant througout the interval*}
   989       hence x'eqab: "x'=a | x'=b" using alex' x'leb by arith
   990       hence fb_eq_fx': "f b = f x'" by (auto simp add: eq)
   991       from dense [OF lt]
   992       obtain r where ar: "a < r" and rb: "r < b" by blast
   993       from lemma_interval [OF ar rb]
   994       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
   995   by blast
   996       have eq_fb: "\<forall>z. a \<le> z --> z \<le> b --> f z = f b"
   997       proof (clarify)
   998         fix z::real
   999         assume az: "a \<le> z" and zb: "z \<le> b"
  1000         show "f z = f b"
  1001         proof (rule order_antisym)
  1002           show "f z \<le> f b" by (simp add: fb_eq_fx x_max az zb)
  1003           show "f b \<le> f z" by (simp add: fb_eq_fx' x'_min az zb)
  1004         qed
  1005       qed
  1006       have bound': "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> f r = f y"
  1007       proof (intro strip)
  1008         fix y::real
  1009         assume lt: "\<bar>r-y\<bar> < d"
  1010         hence "f y = f b" by (simp add: eq_fb bound)
  1011         thus "f r = f y" by (simp add: eq_fb ar rb order_less_imp_le)
  1012       qed
  1013       from differentiableD [OF dif [OF conjI [OF ar rb]]]
  1014       obtain l where der: "DERIV f r :> l" ..
  1015       have "l=0" by (rule DERIV_local_const [OF der d bound'])
  1016         --{*the derivative of a constant function is zero*}
  1017       thus ?thesis using ar rb der by auto
  1018     qed
  1019   qed
  1020 qed
  1021 
  1022 
  1023 subsection{*Mean Value Theorem*}
  1024 
  1025 lemma lemma_MVT:
  1026      "f a - (f b - f a)/(b-a) * a = f b - (f b - f a)/(b-a) * (b::real)"
  1027 proof cases
  1028   assume "a=b" thus ?thesis by simp
  1029 next
  1030   assume "a\<noteq>b"
  1031   hence ba: "b-a \<noteq> 0" by arith
  1032   show ?thesis
  1033     by (rule real_mult_left_cancel [OF ba, THEN iffD1],
  1034         simp add: right_diff_distrib,
  1035         simp add: left_diff_distrib)
  1036 qed
  1037 
  1038 theorem MVT:
  1039   assumes lt:  "a < b"
  1040       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
  1041       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable x"
  1042   shows "\<exists>l z::real. a < z & z < b & DERIV f z :> l &
  1043                    (f(b) - f(a) = (b-a) * l)"
  1044 proof -
  1045   let ?F = "%x. f x - ((f b - f a) / (b-a)) * x"
  1046   have contF: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?F x"
  1047     using con by (fast intro: isCont_intros)
  1048   have difF: "\<forall>x. a < x \<and> x < b \<longrightarrow> ?F differentiable x"
  1049   proof (clarify)
  1050     fix x::real
  1051     assume ax: "a < x" and xb: "x < b"
  1052     from differentiableD [OF dif [OF conjI [OF ax xb]]]
  1053     obtain l where der: "DERIV f x :> l" ..
  1054     show "?F differentiable x"
  1055       by (rule differentiableI [where D = "l - (f b - f a)/(b-a)"],
  1056           blast intro: DERIV_diff DERIV_cmult_Id der)
  1057   qed
  1058   from Rolle [where f = ?F, OF lt lemma_MVT contF difF]
  1059   obtain z where az: "a < z" and zb: "z < b" and der: "DERIV ?F z :> 0"
  1060     by blast
  1061   have "DERIV (%x. ((f b - f a)/(b-a)) * x) z :> (f b - f a)/(b-a)"
  1062     by (rule DERIV_cmult_Id)
  1063   hence derF: "DERIV (\<lambda>x. ?F x + (f b - f a) / (b - a) * x) z
  1064                    :> 0 + (f b - f a) / (b - a)"
  1065     by (rule DERIV_add [OF der])
  1066   show ?thesis
  1067   proof (intro exI conjI)
  1068     show "a < z" using az .
  1069     show "z < b" using zb .
  1070     show "f b - f a = (b - a) * ((f b - f a)/(b-a))" by (simp)
  1071     show "DERIV f z :> ((f b - f a)/(b-a))"  using derF by simp
  1072   qed
  1073 qed
  1074 
  1075 lemma MVT2:
  1076      "[| a < b; \<forall>x. a \<le> x & x \<le> b --> DERIV f x :> f'(x) |]
  1077       ==> \<exists>z::real. a < z & z < b & (f b - f a = (b - a) * f'(z))"
  1078 apply (drule MVT)
  1079 apply (blast intro: DERIV_isCont)
  1080 apply (force dest: order_less_imp_le simp add: differentiable_def)
  1081 apply (blast dest: DERIV_unique order_less_imp_le)
  1082 done
  1083 
  1084 
  1085 text{*A function is constant if its derivative is 0 over an interval.*}
  1086 
  1087 lemma DERIV_isconst_end:
  1088   fixes f :: "real => real"
  1089   shows "[| a < b;
  1090          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1091          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1092         ==> f b = f a"
  1093 apply (drule MVT, assumption)
  1094 apply (blast intro: differentiableI)
  1095 apply (auto dest!: DERIV_unique simp add: diff_eq_eq)
  1096 done
  1097 
  1098 lemma DERIV_isconst1:
  1099   fixes f :: "real => real"
  1100   shows "[| a < b;
  1101          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1102          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1103         ==> \<forall>x. a \<le> x & x \<le> b --> f x = f a"
  1104 apply safe
  1105 apply (drule_tac x = a in order_le_imp_less_or_eq, safe)
  1106 apply (drule_tac b = x in DERIV_isconst_end, auto)
  1107 done
  1108 
  1109 lemma DERIV_isconst2:
  1110   fixes f :: "real => real"
  1111   shows "[| a < b;
  1112          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1113          \<forall>x. a < x & x < b --> DERIV f x :> 0;
  1114          a \<le> x; x \<le> b |]
  1115         ==> f x = f a"
  1116 apply (blast dest: DERIV_isconst1)
  1117 done
  1118 
  1119 lemma DERIV_isconst3: fixes a b x y :: real
  1120   assumes "a < b" and "x \<in> {a <..< b}" and "y \<in> {a <..< b}"
  1121   assumes derivable: "\<And>x. x \<in> {a <..< b} \<Longrightarrow> DERIV f x :> 0"
  1122   shows "f x = f y"
  1123 proof (cases "x = y")
  1124   case False
  1125   let ?a = "min x y"
  1126   let ?b = "max x y"
  1127   
  1128   have "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> DERIV f z :> 0"
  1129   proof (rule allI, rule impI)
  1130     fix z :: real assume "?a \<le> z \<and> z \<le> ?b"
  1131     hence "a < z" and "z < b" using `x \<in> {a <..< b}` and `y \<in> {a <..< b}` by auto
  1132     hence "z \<in> {a<..<b}" by auto
  1133     thus "DERIV f z :> 0" by (rule derivable)
  1134   qed
  1135   hence isCont: "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> isCont f z"
  1136     and DERIV: "\<forall>z. ?a < z \<and> z < ?b \<longrightarrow> DERIV f z :> 0" using DERIV_isCont by auto
  1137 
  1138   have "?a < ?b" using `x \<noteq> y` by auto
  1139   from DERIV_isconst2[OF this isCont DERIV, of x] and DERIV_isconst2[OF this isCont DERIV, of y]
  1140   show ?thesis by auto
  1141 qed auto
  1142 
  1143 lemma DERIV_isconst_all:
  1144   fixes f :: "real => real"
  1145   shows "\<forall>x. DERIV f x :> 0 ==> f(x) = f(y)"
  1146 apply (rule linorder_cases [of x y])
  1147 apply (blast intro: sym DERIV_isCont DERIV_isconst_end)+
  1148 done
  1149 
  1150 lemma DERIV_const_ratio_const:
  1151   fixes f :: "real => real"
  1152   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a)) = (b-a) * k"
  1153 apply (rule linorder_cases [of a b], auto)
  1154 apply (drule_tac [!] f = f in MVT)
  1155 apply (auto dest: DERIV_isCont DERIV_unique simp add: differentiable_def)
  1156 apply (auto dest: DERIV_unique simp add: ring_distribs diff_minus)
  1157 done
  1158 
  1159 lemma DERIV_const_ratio_const2:
  1160   fixes f :: "real => real"
  1161   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a))/(b-a) = k"
  1162 apply (rule_tac c1 = "b-a" in real_mult_right_cancel [THEN iffD1])
  1163 apply (auto dest!: DERIV_const_ratio_const simp add: mult_assoc)
  1164 done
  1165 
  1166 lemma real_average_minus_first [simp]: "((a + b) /2 - a) = (b-a)/(2::real)"
  1167 by (simp)
  1168 
  1169 lemma real_average_minus_second [simp]: "((b + a)/2 - a) = (b-a)/(2::real)"
  1170 by (simp)
  1171 
  1172 text{*Gallileo's "trick": average velocity = av. of end velocities*}
  1173 
  1174 lemma DERIV_const_average:
  1175   fixes v :: "real => real"
  1176   assumes neq: "a \<noteq> (b::real)"
  1177       and der: "\<forall>x. DERIV v x :> k"
  1178   shows "v ((a + b)/2) = (v a + v b)/2"
  1179 proof (cases rule: linorder_cases [of a b])
  1180   case equal with neq show ?thesis by simp
  1181 next
  1182   case less
  1183   have "(v b - v a) / (b - a) = k"
  1184     by (rule DERIV_const_ratio_const2 [OF neq der])
  1185   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1186   moreover have "(v ((a + b) / 2) - v a) / ((a + b) / 2 - a) = k"
  1187     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1188   ultimately show ?thesis using neq by force
  1189 next
  1190   case greater
  1191   have "(v b - v a) / (b - a) = k"
  1192     by (rule DERIV_const_ratio_const2 [OF neq der])
  1193   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1194   moreover have " (v ((b + a) / 2) - v a) / ((b + a) / 2 - a) = k"
  1195     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1196   ultimately show ?thesis using neq by (force simp add: add_commute)
  1197 qed
  1198 
  1199 (* A function with positive derivative is increasing. 
  1200    A simple proof using the MVT, by Jeremy Avigad. And variants.
  1201 *)
  1202 lemma DERIV_pos_imp_increasing:
  1203   fixes a::real and b::real and f::"real => real"
  1204   assumes "a < b" and "\<forall>x. a \<le> x & x \<le> b --> (EX y. DERIV f x :> y & y > 0)"
  1205   shows "f a < f b"
  1206 proof (rule ccontr)
  1207   assume f: "~ f a < f b"
  1208   have "EX l z. a < z & z < b & DERIV f z :> l
  1209       & f b - f a = (b - a) * l"
  1210     apply (rule MVT)
  1211       using assms
  1212       apply auto
  1213       apply (metis DERIV_isCont)
  1214      apply (metis differentiableI less_le)
  1215     done
  1216   then obtain l z where z: "a < z" "z < b" "DERIV f z :> l"
  1217       and "f b - f a = (b - a) * l"
  1218     by auto
  1219   with assms f have "~(l > 0)"
  1220     by (metis linorder_not_le mult_le_0_iff diff_le_0_iff_le)
  1221   with assms z show False
  1222     by (metis DERIV_unique less_le)
  1223 qed
  1224 
  1225 lemma DERIV_nonneg_imp_nondecreasing:
  1226   fixes a::real and b::real and f::"real => real"
  1227   assumes "a \<le> b" and
  1228     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<ge> 0)"
  1229   shows "f a \<le> f b"
  1230 proof (rule ccontr, cases "a = b")
  1231   assume "~ f a \<le> f b" and "a = b"
  1232   then show False by auto
  1233 next
  1234   assume A: "~ f a \<le> f b"
  1235   assume B: "a ~= b"
  1236   with assms have "EX l z. a < z & z < b & DERIV f z :> l
  1237       & f b - f a = (b - a) * l"
  1238     apply -
  1239     apply (rule MVT)
  1240       apply auto
  1241       apply (metis DERIV_isCont)
  1242      apply (metis differentiableI less_le)
  1243     done
  1244   then obtain l z where z: "a < z" "z < b" "DERIV f z :> l"
  1245       and C: "f b - f a = (b - a) * l"
  1246     by auto
  1247   with A have "a < b" "f b < f a" by auto
  1248   with C have "\<not> l \<ge> 0" by (auto simp add: not_le algebra_simps)
  1249     (metis A add_le_cancel_right assms(1) less_eq_real_def mult_right_mono add_left_mono linear order_refl)
  1250   with assms z show False
  1251     by (metis DERIV_unique order_less_imp_le)
  1252 qed
  1253 
  1254 lemma DERIV_neg_imp_decreasing:
  1255   fixes a::real and b::real and f::"real => real"
  1256   assumes "a < b" and
  1257     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y < 0)"
  1258   shows "f a > f b"
  1259 proof -
  1260   have "(%x. -f x) a < (%x. -f x) b"
  1261     apply (rule DERIV_pos_imp_increasing [of a b "%x. -f x"])
  1262     using assms
  1263     apply auto
  1264     apply (metis DERIV_minus neg_0_less_iff_less)
  1265     done
  1266   thus ?thesis
  1267     by simp
  1268 qed
  1269 
  1270 lemma DERIV_nonpos_imp_nonincreasing:
  1271   fixes a::real and b::real and f::"real => real"
  1272   assumes "a \<le> b" and
  1273     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<le> 0)"
  1274   shows "f a \<ge> f b"
  1275 proof -
  1276   have "(%x. -f x) a \<le> (%x. -f x) b"
  1277     apply (rule DERIV_nonneg_imp_nondecreasing [of a b "%x. -f x"])
  1278     using assms
  1279     apply auto
  1280     apply (metis DERIV_minus neg_0_le_iff_le)
  1281     done
  1282   thus ?thesis
  1283     by simp
  1284 qed
  1285 
  1286 subsection {* Continuous injective functions *}
  1287 
  1288 text{*Dull lemma: an continuous injection on an interval must have a
  1289 strict maximum at an end point, not in the middle.*}
  1290 
  1291 lemma lemma_isCont_inj:
  1292   fixes f :: "real \<Rightarrow> real"
  1293   assumes d: "0 < d"
  1294       and inj [rule_format]: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1295       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1296   shows "\<exists>z. \<bar>z-x\<bar> \<le> d & f x < f z"
  1297 proof (rule ccontr)
  1298   assume  "~ (\<exists>z. \<bar>z-x\<bar> \<le> d & f x < f z)"
  1299   hence all [rule_format]: "\<forall>z. \<bar>z - x\<bar> \<le> d --> f z \<le> f x" by auto
  1300   show False
  1301   proof (cases rule: linorder_le_cases [of "f(x-d)" "f(x+d)"])
  1302     case le
  1303     from d cont all [of "x+d"]
  1304     have flef: "f(x+d) \<le> f x"
  1305      and xlex: "x - d \<le> x"
  1306      and cont': "\<forall>z. x - d \<le> z \<and> z \<le> x \<longrightarrow> isCont f z"
  1307        by (auto simp add: abs_if)
  1308     from IVT [OF le flef xlex cont']
  1309     obtain x' where "x-d \<le> x'" "x' \<le> x" "f x' = f(x+d)" by blast
  1310     moreover
  1311     hence "g(f x') = g (f(x+d))" by simp
  1312     ultimately show False using d inj [of x'] inj [of "x+d"]
  1313       by (simp add: abs_le_iff)
  1314   next
  1315     case ge
  1316     from d cont all [of "x-d"]
  1317     have flef: "f(x-d) \<le> f x"
  1318      and xlex: "x \<le> x+d"
  1319      and cont': "\<forall>z. x \<le> z \<and> z \<le> x+d \<longrightarrow> isCont f z"
  1320        by (auto simp add: abs_if)
  1321     from IVT2 [OF ge flef xlex cont']
  1322     obtain x' where "x \<le> x'" "x' \<le> x+d" "f x' = f(x-d)" by blast
  1323     moreover
  1324     hence "g(f x') = g (f(x-d))" by simp
  1325     ultimately show False using d inj [of x'] inj [of "x-d"]
  1326       by (simp add: abs_le_iff)
  1327   qed
  1328 qed
  1329 
  1330 
  1331 text{*Similar version for lower bound.*}
  1332 
  1333 lemma lemma_isCont_inj2:
  1334   fixes f g :: "real \<Rightarrow> real"
  1335   shows "[|0 < d; \<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z;
  1336         \<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z |]
  1337       ==> \<exists>z. \<bar>z-x\<bar> \<le> d & f z < f x"
  1338 apply (insert lemma_isCont_inj
  1339           [where f = "%x. - f x" and g = "%y. g(-y)" and x = x and d = d])
  1340 apply (simp add: linorder_not_le)
  1341 done
  1342 
  1343 text{*Show there's an interval surrounding @{term "f(x)"} in
  1344 @{text "f[[x - d, x + d]]"} .*}
  1345 
  1346 lemma isCont_inj_range:
  1347   fixes f :: "real \<Rightarrow> real"
  1348   assumes d: "0 < d"
  1349       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1350       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1351   shows "\<exists>e>0. \<forall>y. \<bar>y - f x\<bar> \<le> e --> (\<exists>z. \<bar>z-x\<bar> \<le> d & f z = y)"
  1352 proof -
  1353   have "x-d \<le> x+d" "\<forall>z. x-d \<le> z \<and> z \<le> x+d \<longrightarrow> isCont f z" using cont d
  1354     by (auto simp add: abs_le_iff)
  1355   from isCont_Lb_Ub [OF this]
  1356   obtain L M
  1357   where all1 [rule_format]: "\<forall>z. x-d \<le> z \<and> z \<le> x+d \<longrightarrow> L \<le> f z \<and> f z \<le> M"
  1358     and all2 [rule_format]:
  1359            "\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>z. x-d \<le> z \<and> z \<le> x+d \<and> f z = y)"
  1360     by auto
  1361   with d have "L \<le> f x & f x \<le> M" by simp
  1362   moreover have "L \<noteq> f x"
  1363   proof -
  1364     from lemma_isCont_inj2 [OF d inj cont]
  1365     obtain u where "\<bar>u - x\<bar> \<le> d" "f u < f x"  by auto
  1366     thus ?thesis using all1 [of u] by arith
  1367   qed
  1368   moreover have "f x \<noteq> M"
  1369   proof -
  1370     from lemma_isCont_inj [OF d inj cont]
  1371     obtain u where "\<bar>u - x\<bar> \<le> d" "f x < f u"  by auto
  1372     thus ?thesis using all1 [of u] by arith
  1373   qed
  1374   ultimately have "L < f x & f x < M" by arith
  1375   hence "0 < f x - L" "0 < M - f x" by arith+
  1376   from real_lbound_gt_zero [OF this]
  1377   obtain e where e: "0 < e" "e < f x - L" "e < M - f x" by auto
  1378   thus ?thesis
  1379   proof (intro exI conjI)
  1380     show "0<e" using e(1) .
  1381     show "\<forall>y. \<bar>y - f x\<bar> \<le> e \<longrightarrow> (\<exists>z. \<bar>z - x\<bar> \<le> d \<and> f z = y)"
  1382     proof (intro strip)
  1383       fix y::real
  1384       assume "\<bar>y - f x\<bar> \<le> e"
  1385       with e have "L \<le> y \<and> y \<le> M" by arith
  1386       from all2 [OF this]
  1387       obtain z where "x - d \<le> z" "z \<le> x + d" "f z = y" by blast
  1388       thus "\<exists>z. \<bar>z - x\<bar> \<le> d \<and> f z = y" 
  1389         by (force simp add: abs_le_iff)
  1390     qed
  1391   qed
  1392 qed
  1393 
  1394 
  1395 text{*Continuity of inverse function*}
  1396 
  1397 lemma isCont_inverse_function:
  1398   fixes f g :: "real \<Rightarrow> real"
  1399   assumes d: "0 < d"
  1400       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1401       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1402   shows "isCont g (f x)"
  1403 proof (simp add: isCont_iff LIM_eq)
  1404   show "\<forall>r. 0 < r \<longrightarrow>
  1405          (\<exists>s>0. \<forall>z. z\<noteq>0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>g(f x + z) - g(f x)\<bar> < r)"
  1406   proof (intro strip)
  1407     fix r::real
  1408     assume r: "0<r"
  1409     from real_lbound_gt_zero [OF r d]
  1410     obtain e where e: "0 < e" and e_lt: "e < r \<and> e < d" by blast
  1411     with inj cont
  1412     have e_simps: "\<forall>z. \<bar>z-x\<bar> \<le> e --> g (f z) = z"
  1413                   "\<forall>z. \<bar>z-x\<bar> \<le> e --> isCont f z"   by auto
  1414     from isCont_inj_range [OF e this]
  1415     obtain e' where e': "0 < e'"
  1416         and all: "\<forall>y. \<bar>y - f x\<bar> \<le> e' \<longrightarrow> (\<exists>z. \<bar>z - x\<bar> \<le> e \<and> f z = y)"
  1417           by blast
  1418     show "\<exists>s>0. \<forall>z. z\<noteq>0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>g(f x + z) - g(f x)\<bar> < r"
  1419     proof (intro exI conjI)
  1420       show "0<e'" using e' .
  1421       show "\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < e' \<longrightarrow> \<bar>g (f x + z) - g (f x)\<bar> < r"
  1422       proof (intro strip)
  1423         fix z::real
  1424         assume z: "z \<noteq> 0 \<and> \<bar>z\<bar> < e'"
  1425         with e e_lt e_simps all [rule_format, of "f x + z"]
  1426         show "\<bar>g (f x + z) - g (f x)\<bar> < r" by force
  1427       qed
  1428     qed
  1429   qed
  1430 qed
  1431 
  1432 text {* Derivative of inverse function *}
  1433 
  1434 lemma DERIV_inverse_function:
  1435   fixes f g :: "real \<Rightarrow> real"
  1436   assumes der: "DERIV f (g x) :> D"
  1437   assumes neq: "D \<noteq> 0"
  1438   assumes a: "a < x" and b: "x < b"
  1439   assumes inj: "\<forall>y. a < y \<and> y < b \<longrightarrow> f (g y) = y"
  1440   assumes cont: "isCont g x"
  1441   shows "DERIV g x :> inverse D"
  1442 unfolding DERIV_iff2
  1443 proof (rule LIM_equal2)
  1444   show "0 < min (x - a) (b - x)"
  1445     using a b by arith 
  1446 next
  1447   fix y
  1448   assume "norm (y - x) < min (x - a) (b - x)"
  1449   hence "a < y" and "y < b" 
  1450     by (simp_all add: abs_less_iff)
  1451   thus "(g y - g x) / (y - x) =
  1452         inverse ((f (g y) - x) / (g y - g x))"
  1453     by (simp add: inj)
  1454 next
  1455   have "(\<lambda>z. (f z - f (g x)) / (z - g x)) -- g x --> D"
  1456     by (rule der [unfolded DERIV_iff2])
  1457   hence 1: "(\<lambda>z. (f z - x) / (z - g x)) -- g x --> D"
  1458     using inj a b by simp
  1459   have 2: "\<exists>d>0. \<forall>y. y \<noteq> x \<and> norm (y - x) < d \<longrightarrow> g y \<noteq> g x"
  1460   proof (safe intro!: exI)
  1461     show "0 < min (x - a) (b - x)"
  1462       using a b by simp
  1463   next
  1464     fix y
  1465     assume "norm (y - x) < min (x - a) (b - x)"
  1466     hence y: "a < y" "y < b"
  1467       by (simp_all add: abs_less_iff)
  1468     assume "g y = g x"
  1469     hence "f (g y) = f (g x)" by simp
  1470     hence "y = x" using inj y a b by simp
  1471     also assume "y \<noteq> x"
  1472     finally show False by simp
  1473   qed
  1474   have "(\<lambda>y. (f (g y) - x) / (g y - g x)) -- x --> D"
  1475     using cont 1 2 by (rule isCont_LIM_compose2)
  1476   thus "(\<lambda>y. inverse ((f (g y) - x) / (g y - g x)))
  1477         -- x --> inverse D"
  1478     using neq by (rule tendsto_inverse)
  1479 qed
  1480 
  1481 
  1482 subsection {* Generalized Mean Value Theorem *}
  1483 
  1484 theorem GMVT:
  1485   fixes a b :: real
  1486   assumes alb: "a < b"
  1487     and fc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1488     and fd: "\<forall>x. a < x \<and> x < b \<longrightarrow> f differentiable x"
  1489     and gc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont g x"
  1490     and gd: "\<forall>x. a < x \<and> x < b \<longrightarrow> g differentiable x"
  1491   shows "\<exists>g'c f'c c. DERIV g c :> g'c \<and> DERIV f c :> f'c \<and> a < c \<and> c < b \<and> ((f b - f a) * g'c) = ((g b - g a) * f'c)"
  1492 proof -
  1493   let ?h = "\<lambda>x. (f b - f a)*(g x) - (g b - g a)*(f x)"
  1494   from assms have "a < b" by simp
  1495   moreover have "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?h x"
  1496     using fc gc by simp
  1497   moreover have "\<forall>x. a < x \<and> x < b \<longrightarrow> ?h differentiable x"
  1498     using fd gd by simp
  1499   ultimately have "\<exists>l z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" by (rule MVT)
  1500   then obtain l where ldef: "\<exists>z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1501   then obtain c where cdef: "a < c \<and> c < b \<and> DERIV ?h c :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1502 
  1503   from cdef have cint: "a < c \<and> c < b" by auto
  1504   with gd have "g differentiable c" by simp
  1505   hence "\<exists>D. DERIV g c :> D" by (rule differentiableD)
  1506   then obtain g'c where g'cdef: "DERIV g c :> g'c" ..
  1507 
  1508   from cdef have "a < c \<and> c < b" by auto
  1509   with fd have "f differentiable c" by simp
  1510   hence "\<exists>D. DERIV f c :> D" by (rule differentiableD)
  1511   then obtain f'c where f'cdef: "DERIV f c :> f'c" ..
  1512 
  1513   from cdef have "DERIV ?h c :> l" by auto
  1514   moreover have "DERIV ?h c :>  g'c * (f b - f a) - f'c * (g b - g a)"
  1515     using g'cdef f'cdef by (auto intro!: DERIV_intros)
  1516   ultimately have leq: "l =  g'c * (f b - f a) - f'c * (g b - g a)" by (rule DERIV_unique)
  1517 
  1518   {
  1519     from cdef have "?h b - ?h a = (b - a) * l" by auto
  1520     also with leq have "\<dots> = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1521     finally have "?h b - ?h a = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1522   }
  1523   moreover
  1524   {
  1525     have "?h b - ?h a =
  1526          ((f b)*(g b) - (f a)*(g b) - (g b)*(f b) + (g a)*(f b)) -
  1527           ((f b)*(g a) - (f a)*(g a) - (g b)*(f a) + (g a)*(f a))"
  1528       by (simp add: algebra_simps)
  1529     hence "?h b - ?h a = 0" by auto
  1530   }
  1531   ultimately have "(b - a) * (g'c * (f b - f a) - f'c * (g b - g a)) = 0" by auto
  1532   with alb have "g'c * (f b - f a) - f'c * (g b - g a) = 0" by simp
  1533   hence "g'c * (f b - f a) = f'c * (g b - g a)" by simp
  1534   hence "(f b - f a) * g'c = (g b - g a) * f'c" by (simp add: mult_ac)
  1535 
  1536   with g'cdef f'cdef cint show ?thesis by auto
  1537 qed
  1538 
  1539 
  1540 subsection {* Theorems about Limits *}
  1541 
  1542 (* need to rename second isCont_inverse *)
  1543 
  1544 lemma isCont_inv_fun:
  1545   fixes f g :: "real \<Rightarrow> real"
  1546   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1547          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1548       ==> isCont g (f x)"
  1549 by (rule isCont_inverse_function)
  1550 
  1551 lemma isCont_inv_fun_inv:
  1552   fixes f g :: "real \<Rightarrow> real"
  1553   shows "[| 0 < d;  
  1554          \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1555          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1556        ==> \<exists>e. 0 < e &  
  1557              (\<forall>y. 0 < \<bar>y - f(x)\<bar> & \<bar>y - f(x)\<bar> < e --> f(g(y)) = y)"
  1558 apply (drule isCont_inj_range)
  1559 prefer 2 apply (assumption, assumption, auto)
  1560 apply (rule_tac x = e in exI, auto)
  1561 apply (rotate_tac 2)
  1562 apply (drule_tac x = y in spec, auto)
  1563 done
  1564 
  1565 
  1566 text{*Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110*}
  1567 lemma LIM_fun_gt_zero:
  1568      "[| f -- c --> (l::real); 0 < l |]  
  1569          ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> 0 < f x)"
  1570 apply (drule (1) LIM_D, clarify)
  1571 apply (rule_tac x = s in exI)
  1572 apply (simp add: abs_less_iff)
  1573 done
  1574 
  1575 lemma LIM_fun_less_zero:
  1576      "[| f -- c --> (l::real); l < 0 |]  
  1577       ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> f x < 0)"
  1578 apply (drule LIM_D [where r="-l"], simp, clarify)
  1579 apply (rule_tac x = s in exI)
  1580 apply (simp add: abs_less_iff)
  1581 done
  1582 
  1583 lemma LIM_fun_not_zero:
  1584      "[| f -- c --> (l::real); l \<noteq> 0 |] 
  1585       ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> f x \<noteq> 0)"
  1586 apply (rule linorder_cases [of l 0])
  1587 apply (drule (1) LIM_fun_less_zero, force)
  1588 apply simp
  1589 apply (drule (1) LIM_fun_gt_zero, force)
  1590 done
  1591 
  1592 end