src/HOL/Analysis/Cartesian_Euclidean_Space.thy
author paulson <lp15@cam.ac.uk>
Sat Apr 14 09:23:00 2018 +0100 (16 months ago)
changeset 67979 53323937ee25
parent 67971 e9f66b35d636
child 67981 349c639e593c
permissions -rw-r--r--
new material about vec, real^1, etc.
     1 section \<open>Instantiates the finite Cartesian product of Euclidean spaces as a Euclidean space\<close>
     2 
     3 theory Cartesian_Euclidean_Space
     4 imports Finite_Cartesian_Product Derivative
     5 begin
     6 
     7 lemma subspace_special_hyperplane: "subspace {x. x $ k = 0}"
     8   by (simp add: subspace_def)
     9 
    10 lemma sum_mult_product:
    11   "sum h {..<A * B :: nat} = (\<Sum>i\<in>{..<A}. \<Sum>j\<in>{..<B}. h (j + i * B))"
    12   unfolding sum_nat_group[of h B A, unfolded atLeast0LessThan, symmetric]
    13 proof (rule sum.cong, simp, rule sum.reindex_cong)
    14   fix i
    15   show "inj_on (\<lambda>j. j + i * B) {..<B}" by (auto intro!: inj_onI)
    16   show "{i * B..<i * B + B} = (\<lambda>j. j + i * B) ` {..<B}"
    17   proof safe
    18     fix j assume "j \<in> {i * B..<i * B + B}"
    19     then show "j \<in> (\<lambda>j. j + i * B) ` {..<B}"
    20       by (auto intro!: image_eqI[of _ _ "j - i * B"])
    21   qed simp
    22 qed simp
    23 
    24 subsection\<open>Basic componentwise operations on vectors\<close>
    25 
    26 instantiation vec :: (times, finite) times
    27 begin
    28 
    29 definition "( * ) \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) * (y$i)))"
    30 instance ..
    31 
    32 end
    33 
    34 instantiation vec :: (one, finite) one
    35 begin
    36 
    37 definition "1 \<equiv> (\<chi> i. 1)"
    38 instance ..
    39 
    40 end
    41 
    42 instantiation vec :: (ord, finite) ord
    43 begin
    44 
    45 definition "x \<le> y \<longleftrightarrow> (\<forall>i. x$i \<le> y$i)"
    46 definition "x < (y::'a^'b) \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
    47 instance ..
    48 
    49 end
    50 
    51 text\<open>The ordering on one-dimensional vectors is linear.\<close>
    52 
    53 class cart_one =
    54   assumes UNIV_one: "card (UNIV :: 'a set) = Suc 0"
    55 begin
    56 
    57 subclass finite
    58 proof
    59   from UNIV_one show "finite (UNIV :: 'a set)"
    60     by (auto intro!: card_ge_0_finite)
    61 qed
    62 
    63 end
    64 
    65 instance vec:: (order, finite) order
    66   by standard (auto simp: less_eq_vec_def less_vec_def vec_eq_iff
    67       intro: order.trans order.antisym order.strict_implies_order)
    68 
    69 instance vec :: (linorder, cart_one) linorder
    70 proof
    71   obtain a :: 'b where all: "\<And>P. (\<forall>i. P i) \<longleftrightarrow> P a"
    72   proof -
    73     have "card (UNIV :: 'b set) = Suc 0" by (rule UNIV_one)
    74     then obtain b :: 'b where "UNIV = {b}" by (auto iff: card_Suc_eq)
    75     then have "\<And>P. (\<forall>i\<in>UNIV. P i) \<longleftrightarrow> P b" by auto
    76     then show thesis by (auto intro: that)
    77   qed
    78   fix x y :: "'a^'b::cart_one"
    79   note [simp] = less_eq_vec_def less_vec_def all vec_eq_iff field_simps
    80   show "x \<le> y \<or> y \<le> x" by auto
    81 qed
    82 
    83 text\<open>Constant Vectors\<close>
    84 
    85 definition "vec x = (\<chi> i. x)"
    86 
    87 lemma interval_cbox_cart: "{a::real^'n..b} = cbox a b"
    88   by (auto simp add: less_eq_vec_def mem_box Basis_vec_def inner_axis)
    89 
    90 text\<open>Also the scalar-vector multiplication.\<close>
    91 
    92 definition vector_scalar_mult:: "'a::times \<Rightarrow> 'a ^ 'n \<Rightarrow> 'a ^ 'n" (infixl "*s" 70)
    93   where "c *s x = (\<chi> i. c * (x$i))"
    94 
    95 
    96 subsection \<open>A naive proof procedure to lift really trivial arithmetic stuff from the basis of the vector space\<close>
    97 
    98 lemma sum_cong_aux:
    99   "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> sum f A = sum g A"
   100   by (auto intro: sum.cong)
   101 
   102 hide_fact (open) sum_cong_aux
   103 
   104 method_setup vector = \<open>
   105 let
   106   val ss1 =
   107     simpset_of (put_simpset HOL_basic_ss @{context}
   108       addsimps [@{thm sum.distrib} RS sym,
   109       @{thm sum_subtractf} RS sym, @{thm sum_distrib_left},
   110       @{thm sum_distrib_right}, @{thm sum_negf} RS sym])
   111   val ss2 =
   112     simpset_of (@{context} addsimps
   113              [@{thm plus_vec_def}, @{thm times_vec_def},
   114               @{thm minus_vec_def}, @{thm uminus_vec_def},
   115               @{thm one_vec_def}, @{thm zero_vec_def}, @{thm vec_def},
   116               @{thm scaleR_vec_def},
   117               @{thm vec_lambda_beta}, @{thm vector_scalar_mult_def}])
   118   fun vector_arith_tac ctxt ths =
   119     simp_tac (put_simpset ss1 ctxt)
   120     THEN' (fn i => resolve_tac ctxt @{thms Cartesian_Euclidean_Space.sum_cong_aux} i
   121          ORELSE resolve_tac ctxt @{thms sum.neutral} i
   122          ORELSE simp_tac (put_simpset HOL_basic_ss ctxt addsimps [@{thm vec_eq_iff}]) i)
   123     (* THEN' TRY o clarify_tac HOL_cs  THEN' (TRY o rtac @{thm iffI}) *)
   124     THEN' asm_full_simp_tac (put_simpset ss2 ctxt addsimps ths)
   125 in
   126   Attrib.thms >> (fn ths => fn ctxt => SIMPLE_METHOD' (vector_arith_tac ctxt ths))
   127 end
   128 \<close> "lift trivial vector statements to real arith statements"
   129 
   130 lemma vec_0[simp]: "vec 0 = 0" by vector
   131 lemma vec_1[simp]: "vec 1 = 1" by vector
   132 
   133 lemma vec_inj[simp]: "vec x = vec y \<longleftrightarrow> x = y" by vector
   134 
   135 lemma vec_in_image_vec: "vec x \<in> (vec ` S) \<longleftrightarrow> x \<in> S" by auto
   136 
   137 lemma vec_add: "vec(x + y) = vec x + vec y"  by vector
   138 lemma vec_sub: "vec(x - y) = vec x - vec y" by vector
   139 lemma vec_cmul: "vec(c * x) = c *s vec x " by vector
   140 lemma vec_neg: "vec(- x) = - vec x " by vector
   141 
   142 lemma vec_scaleR: "vec(c * x) = c *\<^sub>R vec x"
   143   by vector
   144 
   145 lemma vec_sum:
   146   assumes "finite S"
   147   shows "vec(sum f S) = sum (vec \<circ> f) S"
   148   using assms
   149 proof induct
   150   case empty
   151   then show ?case by simp
   152 next
   153   case insert
   154   then show ?case by (auto simp add: vec_add)
   155 qed
   156 
   157 text\<open>Obvious "component-pushing".\<close>
   158 
   159 lemma vec_component [simp]: "vec x $ i = x"
   160   by vector
   161 
   162 lemma vector_mult_component [simp]: "(x * y)$i = x$i * y$i"
   163   by vector
   164 
   165 lemma vector_smult_component [simp]: "(c *s y)$i = c * (y$i)"
   166   by vector
   167 
   168 lemma cond_component: "(if b then x else y)$i = (if b then x$i else y$i)" by vector
   169 
   170 lemmas vector_component =
   171   vec_component vector_add_component vector_mult_component
   172   vector_smult_component vector_minus_component vector_uminus_component
   173   vector_scaleR_component cond_component
   174 
   175 
   176 subsection \<open>Some frequently useful arithmetic lemmas over vectors\<close>
   177 
   178 instance vec :: (semigroup_mult, finite) semigroup_mult
   179   by standard (vector mult.assoc)
   180 
   181 instance vec :: (monoid_mult, finite) monoid_mult
   182   by standard vector+
   183 
   184 instance vec :: (ab_semigroup_mult, finite) ab_semigroup_mult
   185   by standard (vector mult.commute)
   186 
   187 instance vec :: (comm_monoid_mult, finite) comm_monoid_mult
   188   by standard vector
   189 
   190 instance vec :: (semiring, finite) semiring
   191   by standard (vector field_simps)+
   192 
   193 instance vec :: (semiring_0, finite) semiring_0
   194   by standard (vector field_simps)+
   195 instance vec :: (semiring_1, finite) semiring_1
   196   by standard vector
   197 instance vec :: (comm_semiring, finite) comm_semiring
   198   by standard (vector field_simps)+
   199 
   200 instance vec :: (comm_semiring_0, finite) comm_semiring_0 ..
   201 instance vec :: (cancel_comm_monoid_add, finite) cancel_comm_monoid_add ..
   202 instance vec :: (semiring_0_cancel, finite) semiring_0_cancel ..
   203 instance vec :: (comm_semiring_0_cancel, finite) comm_semiring_0_cancel ..
   204 instance vec :: (ring, finite) ring ..
   205 instance vec :: (semiring_1_cancel, finite) semiring_1_cancel ..
   206 instance vec :: (comm_semiring_1, finite) comm_semiring_1 ..
   207 
   208 instance vec :: (ring_1, finite) ring_1 ..
   209 
   210 instance vec :: (real_algebra, finite) real_algebra
   211   by standard (simp_all add: vec_eq_iff)
   212 
   213 instance vec :: (real_algebra_1, finite) real_algebra_1 ..
   214 
   215 lemma of_nat_index: "(of_nat n :: 'a::semiring_1 ^'n)$i = of_nat n"
   216 proof (induct n)
   217   case 0
   218   then show ?case by vector
   219 next
   220   case Suc
   221   then show ?case by vector
   222 qed
   223 
   224 lemma one_index [simp]: "(1 :: 'a :: one ^ 'n) $ i = 1"
   225   by vector
   226 
   227 lemma neg_one_index [simp]: "(- 1 :: 'a :: {one, uminus} ^ 'n) $ i = - 1"
   228   by vector
   229 
   230 instance vec :: (semiring_char_0, finite) semiring_char_0
   231 proof
   232   fix m n :: nat
   233   show "inj (of_nat :: nat \<Rightarrow> 'a ^ 'b)"
   234     by (auto intro!: injI simp add: vec_eq_iff of_nat_index)
   235 qed
   236 
   237 instance vec :: (numeral, finite) numeral ..
   238 instance vec :: (semiring_numeral, finite) semiring_numeral ..
   239 
   240 lemma numeral_index [simp]: "numeral w $ i = numeral w"
   241   by (induct w) (simp_all only: numeral.simps vector_add_component one_index)
   242 
   243 lemma neg_numeral_index [simp]: "- numeral w $ i = - numeral w"
   244   by (simp only: vector_uminus_component numeral_index)
   245 
   246 instance vec :: (comm_ring_1, finite) comm_ring_1 ..
   247 instance vec :: (ring_char_0, finite) ring_char_0 ..
   248 
   249 lemma vector_smult_assoc: "a *s (b *s x) = ((a::'a::semigroup_mult) * b) *s x"
   250   by (vector mult.assoc)
   251 lemma vector_sadd_rdistrib: "((a::'a::semiring) + b) *s x = a *s x + b *s x"
   252   by (vector field_simps)
   253 lemma vector_add_ldistrib: "(c::'a::semiring) *s (x + y) = c *s x + c *s y"
   254   by (vector field_simps)
   255 lemma vector_smult_lzero[simp]: "(0::'a::mult_zero) *s x = 0" by vector
   256 lemma vector_smult_lid[simp]: "(1::'a::monoid_mult) *s x = x" by vector
   257 lemma vector_ssub_ldistrib: "(c::'a::ring) *s (x - y) = c *s x - c *s y"
   258   by (vector field_simps)
   259 lemma vector_smult_rneg: "(c::'a::ring) *s -x = -(c *s x)" by vector
   260 lemma vector_smult_lneg: "- (c::'a::ring) *s x = -(c *s x)" by vector
   261 lemma vector_sneg_minus1: "-x = (-1::'a::ring_1) *s x" by vector
   262 lemma vector_smult_rzero[simp]: "c *s 0 = (0::'a::mult_zero ^ 'n)" by vector
   263 lemma vector_sub_rdistrib: "((a::'a::ring) - b) *s x = a *s x - b *s x"
   264   by (vector field_simps)
   265 
   266 lemma vec_eq[simp]: "(vec m = vec n) \<longleftrightarrow> (m = n)"
   267   by (simp add: vec_eq_iff)
   268 
   269 lemma linear_vec [simp]: "linear vec"
   270   by (simp add: linearI vec_add vec_eq_iff)
   271 
   272 lemma differentiable_vec:
   273   fixes S :: "'a::euclidean_space set"
   274   shows "vec differentiable_on S"
   275   by (simp add: linear_linear bounded_linear_imp_differentiable_on)
   276 
   277 lemma continuous_vec [continuous_intros]:
   278   fixes x :: "'a::euclidean_space"
   279   shows "isCont vec x"
   280   apply (clarsimp simp add: continuous_def LIM_def dist_vec_def L2_set_def)
   281   apply (rule_tac x="r / sqrt (real CARD('b))" in exI)
   282   by (simp add: mult.commute pos_less_divide_eq real_sqrt_mult)
   283 
   284 lemma box_vec_eq_empty [simp]:
   285   shows "cbox (vec a) (vec b) = {} \<longleftrightarrow> cbox a b = {}"
   286         "box (vec a) (vec b) = {} \<longleftrightarrow> box a b = {}"
   287   by (auto simp: Basis_vec_def mem_box box_eq_empty inner_axis)
   288 
   289 lemma norm_eq_0_imp: "norm x = 0 ==> x = (0::real ^'n)" by (metis norm_eq_zero)
   290 
   291 lemma norm_axis_1 [simp]: "norm (axis m (1::real)) = 1"
   292   by (simp add: inner_axis' norm_eq_1)
   293 
   294 lemma vector_mul_eq_0[simp]: "(a *s x = 0) \<longleftrightarrow> a = (0::'a::idom) \<or> x = 0"
   295   by vector
   296 
   297 lemma vector_mul_lcancel[simp]: "a *s x = a *s y \<longleftrightarrow> a = (0::real) \<or> x = y"
   298   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_ssub_ldistrib)
   299 
   300 lemma vector_mul_rcancel[simp]: "a *s x = b *s x \<longleftrightarrow> (a::real) = b \<or> x = 0"
   301   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_sub_rdistrib)
   302 
   303 lemma vector_mul_lcancel_imp: "a \<noteq> (0::real) ==>  a *s x = a *s y ==> (x = y)"
   304   by (metis vector_mul_lcancel)
   305 
   306 lemma vector_mul_rcancel_imp: "x \<noteq> 0 \<Longrightarrow> (a::real) *s x = b *s x ==> a = b"
   307   by (metis vector_mul_rcancel)
   308 
   309 lemma component_le_norm_cart: "\<bar>x$i\<bar> \<le> norm x"
   310   apply (simp add: norm_vec_def)
   311   apply (rule member_le_L2_set, simp_all)
   312   done
   313 
   314 lemma norm_bound_component_le_cart: "norm x \<le> e ==> \<bar>x$i\<bar> \<le> e"
   315   by (metis component_le_norm_cart order_trans)
   316 
   317 lemma norm_bound_component_lt_cart: "norm x < e ==> \<bar>x$i\<bar> < e"
   318   by (metis component_le_norm_cart le_less_trans)
   319 
   320 lemma norm_le_l1_cart: "norm x \<le> sum(\<lambda>i. \<bar>x$i\<bar>) UNIV"
   321   by (simp add: norm_vec_def L2_set_le_sum)
   322 
   323 lemma scalar_mult_eq_scaleR [simp]: "c *s x = c *\<^sub>R x"
   324   unfolding scaleR_vec_def vector_scalar_mult_def by simp
   325 
   326 lemma dist_mul[simp]: "dist (c *s x) (c *s y) = \<bar>c\<bar> * dist x y"
   327   unfolding dist_norm scalar_mult_eq_scaleR
   328   unfolding scaleR_right_diff_distrib[symmetric] by simp
   329 
   330 lemma sum_component [simp]:
   331   fixes f:: " 'a \<Rightarrow> ('b::comm_monoid_add) ^'n"
   332   shows "(sum f S)$i = sum (\<lambda>x. (f x)$i) S"
   333 proof (cases "finite S")
   334   case True
   335   then show ?thesis by induct simp_all
   336 next
   337   case False
   338   then show ?thesis by simp
   339 qed
   340 
   341 lemma sum_eq: "sum f S = (\<chi> i. sum (\<lambda>x. (f x)$i ) S)"
   342   by (simp add: vec_eq_iff)
   343 
   344 lemma sum_cmul:
   345   fixes f:: "'c \<Rightarrow> ('a::semiring_1)^'n"
   346   shows "sum (\<lambda>x. c *s f x) S = c *s sum f S"
   347   by (simp add: vec_eq_iff sum_distrib_left)
   348 
   349 lemma sum_norm_allsubsets_bound_cart:
   350   fixes f:: "'a \<Rightarrow> real ^'n"
   351   assumes fP: "finite P" and fPs: "\<And>Q. Q \<subseteq> P \<Longrightarrow> norm (sum f Q) \<le> e"
   352   shows "sum (\<lambda>x. norm (f x)) P \<le> 2 * real CARD('n) *  e"
   353   using sum_norm_allsubsets_bound[OF assms]
   354   by simp
   355 
   356 subsection\<open>Closures and interiors of halfspaces\<close>
   357 
   358 lemma interior_halfspace_le [simp]:
   359   assumes "a \<noteq> 0"
   360     shows "interior {x. a \<bullet> x \<le> b} = {x. a \<bullet> x < b}"
   361 proof -
   362   have *: "a \<bullet> x < b" if x: "x \<in> S" and S: "S \<subseteq> {x. a \<bullet> x \<le> b}" and "open S" for S x
   363   proof -
   364     obtain e where "e>0" and e: "cball x e \<subseteq> S"
   365       using \<open>open S\<close> open_contains_cball x by blast
   366     then have "x + (e / norm a) *\<^sub>R a \<in> cball x e"
   367       by (simp add: dist_norm)
   368     then have "x + (e / norm a) *\<^sub>R a \<in> S"
   369       using e by blast
   370     then have "x + (e / norm a) *\<^sub>R a \<in> {x. a \<bullet> x \<le> b}"
   371       using S by blast
   372     moreover have "e * (a \<bullet> a) / norm a > 0"
   373       by (simp add: \<open>0 < e\<close> assms)
   374     ultimately show ?thesis
   375       by (simp add: algebra_simps)
   376   qed
   377   show ?thesis
   378     by (rule interior_unique) (auto simp: open_halfspace_lt *)
   379 qed
   380 
   381 lemma interior_halfspace_ge [simp]:
   382    "a \<noteq> 0 \<Longrightarrow> interior {x. a \<bullet> x \<ge> b} = {x. a \<bullet> x > b}"
   383 using interior_halfspace_le [of "-a" "-b"] by simp
   384 
   385 lemma interior_halfspace_component_le [simp]:
   386      "interior {x. x$k \<le> a} = {x :: (real^'n). x$k < a}" (is "?LE")
   387   and interior_halfspace_component_ge [simp]:
   388      "interior {x. x$k \<ge> a} = {x :: (real^'n). x$k > a}" (is "?GE")
   389 proof -
   390   have "axis k (1::real) \<noteq> 0"
   391     by (simp add: axis_def vec_eq_iff)
   392   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   393     by (simp add: cart_eq_inner_axis inner_commute)
   394   ultimately show ?LE ?GE
   395     using interior_halfspace_le [of "axis k (1::real)" a]
   396           interior_halfspace_ge [of "axis k (1::real)" a] by auto
   397 qed
   398 
   399 lemma closure_halfspace_lt [simp]:
   400   assumes "a \<noteq> 0"
   401     shows "closure {x. a \<bullet> x < b} = {x. a \<bullet> x \<le> b}"
   402 proof -
   403   have [simp]: "-{x. a \<bullet> x < b} = {x. a \<bullet> x \<ge> b}"
   404     by (force simp:)
   405   then show ?thesis
   406     using interior_halfspace_ge [of a b] assms
   407     by (force simp: closure_interior)
   408 qed
   409 
   410 lemma closure_halfspace_gt [simp]:
   411    "a \<noteq> 0 \<Longrightarrow> closure {x. a \<bullet> x > b} = {x. a \<bullet> x \<ge> b}"
   412 using closure_halfspace_lt [of "-a" "-b"] by simp
   413 
   414 lemma closure_halfspace_component_lt [simp]:
   415      "closure {x. x$k < a} = {x :: (real^'n). x$k \<le> a}" (is "?LE")
   416   and closure_halfspace_component_gt [simp]:
   417      "closure {x. x$k > a} = {x :: (real^'n). x$k \<ge> a}" (is "?GE")
   418 proof -
   419   have "axis k (1::real) \<noteq> 0"
   420     by (simp add: axis_def vec_eq_iff)
   421   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   422     by (simp add: cart_eq_inner_axis inner_commute)
   423   ultimately show ?LE ?GE
   424     using closure_halfspace_lt [of "axis k (1::real)" a]
   425           closure_halfspace_gt [of "axis k (1::real)" a] by auto
   426 qed
   427 
   428 lemma interior_hyperplane [simp]:
   429   assumes "a \<noteq> 0"
   430     shows "interior {x. a \<bullet> x = b} = {}"
   431 proof -
   432   have [simp]: "{x. a \<bullet> x = b} = {x. a \<bullet> x \<le> b} \<inter> {x. a \<bullet> x \<ge> b}"
   433     by (force simp:)
   434   then show ?thesis
   435     by (auto simp: assms)
   436 qed
   437 
   438 lemma frontier_halfspace_le:
   439   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   440     shows "frontier {x. a \<bullet> x \<le> b} = {x. a \<bullet> x = b}"
   441 proof (cases "a = 0")
   442   case True with assms show ?thesis by simp
   443 next
   444   case False then show ?thesis
   445     by (force simp: frontier_def closed_halfspace_le)
   446 qed
   447 
   448 lemma frontier_halfspace_ge:
   449   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   450     shows "frontier {x. a \<bullet> x \<ge> b} = {x. a \<bullet> x = b}"
   451 proof (cases "a = 0")
   452   case True with assms show ?thesis by simp
   453 next
   454   case False then show ?thesis
   455     by (force simp: frontier_def closed_halfspace_ge)
   456 qed
   457 
   458 lemma frontier_halfspace_lt:
   459   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   460     shows "frontier {x. a \<bullet> x < b} = {x. a \<bullet> x = b}"
   461 proof (cases "a = 0")
   462   case True with assms show ?thesis by simp
   463 next
   464   case False then show ?thesis
   465     by (force simp: frontier_def interior_open open_halfspace_lt)
   466 qed
   467 
   468 lemma frontier_halfspace_gt:
   469   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   470     shows "frontier {x. a \<bullet> x > b} = {x. a \<bullet> x = b}"
   471 proof (cases "a = 0")
   472   case True with assms show ?thesis by simp
   473 next
   474   case False then show ?thesis
   475     by (force simp: frontier_def interior_open open_halfspace_gt)
   476 qed
   477 
   478 lemma interior_standard_hyperplane:
   479    "interior {x :: (real^'n). x$k = a} = {}"
   480 proof -
   481   have "axis k (1::real) \<noteq> 0"
   482     by (simp add: axis_def vec_eq_iff)
   483   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   484     by (simp add: cart_eq_inner_axis inner_commute)
   485   ultimately show ?thesis
   486     using interior_hyperplane [of "axis k (1::real)" a]
   487     by force
   488 qed
   489 
   490 subsection \<open>Matrix operations\<close>
   491 
   492 text\<open>Matrix notation. NB: an MxN matrix is of type @{typ "'a^'n^'m"}, not @{typ "'a^'m^'n"}\<close>
   493 
   494 definition map_matrix::"('a \<Rightarrow> 'b) \<Rightarrow> (('a, 'i::finite)vec, 'j::finite) vec \<Rightarrow> (('b, 'i)vec, 'j) vec" where
   495   "map_matrix f x = (\<chi> i j. f (x $ i $ j))"
   496 
   497 lemma nth_map_matrix[simp]: "map_matrix f x $ i $ j = f (x $ i $ j)"
   498   by (simp add: map_matrix_def)
   499 
   500 definition matrix_matrix_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'p^'n \<Rightarrow> 'a ^ 'p ^'m"
   501     (infixl "**" 70)
   502   where "m ** m' == (\<chi> i j. sum (\<lambda>k. ((m$i)$k) * ((m'$k)$j)) (UNIV :: 'n set)) ::'a ^ 'p ^'m"
   503 
   504 definition matrix_vector_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n \<Rightarrow> 'a ^ 'm"
   505     (infixl "*v" 70)
   506   where "m *v x \<equiv> (\<chi> i. sum (\<lambda>j. ((m$i)$j) * (x$j)) (UNIV ::'n set)) :: 'a^'m"
   507 
   508 definition vector_matrix_mult :: "'a ^ 'm \<Rightarrow> ('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n "
   509     (infixl "v*" 70)
   510   where "v v* m == (\<chi> j. sum (\<lambda>i. ((m$i)$j) * (v$i)) (UNIV :: 'm set)) :: 'a^'n"
   511 
   512 definition "(mat::'a::zero => 'a ^'n^'n) k = (\<chi> i j. if i = j then k else 0)"
   513 definition transpose where
   514   "(transpose::'a^'n^'m \<Rightarrow> 'a^'m^'n) A = (\<chi> i j. ((A$j)$i))"
   515 definition "(row::'m => 'a ^'n^'m \<Rightarrow> 'a ^'n) i A = (\<chi> j. ((A$i)$j))"
   516 definition "(column::'n =>'a^'n^'m =>'a^'m) j A = (\<chi> i. ((A$i)$j))"
   517 definition "rows(A::'a^'n^'m) = { row i A | i. i \<in> (UNIV :: 'm set)}"
   518 definition "columns(A::'a^'n^'m) = { column i A | i. i \<in> (UNIV :: 'n set)}"
   519 
   520 lemma mat_0[simp]: "mat 0 = 0" by (vector mat_def)
   521 lemma matrix_add_ldistrib: "(A ** (B + C)) = (A ** B) + (A ** C)"
   522   by (vector matrix_matrix_mult_def sum.distrib[symmetric] field_simps)
   523 
   524 lemma matrix_mul_lid [simp]:
   525   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   526   shows "mat 1 ** A = A"
   527   apply (simp add: matrix_matrix_mult_def mat_def)
   528   apply vector
   529   apply (auto simp only: if_distrib cond_application_beta sum.delta'[OF finite]
   530     mult_1_left mult_zero_left if_True UNIV_I)
   531   done
   532 
   533 
   534 lemma matrix_mul_rid [simp]:
   535   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   536   shows "A ** mat 1 = A"
   537   apply (simp add: matrix_matrix_mult_def mat_def)
   538   apply vector
   539   apply (auto simp only: if_distrib cond_application_beta sum.delta[OF finite]
   540     mult_1_right mult_zero_right if_True UNIV_I cong: if_cong)
   541   done
   542 
   543 lemma matrix_mul_assoc: "A ** (B ** C) = (A ** B) ** C"
   544   apply (vector matrix_matrix_mult_def sum_distrib_left sum_distrib_right mult.assoc)
   545   apply (subst sum.swap)
   546   apply simp
   547   done
   548 
   549 lemma matrix_vector_mul_assoc: "A *v (B *v x) = (A ** B) *v x"
   550   apply (vector matrix_matrix_mult_def matrix_vector_mult_def
   551     sum_distrib_left sum_distrib_right mult.assoc)
   552   apply (subst sum.swap)
   553   apply simp
   554   done
   555 
   556 lemma matrix_vector_mul_lid [simp]: "mat 1 *v x = (x::'a::semiring_1 ^ 'n)"
   557   apply (vector matrix_vector_mult_def mat_def)
   558   apply (simp add: if_distrib cond_application_beta sum.delta' cong del: if_weak_cong)
   559   done
   560 
   561 lemma matrix_transpose_mul:
   562     "transpose(A ** B) = transpose B ** transpose (A::'a::comm_semiring_1^_^_)"
   563   by (simp add: matrix_matrix_mult_def transpose_def vec_eq_iff mult.commute)
   564 
   565 lemma matrix_eq:
   566   fixes A B :: "'a::semiring_1 ^ 'n ^ 'm"
   567   shows "A = B \<longleftrightarrow>  (\<forall>x. A *v x = B *v x)" (is "?lhs \<longleftrightarrow> ?rhs")
   568   apply auto
   569   apply (subst vec_eq_iff)
   570   apply clarify
   571   apply (clarsimp simp add: matrix_vector_mult_def if_distrib cond_application_beta vec_eq_iff cong del: if_weak_cong)
   572   apply (erule_tac x="axis ia 1" in allE)
   573   apply (erule_tac x="i" in allE)
   574   apply (auto simp add: if_distrib cond_application_beta axis_def
   575     sum.delta[OF finite] cong del: if_weak_cong)
   576   done
   577 
   578 lemma matrix_vector_mul_component: "((A::real^_^_) *v x)$k = (A$k) \<bullet> x"
   579   by (simp add: matrix_vector_mult_def inner_vec_def)
   580 
   581 lemma dot_lmul_matrix: "((x::real ^_) v* A) \<bullet> y = x \<bullet> (A *v y)"
   582   apply (simp add: inner_vec_def matrix_vector_mult_def vector_matrix_mult_def sum_distrib_right sum_distrib_left ac_simps)
   583   apply (subst sum.swap)
   584   apply simp
   585   done
   586 
   587 lemma transpose_mat [simp]: "transpose (mat n) = mat n"
   588   by (vector transpose_def mat_def)
   589 
   590 lemma transpose_transpose [simp]: "transpose(transpose A) = A"
   591   by (vector transpose_def)
   592 
   593 lemma row_transpose [simp]:
   594   fixes A:: "'a::semiring_1^_^_"
   595   shows "row i (transpose A) = column i A"
   596   by (simp add: row_def column_def transpose_def vec_eq_iff)
   597 
   598 lemma column_transpose [simp]:
   599   fixes A:: "'a::semiring_1^_^_"
   600   shows "column i (transpose A) = row i A"
   601   by (simp add: row_def column_def transpose_def vec_eq_iff)
   602 
   603 lemma rows_transpose [simp]: "rows(transpose (A::'a::semiring_1^_^_)) = columns A"
   604   by (auto simp add: rows_def columns_def row_transpose intro: set_eqI)
   605 
   606 lemma columns_transpose [simp]: "columns(transpose (A::'a::semiring_1^_^_)) = rows A"
   607   by (metis transpose_transpose rows_transpose)
   608 
   609 lemma matrix_mult_transpose_dot_column:
   610   fixes A :: "real^'n^'n"
   611   shows "transpose A ** A = (\<chi> i j. (column i A) \<bullet> (column j A))"
   612   by (simp add: matrix_matrix_mult_def vec_eq_iff transpose_def column_def inner_vec_def)
   613 
   614 lemma matrix_mult_transpose_dot_row:
   615   fixes A :: "real^'n^'n"
   616   shows "A ** transpose A = (\<chi> i j. (row i A) \<bullet> (row j A))"
   617   by (simp add: matrix_matrix_mult_def vec_eq_iff transpose_def row_def inner_vec_def)
   618 
   619 text\<open>Two sometimes fruitful ways of looking at matrix-vector multiplication.\<close>
   620 
   621 lemma matrix_mult_dot: "A *v x = (\<chi> i. A$i \<bullet> x)"
   622   by (simp add: matrix_vector_mult_def inner_vec_def)
   623 
   624 lemma matrix_mult_sum:
   625   "(A::'a::comm_semiring_1^'n^'m) *v x = sum (\<lambda>i. (x$i) *s column i A) (UNIV:: 'n set)"
   626   by (simp add: matrix_vector_mult_def vec_eq_iff column_def mult.commute)
   627 
   628 lemma vector_componentwise:
   629   "(x::'a::ring_1^'n) = (\<chi> j. \<Sum>i\<in>UNIV. (x$i) * (axis i 1 :: 'a^'n) $ j)"
   630   by (simp add: axis_def if_distrib sum.If_cases vec_eq_iff)
   631 
   632 lemma basis_expansion: "sum (\<lambda>i. (x$i) *s axis i 1) UNIV = (x::('a::ring_1) ^'n)"
   633   by (auto simp add: axis_def vec_eq_iff if_distrib sum.If_cases cong del: if_weak_cong)
   634 
   635 lemma linear_componentwise_expansion:
   636   fixes f:: "real ^'m \<Rightarrow> real ^ _"
   637   assumes lf: "linear f"
   638   shows "(f x)$j = sum (\<lambda>i. (x$i) * (f (axis i 1)$j)) (UNIV :: 'm set)" (is "?lhs = ?rhs")
   639 proof -
   640   let ?M = "(UNIV :: 'm set)"
   641   let ?N = "(UNIV :: 'n set)"
   642   have "?rhs = (sum (\<lambda>i.(x$i) *\<^sub>R f (axis i 1) ) ?M)$j"
   643     unfolding sum_component by simp
   644   then show ?thesis
   645     unfolding linear_sum_mul[OF lf, symmetric]
   646     unfolding scalar_mult_eq_scaleR[symmetric]
   647     unfolding basis_expansion
   648     by simp
   649 qed
   650 
   651 subsection\<open>Inverse matrices  (not necessarily square)\<close>
   652 
   653 definition
   654   "invertible(A::'a::semiring_1^'n^'m) \<longleftrightarrow> (\<exists>A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   655 
   656 definition
   657   "matrix_inv(A:: 'a::semiring_1^'n^'m) =
   658     (SOME A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   659 
   660 text\<open>Correspondence between matrices and linear operators.\<close>
   661 
   662 definition matrix :: "('a::{plus,times, one, zero}^'m \<Rightarrow> 'a ^ 'n) \<Rightarrow> 'a^'m^'n"
   663   where "matrix f = (\<chi> i j. (f(axis j 1))$i)"
   664 
   665 lemma matrix_vector_mul_linear: "linear(\<lambda>x. A *v (x::real ^ _))"
   666   by (simp add: linear_iff matrix_vector_mult_def vec_eq_iff
   667       field_simps sum_distrib_left sum.distrib)
   668 
   669 lemma
   670   fixes A :: "real^'n^'m"
   671   shows matrix_vector_mult_linear_continuous_at [continuous_intros]: "isCont (( *v) A) z"
   672     and matrix_vector_mult_linear_continuous_on [continuous_intros]: "continuous_on S (( *v) A)"
   673   by (simp_all add: linear_linear linear_continuous_at linear_continuous_on matrix_vector_mul_linear)
   674 
   675 lemma matrix_vector_mult_add_distrib [algebra_simps]:
   676   "A *v (x + y) = A *v x + A *v y"
   677   by (vector matrix_vector_mult_def sum.distrib distrib_left)
   678 
   679 lemma matrix_vector_mult_diff_distrib [algebra_simps]:
   680   fixes A :: "'a::ring_1^'n^'m"
   681   shows "A *v (x - y) = A *v x - A *v y"
   682   by (vector matrix_vector_mult_def sum_subtractf right_diff_distrib)
   683 
   684 lemma matrix_vector_mult_scaleR[algebra_simps]:
   685   fixes A :: "real^'n^'m"
   686   shows "A *v (c *\<^sub>R x) = c *\<^sub>R (A *v x)"
   687   using linear_iff matrix_vector_mul_linear by blast
   688 
   689 lemma matrix_vector_mult_0_right [simp]: "A *v 0 = 0"
   690   by (simp add: matrix_vector_mult_def vec_eq_iff)
   691 
   692 lemma matrix_vector_mult_0 [simp]: "0 *v w = 0"
   693   by (simp add: matrix_vector_mult_def vec_eq_iff)
   694 
   695 lemma matrix_vector_mult_add_rdistrib [algebra_simps]:
   696   "(A + B) *v x = (A *v x) + (B *v x)"
   697   by (vector matrix_vector_mult_def sum.distrib distrib_right)
   698 
   699 lemma matrix_vector_mult_diff_rdistrib [algebra_simps]:
   700   fixes A :: "'a :: ring_1^'n^'m"
   701   shows "(A - B) *v x = (A *v x) - (B *v x)"
   702   by (vector matrix_vector_mult_def sum_subtractf left_diff_distrib)
   703 
   704 lemma matrix_works:
   705   assumes lf: "linear f"
   706   shows "matrix f *v x = f (x::real ^ 'n)"
   707   apply (simp add: matrix_def matrix_vector_mult_def vec_eq_iff mult.commute)
   708   by (simp add: linear_componentwise_expansion lf)
   709 
   710 lemma matrix_vector_mul: "linear f ==> f = (\<lambda>x. matrix f *v (x::real ^ 'n))"
   711   by (simp add: ext matrix_works)
   712 
   713 declare matrix_vector_mul [symmetric, simp]
   714 
   715 lemma matrix_of_matrix_vector_mul [simp]: "matrix(\<lambda>x. A *v (x :: real ^ 'n)) = A"
   716   by (simp add: matrix_eq matrix_vector_mul_linear matrix_works)
   717 
   718 lemma matrix_compose:
   719   assumes lf: "linear (f::real^'n \<Rightarrow> real^'m)"
   720     and lg: "linear (g::real^'m \<Rightarrow> real^_)"
   721   shows "matrix (g \<circ> f) = matrix g ** matrix f"
   722   using lf lg linear_compose[OF lf lg] matrix_works[OF linear_compose[OF lf lg]]
   723   by (simp add: matrix_eq matrix_works matrix_vector_mul_assoc[symmetric] o_def)
   724 
   725 lemma matrix_vector_column:
   726   "(A::'a::comm_semiring_1^'n^_) *v x = sum (\<lambda>i. (x$i) *s ((transpose A)$i)) (UNIV:: 'n set)"
   727   by (simp add: matrix_vector_mult_def transpose_def vec_eq_iff mult.commute)
   728 
   729 lemma adjoint_matrix: "adjoint(\<lambda>x. (A::real^'n^'m) *v x) = (\<lambda>x. transpose A *v x)"
   730   apply (rule adjoint_unique)
   731   apply (simp add: transpose_def inner_vec_def matrix_vector_mult_def
   732     sum_distrib_right sum_distrib_left)
   733   apply (subst sum.swap)
   734   apply (auto simp add: ac_simps)
   735   done
   736 
   737 lemma matrix_adjoint: assumes lf: "linear (f :: real^'n \<Rightarrow> real ^'m)"
   738   shows "matrix(adjoint f) = transpose(matrix f)"
   739   apply (subst matrix_vector_mul[OF lf])
   740   unfolding adjoint_matrix matrix_of_matrix_vector_mul
   741   apply rule
   742   done
   743 
   744 
   745 subsection\<open>Some bounds on components etc. relative to operator norm\<close>
   746 
   747 lemma norm_column_le_onorm:
   748   fixes A :: "real^'n^'m"
   749   shows "norm(column i A) \<le> onorm(( *v) A)"
   750 proof -
   751   have bl: "bounded_linear (( *v) A)"
   752     by (simp add: linear_linear matrix_vector_mul_linear)
   753   have "norm (\<chi> j. A $ j $ i) \<le> norm (A *v axis i 1)"
   754     by (simp add: matrix_mult_dot cart_eq_inner_axis)
   755   also have "\<dots> \<le> onorm (( *v) A)"
   756     using onorm [OF bl, of "axis i 1"] by (auto simp: axis_in_Basis)
   757   finally have "norm (\<chi> j. A $ j $ i) \<le> onorm (( *v) A)" .
   758   then show ?thesis
   759     unfolding column_def .
   760 qed
   761 
   762 lemma matrix_component_le_onorm:
   763   fixes A :: "real^'n^'m"
   764   shows "\<bar>A $ i $ j\<bar> \<le> onorm(( *v) A)"
   765 proof -
   766   have "\<bar>A $ i $ j\<bar> \<le> norm (\<chi> n. (A $ n $ j))"
   767     by (metis (full_types, lifting) component_le_norm_cart vec_lambda_beta)
   768   also have "\<dots> \<le> onorm (( *v) A)"
   769     by (metis (no_types) column_def norm_column_le_onorm)
   770   finally show ?thesis .
   771 qed
   772 
   773 lemma component_le_onorm:
   774   fixes f :: "real^'m \<Rightarrow> real^'n"
   775   shows "linear f \<Longrightarrow> \<bar>matrix f $ i $ j\<bar> \<le> onorm f"
   776   by (metis matrix_component_le_onorm matrix_vector_mul)
   777 
   778 lemma onorm_le_matrix_component_sum:
   779   fixes A :: "real^'n^'m"
   780   shows "onorm(( *v) A) \<le> (\<Sum>i\<in>UNIV. \<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar>)"
   781 proof (rule onorm_le)
   782   fix x
   783   have "norm (A *v x) \<le> (\<Sum>i\<in>UNIV. \<bar>(A *v x) $ i\<bar>)"
   784     by (rule norm_le_l1_cart)
   785   also have "\<dots> \<le> (\<Sum>i\<in>UNIV. \<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar> * norm x)"
   786   proof (rule sum_mono)
   787     fix i
   788     have "\<bar>(A *v x) $ i\<bar> \<le> \<bar>\<Sum>j\<in>UNIV. A $ i $ j * x $ j\<bar>"
   789       by (simp add: matrix_vector_mult_def)
   790     also have "\<dots> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j * x $ j\<bar>)"
   791       by (rule sum_abs)
   792     also have "\<dots> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar> * norm x)"
   793       by (rule sum_mono) (simp add: abs_mult component_le_norm_cart mult_left_mono)
   794     finally show "\<bar>(A *v x) $ i\<bar> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar> * norm x)" .
   795   qed
   796   finally show "norm (A *v x) \<le> (\<Sum>i\<in>UNIV. \<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar>) * norm x"
   797     by (simp add: sum_distrib_right)
   798 qed
   799 
   800 lemma onorm_le_matrix_component:
   801   fixes A :: "real^'n^'m"
   802   assumes "\<And>i j. abs(A$i$j) \<le> B"
   803   shows "onorm(( *v) A) \<le> real (CARD('m)) * real (CARD('n)) * B"
   804 proof (rule onorm_le)
   805   fix x :: "real^'n::_"
   806   have "norm (A *v x) \<le> (\<Sum>i\<in>UNIV. \<bar>(A *v x) $ i\<bar>)"
   807     by (rule norm_le_l1_cart)
   808   also have "\<dots> \<le> (\<Sum>i::'m \<in>UNIV. real (CARD('n)) * B * norm x)"
   809   proof (rule sum_mono)
   810     fix i
   811     have "\<bar>(A *v x) $ i\<bar> \<le> norm(A $ i) * norm x"
   812       by (simp add: matrix_mult_dot Cauchy_Schwarz_ineq2)
   813     also have "\<dots> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar>) * norm x"
   814       by (simp add: mult_right_mono norm_le_l1_cart)
   815     also have "\<dots> \<le> real (CARD('n)) * B * norm x"
   816       by (simp add: assms sum_bounded_above mult_right_mono)
   817     finally show "\<bar>(A *v x) $ i\<bar> \<le> real (CARD('n)) * B * norm x" .
   818   qed
   819   also have "\<dots> \<le> CARD('m) * real (CARD('n)) * B * norm x"
   820     by simp
   821   finally show "norm (A *v x) \<le> CARD('m) * real (CARD('n)) * B * norm x" .
   822 qed
   823 
   824 subsection \<open>lambda skolemization on cartesian products\<close>
   825 
   826 lemma lambda_skolem: "(\<forall>i. \<exists>x. P i x) \<longleftrightarrow>
   827    (\<exists>x::'a ^ 'n. \<forall>i. P i (x $ i))" (is "?lhs \<longleftrightarrow> ?rhs")
   828 proof -
   829   let ?S = "(UNIV :: 'n set)"
   830   { assume H: "?rhs"
   831     then have ?lhs by auto }
   832   moreover
   833   { assume H: "?lhs"
   834     then obtain f where f:"\<forall>i. P i (f i)" unfolding choice_iff by metis
   835     let ?x = "(\<chi> i. (f i)) :: 'a ^ 'n"
   836     { fix i
   837       from f have "P i (f i)" by metis
   838       then have "P i (?x $ i)" by auto
   839     }
   840     hence "\<forall>i. P i (?x$i)" by metis
   841     hence ?rhs by metis }
   842   ultimately show ?thesis by metis
   843 qed
   844 
   845 lemma rational_approximation:
   846   assumes "e > 0"
   847   obtains r::real where "r \<in> \<rat>" "\<bar>r - x\<bar> < e"
   848   using Rats_dense_in_real [of "x - e/2" "x + e/2"] assms by auto
   849 
   850 lemma matrix_rational_approximation:
   851   fixes A :: "real^'n^'m"
   852   assumes "e > 0"
   853   obtains B where "\<And>i j. B$i$j \<in> \<rat>" "onorm(\<lambda>x. (A - B) *v x) < e"
   854 proof -
   855   have "\<forall>i j. \<exists>q \<in> \<rat>. \<bar>q - A $ i $ j\<bar> < e / (2 * CARD('m) * CARD('n))"
   856     using assms by (force intro: rational_approximation [of "e / (2 * CARD('m) * CARD('n))"])
   857   then obtain B where B: "\<And>i j. B$i$j \<in> \<rat>" and Bclo: "\<And>i j. \<bar>B$i$j - A $ i $ j\<bar> < e / (2 * CARD('m) * CARD('n))"
   858     by (auto simp: lambda_skolem Bex_def)
   859   show ?thesis
   860   proof
   861     have "onorm (( *v) (A - B)) \<le> real CARD('m) * real CARD('n) *
   862     (e / (2 * real CARD('m) * real CARD('n)))"
   863       apply (rule onorm_le_matrix_component)
   864       using Bclo by (simp add: abs_minus_commute less_imp_le)
   865     also have "\<dots> < e"
   866       using \<open>0 < e\<close> by (simp add: divide_simps)
   867     finally show "onorm (( *v) (A - B)) < e" .
   868   qed (use B in auto)
   869 qed
   870 
   871 lemma vector_sub_project_orthogonal_cart: "(b::real^'n) \<bullet> (x - ((b \<bullet> x) / (b \<bullet> b)) *s b) = 0"
   872   unfolding inner_simps scalar_mult_eq_scaleR by auto
   873 
   874 lemma left_invertible_transpose:
   875   "(\<exists>(B). B ** transpose (A) = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). A ** B = mat 1)"
   876   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   877 
   878 lemma right_invertible_transpose:
   879   "(\<exists>(B). transpose (A) ** B = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). B ** A = mat 1)"
   880   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   881 
   882 lemma matrix_left_invertible_injective:
   883   "(\<exists>B. (B::real^'m^'n) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x y. A *v x = A *v y \<longrightarrow> x = y)"
   884 proof -
   885   { fix B:: "real^'m^'n" and x y assume B: "B ** A = mat 1" and xy: "A *v x = A*v y"
   886     from xy have "B*v (A *v x) = B *v (A*v y)" by simp
   887     hence "x = y"
   888       unfolding matrix_vector_mul_assoc B matrix_vector_mul_lid . }
   889   moreover
   890   { assume A: "\<forall>x y. A *v x = A *v y \<longrightarrow> x = y"
   891     hence i: "inj (( *v) A)" unfolding inj_on_def by auto
   892     from linear_injective_left_inverse[OF matrix_vector_mul_linear i]
   893     obtain g where g: "linear g" "g \<circ> ( *v) A = id" by blast
   894     have "matrix g ** A = mat 1"
   895       unfolding matrix_eq matrix_vector_mul_lid matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
   896       using g(2) by (simp add: fun_eq_iff)
   897     then have "\<exists>B. (B::real ^'m^'n) ** A = mat 1" by blast }
   898   ultimately show ?thesis by blast
   899 qed
   900 
   901 lemma matrix_left_invertible_ker:
   902   "(\<exists>B. (B::real ^'m^'n) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x. A *v x = 0 \<longrightarrow> x = 0)"
   903   unfolding matrix_left_invertible_injective
   904   using linear_injective_0[OF matrix_vector_mul_linear, of A]
   905   by (simp add: inj_on_def)
   906 
   907 lemma matrix_right_invertible_surjective:
   908   "(\<exists>B. (A::real^'n^'m) ** (B::real^'m^'n) = mat 1) \<longleftrightarrow> surj (\<lambda>x. A *v x)"
   909 proof -
   910   { fix B :: "real ^'m^'n"
   911     assume AB: "A ** B = mat 1"
   912     { fix x :: "real ^ 'm"
   913       have "A *v (B *v x) = x"
   914         by (simp add: matrix_vector_mul_lid matrix_vector_mul_assoc AB) }
   915     hence "surj (( *v) A)" unfolding surj_def by metis }
   916   moreover
   917   { assume sf: "surj (( *v) A)"
   918     from linear_surjective_right_inverse[OF matrix_vector_mul_linear sf]
   919     obtain g:: "real ^'m \<Rightarrow> real ^'n" where g: "linear g" "( *v) A \<circ> g = id"
   920       by blast
   921 
   922     have "A ** (matrix g) = mat 1"
   923       unfolding matrix_eq  matrix_vector_mul_lid
   924         matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
   925       using g(2) unfolding o_def fun_eq_iff id_def
   926       .
   927     hence "\<exists>B. A ** (B::real^'m^'n) = mat 1" by blast
   928   }
   929   ultimately show ?thesis unfolding surj_def by blast
   930 qed
   931 
   932 lemma matrix_left_invertible_independent_columns:
   933   fixes A :: "real^'n^'m"
   934   shows "(\<exists>(B::real ^'m^'n). B ** A = mat 1) \<longleftrightarrow>
   935       (\<forall>c. sum (\<lambda>i. c i *s column i A) (UNIV :: 'n set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   936     (is "?lhs \<longleftrightarrow> ?rhs")
   937 proof -
   938   let ?U = "UNIV :: 'n set"
   939   { assume k: "\<forall>x. A *v x = 0 \<longrightarrow> x = 0"
   940     { fix c i
   941       assume c: "sum (\<lambda>i. c i *s column i A) ?U = 0" and i: "i \<in> ?U"
   942       let ?x = "\<chi> i. c i"
   943       have th0:"A *v ?x = 0"
   944         using c
   945         unfolding matrix_mult_sum vec_eq_iff
   946         by auto
   947       from k[rule_format, OF th0] i
   948       have "c i = 0" by (vector vec_eq_iff)}
   949     hence ?rhs by blast }
   950   moreover
   951   { assume H: ?rhs
   952     { fix x assume x: "A *v x = 0"
   953       let ?c = "\<lambda>i. ((x$i ):: real)"
   954       from H[rule_format, of ?c, unfolded matrix_mult_sum[symmetric], OF x]
   955       have "x = 0" by vector }
   956   }
   957   ultimately show ?thesis unfolding matrix_left_invertible_ker by blast
   958 qed
   959 
   960 lemma matrix_right_invertible_independent_rows:
   961   fixes A :: "real^'n^'m"
   962   shows "(\<exists>(B::real^'m^'n). A ** B = mat 1) \<longleftrightarrow>
   963     (\<forall>c. sum (\<lambda>i. c i *s row i A) (UNIV :: 'm set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   964   unfolding left_invertible_transpose[symmetric]
   965     matrix_left_invertible_independent_columns
   966   by (simp add: column_transpose)
   967 
   968 lemma matrix_right_invertible_span_columns:
   969   "(\<exists>(B::real ^'n^'m). (A::real ^'m^'n) ** B = mat 1) \<longleftrightarrow>
   970     span (columns A) = UNIV" (is "?lhs = ?rhs")
   971 proof -
   972   let ?U = "UNIV :: 'm set"
   973   have fU: "finite ?U" by simp
   974   have lhseq: "?lhs \<longleftrightarrow> (\<forall>y. \<exists>(x::real^'m). sum (\<lambda>i. (x$i) *s column i A) ?U = y)"
   975     unfolding matrix_right_invertible_surjective matrix_mult_sum surj_def
   976     apply (subst eq_commute)
   977     apply rule
   978     done
   979   have rhseq: "?rhs \<longleftrightarrow> (\<forall>x. x \<in> span (columns A))" by blast
   980   { assume h: ?lhs
   981     { fix x:: "real ^'n"
   982       from h[unfolded lhseq, rule_format, of x] obtain y :: "real ^'m"
   983         where y: "sum (\<lambda>i. (y$i) *s column i A) ?U = x" by blast
   984       have "x \<in> span (columns A)"
   985         unfolding y[symmetric]
   986         apply (rule span_sum)
   987         unfolding scalar_mult_eq_scaleR
   988         apply (rule span_mul)
   989         apply (rule span_superset)
   990         unfolding columns_def
   991         apply blast
   992         done
   993     }
   994     then have ?rhs unfolding rhseq by blast }
   995   moreover
   996   { assume h:?rhs
   997     let ?P = "\<lambda>(y::real ^'n). \<exists>(x::real^'m). sum (\<lambda>i. (x$i) *s column i A) ?U = y"
   998     { fix y
   999       have "?P y"
  1000       proof (rule span_induct_alt[of ?P "columns A", folded scalar_mult_eq_scaleR])
  1001         show "\<exists>x::real ^ 'm. sum (\<lambda>i. (x$i) *s column i A) ?U = 0"
  1002           by (rule exI[where x=0], simp)
  1003       next
  1004         fix c y1 y2
  1005         assume y1: "y1 \<in> columns A" and y2: "?P y2"
  1006         from y1 obtain i where i: "i \<in> ?U" "y1 = column i A"
  1007           unfolding columns_def by blast
  1008         from y2 obtain x:: "real ^'m" where
  1009           x: "sum (\<lambda>i. (x$i) *s column i A) ?U = y2" by blast
  1010         let ?x = "(\<chi> j. if j = i then c + (x$i) else (x$j))::real^'m"
  1011         show "?P (c*s y1 + y2)"
  1012         proof (rule exI[where x= "?x"], vector, auto simp add: i x[symmetric] if_distrib distrib_left cond_application_beta cong del: if_weak_cong)
  1013           fix j
  1014           have th: "\<forall>xa \<in> ?U. (if xa = i then (c + (x$i)) * ((column xa A)$j)
  1015               else (x$xa) * ((column xa A$j))) = (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))"
  1016             using i(1) by (simp add: field_simps)
  1017           have "sum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
  1018               else (x$xa) * ((column xa A$j))) ?U = sum (\<lambda>xa. (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))) ?U"
  1019             apply (rule sum.cong[OF refl])
  1020             using th apply blast
  1021             done
  1022           also have "\<dots> = sum (\<lambda>xa. if xa = i then c * ((column i A)$j) else 0) ?U + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
  1023             by (simp add: sum.distrib)
  1024           also have "\<dots> = c * ((column i A)$j) + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
  1025             unfolding sum.delta[OF fU]
  1026             using i(1) by simp
  1027           finally show "sum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
  1028             else (x$xa) * ((column xa A$j))) ?U = c * ((column i A)$j) + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U" .
  1029         qed
  1030       next
  1031         show "y \<in> span (columns A)"
  1032           unfolding h by blast
  1033       qed
  1034     }
  1035     then have ?lhs unfolding lhseq ..
  1036   }
  1037   ultimately show ?thesis by blast
  1038 qed
  1039 
  1040 lemma matrix_left_invertible_span_rows:
  1041   "(\<exists>(B::real^'m^'n). B ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> span (rows A) = UNIV"
  1042   unfolding right_invertible_transpose[symmetric]
  1043   unfolding columns_transpose[symmetric]
  1044   unfolding matrix_right_invertible_span_columns
  1045   ..
  1046 
  1047 text \<open>The same result in terms of square matrices.\<close>
  1048 
  1049 lemma matrix_left_right_inverse:
  1050   fixes A A' :: "real ^'n^'n"
  1051   shows "A ** A' = mat 1 \<longleftrightarrow> A' ** A = mat 1"
  1052 proof -
  1053   { fix A A' :: "real ^'n^'n"
  1054     assume AA': "A ** A' = mat 1"
  1055     have sA: "surj (( *v) A)"
  1056       unfolding surj_def
  1057       apply clarify
  1058       apply (rule_tac x="(A' *v y)" in exI)
  1059       apply (simp add: matrix_vector_mul_assoc AA' matrix_vector_mul_lid)
  1060       done
  1061     from linear_surjective_isomorphism[OF matrix_vector_mul_linear sA]
  1062     obtain f' :: "real ^'n \<Rightarrow> real ^'n"
  1063       where f': "linear f'" "\<forall>x. f' (A *v x) = x" "\<forall>x. A *v f' x = x" by blast
  1064     have th: "matrix f' ** A = mat 1"
  1065       by (simp add: matrix_eq matrix_works[OF f'(1)]
  1066           matrix_vector_mul_assoc[symmetric] matrix_vector_mul_lid f'(2)[rule_format])
  1067     hence "(matrix f' ** A) ** A' = mat 1 ** A'" by simp
  1068     hence "matrix f' = A'"
  1069       by (simp add: matrix_mul_assoc[symmetric] AA' matrix_mul_rid matrix_mul_lid)
  1070     hence "matrix f' ** A = A' ** A" by simp
  1071     hence "A' ** A = mat 1" by (simp add: th)
  1072   }
  1073   then show ?thesis by blast
  1074 qed
  1075 
  1076 text \<open>Considering an n-element vector as an n-by-1 or 1-by-n matrix.\<close>
  1077 
  1078 definition "rowvector v = (\<chi> i j. (v$j))"
  1079 
  1080 definition "columnvector v = (\<chi> i j. (v$i))"
  1081 
  1082 lemma transpose_columnvector: "transpose(columnvector v) = rowvector v"
  1083   by (simp add: transpose_def rowvector_def columnvector_def vec_eq_iff)
  1084 
  1085 lemma transpose_rowvector: "transpose(rowvector v) = columnvector v"
  1086   by (simp add: transpose_def columnvector_def rowvector_def vec_eq_iff)
  1087 
  1088 lemma dot_rowvector_columnvector: "columnvector (A *v v) = A ** columnvector v"
  1089   by (vector columnvector_def matrix_matrix_mult_def matrix_vector_mult_def)
  1090 
  1091 lemma dot_matrix_product:
  1092   "(x::real^'n) \<bullet> y = (((rowvector x ::real^'n^1) ** (columnvector y :: real^1^'n))$1)$1"
  1093   by (vector matrix_matrix_mult_def rowvector_def columnvector_def inner_vec_def)
  1094 
  1095 lemma dot_matrix_vector_mul:
  1096   fixes A B :: "real ^'n ^'n" and x y :: "real ^'n"
  1097   shows "(A *v x) \<bullet> (B *v y) =
  1098       (((rowvector x :: real^'n^1) ** ((transpose A ** B) ** (columnvector y :: real ^1^'n)))$1)$1"
  1099   unfolding dot_matrix_product transpose_columnvector[symmetric]
  1100     dot_rowvector_columnvector matrix_transpose_mul matrix_mul_assoc ..
  1101 
  1102 lemma infnorm_cart:"infnorm (x::real^'n) = Sup {\<bar>x$i\<bar> |i. i\<in>UNIV}"
  1103   by (simp add: infnorm_def inner_axis Basis_vec_def) (metis (lifting) inner_axis real_inner_1_right)
  1104 
  1105 lemma component_le_infnorm_cart: "\<bar>x$i\<bar> \<le> infnorm (x::real^'n)"
  1106   using Basis_le_infnorm[of "axis i 1" x]
  1107   by (simp add: Basis_vec_def axis_eq_axis inner_axis)
  1108 
  1109 lemma continuous_component[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x $ i)"
  1110   unfolding continuous_def by (rule tendsto_vec_nth)
  1111 
  1112 lemma continuous_on_component[continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x $ i)"
  1113   unfolding continuous_on_def by (fast intro: tendsto_vec_nth)
  1114 
  1115 lemma continuous_on_vec_lambda[continuous_intros]:
  1116   "(\<And>i. continuous_on S (f i)) \<Longrightarrow> continuous_on S (\<lambda>x. \<chi> i. f i x)"
  1117   unfolding continuous_on_def by (auto intro: tendsto_vec_lambda)
  1118 
  1119 lemma closed_positive_orthant: "closed {x::real^'n. \<forall>i. 0 \<le>x$i}"
  1120   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1121 
  1122 lemma bounded_component_cart: "bounded s \<Longrightarrow> bounded ((\<lambda>x. x $ i) ` s)"
  1123   unfolding bounded_def
  1124   apply clarify
  1125   apply (rule_tac x="x $ i" in exI)
  1126   apply (rule_tac x="e" in exI)
  1127   apply clarify
  1128   apply (rule order_trans [OF dist_vec_nth_le], simp)
  1129   done
  1130 
  1131 lemma compact_lemma_cart:
  1132   fixes f :: "nat \<Rightarrow> 'a::heine_borel ^ 'n"
  1133   assumes f: "bounded (range f)"
  1134   shows "\<exists>l r. strict_mono r \<and>
  1135         (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $ i) (l $ i) < e) sequentially)"
  1136     (is "?th d")
  1137 proof -
  1138   have "\<forall>d' \<subseteq> d. ?th d'"
  1139     by (rule compact_lemma_general[where unproj=vec_lambda])
  1140       (auto intro!: f bounded_component_cart simp: vec_lambda_eta)
  1141   then show "?th d" by simp
  1142 qed
  1143 
  1144 instance vec :: (heine_borel, finite) heine_borel
  1145 proof
  1146   fix f :: "nat \<Rightarrow> 'a ^ 'b"
  1147   assume f: "bounded (range f)"
  1148   then obtain l r where r: "strict_mono r"
  1149       and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>UNIV. dist (f (r n) $ i) (l $ i) < e) sequentially"
  1150     using compact_lemma_cart [OF f] by blast
  1151   let ?d = "UNIV::'b set"
  1152   { fix e::real assume "e>0"
  1153     hence "0 < e / (real_of_nat (card ?d))"
  1154       using zero_less_card_finite divide_pos_pos[of e, of "real_of_nat (card ?d)"] by auto
  1155     with l have "eventually (\<lambda>n. \<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))) sequentially"
  1156       by simp
  1157     moreover
  1158     { fix n
  1159       assume n: "\<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))"
  1160       have "dist (f (r n)) l \<le> (\<Sum>i\<in>?d. dist (f (r n) $ i) (l $ i))"
  1161         unfolding dist_vec_def using zero_le_dist by (rule L2_set_le_sum)
  1162       also have "\<dots> < (\<Sum>i\<in>?d. e / (real_of_nat (card ?d)))"
  1163         by (rule sum_strict_mono) (simp_all add: n)
  1164       finally have "dist (f (r n)) l < e" by simp
  1165     }
  1166     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
  1167       by (rule eventually_mono)
  1168   }
  1169   hence "((f \<circ> r) \<longlongrightarrow> l) sequentially" unfolding o_def tendsto_iff by simp
  1170   with r show "\<exists>l r. strict_mono r \<and> ((f \<circ> r) \<longlongrightarrow> l) sequentially" by auto
  1171 qed
  1172 
  1173 lemma interval_cart:
  1174   fixes a :: "real^'n"
  1175   shows "box a b = {x::real^'n. \<forall>i. a$i < x$i \<and> x$i < b$i}"
  1176     and "cbox a b = {x::real^'n. \<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i}"
  1177   by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def mem_box Basis_vec_def inner_axis)
  1178 
  1179 lemma mem_box_cart:
  1180   fixes a :: "real^'n"
  1181   shows "x \<in> box a b \<longleftrightarrow> (\<forall>i. a$i < x$i \<and> x$i < b$i)"
  1182     and "x \<in> cbox a b \<longleftrightarrow> (\<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i)"
  1183   using interval_cart[of a b] by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def)
  1184 
  1185 lemma interval_eq_empty_cart:
  1186   fixes a :: "real^'n"
  1187   shows "(box a b = {} \<longleftrightarrow> (\<exists>i. b$i \<le> a$i))" (is ?th1)
  1188     and "(cbox a b = {} \<longleftrightarrow> (\<exists>i. b$i < a$i))" (is ?th2)
  1189 proof -
  1190   { fix i x assume as:"b$i \<le> a$i" and x:"x\<in>box a b"
  1191     hence "a $ i < x $ i \<and> x $ i < b $ i" unfolding mem_box_cart by auto
  1192     hence "a$i < b$i" by auto
  1193     hence False using as by auto }
  1194   moreover
  1195   { assume as:"\<forall>i. \<not> (b$i \<le> a$i)"
  1196     let ?x = "(1/2) *\<^sub>R (a + b)"
  1197     { fix i
  1198       have "a$i < b$i" using as[THEN spec[where x=i]] by auto
  1199       hence "a$i < ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i < b$i"
  1200         unfolding vector_smult_component and vector_add_component
  1201         by auto }
  1202     hence "box a b \<noteq> {}" using mem_box_cart(1)[of "?x" a b] by auto }
  1203   ultimately show ?th1 by blast
  1204 
  1205   { fix i x assume as:"b$i < a$i" and x:"x\<in>cbox a b"
  1206     hence "a $ i \<le> x $ i \<and> x $ i \<le> b $ i" unfolding mem_box_cart by auto
  1207     hence "a$i \<le> b$i" by auto
  1208     hence False using as by auto }
  1209   moreover
  1210   { assume as:"\<forall>i. \<not> (b$i < a$i)"
  1211     let ?x = "(1/2) *\<^sub>R (a + b)"
  1212     { fix i
  1213       have "a$i \<le> b$i" using as[THEN spec[where x=i]] by auto
  1214       hence "a$i \<le> ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i \<le> b$i"
  1215         unfolding vector_smult_component and vector_add_component
  1216         by auto }
  1217     hence "cbox a b \<noteq> {}" using mem_box_cart(2)[of "?x" a b] by auto  }
  1218   ultimately show ?th2 by blast
  1219 qed
  1220 
  1221 lemma interval_ne_empty_cart:
  1222   fixes a :: "real^'n"
  1223   shows "cbox a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i \<le> b$i)"
  1224     and "box a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i < b$i)"
  1225   unfolding interval_eq_empty_cart[of a b] by (auto simp add: not_less not_le)
  1226     (* BH: Why doesn't just "auto" work here? *)
  1227 
  1228 lemma subset_interval_imp_cart:
  1229   fixes a :: "real^'n"
  1230   shows "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> cbox c d \<subseteq> cbox a b"
  1231     and "(\<forall>i. a$i < c$i \<and> d$i < b$i) \<Longrightarrow> cbox c d \<subseteq> box a b"
  1232     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> cbox a b"
  1233     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> box a b"
  1234   unfolding subset_eq[unfolded Ball_def] unfolding mem_box_cart
  1235   by (auto intro: order_trans less_le_trans le_less_trans less_imp_le) (* BH: Why doesn't just "auto" work here? *)
  1236 
  1237 lemma interval_sing:
  1238   fixes a :: "'a::linorder^'n"
  1239   shows "{a .. a} = {a} \<and> {a<..<a} = {}"
  1240   apply (auto simp add: set_eq_iff less_vec_def less_eq_vec_def vec_eq_iff)
  1241   done
  1242 
  1243 lemma subset_interval_cart:
  1244   fixes a :: "real^'n"
  1245   shows "cbox c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th1)
  1246     and "cbox c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i < c$i \<and> d$i < b$i)" (is ?th2)
  1247     and "box c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th3)
  1248     and "box c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th4)
  1249   using subset_box[of c d a b] by (simp_all add: Basis_vec_def inner_axis)
  1250 
  1251 lemma disjoint_interval_cart:
  1252   fixes a::"real^'n"
  1253   shows "cbox a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i < c$i \<or> b$i < c$i \<or> d$i < a$i))" (is ?th1)
  1254     and "cbox a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th2)
  1255     and "box a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i < c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th3)
  1256     and "box a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th4)
  1257   using disjoint_interval[of a b c d] by (simp_all add: Basis_vec_def inner_axis)
  1258 
  1259 lemma Int_interval_cart:
  1260   fixes a :: "real^'n"
  1261   shows "cbox a b \<inter> cbox c d =  {(\<chi> i. max (a$i) (c$i)) .. (\<chi> i. min (b$i) (d$i))}"
  1262   unfolding Int_interval
  1263   by (auto simp: mem_box less_eq_vec_def)
  1264     (auto simp: Basis_vec_def inner_axis)
  1265 
  1266 lemma closed_interval_left_cart:
  1267   fixes b :: "real^'n"
  1268   shows "closed {x::real^'n. \<forall>i. x$i \<le> b$i}"
  1269   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1270 
  1271 lemma closed_interval_right_cart:
  1272   fixes a::"real^'n"
  1273   shows "closed {x::real^'n. \<forall>i. a$i \<le> x$i}"
  1274   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1275 
  1276 lemma is_interval_cart:
  1277   "is_interval (s::(real^'n) set) \<longleftrightarrow>
  1278     (\<forall>a\<in>s. \<forall>b\<in>s. \<forall>x. (\<forall>i. ((a$i \<le> x$i \<and> x$i \<le> b$i) \<or> (b$i \<le> x$i \<and> x$i \<le> a$i))) \<longrightarrow> x \<in> s)"
  1279   by (simp add: is_interval_def Ball_def Basis_vec_def inner_axis imp_ex)
  1280 
  1281 lemma closed_halfspace_component_le_cart: "closed {x::real^'n. x$i \<le> a}"
  1282   by (simp add: closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1283 
  1284 lemma closed_halfspace_component_ge_cart: "closed {x::real^'n. x$i \<ge> a}"
  1285   by (simp add: closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1286 
  1287 lemma open_halfspace_component_lt_cart: "open {x::real^'n. x$i < a}"
  1288   by (simp add: open_Collect_less continuous_on_const continuous_on_id continuous_on_component)
  1289 
  1290 lemma open_halfspace_component_gt_cart: "open {x::real^'n. x$i  > a}"
  1291   by (simp add: open_Collect_less continuous_on_const continuous_on_id continuous_on_component)
  1292 
  1293 lemma Lim_component_le_cart:
  1294   fixes f :: "'a \<Rightarrow> real^'n"
  1295   assumes "(f \<longlongrightarrow> l) net" "\<not> (trivial_limit net)"  "eventually (\<lambda>x. f x $i \<le> b) net"
  1296   shows "l$i \<le> b"
  1297   by (rule tendsto_le[OF assms(2) tendsto_const tendsto_vec_nth, OF assms(1, 3)])
  1298 
  1299 lemma Lim_component_ge_cart:
  1300   fixes f :: "'a \<Rightarrow> real^'n"
  1301   assumes "(f \<longlongrightarrow> l) net"  "\<not> (trivial_limit net)"  "eventually (\<lambda>x. b \<le> (f x)$i) net"
  1302   shows "b \<le> l$i"
  1303   by (rule tendsto_le[OF assms(2) tendsto_vec_nth tendsto_const, OF assms(1, 3)])
  1304 
  1305 lemma Lim_component_eq_cart:
  1306   fixes f :: "'a \<Rightarrow> real^'n"
  1307   assumes net: "(f \<longlongrightarrow> l) net" "~(trivial_limit net)" and ev:"eventually (\<lambda>x. f(x)$i = b) net"
  1308   shows "l$i = b"
  1309   using ev[unfolded order_eq_iff eventually_conj_iff] and
  1310     Lim_component_ge_cart[OF net, of b i] and
  1311     Lim_component_le_cart[OF net, of i b] by auto
  1312 
  1313 lemma connected_ivt_component_cart:
  1314   fixes x :: "real^'n"
  1315   shows "connected s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s \<Longrightarrow> x$k \<le> a \<Longrightarrow> a \<le> y$k \<Longrightarrow> (\<exists>z\<in>s.  z$k = a)"
  1316   using connected_ivt_hyperplane[of s x y "axis k 1" a]
  1317   by (auto simp add: inner_axis inner_commute)
  1318 
  1319 lemma subspace_substandard_cart: "subspace {x::real^_. (\<forall>i. P i \<longrightarrow> x$i = 0)}"
  1320   unfolding subspace_def by auto
  1321 
  1322 lemma closed_substandard_cart:
  1323   "closed {x::'a::real_normed_vector ^ 'n. \<forall>i. P i \<longrightarrow> x$i = 0}"
  1324 proof -
  1325   { fix i::'n
  1326     have "closed {x::'a ^ 'n. P i \<longrightarrow> x$i = 0}"
  1327       by (cases "P i") (simp_all add: closed_Collect_eq continuous_on_const continuous_on_id continuous_on_component) }
  1328   thus ?thesis
  1329     unfolding Collect_all_eq by (simp add: closed_INT)
  1330 qed
  1331 
  1332 lemma dim_substandard_cart: "dim {x::real^'n. \<forall>i. i \<notin> d \<longrightarrow> x$i = 0} = card d"
  1333   (is "dim ?A = _")
  1334 proof -
  1335   let ?a = "\<lambda>x. axis x 1 :: real^'n"
  1336   have *: "{x. \<forall>i\<in>Basis. i \<notin> ?a ` d \<longrightarrow> x \<bullet> i = 0} = ?A"
  1337     by (auto simp: image_iff Basis_vec_def axis_eq_axis inner_axis)
  1338   have "?a ` d \<subseteq> Basis"
  1339     by (auto simp: Basis_vec_def)
  1340   thus ?thesis
  1341     using dim_substandard[of "?a ` d"] card_image[of ?a d]
  1342     by (auto simp: axis_eq_axis inj_on_def *)
  1343 qed
  1344 
  1345 lemma dim_subset_UNIV_cart:
  1346   fixes S :: "(real^'n) set"
  1347   shows "dim S \<le> CARD('n)"
  1348   by (metis dim_subset_UNIV DIM_cart DIM_real mult.right_neutral)
  1349 
  1350 lemma affinity_inverses:
  1351   assumes m0: "m \<noteq> (0::'a::field)"
  1352   shows "(\<lambda>x. m *s x + c) \<circ> (\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) = id"
  1353   "(\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) \<circ> (\<lambda>x. m *s x + c) = id"
  1354   using m0
  1355   apply (auto simp add: fun_eq_iff vector_add_ldistrib diff_conv_add_uminus simp del: add_uminus_conv_diff)
  1356   apply (simp_all add: vector_smult_lneg[symmetric] vector_smult_assoc vector_sneg_minus1 [symmetric])
  1357   done
  1358 
  1359 lemma vector_affinity_eq:
  1360   assumes m0: "(m::'a::field) \<noteq> 0"
  1361   shows "m *s x + c = y \<longleftrightarrow> x = inverse m *s y + -(inverse m *s c)"
  1362 proof
  1363   assume h: "m *s x + c = y"
  1364   hence "m *s x = y - c" by (simp add: field_simps)
  1365   hence "inverse m *s (m *s x) = inverse m *s (y - c)" by simp
  1366   then show "x = inverse m *s y + - (inverse m *s c)"
  1367     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1368 next
  1369   assume h: "x = inverse m *s y + - (inverse m *s c)"
  1370   show "m *s x + c = y" unfolding h
  1371     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1372 qed
  1373 
  1374 lemma vector_eq_affinity:
  1375     "(m::'a::field) \<noteq> 0 ==> (y = m *s x + c \<longleftrightarrow> inverse(m) *s y + -(inverse(m) *s c) = x)"
  1376   using vector_affinity_eq[where m=m and x=x and y=y and c=c]
  1377   by metis
  1378 
  1379 lemma vector_cart:
  1380   fixes f :: "real^'n \<Rightarrow> real"
  1381   shows "(\<chi> i. f (axis i 1)) = (\<Sum>i\<in>Basis. f i *\<^sub>R i)"
  1382   unfolding euclidean_eq_iff[where 'a="real^'n"]
  1383   by simp (simp add: Basis_vec_def inner_axis)
  1384 
  1385 lemma const_vector_cart:"((\<chi> i. d)::real^'n) = (\<Sum>i\<in>Basis. d *\<^sub>R i)"
  1386   by (rule vector_cart)
  1387 
  1388 subsection "Convex Euclidean Space"
  1389 
  1390 lemma Cart_1:"(1::real^'n) = \<Sum>Basis"
  1391   using const_vector_cart[of 1] by (simp add: one_vec_def)
  1392 
  1393 declare vector_add_ldistrib[simp] vector_ssub_ldistrib[simp] vector_smult_assoc[simp] vector_smult_rneg[simp]
  1394 declare vector_sadd_rdistrib[simp] vector_sub_rdistrib[simp]
  1395 
  1396 lemmas vector_component_simps = vector_minus_component vector_smult_component vector_add_component less_eq_vec_def vec_lambda_beta vector_uminus_component
  1397 
  1398 lemma convex_box_cart:
  1399   assumes "\<And>i. convex {x. P i x}"
  1400   shows "convex {x. \<forall>i. P i (x$i)}"
  1401   using assms unfolding convex_def by auto
  1402 
  1403 lemma convex_positive_orthant_cart: "convex {x::real^'n. (\<forall>i. 0 \<le> x$i)}"
  1404   by (rule convex_box_cart) (simp add: atLeast_def[symmetric])
  1405 
  1406 lemma unit_interval_convex_hull_cart:
  1407   "cbox (0::real^'n) 1 = convex hull {x. \<forall>i. (x$i = 0) \<or> (x$i = 1)}"
  1408   unfolding Cart_1 unit_interval_convex_hull[where 'a="real^'n"] box_real[symmetric]
  1409   by (rule arg_cong[where f="\<lambda>x. convex hull x"]) (simp add: Basis_vec_def inner_axis)
  1410 
  1411 lemma cube_convex_hull_cart:
  1412   assumes "0 < d"
  1413   obtains s::"(real^'n) set"
  1414     where "finite s" "cbox (x - (\<chi> i. d)) (x + (\<chi> i. d)) = convex hull s"
  1415 proof -
  1416   from assms obtain s where "finite s"
  1417     and "cbox (x - sum (( *\<^sub>R) d) Basis) (x + sum (( *\<^sub>R) d) Basis) = convex hull s"
  1418     by (rule cube_convex_hull)
  1419   with that[of s] show thesis
  1420     by (simp add: const_vector_cart)
  1421 qed
  1422 
  1423 
  1424 subsection "Derivative"
  1425 
  1426 definition "jacobian f net = matrix(frechet_derivative f net)"
  1427 
  1428 lemma jacobian_works:
  1429   "(f::(real^'a) \<Rightarrow> (real^'b)) differentiable net \<longleftrightarrow>
  1430     (f has_derivative (\<lambda>h. (jacobian f net) *v h)) net"
  1431   apply rule
  1432   unfolding jacobian_def
  1433   apply (simp only: matrix_works[OF linear_frechet_derivative]) defer
  1434   apply (rule differentiableI)
  1435   apply assumption
  1436   unfolding frechet_derivative_works
  1437   apply assumption
  1438   done
  1439 
  1440 
  1441 subsection \<open>Component of the differential must be zero if it exists at a local
  1442   maximum or minimum for that corresponding component\<close>
  1443 
  1444 lemma differential_zero_maxmin_cart:
  1445   fixes f::"real^'a \<Rightarrow> real^'b"
  1446   assumes "0 < e" "((\<forall>y \<in> ball x e. (f y)$k \<le> (f x)$k) \<or> (\<forall>y\<in>ball x e. (f x)$k \<le> (f y)$k))"
  1447     "f differentiable (at x)"
  1448   shows "jacobian f (at x) $ k = 0"
  1449   using differential_zero_maxmin_component[of "axis k 1" e x f] assms
  1450     vector_cart[of "\<lambda>j. frechet_derivative f (at x) j $ k"]
  1451   by (simp add: Basis_vec_def axis_eq_axis inner_axis jacobian_def matrix_def)
  1452 
  1453 subsection \<open>Lemmas for working on @{typ "real^1"}\<close>
  1454 
  1455 lemma forall_1[simp]: "(\<forall>i::1. P i) \<longleftrightarrow> P 1"
  1456   by (metis (full_types) num1_eq_iff)
  1457 
  1458 lemma ex_1[simp]: "(\<exists>x::1. P x) \<longleftrightarrow> P 1"
  1459   by auto (metis (full_types) num1_eq_iff)
  1460 
  1461 lemma exhaust_2:
  1462   fixes x :: 2
  1463   shows "x = 1 \<or> x = 2"
  1464 proof (induct x)
  1465   case (of_int z)
  1466   then have "0 \<le> z" and "z < 2" by simp_all
  1467   then have "z = 0 | z = 1" by arith
  1468   then show ?case by auto
  1469 qed
  1470 
  1471 lemma forall_2: "(\<forall>i::2. P i) \<longleftrightarrow> P 1 \<and> P 2"
  1472   by (metis exhaust_2)
  1473 
  1474 lemma exhaust_3:
  1475   fixes x :: 3
  1476   shows "x = 1 \<or> x = 2 \<or> x = 3"
  1477 proof (induct x)
  1478   case (of_int z)
  1479   then have "0 \<le> z" and "z < 3" by simp_all
  1480   then have "z = 0 \<or> z = 1 \<or> z = 2" by arith
  1481   then show ?case by auto
  1482 qed
  1483 
  1484 lemma forall_3: "(\<forall>i::3. P i) \<longleftrightarrow> P 1 \<and> P 2 \<and> P 3"
  1485   by (metis exhaust_3)
  1486 
  1487 lemma UNIV_1 [simp]: "UNIV = {1::1}"
  1488   by (auto simp add: num1_eq_iff)
  1489 
  1490 lemma UNIV_2: "UNIV = {1::2, 2::2}"
  1491   using exhaust_2 by auto
  1492 
  1493 lemma UNIV_3: "UNIV = {1::3, 2::3, 3::3}"
  1494   using exhaust_3 by auto
  1495 
  1496 lemma sum_1: "sum f (UNIV::1 set) = f 1"
  1497   unfolding UNIV_1 by simp
  1498 
  1499 lemma sum_2: "sum f (UNIV::2 set) = f 1 + f 2"
  1500   unfolding UNIV_2 by simp
  1501 
  1502 lemma sum_3: "sum f (UNIV::3 set) = f 1 + f 2 + f 3"
  1503   unfolding UNIV_3 by (simp add: ac_simps)
  1504 
  1505 lemma num1_eqI:
  1506   fixes a::num1 shows "a = b"
  1507   by (metis (full_types) UNIV_1 UNIV_I empty_iff insert_iff)
  1508 
  1509 lemma num1_eq1 [simp]:
  1510   fixes a::num1 shows "a = 1"
  1511   by (rule num1_eqI)
  1512 
  1513 instantiation num1 :: cart_one
  1514 begin
  1515 
  1516 instance
  1517 proof
  1518   show "CARD(1) = Suc 0" by auto
  1519 qed
  1520 
  1521 end
  1522 
  1523 instantiation num1 :: linorder begin
  1524 definition "a < b \<longleftrightarrow> Rep_num1 a < Rep_num1 b"
  1525 definition "a \<le> b \<longleftrightarrow> Rep_num1 a \<le> Rep_num1 b"
  1526 instance
  1527   by intro_classes (auto simp: less_eq_num1_def less_num1_def intro: num1_eqI)
  1528 end
  1529 
  1530 instance num1 :: wellorder
  1531   by intro_classes (auto simp: less_eq_num1_def less_num1_def)
  1532 
  1533 subsection\<open>The collapse of the general concepts to dimension one\<close>
  1534 
  1535 lemma vector_one: "(x::'a ^1) = (\<chi> i. (x$1))"
  1536   by (simp add: vec_eq_iff)
  1537 
  1538 lemma forall_one: "(\<forall>(x::'a ^1). P x) \<longleftrightarrow> (\<forall>x. P(\<chi> i. x))"
  1539   apply auto
  1540   apply (erule_tac x= "x$1" in allE)
  1541   apply (simp only: vector_one[symmetric])
  1542   done
  1543 
  1544 lemma norm_vector_1: "norm (x :: _^1) = norm (x$1)"
  1545   by (simp add: norm_vec_def)
  1546 
  1547 lemma dist_vector_1:
  1548   fixes x :: "'a::real_normed_vector^1"
  1549   shows "dist x y = dist (x$1) (y$1)"
  1550   by (simp add: dist_norm norm_vector_1)
  1551 
  1552 lemma norm_real: "norm(x::real ^ 1) = \<bar>x$1\<bar>"
  1553   by (simp add: norm_vector_1)
  1554 
  1555 lemma dist_real: "dist(x::real ^ 1) y = \<bar>(x$1) - (y$1)\<bar>"
  1556   by (auto simp add: norm_real dist_norm)
  1557 
  1558 
  1559 lemma tendsto_at_within_vector_1:
  1560   fixes S :: "'a :: metric_space set"
  1561   assumes "(f \<longlongrightarrow> fx) (at x within S)"
  1562   shows "((\<lambda>y::'a^1. \<chi> i. f (y $ 1)) \<longlongrightarrow> (vec fx::'a^1)) (at (vec x) within vec ` S)"
  1563 proof (rule topological_tendstoI)
  1564   fix T :: "('a^1) set"
  1565   assume "open T" "vec fx \<in> T"
  1566   have "\<forall>\<^sub>F x in at x within S. f x \<in> (\<lambda>x. x $ 1) ` T"
  1567     using \<open>open T\<close> \<open>vec fx \<in> T\<close> assms open_image_vec_nth tendsto_def by fastforce
  1568   then show "\<forall>\<^sub>F x::'a^1 in at (vec x) within vec ` S. (\<chi> i. f (x $ 1)) \<in> T"
  1569     unfolding eventually_at dist_norm [symmetric]
  1570     by (rule ex_forward)
  1571        (use \<open>open T\<close> in 
  1572          \<open>fastforce simp: dist_norm dist_vec_def L2_set_def image_iff vector_one open_vec_def\<close>)
  1573 qed
  1574 
  1575 lemma has_derivative_vector_1:
  1576   assumes der_g: "(g has_derivative (\<lambda>x. x * g' a)) (at a within S)"
  1577   shows "((\<lambda>x. vec (g (x $ 1))) has_derivative ( *\<^sub>R) (g' a))
  1578          (at ((vec a)::real^1) within vec ` S)"
  1579     using der_g
  1580     apply (auto simp: Deriv.has_derivative_within bounded_linear_scaleR_right norm_vector_1)
  1581     apply (drule tendsto_at_within_vector_1, vector)
  1582     apply (auto simp: algebra_simps eventually_at tendsto_def)
  1583     done
  1584 
  1585 
  1586 subsection\<open>Explicit vector construction from lists\<close>
  1587 
  1588 definition "vector l = (\<chi> i. foldr (\<lambda>x f n. fun_upd (f (n+1)) n x) l (\<lambda>n x. 0) 1 i)"
  1589 
  1590 lemma vector_1: "(vector[x]) $1 = x"
  1591   unfolding vector_def by simp
  1592 
  1593 lemma vector_2:
  1594  "(vector[x,y]) $1 = x"
  1595  "(vector[x,y] :: 'a^2)$2 = (y::'a::zero)"
  1596   unfolding vector_def by simp_all
  1597 
  1598 lemma vector_3:
  1599  "(vector [x,y,z] ::('a::zero)^3)$1 = x"
  1600  "(vector [x,y,z] ::('a::zero)^3)$2 = y"
  1601  "(vector [x,y,z] ::('a::zero)^3)$3 = z"
  1602   unfolding vector_def by simp_all
  1603 
  1604 lemma forall_vector_1: "(\<forall>v::'a::zero^1. P v) \<longleftrightarrow> (\<forall>x. P(vector[x]))"
  1605   by (metis vector_1 vector_one)
  1606 
  1607 lemma forall_vector_2: "(\<forall>v::'a::zero^2. P v) \<longleftrightarrow> (\<forall>x y. P(vector[x, y]))"
  1608   apply auto
  1609   apply (erule_tac x="v$1" in allE)
  1610   apply (erule_tac x="v$2" in allE)
  1611   apply (subgoal_tac "vector [v$1, v$2] = v")
  1612   apply simp
  1613   apply (vector vector_def)
  1614   apply (simp add: forall_2)
  1615   done
  1616 
  1617 lemma forall_vector_3: "(\<forall>v::'a::zero^3. P v) \<longleftrightarrow> (\<forall>x y z. P(vector[x, y, z]))"
  1618   apply auto
  1619   apply (erule_tac x="v$1" in allE)
  1620   apply (erule_tac x="v$2" in allE)
  1621   apply (erule_tac x="v$3" in allE)
  1622   apply (subgoal_tac "vector [v$1, v$2, v$3] = v")
  1623   apply simp
  1624   apply (vector vector_def)
  1625   apply (simp add: forall_3)
  1626   done
  1627 
  1628 lemma bounded_linear_component_cart[intro]: "bounded_linear (\<lambda>x::real^'n. x $ k)"
  1629   apply (rule bounded_linearI[where K=1])
  1630   using component_le_norm_cart[of _ k] unfolding real_norm_def by auto
  1631 
  1632 lemma interval_split_cart:
  1633   "{a..b::real^'n} \<inter> {x. x$k \<le> c} = {a .. (\<chi> i. if i = k then min (b$k) c else b$i)}"
  1634   "cbox a b \<inter> {x. x$k \<ge> c} = {(\<chi> i. if i = k then max (a$k) c else a$i) .. b}"
  1635   apply (rule_tac[!] set_eqI)
  1636   unfolding Int_iff mem_box_cart mem_Collect_eq interval_cbox_cart
  1637   unfolding vec_lambda_beta
  1638   by auto
  1639 
  1640 lemmas cartesian_euclidean_space_uniform_limit_intros[uniform_limit_intros] =
  1641   bounded_linear.uniform_limit[OF blinfun.bounded_linear_right]
  1642   bounded_linear.uniform_limit[OF bounded_linear_vec_nth]
  1643   bounded_linear.uniform_limit[OF bounded_linear_component_cart]
  1644 
  1645 end