src/HOL/Tools/hologic.ML
author huffman
Fri Mar 30 12:32:35 2012 +0200 (2012-03-30)
changeset 47220 52426c62b5d0
parent 47108 2a1953f0d20d
child 51126 df86080de4cb
permissions -rw-r--r--
replace lemmas eval_nat_numeral with a simpler reformulation
     1 (*  Title:      HOL/Tools/hologic.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Abstract syntax operations for HOL.
     5 *)
     6 
     7 signature HOLOGIC =
     8 sig
     9   val typeS: sort
    10   val typeT: typ
    11   val id_const: typ -> term
    12   val mk_comp: term * term -> term
    13   val boolN: string
    14   val boolT: typ
    15   val Trueprop: term
    16   val mk_Trueprop: term -> term
    17   val dest_Trueprop: term -> term
    18   val mk_induct_forall: typ -> term
    19   val mk_setT: typ -> typ
    20   val dest_setT: typ -> typ
    21   val Collect_const: typ -> term
    22   val mk_Collect: string * typ * term -> term
    23   val mk_mem: term * term -> term
    24   val dest_mem: term -> term * term
    25   val mk_set: typ -> term list -> term
    26   val dest_set: term -> term list
    27   val mk_UNIV: typ -> term
    28   val conj_intr: thm -> thm -> thm
    29   val conj_elim: thm -> thm * thm
    30   val conj_elims: thm -> thm list
    31   val conj: term
    32   val disj: term
    33   val imp: term
    34   val Not: term
    35   val mk_conj: term * term -> term
    36   val mk_disj: term * term -> term
    37   val mk_imp: term * term -> term
    38   val mk_not: term -> term
    39   val dest_conj: term -> term list
    40   val dest_disj: term -> term list
    41   val disjuncts: term -> term list
    42   val dest_imp: term -> term * term
    43   val dest_not: term -> term
    44   val eq_const: typ -> term
    45   val mk_eq: term * term -> term
    46   val dest_eq: term -> term * term
    47   val all_const: typ -> term
    48   val mk_all: string * typ * term -> term
    49   val list_all: (string * typ) list * term -> term
    50   val exists_const: typ -> term
    51   val mk_exists: string * typ * term -> term
    52   val choice_const: typ -> term
    53   val class_equal: string
    54   val mk_binop: string -> term * term -> term
    55   val mk_binrel: string -> term * term -> term
    56   val dest_bin: string -> typ -> term -> term * term
    57   val unitT: typ
    58   val is_unitT: typ -> bool
    59   val unit: term
    60   val is_unit: term -> bool
    61   val mk_prodT: typ * typ -> typ
    62   val dest_prodT: typ -> typ * typ
    63   val pair_const: typ -> typ -> term
    64   val mk_prod: term * term -> term
    65   val dest_prod: term -> term * term
    66   val mk_fst: term -> term
    67   val mk_snd: term -> term
    68   val split_const: typ * typ * typ -> term
    69   val mk_split: term -> term
    70   val flatten_tupleT: typ -> typ list
    71   val tupled_lambda: term -> term -> term
    72   val mk_tupleT: typ list -> typ
    73   val strip_tupleT: typ -> typ list
    74   val mk_tuple: term list -> term
    75   val strip_tuple: term -> term list
    76   val mk_ptupleT: int list list -> typ list -> typ
    77   val strip_ptupleT: int list list -> typ -> typ list
    78   val flat_tupleT_paths: typ -> int list list
    79   val mk_ptuple: int list list -> typ -> term list -> term
    80   val strip_ptuple: int list list -> term -> term list
    81   val flat_tuple_paths: term -> int list list
    82   val mk_psplits: int list list -> typ -> typ -> term -> term
    83   val strip_psplits: term -> term * typ list * int list list
    84   val natT: typ
    85   val zero: term
    86   val is_zero: term -> bool
    87   val mk_Suc: term -> term
    88   val dest_Suc: term -> term
    89   val Suc_zero: term
    90   val mk_nat: int -> term
    91   val dest_nat: term -> int
    92   val class_size: string
    93   val size_const: typ -> term
    94   val code_numeralT: typ
    95   val intT: typ
    96   val one_const: term
    97   val bit0_const: term
    98   val bit1_const: term
    99   val mk_bit: int -> term
   100   val dest_bit: term -> int
   101   val mk_numeral: int -> term
   102   val dest_num: term -> int
   103   val numeral_const: typ -> term
   104   val neg_numeral_const: typ -> term
   105   val add_numerals: term -> (term * typ) list -> (term * typ) list
   106   val mk_number: typ -> int -> term
   107   val dest_number: term -> typ * int
   108   val realT: typ
   109   val nibbleT: typ
   110   val mk_nibble: int -> term
   111   val dest_nibble: term -> int
   112   val charT: typ
   113   val mk_char: int -> term
   114   val dest_char: term -> int
   115   val listT: typ -> typ
   116   val nil_const: typ -> term
   117   val cons_const: typ -> term
   118   val mk_list: typ -> term list -> term
   119   val dest_list: term -> term list
   120   val stringT: typ
   121   val mk_string: string -> term
   122   val dest_string: term -> string
   123   val literalT: typ
   124   val mk_literal: string -> term
   125   val dest_literal: term -> string
   126   val mk_typerep: typ -> term
   127   val termT: typ
   128   val term_of_const: typ -> term
   129   val mk_term_of: typ -> term -> term
   130   val reflect_term: term -> term
   131   val mk_valtermify_app: string -> (string * typ) list -> typ -> term
   132   val mk_return: typ -> typ -> term -> term
   133   val mk_ST: ((term * typ) * (string * typ) option)  list -> term -> typ -> typ option * typ -> term
   134   val mk_random: typ -> term -> term
   135 end;
   136 
   137 structure HOLogic: HOLOGIC =
   138 struct
   139 
   140 (* HOL syntax *)
   141 
   142 val typeS: sort = ["HOL.type"];
   143 val typeT = Type_Infer.anyT typeS;
   144 
   145 
   146 (* functions *)
   147 
   148 fun id_const T = Const ("Fun.id", T --> T);
   149 
   150 fun mk_comp (f, g) =
   151   let
   152     val fT = fastype_of f;
   153     val gT = fastype_of g;
   154     val compT = fT --> gT --> domain_type gT --> range_type fT;
   155   in Const ("Fun.comp", compT) $ f $ g end;
   156 
   157 
   158 (* bool and set *)
   159 
   160 val boolN = "HOL.bool";
   161 val boolT = Type (boolN, []);
   162 
   163 fun mk_induct_forall T = Const ("HOL.induct_forall", (T --> boolT) --> boolT);
   164 
   165 fun mk_setT T = Type ("Set.set", [T]);
   166 
   167 fun dest_setT (Type ("Set.set", [T])) = T
   168   | dest_setT T = raise TYPE ("dest_setT: set type expected", [T], []);
   169 
   170 fun mk_set T ts =
   171   let
   172     val sT = mk_setT T;
   173     val empty = Const ("Orderings.bot_class.bot", sT);
   174     fun insert t u = Const ("Set.insert", T --> sT --> sT) $ t $ u;
   175   in fold_rev insert ts empty end;
   176 
   177 fun mk_UNIV T = Const ("Orderings.top_class.top", mk_setT T);
   178 
   179 fun dest_set (Const ("Orderings.bot_class.bot", _)) = []
   180   | dest_set (Const ("Set.insert", _) $ t $ u) = t :: dest_set u
   181   | dest_set t = raise TERM ("dest_set", [t]);
   182 
   183 fun Collect_const T = Const ("Set.Collect", (T --> boolT) --> mk_setT T);
   184 fun mk_Collect (a, T, t) = Collect_const T $ absfree (a, T) t;
   185 
   186 fun mk_mem (x, A) =
   187   let val setT = fastype_of A in
   188     Const ("Set.member", dest_setT setT --> setT --> boolT) $ x $ A
   189   end;
   190 
   191 fun dest_mem (Const ("Set.member", _) $ x $ A) = (x, A)
   192   | dest_mem t = raise TERM ("dest_mem", [t]);
   193 
   194 
   195 (* logic *)
   196 
   197 val Trueprop = Const ("HOL.Trueprop", boolT --> propT);
   198 
   199 fun mk_Trueprop P = Trueprop $ P;
   200 
   201 fun dest_Trueprop (Const ("HOL.Trueprop", _) $ P) = P
   202   | dest_Trueprop t = raise TERM ("dest_Trueprop", [t]);
   203 
   204 fun conj_intr thP thQ =
   205   let
   206     val (P, Q) = pairself (Object_Logic.dest_judgment o Thm.cprop_of) (thP, thQ)
   207       handle CTERM (msg, _) => raise THM (msg, 0, [thP, thQ]);
   208     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   209   in Drule.implies_elim_list (inst @{thm conjI}) [thP, thQ] end;
   210 
   211 fun conj_elim thPQ =
   212   let
   213     val (P, Q) = Thm.dest_binop (Object_Logic.dest_judgment (Thm.cprop_of thPQ))
   214       handle CTERM (msg, _) => raise THM (msg, 0, [thPQ]);
   215     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   216     val thP = Thm.implies_elim (inst @{thm conjunct1}) thPQ;
   217     val thQ = Thm.implies_elim (inst @{thm conjunct2}) thPQ;
   218   in (thP, thQ) end;
   219 
   220 fun conj_elims th =
   221   let val (th1, th2) = conj_elim th
   222   in conj_elims th1 @ conj_elims th2 end handle THM _ => [th];
   223 
   224 val conj = @{term HOL.conj}
   225 and disj = @{term HOL.disj}
   226 and imp = @{term implies}
   227 and Not = @{term Not};
   228 
   229 fun mk_conj (t1, t2) = conj $ t1 $ t2
   230 and mk_disj (t1, t2) = disj $ t1 $ t2
   231 and mk_imp (t1, t2) = imp $ t1 $ t2
   232 and mk_not t = Not $ t;
   233 
   234 fun dest_conj (Const ("HOL.conj", _) $ t $ t') = t :: dest_conj t'
   235   | dest_conj t = [t];
   236 
   237 fun dest_disj (Const ("HOL.disj", _) $ t $ t') = t :: dest_disj t'
   238   | dest_disj t = [t];
   239 
   240 (*Like dest_disj, but flattens disjunctions however nested*)
   241 fun disjuncts_aux (Const ("HOL.disj", _) $ t $ t') disjs = disjuncts_aux t (disjuncts_aux t' disjs)
   242   | disjuncts_aux t disjs = t::disjs;
   243 
   244 fun disjuncts t = disjuncts_aux t [];
   245 
   246 fun dest_imp (Const ("HOL.implies", _) $ A $ B) = (A, B)
   247   | dest_imp  t = raise TERM ("dest_imp", [t]);
   248 
   249 fun dest_not (Const ("HOL.Not", _) $ t) = t
   250   | dest_not t = raise TERM ("dest_not", [t]);
   251 
   252 fun eq_const T = Const ("HOL.eq", T --> T --> boolT);
   253 fun mk_eq (t, u) = eq_const (fastype_of t) $ t $ u;
   254 
   255 fun dest_eq (Const ("HOL.eq", _) $ lhs $ rhs) = (lhs, rhs)
   256   | dest_eq t = raise TERM ("dest_eq", [t])
   257 
   258 fun all_const T = Const ("HOL.All", (T --> boolT) --> boolT);
   259 fun mk_all (x, T, P) = all_const T $ absfree (x, T) P;
   260 fun list_all (xs, t) = fold_rev (fn (x, T) => fn P => all_const T $ Abs (x, T, P)) xs t;
   261 
   262 fun exists_const T = Const ("HOL.Ex", (T --> boolT) --> boolT);
   263 fun mk_exists (x, T, P) = exists_const T $ absfree (x, T) P;
   264 
   265 fun choice_const T = Const("Hilbert_Choice.Eps", (T --> boolT) --> T);
   266 
   267 val class_equal = "HOL.equal";
   268 
   269 
   270 (* binary operations and relations *)
   271 
   272 fun mk_binop c (t, u) =
   273   let val T = fastype_of t
   274   in Const (c, T --> T --> T) $ t $ u end;
   275 
   276 fun mk_binrel c (t, u) =
   277   let val T = fastype_of t
   278   in Const (c, T --> T --> boolT) $ t $ u end;
   279 
   280 (*destruct the application of a binary operator. The dummyT case is a crude
   281   way of handling polymorphic operators.*)
   282 fun dest_bin c T (tm as Const (c', Type ("fun", [T', _])) $ t $ u) =
   283       if c = c' andalso (T=T' orelse T=dummyT) then (t, u)
   284       else raise TERM ("dest_bin " ^ c, [tm])
   285   | dest_bin c _ tm = raise TERM ("dest_bin " ^ c, [tm]);
   286 
   287 
   288 (* unit *)
   289 
   290 val unitT = Type ("Product_Type.unit", []);
   291 
   292 fun is_unitT (Type ("Product_Type.unit", [])) = true
   293   | is_unitT _ = false;
   294 
   295 val unit = Const ("Product_Type.Unity", unitT);
   296 
   297 fun is_unit (Const ("Product_Type.Unity", _)) = true
   298   | is_unit _ = false;
   299 
   300 
   301 (* prod *)
   302 
   303 fun mk_prodT (T1, T2) = Type ("Product_Type.prod", [T1, T2]);
   304 
   305 fun dest_prodT (Type ("Product_Type.prod", [T1, T2])) = (T1, T2)
   306   | dest_prodT T = raise TYPE ("dest_prodT", [T], []);
   307 
   308 fun pair_const T1 T2 = Const ("Product_Type.Pair", T1 --> T2 --> mk_prodT (T1, T2));
   309 
   310 fun mk_prod (t1, t2) =
   311   let val T1 = fastype_of t1 and T2 = fastype_of t2 in
   312     pair_const T1 T2 $ t1 $ t2
   313   end;
   314 
   315 fun dest_prod (Const ("Product_Type.Pair", _) $ t1 $ t2) = (t1, t2)
   316   | dest_prod t = raise TERM ("dest_prod", [t]);
   317 
   318 fun mk_fst p =
   319   let val pT = fastype_of p in
   320     Const ("Product_Type.fst", pT --> fst (dest_prodT pT)) $ p
   321   end;
   322 
   323 fun mk_snd p =
   324   let val pT = fastype_of p in
   325     Const ("Product_Type.snd", pT --> snd (dest_prodT pT)) $ p
   326   end;
   327 
   328 fun split_const (A, B, C) =
   329   Const ("Product_Type.prod.prod_case", (A --> B --> C) --> mk_prodT (A, B) --> C);
   330 
   331 fun mk_split t =
   332   (case Term.fastype_of t of
   333     T as (Type ("fun", [A, Type ("fun", [B, C])])) =>
   334       Const ("Product_Type.prod.prod_case", T --> mk_prodT (A, B) --> C) $ t
   335   | _ => raise TERM ("mk_split: bad body type", [t]));
   336 
   337 (*Maps the type T1 * ... * Tn to [T1, ..., Tn], however nested*)
   338 fun flatten_tupleT (Type ("Product_Type.prod", [T1, T2])) = flatten_tupleT T1 @ flatten_tupleT T2
   339   | flatten_tupleT T = [T];
   340 
   341 (*abstraction over nested tuples*)
   342 fun tupled_lambda (x as Free _) b = lambda x b
   343   | tupled_lambda (x as Var _) b = lambda x b
   344   | tupled_lambda (Const ("Product_Type.Pair", _) $ u $ v) b =
   345       mk_split (tupled_lambda u (tupled_lambda v b))
   346   | tupled_lambda (Const ("Product_Type.Unity", _)) b =
   347       Abs ("x", unitT, b)
   348   | tupled_lambda t _ = raise TERM ("tupled_lambda: bad tuple", [t]);
   349 
   350 
   351 (* tuples with right-fold structure *)
   352 
   353 fun mk_tupleT [] = unitT
   354   | mk_tupleT Ts = foldr1 mk_prodT Ts;
   355 
   356 fun strip_tupleT (Type ("Product_Type.unit", [])) = []
   357   | strip_tupleT (Type ("Product_Type.prod", [T1, T2])) = T1 :: strip_tupleT T2
   358   | strip_tupleT T = [T];
   359 
   360 fun mk_tuple [] = unit
   361   | mk_tuple ts = foldr1 mk_prod ts;
   362 
   363 fun strip_tuple (Const ("Product_Type.Unity", _)) = []
   364   | strip_tuple (Const ("Product_Type.Pair", _) $ t1 $ t2) = t1 :: strip_tuple t2
   365   | strip_tuple t = [t];
   366 
   367 
   368 (* tuples with specific arities
   369 
   370    an "arity" of a tuple is a list of lists of integers,
   371    denoting paths to subterms that are pairs
   372 *)
   373 
   374 fun ptuple_err s = raise TERM (s ^ ": inconsistent use of nested products", []);
   375 
   376 fun mk_ptupleT ps =
   377   let
   378     fun mk p Ts =
   379       if member (op =) ps p then
   380         let
   381           val (T, Ts') = mk (1::p) Ts;
   382           val (U, Ts'') = mk (2::p) Ts'
   383         in (mk_prodT (T, U), Ts'') end
   384       else (hd Ts, tl Ts)
   385   in fst o mk [] end;
   386 
   387 fun strip_ptupleT ps =
   388   let
   389     fun factors p T = if member (op =) ps p then (case T of
   390         Type ("Product_Type.prod", [T1, T2]) =>
   391           factors (1::p) T1 @ factors (2::p) T2
   392       | _ => ptuple_err "strip_ptupleT") else [T]
   393   in factors [] end;
   394 
   395 val flat_tupleT_paths =
   396   let
   397     fun factors p (Type ("Product_Type.prod", [T1, T2])) =
   398           p :: factors (1::p) T1 @ factors (2::p) T2
   399       | factors p _ = []
   400   in factors [] end;
   401 
   402 fun mk_ptuple ps =
   403   let
   404     fun mk p T ts =
   405       if member (op =) ps p then (case T of
   406           Type ("Product_Type.prod", [T1, T2]) =>
   407             let
   408               val (t, ts') = mk (1::p) T1 ts;
   409               val (u, ts'') = mk (2::p) T2 ts'
   410             in (pair_const T1 T2 $ t $ u, ts'') end
   411         | _ => ptuple_err "mk_ptuple")
   412       else (hd ts, tl ts)
   413   in fst oo mk [] end;
   414 
   415 fun strip_ptuple ps =
   416   let
   417     fun dest p t = if member (op =) ps p then (case t of
   418         Const ("Product_Type.Pair", _) $ t $ u =>
   419           dest (1::p) t @ dest (2::p) u
   420       | _ => ptuple_err "strip_ptuple") else [t]
   421   in dest [] end;
   422 
   423 val flat_tuple_paths =
   424   let
   425     fun factors p (Const ("Product_Type.Pair", _) $ t $ u) =
   426           p :: factors (1::p) t @ factors (2::p) u
   427       | factors p _ = []
   428   in factors [] end;
   429 
   430 (*In mk_psplits ps S T u, term u expects separate arguments for the factors of S,
   431   with result type T.  The call creates a new term expecting one argument
   432   of type S.*)
   433 fun mk_psplits ps T T3 u =
   434   let
   435     fun ap ((p, T) :: pTs) =
   436           if member (op =) ps p then (case T of
   437               Type ("Product_Type.prod", [T1, T2]) =>
   438                 split_const (T1, T2, map snd pTs ---> T3) $
   439                   ap ((1::p, T1) :: (2::p, T2) :: pTs)
   440             | _ => ptuple_err "mk_psplits")
   441           else Abs ("x", T, ap pTs)
   442       | ap [] =
   443           let val k = length ps
   444           in list_comb (incr_boundvars (k + 1) u, map Bound (k downto 0)) end
   445   in ap [([], T)] end;
   446 
   447 val strip_psplits =
   448   let
   449     fun strip [] qs Ts t = (t, rev Ts, qs)
   450       | strip (p :: ps) qs Ts (Const ("Product_Type.prod.prod_case", _) $ t) =
   451           strip ((1 :: p) :: (2 :: p) :: ps) (p :: qs) Ts t
   452       | strip (p :: ps) qs Ts (Abs (s, T, t)) = strip ps qs (T :: Ts) t
   453       | strip (p :: ps) qs Ts t = strip ps qs
   454           (hd (binder_types (fastype_of1 (Ts, t))) :: Ts)
   455           (incr_boundvars 1 t $ Bound 0)
   456   in strip [[]] [] [] end;
   457 
   458 
   459 (* nat *)
   460 
   461 val natT = Type ("Nat.nat", []);
   462 
   463 val zero = Const ("Groups.zero_class.zero", natT);
   464 
   465 fun is_zero (Const ("Groups.zero_class.zero", _)) = true
   466   | is_zero _ = false;
   467 
   468 fun mk_Suc t = Const ("Nat.Suc", natT --> natT) $ t;
   469 
   470 fun dest_Suc (Const ("Nat.Suc", _) $ t) = t
   471   | dest_Suc t = raise TERM ("dest_Suc", [t]);
   472 
   473 val Suc_zero = mk_Suc zero;
   474 
   475 fun mk_nat n =
   476   let
   477     fun mk 0 = zero
   478       | mk n = mk_Suc (mk (n - 1));
   479   in if n < 0 then raise TERM ("mk_nat: negative number", []) else mk n end;
   480 
   481 fun dest_nat (Const ("Groups.zero_class.zero", _)) = 0
   482   | dest_nat (Const ("Nat.Suc", _) $ t) = dest_nat t + 1
   483   | dest_nat t = raise TERM ("dest_nat", [t]);
   484 
   485 val class_size = "Nat.size";
   486 
   487 fun size_const T = Const ("Nat.size_class.size", T --> natT);
   488 
   489 
   490 (* code numeral *)
   491 
   492 val code_numeralT = Type ("Code_Numeral.code_numeral", []);
   493 
   494 
   495 (* binary numerals and int *)
   496 
   497 val numT = Type ("Num.num", []);
   498 val intT = Type ("Int.int", []);
   499 
   500 val one_const = Const ("Num.num.One", numT)
   501 and bit0_const = Const ("Num.num.Bit0", numT --> numT)
   502 and bit1_const = Const ("Num.num.Bit1", numT --> numT);
   503 
   504 fun mk_bit 0 = bit0_const
   505   | mk_bit 1 = bit1_const
   506   | mk_bit _ = raise TERM ("mk_bit", []);
   507 
   508 fun dest_bit (Const ("Num.num.Bit0", _)) = 0
   509   | dest_bit (Const ("Num.num.Bit1", _)) = 1
   510   | dest_bit t = raise TERM ("dest_bit", [t]);
   511 
   512 fun mk_numeral i =
   513   let fun mk 1 = one_const
   514         | mk i = let val (q, r) = Integer.div_mod i 2 in mk_bit r $ mk q end
   515   in if i > 0 then mk i else raise TERM ("mk_numeral: " ^ string_of_int i, [])
   516   end
   517 
   518 fun dest_num (Const ("Num.num.One", _)) = 1
   519   | dest_num (Const ("Num.num.Bit0", _) $ bs) = 2 * dest_num bs
   520   | dest_num (Const ("Num.num.Bit1", _) $ bs) = 2 * dest_num bs + 1
   521   | dest_num t = raise TERM ("dest_num", [t]);
   522 
   523 fun numeral_const T = Const ("Num.numeral_class.numeral", numT --> T);
   524 fun neg_numeral_const T = Const ("Num.neg_numeral_class.neg_numeral", numT --> T);
   525 
   526 fun add_numerals (Const ("Num.numeral_class.numeral", Type (_, [_, T])) $ t) = cons (t, T)
   527   | add_numerals (t $ u) = add_numerals t #> add_numerals u
   528   | add_numerals (Abs (_, _, t)) = add_numerals t
   529   | add_numerals _ = I;
   530 
   531 fun mk_number T 0 = Const ("Groups.zero_class.zero", T)
   532   | mk_number T 1 = Const ("Groups.one_class.one", T)
   533   | mk_number T i =
   534     if i > 0 then numeral_const T $ mk_numeral i
   535     else neg_numeral_const T $ mk_numeral (~ i);
   536 
   537 fun dest_number (Const ("Groups.zero_class.zero", T)) = (T, 0)
   538   | dest_number (Const ("Groups.one_class.one", T)) = (T, 1)
   539   | dest_number (Const ("Num.numeral_class.numeral", Type ("fun", [_, T])) $ t) =
   540       (T, dest_num t)
   541   | dest_number (Const ("Num.neg_numeral_class.neg_numeral", Type ("fun", [_, T])) $ t) =
   542       (T, ~ (dest_num t))
   543   | dest_number t = raise TERM ("dest_number", [t]);
   544 
   545 
   546 (* real *)
   547 
   548 val realT = Type ("RealDef.real", []);
   549 
   550 
   551 (* list *)
   552 
   553 fun listT T = Type ("List.list", [T]);
   554 
   555 fun nil_const T = Const ("List.list.Nil", listT T);
   556 
   557 fun cons_const T =
   558   let val lT = listT T
   559   in Const ("List.list.Cons", T --> lT --> lT) end;
   560 
   561 fun mk_list T ts =
   562   let
   563     val lT = listT T;
   564     val Nil = Const ("List.list.Nil", lT);
   565     fun Cons t u = Const ("List.list.Cons", T --> lT --> lT) $ t $ u;
   566   in fold_rev Cons ts Nil end;
   567 
   568 fun dest_list (Const ("List.list.Nil", _)) = []
   569   | dest_list (Const ("List.list.Cons", _) $ t $ u) = t :: dest_list u
   570   | dest_list t = raise TERM ("dest_list", [t]);
   571 
   572 
   573 (* nibble *)
   574 
   575 val nibbleT = Type ("String.nibble", []);
   576 
   577 fun mk_nibble n =
   578   let val s =
   579     if 0 <= n andalso n <= 9 then chr (n + ord "0")
   580     else if 10 <= n andalso n <= 15 then chr (n + ord "A" - 10)
   581     else raise TERM ("mk_nibble", [])
   582   in Const ("String.nibble.Nibble" ^ s, nibbleT) end;
   583 
   584 fun dest_nibble t =
   585   let fun err () = raise TERM ("dest_nibble", [t]) in
   586     (case try (unprefix "String.nibble.Nibble" o fst o Term.dest_Const) t of
   587       NONE => err ()
   588     | SOME c =>
   589         if size c <> 1 then err ()
   590         else if "0" <= c andalso c <= "9" then ord c - ord "0"
   591         else if "A" <= c andalso c <= "F" then ord c - ord "A" + 10
   592         else err ())
   593   end;
   594 
   595 
   596 (* char *)
   597 
   598 val charT = Type ("String.char", []);
   599 
   600 fun mk_char n =
   601   if 0 <= n andalso n <= 255 then
   602     Const ("String.char.Char", nibbleT --> nibbleT --> charT) $
   603       mk_nibble (n div 16) $ mk_nibble (n mod 16)
   604   else raise TERM ("mk_char", []);
   605 
   606 fun dest_char (Const ("String.char.Char", _) $ t $ u) =
   607       dest_nibble t * 16 + dest_nibble u
   608   | dest_char t = raise TERM ("dest_char", [t]);
   609 
   610 
   611 (* string *)
   612 
   613 val stringT = listT charT;
   614 
   615 val mk_string = mk_list charT o map (mk_char o ord) o raw_explode;
   616 val dest_string = implode o map (chr o dest_char) o dest_list;
   617 
   618 
   619 (* literal *)
   620 
   621 val literalT = Type ("String.literal", []);
   622 
   623 fun mk_literal s = Const ("String.STR", stringT --> literalT)
   624       $ mk_string s;
   625 fun dest_literal (Const ("String.STR", _) $ t) =
   626       dest_string t
   627   | dest_literal t = raise TERM ("dest_literal", [t]);
   628 
   629 
   630 (* typerep and term *)
   631 
   632 val typerepT = Type ("Typerep.typerep", []);
   633 
   634 fun mk_typerep (Type (tyco, Ts)) = Const ("Typerep.typerep.Typerep",
   635       literalT --> listT typerepT --> typerepT) $ mk_literal tyco
   636         $ mk_list typerepT (map mk_typerep Ts)
   637   | mk_typerep (T as TFree _) = Const ("Typerep.typerep_class.typerep",
   638       Term.itselfT T --> typerepT) $ Logic.mk_type T;
   639 
   640 val termT = Type ("Code_Evaluation.term", []);
   641 
   642 fun term_of_const T = Const ("Code_Evaluation.term_of_class.term_of", T --> termT);
   643 
   644 fun mk_term_of T t = term_of_const T $ t;
   645 
   646 fun reflect_term (Const (c, T)) =
   647       Const ("Code_Evaluation.Const", literalT --> typerepT --> termT)
   648         $ mk_literal c $ mk_typerep T
   649   | reflect_term (t1 $ t2) =
   650       Const ("Code_Evaluation.App", termT --> termT --> termT)
   651         $ reflect_term t1 $ reflect_term t2
   652   | reflect_term (Abs (v, _, t)) = Abs (v, termT, reflect_term t)
   653   | reflect_term t = t;
   654 
   655 fun mk_valtermify_app c vs T =
   656   let
   657     fun termifyT T = mk_prodT (T, unitT --> termT);
   658     fun valapp T T' = Const ("Code_Evaluation.valapp",
   659       termifyT (T --> T') --> termifyT T --> termifyT T');
   660     fun mk_fTs [] _ = []
   661       | mk_fTs (_ :: Ts) T = (Ts ---> T) :: mk_fTs Ts T;
   662     val Ts = map snd vs;
   663     val t = Const (c, Ts ---> T);
   664     val tt = mk_prod (t, Abs ("u", unitT, reflect_term t));
   665     fun app (fT, (v, T)) t = valapp T fT $ t $ Free (v, termifyT T);
   666   in fold app (mk_fTs Ts T ~~ vs) tt end;
   667 
   668 
   669 (* open state monads *)
   670 
   671 fun mk_return T U x = pair_const T U $ x;
   672 
   673 fun mk_ST clauses t U (someT, V) =
   674   let
   675     val R = case someT of SOME T => mk_prodT (T, V) | NONE => V
   676     fun mk_clause ((t, U), SOME (v, T)) (t', U') =
   677           (Const ("Product_Type.scomp", (U --> mk_prodT (T, U')) --> (T --> U' --> R) --> U --> R)
   678             $ t $ lambda (Free (v, T)) t', U)
   679       | mk_clause ((t, U), NONE) (t', U') =
   680           (Const ("Product_Type.fcomp", (U --> U') --> (U' --> R) --> U --> R)
   681             $ t $ t', U)
   682   in fold_rev mk_clause clauses (t, U) |> fst end;
   683 
   684 
   685 (* random seeds *)
   686 
   687 val random_seedT = mk_prodT (code_numeralT, code_numeralT);
   688 
   689 fun mk_random T t = Const ("Quickcheck.random_class.random", code_numeralT
   690   --> random_seedT --> mk_prodT (mk_prodT (T, unitT --> termT), random_seedT)) $ t;
   691 
   692 end;