src/HOL/Series.thy
author paulson <lp15@cam.ac.uk>
Fri Jan 22 16:00:03 2016 +0000 (2016-01-22)
changeset 62217 527488dc8b90
parent 62087 44841d07ef1d
child 62368 106569399cd6
permissions -rw-r--r--
Reorganised a huge proof
     1 (*  Title       : Series.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4 
     5 Converted to Isar and polished by lcp
     6 Converted to setsum and polished yet more by TNN
     7 Additional contributions by Jeremy Avigad
     8 *)
     9 
    10 section \<open>Infinite Series\<close>
    11 
    12 theory Series
    13 imports Limits Inequalities
    14 begin
    15 
    16 subsection \<open>Definition of infinite summability\<close>
    17 
    18 definition
    19   sums :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a \<Rightarrow> bool"
    20   (infixr "sums" 80)
    21 where
    22   "f sums s \<longleftrightarrow> (\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> s"
    23 
    24 definition summable :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> bool" where
    25    "summable f \<longleftrightarrow> (\<exists>s. f sums s)"
    26 
    27 definition
    28   suminf :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a"
    29   (binder "\<Sum>" 10)
    30 where
    31   "suminf f = (THE s. f sums s)"
    32 
    33 lemma sums_def': "f sums s \<longleftrightarrow> (\<lambda>n. \<Sum>i = 0..n. f i) \<longlonglongrightarrow> s"
    34   apply (simp add: sums_def)
    35   apply (subst LIMSEQ_Suc_iff [symmetric])
    36   apply (simp only: lessThan_Suc_atMost atLeast0AtMost)
    37   done
    38 
    39 subsection \<open>Infinite summability on topological monoids\<close>
    40 
    41 lemma sums_subst[trans]: "f = g \<Longrightarrow> g sums z \<Longrightarrow> f sums z"
    42   by simp
    43 
    44 lemma sums_cong: "(\<And>n. f n = g n) \<Longrightarrow> f sums c \<longleftrightarrow> g sums c"
    45   by (drule ext) simp
    46 
    47 lemma sums_summable: "f sums l \<Longrightarrow> summable f"
    48   by (simp add: sums_def summable_def, blast)
    49 
    50 lemma summable_iff_convergent: "summable f \<longleftrightarrow> convergent (\<lambda>n. \<Sum>i<n. f i)"
    51   by (simp add: summable_def sums_def convergent_def)
    52 
    53 lemma summable_iff_convergent':
    54   "summable f \<longleftrightarrow> convergent (\<lambda>n. setsum f {..n})"
    55   by (simp_all only: summable_iff_convergent convergent_def
    56         lessThan_Suc_atMost [symmetric] LIMSEQ_Suc_iff[of "\<lambda>n. setsum f {..<n}"])
    57 
    58 lemma suminf_eq_lim: "suminf f = lim (\<lambda>n. \<Sum>i<n. f i)"
    59   by (simp add: suminf_def sums_def lim_def)
    60 
    61 lemma sums_zero[simp, intro]: "(\<lambda>n. 0) sums 0"
    62   unfolding sums_def by simp
    63 
    64 lemma summable_zero[simp, intro]: "summable (\<lambda>n. 0)"
    65   by (rule sums_zero [THEN sums_summable])
    66 
    67 lemma sums_group: "f sums s \<Longrightarrow> 0 < k \<Longrightarrow> (\<lambda>n. setsum f {n * k ..< n * k + k}) sums s"
    68   apply (simp only: sums_def setsum_nat_group tendsto_def eventually_sequentially)
    69   apply safe
    70   apply (erule_tac x=S in allE)
    71   apply safe
    72   apply (rule_tac x="N" in exI, safe)
    73   apply (drule_tac x="n*k" in spec)
    74   apply (erule mp)
    75   apply (erule order_trans)
    76   apply simp
    77   done
    78 
    79 lemma suminf_cong: "(\<And>n. f n = g n) \<Longrightarrow> suminf f = suminf g"
    80   by (rule arg_cong[of f g], rule ext) simp
    81 
    82 lemma summable_cong:
    83   assumes "eventually (\<lambda>x. f x = (g x :: 'a :: real_normed_vector)) sequentially"
    84   shows   "summable f = summable g"
    85 proof -
    86   from assms obtain N where N: "\<forall>n\<ge>N. f n = g n" by (auto simp: eventually_at_top_linorder)
    87   def C \<equiv> "(\<Sum>k<N. f k - g k)"
    88   from eventually_ge_at_top[of N]
    89     have "eventually (\<lambda>n. setsum f {..<n} = C + setsum g {..<n}) sequentially"
    90   proof eventually_elim
    91     fix n assume n: "n \<ge> N"
    92     from n have "{..<n} = {..<N} \<union> {N..<n}" by auto
    93     also have "setsum f ... = setsum f {..<N} + setsum f {N..<n}"
    94       by (intro setsum.union_disjoint) auto
    95     also from N have "setsum f {N..<n} = setsum g {N..<n}" by (intro setsum.cong) simp_all
    96     also have "setsum f {..<N} + setsum g {N..<n} = C + (setsum g {..<N} + setsum g {N..<n})"
    97       unfolding C_def by (simp add: algebra_simps setsum_subtractf)
    98     also have "setsum g {..<N} + setsum g {N..<n} = setsum g ({..<N} \<union> {N..<n})"
    99       by (intro setsum.union_disjoint [symmetric]) auto
   100     also from n have "{..<N} \<union> {N..<n} = {..<n}" by auto
   101     finally show "setsum f {..<n} = C + setsum g {..<n}" .
   102   qed
   103   from convergent_cong[OF this] show ?thesis
   104     by (simp add: summable_iff_convergent convergent_add_const_iff)
   105 qed
   106 
   107 lemma sums_finite:
   108   assumes [simp]: "finite N" and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   109   shows "f sums (\<Sum>n\<in>N. f n)"
   110 proof -
   111   { fix n
   112     have "setsum f {..<n + Suc (Max N)} = setsum f N"
   113     proof cases
   114       assume "N = {}"
   115       with f have "f = (\<lambda>x. 0)" by auto
   116       then show ?thesis by simp
   117     next
   118       assume [simp]: "N \<noteq> {}"
   119       show ?thesis
   120       proof (safe intro!: setsum.mono_neutral_right f)
   121         fix i assume "i \<in> N"
   122         then have "i \<le> Max N" by simp
   123         then show "i < n + Suc (Max N)" by simp
   124       qed
   125     qed }
   126   note eq = this
   127   show ?thesis unfolding sums_def
   128     by (rule LIMSEQ_offset[of _ "Suc (Max N)"])
   129        (simp add: eq atLeast0LessThan del: add_Suc_right)
   130 qed
   131 
   132 corollary sums_0:
   133    "(\<And>n. f n = 0) \<Longrightarrow> (f sums 0)"
   134     by (metis (no_types) finite.emptyI setsum.empty sums_finite)
   135 
   136 lemma summable_finite: "finite N \<Longrightarrow> (\<And>n. n \<notin> N \<Longrightarrow> f n = 0) \<Longrightarrow> summable f"
   137   by (rule sums_summable) (rule sums_finite)
   138 
   139 lemma sums_If_finite_set: "finite A \<Longrightarrow> (\<lambda>r. if r \<in> A then f r else 0) sums (\<Sum>r\<in>A. f r)"
   140   using sums_finite[of A "(\<lambda>r. if r \<in> A then f r else 0)"] by simp
   141 
   142 lemma summable_If_finite_set[simp, intro]: "finite A \<Longrightarrow> summable (\<lambda>r. if r \<in> A then f r else 0)"
   143   by (rule sums_summable) (rule sums_If_finite_set)
   144 
   145 lemma sums_If_finite: "finite {r. P r} \<Longrightarrow> (\<lambda>r. if P r then f r else 0) sums (\<Sum>r | P r. f r)"
   146   using sums_If_finite_set[of "{r. P r}"] by simp
   147 
   148 lemma summable_If_finite[simp, intro]: "finite {r. P r} \<Longrightarrow> summable (\<lambda>r. if P r then f r else 0)"
   149   by (rule sums_summable) (rule sums_If_finite)
   150 
   151 lemma sums_single: "(\<lambda>r. if r = i then f r else 0) sums f i"
   152   using sums_If_finite[of "\<lambda>r. r = i"] by simp
   153 
   154 lemma summable_single[simp, intro]: "summable (\<lambda>r. if r = i then f r else 0)"
   155   by (rule sums_summable) (rule sums_single)
   156 
   157 context
   158   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   159 begin
   160 
   161 lemma summable_sums[intro]: "summable f \<Longrightarrow> f sums (suminf f)"
   162   by (simp add: summable_def sums_def suminf_def)
   163      (metis convergent_LIMSEQ_iff convergent_def lim_def)
   164 
   165 lemma summable_LIMSEQ: "summable f \<Longrightarrow> (\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> suminf f"
   166   by (rule summable_sums [unfolded sums_def])
   167 
   168 lemma sums_unique: "f sums s \<Longrightarrow> s = suminf f"
   169   by (metis limI suminf_eq_lim sums_def)
   170 
   171 lemma sums_iff: "f sums x \<longleftrightarrow> summable f \<and> (suminf f = x)"
   172   by (metis summable_sums sums_summable sums_unique)
   173 
   174 lemma summable_sums_iff:
   175   "summable (f :: nat \<Rightarrow> 'a :: {comm_monoid_add,t2_space}) \<longleftrightarrow> f sums suminf f"
   176   by (auto simp: sums_iff summable_sums)
   177 
   178 lemma sums_unique2:
   179   fixes a b :: "'a::{comm_monoid_add,t2_space}"
   180   shows "f sums a \<Longrightarrow> f sums b \<Longrightarrow> a = b"
   181 by (simp add: sums_iff)
   182 
   183 lemma suminf_finite:
   184   assumes N: "finite N" and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   185   shows "suminf f = (\<Sum>n\<in>N. f n)"
   186   using sums_finite[OF assms, THEN sums_unique] by simp
   187 
   188 end
   189 
   190 lemma suminf_zero[simp]: "suminf (\<lambda>n. 0::'a::{t2_space, comm_monoid_add}) = 0"
   191   by (rule sums_zero [THEN sums_unique, symmetric])
   192 
   193 
   194 subsection \<open>Infinite summability on ordered, topological monoids\<close>
   195 
   196 lemma sums_le:
   197   fixes f g :: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology}"
   198   shows "\<forall>n. f n \<le> g n \<Longrightarrow> f sums s \<Longrightarrow> g sums t \<Longrightarrow> s \<le> t"
   199   by (rule LIMSEQ_le) (auto intro: setsum_mono simp: sums_def)
   200 
   201 context
   202   fixes f :: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology}"
   203 begin
   204 
   205 lemma suminf_le: "\<lbrakk>\<forall>n. f n \<le> g n; summable f; summable g\<rbrakk> \<Longrightarrow> suminf f \<le> suminf g"
   206   by (auto dest: sums_summable intro: sums_le)
   207 
   208 lemma setsum_le_suminf: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 \<le> f m \<Longrightarrow> setsum f {..<n} \<le> suminf f"
   209   by (rule sums_le[OF _ sums_If_finite_set summable_sums]) auto
   210 
   211 lemma suminf_nonneg: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 \<le> suminf f"
   212   using setsum_le_suminf[of 0] by simp
   213 
   214 lemma setsum_less_suminf2: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 \<le> f m \<Longrightarrow> n \<le> i \<Longrightarrow> 0 < f i \<Longrightarrow> setsum f {..<n} < suminf f"
   215   using
   216     setsum_le_suminf[of "Suc i"]
   217     add_strict_increasing[of "f i" "setsum f {..<n}" "setsum f {..<i}"]
   218     setsum_mono2[of "{..<i}" "{..<n}" f]
   219   by (auto simp: less_imp_le ac_simps)
   220 
   221 lemma setsum_less_suminf: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 < f m \<Longrightarrow> setsum f {..<n} < suminf f"
   222   using setsum_less_suminf2[of n n] by (simp add: less_imp_le)
   223 
   224 lemma suminf_pos2: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 < f i \<Longrightarrow> 0 < suminf f"
   225   using setsum_less_suminf2[of 0 i] by simp
   226 
   227 lemma suminf_pos: "summable f \<Longrightarrow> \<forall>n. 0 < f n \<Longrightarrow> 0 < suminf f"
   228   using suminf_pos2[of 0] by (simp add: less_imp_le)
   229 
   230 lemma suminf_le_const: "summable f \<Longrightarrow> (\<And>n. setsum f {..<n} \<le> x) \<Longrightarrow> suminf f \<le> x"
   231   by (metis LIMSEQ_le_const2 summable_LIMSEQ)
   232 
   233 lemma suminf_eq_zero_iff: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> suminf f = 0 \<longleftrightarrow> (\<forall>n. f n = 0)"
   234 proof
   235   assume "summable f" "suminf f = 0" and pos: "\<forall>n. 0 \<le> f n"
   236   then have f: "(\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> 0"
   237     using summable_LIMSEQ[of f] by simp
   238   then have "\<And>i. (\<Sum>n\<in>{i}. f n) \<le> 0"
   239   proof (rule LIMSEQ_le_const)
   240     fix i show "\<exists>N. \<forall>n\<ge>N. (\<Sum>n\<in>{i}. f n) \<le> setsum f {..<n}"
   241       using pos by (intro exI[of _ "Suc i"] allI impI setsum_mono2) auto
   242   qed
   243   with pos show "\<forall>n. f n = 0"
   244     by (auto intro!: antisym)
   245 qed (metis suminf_zero fun_eq_iff)
   246 
   247 lemma suminf_pos_iff: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 < suminf f \<longleftrightarrow> (\<exists>i. 0 < f i)"
   248   using setsum_le_suminf[of 0] suminf_eq_zero_iff by (simp add: less_le)
   249 
   250 end
   251 
   252 lemma summableI_nonneg_bounded:
   253   fixes f:: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology, conditionally_complete_linorder}"
   254   assumes pos[simp]: "\<And>n. 0 \<le> f n" and le: "\<And>n. (\<Sum>i<n. f i) \<le> x"
   255   shows "summable f"
   256   unfolding summable_def sums_def[abs_def]
   257 proof (intro exI order_tendstoI)
   258   have [simp, intro]: "bdd_above (range (\<lambda>n. \<Sum>i<n. f i))"
   259     using le by (auto simp: bdd_above_def)
   260   { fix a assume "a < (SUP n. \<Sum>i<n. f i)"
   261     then obtain n where "a < (\<Sum>i<n. f i)"
   262       by (auto simp add: less_cSUP_iff)
   263     then have "\<And>m. n \<le> m \<Longrightarrow> a < (\<Sum>i<m. f i)"
   264       by (rule less_le_trans) (auto intro!: setsum_mono2)
   265     then show "eventually (\<lambda>n. a < (\<Sum>i<n. f i)) sequentially"
   266       by (auto simp: eventually_sequentially) }
   267   { fix a assume "(SUP n. \<Sum>i<n. f i) < a"
   268     moreover have "\<And>n. (\<Sum>i<n. f i) \<le> (SUP n. \<Sum>i<n. f i)"
   269       by (auto intro: cSUP_upper)
   270     ultimately show "eventually (\<lambda>n. (\<Sum>i<n. f i) < a) sequentially"
   271       by (auto intro: le_less_trans simp: eventually_sequentially) }
   272 qed
   273 
   274 
   275 subsection \<open>Infinite summability on real normed vector spaces\<close>
   276 
   277 lemma sums_Suc_iff:
   278   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   279   shows "(\<lambda>n. f (Suc n)) sums s \<longleftrightarrow> f sums (s + f 0)"
   280 proof -
   281   have "f sums (s + f 0) \<longleftrightarrow> (\<lambda>i. \<Sum>j<Suc i. f j) \<longlonglongrightarrow> s + f 0"
   282     by (subst LIMSEQ_Suc_iff) (simp add: sums_def)
   283   also have "\<dots> \<longleftrightarrow> (\<lambda>i. (\<Sum>j<i. f (Suc j)) + f 0) \<longlonglongrightarrow> s + f 0"
   284     by (simp add: ac_simps setsum.reindex image_iff lessThan_Suc_eq_insert_0)
   285   also have "\<dots> \<longleftrightarrow> (\<lambda>n. f (Suc n)) sums s"
   286   proof
   287     assume "(\<lambda>i. (\<Sum>j<i. f (Suc j)) + f 0) \<longlonglongrightarrow> s + f 0"
   288     with tendsto_add[OF this tendsto_const, of "- f 0"]
   289     show "(\<lambda>i. f (Suc i)) sums s"
   290       by (simp add: sums_def)
   291   qed (auto intro: tendsto_add simp: sums_def)
   292   finally show ?thesis ..
   293 qed
   294 
   295 lemma summable_Suc_iff: "summable (\<lambda>n. f (Suc n) :: 'a :: real_normed_vector) = summable f"
   296 proof
   297   assume "summable f"
   298   hence "f sums suminf f" by (rule summable_sums)
   299   hence "(\<lambda>n. f (Suc n)) sums (suminf f - f 0)" by (simp add: sums_Suc_iff)
   300   thus "summable (\<lambda>n. f (Suc n))" unfolding summable_def by blast
   301 qed (auto simp: sums_Suc_iff summable_def)
   302 
   303 context
   304   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   305 begin
   306 
   307 lemma sums_add: "f sums a \<Longrightarrow> g sums b \<Longrightarrow> (\<lambda>n. f n + g n) sums (a + b)"
   308   unfolding sums_def by (simp add: setsum.distrib tendsto_add)
   309 
   310 lemma summable_add: "summable f \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. f n + g n)"
   311   unfolding summable_def by (auto intro: sums_add)
   312 
   313 lemma suminf_add: "summable f \<Longrightarrow> summable g \<Longrightarrow> suminf f + suminf g = (\<Sum>n. f n + g n)"
   314   by (intro sums_unique sums_add summable_sums)
   315 
   316 lemma sums_diff: "f sums a \<Longrightarrow> g sums b \<Longrightarrow> (\<lambda>n. f n - g n) sums (a - b)"
   317   unfolding sums_def by (simp add: setsum_subtractf tendsto_diff)
   318 
   319 lemma summable_diff: "summable f \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. f n - g n)"
   320   unfolding summable_def by (auto intro: sums_diff)
   321 
   322 lemma suminf_diff: "summable f \<Longrightarrow> summable g \<Longrightarrow> suminf f - suminf g = (\<Sum>n. f n - g n)"
   323   by (intro sums_unique sums_diff summable_sums)
   324 
   325 lemma sums_minus: "f sums a \<Longrightarrow> (\<lambda>n. - f n) sums (- a)"
   326   unfolding sums_def by (simp add: setsum_negf tendsto_minus)
   327 
   328 lemma summable_minus: "summable f \<Longrightarrow> summable (\<lambda>n. - f n)"
   329   unfolding summable_def by (auto intro: sums_minus)
   330 
   331 lemma suminf_minus: "summable f \<Longrightarrow> (\<Sum>n. - f n) = - (\<Sum>n. f n)"
   332   by (intro sums_unique [symmetric] sums_minus summable_sums)
   333 
   334 lemma sums_Suc: "(\<lambda> n. f (Suc n)) sums l \<Longrightarrow> f sums (l + f 0)"
   335   by (simp add: sums_Suc_iff)
   336 
   337 lemma sums_iff_shift: "(\<lambda>i. f (i + n)) sums s \<longleftrightarrow> f sums (s + (\<Sum>i<n. f i))"
   338 proof (induct n arbitrary: s)
   339   case (Suc n)
   340   moreover have "(\<lambda>i. f (Suc i + n)) sums s \<longleftrightarrow> (\<lambda>i. f (i + n)) sums (s + f n)"
   341     by (subst sums_Suc_iff) simp
   342   ultimately show ?case
   343     by (simp add: ac_simps)
   344 qed simp
   345 
   346 lemma summable_iff_shift: "summable (\<lambda>n. f (n + k)) \<longleftrightarrow> summable f"
   347   by (metis diff_add_cancel summable_def sums_iff_shift[abs_def])
   348 
   349 lemma sums_split_initial_segment: "f sums s \<Longrightarrow> (\<lambda>i. f (i + n)) sums (s - (\<Sum>i<n. f i))"
   350   by (simp add: sums_iff_shift)
   351 
   352 lemma summable_ignore_initial_segment: "summable f \<Longrightarrow> summable (\<lambda>n. f(n + k))"
   353   by (simp add: summable_iff_shift)
   354 
   355 lemma suminf_minus_initial_segment: "summable f \<Longrightarrow> (\<Sum>n. f (n + k)) = (\<Sum>n. f n) - (\<Sum>i<k. f i)"
   356   by (rule sums_unique[symmetric]) (auto simp: sums_iff_shift)
   357 
   358 lemma suminf_split_initial_segment: "summable f \<Longrightarrow> suminf f = (\<Sum>n. f(n + k)) + (\<Sum>i<k. f i)"
   359   by (auto simp add: suminf_minus_initial_segment)
   360 
   361 lemma suminf_split_head: "summable f \<Longrightarrow> (\<Sum>n. f (Suc n)) = suminf f - f 0"
   362   using suminf_split_initial_segment[of 1] by simp
   363 
   364 lemma suminf_exist_split:
   365   fixes r :: real assumes "0 < r" and "summable f"
   366   shows "\<exists>N. \<forall>n\<ge>N. norm (\<Sum>i. f (i + n)) < r"
   367 proof -
   368   from LIMSEQ_D[OF summable_LIMSEQ[OF \<open>summable f\<close>] \<open>0 < r\<close>]
   369   obtain N :: nat where "\<forall> n \<ge> N. norm (setsum f {..<n} - suminf f) < r" by auto
   370   thus ?thesis
   371     by (auto simp: norm_minus_commute suminf_minus_initial_segment[OF \<open>summable f\<close>])
   372 qed
   373 
   374 lemma summable_LIMSEQ_zero: "summable f \<Longrightarrow> f \<longlonglongrightarrow> 0"
   375   apply (drule summable_iff_convergent [THEN iffD1])
   376   apply (drule convergent_Cauchy)
   377   apply (simp only: Cauchy_iff LIMSEQ_iff, safe)
   378   apply (drule_tac x="r" in spec, safe)
   379   apply (rule_tac x="M" in exI, safe)
   380   apply (drule_tac x="Suc n" in spec, simp)
   381   apply (drule_tac x="n" in spec, simp)
   382   done
   383 
   384 lemma summable_imp_convergent:
   385   "summable (f :: nat \<Rightarrow> 'a) \<Longrightarrow> convergent f"
   386   by (force dest!: summable_LIMSEQ_zero simp: convergent_def)
   387 
   388 lemma summable_imp_Bseq:
   389   "summable f \<Longrightarrow> Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector)"
   390   by (simp add: convergent_imp_Bseq summable_imp_convergent)
   391 
   392 end
   393 
   394 lemma summable_minus_iff:
   395   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   396   shows "summable (\<lambda>n. - f n) \<longleftrightarrow> summable f"
   397   by (auto dest: summable_minus) \<comment>\<open>used two ways, hence must be outside the context above\<close>
   398 
   399 
   400 context
   401   fixes f :: "'i \<Rightarrow> nat \<Rightarrow> 'a::real_normed_vector" and I :: "'i set"
   402 begin
   403 
   404 lemma sums_setsum: "(\<And>i. i \<in> I \<Longrightarrow> (f i) sums (x i)) \<Longrightarrow> (\<lambda>n. \<Sum>i\<in>I. f i n) sums (\<Sum>i\<in>I. x i)"
   405   by (induct I rule: infinite_finite_induct) (auto intro!: sums_add)
   406 
   407 lemma suminf_setsum: "(\<And>i. i \<in> I \<Longrightarrow> summable (f i)) \<Longrightarrow> (\<Sum>n. \<Sum>i\<in>I. f i n) = (\<Sum>i\<in>I. \<Sum>n. f i n)"
   408   using sums_unique[OF sums_setsum, OF summable_sums] by simp
   409 
   410 lemma summable_setsum: "(\<And>i. i \<in> I \<Longrightarrow> summable (f i)) \<Longrightarrow> summable (\<lambda>n. \<Sum>i\<in>I. f i n)"
   411   using sums_summable[OF sums_setsum[OF summable_sums]] .
   412 
   413 end
   414 
   415 lemma (in bounded_linear) sums: "(\<lambda>n. X n) sums a \<Longrightarrow> (\<lambda>n. f (X n)) sums (f a)"
   416   unfolding sums_def by (drule tendsto, simp only: setsum)
   417 
   418 lemma (in bounded_linear) summable: "summable (\<lambda>n. X n) \<Longrightarrow> summable (\<lambda>n. f (X n))"
   419   unfolding summable_def by (auto intro: sums)
   420 
   421 lemma (in bounded_linear) suminf: "summable (\<lambda>n. X n) \<Longrightarrow> f (\<Sum>n. X n) = (\<Sum>n. f (X n))"
   422   by (intro sums_unique sums summable_sums)
   423 
   424 lemmas sums_of_real = bounded_linear.sums [OF bounded_linear_of_real]
   425 lemmas summable_of_real = bounded_linear.summable [OF bounded_linear_of_real]
   426 lemmas suminf_of_real = bounded_linear.suminf [OF bounded_linear_of_real]
   427 
   428 lemmas sums_scaleR_left = bounded_linear.sums[OF bounded_linear_scaleR_left]
   429 lemmas summable_scaleR_left = bounded_linear.summable[OF bounded_linear_scaleR_left]
   430 lemmas suminf_scaleR_left = bounded_linear.suminf[OF bounded_linear_scaleR_left]
   431 
   432 lemmas sums_scaleR_right = bounded_linear.sums[OF bounded_linear_scaleR_right]
   433 lemmas summable_scaleR_right = bounded_linear.summable[OF bounded_linear_scaleR_right]
   434 lemmas suminf_scaleR_right = bounded_linear.suminf[OF bounded_linear_scaleR_right]
   435 
   436 lemma summable_const_iff: "summable (\<lambda>_. c) \<longleftrightarrow> (c :: 'a :: real_normed_vector) = 0"
   437 proof -
   438   {
   439     assume "c \<noteq> 0"
   440     hence "filterlim (\<lambda>n. of_nat n * norm c) at_top sequentially"
   441       by (subst mult.commute)
   442          (auto intro!: filterlim_tendsto_pos_mult_at_top filterlim_real_sequentially)
   443     hence "\<not>convergent (\<lambda>n. norm (\<Sum>k<n. c))"
   444       by (intro filterlim_at_infinity_imp_not_convergent filterlim_at_top_imp_at_infinity)
   445          (simp_all add: setsum_constant_scaleR)
   446     hence "\<not>summable (\<lambda>_. c)" unfolding summable_iff_convergent using convergent_norm by blast
   447   }
   448   thus ?thesis by auto
   449 qed
   450 
   451 
   452 subsection \<open>Infinite summability on real normed algebras\<close>
   453 
   454 context
   455   fixes f :: "nat \<Rightarrow> 'a::real_normed_algebra"
   456 begin
   457 
   458 lemma sums_mult: "f sums a \<Longrightarrow> (\<lambda>n. c * f n) sums (c * a)"
   459   by (rule bounded_linear.sums [OF bounded_linear_mult_right])
   460 
   461 lemma summable_mult: "summable f \<Longrightarrow> summable (\<lambda>n. c * f n)"
   462   by (rule bounded_linear.summable [OF bounded_linear_mult_right])
   463 
   464 lemma suminf_mult: "summable f \<Longrightarrow> suminf (\<lambda>n. c * f n) = c * suminf f"
   465   by (rule bounded_linear.suminf [OF bounded_linear_mult_right, symmetric])
   466 
   467 lemma sums_mult2: "f sums a \<Longrightarrow> (\<lambda>n. f n * c) sums (a * c)"
   468   by (rule bounded_linear.sums [OF bounded_linear_mult_left])
   469 
   470 lemma summable_mult2: "summable f \<Longrightarrow> summable (\<lambda>n. f n * c)"
   471   by (rule bounded_linear.summable [OF bounded_linear_mult_left])
   472 
   473 lemma suminf_mult2: "summable f \<Longrightarrow> suminf f * c = (\<Sum>n. f n * c)"
   474   by (rule bounded_linear.suminf [OF bounded_linear_mult_left])
   475 
   476 end
   477 
   478 lemma sums_mult_iff:
   479   assumes "c \<noteq> 0"
   480   shows   "(\<lambda>n. c * f n :: 'a :: {real_normed_algebra,field}) sums (c * d) \<longleftrightarrow> f sums d"
   481   using sums_mult[of f d c] sums_mult[of "\<lambda>n. c * f n" "c * d" "inverse c"]
   482   by (force simp: field_simps assms)
   483 
   484 lemma sums_mult2_iff:
   485   assumes "c \<noteq> (0 :: 'a :: {real_normed_algebra, field})"
   486   shows   "(\<lambda>n. f n * c) sums (d * c) \<longleftrightarrow> f sums d"
   487   using sums_mult_iff[OF assms, of f d] by (simp add: mult.commute)
   488 
   489 lemma sums_of_real_iff:
   490   "(\<lambda>n. of_real (f n) :: 'a :: real_normed_div_algebra) sums of_real c \<longleftrightarrow> f sums c"
   491   by (simp add: sums_def of_real_setsum[symmetric] tendsto_of_real_iff del: of_real_setsum)
   492 
   493 
   494 subsection \<open>Infinite summability on real normed fields\<close>
   495 
   496 context
   497   fixes c :: "'a::real_normed_field"
   498 begin
   499 
   500 lemma sums_divide: "f sums a \<Longrightarrow> (\<lambda>n. f n / c) sums (a / c)"
   501   by (rule bounded_linear.sums [OF bounded_linear_divide])
   502 
   503 lemma summable_divide: "summable f \<Longrightarrow> summable (\<lambda>n. f n / c)"
   504   by (rule bounded_linear.summable [OF bounded_linear_divide])
   505 
   506 lemma suminf_divide: "summable f \<Longrightarrow> suminf (\<lambda>n. f n / c) = suminf f / c"
   507   by (rule bounded_linear.suminf [OF bounded_linear_divide, symmetric])
   508 
   509 text\<open>Sum of a geometric progression.\<close>
   510 
   511 lemma geometric_sums: "norm c < 1 \<Longrightarrow> (\<lambda>n. c^n) sums (1 / (1 - c))"
   512 proof -
   513   assume less_1: "norm c < 1"
   514   hence neq_1: "c \<noteq> 1" by auto
   515   hence neq_0: "c - 1 \<noteq> 0" by simp
   516   from less_1 have lim_0: "(\<lambda>n. c^n) \<longlonglongrightarrow> 0"
   517     by (rule LIMSEQ_power_zero)
   518   hence "(\<lambda>n. c ^ n / (c - 1) - 1 / (c - 1)) \<longlonglongrightarrow> 0 / (c - 1) - 1 / (c - 1)"
   519     using neq_0 by (intro tendsto_intros)
   520   hence "(\<lambda>n. (c ^ n - 1) / (c - 1)) \<longlonglongrightarrow> 1 / (1 - c)"
   521     by (simp add: nonzero_minus_divide_right [OF neq_0] diff_divide_distrib)
   522   thus "(\<lambda>n. c ^ n) sums (1 / (1 - c))"
   523     by (simp add: sums_def geometric_sum neq_1)
   524 qed
   525 
   526 lemma summable_geometric: "norm c < 1 \<Longrightarrow> summable (\<lambda>n. c^n)"
   527   by (rule geometric_sums [THEN sums_summable])
   528 
   529 lemma suminf_geometric: "norm c < 1 \<Longrightarrow> suminf (\<lambda>n. c^n) = 1 / (1 - c)"
   530   by (rule sums_unique[symmetric]) (rule geometric_sums)
   531 
   532 lemma summable_geometric_iff: "summable (\<lambda>n. c ^ n) \<longleftrightarrow> norm c < 1"
   533 proof
   534   assume "summable (\<lambda>n. c ^ n :: 'a :: real_normed_field)"
   535   hence "(\<lambda>n. norm c ^ n) \<longlonglongrightarrow> 0"
   536     by (simp add: norm_power [symmetric] tendsto_norm_zero_iff summable_LIMSEQ_zero)
   537   from order_tendstoD(2)[OF this zero_less_one] obtain n where "norm c ^ n < 1"
   538     by (auto simp: eventually_at_top_linorder)
   539   thus "norm c < 1" using one_le_power[of "norm c" n] by (cases "norm c \<ge> 1") (linarith, simp)
   540 qed (rule summable_geometric)
   541 
   542 end
   543 
   544 lemma power_half_series: "(\<lambda>n. (1/2::real)^Suc n) sums 1"
   545 proof -
   546   have 2: "(\<lambda>n. (1/2::real)^n) sums 2" using geometric_sums [of "1/2::real"]
   547     by auto
   548   have "(\<lambda>n. (1/2::real)^Suc n) = (\<lambda>n. (1 / 2) ^ n / 2)"
   549     by (simp add: mult.commute)
   550   thus ?thesis using sums_divide [OF 2, of 2]
   551     by simp
   552 qed
   553 
   554 
   555 subsection \<open>Telescoping\<close>
   556 
   557 lemma telescope_sums:
   558   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   559   shows   "(\<lambda>n. f (Suc n) - f n) sums (c - f 0)"
   560   unfolding sums_def
   561 proof (subst LIMSEQ_Suc_iff [symmetric])
   562   have "(\<lambda>n. \<Sum>k<Suc n. f (Suc k) - f k) = (\<lambda>n. f (Suc n) - f 0)"
   563     by (simp add: lessThan_Suc_atMost atLeast0AtMost [symmetric] setsum_Suc_diff)
   564   also have "\<dots> \<longlonglongrightarrow> c - f 0" by (intro tendsto_diff LIMSEQ_Suc[OF assms] tendsto_const)
   565   finally show "(\<lambda>n. \<Sum>n<Suc n. f (Suc n) - f n) \<longlonglongrightarrow> c - f 0" .
   566 qed
   567 
   568 lemma telescope_sums':
   569   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   570   shows   "(\<lambda>n. f n - f (Suc n)) sums (f 0 - c)"
   571   using sums_minus[OF telescope_sums[OF assms]] by (simp add: algebra_simps)
   572 
   573 lemma telescope_summable:
   574   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   575   shows   "summable (\<lambda>n. f (Suc n) - f n)"
   576   using telescope_sums[OF assms] by (simp add: sums_iff)
   577 
   578 lemma telescope_summable':
   579   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   580   shows   "summable (\<lambda>n. f n - f (Suc n))"
   581   using summable_minus[OF telescope_summable[OF assms]] by (simp add: algebra_simps)
   582 
   583 
   584 subsection \<open>Infinite summability on Banach spaces\<close>
   585 
   586 text\<open>Cauchy-type criterion for convergence of series (c.f. Harrison)\<close>
   587 
   588 lemma summable_Cauchy:
   589   fixes f :: "nat \<Rightarrow> 'a::banach"
   590   shows "summable f \<longleftrightarrow> (\<forall>e>0. \<exists>N. \<forall>m\<ge>N. \<forall>n. norm (setsum f {m..<n}) < e)"
   591   apply (simp only: summable_iff_convergent Cauchy_convergent_iff [symmetric] Cauchy_iff, safe)
   592   apply (drule spec, drule (1) mp)
   593   apply (erule exE, rule_tac x="M" in exI, clarify)
   594   apply (rule_tac x="m" and y="n" in linorder_le_cases)
   595   apply (frule (1) order_trans)
   596   apply (drule_tac x="n" in spec, drule (1) mp)
   597   apply (drule_tac x="m" in spec, drule (1) mp)
   598   apply (simp_all add: setsum_diff [symmetric])
   599   apply (drule spec, drule (1) mp)
   600   apply (erule exE, rule_tac x="N" in exI, clarify)
   601   apply (rule_tac x="m" and y="n" in linorder_le_cases)
   602   apply (subst norm_minus_commute)
   603   apply (simp_all add: setsum_diff [symmetric])
   604   done
   605 
   606 context
   607   fixes f :: "nat \<Rightarrow> 'a::banach"
   608 begin
   609 
   610 text\<open>Absolute convergence imples normal convergence\<close>
   611 
   612 lemma summable_norm_cancel: "summable (\<lambda>n. norm (f n)) \<Longrightarrow> summable f"
   613   apply (simp only: summable_Cauchy, safe)
   614   apply (drule_tac x="e" in spec, safe)
   615   apply (rule_tac x="N" in exI, safe)
   616   apply (drule_tac x="m" in spec, safe)
   617   apply (rule order_le_less_trans [OF norm_setsum])
   618   apply (rule order_le_less_trans [OF abs_ge_self])
   619   apply simp
   620   done
   621 
   622 lemma summable_norm: "summable (\<lambda>n. norm (f n)) \<Longrightarrow> norm (suminf f) \<le> (\<Sum>n. norm (f n))"
   623   by (auto intro: LIMSEQ_le tendsto_norm summable_norm_cancel summable_LIMSEQ norm_setsum)
   624 
   625 text \<open>Comparison tests\<close>
   626 
   627 lemma summable_comparison_test: "\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n \<Longrightarrow> summable g \<Longrightarrow> summable f"
   628   apply (simp add: summable_Cauchy, safe)
   629   apply (drule_tac x="e" in spec, safe)
   630   apply (rule_tac x = "N + Na" in exI, safe)
   631   apply (rotate_tac 2)
   632   apply (drule_tac x = m in spec)
   633   apply (auto, rotate_tac 2, drule_tac x = n in spec)
   634   apply (rule_tac y = "\<Sum>k=m..<n. norm (f k)" in order_le_less_trans)
   635   apply (rule norm_setsum)
   636   apply (rule_tac y = "setsum g {m..<n}" in order_le_less_trans)
   637   apply (auto intro: setsum_mono simp add: abs_less_iff)
   638   done
   639 
   640 lemma summable_comparison_test_ev:
   641   shows "eventually (\<lambda>n. norm (f n) \<le> g n) sequentially \<Longrightarrow> summable g \<Longrightarrow> summable f"
   642   by (rule summable_comparison_test) (auto simp: eventually_at_top_linorder)
   643 
   644 (*A better argument order*)
   645 lemma summable_comparison_test': "summable g \<Longrightarrow> (\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> g n) \<Longrightarrow> summable f"
   646   by (rule summable_comparison_test) auto
   647 
   648 subsection \<open>The Ratio Test\<close>
   649 
   650 lemma summable_ratio_test:
   651   assumes "c < 1" "\<And>n. n \<ge> N \<Longrightarrow> norm (f (Suc n)) \<le> c * norm (f n)"
   652   shows "summable f"
   653 proof cases
   654   assume "0 < c"
   655   show "summable f"
   656   proof (rule summable_comparison_test)
   657     show "\<exists>N'. \<forall>n\<ge>N'. norm (f n) \<le> (norm (f N) / (c ^ N)) * c ^ n"
   658     proof (intro exI allI impI)
   659       fix n assume "N \<le> n" then show "norm (f n) \<le> (norm (f N) / (c ^ N)) * c ^ n"
   660       proof (induct rule: inc_induct)
   661         case (step m)
   662         moreover have "norm (f (Suc m)) / c ^ Suc m * c ^ n \<le> norm (f m) / c ^ m * c ^ n"
   663           using \<open>0 < c\<close> \<open>c < 1\<close> assms(2)[OF \<open>N \<le> m\<close>] by (simp add: field_simps)
   664         ultimately show ?case by simp
   665       qed (insert \<open>0 < c\<close>, simp)
   666     qed
   667     show "summable (\<lambda>n. norm (f N) / c ^ N * c ^ n)"
   668       using \<open>0 < c\<close> \<open>c < 1\<close> by (intro summable_mult summable_geometric) simp
   669   qed
   670 next
   671   assume c: "\<not> 0 < c"
   672   { fix n assume "n \<ge> N"
   673     then have "norm (f (Suc n)) \<le> c * norm (f n)"
   674       by fact
   675     also have "\<dots> \<le> 0"
   676       using c by (simp add: not_less mult_nonpos_nonneg)
   677     finally have "f (Suc n) = 0"
   678       by auto }
   679   then show "summable f"
   680     by (intro sums_summable[OF sums_finite, of "{.. Suc N}"]) (auto simp: not_le Suc_less_eq2)
   681 qed
   682 
   683 end
   684 
   685 text\<open>Relations among convergence and absolute convergence for power series.\<close>
   686 
   687 lemma Abel_lemma:
   688   fixes a :: "nat \<Rightarrow> 'a::real_normed_vector"
   689   assumes r: "0 \<le> r" and r0: "r < r0" and M: "\<And>n. norm (a n) * r0^n \<le> M"
   690     shows "summable (\<lambda>n. norm (a n) * r^n)"
   691 proof (rule summable_comparison_test')
   692   show "summable (\<lambda>n. M * (r / r0) ^ n)"
   693     using assms
   694     by (auto simp add: summable_mult summable_geometric)
   695 next
   696   fix n
   697   show "norm (norm (a n) * r ^ n) \<le> M * (r / r0) ^ n"
   698     using r r0 M [of n]
   699     apply (auto simp add: abs_mult field_simps)
   700     apply (cases "r=0", simp)
   701     apply (cases n, auto)
   702     done
   703 qed
   704 
   705 
   706 text\<open>Summability of geometric series for real algebras\<close>
   707 
   708 lemma complete_algebra_summable_geometric:
   709   fixes x :: "'a::{real_normed_algebra_1,banach}"
   710   shows "norm x < 1 \<Longrightarrow> summable (\<lambda>n. x ^ n)"
   711 proof (rule summable_comparison_test)
   712   show "\<exists>N. \<forall>n\<ge>N. norm (x ^ n) \<le> norm x ^ n"
   713     by (simp add: norm_power_ineq)
   714   show "norm x < 1 \<Longrightarrow> summable (\<lambda>n. norm x ^ n)"
   715     by (simp add: summable_geometric)
   716 qed
   717 
   718 subsection \<open>Cauchy Product Formula\<close>
   719 
   720 text \<open>
   721   Proof based on Analysis WebNotes: Chapter 07, Class 41
   722   @{url "http://www.math.unl.edu/~webnotes/classes/class41/prp77.htm"}
   723 \<close>
   724 
   725 lemma Cauchy_product_sums:
   726   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   727   assumes a: "summable (\<lambda>k. norm (a k))"
   728   assumes b: "summable (\<lambda>k. norm (b k))"
   729   shows "(\<lambda>k. \<Sum>i\<le>k. a i * b (k - i)) sums ((\<Sum>k. a k) * (\<Sum>k. b k))"
   730 proof -
   731   let ?S1 = "\<lambda>n::nat. {..<n} \<times> {..<n}"
   732   let ?S2 = "\<lambda>n::nat. {(i,j). i + j < n}"
   733   have S1_mono: "\<And>m n. m \<le> n \<Longrightarrow> ?S1 m \<subseteq> ?S1 n" by auto
   734   have S2_le_S1: "\<And>n. ?S2 n \<subseteq> ?S1 n" by auto
   735   have S1_le_S2: "\<And>n. ?S1 (n div 2) \<subseteq> ?S2 n" by auto
   736   have finite_S1: "\<And>n. finite (?S1 n)" by simp
   737   with S2_le_S1 have finite_S2: "\<And>n. finite (?S2 n)" by (rule finite_subset)
   738 
   739   let ?g = "\<lambda>(i,j). a i * b j"
   740   let ?f = "\<lambda>(i,j). norm (a i) * norm (b j)"
   741   have f_nonneg: "\<And>x. 0 \<le> ?f x" by (auto)
   742   hence norm_setsum_f: "\<And>A. norm (setsum ?f A) = setsum ?f A"
   743     unfolding real_norm_def
   744     by (simp only: abs_of_nonneg setsum_nonneg [rule_format])
   745 
   746   have "(\<lambda>n. (\<Sum>k<n. a k) * (\<Sum>k<n. b k)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   747     by (intro tendsto_mult summable_LIMSEQ summable_norm_cancel [OF a] summable_norm_cancel [OF b])
   748   hence 1: "(\<lambda>n. setsum ?g (?S1 n)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   749     by (simp only: setsum_product setsum.Sigma [rule_format] finite_lessThan)
   750 
   751   have "(\<lambda>n. (\<Sum>k<n. norm (a k)) * (\<Sum>k<n. norm (b k))) \<longlonglongrightarrow> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   752     using a b by (intro tendsto_mult summable_LIMSEQ)
   753   hence "(\<lambda>n. setsum ?f (?S1 n)) \<longlonglongrightarrow> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   754     by (simp only: setsum_product setsum.Sigma [rule_format] finite_lessThan)
   755   hence "convergent (\<lambda>n. setsum ?f (?S1 n))"
   756     by (rule convergentI)
   757   hence Cauchy: "Cauchy (\<lambda>n. setsum ?f (?S1 n))"
   758     by (rule convergent_Cauchy)
   759   have "Zfun (\<lambda>n. setsum ?f (?S1 n - ?S2 n)) sequentially"
   760   proof (rule ZfunI, simp only: eventually_sequentially norm_setsum_f)
   761     fix r :: real
   762     assume r: "0 < r"
   763     from CauchyD [OF Cauchy r] obtain N
   764     where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (setsum ?f (?S1 m) - setsum ?f (?S1 n)) < r" ..
   765     hence "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> norm (setsum ?f (?S1 m - ?S1 n)) < r"
   766       by (simp only: setsum_diff finite_S1 S1_mono)
   767     hence N: "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> setsum ?f (?S1 m - ?S1 n) < r"
   768       by (simp only: norm_setsum_f)
   769     show "\<exists>N. \<forall>n\<ge>N. setsum ?f (?S1 n - ?S2 n) < r"
   770     proof (intro exI allI impI)
   771       fix n assume "2 * N \<le> n"
   772       hence n: "N \<le> n div 2" by simp
   773       have "setsum ?f (?S1 n - ?S2 n) \<le> setsum ?f (?S1 n - ?S1 (n div 2))"
   774         by (intro setsum_mono2 finite_Diff finite_S1 f_nonneg
   775                   Diff_mono subset_refl S1_le_S2)
   776       also have "\<dots> < r"
   777         using n div_le_dividend by (rule N)
   778       finally show "setsum ?f (?S1 n - ?S2 n) < r" .
   779     qed
   780   qed
   781   hence "Zfun (\<lambda>n. setsum ?g (?S1 n - ?S2 n)) sequentially"
   782     apply (rule Zfun_le [rule_format])
   783     apply (simp only: norm_setsum_f)
   784     apply (rule order_trans [OF norm_setsum setsum_mono])
   785     apply (auto simp add: norm_mult_ineq)
   786     done
   787   hence 2: "(\<lambda>n. setsum ?g (?S1 n) - setsum ?g (?S2 n)) \<longlonglongrightarrow> 0"
   788     unfolding tendsto_Zfun_iff diff_0_right
   789     by (simp only: setsum_diff finite_S1 S2_le_S1)
   790 
   791   with 1 have "(\<lambda>n. setsum ?g (?S2 n)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   792     by (rule Lim_transform2)
   793   thus ?thesis by (simp only: sums_def setsum_triangle_reindex)
   794 qed
   795 
   796 lemma Cauchy_product:
   797   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   798   assumes a: "summable (\<lambda>k. norm (a k))"
   799   assumes b: "summable (\<lambda>k. norm (b k))"
   800   shows "(\<Sum>k. a k) * (\<Sum>k. b k) = (\<Sum>k. \<Sum>i\<le>k. a i * b (k - i))"
   801   using a b
   802   by (rule Cauchy_product_sums [THEN sums_unique])
   803 
   804 lemma summable_Cauchy_product:
   805   assumes "summable (\<lambda>k. norm (a k :: 'a :: {real_normed_algebra,banach}))"
   806           "summable (\<lambda>k. norm (b k))"
   807   shows   "summable (\<lambda>k. \<Sum>i\<le>k. a i * b (k - i))"
   808   using Cauchy_product_sums[OF assms] by (simp add: sums_iff)
   809 
   810 subsection \<open>Series on @{typ real}s\<close>
   811 
   812 lemma summable_norm_comparison_test: "\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. norm (f n))"
   813   by (rule summable_comparison_test) auto
   814 
   815 lemma summable_rabs_comparison_test: "\<lbrakk>\<exists>N. \<forall>n\<ge>N. \<bar>f n\<bar> \<le> g n; summable g\<rbrakk> \<Longrightarrow> summable (\<lambda>n. \<bar>f n :: real\<bar>)"
   816   by (rule summable_comparison_test) auto
   817 
   818 lemma summable_rabs_cancel: "summable (\<lambda>n. \<bar>f n :: real\<bar>) \<Longrightarrow> summable f"
   819   by (rule summable_norm_cancel) simp
   820 
   821 lemma summable_rabs: "summable (\<lambda>n. \<bar>f n :: real\<bar>) \<Longrightarrow> \<bar>suminf f\<bar> \<le> (\<Sum>n. \<bar>f n\<bar>)"
   822   by (fold real_norm_def) (rule summable_norm)
   823 
   824 lemma summable_zero_power [simp]: "summable (\<lambda>n. 0 ^ n :: 'a :: {comm_ring_1,topological_space})"
   825 proof -
   826   have "(\<lambda>n. 0 ^ n :: 'a) = (\<lambda>n. if n = 0 then 0^0 else 0)" by (intro ext) (simp add: zero_power)
   827   moreover have "summable \<dots>" by simp
   828   ultimately show ?thesis by simp
   829 qed
   830 
   831 lemma summable_zero_power' [simp]: "summable (\<lambda>n. f n * 0 ^ n :: 'a :: {ring_1,topological_space})"
   832 proof -
   833   have "(\<lambda>n. f n * 0 ^ n :: 'a) = (\<lambda>n. if n = 0 then f 0 * 0^0 else 0)"
   834     by (intro ext) (simp add: zero_power)
   835   moreover have "summable \<dots>" by simp
   836   ultimately show ?thesis by simp
   837 qed
   838 
   839 lemma summable_power_series:
   840   fixes z :: real
   841   assumes le_1: "\<And>i. f i \<le> 1" and nonneg: "\<And>i. 0 \<le> f i" and z: "0 \<le> z" "z < 1"
   842   shows "summable (\<lambda>i. f i * z^i)"
   843 proof (rule summable_comparison_test[OF _ summable_geometric])
   844   show "norm z < 1" using z by (auto simp: less_imp_le)
   845   show "\<And>n. \<exists>N. \<forall>na\<ge>N. norm (f na * z ^ na) \<le> z ^ na"
   846     using z by (auto intro!: exI[of _ 0] mult_left_le_one_le simp: abs_mult nonneg power_abs less_imp_le le_1)
   847 qed
   848 
   849 lemma summable_0_powser:
   850   "summable (\<lambda>n. f n * 0 ^ n :: 'a :: real_normed_div_algebra)"
   851 proof -
   852   have A: "(\<lambda>n. f n * 0 ^ n) = (\<lambda>n. if n = 0 then f n else 0)"
   853     by (intro ext) auto
   854   thus ?thesis by (subst A) simp_all
   855 qed
   856 
   857 lemma summable_powser_split_head:
   858   "summable (\<lambda>n. f (Suc n) * z ^ n :: 'a :: real_normed_div_algebra) = summable (\<lambda>n. f n * z ^ n)"
   859 proof -
   860   have "summable (\<lambda>n. f (Suc n) * z ^ n) \<longleftrightarrow> summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   861   proof
   862     assume "summable (\<lambda>n. f (Suc n) * z ^ n)"
   863     from summable_mult2[OF this, of z] show "summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   864       by (simp add: power_commutes algebra_simps)
   865   next
   866     assume "summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   867     from summable_mult2[OF this, of "inverse z"] show "summable (\<lambda>n. f (Suc n) * z ^ n)"
   868       by (cases "z \<noteq> 0", subst (asm) power_Suc2) (simp_all add: algebra_simps)
   869   qed
   870   also have "\<dots> \<longleftrightarrow> summable (\<lambda>n. f n * z ^ n)" by (rule summable_Suc_iff)
   871   finally show ?thesis .
   872 qed
   873 
   874 lemma powser_split_head:
   875   assumes "summable (\<lambda>n. f n * z ^ n :: 'a :: {real_normed_div_algebra,banach})"
   876   shows   "suminf (\<lambda>n. f n * z ^ n) = f 0 + suminf (\<lambda>n. f (Suc n) * z ^ n) * z"
   877           "suminf (\<lambda>n. f (Suc n) * z ^ n) * z = suminf (\<lambda>n. f n * z ^ n) - f 0"
   878           "summable (\<lambda>n. f (Suc n) * z ^ n)"
   879 proof -
   880   from assms show "summable (\<lambda>n. f (Suc n) * z ^ n)" by (subst summable_powser_split_head)
   881 
   882   from suminf_mult2[OF this, of z]
   883     have "(\<Sum>n. f (Suc n) * z ^ n) * z = (\<Sum>n. f (Suc n) * z ^ Suc n)"
   884     by (simp add: power_commutes algebra_simps)
   885   also from assms have "\<dots> = suminf (\<lambda>n. f n * z ^ n) - f 0"
   886     by (subst suminf_split_head) simp_all
   887   finally show "suminf (\<lambda>n. f n * z ^ n) = f 0 + suminf (\<lambda>n. f (Suc n) * z ^ n) * z" by simp
   888   thus "suminf (\<lambda>n. f (Suc n) * z ^ n) * z = suminf (\<lambda>n. f n * z ^ n) - f 0" by simp
   889 qed
   890 
   891 lemma summable_partial_sum_bound:
   892   fixes f :: "nat \<Rightarrow> 'a :: banach"
   893   assumes summable: "summable f" and e: "e > (0::real)"
   894   obtains N where "\<And>m n. m \<ge> N \<Longrightarrow> norm (\<Sum>k=m..n. f k) < e"
   895 proof -
   896   from summable have "Cauchy (\<lambda>n. \<Sum>k<n. f k)"
   897     by (simp add: Cauchy_convergent_iff summable_iff_convergent)
   898   from CauchyD[OF this e] obtain N
   899     where N: "\<And>m n. m \<ge> N \<Longrightarrow> n \<ge> N \<Longrightarrow> norm ((\<Sum>k<m. f k) - (\<Sum>k<n. f k)) < e" by blast
   900   {
   901     fix m n :: nat assume m: "m \<ge> N"
   902     have "norm (\<Sum>k=m..n. f k) < e"
   903     proof (cases "n \<ge> m")
   904       assume n: "n \<ge> m"
   905       with m have "norm ((\<Sum>k<Suc n. f k) - (\<Sum>k<m. f k)) < e" by (intro N) simp_all
   906       also from n have "(\<Sum>k<Suc n. f k) - (\<Sum>k<m. f k) = (\<Sum>k=m..n. f k)"
   907         by (subst setsum_diff [symmetric]) (simp_all add: setsum_last_plus)
   908       finally show ?thesis .
   909     qed (insert e, simp_all)
   910   }
   911   thus ?thesis by (rule that)
   912 qed
   913 
   914 lemma powser_sums_if:
   915   "(\<lambda>n. (if n = m then (1 :: 'a :: {ring_1,topological_space}) else 0) * z^n) sums z^m"
   916 proof -
   917   have "(\<lambda>n. (if n = m then 1 else 0) * z^n) = (\<lambda>n. if n = m then z^n else 0)"
   918     by (intro ext) auto
   919   thus ?thesis by (simp add: sums_single)
   920 qed
   921 
   922 lemma
   923    fixes f :: "nat \<Rightarrow> real"
   924    assumes "summable f"
   925    and "inj g"
   926    and pos: "!!x. 0 \<le> f x"
   927    shows summable_reindex: "summable (f o g)"
   928    and suminf_reindex_mono: "suminf (f o g) \<le> suminf f"
   929    and suminf_reindex: "(\<And>x. x \<notin> range g \<Longrightarrow> f x = 0) \<Longrightarrow> suminf (f \<circ> g) = suminf f"
   930 proof -
   931   from \<open>inj g\<close> have [simp]: "\<And>A. inj_on g A" by(rule subset_inj_on) simp
   932 
   933   have smaller: "\<forall>n. (\<Sum>i<n. (f \<circ> g) i) \<le> suminf f"
   934   proof
   935     fix n
   936     have "\<forall> n' \<in> (g ` {..<n}). n' < Suc (Max (g ` {..<n}))"
   937       by(metis Max_ge finite_imageI finite_lessThan not_le not_less_eq)
   938     then obtain m where n: "\<And>n'. n' < n \<Longrightarrow> g n' < m" by blast
   939 
   940     have "(\<Sum>i<n. f (g i)) = setsum f (g ` {..<n})"
   941       by (simp add: setsum.reindex)
   942     also have "\<dots> \<le> (\<Sum>i<m. f i)"
   943       by (rule setsum_mono3) (auto simp add: pos n[rule_format])
   944     also have "\<dots> \<le> suminf f"
   945       using \<open>summable f\<close>
   946       by (rule setsum_le_suminf) (simp add: pos)
   947     finally show "(\<Sum>i<n. (f \<circ>  g) i) \<le> suminf f" by simp
   948   qed
   949 
   950   have "incseq (\<lambda>n. \<Sum>i<n. (f \<circ> g) i)"
   951     by (rule incseq_SucI) (auto simp add: pos)
   952   then obtain  L where L: "(\<lambda> n. \<Sum>i<n. (f \<circ> g) i) \<longlonglongrightarrow> L"
   953     using smaller by(rule incseq_convergent)
   954   hence "(f \<circ> g) sums L" by (simp add: sums_def)
   955   thus "summable (f o g)" by (auto simp add: sums_iff)
   956 
   957   hence "(\<lambda>n. \<Sum>i<n. (f \<circ> g) i) \<longlonglongrightarrow> suminf (f \<circ> g)"
   958     by(rule summable_LIMSEQ)
   959   thus le: "suminf (f \<circ> g) \<le> suminf f"
   960     by(rule LIMSEQ_le_const2)(blast intro: smaller[rule_format])
   961 
   962   assume f: "\<And>x. x \<notin> range g \<Longrightarrow> f x = 0"
   963 
   964   from \<open>summable f\<close> have "suminf f \<le> suminf (f \<circ> g)"
   965   proof(rule suminf_le_const)
   966     fix n
   967     have "\<forall> n' \<in> (g -` {..<n}). n' < Suc (Max (g -` {..<n}))"
   968       by(auto intro: Max_ge simp add: finite_vimageI less_Suc_eq_le)
   969     then obtain m where n: "\<And>n'. g n' < n \<Longrightarrow> n' < m" by blast
   970 
   971     have "(\<Sum>i<n. f i) = (\<Sum>i\<in>{..<n} \<inter> range g. f i)"
   972       using f by(auto intro: setsum.mono_neutral_cong_right)
   973     also have "\<dots> = (\<Sum>i\<in>g -` {..<n}. (f \<circ> g) i)"
   974       by(rule setsum.reindex_cong[where l=g])(auto)
   975     also have "\<dots> \<le> (\<Sum>i<m. (f \<circ> g) i)"
   976       by(rule setsum_mono3)(auto simp add: pos n)
   977     also have "\<dots> \<le> suminf (f \<circ> g)"
   978       using \<open>summable (f o g)\<close>
   979       by(rule setsum_le_suminf)(simp add: pos)
   980     finally show "setsum f {..<n} \<le> suminf (f \<circ> g)" .
   981   qed
   982   with le show "suminf (f \<circ> g) = suminf f" by(rule antisym)
   983 qed
   984 
   985 lemma sums_mono_reindex:
   986   assumes subseq: "subseq g" and zero: "\<And>n. n \<notin> range g \<Longrightarrow> f n = 0"
   987   shows   "(\<lambda>n. f (g n)) sums c \<longleftrightarrow> f sums c"
   988 unfolding sums_def
   989 proof
   990   assume lim: "(\<lambda>n. \<Sum>k<n. f k) \<longlonglongrightarrow> c"
   991   have "(\<lambda>n. \<Sum>k<n. f (g k)) = (\<lambda>n. \<Sum>k<g n. f k)"
   992   proof
   993     fix n :: nat
   994     from subseq have "(\<Sum>k<n. f (g k)) = (\<Sum>k\<in>g`{..<n}. f k)"
   995       by (subst setsum.reindex) (auto intro: subseq_imp_inj_on)
   996     also from subseq have "\<dots> = (\<Sum>k<g n. f k)"
   997       by (intro setsum.mono_neutral_left ballI zero)
   998          (auto dest: subseq_strict_mono simp: strict_mono_less strict_mono_less_eq)
   999     finally show "(\<Sum>k<n. f (g k)) = (\<Sum>k<g n. f k)" .
  1000   qed
  1001   also from LIMSEQ_subseq_LIMSEQ[OF lim subseq] have "\<dots> \<longlonglongrightarrow> c" unfolding o_def .
  1002   finally show "(\<lambda>n. \<Sum>k<n. f (g k)) \<longlonglongrightarrow> c" .
  1003 next
  1004   assume lim: "(\<lambda>n. \<Sum>k<n. f (g k)) \<longlonglongrightarrow> c"
  1005   def g_inv \<equiv> "\<lambda>n. LEAST m. g m \<ge> n"
  1006   from filterlim_subseq[OF subseq] have g_inv_ex: "\<exists>m. g m \<ge> n" for n
  1007     by (auto simp: filterlim_at_top eventually_at_top_linorder)
  1008   hence g_inv: "g (g_inv n) \<ge> n" for n unfolding g_inv_def by (rule LeastI_ex)
  1009   have g_inv_least: "m \<ge> g_inv n" if "g m \<ge> n" for m n using that
  1010     unfolding g_inv_def by (rule Least_le)
  1011   have g_inv_least': "g m < n" if "m < g_inv n" for m n using that g_inv_least[of n m] by linarith
  1012   have "(\<lambda>n. \<Sum>k<n. f k) = (\<lambda>n. \<Sum>k<g_inv n. f (g k))"
  1013   proof
  1014     fix n :: nat
  1015     {
  1016       fix k assume k: "k \<in> {..<n} - g`{..<g_inv n}"
  1017       have "k \<notin> range g"
  1018       proof (rule notI, elim imageE)
  1019         fix l assume l: "k = g l"
  1020         have "g l < g (g_inv n)" by (rule less_le_trans[OF _ g_inv]) (insert k l, simp_all)
  1021         with subseq have "l < g_inv n" by (simp add: subseq_strict_mono strict_mono_less)
  1022         with k l show False by simp
  1023       qed
  1024       hence "f k = 0" by (rule zero)
  1025     }
  1026     with g_inv_least' g_inv have "(\<Sum>k<n. f k) = (\<Sum>k\<in>g`{..<g_inv n}. f k)"
  1027       by (intro setsum.mono_neutral_right) auto
  1028     also from subseq have "\<dots> = (\<Sum>k<g_inv n. f (g k))" using subseq_imp_inj_on
  1029       by (subst setsum.reindex) simp_all
  1030     finally show "(\<Sum>k<n. f k) = (\<Sum>k<g_inv n. f (g k))" .
  1031   qed
  1032   also {
  1033     fix K n :: nat assume "g K \<le> n"
  1034     also have "n \<le> g (g_inv n)" by (rule g_inv)
  1035     finally have "K \<le> g_inv n" using subseq by (simp add: strict_mono_less_eq subseq_strict_mono)
  1036   }
  1037   hence "filterlim g_inv at_top sequentially"
  1038     by (auto simp: filterlim_at_top eventually_at_top_linorder)
  1039   from lim and this have "(\<lambda>n. \<Sum>k<g_inv n. f (g k)) \<longlonglongrightarrow> c" by (rule filterlim_compose)
  1040   finally show "(\<lambda>n. \<Sum>k<n. f k) \<longlonglongrightarrow> c" .
  1041 qed
  1042 
  1043 lemma summable_mono_reindex:
  1044   assumes subseq: "subseq g" and zero: "\<And>n. n \<notin> range g \<Longrightarrow> f n = 0"
  1045   shows   "summable (\<lambda>n. f (g n)) \<longleftrightarrow> summable f"
  1046   using sums_mono_reindex[of g f, OF assms] by (simp add: summable_def)
  1047 
  1048 lemma suminf_mono_reindex:
  1049   assumes "subseq g" "\<And>n. n \<notin> range g \<Longrightarrow> f n = (0 :: 'a :: {t2_space,comm_monoid_add})"
  1050   shows   "suminf (\<lambda>n. f (g n)) = suminf f"
  1051 proof (cases "summable f")
  1052   case False
  1053   hence "\<not>(\<exists>c. f sums c)" unfolding summable_def by blast
  1054   hence "suminf f = The (\<lambda>_. False)" by (simp add: suminf_def)
  1055   moreover from False have "\<not>summable (\<lambda>n. f (g n))"
  1056     using summable_mono_reindex[of g f, OF assms] by simp
  1057   hence "\<not>(\<exists>c. (\<lambda>n. f (g n)) sums c)" unfolding summable_def by blast
  1058   hence "suminf (\<lambda>n. f (g n)) = The (\<lambda>_. False)" by (simp add: suminf_def)
  1059   ultimately show ?thesis by simp
  1060 qed (insert sums_mono_reindex[of g f, OF assms] summable_mono_reindex[of g f, OF assms],
  1061      simp_all add: sums_iff)
  1062 
  1063 end