src/HOL/Series.thy
author haftmann
Sat Jul 02 08:41:05 2016 +0200 (2016-07-02)
changeset 63365 5340fb6633d0
parent 63145 703edebd1d92
child 63550 3a0f40a6fa42
permissions -rw-r--r--
more theorems
     1 (*  Title       : Series.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4 
     5 Converted to Isar and polished by lcp
     6 Converted to setsum and polished yet more by TNN
     7 Additional contributions by Jeremy Avigad
     8 *)
     9 
    10 section \<open>Infinite Series\<close>
    11 
    12 theory Series
    13 imports Limits Inequalities
    14 begin
    15 
    16 subsection \<open>Definition of infinite summability\<close>
    17 
    18 definition
    19   sums :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a \<Rightarrow> bool"
    20   (infixr "sums" 80)
    21 where
    22   "f sums s \<longleftrightarrow> (\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> s"
    23 
    24 definition summable :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> bool" where
    25    "summable f \<longleftrightarrow> (\<exists>s. f sums s)"
    26 
    27 definition
    28   suminf :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a"
    29   (binder "\<Sum>" 10)
    30 where
    31   "suminf f = (THE s. f sums s)"
    32 
    33 lemma sums_def': "f sums s \<longleftrightarrow> (\<lambda>n. \<Sum>i = 0..n. f i) \<longlonglongrightarrow> s"
    34   apply (simp add: sums_def)
    35   apply (subst LIMSEQ_Suc_iff [symmetric])
    36   apply (simp only: lessThan_Suc_atMost atLeast0AtMost)
    37   done
    38 
    39 subsection \<open>Infinite summability on topological monoids\<close>
    40 
    41 lemma sums_subst[trans]: "f = g \<Longrightarrow> g sums z \<Longrightarrow> f sums z"
    42   by simp
    43 
    44 lemma sums_cong: "(\<And>n. f n = g n) \<Longrightarrow> f sums c \<longleftrightarrow> g sums c"
    45   by (drule ext) simp
    46 
    47 lemma sums_summable: "f sums l \<Longrightarrow> summable f"
    48   by (simp add: sums_def summable_def, blast)
    49 
    50 lemma summable_iff_convergent: "summable f \<longleftrightarrow> convergent (\<lambda>n. \<Sum>i<n. f i)"
    51   by (simp add: summable_def sums_def convergent_def)
    52 
    53 lemma summable_iff_convergent':
    54   "summable f \<longleftrightarrow> convergent (\<lambda>n. setsum f {..n})"
    55   by (simp_all only: summable_iff_convergent convergent_def
    56         lessThan_Suc_atMost [symmetric] LIMSEQ_Suc_iff[of "\<lambda>n. setsum f {..<n}"])
    57 
    58 lemma suminf_eq_lim: "suminf f = lim (\<lambda>n. \<Sum>i<n. f i)"
    59   by (simp add: suminf_def sums_def lim_def)
    60 
    61 lemma sums_zero[simp, intro]: "(\<lambda>n. 0) sums 0"
    62   unfolding sums_def by simp
    63 
    64 lemma summable_zero[simp, intro]: "summable (\<lambda>n. 0)"
    65   by (rule sums_zero [THEN sums_summable])
    66 
    67 lemma sums_group: "f sums s \<Longrightarrow> 0 < k \<Longrightarrow> (\<lambda>n. setsum f {n * k ..< n * k + k}) sums s"
    68   apply (simp only: sums_def setsum_nat_group tendsto_def eventually_sequentially)
    69   apply safe
    70   apply (erule_tac x=S in allE)
    71   apply safe
    72   apply (rule_tac x="N" in exI, safe)
    73   apply (drule_tac x="n*k" in spec)
    74   apply (erule mp)
    75   apply (erule order_trans)
    76   apply simp
    77   done
    78 
    79 lemma suminf_cong: "(\<And>n. f n = g n) \<Longrightarrow> suminf f = suminf g"
    80   by (rule arg_cong[of f g], rule ext) simp
    81 
    82 lemma summable_cong:
    83   assumes "eventually (\<lambda>x. f x = (g x :: 'a :: real_normed_vector)) sequentially"
    84   shows   "summable f = summable g"
    85 proof -
    86   from assms obtain N where N: "\<forall>n\<ge>N. f n = g n" by (auto simp: eventually_at_top_linorder)
    87   define C where "C = (\<Sum>k<N. f k - g k)"
    88   from eventually_ge_at_top[of N]
    89     have "eventually (\<lambda>n. setsum f {..<n} = C + setsum g {..<n}) sequentially"
    90   proof eventually_elim
    91     fix n assume n: "n \<ge> N"
    92     from n have "{..<n} = {..<N} \<union> {N..<n}" by auto
    93     also have "setsum f ... = setsum f {..<N} + setsum f {N..<n}"
    94       by (intro setsum.union_disjoint) auto
    95     also from N have "setsum f {N..<n} = setsum g {N..<n}" by (intro setsum.cong) simp_all
    96     also have "setsum f {..<N} + setsum g {N..<n} = C + (setsum g {..<N} + setsum g {N..<n})"
    97       unfolding C_def by (simp add: algebra_simps setsum_subtractf)
    98     also have "setsum g {..<N} + setsum g {N..<n} = setsum g ({..<N} \<union> {N..<n})"
    99       by (intro setsum.union_disjoint [symmetric]) auto
   100     also from n have "{..<N} \<union> {N..<n} = {..<n}" by auto
   101     finally show "setsum f {..<n} = C + setsum g {..<n}" .
   102   qed
   103   from convergent_cong[OF this] show ?thesis
   104     by (simp add: summable_iff_convergent convergent_add_const_iff)
   105 qed
   106 
   107 lemma sums_finite:
   108   assumes [simp]: "finite N" and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   109   shows "f sums (\<Sum>n\<in>N. f n)"
   110 proof -
   111   { fix n
   112     have "setsum f {..<n + Suc (Max N)} = setsum f N"
   113     proof cases
   114       assume "N = {}"
   115       with f have "f = (\<lambda>x. 0)" by auto
   116       then show ?thesis by simp
   117     next
   118       assume [simp]: "N \<noteq> {}"
   119       show ?thesis
   120       proof (safe intro!: setsum.mono_neutral_right f)
   121         fix i assume "i \<in> N"
   122         then have "i \<le> Max N" by simp
   123         then show "i < n + Suc (Max N)" by simp
   124       qed
   125     qed }
   126   note eq = this
   127   show ?thesis unfolding sums_def
   128     by (rule LIMSEQ_offset[of _ "Suc (Max N)"])
   129        (simp add: eq atLeast0LessThan del: add_Suc_right)
   130 qed
   131 
   132 corollary sums_0:
   133    "(\<And>n. f n = 0) \<Longrightarrow> (f sums 0)"
   134     by (metis (no_types) finite.emptyI setsum.empty sums_finite)
   135 
   136 lemma summable_finite: "finite N \<Longrightarrow> (\<And>n. n \<notin> N \<Longrightarrow> f n = 0) \<Longrightarrow> summable f"
   137   by (rule sums_summable) (rule sums_finite)
   138 
   139 lemma sums_If_finite_set: "finite A \<Longrightarrow> (\<lambda>r. if r \<in> A then f r else 0) sums (\<Sum>r\<in>A. f r)"
   140   using sums_finite[of A "(\<lambda>r. if r \<in> A then f r else 0)"] by simp
   141 
   142 lemma summable_If_finite_set[simp, intro]: "finite A \<Longrightarrow> summable (\<lambda>r. if r \<in> A then f r else 0)"
   143   by (rule sums_summable) (rule sums_If_finite_set)
   144 
   145 lemma sums_If_finite: "finite {r. P r} \<Longrightarrow> (\<lambda>r. if P r then f r else 0) sums (\<Sum>r | P r. f r)"
   146   using sums_If_finite_set[of "{r. P r}"] by simp
   147 
   148 lemma summable_If_finite[simp, intro]: "finite {r. P r} \<Longrightarrow> summable (\<lambda>r. if P r then f r else 0)"
   149   by (rule sums_summable) (rule sums_If_finite)
   150 
   151 lemma sums_single: "(\<lambda>r. if r = i then f r else 0) sums f i"
   152   using sums_If_finite[of "\<lambda>r. r = i"] by simp
   153 
   154 lemma summable_single[simp, intro]: "summable (\<lambda>r. if r = i then f r else 0)"
   155   by (rule sums_summable) (rule sums_single)
   156 
   157 context
   158   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   159 begin
   160 
   161 lemma summable_sums[intro]: "summable f \<Longrightarrow> f sums (suminf f)"
   162   by (simp add: summable_def sums_def suminf_def)
   163      (metis convergent_LIMSEQ_iff convergent_def lim_def)
   164 
   165 lemma summable_LIMSEQ: "summable f \<Longrightarrow> (\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> suminf f"
   166   by (rule summable_sums [unfolded sums_def])
   167 
   168 lemma sums_unique: "f sums s \<Longrightarrow> s = suminf f"
   169   by (metis limI suminf_eq_lim sums_def)
   170 
   171 lemma sums_iff: "f sums x \<longleftrightarrow> summable f \<and> (suminf f = x)"
   172   by (metis summable_sums sums_summable sums_unique)
   173 
   174 lemma summable_sums_iff:
   175   "summable (f :: nat \<Rightarrow> 'a :: {comm_monoid_add,t2_space}) \<longleftrightarrow> f sums suminf f"
   176   by (auto simp: sums_iff summable_sums)
   177 
   178 lemma sums_unique2:
   179   fixes a b :: "'a::{comm_monoid_add,t2_space}"
   180   shows "f sums a \<Longrightarrow> f sums b \<Longrightarrow> a = b"
   181 by (simp add: sums_iff)
   182 
   183 lemma suminf_finite:
   184   assumes N: "finite N" and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   185   shows "suminf f = (\<Sum>n\<in>N. f n)"
   186   using sums_finite[OF assms, THEN sums_unique] by simp
   187 
   188 end
   189 
   190 lemma suminf_zero[simp]: "suminf (\<lambda>n. 0::'a::{t2_space, comm_monoid_add}) = 0"
   191   by (rule sums_zero [THEN sums_unique, symmetric])
   192 
   193 
   194 subsection \<open>Infinite summability on ordered, topological monoids\<close>
   195 
   196 lemma sums_le:
   197   fixes f g :: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology}"
   198   shows "\<forall>n. f n \<le> g n \<Longrightarrow> f sums s \<Longrightarrow> g sums t \<Longrightarrow> s \<le> t"
   199   by (rule LIMSEQ_le) (auto intro: setsum_mono simp: sums_def)
   200 
   201 context
   202   fixes f :: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology}"
   203 begin
   204 
   205 lemma suminf_le: "\<lbrakk>\<forall>n. f n \<le> g n; summable f; summable g\<rbrakk> \<Longrightarrow> suminf f \<le> suminf g"
   206   by (auto dest: sums_summable intro: sums_le)
   207 
   208 lemma setsum_le_suminf: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 \<le> f m \<Longrightarrow> setsum f {..<n} \<le> suminf f"
   209   by (rule sums_le[OF _ sums_If_finite_set summable_sums]) auto
   210 
   211 lemma suminf_nonneg: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 \<le> suminf f"
   212   using setsum_le_suminf[of 0] by simp
   213 
   214 lemma suminf_le_const: "summable f \<Longrightarrow> (\<And>n. setsum f {..<n} \<le> x) \<Longrightarrow> suminf f \<le> x"
   215   by (metis LIMSEQ_le_const2 summable_LIMSEQ)
   216 
   217 lemma suminf_eq_zero_iff: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> suminf f = 0 \<longleftrightarrow> (\<forall>n. f n = 0)"
   218 proof
   219   assume "summable f" "suminf f = 0" and pos: "\<forall>n. 0 \<le> f n"
   220   then have f: "(\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> 0"
   221     using summable_LIMSEQ[of f] by simp
   222   then have "\<And>i. (\<Sum>n\<in>{i}. f n) \<le> 0"
   223   proof (rule LIMSEQ_le_const)
   224     fix i show "\<exists>N. \<forall>n\<ge>N. (\<Sum>n\<in>{i}. f n) \<le> setsum f {..<n}"
   225       using pos by (intro exI[of _ "Suc i"] allI impI setsum_mono2) auto
   226   qed
   227   with pos show "\<forall>n. f n = 0"
   228     by (auto intro!: antisym)
   229 qed (metis suminf_zero fun_eq_iff)
   230 
   231 lemma suminf_pos_iff:
   232   "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 < suminf f \<longleftrightarrow> (\<exists>i. 0 < f i)"
   233   using setsum_le_suminf[of 0] suminf_eq_zero_iff by (simp add: less_le)
   234 
   235 lemma suminf_pos2:
   236   assumes "summable f" "\<forall>n. 0 \<le> f n" "0 < f i"
   237   shows "0 < suminf f"
   238 proof -
   239   have "0 < (\<Sum>n<Suc i. f n)"
   240     using assms by (intro setsum_pos2[where i=i]) auto
   241   also have "\<dots> \<le> suminf f"
   242     using assms by (intro setsum_le_suminf) auto
   243   finally show ?thesis .
   244 qed
   245 
   246 lemma suminf_pos: "summable f \<Longrightarrow> \<forall>n. 0 < f n \<Longrightarrow> 0 < suminf f"
   247   by (intro suminf_pos2[where i=0]) (auto intro: less_imp_le)
   248 
   249 end
   250 
   251 context
   252   fixes f :: "nat \<Rightarrow> 'a::{ordered_cancel_comm_monoid_add, linorder_topology}"
   253 begin
   254 
   255 lemma setsum_less_suminf2: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 \<le> f m \<Longrightarrow> n \<le> i \<Longrightarrow> 0 < f i \<Longrightarrow> setsum f {..<n} < suminf f"
   256   using
   257     setsum_le_suminf[of f "Suc i"]
   258     add_strict_increasing[of "f i" "setsum f {..<n}" "setsum f {..<i}"]
   259     setsum_mono2[of "{..<i}" "{..<n}" f]
   260   by (auto simp: less_imp_le ac_simps)
   261 
   262 lemma setsum_less_suminf: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 < f m \<Longrightarrow> setsum f {..<n} < suminf f"
   263   using setsum_less_suminf2[of n n] by (simp add: less_imp_le)
   264 
   265 end
   266 
   267 lemma summableI_nonneg_bounded:
   268   fixes f:: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology, conditionally_complete_linorder}"
   269   assumes pos[simp]: "\<And>n. 0 \<le> f n" and le: "\<And>n. (\<Sum>i<n. f i) \<le> x"
   270   shows "summable f"
   271   unfolding summable_def sums_def[abs_def]
   272 proof (rule exI LIMSEQ_incseq_SUP)+
   273   show "bdd_above (range (\<lambda>n. setsum f {..<n}))"
   274     using le by (auto simp: bdd_above_def)
   275   show "incseq (\<lambda>n. setsum f {..<n})"
   276     by (auto simp: mono_def intro!: setsum_mono2)
   277 qed
   278 
   279 lemma summableI[intro, simp]:
   280   fixes f:: "nat \<Rightarrow> 'a::{canonically_ordered_monoid_add, linorder_topology, complete_linorder}"
   281   shows "summable f"
   282   by (intro summableI_nonneg_bounded[where x=top] zero_le top_greatest)
   283 
   284 subsection \<open>Infinite summability on topological monoids\<close>
   285 
   286 context
   287   fixes f g :: "nat \<Rightarrow> 'a :: {t2_space, topological_comm_monoid_add}"
   288 begin
   289 
   290 lemma sums_Suc:
   291   assumes "(\<lambda>n. f (Suc n)) sums l" shows "f sums (l + f 0)"
   292 proof  -
   293   have "(\<lambda>n. (\<Sum>i<n. f (Suc i)) + f 0) \<longlonglongrightarrow> l + f 0"
   294     using assms by (auto intro!: tendsto_add simp: sums_def)
   295   moreover have "(\<Sum>i<n. f (Suc i)) + f 0 = (\<Sum>i<Suc n. f i)" for n
   296     unfolding lessThan_Suc_eq_insert_0
   297       by (simp add: ac_simps setsum_atLeast1_atMost_eq image_Suc_lessThan)
   298   ultimately show ?thesis
   299     by (auto simp add: sums_def simp del: setsum_lessThan_Suc intro: LIMSEQ_Suc_iff[THEN iffD1])
   300 qed
   301 
   302 lemma sums_add: "f sums a \<Longrightarrow> g sums b \<Longrightarrow> (\<lambda>n. f n + g n) sums (a + b)"
   303   unfolding sums_def by (simp add: setsum.distrib tendsto_add)
   304 
   305 lemma summable_add: "summable f \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. f n + g n)"
   306   unfolding summable_def by (auto intro: sums_add)
   307 
   308 lemma suminf_add: "summable f \<Longrightarrow> summable g \<Longrightarrow> suminf f + suminf g = (\<Sum>n. f n + g n)"
   309   by (intro sums_unique sums_add summable_sums)
   310 
   311 end
   312 
   313 context
   314   fixes f :: "'i \<Rightarrow> nat \<Rightarrow> 'a::{t2_space, topological_comm_monoid_add}" and I :: "'i set"
   315 begin
   316 
   317 lemma sums_setsum: "(\<And>i. i \<in> I \<Longrightarrow> (f i) sums (x i)) \<Longrightarrow> (\<lambda>n. \<Sum>i\<in>I. f i n) sums (\<Sum>i\<in>I. x i)"
   318   by (induct I rule: infinite_finite_induct) (auto intro!: sums_add)
   319 
   320 lemma suminf_setsum: "(\<And>i. i \<in> I \<Longrightarrow> summable (f i)) \<Longrightarrow> (\<Sum>n. \<Sum>i\<in>I. f i n) = (\<Sum>i\<in>I. \<Sum>n. f i n)"
   321   using sums_unique[OF sums_setsum, OF summable_sums] by simp
   322 
   323 lemma summable_setsum: "(\<And>i. i \<in> I \<Longrightarrow> summable (f i)) \<Longrightarrow> summable (\<lambda>n. \<Sum>i\<in>I. f i n)"
   324   using sums_summable[OF sums_setsum[OF summable_sums]] .
   325 
   326 end
   327 
   328 subsection \<open>Infinite summability on real normed vector spaces\<close>
   329 
   330 context
   331   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   332 begin
   333 
   334 lemma sums_Suc_iff: "(\<lambda>n. f (Suc n)) sums s \<longleftrightarrow> f sums (s + f 0)"
   335 proof -
   336   have "f sums (s + f 0) \<longleftrightarrow> (\<lambda>i. \<Sum>j<Suc i. f j) \<longlonglongrightarrow> s + f 0"
   337     by (subst LIMSEQ_Suc_iff) (simp add: sums_def)
   338   also have "\<dots> \<longleftrightarrow> (\<lambda>i. (\<Sum>j<i. f (Suc j)) + f 0) \<longlonglongrightarrow> s + f 0"
   339     by (simp add: ac_simps lessThan_Suc_eq_insert_0 image_Suc_lessThan setsum_atLeast1_atMost_eq)
   340   also have "\<dots> \<longleftrightarrow> (\<lambda>n. f (Suc n)) sums s"
   341   proof
   342     assume "(\<lambda>i. (\<Sum>j<i. f (Suc j)) + f 0) \<longlonglongrightarrow> s + f 0"
   343     with tendsto_add[OF this tendsto_const, of "- f 0"]
   344     show "(\<lambda>i. f (Suc i)) sums s"
   345       by (simp add: sums_def)
   346   qed (auto intro: tendsto_add simp: sums_def)
   347   finally show ?thesis ..
   348 qed
   349 
   350 lemma summable_Suc_iff: "summable (\<lambda>n. f (Suc n)) = summable f"
   351 proof
   352   assume "summable f"
   353   hence "f sums suminf f" by (rule summable_sums)
   354   hence "(\<lambda>n. f (Suc n)) sums (suminf f - f 0)" by (simp add: sums_Suc_iff)
   355   thus "summable (\<lambda>n. f (Suc n))" unfolding summable_def by blast
   356 qed (auto simp: sums_Suc_iff summable_def)
   357 
   358 lemma sums_Suc_imp: "f 0 = 0 \<Longrightarrow> (\<lambda>n. f (Suc n)) sums s \<Longrightarrow> (\<lambda>n. f n) sums s"
   359   using sums_Suc_iff by simp
   360 
   361 end
   362 
   363 context \<comment>\<open>Separate contexts are necessary to allow general use of the results above, here.\<close>
   364   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   365 begin
   366 
   367 lemma sums_diff: "f sums a \<Longrightarrow> g sums b \<Longrightarrow> (\<lambda>n. f n - g n) sums (a - b)"
   368   unfolding sums_def by (simp add: setsum_subtractf tendsto_diff)
   369 
   370 lemma summable_diff: "summable f \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. f n - g n)"
   371   unfolding summable_def by (auto intro: sums_diff)
   372 
   373 lemma suminf_diff: "summable f \<Longrightarrow> summable g \<Longrightarrow> suminf f - suminf g = (\<Sum>n. f n - g n)"
   374   by (intro sums_unique sums_diff summable_sums)
   375 
   376 lemma sums_minus: "f sums a \<Longrightarrow> (\<lambda>n. - f n) sums (- a)"
   377   unfolding sums_def by (simp add: setsum_negf tendsto_minus)
   378 
   379 lemma summable_minus: "summable f \<Longrightarrow> summable (\<lambda>n. - f n)"
   380   unfolding summable_def by (auto intro: sums_minus)
   381 
   382 lemma suminf_minus: "summable f \<Longrightarrow> (\<Sum>n. - f n) = - (\<Sum>n. f n)"
   383   by (intro sums_unique [symmetric] sums_minus summable_sums)
   384 
   385 lemma sums_iff_shift: "(\<lambda>i. f (i + n)) sums s \<longleftrightarrow> f sums (s + (\<Sum>i<n. f i))"
   386 proof (induct n arbitrary: s)
   387   case (Suc n)
   388   moreover have "(\<lambda>i. f (Suc i + n)) sums s \<longleftrightarrow> (\<lambda>i. f (i + n)) sums (s + f n)"
   389     by (subst sums_Suc_iff) simp
   390   ultimately show ?case
   391     by (simp add: ac_simps)
   392 qed simp
   393 
   394 corollary sums_iff_shift': "(\<lambda>i. f (i + n)) sums (s - (\<Sum>i<n. f i)) \<longleftrightarrow> f sums s"
   395   by (simp add: sums_iff_shift)
   396 
   397 lemma sums_zero_iff_shift:
   398   assumes "\<And>i. i < n \<Longrightarrow> f i = 0"
   399   shows "(\<lambda>i. f (i+n)) sums s \<longleftrightarrow> (\<lambda>i. f i) sums s"
   400 by (simp add: assms sums_iff_shift)
   401 
   402 lemma summable_iff_shift: "summable (\<lambda>n. f (n + k)) \<longleftrightarrow> summable f"
   403   by (metis diff_add_cancel summable_def sums_iff_shift[abs_def])
   404 
   405 lemma sums_split_initial_segment: "f sums s \<Longrightarrow> (\<lambda>i. f (i + n)) sums (s - (\<Sum>i<n. f i))"
   406   by (simp add: sums_iff_shift)
   407 
   408 lemma summable_ignore_initial_segment: "summable f \<Longrightarrow> summable (\<lambda>n. f(n + k))"
   409   by (simp add: summable_iff_shift)
   410 
   411 lemma suminf_minus_initial_segment: "summable f \<Longrightarrow> (\<Sum>n. f (n + k)) = (\<Sum>n. f n) - (\<Sum>i<k. f i)"
   412   by (rule sums_unique[symmetric]) (auto simp: sums_iff_shift)
   413 
   414 lemma suminf_split_initial_segment: "summable f \<Longrightarrow> suminf f = (\<Sum>n. f(n + k)) + (\<Sum>i<k. f i)"
   415   by (auto simp add: suminf_minus_initial_segment)
   416 
   417 lemma suminf_split_head: "summable f \<Longrightarrow> (\<Sum>n. f (Suc n)) = suminf f - f 0"
   418   using suminf_split_initial_segment[of 1] by simp
   419 
   420 lemma suminf_exist_split:
   421   fixes r :: real assumes "0 < r" and "summable f"
   422   shows "\<exists>N. \<forall>n\<ge>N. norm (\<Sum>i. f (i + n)) < r"
   423 proof -
   424   from LIMSEQ_D[OF summable_LIMSEQ[OF \<open>summable f\<close>] \<open>0 < r\<close>]
   425   obtain N :: nat where "\<forall> n \<ge> N. norm (setsum f {..<n} - suminf f) < r" by auto
   426   thus ?thesis
   427     by (auto simp: norm_minus_commute suminf_minus_initial_segment[OF \<open>summable f\<close>])
   428 qed
   429 
   430 lemma summable_LIMSEQ_zero: "summable f \<Longrightarrow> f \<longlonglongrightarrow> 0"
   431   apply (drule summable_iff_convergent [THEN iffD1])
   432   apply (drule convergent_Cauchy)
   433   apply (simp only: Cauchy_iff LIMSEQ_iff, safe)
   434   apply (drule_tac x="r" in spec, safe)
   435   apply (rule_tac x="M" in exI, safe)
   436   apply (drule_tac x="Suc n" in spec, simp)
   437   apply (drule_tac x="n" in spec, simp)
   438   done
   439 
   440 lemma summable_imp_convergent: "summable f \<Longrightarrow> convergent f"
   441   by (force dest!: summable_LIMSEQ_zero simp: convergent_def)
   442 
   443 lemma summable_imp_Bseq: "summable f \<Longrightarrow> Bseq f"
   444   by (simp add: convergent_imp_Bseq summable_imp_convergent)
   445 
   446 end
   447 
   448 lemma summable_minus_iff:
   449   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   450   shows "summable (\<lambda>n. - f n) \<longleftrightarrow> summable f"
   451   by (auto dest: summable_minus) \<comment>\<open>used two ways, hence must be outside the context above\<close>
   452 
   453 lemma (in bounded_linear) sums: "(\<lambda>n. X n) sums a \<Longrightarrow> (\<lambda>n. f (X n)) sums (f a)"
   454   unfolding sums_def by (drule tendsto, simp only: setsum)
   455 
   456 lemma (in bounded_linear) summable: "summable (\<lambda>n. X n) \<Longrightarrow> summable (\<lambda>n. f (X n))"
   457   unfolding summable_def by (auto intro: sums)
   458 
   459 lemma (in bounded_linear) suminf: "summable (\<lambda>n. X n) \<Longrightarrow> f (\<Sum>n. X n) = (\<Sum>n. f (X n))"
   460   by (intro sums_unique sums summable_sums)
   461 
   462 lemmas sums_of_real = bounded_linear.sums [OF bounded_linear_of_real]
   463 lemmas summable_of_real = bounded_linear.summable [OF bounded_linear_of_real]
   464 lemmas suminf_of_real = bounded_linear.suminf [OF bounded_linear_of_real]
   465 
   466 lemmas sums_scaleR_left = bounded_linear.sums[OF bounded_linear_scaleR_left]
   467 lemmas summable_scaleR_left = bounded_linear.summable[OF bounded_linear_scaleR_left]
   468 lemmas suminf_scaleR_left = bounded_linear.suminf[OF bounded_linear_scaleR_left]
   469 
   470 lemmas sums_scaleR_right = bounded_linear.sums[OF bounded_linear_scaleR_right]
   471 lemmas summable_scaleR_right = bounded_linear.summable[OF bounded_linear_scaleR_right]
   472 lemmas suminf_scaleR_right = bounded_linear.suminf[OF bounded_linear_scaleR_right]
   473 
   474 lemma summable_const_iff: "summable (\<lambda>_. c) \<longleftrightarrow> (c :: 'a :: real_normed_vector) = 0"
   475 proof -
   476   {
   477     assume "c \<noteq> 0"
   478     hence "filterlim (\<lambda>n. of_nat n * norm c) at_top sequentially"
   479       by (subst mult.commute)
   480          (auto intro!: filterlim_tendsto_pos_mult_at_top filterlim_real_sequentially)
   481     hence "\<not>convergent (\<lambda>n. norm (\<Sum>k<n. c))"
   482       by (intro filterlim_at_infinity_imp_not_convergent filterlim_at_top_imp_at_infinity)
   483          (simp_all add: setsum_constant_scaleR)
   484     hence "\<not>summable (\<lambda>_. c)" unfolding summable_iff_convergent using convergent_norm by blast
   485   }
   486   thus ?thesis by auto
   487 qed
   488 
   489 
   490 subsection \<open>Infinite summability on real normed algebras\<close>
   491 
   492 context
   493   fixes f :: "nat \<Rightarrow> 'a::real_normed_algebra"
   494 begin
   495 
   496 lemma sums_mult: "f sums a \<Longrightarrow> (\<lambda>n. c * f n) sums (c * a)"
   497   by (rule bounded_linear.sums [OF bounded_linear_mult_right])
   498 
   499 lemma summable_mult: "summable f \<Longrightarrow> summable (\<lambda>n. c * f n)"
   500   by (rule bounded_linear.summable [OF bounded_linear_mult_right])
   501 
   502 lemma suminf_mult: "summable f \<Longrightarrow> suminf (\<lambda>n. c * f n) = c * suminf f"
   503   by (rule bounded_linear.suminf [OF bounded_linear_mult_right, symmetric])
   504 
   505 lemma sums_mult2: "f sums a \<Longrightarrow> (\<lambda>n. f n * c) sums (a * c)"
   506   by (rule bounded_linear.sums [OF bounded_linear_mult_left])
   507 
   508 lemma summable_mult2: "summable f \<Longrightarrow> summable (\<lambda>n. f n * c)"
   509   by (rule bounded_linear.summable [OF bounded_linear_mult_left])
   510 
   511 lemma suminf_mult2: "summable f \<Longrightarrow> suminf f * c = (\<Sum>n. f n * c)"
   512   by (rule bounded_linear.suminf [OF bounded_linear_mult_left])
   513 
   514 end
   515 
   516 lemma sums_mult_iff:
   517   assumes "c \<noteq> 0"
   518   shows   "(\<lambda>n. c * f n :: 'a :: {real_normed_algebra,field}) sums (c * d) \<longleftrightarrow> f sums d"
   519   using sums_mult[of f d c] sums_mult[of "\<lambda>n. c * f n" "c * d" "inverse c"]
   520   by (force simp: field_simps assms)
   521 
   522 lemma sums_mult2_iff:
   523   assumes "c \<noteq> (0 :: 'a :: {real_normed_algebra, field})"
   524   shows   "(\<lambda>n. f n * c) sums (d * c) \<longleftrightarrow> f sums d"
   525   using sums_mult_iff[OF assms, of f d] by (simp add: mult.commute)
   526 
   527 lemma sums_of_real_iff:
   528   "(\<lambda>n. of_real (f n) :: 'a :: real_normed_div_algebra) sums of_real c \<longleftrightarrow> f sums c"
   529   by (simp add: sums_def of_real_setsum[symmetric] tendsto_of_real_iff del: of_real_setsum)
   530 
   531 
   532 subsection \<open>Infinite summability on real normed fields\<close>
   533 
   534 context
   535   fixes c :: "'a::real_normed_field"
   536 begin
   537 
   538 lemma sums_divide: "f sums a \<Longrightarrow> (\<lambda>n. f n / c) sums (a / c)"
   539   by (rule bounded_linear.sums [OF bounded_linear_divide])
   540 
   541 lemma summable_divide: "summable f \<Longrightarrow> summable (\<lambda>n. f n / c)"
   542   by (rule bounded_linear.summable [OF bounded_linear_divide])
   543 
   544 lemma suminf_divide: "summable f \<Longrightarrow> suminf (\<lambda>n. f n / c) = suminf f / c"
   545   by (rule bounded_linear.suminf [OF bounded_linear_divide, symmetric])
   546 
   547 lemma sums_mult_D: "\<lbrakk>(\<lambda>n. c * f n) sums a; c \<noteq> 0\<rbrakk> \<Longrightarrow> f sums (a/c)"
   548   using sums_mult_iff by fastforce
   549 
   550 lemma summable_mult_D: "\<lbrakk>summable (\<lambda>n. c * f n); c \<noteq> 0\<rbrakk> \<Longrightarrow> summable f"
   551   by (auto dest: summable_divide)
   552 
   553 text\<open>Sum of a geometric progression.\<close>
   554 
   555 lemma geometric_sums: "norm c < 1 \<Longrightarrow> (\<lambda>n. c^n) sums (1 / (1 - c))"
   556 proof -
   557   assume less_1: "norm c < 1"
   558   hence neq_1: "c \<noteq> 1" by auto
   559   hence neq_0: "c - 1 \<noteq> 0" by simp
   560   from less_1 have lim_0: "(\<lambda>n. c^n) \<longlonglongrightarrow> 0"
   561     by (rule LIMSEQ_power_zero)
   562   hence "(\<lambda>n. c ^ n / (c - 1) - 1 / (c - 1)) \<longlonglongrightarrow> 0 / (c - 1) - 1 / (c - 1)"
   563     using neq_0 by (intro tendsto_intros)
   564   hence "(\<lambda>n. (c ^ n - 1) / (c - 1)) \<longlonglongrightarrow> 1 / (1 - c)"
   565     by (simp add: nonzero_minus_divide_right [OF neq_0] diff_divide_distrib)
   566   thus "(\<lambda>n. c ^ n) sums (1 / (1 - c))"
   567     by (simp add: sums_def geometric_sum neq_1)
   568 qed
   569 
   570 lemma summable_geometric: "norm c < 1 \<Longrightarrow> summable (\<lambda>n. c^n)"
   571   by (rule geometric_sums [THEN sums_summable])
   572 
   573 lemma suminf_geometric: "norm c < 1 \<Longrightarrow> suminf (\<lambda>n. c^n) = 1 / (1 - c)"
   574   by (rule sums_unique[symmetric]) (rule geometric_sums)
   575 
   576 lemma summable_geometric_iff: "summable (\<lambda>n. c ^ n) \<longleftrightarrow> norm c < 1"
   577 proof
   578   assume "summable (\<lambda>n. c ^ n :: 'a :: real_normed_field)"
   579   hence "(\<lambda>n. norm c ^ n) \<longlonglongrightarrow> 0"
   580     by (simp add: norm_power [symmetric] tendsto_norm_zero_iff summable_LIMSEQ_zero)
   581   from order_tendstoD(2)[OF this zero_less_one] obtain n where "norm c ^ n < 1"
   582     by (auto simp: eventually_at_top_linorder)
   583   thus "norm c < 1" using one_le_power[of "norm c" n] by (cases "norm c \<ge> 1") (linarith, simp)
   584 qed (rule summable_geometric)
   585 
   586 end
   587 
   588 lemma power_half_series: "(\<lambda>n. (1/2::real)^Suc n) sums 1"
   589 proof -
   590   have 2: "(\<lambda>n. (1/2::real)^n) sums 2" using geometric_sums [of "1/2::real"]
   591     by auto
   592   have "(\<lambda>n. (1/2::real)^Suc n) = (\<lambda>n. (1 / 2) ^ n / 2)"
   593     by (simp add: mult.commute)
   594   thus ?thesis using sums_divide [OF 2, of 2]
   595     by simp
   596 qed
   597 
   598 
   599 subsection \<open>Telescoping\<close>
   600 
   601 lemma telescope_sums:
   602   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   603   shows   "(\<lambda>n. f (Suc n) - f n) sums (c - f 0)"
   604   unfolding sums_def
   605 proof (subst LIMSEQ_Suc_iff [symmetric])
   606   have "(\<lambda>n. \<Sum>k<Suc n. f (Suc k) - f k) = (\<lambda>n. f (Suc n) - f 0)"
   607     by (simp add: lessThan_Suc_atMost atLeast0AtMost [symmetric] setsum_Suc_diff)
   608   also have "\<dots> \<longlonglongrightarrow> c - f 0" by (intro tendsto_diff LIMSEQ_Suc[OF assms] tendsto_const)
   609   finally show "(\<lambda>n. \<Sum>n<Suc n. f (Suc n) - f n) \<longlonglongrightarrow> c - f 0" .
   610 qed
   611 
   612 lemma telescope_sums':
   613   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   614   shows   "(\<lambda>n. f n - f (Suc n)) sums (f 0 - c)"
   615   using sums_minus[OF telescope_sums[OF assms]] by (simp add: algebra_simps)
   616 
   617 lemma telescope_summable:
   618   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   619   shows   "summable (\<lambda>n. f (Suc n) - f n)"
   620   using telescope_sums[OF assms] by (simp add: sums_iff)
   621 
   622 lemma telescope_summable':
   623   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   624   shows   "summable (\<lambda>n. f n - f (Suc n))"
   625   using summable_minus[OF telescope_summable[OF assms]] by (simp add: algebra_simps)
   626 
   627 
   628 subsection \<open>Infinite summability on Banach spaces\<close>
   629 
   630 text\<open>Cauchy-type criterion for convergence of series (c.f. Harrison)\<close>
   631 
   632 lemma summable_Cauchy:
   633   fixes f :: "nat \<Rightarrow> 'a::banach"
   634   shows "summable f \<longleftrightarrow> (\<forall>e>0. \<exists>N. \<forall>m\<ge>N. \<forall>n. norm (setsum f {m..<n}) < e)"
   635   apply (simp only: summable_iff_convergent Cauchy_convergent_iff [symmetric] Cauchy_iff, safe)
   636   apply (drule spec, drule (1) mp)
   637   apply (erule exE, rule_tac x="M" in exI, clarify)
   638   apply (rule_tac x="m" and y="n" in linorder_le_cases)
   639   apply (frule (1) order_trans)
   640   apply (drule_tac x="n" in spec, drule (1) mp)
   641   apply (drule_tac x="m" in spec, drule (1) mp)
   642   apply (simp_all add: setsum_diff [symmetric])
   643   apply (drule spec, drule (1) mp)
   644   apply (erule exE, rule_tac x="N" in exI, clarify)
   645   apply (rule_tac x="m" and y="n" in linorder_le_cases)
   646   apply (subst norm_minus_commute)
   647   apply (simp_all add: setsum_diff [symmetric])
   648   done
   649 
   650 context
   651   fixes f :: "nat \<Rightarrow> 'a::banach"
   652 begin
   653 
   654 text\<open>Absolute convergence imples normal convergence\<close>
   655 
   656 lemma summable_norm_cancel: "summable (\<lambda>n. norm (f n)) \<Longrightarrow> summable f"
   657   apply (simp only: summable_Cauchy, safe)
   658   apply (drule_tac x="e" in spec, safe)
   659   apply (rule_tac x="N" in exI, safe)
   660   apply (drule_tac x="m" in spec, safe)
   661   apply (rule order_le_less_trans [OF norm_setsum])
   662   apply (rule order_le_less_trans [OF abs_ge_self])
   663   apply simp
   664   done
   665 
   666 lemma summable_norm: "summable (\<lambda>n. norm (f n)) \<Longrightarrow> norm (suminf f) \<le> (\<Sum>n. norm (f n))"
   667   by (auto intro: LIMSEQ_le tendsto_norm summable_norm_cancel summable_LIMSEQ norm_setsum)
   668 
   669 text \<open>Comparison tests\<close>
   670 
   671 lemma summable_comparison_test: "\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n \<Longrightarrow> summable g \<Longrightarrow> summable f"
   672   apply (simp add: summable_Cauchy, safe)
   673   apply (drule_tac x="e" in spec, safe)
   674   apply (rule_tac x = "N + Na" in exI, safe)
   675   apply (rotate_tac 2)
   676   apply (drule_tac x = m in spec)
   677   apply (auto, rotate_tac 2, drule_tac x = n in spec)
   678   apply (rule_tac y = "\<Sum>k=m..<n. norm (f k)" in order_le_less_trans)
   679   apply (rule norm_setsum)
   680   apply (rule_tac y = "setsum g {m..<n}" in order_le_less_trans)
   681   apply (auto intro: setsum_mono simp add: abs_less_iff)
   682   done
   683 
   684 lemma summable_comparison_test_ev:
   685   shows "eventually (\<lambda>n. norm (f n) \<le> g n) sequentially \<Longrightarrow> summable g \<Longrightarrow> summable f"
   686   by (rule summable_comparison_test) (auto simp: eventually_at_top_linorder)
   687 
   688 (*A better argument order*)
   689 lemma summable_comparison_test': "summable g \<Longrightarrow> (\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> g n) \<Longrightarrow> summable f"
   690   by (rule summable_comparison_test) auto
   691 
   692 subsection \<open>The Ratio Test\<close>
   693 
   694 lemma summable_ratio_test:
   695   assumes "c < 1" "\<And>n. n \<ge> N \<Longrightarrow> norm (f (Suc n)) \<le> c * norm (f n)"
   696   shows "summable f"
   697 proof cases
   698   assume "0 < c"
   699   show "summable f"
   700   proof (rule summable_comparison_test)
   701     show "\<exists>N'. \<forall>n\<ge>N'. norm (f n) \<le> (norm (f N) / (c ^ N)) * c ^ n"
   702     proof (intro exI allI impI)
   703       fix n assume "N \<le> n" then show "norm (f n) \<le> (norm (f N) / (c ^ N)) * c ^ n"
   704       proof (induct rule: inc_induct)
   705         case (step m)
   706         moreover have "norm (f (Suc m)) / c ^ Suc m * c ^ n \<le> norm (f m) / c ^ m * c ^ n"
   707           using \<open>0 < c\<close> \<open>c < 1\<close> assms(2)[OF \<open>N \<le> m\<close>] by (simp add: field_simps)
   708         ultimately show ?case by simp
   709       qed (insert \<open>0 < c\<close>, simp)
   710     qed
   711     show "summable (\<lambda>n. norm (f N) / c ^ N * c ^ n)"
   712       using \<open>0 < c\<close> \<open>c < 1\<close> by (intro summable_mult summable_geometric) simp
   713   qed
   714 next
   715   assume c: "\<not> 0 < c"
   716   { fix n assume "n \<ge> N"
   717     then have "norm (f (Suc n)) \<le> c * norm (f n)"
   718       by fact
   719     also have "\<dots> \<le> 0"
   720       using c by (simp add: not_less mult_nonpos_nonneg)
   721     finally have "f (Suc n) = 0"
   722       by auto }
   723   then show "summable f"
   724     by (intro sums_summable[OF sums_finite, of "{.. Suc N}"]) (auto simp: not_le Suc_less_eq2)
   725 qed
   726 
   727 end
   728 
   729 text\<open>Relations among convergence and absolute convergence for power series.\<close>
   730 
   731 lemma Abel_lemma:
   732   fixes a :: "nat \<Rightarrow> 'a::real_normed_vector"
   733   assumes r: "0 \<le> r" and r0: "r < r0" and M: "\<And>n. norm (a n) * r0^n \<le> M"
   734     shows "summable (\<lambda>n. norm (a n) * r^n)"
   735 proof (rule summable_comparison_test')
   736   show "summable (\<lambda>n. M * (r / r0) ^ n)"
   737     using assms
   738     by (auto simp add: summable_mult summable_geometric)
   739 next
   740   fix n
   741   show "norm (norm (a n) * r ^ n) \<le> M * (r / r0) ^ n"
   742     using r r0 M [of n]
   743     apply (auto simp add: abs_mult field_simps)
   744     apply (cases "r=0", simp)
   745     apply (cases n, auto)
   746     done
   747 qed
   748 
   749 
   750 text\<open>Summability of geometric series for real algebras\<close>
   751 
   752 lemma complete_algebra_summable_geometric:
   753   fixes x :: "'a::{real_normed_algebra_1,banach}"
   754   shows "norm x < 1 \<Longrightarrow> summable (\<lambda>n. x ^ n)"
   755 proof (rule summable_comparison_test)
   756   show "\<exists>N. \<forall>n\<ge>N. norm (x ^ n) \<le> norm x ^ n"
   757     by (simp add: norm_power_ineq)
   758   show "norm x < 1 \<Longrightarrow> summable (\<lambda>n. norm x ^ n)"
   759     by (simp add: summable_geometric)
   760 qed
   761 
   762 subsection \<open>Cauchy Product Formula\<close>
   763 
   764 text \<open>
   765   Proof based on Analysis WebNotes: Chapter 07, Class 41
   766   @{url "http://www.math.unl.edu/~webnotes/classes/class41/prp77.htm"}
   767 \<close>
   768 
   769 lemma Cauchy_product_sums:
   770   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   771   assumes a: "summable (\<lambda>k. norm (a k))"
   772   assumes b: "summable (\<lambda>k. norm (b k))"
   773   shows "(\<lambda>k. \<Sum>i\<le>k. a i * b (k - i)) sums ((\<Sum>k. a k) * (\<Sum>k. b k))"
   774 proof -
   775   let ?S1 = "\<lambda>n::nat. {..<n} \<times> {..<n}"
   776   let ?S2 = "\<lambda>n::nat. {(i,j). i + j < n}"
   777   have S1_mono: "\<And>m n. m \<le> n \<Longrightarrow> ?S1 m \<subseteq> ?S1 n" by auto
   778   have S2_le_S1: "\<And>n. ?S2 n \<subseteq> ?S1 n" by auto
   779   have S1_le_S2: "\<And>n. ?S1 (n div 2) \<subseteq> ?S2 n" by auto
   780   have finite_S1: "\<And>n. finite (?S1 n)" by simp
   781   with S2_le_S1 have finite_S2: "\<And>n. finite (?S2 n)" by (rule finite_subset)
   782 
   783   let ?g = "\<lambda>(i,j). a i * b j"
   784   let ?f = "\<lambda>(i,j). norm (a i) * norm (b j)"
   785   have f_nonneg: "\<And>x. 0 \<le> ?f x" by (auto)
   786   hence norm_setsum_f: "\<And>A. norm (setsum ?f A) = setsum ?f A"
   787     unfolding real_norm_def
   788     by (simp only: abs_of_nonneg setsum_nonneg [rule_format])
   789 
   790   have "(\<lambda>n. (\<Sum>k<n. a k) * (\<Sum>k<n. b k)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   791     by (intro tendsto_mult summable_LIMSEQ summable_norm_cancel [OF a] summable_norm_cancel [OF b])
   792   hence 1: "(\<lambda>n. setsum ?g (?S1 n)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   793     by (simp only: setsum_product setsum.Sigma [rule_format] finite_lessThan)
   794 
   795   have "(\<lambda>n. (\<Sum>k<n. norm (a k)) * (\<Sum>k<n. norm (b k))) \<longlonglongrightarrow> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   796     using a b by (intro tendsto_mult summable_LIMSEQ)
   797   hence "(\<lambda>n. setsum ?f (?S1 n)) \<longlonglongrightarrow> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   798     by (simp only: setsum_product setsum.Sigma [rule_format] finite_lessThan)
   799   hence "convergent (\<lambda>n. setsum ?f (?S1 n))"
   800     by (rule convergentI)
   801   hence Cauchy: "Cauchy (\<lambda>n. setsum ?f (?S1 n))"
   802     by (rule convergent_Cauchy)
   803   have "Zfun (\<lambda>n. setsum ?f (?S1 n - ?S2 n)) sequentially"
   804   proof (rule ZfunI, simp only: eventually_sequentially norm_setsum_f)
   805     fix r :: real
   806     assume r: "0 < r"
   807     from CauchyD [OF Cauchy r] obtain N
   808     where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (setsum ?f (?S1 m) - setsum ?f (?S1 n)) < r" ..
   809     hence "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> norm (setsum ?f (?S1 m - ?S1 n)) < r"
   810       by (simp only: setsum_diff finite_S1 S1_mono)
   811     hence N: "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> setsum ?f (?S1 m - ?S1 n) < r"
   812       by (simp only: norm_setsum_f)
   813     show "\<exists>N. \<forall>n\<ge>N. setsum ?f (?S1 n - ?S2 n) < r"
   814     proof (intro exI allI impI)
   815       fix n assume "2 * N \<le> n"
   816       hence n: "N \<le> n div 2" by simp
   817       have "setsum ?f (?S1 n - ?S2 n) \<le> setsum ?f (?S1 n - ?S1 (n div 2))"
   818         by (intro setsum_mono2 finite_Diff finite_S1 f_nonneg
   819                   Diff_mono subset_refl S1_le_S2)
   820       also have "\<dots> < r"
   821         using n div_le_dividend by (rule N)
   822       finally show "setsum ?f (?S1 n - ?S2 n) < r" .
   823     qed
   824   qed
   825   hence "Zfun (\<lambda>n. setsum ?g (?S1 n - ?S2 n)) sequentially"
   826     apply (rule Zfun_le [rule_format])
   827     apply (simp only: norm_setsum_f)
   828     apply (rule order_trans [OF norm_setsum setsum_mono])
   829     apply (auto simp add: norm_mult_ineq)
   830     done
   831   hence 2: "(\<lambda>n. setsum ?g (?S1 n) - setsum ?g (?S2 n)) \<longlonglongrightarrow> 0"
   832     unfolding tendsto_Zfun_iff diff_0_right
   833     by (simp only: setsum_diff finite_S1 S2_le_S1)
   834 
   835   with 1 have "(\<lambda>n. setsum ?g (?S2 n)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   836     by (rule Lim_transform2)
   837   thus ?thesis by (simp only: sums_def setsum_triangle_reindex)
   838 qed
   839 
   840 lemma Cauchy_product:
   841   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   842   assumes a: "summable (\<lambda>k. norm (a k))"
   843   assumes b: "summable (\<lambda>k. norm (b k))"
   844   shows "(\<Sum>k. a k) * (\<Sum>k. b k) = (\<Sum>k. \<Sum>i\<le>k. a i * b (k - i))"
   845   using a b
   846   by (rule Cauchy_product_sums [THEN sums_unique])
   847 
   848 lemma summable_Cauchy_product:
   849   assumes "summable (\<lambda>k. norm (a k :: 'a :: {real_normed_algebra,banach}))"
   850           "summable (\<lambda>k. norm (b k))"
   851   shows   "summable (\<lambda>k. \<Sum>i\<le>k. a i * b (k - i))"
   852   using Cauchy_product_sums[OF assms] by (simp add: sums_iff)
   853 
   854 subsection \<open>Series on @{typ real}s\<close>
   855 
   856 lemma summable_norm_comparison_test: "\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. norm (f n))"
   857   by (rule summable_comparison_test) auto
   858 
   859 lemma summable_rabs_comparison_test: "\<lbrakk>\<exists>N. \<forall>n\<ge>N. \<bar>f n\<bar> \<le> g n; summable g\<rbrakk> \<Longrightarrow> summable (\<lambda>n. \<bar>f n :: real\<bar>)"
   860   by (rule summable_comparison_test) auto
   861 
   862 lemma summable_rabs_cancel: "summable (\<lambda>n. \<bar>f n :: real\<bar>) \<Longrightarrow> summable f"
   863   by (rule summable_norm_cancel) simp
   864 
   865 lemma summable_rabs: "summable (\<lambda>n. \<bar>f n :: real\<bar>) \<Longrightarrow> \<bar>suminf f\<bar> \<le> (\<Sum>n. \<bar>f n\<bar>)"
   866   by (fold real_norm_def) (rule summable_norm)
   867 
   868 lemma summable_zero_power [simp]: "summable (\<lambda>n. 0 ^ n :: 'a :: {comm_ring_1,topological_space})"
   869 proof -
   870   have "(\<lambda>n. 0 ^ n :: 'a) = (\<lambda>n. if n = 0 then 0^0 else 0)" by (intro ext) (simp add: zero_power)
   871   moreover have "summable \<dots>" by simp
   872   ultimately show ?thesis by simp
   873 qed
   874 
   875 lemma summable_zero_power' [simp]: "summable (\<lambda>n. f n * 0 ^ n :: 'a :: {ring_1,topological_space})"
   876 proof -
   877   have "(\<lambda>n. f n * 0 ^ n :: 'a) = (\<lambda>n. if n = 0 then f 0 * 0^0 else 0)"
   878     by (intro ext) (simp add: zero_power)
   879   moreover have "summable \<dots>" by simp
   880   ultimately show ?thesis by simp
   881 qed
   882 
   883 lemma summable_power_series:
   884   fixes z :: real
   885   assumes le_1: "\<And>i. f i \<le> 1" and nonneg: "\<And>i. 0 \<le> f i" and z: "0 \<le> z" "z < 1"
   886   shows "summable (\<lambda>i. f i * z^i)"
   887 proof (rule summable_comparison_test[OF _ summable_geometric])
   888   show "norm z < 1" using z by (auto simp: less_imp_le)
   889   show "\<And>n. \<exists>N. \<forall>na\<ge>N. norm (f na * z ^ na) \<le> z ^ na"
   890     using z by (auto intro!: exI[of _ 0] mult_left_le_one_le simp: abs_mult nonneg power_abs less_imp_le le_1)
   891 qed
   892 
   893 lemma summable_0_powser:
   894   "summable (\<lambda>n. f n * 0 ^ n :: 'a :: real_normed_div_algebra)"
   895 proof -
   896   have A: "(\<lambda>n. f n * 0 ^ n) = (\<lambda>n. if n = 0 then f n else 0)"
   897     by (intro ext) auto
   898   thus ?thesis by (subst A) simp_all
   899 qed
   900 
   901 lemma summable_powser_split_head:
   902   "summable (\<lambda>n. f (Suc n) * z ^ n :: 'a :: real_normed_div_algebra) = summable (\<lambda>n. f n * z ^ n)"
   903 proof -
   904   have "summable (\<lambda>n. f (Suc n) * z ^ n) \<longleftrightarrow> summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   905   proof
   906     assume "summable (\<lambda>n. f (Suc n) * z ^ n)"
   907     from summable_mult2[OF this, of z] show "summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   908       by (simp add: power_commutes algebra_simps)
   909   next
   910     assume "summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   911     from summable_mult2[OF this, of "inverse z"] show "summable (\<lambda>n. f (Suc n) * z ^ n)"
   912       by (cases "z \<noteq> 0", subst (asm) power_Suc2) (simp_all add: algebra_simps)
   913   qed
   914   also have "\<dots> \<longleftrightarrow> summable (\<lambda>n. f n * z ^ n)" by (rule summable_Suc_iff)
   915   finally show ?thesis .
   916 qed
   917 
   918 lemma powser_split_head:
   919   assumes "summable (\<lambda>n. f n * z ^ n :: 'a :: {real_normed_div_algebra,banach})"
   920   shows   "suminf (\<lambda>n. f n * z ^ n) = f 0 + suminf (\<lambda>n. f (Suc n) * z ^ n) * z"
   921           "suminf (\<lambda>n. f (Suc n) * z ^ n) * z = suminf (\<lambda>n. f n * z ^ n) - f 0"
   922           "summable (\<lambda>n. f (Suc n) * z ^ n)"
   923 proof -
   924   from assms show "summable (\<lambda>n. f (Suc n) * z ^ n)" by (subst summable_powser_split_head)
   925 
   926   from suminf_mult2[OF this, of z]
   927     have "(\<Sum>n. f (Suc n) * z ^ n) * z = (\<Sum>n. f (Suc n) * z ^ Suc n)"
   928     by (simp add: power_commutes algebra_simps)
   929   also from assms have "\<dots> = suminf (\<lambda>n. f n * z ^ n) - f 0"
   930     by (subst suminf_split_head) simp_all
   931   finally show "suminf (\<lambda>n. f n * z ^ n) = f 0 + suminf (\<lambda>n. f (Suc n) * z ^ n) * z" by simp
   932   thus "suminf (\<lambda>n. f (Suc n) * z ^ n) * z = suminf (\<lambda>n. f n * z ^ n) - f 0" by simp
   933 qed
   934 
   935 lemma summable_partial_sum_bound:
   936   fixes f :: "nat \<Rightarrow> 'a :: banach"
   937   assumes summable: "summable f" and e: "e > (0::real)"
   938   obtains N where "\<And>m n. m \<ge> N \<Longrightarrow> norm (\<Sum>k=m..n. f k) < e"
   939 proof -
   940   from summable have "Cauchy (\<lambda>n. \<Sum>k<n. f k)"
   941     by (simp add: Cauchy_convergent_iff summable_iff_convergent)
   942   from CauchyD[OF this e] obtain N
   943     where N: "\<And>m n. m \<ge> N \<Longrightarrow> n \<ge> N \<Longrightarrow> norm ((\<Sum>k<m. f k) - (\<Sum>k<n. f k)) < e" by blast
   944   {
   945     fix m n :: nat assume m: "m \<ge> N"
   946     have "norm (\<Sum>k=m..n. f k) < e"
   947     proof (cases "n \<ge> m")
   948       assume n: "n \<ge> m"
   949       with m have "norm ((\<Sum>k<Suc n. f k) - (\<Sum>k<m. f k)) < e" by (intro N) simp_all
   950       also from n have "(\<Sum>k<Suc n. f k) - (\<Sum>k<m. f k) = (\<Sum>k=m..n. f k)"
   951         by (subst setsum_diff [symmetric]) (simp_all add: setsum_last_plus)
   952       finally show ?thesis .
   953     qed (insert e, simp_all)
   954   }
   955   thus ?thesis by (rule that)
   956 qed
   957 
   958 lemma powser_sums_if:
   959   "(\<lambda>n. (if n = m then (1 :: 'a :: {ring_1,topological_space}) else 0) * z^n) sums z^m"
   960 proof -
   961   have "(\<lambda>n. (if n = m then 1 else 0) * z^n) = (\<lambda>n. if n = m then z^n else 0)"
   962     by (intro ext) auto
   963   thus ?thesis by (simp add: sums_single)
   964 qed
   965 
   966 lemma
   967    fixes f :: "nat \<Rightarrow> real"
   968    assumes "summable f"
   969    and "inj g"
   970    and pos: "\<And>x. 0 \<le> f x"
   971    shows summable_reindex: "summable (f o g)"
   972    and suminf_reindex_mono: "suminf (f o g) \<le> suminf f"
   973    and suminf_reindex: "(\<And>x. x \<notin> range g \<Longrightarrow> f x = 0) \<Longrightarrow> suminf (f \<circ> g) = suminf f"
   974 proof -
   975   from \<open>inj g\<close> have [simp]: "\<And>A. inj_on g A" by(rule subset_inj_on) simp
   976 
   977   have smaller: "\<forall>n. (\<Sum>i<n. (f \<circ> g) i) \<le> suminf f"
   978   proof
   979     fix n
   980     have "\<forall> n' \<in> (g ` {..<n}). n' < Suc (Max (g ` {..<n}))"
   981       by(metis Max_ge finite_imageI finite_lessThan not_le not_less_eq)
   982     then obtain m where n: "\<And>n'. n' < n \<Longrightarrow> g n' < m" by blast
   983 
   984     have "(\<Sum>i<n. f (g i)) = setsum f (g ` {..<n})"
   985       by (simp add: setsum.reindex)
   986     also have "\<dots> \<le> (\<Sum>i<m. f i)"
   987       by (rule setsum_mono3) (auto simp add: pos n[rule_format])
   988     also have "\<dots> \<le> suminf f"
   989       using \<open>summable f\<close>
   990       by (rule setsum_le_suminf) (simp add: pos)
   991     finally show "(\<Sum>i<n. (f \<circ>  g) i) \<le> suminf f" by simp
   992   qed
   993 
   994   have "incseq (\<lambda>n. \<Sum>i<n. (f \<circ> g) i)"
   995     by (rule incseq_SucI) (auto simp add: pos)
   996   then obtain  L where L: "(\<lambda> n. \<Sum>i<n. (f \<circ> g) i) \<longlonglongrightarrow> L"
   997     using smaller by(rule incseq_convergent)
   998   hence "(f \<circ> g) sums L" by (simp add: sums_def)
   999   thus "summable (f o g)" by (auto simp add: sums_iff)
  1000 
  1001   hence "(\<lambda>n. \<Sum>i<n. (f \<circ> g) i) \<longlonglongrightarrow> suminf (f \<circ> g)"
  1002     by(rule summable_LIMSEQ)
  1003   thus le: "suminf (f \<circ> g) \<le> suminf f"
  1004     by(rule LIMSEQ_le_const2)(blast intro: smaller[rule_format])
  1005 
  1006   assume f: "\<And>x. x \<notin> range g \<Longrightarrow> f x = 0"
  1007 
  1008   from \<open>summable f\<close> have "suminf f \<le> suminf (f \<circ> g)"
  1009   proof(rule suminf_le_const)
  1010     fix n
  1011     have "\<forall> n' \<in> (g -` {..<n}). n' < Suc (Max (g -` {..<n}))"
  1012       by(auto intro: Max_ge simp add: finite_vimageI less_Suc_eq_le)
  1013     then obtain m where n: "\<And>n'. g n' < n \<Longrightarrow> n' < m" by blast
  1014 
  1015     have "(\<Sum>i<n. f i) = (\<Sum>i\<in>{..<n} \<inter> range g. f i)"
  1016       using f by(auto intro: setsum.mono_neutral_cong_right)
  1017     also have "\<dots> = (\<Sum>i\<in>g -` {..<n}. (f \<circ> g) i)"
  1018       by(rule setsum.reindex_cong[where l=g])(auto)
  1019     also have "\<dots> \<le> (\<Sum>i<m. (f \<circ> g) i)"
  1020       by(rule setsum_mono3)(auto simp add: pos n)
  1021     also have "\<dots> \<le> suminf (f \<circ> g)"
  1022       using \<open>summable (f o g)\<close>
  1023       by(rule setsum_le_suminf)(simp add: pos)
  1024     finally show "setsum f {..<n} \<le> suminf (f \<circ> g)" .
  1025   qed
  1026   with le show "suminf (f \<circ> g) = suminf f" by(rule antisym)
  1027 qed
  1028 
  1029 lemma sums_mono_reindex:
  1030   assumes subseq: "subseq g" and zero: "\<And>n. n \<notin> range g \<Longrightarrow> f n = 0"
  1031   shows   "(\<lambda>n. f (g n)) sums c \<longleftrightarrow> f sums c"
  1032 unfolding sums_def
  1033 proof
  1034   assume lim: "(\<lambda>n. \<Sum>k<n. f k) \<longlonglongrightarrow> c"
  1035   have "(\<lambda>n. \<Sum>k<n. f (g k)) = (\<lambda>n. \<Sum>k<g n. f k)"
  1036   proof
  1037     fix n :: nat
  1038     from subseq have "(\<Sum>k<n. f (g k)) = (\<Sum>k\<in>g`{..<n}. f k)"
  1039       by (subst setsum.reindex) (auto intro: subseq_imp_inj_on)
  1040     also from subseq have "\<dots> = (\<Sum>k<g n. f k)"
  1041       by (intro setsum.mono_neutral_left ballI zero)
  1042          (auto dest: subseq_strict_mono simp: strict_mono_less strict_mono_less_eq)
  1043     finally show "(\<Sum>k<n. f (g k)) = (\<Sum>k<g n. f k)" .
  1044   qed
  1045   also from LIMSEQ_subseq_LIMSEQ[OF lim subseq] have "\<dots> \<longlonglongrightarrow> c" unfolding o_def .
  1046   finally show "(\<lambda>n. \<Sum>k<n. f (g k)) \<longlonglongrightarrow> c" .
  1047 next
  1048   assume lim: "(\<lambda>n. \<Sum>k<n. f (g k)) \<longlonglongrightarrow> c"
  1049   define g_inv where "g_inv n = (LEAST m. g m \<ge> n)" for n
  1050   from filterlim_subseq[OF subseq] have g_inv_ex: "\<exists>m. g m \<ge> n" for n
  1051     by (auto simp: filterlim_at_top eventually_at_top_linorder)
  1052   hence g_inv: "g (g_inv n) \<ge> n" for n unfolding g_inv_def by (rule LeastI_ex)
  1053   have g_inv_least: "m \<ge> g_inv n" if "g m \<ge> n" for m n using that
  1054     unfolding g_inv_def by (rule Least_le)
  1055   have g_inv_least': "g m < n" if "m < g_inv n" for m n using that g_inv_least[of n m] by linarith
  1056   have "(\<lambda>n. \<Sum>k<n. f k) = (\<lambda>n. \<Sum>k<g_inv n. f (g k))"
  1057   proof
  1058     fix n :: nat
  1059     {
  1060       fix k assume k: "k \<in> {..<n} - g`{..<g_inv n}"
  1061       have "k \<notin> range g"
  1062       proof (rule notI, elim imageE)
  1063         fix l assume l: "k = g l"
  1064         have "g l < g (g_inv n)" by (rule less_le_trans[OF _ g_inv]) (insert k l, simp_all)
  1065         with subseq have "l < g_inv n" by (simp add: subseq_strict_mono strict_mono_less)
  1066         with k l show False by simp
  1067       qed
  1068       hence "f k = 0" by (rule zero)
  1069     }
  1070     with g_inv_least' g_inv have "(\<Sum>k<n. f k) = (\<Sum>k\<in>g`{..<g_inv n}. f k)"
  1071       by (intro setsum.mono_neutral_right) auto
  1072     also from subseq have "\<dots> = (\<Sum>k<g_inv n. f (g k))" using subseq_imp_inj_on
  1073       by (subst setsum.reindex) simp_all
  1074     finally show "(\<Sum>k<n. f k) = (\<Sum>k<g_inv n. f (g k))" .
  1075   qed
  1076   also {
  1077     fix K n :: nat assume "g K \<le> n"
  1078     also have "n \<le> g (g_inv n)" by (rule g_inv)
  1079     finally have "K \<le> g_inv n" using subseq by (simp add: strict_mono_less_eq subseq_strict_mono)
  1080   }
  1081   hence "filterlim g_inv at_top sequentially"
  1082     by (auto simp: filterlim_at_top eventually_at_top_linorder)
  1083   from lim and this have "(\<lambda>n. \<Sum>k<g_inv n. f (g k)) \<longlonglongrightarrow> c" by (rule filterlim_compose)
  1084   finally show "(\<lambda>n. \<Sum>k<n. f k) \<longlonglongrightarrow> c" .
  1085 qed
  1086 
  1087 lemma summable_mono_reindex:
  1088   assumes subseq: "subseq g" and zero: "\<And>n. n \<notin> range g \<Longrightarrow> f n = 0"
  1089   shows   "summable (\<lambda>n. f (g n)) \<longleftrightarrow> summable f"
  1090   using sums_mono_reindex[of g f, OF assms] by (simp add: summable_def)
  1091 
  1092 lemma suminf_mono_reindex:
  1093   assumes "subseq g" "\<And>n. n \<notin> range g \<Longrightarrow> f n = (0 :: 'a :: {t2_space,comm_monoid_add})"
  1094   shows   "suminf (\<lambda>n. f (g n)) = suminf f"
  1095 proof (cases "summable f")
  1096   case False
  1097   hence "\<not>(\<exists>c. f sums c)" unfolding summable_def by blast
  1098   hence "suminf f = The (\<lambda>_. False)" by (simp add: suminf_def)
  1099   moreover from False have "\<not>summable (\<lambda>n. f (g n))"
  1100     using summable_mono_reindex[of g f, OF assms] by simp
  1101   hence "\<not>(\<exists>c. (\<lambda>n. f (g n)) sums c)" unfolding summable_def by blast
  1102   hence "suminf (\<lambda>n. f (g n)) = The (\<lambda>_. False)" by (simp add: suminf_def)
  1103   ultimately show ?thesis by simp
  1104 qed (insert sums_mono_reindex[of g f, OF assms] summable_mono_reindex[of g f, OF assms],
  1105      simp_all add: sums_iff)
  1106 
  1107 end