src/HOL/Library/Extended_Nat.thy
author huffman
Fri Mar 30 12:32:35 2012 +0200 (2012-03-30)
changeset 47220 52426c62b5d0
parent 47108 2a1953f0d20d
child 49834 b27bbb021df1
permissions -rw-r--r--
replace lemmas eval_nat_numeral with a simpler reformulation
     1 (*  Title:      HOL/Library/Extended_Nat.thy
     2     Author:     David von Oheimb, TU Muenchen;  Florian Haftmann, TU Muenchen
     3     Contributions: David Trachtenherz, TU Muenchen
     4 *)
     5 
     6 header {* Extended natural numbers (i.e. with infinity) *}
     7 
     8 theory Extended_Nat
     9 imports Main
    10 begin
    11 
    12 class infinity =
    13   fixes infinity :: "'a"
    14 
    15 notation (xsymbols)
    16   infinity  ("\<infinity>")
    17 
    18 notation (HTML output)
    19   infinity  ("\<infinity>")
    20 
    21 subsection {* Type definition *}
    22 
    23 text {*
    24   We extend the standard natural numbers by a special value indicating
    25   infinity.
    26 *}
    27 
    28 typedef (open) enat = "UNIV :: nat option set" ..
    29  
    30 definition enat :: "nat \<Rightarrow> enat" where
    31   "enat n = Abs_enat (Some n)"
    32  
    33 instantiation enat :: infinity
    34 begin
    35   definition "\<infinity> = Abs_enat None"
    36   instance proof qed
    37 end
    38  
    39 rep_datatype enat "\<infinity> :: enat"
    40 proof -
    41   fix P i assume "\<And>j. P (enat j)" "P \<infinity>"
    42   then show "P i"
    43   proof induct
    44     case (Abs_enat y) then show ?case
    45       by (cases y rule: option.exhaust)
    46          (auto simp: enat_def infinity_enat_def)
    47   qed
    48 qed (auto simp add: enat_def infinity_enat_def Abs_enat_inject)
    49 
    50 declare [[coercion "enat::nat\<Rightarrow>enat"]]
    51 
    52 lemmas enat2_cases = enat.exhaust[case_product enat.exhaust]
    53 lemmas enat3_cases = enat.exhaust[case_product enat.exhaust enat.exhaust]
    54 
    55 lemma not_infinity_eq [iff]: "(x \<noteq> \<infinity>) = (EX i. x = enat i)"
    56   by (cases x) auto
    57 
    58 lemma not_enat_eq [iff]: "(ALL y. x ~= enat y) = (x = \<infinity>)"
    59   by (cases x) auto
    60 
    61 primrec the_enat :: "enat \<Rightarrow> nat"
    62   where "the_enat (enat n) = n"
    63 
    64 
    65 subsection {* Constructors and numbers *}
    66 
    67 instantiation enat :: "{zero, one}"
    68 begin
    69 
    70 definition
    71   "0 = enat 0"
    72 
    73 definition
    74   "1 = enat 1"
    75 
    76 instance ..
    77 
    78 end
    79 
    80 definition eSuc :: "enat \<Rightarrow> enat" where
    81   "eSuc i = (case i of enat n \<Rightarrow> enat (Suc n) | \<infinity> \<Rightarrow> \<infinity>)"
    82 
    83 lemma enat_0 [code_post]: "enat 0 = 0"
    84   by (simp add: zero_enat_def)
    85 
    86 lemma enat_1 [code_post]: "enat 1 = 1"
    87   by (simp add: one_enat_def)
    88 
    89 lemma one_eSuc: "1 = eSuc 0"
    90   by (simp add: zero_enat_def one_enat_def eSuc_def)
    91 
    92 lemma infinity_ne_i0 [simp]: "(\<infinity>::enat) \<noteq> 0"
    93   by (simp add: zero_enat_def)
    94 
    95 lemma i0_ne_infinity [simp]: "0 \<noteq> (\<infinity>::enat)"
    96   by (simp add: zero_enat_def)
    97 
    98 lemma zero_one_enat_neq [simp]:
    99   "\<not> 0 = (1\<Colon>enat)"
   100   "\<not> 1 = (0\<Colon>enat)"
   101   unfolding zero_enat_def one_enat_def by simp_all
   102 
   103 lemma infinity_ne_i1 [simp]: "(\<infinity>::enat) \<noteq> 1"
   104   by (simp add: one_enat_def)
   105 
   106 lemma i1_ne_infinity [simp]: "1 \<noteq> (\<infinity>::enat)"
   107   by (simp add: one_enat_def)
   108 
   109 lemma eSuc_enat: "eSuc (enat n) = enat (Suc n)"
   110   by (simp add: eSuc_def)
   111 
   112 lemma eSuc_infinity [simp]: "eSuc \<infinity> = \<infinity>"
   113   by (simp add: eSuc_def)
   114 
   115 lemma eSuc_ne_0 [simp]: "eSuc n \<noteq> 0"
   116   by (simp add: eSuc_def zero_enat_def split: enat.splits)
   117 
   118 lemma zero_ne_eSuc [simp]: "0 \<noteq> eSuc n"
   119   by (rule eSuc_ne_0 [symmetric])
   120 
   121 lemma eSuc_inject [simp]: "eSuc m = eSuc n \<longleftrightarrow> m = n"
   122   by (simp add: eSuc_def split: enat.splits)
   123 
   124 subsection {* Addition *}
   125 
   126 instantiation enat :: comm_monoid_add
   127 begin
   128 
   129 definition [nitpick_simp]:
   130   "m + n = (case m of \<infinity> \<Rightarrow> \<infinity> | enat m \<Rightarrow> (case n of \<infinity> \<Rightarrow> \<infinity> | enat n \<Rightarrow> enat (m + n)))"
   131 
   132 lemma plus_enat_simps [simp, code]:
   133   fixes q :: enat
   134   shows "enat m + enat n = enat (m + n)"
   135     and "\<infinity> + q = \<infinity>"
   136     and "q + \<infinity> = \<infinity>"
   137   by (simp_all add: plus_enat_def split: enat.splits)
   138 
   139 instance proof
   140   fix n m q :: enat
   141   show "n + m + q = n + (m + q)"
   142     by (cases n m q rule: enat3_cases) auto
   143   show "n + m = m + n"
   144     by (cases n m rule: enat2_cases) auto
   145   show "0 + n = n"
   146     by (cases n) (simp_all add: zero_enat_def)
   147 qed
   148 
   149 end
   150 
   151 lemma eSuc_plus_1:
   152   "eSuc n = n + 1"
   153   by (cases n) (simp_all add: eSuc_enat one_enat_def)
   154   
   155 lemma plus_1_eSuc:
   156   "1 + q = eSuc q"
   157   "q + 1 = eSuc q"
   158   by (simp_all add: eSuc_plus_1 add_ac)
   159 
   160 lemma iadd_Suc: "eSuc m + n = eSuc (m + n)"
   161   by (simp_all add: eSuc_plus_1 add_ac)
   162 
   163 lemma iadd_Suc_right: "m + eSuc n = eSuc (m + n)"
   164   by (simp only: add_commute[of m] iadd_Suc)
   165 
   166 lemma iadd_is_0: "(m + n = (0::enat)) = (m = 0 \<and> n = 0)"
   167   by (cases m, cases n, simp_all add: zero_enat_def)
   168 
   169 subsection {* Multiplication *}
   170 
   171 instantiation enat :: comm_semiring_1
   172 begin
   173 
   174 definition times_enat_def [nitpick_simp]:
   175   "m * n = (case m of \<infinity> \<Rightarrow> if n = 0 then 0 else \<infinity> | enat m \<Rightarrow>
   176     (case n of \<infinity> \<Rightarrow> if m = 0 then 0 else \<infinity> | enat n \<Rightarrow> enat (m * n)))"
   177 
   178 lemma times_enat_simps [simp, code]:
   179   "enat m * enat n = enat (m * n)"
   180   "\<infinity> * \<infinity> = (\<infinity>::enat)"
   181   "\<infinity> * enat n = (if n = 0 then 0 else \<infinity>)"
   182   "enat m * \<infinity> = (if m = 0 then 0 else \<infinity>)"
   183   unfolding times_enat_def zero_enat_def
   184   by (simp_all split: enat.split)
   185 
   186 instance proof
   187   fix a b c :: enat
   188   show "(a * b) * c = a * (b * c)"
   189     unfolding times_enat_def zero_enat_def
   190     by (simp split: enat.split)
   191   show "a * b = b * a"
   192     unfolding times_enat_def zero_enat_def
   193     by (simp split: enat.split)
   194   show "1 * a = a"
   195     unfolding times_enat_def zero_enat_def one_enat_def
   196     by (simp split: enat.split)
   197   show "(a + b) * c = a * c + b * c"
   198     unfolding times_enat_def zero_enat_def
   199     by (simp split: enat.split add: left_distrib)
   200   show "0 * a = 0"
   201     unfolding times_enat_def zero_enat_def
   202     by (simp split: enat.split)
   203   show "a * 0 = 0"
   204     unfolding times_enat_def zero_enat_def
   205     by (simp split: enat.split)
   206   show "(0::enat) \<noteq> 1"
   207     unfolding zero_enat_def one_enat_def
   208     by simp
   209 qed
   210 
   211 end
   212 
   213 lemma mult_eSuc: "eSuc m * n = n + m * n"
   214   unfolding eSuc_plus_1 by (simp add: algebra_simps)
   215 
   216 lemma mult_eSuc_right: "m * eSuc n = m + m * n"
   217   unfolding eSuc_plus_1 by (simp add: algebra_simps)
   218 
   219 lemma of_nat_eq_enat: "of_nat n = enat n"
   220   apply (induct n)
   221   apply (simp add: enat_0)
   222   apply (simp add: plus_1_eSuc eSuc_enat)
   223   done
   224 
   225 instance enat :: semiring_char_0 proof
   226   have "inj enat" by (rule injI) simp
   227   then show "inj (\<lambda>n. of_nat n :: enat)" by (simp add: of_nat_eq_enat)
   228 qed
   229 
   230 lemma imult_is_0 [simp]: "((m::enat) * n = 0) = (m = 0 \<or> n = 0)"
   231   by (auto simp add: times_enat_def zero_enat_def split: enat.split)
   232 
   233 lemma imult_is_infinity: "((a::enat) * b = \<infinity>) = (a = \<infinity> \<and> b \<noteq> 0 \<or> b = \<infinity> \<and> a \<noteq> 0)"
   234   by (auto simp add: times_enat_def zero_enat_def split: enat.split)
   235 
   236 
   237 subsection {* Numerals *}
   238 
   239 lemma numeral_eq_enat:
   240   "numeral k = enat (numeral k)"
   241   using of_nat_eq_enat [of "numeral k"] by simp
   242 
   243 lemma enat_numeral [code_abbrev]:
   244   "enat (numeral k) = numeral k"
   245   using numeral_eq_enat ..
   246 
   247 lemma infinity_ne_numeral [simp]: "(\<infinity>::enat) \<noteq> numeral k"
   248   by (simp add: numeral_eq_enat)
   249 
   250 lemma numeral_ne_infinity [simp]: "numeral k \<noteq> (\<infinity>::enat)"
   251   by (simp add: numeral_eq_enat)
   252 
   253 lemma eSuc_numeral [simp]: "eSuc (numeral k) = numeral (k + Num.One)"
   254   by (simp only: eSuc_plus_1 numeral_plus_one)
   255 
   256 subsection {* Subtraction *}
   257 
   258 instantiation enat :: minus
   259 begin
   260 
   261 definition diff_enat_def:
   262 "a - b = (case a of (enat x) \<Rightarrow> (case b of (enat y) \<Rightarrow> enat (x - y) | \<infinity> \<Rightarrow> 0)
   263           | \<infinity> \<Rightarrow> \<infinity>)"
   264 
   265 instance ..
   266 
   267 end
   268 
   269 lemma idiff_enat_enat [simp, code]: "enat a - enat b = enat (a - b)"
   270   by (simp add: diff_enat_def)
   271 
   272 lemma idiff_infinity [simp, code]: "\<infinity> - n = (\<infinity>::enat)"
   273   by (simp add: diff_enat_def)
   274 
   275 lemma idiff_infinity_right [simp, code]: "enat a - \<infinity> = 0"
   276   by (simp add: diff_enat_def)
   277 
   278 lemma idiff_0 [simp]: "(0::enat) - n = 0"
   279   by (cases n, simp_all add: zero_enat_def)
   280 
   281 lemmas idiff_enat_0 [simp] = idiff_0 [unfolded zero_enat_def]
   282 
   283 lemma idiff_0_right [simp]: "(n::enat) - 0 = n"
   284   by (cases n) (simp_all add: zero_enat_def)
   285 
   286 lemmas idiff_enat_0_right [simp] = idiff_0_right [unfolded zero_enat_def]
   287 
   288 lemma idiff_self [simp]: "n \<noteq> \<infinity> \<Longrightarrow> (n::enat) - n = 0"
   289   by (auto simp: zero_enat_def)
   290 
   291 lemma eSuc_minus_eSuc [simp]: "eSuc n - eSuc m = n - m"
   292   by (simp add: eSuc_def split: enat.split)
   293 
   294 lemma eSuc_minus_1 [simp]: "eSuc n - 1 = n"
   295   by (simp add: one_enat_def eSuc_enat[symmetric] zero_enat_def[symmetric])
   296 
   297 (*lemmas idiff_self_eq_0_enat = idiff_self_eq_0[unfolded zero_enat_def]*)
   298 
   299 subsection {* Ordering *}
   300 
   301 instantiation enat :: linordered_ab_semigroup_add
   302 begin
   303 
   304 definition [nitpick_simp]:
   305   "m \<le> n = (case n of enat n1 \<Rightarrow> (case m of enat m1 \<Rightarrow> m1 \<le> n1 | \<infinity> \<Rightarrow> False)
   306     | \<infinity> \<Rightarrow> True)"
   307 
   308 definition [nitpick_simp]:
   309   "m < n = (case m of enat m1 \<Rightarrow> (case n of enat n1 \<Rightarrow> m1 < n1 | \<infinity> \<Rightarrow> True)
   310     | \<infinity> \<Rightarrow> False)"
   311 
   312 lemma enat_ord_simps [simp]:
   313   "enat m \<le> enat n \<longleftrightarrow> m \<le> n"
   314   "enat m < enat n \<longleftrightarrow> m < n"
   315   "q \<le> (\<infinity>::enat)"
   316   "q < (\<infinity>::enat) \<longleftrightarrow> q \<noteq> \<infinity>"
   317   "(\<infinity>::enat) \<le> q \<longleftrightarrow> q = \<infinity>"
   318   "(\<infinity>::enat) < q \<longleftrightarrow> False"
   319   by (simp_all add: less_eq_enat_def less_enat_def split: enat.splits)
   320 
   321 lemma numeral_le_enat_iff[simp]:
   322   shows "numeral m \<le> enat n \<longleftrightarrow> numeral m \<le> n"
   323 by (auto simp: numeral_eq_enat)
   324 
   325 lemma numeral_less_enat_iff[simp]:
   326   shows "numeral m < enat n \<longleftrightarrow> numeral m < n"
   327 by (auto simp: numeral_eq_enat)
   328 
   329 lemma enat_ord_code [code]:
   330   "enat m \<le> enat n \<longleftrightarrow> m \<le> n"
   331   "enat m < enat n \<longleftrightarrow> m < n"
   332   "q \<le> (\<infinity>::enat) \<longleftrightarrow> True"
   333   "enat m < \<infinity> \<longleftrightarrow> True"
   334   "\<infinity> \<le> enat n \<longleftrightarrow> False"
   335   "(\<infinity>::enat) < q \<longleftrightarrow> False"
   336   by simp_all
   337 
   338 instance by default
   339   (auto simp add: less_eq_enat_def less_enat_def plus_enat_def split: enat.splits)
   340 
   341 end
   342 
   343 instance enat :: ordered_comm_semiring
   344 proof
   345   fix a b c :: enat
   346   assume "a \<le> b" and "0 \<le> c"
   347   thus "c * a \<le> c * b"
   348     unfolding times_enat_def less_eq_enat_def zero_enat_def
   349     by (simp split: enat.splits)
   350 qed
   351 
   352 (* BH: These equations are already proven generally for any type in
   353 class linordered_semidom. However, enat is not in that class because
   354 it does not have the cancellation property. Would it be worthwhile to
   355 a generalize linordered_semidom to a new class that includes enat? *)
   356 
   357 lemma enat_ord_number [simp]:
   358   "(numeral m \<Colon> enat) \<le> numeral n \<longleftrightarrow> (numeral m \<Colon> nat) \<le> numeral n"
   359   "(numeral m \<Colon> enat) < numeral n \<longleftrightarrow> (numeral m \<Colon> nat) < numeral n"
   360   by (simp_all add: numeral_eq_enat)
   361 
   362 lemma i0_lb [simp]: "(0\<Colon>enat) \<le> n"
   363   by (simp add: zero_enat_def less_eq_enat_def split: enat.splits)
   364 
   365 lemma ile0_eq [simp]: "n \<le> (0\<Colon>enat) \<longleftrightarrow> n = 0"
   366   by (simp add: zero_enat_def less_eq_enat_def split: enat.splits)
   367 
   368 lemma infinity_ileE [elim!]: "\<infinity> \<le> enat m \<Longrightarrow> R"
   369   by (simp add: zero_enat_def less_eq_enat_def split: enat.splits)
   370 
   371 lemma infinity_ilessE [elim!]: "\<infinity> < enat m \<Longrightarrow> R"
   372   by simp
   373 
   374 lemma not_iless0 [simp]: "\<not> n < (0\<Colon>enat)"
   375   by (simp add: zero_enat_def less_enat_def split: enat.splits)
   376 
   377 lemma i0_less [simp]: "(0\<Colon>enat) < n \<longleftrightarrow> n \<noteq> 0"
   378   by (simp add: zero_enat_def less_enat_def split: enat.splits)
   379 
   380 lemma eSuc_ile_mono [simp]: "eSuc n \<le> eSuc m \<longleftrightarrow> n \<le> m"
   381   by (simp add: eSuc_def less_eq_enat_def split: enat.splits)
   382  
   383 lemma eSuc_mono [simp]: "eSuc n < eSuc m \<longleftrightarrow> n < m"
   384   by (simp add: eSuc_def less_enat_def split: enat.splits)
   385 
   386 lemma ile_eSuc [simp]: "n \<le> eSuc n"
   387   by (simp add: eSuc_def less_eq_enat_def split: enat.splits)
   388 
   389 lemma not_eSuc_ilei0 [simp]: "\<not> eSuc n \<le> 0"
   390   by (simp add: zero_enat_def eSuc_def less_eq_enat_def split: enat.splits)
   391 
   392 lemma i0_iless_eSuc [simp]: "0 < eSuc n"
   393   by (simp add: zero_enat_def eSuc_def less_enat_def split: enat.splits)
   394 
   395 lemma iless_eSuc0[simp]: "(n < eSuc 0) = (n = 0)"
   396   by (simp add: zero_enat_def eSuc_def less_enat_def split: enat.split)
   397 
   398 lemma ileI1: "m < n \<Longrightarrow> eSuc m \<le> n"
   399   by (simp add: eSuc_def less_eq_enat_def less_enat_def split: enat.splits)
   400 
   401 lemma Suc_ile_eq: "enat (Suc m) \<le> n \<longleftrightarrow> enat m < n"
   402   by (cases n) auto
   403 
   404 lemma iless_Suc_eq [simp]: "enat m < eSuc n \<longleftrightarrow> enat m \<le> n"
   405   by (auto simp add: eSuc_def less_enat_def split: enat.splits)
   406 
   407 lemma imult_infinity: "(0::enat) < n \<Longrightarrow> \<infinity> * n = \<infinity>"
   408   by (simp add: zero_enat_def less_enat_def split: enat.splits)
   409 
   410 lemma imult_infinity_right: "(0::enat) < n \<Longrightarrow> n * \<infinity> = \<infinity>"
   411   by (simp add: zero_enat_def less_enat_def split: enat.splits)
   412 
   413 lemma enat_0_less_mult_iff: "(0 < (m::enat) * n) = (0 < m \<and> 0 < n)"
   414   by (simp only: i0_less imult_is_0, simp)
   415 
   416 lemma mono_eSuc: "mono eSuc"
   417   by (simp add: mono_def)
   418 
   419 
   420 lemma min_enat_simps [simp]:
   421   "min (enat m) (enat n) = enat (min m n)"
   422   "min q 0 = 0"
   423   "min 0 q = 0"
   424   "min q (\<infinity>::enat) = q"
   425   "min (\<infinity>::enat) q = q"
   426   by (auto simp add: min_def)
   427 
   428 lemma max_enat_simps [simp]:
   429   "max (enat m) (enat n) = enat (max m n)"
   430   "max q 0 = q"
   431   "max 0 q = q"
   432   "max q \<infinity> = (\<infinity>::enat)"
   433   "max \<infinity> q = (\<infinity>::enat)"
   434   by (simp_all add: max_def)
   435 
   436 lemma enat_ile: "n \<le> enat m \<Longrightarrow> \<exists>k. n = enat k"
   437   by (cases n) simp_all
   438 
   439 lemma enat_iless: "n < enat m \<Longrightarrow> \<exists>k. n = enat k"
   440   by (cases n) simp_all
   441 
   442 lemma chain_incr: "\<forall>i. \<exists>j. Y i < Y j ==> \<exists>j. enat k < Y j"
   443 apply (induct_tac k)
   444  apply (simp (no_asm) only: enat_0)
   445  apply (fast intro: le_less_trans [OF i0_lb])
   446 apply (erule exE)
   447 apply (drule spec)
   448 apply (erule exE)
   449 apply (drule ileI1)
   450 apply (rule eSuc_enat [THEN subst])
   451 apply (rule exI)
   452 apply (erule (1) le_less_trans)
   453 done
   454 
   455 instantiation enat :: "{bot, top}"
   456 begin
   457 
   458 definition bot_enat :: enat where
   459   "bot_enat = 0"
   460 
   461 definition top_enat :: enat where
   462   "top_enat = \<infinity>"
   463 
   464 instance proof
   465 qed (simp_all add: bot_enat_def top_enat_def)
   466 
   467 end
   468 
   469 lemma finite_enat_bounded:
   470   assumes le_fin: "\<And>y. y \<in> A \<Longrightarrow> y \<le> enat n"
   471   shows "finite A"
   472 proof (rule finite_subset)
   473   show "finite (enat ` {..n})" by blast
   474 
   475   have "A \<subseteq> {..enat n}" using le_fin by fastforce
   476   also have "\<dots> \<subseteq> enat ` {..n}"
   477     by (rule subsetI) (case_tac x, auto)
   478   finally show "A \<subseteq> enat ` {..n}" .
   479 qed
   480 
   481 
   482 subsection {* Cancellation simprocs *}
   483 
   484 lemma enat_add_left_cancel: "a + b = a + c \<longleftrightarrow> a = (\<infinity>::enat) \<or> b = c"
   485   unfolding plus_enat_def by (simp split: enat.split)
   486 
   487 lemma enat_add_left_cancel_le: "a + b \<le> a + c \<longleftrightarrow> a = (\<infinity>::enat) \<or> b \<le> c"
   488   unfolding plus_enat_def by (simp split: enat.split)
   489 
   490 lemma enat_add_left_cancel_less: "a + b < a + c \<longleftrightarrow> a \<noteq> (\<infinity>::enat) \<and> b < c"
   491   unfolding plus_enat_def by (simp split: enat.split)
   492 
   493 ML {*
   494 structure Cancel_Enat_Common =
   495 struct
   496   (* copied from src/HOL/Tools/nat_numeral_simprocs.ML *)
   497   fun find_first_t _    _ []         = raise TERM("find_first_t", [])
   498     | find_first_t past u (t::terms) =
   499           if u aconv t then (rev past @ terms)
   500           else find_first_t (t::past) u terms
   501 
   502   val mk_sum = Arith_Data.long_mk_sum
   503   val dest_sum = Arith_Data.dest_sum
   504   val find_first = find_first_t []
   505   val trans_tac = Numeral_Simprocs.trans_tac
   506   val norm_ss = HOL_basic_ss addsimps
   507     @{thms add_ac add_0_left add_0_right}
   508   fun norm_tac ss = ALLGOALS (simp_tac (Simplifier.inherit_context ss norm_ss))
   509   fun simplify_meta_eq ss cancel_th th =
   510     Arith_Data.simplify_meta_eq [] ss
   511       ([th, cancel_th] MRS trans)
   512   fun mk_eq (a, b) = HOLogic.mk_Trueprop (HOLogic.mk_eq (a, b))
   513 end
   514 
   515 structure Eq_Enat_Cancel = ExtractCommonTermFun
   516 (open Cancel_Enat_Common
   517   val mk_bal = HOLogic.mk_eq
   518   val dest_bal = HOLogic.dest_bin @{const_name HOL.eq} @{typ enat}
   519   fun simp_conv _ _ = SOME @{thm enat_add_left_cancel}
   520 )
   521 
   522 structure Le_Enat_Cancel = ExtractCommonTermFun
   523 (open Cancel_Enat_Common
   524   val mk_bal = HOLogic.mk_binrel @{const_name Orderings.less_eq}
   525   val dest_bal = HOLogic.dest_bin @{const_name Orderings.less_eq} @{typ enat}
   526   fun simp_conv _ _ = SOME @{thm enat_add_left_cancel_le}
   527 )
   528 
   529 structure Less_Enat_Cancel = ExtractCommonTermFun
   530 (open Cancel_Enat_Common
   531   val mk_bal = HOLogic.mk_binrel @{const_name Orderings.less}
   532   val dest_bal = HOLogic.dest_bin @{const_name Orderings.less} @{typ enat}
   533   fun simp_conv _ _ = SOME @{thm enat_add_left_cancel_less}
   534 )
   535 *}
   536 
   537 simproc_setup enat_eq_cancel
   538   ("(l::enat) + m = n" | "(l::enat) = m + n") =
   539   {* fn phi => fn ss => fn ct => Eq_Enat_Cancel.proc ss (term_of ct) *}
   540 
   541 simproc_setup enat_le_cancel
   542   ("(l::enat) + m \<le> n" | "(l::enat) \<le> m + n") =
   543   {* fn phi => fn ss => fn ct => Le_Enat_Cancel.proc ss (term_of ct) *}
   544 
   545 simproc_setup enat_less_cancel
   546   ("(l::enat) + m < n" | "(l::enat) < m + n") =
   547   {* fn phi => fn ss => fn ct => Less_Enat_Cancel.proc ss (term_of ct) *}
   548 
   549 text {* TODO: add regression tests for these simprocs *}
   550 
   551 text {* TODO: add simprocs for combining and cancelling numerals *}
   552 
   553 
   554 subsection {* Well-ordering *}
   555 
   556 lemma less_enatE:
   557   "[| n < enat m; !!k. n = enat k ==> k < m ==> P |] ==> P"
   558 by (induct n) auto
   559 
   560 lemma less_infinityE:
   561   "[| n < \<infinity>; !!k. n = enat k ==> P |] ==> P"
   562 by (induct n) auto
   563 
   564 lemma enat_less_induct:
   565   assumes prem: "!!n. \<forall>m::enat. m < n --> P m ==> P n" shows "P n"
   566 proof -
   567   have P_enat: "!!k. P (enat k)"
   568     apply (rule nat_less_induct)
   569     apply (rule prem, clarify)
   570     apply (erule less_enatE, simp)
   571     done
   572   show ?thesis
   573   proof (induct n)
   574     fix nat
   575     show "P (enat nat)" by (rule P_enat)
   576   next
   577     show "P \<infinity>"
   578       apply (rule prem, clarify)
   579       apply (erule less_infinityE)
   580       apply (simp add: P_enat)
   581       done
   582   qed
   583 qed
   584 
   585 instance enat :: wellorder
   586 proof
   587   fix P and n
   588   assume hyp: "(\<And>n\<Colon>enat. (\<And>m\<Colon>enat. m < n \<Longrightarrow> P m) \<Longrightarrow> P n)"
   589   show "P n" by (blast intro: enat_less_induct hyp)
   590 qed
   591 
   592 subsection {* Complete Lattice *}
   593 
   594 instantiation enat :: complete_lattice
   595 begin
   596 
   597 definition inf_enat :: "enat \<Rightarrow> enat \<Rightarrow> enat" where
   598   "inf_enat \<equiv> min"
   599 
   600 definition sup_enat :: "enat \<Rightarrow> enat \<Rightarrow> enat" where
   601   "sup_enat \<equiv> max"
   602 
   603 definition Inf_enat :: "enat set \<Rightarrow> enat" where
   604   "Inf_enat A \<equiv> if A = {} then \<infinity> else (LEAST x. x \<in> A)"
   605 
   606 definition Sup_enat :: "enat set \<Rightarrow> enat" where
   607   "Sup_enat A \<equiv> if A = {} then 0
   608     else if finite A then Max A
   609                      else \<infinity>"
   610 instance proof
   611   fix x :: "enat" and A :: "enat set"
   612   { assume "x \<in> A" then show "Inf A \<le> x"
   613       unfolding Inf_enat_def by (auto intro: Least_le) }
   614   { assume "\<And>y. y \<in> A \<Longrightarrow> x \<le> y" then show "x \<le> Inf A"
   615       unfolding Inf_enat_def
   616       by (cases "A = {}") (auto intro: LeastI2_ex) }
   617   { assume "x \<in> A" then show "x \<le> Sup A"
   618       unfolding Sup_enat_def by (cases "finite A") auto }
   619   { assume "\<And>y. y \<in> A \<Longrightarrow> y \<le> x" then show "Sup A \<le> x"
   620       unfolding Sup_enat_def using finite_enat_bounded by auto }
   621 qed (simp_all add: inf_enat_def sup_enat_def)
   622 end
   623 
   624 instance enat :: complete_linorder ..
   625 
   626 subsection {* Traditional theorem names *}
   627 
   628 lemmas enat_defs = zero_enat_def one_enat_def eSuc_def
   629   plus_enat_def less_eq_enat_def less_enat_def
   630 
   631 end