src/HOL/Nat.thy
author huffman
Fri Mar 30 12:32:35 2012 +0200 (2012-03-30)
changeset 47220 52426c62b5d0
parent 47208 9a91b163bb71
child 47255 30a1692557b0
permissions -rw-r--r--
replace lemmas eval_nat_numeral with a simpler reformulation
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 uses
    13   "~~/src/Tools/rat.ML"
    14   "~~/src/Provers/Arith/cancel_sums.ML"
    15   "Tools/arith_data.ML"
    16   ("Tools/nat_arith.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    26   -- {* the axiom of infinity in 2 parts *}
    27   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    28   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    29 
    30 subsection {* Type nat *}
    31 
    32 text {* Type definition *}
    33 
    34 inductive Nat :: "ind \<Rightarrow> bool" where
    35   Zero_RepI: "Nat Zero_Rep"
    36 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    37 
    38 typedef (open) nat = "{n. Nat n}"
    39   morphisms Rep_Nat Abs_Nat
    40   using Nat.Zero_RepI by auto
    41 
    42 lemma Nat_Rep_Nat:
    43   "Nat (Rep_Nat n)"
    44   using Rep_Nat by simp
    45 
    46 lemma Nat_Abs_Nat_inverse:
    47   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    48   using Abs_Nat_inverse by simp
    49 
    50 lemma Nat_Abs_Nat_inject:
    51   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    52   using Abs_Nat_inject by simp
    53 
    54 instantiation nat :: zero
    55 begin
    56 
    57 definition Zero_nat_def:
    58   "0 = Abs_Nat Zero_Rep"
    59 
    60 instance ..
    61 
    62 end
    63 
    64 definition Suc :: "nat \<Rightarrow> nat" where
    65   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    66 
    67 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    68   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    69 
    70 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    71   by (rule not_sym, rule Suc_not_Zero not_sym)
    72 
    73 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    74   by (rule iffI, rule Suc_Rep_inject) simp_all
    75 
    76 rep_datatype "0 \<Colon> nat" Suc
    77   apply (unfold Zero_nat_def Suc_def)
    78   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    79    apply (erule Nat_Rep_Nat [THEN Nat.induct])
    80    apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    81     apply (simp_all add: Nat_Abs_Nat_inject Nat_Rep_Nat
    82       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep
    83       Suc_Rep_not_Zero_Rep [symmetric]
    84       Suc_Rep_inject' Rep_Nat_inject)
    85   done
    86 
    87 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    88   -- {* for backward compatibility -- names of variables differ *}
    89   fixes n
    90   assumes "P 0"
    91     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    92   shows "P n"
    93   using assms by (rule nat.induct)
    94 
    95 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    96 
    97 lemmas nat_rec_0 = nat.recs(1)
    98   and nat_rec_Suc = nat.recs(2)
    99 
   100 lemmas nat_case_0 = nat.cases(1)
   101   and nat_case_Suc = nat.cases(2)
   102    
   103 
   104 text {* Injectiveness and distinctness lemmas *}
   105 
   106 lemma inj_Suc[simp]: "inj_on Suc N"
   107   by (simp add: inj_on_def)
   108 
   109 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   110 by (rule notE, rule Suc_not_Zero)
   111 
   112 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   113 by (rule Suc_neq_Zero, erule sym)
   114 
   115 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   116 by (rule inj_Suc [THEN injD])
   117 
   118 lemma n_not_Suc_n: "n \<noteq> Suc n"
   119 by (induct n) simp_all
   120 
   121 lemma Suc_n_not_n: "Suc n \<noteq> n"
   122 by (rule not_sym, rule n_not_Suc_n)
   123 
   124 text {* A special form of induction for reasoning
   125   about @{term "m < n"} and @{term "m - n"} *}
   126 
   127 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   128     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   129   apply (rule_tac x = m in spec)
   130   apply (induct n)
   131   prefer 2
   132   apply (rule allI)
   133   apply (induct_tac x, iprover+)
   134   done
   135 
   136 
   137 subsection {* Arithmetic operators *}
   138 
   139 instantiation nat :: "{minus, comm_monoid_add}"
   140 begin
   141 
   142 primrec plus_nat where
   143   add_0:      "0 + n = (n\<Colon>nat)"
   144 | add_Suc:  "Suc m + n = Suc (m + n)"
   145 
   146 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   147   by (induct m) simp_all
   148 
   149 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   150   by (induct m) simp_all
   151 
   152 declare add_0 [code]
   153 
   154 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   155   by simp
   156 
   157 primrec minus_nat where
   158   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   159 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   160 
   161 declare diff_Suc [simp del]
   162 
   163 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   164   by (induct n) (simp_all add: diff_Suc)
   165 
   166 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   167   by (induct n) (simp_all add: diff_Suc)
   168 
   169 instance proof
   170   fix n m q :: nat
   171   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   172   show "n + m = m + n" by (induct n) simp_all
   173   show "0 + n = n" by simp
   174 qed
   175 
   176 end
   177 
   178 hide_fact (open) add_0 add_0_right diff_0
   179 
   180 instantiation nat :: comm_semiring_1_cancel
   181 begin
   182 
   183 definition
   184   One_nat_def [simp]: "1 = Suc 0"
   185 
   186 primrec times_nat where
   187   mult_0:     "0 * n = (0\<Colon>nat)"
   188 | mult_Suc: "Suc m * n = n + (m * n)"
   189 
   190 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   191   by (induct m) simp_all
   192 
   193 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   194   by (induct m) (simp_all add: add_left_commute)
   195 
   196 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   197   by (induct m) (simp_all add: add_assoc)
   198 
   199 instance proof
   200   fix n m q :: nat
   201   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   202   show "1 * n = n" unfolding One_nat_def by simp
   203   show "n * m = m * n" by (induct n) simp_all
   204   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   205   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   206   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   207 qed
   208 
   209 end
   210 
   211 subsubsection {* Addition *}
   212 
   213 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   214   by (rule add_assoc)
   215 
   216 lemma nat_add_commute: "m + n = n + (m::nat)"
   217   by (rule add_commute)
   218 
   219 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   220   by (rule add_left_commute)
   221 
   222 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   223   by (rule add_left_cancel)
   224 
   225 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   226   by (rule add_right_cancel)
   227 
   228 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   229 
   230 lemma add_is_0 [iff]:
   231   fixes m n :: nat
   232   shows "(m + n = 0) = (m = 0 & n = 0)"
   233   by (cases m) simp_all
   234 
   235 lemma add_is_1:
   236   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   237   by (cases m) simp_all
   238 
   239 lemma one_is_add:
   240   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   241   by (rule trans, rule eq_commute, rule add_is_1)
   242 
   243 lemma add_eq_self_zero:
   244   fixes m n :: nat
   245   shows "m + n = m \<Longrightarrow> n = 0"
   246   by (induct m) simp_all
   247 
   248 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   249   apply (induct k)
   250    apply simp
   251   apply(drule comp_inj_on[OF _ inj_Suc])
   252   apply (simp add:o_def)
   253   done
   254 
   255 lemma Suc_eq_plus1: "Suc n = n + 1"
   256   unfolding One_nat_def by simp
   257 
   258 lemma Suc_eq_plus1_left: "Suc n = 1 + n"
   259   unfolding One_nat_def by simp
   260 
   261 
   262 subsubsection {* Difference *}
   263 
   264 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   265   by (induct m) simp_all
   266 
   267 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   268   by (induct i j rule: diff_induct) simp_all
   269 
   270 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   271   by (simp add: diff_diff_left)
   272 
   273 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   274   by (simp add: diff_diff_left add_commute)
   275 
   276 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   277   by (induct n) simp_all
   278 
   279 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   280   by (simp add: diff_add_inverse add_commute [of m n])
   281 
   282 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   283   by (induct k) simp_all
   284 
   285 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   286   by (simp add: diff_cancel add_commute)
   287 
   288 lemma diff_add_0: "n - (n + m) = (0::nat)"
   289   by (induct n) simp_all
   290 
   291 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   292   unfolding One_nat_def by simp
   293 
   294 text {* Difference distributes over multiplication *}
   295 
   296 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   297 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   298 
   299 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   300 by (simp add: diff_mult_distrib mult_commute [of k])
   301   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   302 
   303 
   304 subsubsection {* Multiplication *}
   305 
   306 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   307   by (rule mult_assoc)
   308 
   309 lemma nat_mult_commute: "m * n = n * (m::nat)"
   310   by (rule mult_commute)
   311 
   312 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   313   by (rule right_distrib)
   314 
   315 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   316   by (induct m) auto
   317 
   318 lemmas nat_distrib =
   319   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   320 
   321 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   322   apply (induct m)
   323    apply simp
   324   apply (induct n)
   325    apply auto
   326   done
   327 
   328 lemma one_eq_mult_iff [simp,no_atp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   329   apply (rule trans)
   330   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   331   done
   332 
   333 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   334   unfolding One_nat_def by (rule mult_eq_1_iff)
   335 
   336 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   337   unfolding One_nat_def by (rule one_eq_mult_iff)
   338 
   339 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   340 proof -
   341   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   342   proof (induct n arbitrary: m)
   343     case 0 then show "m = 0" by simp
   344   next
   345     case (Suc n) then show "m = Suc n"
   346       by (cases m) (simp_all add: eq_commute [of "0"])
   347   qed
   348   then show ?thesis by auto
   349 qed
   350 
   351 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   352   by (simp add: mult_commute)
   353 
   354 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   355   by (subst mult_cancel1) simp
   356 
   357 
   358 subsection {* Orders on @{typ nat} *}
   359 
   360 subsubsection {* Operation definition *}
   361 
   362 instantiation nat :: linorder
   363 begin
   364 
   365 primrec less_eq_nat where
   366   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   367 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   368 
   369 declare less_eq_nat.simps [simp del]
   370 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   371 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   372 
   373 definition less_nat where
   374   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   375 
   376 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   377   by (simp add: less_eq_nat.simps(2))
   378 
   379 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   380   unfolding less_eq_Suc_le ..
   381 
   382 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   383   by (induct n) (simp_all add: less_eq_nat.simps(2))
   384 
   385 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   386   by (simp add: less_eq_Suc_le)
   387 
   388 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   389   by simp
   390 
   391 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   392   by (simp add: less_eq_Suc_le)
   393 
   394 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   395   by (simp add: less_eq_Suc_le)
   396 
   397 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   398   by (induct m arbitrary: n)
   399     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   400 
   401 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   402   by (cases n) (auto intro: le_SucI)
   403 
   404 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   405   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   406 
   407 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   408   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   409 
   410 instance
   411 proof
   412   fix n m :: nat
   413   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   414   proof (induct n arbitrary: m)
   415     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   416   next
   417     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   418   qed
   419 next
   420   fix n :: nat show "n \<le> n" by (induct n) simp_all
   421 next
   422   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   423   then show "n = m"
   424     by (induct n arbitrary: m)
   425       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   426 next
   427   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   428   then show "n \<le> q"
   429   proof (induct n arbitrary: m q)
   430     case 0 show ?case by simp
   431   next
   432     case (Suc n) then show ?case
   433       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   434         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   435         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   436   qed
   437 next
   438   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   439     by (induct n arbitrary: m)
   440       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   441 qed
   442 
   443 end
   444 
   445 instantiation nat :: bot
   446 begin
   447 
   448 definition bot_nat :: nat where
   449   "bot_nat = 0"
   450 
   451 instance proof
   452 qed (simp add: bot_nat_def)
   453 
   454 end
   455 
   456 subsubsection {* Introduction properties *}
   457 
   458 lemma lessI [iff]: "n < Suc n"
   459   by (simp add: less_Suc_eq_le)
   460 
   461 lemma zero_less_Suc [iff]: "0 < Suc n"
   462   by (simp add: less_Suc_eq_le)
   463 
   464 
   465 subsubsection {* Elimination properties *}
   466 
   467 lemma less_not_refl: "~ n < (n::nat)"
   468   by (rule order_less_irrefl)
   469 
   470 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   471   by (rule not_sym) (rule less_imp_neq) 
   472 
   473 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   474   by (rule less_imp_neq)
   475 
   476 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   477   by (rule notE, rule less_not_refl)
   478 
   479 lemma less_zeroE: "(n::nat) < 0 ==> R"
   480   by (rule notE) (rule not_less0)
   481 
   482 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   483   unfolding less_Suc_eq_le le_less ..
   484 
   485 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   486   by (simp add: less_Suc_eq)
   487 
   488 lemma less_one [iff, no_atp]: "(n < (1::nat)) = (n = 0)"
   489   unfolding One_nat_def by (rule less_Suc0)
   490 
   491 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   492   by simp
   493 
   494 text {* "Less than" is antisymmetric, sort of *}
   495 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   496   unfolding not_less less_Suc_eq_le by (rule antisym)
   497 
   498 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   499   by (rule linorder_neq_iff)
   500 
   501 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   502   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   503   shows "P n m"
   504   apply (rule less_linear [THEN disjE])
   505   apply (erule_tac [2] disjE)
   506   apply (erule lessCase)
   507   apply (erule sym [THEN eqCase])
   508   apply (erule major)
   509   done
   510 
   511 
   512 subsubsection {* Inductive (?) properties *}
   513 
   514 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   515   unfolding less_eq_Suc_le [of m] le_less by simp 
   516 
   517 lemma lessE:
   518   assumes major: "i < k"
   519   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   520   shows P
   521 proof -
   522   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   523     unfolding less_eq_Suc_le by (induct k) simp_all
   524   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   525     by (clarsimp simp add: less_le)
   526   with p1 p2 show P by auto
   527 qed
   528 
   529 lemma less_SucE: assumes major: "m < Suc n"
   530   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   531   apply (rule major [THEN lessE])
   532   apply (rule eq, blast)
   533   apply (rule less, blast)
   534   done
   535 
   536 lemma Suc_lessE: assumes major: "Suc i < k"
   537   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   538   apply (rule major [THEN lessE])
   539   apply (erule lessI [THEN minor])
   540   apply (erule Suc_lessD [THEN minor], assumption)
   541   done
   542 
   543 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   544   by simp
   545 
   546 lemma less_trans_Suc:
   547   assumes le: "i < j" shows "j < k ==> Suc i < k"
   548   apply (induct k, simp_all)
   549   apply (insert le)
   550   apply (simp add: less_Suc_eq)
   551   apply (blast dest: Suc_lessD)
   552   done
   553 
   554 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   555 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   556   unfolding not_less less_Suc_eq_le ..
   557 
   558 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   559   unfolding not_le Suc_le_eq ..
   560 
   561 text {* Properties of "less than or equal" *}
   562 
   563 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   564   unfolding less_Suc_eq_le .
   565 
   566 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   567   unfolding not_le less_Suc_eq_le ..
   568 
   569 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   570   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   571 
   572 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   573   by (drule le_Suc_eq [THEN iffD1], iprover+)
   574 
   575 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   576   unfolding Suc_le_eq .
   577 
   578 text {* Stronger version of @{text Suc_leD} *}
   579 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   580   unfolding Suc_le_eq .
   581 
   582 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   583   unfolding less_eq_Suc_le by (rule Suc_leD)
   584 
   585 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   586 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   587 
   588 
   589 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   590 
   591 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   592   unfolding le_less .
   593 
   594 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   595   by (rule le_less)
   596 
   597 text {* Useful with @{text blast}. *}
   598 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   599   by auto
   600 
   601 lemma le_refl: "n \<le> (n::nat)"
   602   by simp
   603 
   604 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   605   by (rule order_trans)
   606 
   607 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   608   by (rule antisym)
   609 
   610 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   611   by (rule less_le)
   612 
   613 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   614   unfolding less_le ..
   615 
   616 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   617   by (rule linear)
   618 
   619 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   620 
   621 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   622   unfolding less_Suc_eq_le by auto
   623 
   624 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   625   unfolding not_less by (rule le_less_Suc_eq)
   626 
   627 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   628 
   629 text {* These two rules ease the use of primitive recursion.
   630 NOTE USE OF @{text "=="} *}
   631 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   632 by simp
   633 
   634 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   635 by simp
   636 
   637 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   638 by (cases n) simp_all
   639 
   640 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   641 by (cases n) simp_all
   642 
   643 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   644 by (cases n) simp_all
   645 
   646 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   647 by (cases n) simp_all
   648 
   649 text {* This theorem is useful with @{text blast} *}
   650 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   651 by (rule neq0_conv[THEN iffD1], iprover)
   652 
   653 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   654 by (fast intro: not0_implies_Suc)
   655 
   656 lemma not_gr0 [iff,no_atp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   657 using neq0_conv by blast
   658 
   659 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   660 by (induct m') simp_all
   661 
   662 text {* Useful in certain inductive arguments *}
   663 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   664 by (cases m) simp_all
   665 
   666 
   667 subsubsection {* Monotonicity of Addition *}
   668 
   669 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   670 by (simp add: diff_Suc split: nat.split)
   671 
   672 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   673 unfolding One_nat_def by (rule Suc_pred)
   674 
   675 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   676 by (induct k) simp_all
   677 
   678 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   679 by (induct k) simp_all
   680 
   681 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   682 by(auto dest:gr0_implies_Suc)
   683 
   684 text {* strict, in 1st argument *}
   685 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   686 by (induct k) simp_all
   687 
   688 text {* strict, in both arguments *}
   689 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   690   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   691   apply (induct j, simp_all)
   692   done
   693 
   694 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   695 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   696   apply (induct n)
   697   apply (simp_all add: order_le_less)
   698   apply (blast elim!: less_SucE
   699                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   700   done
   701 
   702 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   703 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   704 apply(auto simp: gr0_conv_Suc)
   705 apply (induct_tac m)
   706 apply (simp_all add: add_less_mono)
   707 done
   708 
   709 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   710 instance nat :: linordered_semidom
   711 proof
   712   fix i j k :: nat
   713   show "0 < (1::nat)" by simp
   714   show "i \<le> j ==> k + i \<le> k + j" by simp
   715   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   716 qed
   717 
   718 instance nat :: no_zero_divisors
   719 proof
   720   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   721 qed
   722 
   723 
   724 subsubsection {* @{term min} and @{term max} *}
   725 
   726 lemma mono_Suc: "mono Suc"
   727 by (rule monoI) simp
   728 
   729 lemma min_0L [simp]: "min 0 n = (0::nat)"
   730 by (rule min_absorb1) simp
   731 
   732 lemma min_0R [simp]: "min n 0 = (0::nat)"
   733 by (rule min_absorb2) simp
   734 
   735 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   736 by (simp add: mono_Suc min_of_mono)
   737 
   738 lemma min_Suc1:
   739    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   740 by (simp split: nat.split)
   741 
   742 lemma min_Suc2:
   743    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   744 by (simp split: nat.split)
   745 
   746 lemma max_0L [simp]: "max 0 n = (n::nat)"
   747 by (rule max_absorb2) simp
   748 
   749 lemma max_0R [simp]: "max n 0 = (n::nat)"
   750 by (rule max_absorb1) simp
   751 
   752 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   753 by (simp add: mono_Suc max_of_mono)
   754 
   755 lemma max_Suc1:
   756    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   757 by (simp split: nat.split)
   758 
   759 lemma max_Suc2:
   760    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   761 by (simp split: nat.split)
   762 
   763 lemma nat_mult_min_left:
   764   fixes m n q :: nat
   765   shows "min m n * q = min (m * q) (n * q)"
   766   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   767 
   768 lemma nat_mult_min_right:
   769   fixes m n q :: nat
   770   shows "m * min n q = min (m * n) (m * q)"
   771   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   772 
   773 lemma nat_add_max_left:
   774   fixes m n q :: nat
   775   shows "max m n + q = max (m + q) (n + q)"
   776   by (simp add: max_def)
   777 
   778 lemma nat_add_max_right:
   779   fixes m n q :: nat
   780   shows "m + max n q = max (m + n) (m + q)"
   781   by (simp add: max_def)
   782 
   783 lemma nat_mult_max_left:
   784   fixes m n q :: nat
   785   shows "max m n * q = max (m * q) (n * q)"
   786   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   787 
   788 lemma nat_mult_max_right:
   789   fixes m n q :: nat
   790   shows "m * max n q = max (m * n) (m * q)"
   791   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   792 
   793 
   794 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   795 
   796 text {* Complete induction, aka course-of-values induction *}
   797 
   798 instance nat :: wellorder proof
   799   fix P and n :: nat
   800   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   801   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   802   proof (induct n)
   803     case (0 n)
   804     have "P 0" by (rule step) auto
   805     thus ?case using 0 by auto
   806   next
   807     case (Suc m n)
   808     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   809     thus ?case
   810     proof
   811       assume "n \<le> m" thus "P n" by (rule Suc(1))
   812     next
   813       assume n: "n = Suc m"
   814       show "P n"
   815         by (rule step) (rule Suc(1), simp add: n le_simps)
   816     qed
   817   qed
   818   then show "P n" by auto
   819 qed
   820 
   821 lemma Least_Suc:
   822      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   823   apply (case_tac "n", auto)
   824   apply (frule LeastI)
   825   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   826   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   827   apply (erule_tac [2] Least_le)
   828   apply (case_tac "LEAST x. P x", auto)
   829   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   830   apply (blast intro: order_antisym)
   831   done
   832 
   833 lemma Least_Suc2:
   834    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   835   apply (erule (1) Least_Suc [THEN ssubst])
   836   apply simp
   837   done
   838 
   839 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   840   apply (cases n)
   841    apply blast
   842   apply (rule_tac x="LEAST k. P(k)" in exI)
   843   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   844   done
   845 
   846 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   847   unfolding One_nat_def
   848   apply (cases n)
   849    apply blast
   850   apply (frule (1) ex_least_nat_le)
   851   apply (erule exE)
   852   apply (case_tac k)
   853    apply simp
   854   apply (rename_tac k1)
   855   apply (rule_tac x=k1 in exI)
   856   apply (auto simp add: less_eq_Suc_le)
   857   done
   858 
   859 lemma nat_less_induct:
   860   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   861   using assms less_induct by blast
   862 
   863 lemma measure_induct_rule [case_names less]:
   864   fixes f :: "'a \<Rightarrow> nat"
   865   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   866   shows "P a"
   867 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   868 
   869 text {* old style induction rules: *}
   870 lemma measure_induct:
   871   fixes f :: "'a \<Rightarrow> nat"
   872   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   873   by (rule measure_induct_rule [of f P a]) iprover
   874 
   875 lemma full_nat_induct:
   876   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   877   shows "P n"
   878   by (rule less_induct) (auto intro: step simp:le_simps)
   879 
   880 text{*An induction rule for estabilishing binary relations*}
   881 lemma less_Suc_induct:
   882   assumes less:  "i < j"
   883      and  step:  "!!i. P i (Suc i)"
   884      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   885   shows "P i j"
   886 proof -
   887   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   888   have "P i (Suc (i + k))"
   889   proof (induct k)
   890     case 0
   891     show ?case by (simp add: step)
   892   next
   893     case (Suc k)
   894     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   895     hence "i < Suc (i + k)" by (simp add: add_commute)
   896     from trans[OF this lessI Suc step]
   897     show ?case by simp
   898   qed
   899   thus "P i j" by (simp add: j)
   900 qed
   901 
   902 text {* The method of infinite descent, frequently used in number theory.
   903 Provided by Roelof Oosterhuis.
   904 $P(n)$ is true for all $n\in\mathbb{N}$ if
   905 \begin{itemize}
   906   \item case ``0'': given $n=0$ prove $P(n)$,
   907   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   908         a smaller integer $m$ such that $\neg P(m)$.
   909 \end{itemize} *}
   910 
   911 text{* A compact version without explicit base case: *}
   912 lemma infinite_descent:
   913   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   914 by (induct n rule: less_induct, auto)
   915 
   916 lemma infinite_descent0[case_names 0 smaller]: 
   917   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   918 by (rule infinite_descent) (case_tac "n>0", auto)
   919 
   920 text {*
   921 Infinite descent using a mapping to $\mathbb{N}$:
   922 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   923 \begin{itemize}
   924 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   925 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   926 \end{itemize}
   927 NB: the proof also shows how to use the previous lemma. *}
   928 
   929 corollary infinite_descent0_measure [case_names 0 smaller]:
   930   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   931     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   932   shows "P x"
   933 proof -
   934   obtain n where "n = V x" by auto
   935   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   936   proof (induct n rule: infinite_descent0)
   937     case 0 -- "i.e. $V(x) = 0$"
   938     with A0 show "P x" by auto
   939   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   940     case (smaller n)
   941     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   942     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   943     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   944     then show ?case by auto
   945   qed
   946   ultimately show "P x" by auto
   947 qed
   948 
   949 text{* Again, without explicit base case: *}
   950 lemma infinite_descent_measure:
   951 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   952 proof -
   953   from assms obtain n where "n = V x" by auto
   954   moreover have "!!x. V x = n \<Longrightarrow> P x"
   955   proof (induct n rule: infinite_descent, auto)
   956     fix x assume "\<not> P x"
   957     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   958   qed
   959   ultimately show "P x" by auto
   960 qed
   961 
   962 text {* A [clumsy] way of lifting @{text "<"}
   963   monotonicity to @{text "\<le>"} monotonicity *}
   964 lemma less_mono_imp_le_mono:
   965   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   966 by (simp add: order_le_less) (blast)
   967 
   968 
   969 text {* non-strict, in 1st argument *}
   970 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   971 by (rule add_right_mono)
   972 
   973 text {* non-strict, in both arguments *}
   974 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   975 by (rule add_mono)
   976 
   977 lemma le_add2: "n \<le> ((m + n)::nat)"
   978 by (insert add_right_mono [of 0 m n], simp)
   979 
   980 lemma le_add1: "n \<le> ((n + m)::nat)"
   981 by (simp add: add_commute, rule le_add2)
   982 
   983 lemma less_add_Suc1: "i < Suc (i + m)"
   984 by (rule le_less_trans, rule le_add1, rule lessI)
   985 
   986 lemma less_add_Suc2: "i < Suc (m + i)"
   987 by (rule le_less_trans, rule le_add2, rule lessI)
   988 
   989 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   990 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   991 
   992 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   993 by (rule le_trans, assumption, rule le_add1)
   994 
   995 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   996 by (rule le_trans, assumption, rule le_add2)
   997 
   998 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   999 by (rule less_le_trans, assumption, rule le_add1)
  1000 
  1001 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
  1002 by (rule less_le_trans, assumption, rule le_add2)
  1003 
  1004 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
  1005 apply (rule le_less_trans [of _ "i+j"])
  1006 apply (simp_all add: le_add1)
  1007 done
  1008 
  1009 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1010 apply (rule notI)
  1011 apply (drule add_lessD1)
  1012 apply (erule less_irrefl [THEN notE])
  1013 done
  1014 
  1015 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1016 by (simp add: add_commute)
  1017 
  1018 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1019 apply (rule order_trans [of _ "m+k"])
  1020 apply (simp_all add: le_add1)
  1021 done
  1022 
  1023 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1024 apply (simp add: add_commute)
  1025 apply (erule add_leD1)
  1026 done
  1027 
  1028 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1029 by (blast dest: add_leD1 add_leD2)
  1030 
  1031 text {* needs @{text "!!k"} for @{text add_ac} to work *}
  1032 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1033 by (force simp del: add_Suc_right
  1034     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1035 
  1036 
  1037 subsubsection {* More results about difference *}
  1038 
  1039 text {* Addition is the inverse of subtraction:
  1040   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1041 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1042 by (induct m n rule: diff_induct) simp_all
  1043 
  1044 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1045 by (simp add: add_diff_inverse linorder_not_less)
  1046 
  1047 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1048 by (simp add: add_commute)
  1049 
  1050 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1051 by (induct m n rule: diff_induct) simp_all
  1052 
  1053 lemma diff_less_Suc: "m - n < Suc m"
  1054 apply (induct m n rule: diff_induct)
  1055 apply (erule_tac [3] less_SucE)
  1056 apply (simp_all add: less_Suc_eq)
  1057 done
  1058 
  1059 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1060 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1061 
  1062 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1063   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1064 
  1065 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1066 by (rule le_less_trans, rule diff_le_self)
  1067 
  1068 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1069 by (cases n) (auto simp add: le_simps)
  1070 
  1071 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1072 by (induct j k rule: diff_induct) simp_all
  1073 
  1074 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1075 by (simp add: add_commute diff_add_assoc)
  1076 
  1077 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1078 by (auto simp add: diff_add_inverse2)
  1079 
  1080 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1081 by (induct m n rule: diff_induct) simp_all
  1082 
  1083 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1084 by (rule iffD2, rule diff_is_0_eq)
  1085 
  1086 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1087 by (induct m n rule: diff_induct) simp_all
  1088 
  1089 lemma less_imp_add_positive:
  1090   assumes "i < j"
  1091   shows "\<exists>k::nat. 0 < k & i + k = j"
  1092 proof
  1093   from assms show "0 < j - i & i + (j - i) = j"
  1094     by (simp add: order_less_imp_le)
  1095 qed
  1096 
  1097 text {* a nice rewrite for bounded subtraction *}
  1098 lemma nat_minus_add_max:
  1099   fixes n m :: nat
  1100   shows "n - m + m = max n m"
  1101     by (simp add: max_def not_le order_less_imp_le)
  1102 
  1103 lemma nat_diff_split:
  1104   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1105     -- {* elimination of @{text -} on @{text nat} *}
  1106 by (cases "a < b")
  1107   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1108     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1109 
  1110 lemma nat_diff_split_asm:
  1111   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1112     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1113 by (auto split: nat_diff_split)
  1114 
  1115 
  1116 subsubsection {* Monotonicity of Multiplication *}
  1117 
  1118 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1119 by (simp add: mult_right_mono)
  1120 
  1121 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1122 by (simp add: mult_left_mono)
  1123 
  1124 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1125 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1126 by (simp add: mult_mono)
  1127 
  1128 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1129 by (simp add: mult_strict_right_mono)
  1130 
  1131 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1132       there are no negative numbers.*}
  1133 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1134   apply (induct m)
  1135    apply simp
  1136   apply (case_tac n)
  1137    apply simp_all
  1138   done
  1139 
  1140 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1141   apply (induct m)
  1142    apply simp
  1143   apply (case_tac n)
  1144    apply simp_all
  1145   done
  1146 
  1147 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1148   apply (safe intro!: mult_less_mono1)
  1149   apply (case_tac k, auto)
  1150   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1151   apply (blast intro: mult_le_mono1)
  1152   done
  1153 
  1154 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1155 by (simp add: mult_commute [of k])
  1156 
  1157 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1158 by (simp add: linorder_not_less [symmetric], auto)
  1159 
  1160 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1161 by (simp add: linorder_not_less [symmetric], auto)
  1162 
  1163 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1164 by (subst mult_less_cancel1) simp
  1165 
  1166 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1167 by (subst mult_le_cancel1) simp
  1168 
  1169 lemma le_square: "m \<le> m * (m::nat)"
  1170   by (cases m) (auto intro: le_add1)
  1171 
  1172 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1173   by (cases m) (auto intro: le_add1)
  1174 
  1175 text {* Lemma for @{text gcd} *}
  1176 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1177   apply (drule sym)
  1178   apply (rule disjCI)
  1179   apply (rule nat_less_cases, erule_tac [2] _)
  1180    apply (drule_tac [2] mult_less_mono2)
  1181     apply (auto)
  1182   done
  1183 
  1184 text {* the lattice order on @{typ nat} *}
  1185 
  1186 instantiation nat :: distrib_lattice
  1187 begin
  1188 
  1189 definition
  1190   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1191 
  1192 definition
  1193   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1194 
  1195 instance by intro_classes
  1196   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1197     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1198 
  1199 end
  1200 
  1201 
  1202 subsection {* Natural operation of natural numbers on functions *}
  1203 
  1204 text {*
  1205   We use the same logical constant for the power operations on
  1206   functions and relations, in order to share the same syntax.
  1207 *}
  1208 
  1209 consts compow :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1210 
  1211 abbreviation compower :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^^" 80) where
  1212   "f ^^ n \<equiv> compow n f"
  1213 
  1214 notation (latex output)
  1215   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1216 
  1217 notation (HTML output)
  1218   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1219 
  1220 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1221 
  1222 overloading
  1223   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1224 begin
  1225 
  1226 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1227   "funpow 0 f = id"
  1228 | "funpow (Suc n) f = f o funpow n f"
  1229 
  1230 end
  1231 
  1232 text {* for code generation *}
  1233 
  1234 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1235   funpow_code_def [code_abbrev]: "funpow = compow"
  1236 
  1237 lemma [code]:
  1238   "funpow (Suc n) f = f o funpow n f"
  1239   "funpow 0 f = id"
  1240   by (simp_all add: funpow_code_def)
  1241 
  1242 hide_const (open) funpow
  1243 
  1244 lemma funpow_add:
  1245   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1246   by (induct m) simp_all
  1247 
  1248 lemma funpow_mult:
  1249   fixes f :: "'a \<Rightarrow> 'a"
  1250   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1251   by (induct n) (simp_all add: funpow_add)
  1252 
  1253 lemma funpow_swap1:
  1254   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1255 proof -
  1256   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1257   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1258   also have "\<dots> = (f ^^ n) (f x)" by simp
  1259   finally show ?thesis .
  1260 qed
  1261 
  1262 lemma comp_funpow:
  1263   fixes f :: "'a \<Rightarrow> 'a"
  1264   shows "comp f ^^ n = comp (f ^^ n)"
  1265   by (induct n) simp_all
  1266 
  1267 
  1268 subsection {* Kleene iteration *}
  1269 
  1270 lemma Kleene_iter_lpfp: assumes "mono f" and "f p \<le> p" shows "(f^^k) bot \<le> p"
  1271 proof(induction k)
  1272   case 0 show ?case by simp
  1273 next
  1274   case Suc
  1275   from monoD[OF assms(1) Suc] assms(2)
  1276   show ?case by simp
  1277 qed
  1278 
  1279 lemma lfp_Kleene_iter: assumes "mono f" and "(f^^Suc k) bot = (f^^k) bot"
  1280 shows "lfp f = (f^^k) bot"
  1281 proof(rule antisym)
  1282   show "lfp f \<le> (f^^k) bot"
  1283   proof(rule lfp_lowerbound)
  1284     show "f ((f^^k) bot) \<le> (f^^k) bot" using assms(2) by simp
  1285   qed
  1286 next
  1287   show "(f^^k) bot \<le> lfp f"
  1288     using Kleene_iter_lpfp[OF assms(1)] lfp_unfold[OF assms(1)] by simp
  1289 qed
  1290 
  1291 
  1292 subsection {* Embedding of the Naturals into any @{text semiring_1}: @{term of_nat} *}
  1293 
  1294 context semiring_1
  1295 begin
  1296 
  1297 definition of_nat :: "nat \<Rightarrow> 'a" where
  1298   "of_nat n = (plus 1 ^^ n) 0"
  1299 
  1300 lemma of_nat_simps [simp]:
  1301   shows of_nat_0: "of_nat 0 = 0"
  1302     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1303   by (simp_all add: of_nat_def)
  1304 
  1305 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1306   by (simp add: of_nat_def)
  1307 
  1308 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1309   by (induct m) (simp_all add: add_ac)
  1310 
  1311 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1312   by (induct m) (simp_all add: add_ac left_distrib)
  1313 
  1314 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1315   "of_nat_aux inc 0 i = i"
  1316 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1317 
  1318 lemma of_nat_code:
  1319   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1320 proof (induct n)
  1321   case 0 then show ?case by simp
  1322 next
  1323   case (Suc n)
  1324   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1325     by (induct n) simp_all
  1326   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1327     by simp
  1328   with Suc show ?case by (simp add: add_commute)
  1329 qed
  1330 
  1331 end
  1332 
  1333 declare of_nat_code [code]
  1334 
  1335 text{*Class for unital semirings with characteristic zero.
  1336  Includes non-ordered rings like the complex numbers.*}
  1337 
  1338 class semiring_char_0 = semiring_1 +
  1339   assumes inj_of_nat: "inj of_nat"
  1340 begin
  1341 
  1342 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1343   by (auto intro: inj_of_nat injD)
  1344 
  1345 text{*Special cases where either operand is zero*}
  1346 
  1347 lemma of_nat_0_eq_iff [simp, no_atp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1348   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1349 
  1350 lemma of_nat_eq_0_iff [simp, no_atp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1351   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1352 
  1353 end
  1354 
  1355 context linordered_semidom
  1356 begin
  1357 
  1358 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1359   by (induct m) simp_all
  1360 
  1361 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1362   apply (induct m n rule: diff_induct, simp_all)
  1363   apply (rule add_pos_nonneg [OF zero_less_one zero_le_imp_of_nat])
  1364   done
  1365 
  1366 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1367   apply (induct m n rule: diff_induct, simp_all)
  1368   apply (insert zero_le_imp_of_nat)
  1369   apply (force simp add: not_less [symmetric])
  1370   done
  1371 
  1372 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1373   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1374 
  1375 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1376   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1377 
  1378 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1379 
  1380 subclass semiring_char_0 proof
  1381 qed (auto intro!: injI simp add: eq_iff)
  1382 
  1383 text{*Special cases where either operand is zero*}
  1384 
  1385 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1386   by (rule of_nat_le_iff [of 0, simplified])
  1387 
  1388 lemma of_nat_le_0_iff [simp, no_atp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1389   by (rule of_nat_le_iff [of _ 0, simplified])
  1390 
  1391 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1392   by (rule of_nat_less_iff [of 0, simplified])
  1393 
  1394 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1395   by (rule of_nat_less_iff [of _ 0, simplified])
  1396 
  1397 end
  1398 
  1399 context ring_1
  1400 begin
  1401 
  1402 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1403 by (simp add: algebra_simps of_nat_add [symmetric])
  1404 
  1405 end
  1406 
  1407 context linordered_idom
  1408 begin
  1409 
  1410 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1411   unfolding abs_if by auto
  1412 
  1413 end
  1414 
  1415 lemma of_nat_id [simp]: "of_nat n = n"
  1416   by (induct n) simp_all
  1417 
  1418 lemma of_nat_eq_id [simp]: "of_nat = id"
  1419   by (auto simp add: fun_eq_iff)
  1420 
  1421 
  1422 subsection {* The Set of Natural Numbers *}
  1423 
  1424 context semiring_1
  1425 begin
  1426 
  1427 definition Nats  :: "'a set" where
  1428   "Nats = range of_nat"
  1429 
  1430 notation (xsymbols)
  1431   Nats  ("\<nat>")
  1432 
  1433 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1434   by (simp add: Nats_def)
  1435 
  1436 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1437 apply (simp add: Nats_def)
  1438 apply (rule range_eqI)
  1439 apply (rule of_nat_0 [symmetric])
  1440 done
  1441 
  1442 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1443 apply (simp add: Nats_def)
  1444 apply (rule range_eqI)
  1445 apply (rule of_nat_1 [symmetric])
  1446 done
  1447 
  1448 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1449 apply (auto simp add: Nats_def)
  1450 apply (rule range_eqI)
  1451 apply (rule of_nat_add [symmetric])
  1452 done
  1453 
  1454 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1455 apply (auto simp add: Nats_def)
  1456 apply (rule range_eqI)
  1457 apply (rule of_nat_mult [symmetric])
  1458 done
  1459 
  1460 lemma Nats_cases [cases set: Nats]:
  1461   assumes "x \<in> \<nat>"
  1462   obtains (of_nat) n where "x = of_nat n"
  1463   unfolding Nats_def
  1464 proof -
  1465   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1466   then obtain n where "x = of_nat n" ..
  1467   then show thesis ..
  1468 qed
  1469 
  1470 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1471   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1472   by (rule Nats_cases) auto
  1473 
  1474 end
  1475 
  1476 
  1477 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1478 
  1479 lemma subst_equals:
  1480   assumes 1: "t = s" and 2: "u = t"
  1481   shows "u = s"
  1482   using 2 1 by (rule trans)
  1483 
  1484 setup Arith_Data.setup
  1485 
  1486 use "Tools/nat_arith.ML"
  1487 declaration {* K Nat_Arith.setup *}
  1488 
  1489 use "Tools/lin_arith.ML"
  1490 setup {* Lin_Arith.global_setup *}
  1491 declaration {* K Lin_Arith.setup *}
  1492 
  1493 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1494   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (term_of ct) *}
  1495 (* Because of this simproc, the arithmetic solver is really only
  1496 useful to detect inconsistencies among the premises for subgoals which are
  1497 *not* themselves (in)equalities, because the latter activate
  1498 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1499 solver all the time rather than add the additional check. *)
  1500 
  1501 
  1502 lemmas [arith_split] = nat_diff_split split_min split_max
  1503 
  1504 context order
  1505 begin
  1506 
  1507 lemma lift_Suc_mono_le:
  1508   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1509   shows "f n \<le> f n'"
  1510 proof (cases "n < n'")
  1511   case True
  1512   thus ?thesis
  1513     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1514 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1515 
  1516 lemma lift_Suc_mono_less:
  1517   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1518   shows "f n < f n'"
  1519 using `n < n'`
  1520 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1521 
  1522 lemma lift_Suc_mono_less_iff:
  1523   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1524 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1525          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1526 
  1527 end
  1528 
  1529 lemma mono_iff_le_Suc: "mono f = (\<forall>n. f n \<le> f (Suc n))"
  1530   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1531 
  1532 lemma mono_nat_linear_lb:
  1533   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1534 apply(induct_tac k)
  1535  apply simp
  1536 apply(erule_tac x="m+n" in meta_allE)
  1537 apply(erule_tac x="Suc(m+n)" in meta_allE)
  1538 apply simp
  1539 done
  1540 
  1541 
  1542 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1543 
  1544 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1545 by arith
  1546 
  1547 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1548 by arith
  1549 
  1550 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1551 by arith
  1552 
  1553 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1554 by arith
  1555 
  1556 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1557 by arith
  1558 
  1559 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1560 by arith
  1561 
  1562 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1563   second premise n\<le>m*)
  1564 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1565 by arith
  1566 
  1567 text {* Simplification of relational expressions involving subtraction *}
  1568 
  1569 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1570 by (simp split add: nat_diff_split)
  1571 
  1572 hide_fact (open) diff_diff_eq
  1573 
  1574 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1575 by (auto split add: nat_diff_split)
  1576 
  1577 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1578 by (auto split add: nat_diff_split)
  1579 
  1580 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1581 by (auto split add: nat_diff_split)
  1582 
  1583 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1584 
  1585 (* Monotonicity of subtraction in first argument *)
  1586 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1587 by (simp split add: nat_diff_split)
  1588 
  1589 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1590 by (simp split add: nat_diff_split)
  1591 
  1592 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1593 by (simp split add: nat_diff_split)
  1594 
  1595 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1596 by (simp split add: nat_diff_split)
  1597 
  1598 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1599 by auto
  1600 
  1601 lemma inj_on_diff_nat: 
  1602   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1603   shows "inj_on (\<lambda>n. n - k) N"
  1604 proof (rule inj_onI)
  1605   fix x y
  1606   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1607   with k_le_n have "x - k + k = y - k + k" by auto
  1608   with a k_le_n show "x = y" by auto
  1609 qed
  1610 
  1611 text{*Rewriting to pull differences out*}
  1612 
  1613 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1614 by arith
  1615 
  1616 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1617 by arith
  1618 
  1619 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1620 by arith
  1621 
  1622 lemma Suc_diff_Suc: "n < m \<Longrightarrow> Suc (m - Suc n) = m - n"
  1623 by simp
  1624 
  1625 (*The others are
  1626       i - j - k = i - (j + k),
  1627       k \<le> j ==> j - k + i = j + i - k,
  1628       k \<le> j ==> i + (j - k) = i + j - k *)
  1629 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1630 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1631 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1632 
  1633 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1634 Least_Suc}, since there appears to be no need.*}
  1635 
  1636 text{*Lemmas for ex/Factorization*}
  1637 
  1638 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1639 by (cases m) auto
  1640 
  1641 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1642 by (cases m) auto
  1643 
  1644 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1645 by (cases m) auto
  1646 
  1647 text {* Specialized induction principles that work "backwards": *}
  1648 
  1649 lemma inc_induct[consumes 1, case_names base step]:
  1650   assumes less: "i <= j"
  1651   assumes base: "P j"
  1652   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1653   shows "P i"
  1654   using less
  1655 proof (induct d=="j - i" arbitrary: i)
  1656   case (0 i)
  1657   hence "i = j" by simp
  1658   with base show ?case by simp
  1659 next
  1660   case (Suc d i)
  1661   hence "i < j" "P (Suc i)"
  1662     by simp_all
  1663   thus "P i" by (rule step)
  1664 qed
  1665 
  1666 lemma strict_inc_induct[consumes 1, case_names base step]:
  1667   assumes less: "i < j"
  1668   assumes base: "!!i. j = Suc i ==> P i"
  1669   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1670   shows "P i"
  1671   using less
  1672 proof (induct d=="j - i - 1" arbitrary: i)
  1673   case (0 i)
  1674   with `i < j` have "j = Suc i" by simp
  1675   with base show ?case by simp
  1676 next
  1677   case (Suc d i)
  1678   hence "i < j" "P (Suc i)"
  1679     by simp_all
  1680   thus "P i" by (rule step)
  1681 qed
  1682 
  1683 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1684   using inc_induct[of "k - i" k P, simplified] by blast
  1685 
  1686 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1687   using inc_induct[of 0 k P] by blast
  1688 
  1689 text {* Further induction rule similar to @{thm inc_induct} *}
  1690 
  1691 lemma dec_induct[consumes 1, case_names base step]:
  1692   "i \<le> j \<Longrightarrow> P i \<Longrightarrow> (\<And>n. i \<le> n \<Longrightarrow> P n \<Longrightarrow> P (Suc n)) \<Longrightarrow> P j"
  1693   by (induct j arbitrary: i) (auto simp: le_Suc_eq)
  1694 
  1695  
  1696 subsection {* The divides relation on @{typ nat} *}
  1697 
  1698 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1699 unfolding dvd_def by simp
  1700 
  1701 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1702 by (simp add: dvd_def)
  1703 
  1704 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1705 by (simp add: dvd_def)
  1706 
  1707 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1708   unfolding dvd_def
  1709   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc)
  1710 
  1711 text {* @{term "op dvd"} is a partial order *}
  1712 
  1713 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1714   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1715 
  1716 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1717 unfolding dvd_def
  1718 by (blast intro: diff_mult_distrib2 [symmetric])
  1719 
  1720 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1721   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1722   apply (blast intro: dvd_add)
  1723   done
  1724 
  1725 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1726 by (drule_tac m = m in dvd_diff_nat, auto)
  1727 
  1728 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1729   apply (rule iffI)
  1730    apply (erule_tac [2] dvd_add)
  1731    apply (rule_tac [2] dvd_refl)
  1732   apply (subgoal_tac "n = (n+k) -k")
  1733    prefer 2 apply simp
  1734   apply (erule ssubst)
  1735   apply (erule dvd_diff_nat)
  1736   apply (rule dvd_refl)
  1737   done
  1738 
  1739 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1740   unfolding dvd_def
  1741   apply (erule exE)
  1742   apply (simp add: mult_ac)
  1743   done
  1744 
  1745 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1746   apply auto
  1747    apply (subgoal_tac "m*n dvd m*1")
  1748    apply (drule dvd_mult_cancel, auto)
  1749   done
  1750 
  1751 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1752   apply (subst mult_commute)
  1753   apply (erule dvd_mult_cancel1)
  1754   done
  1755 
  1756 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1757 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1758 
  1759 lemma nat_dvd_not_less:
  1760   fixes m n :: nat
  1761   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1762 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1763 
  1764 
  1765 subsection {* aliasses *}
  1766 
  1767 lemma nat_mult_1: "(1::nat) * n = n"
  1768   by simp
  1769  
  1770 lemma nat_mult_1_right: "n * (1::nat) = n"
  1771   by simp
  1772 
  1773 
  1774 subsection {* size of a datatype value *}
  1775 
  1776 class size =
  1777   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1778 
  1779 
  1780 subsection {* code module namespace *}
  1781 
  1782 code_modulename SML
  1783   Nat Arith
  1784 
  1785 code_modulename OCaml
  1786   Nat Arith
  1787 
  1788 code_modulename Haskell
  1789   Nat Arith
  1790 
  1791 hide_const (open) of_nat_aux
  1792 
  1793 end