src/HOL/Complex.thy
author haftmann
Wed Apr 29 14:20:26 2009 +0200 (2009-04-29)
changeset 31021 53642251a04f
parent 30960 fec1a04b7220
child 31292 d24b2692562f
permissions -rw-r--r--
farewell to class recpower
     1 (*  Title:       Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 datatype complex = Complex real real
    14 
    15 primrec
    16   Re :: "complex \<Rightarrow> real"
    17 where
    18   Re: "Re (Complex x y) = x"
    19 
    20 primrec
    21   Im :: "complex \<Rightarrow> real"
    22 where
    23   Im: "Im (Complex x y) = y"
    24 
    25 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
    26   by (induct z) simp
    27 
    28 lemma complex_equality [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    29   by (induct x, induct y) simp
    30 
    31 lemma expand_complex_eq: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    32   by (induct x, induct y) simp
    33 
    34 lemmas complex_Re_Im_cancel_iff = expand_complex_eq
    35 
    36 
    37 subsection {* Addition and Subtraction *}
    38 
    39 instantiation complex :: ab_group_add
    40 begin
    41 
    42 definition
    43   complex_zero_def: "0 = Complex 0 0"
    44 
    45 definition
    46   complex_add_def: "x + y = Complex (Re x + Re y) (Im x + Im y)"
    47 
    48 definition
    49   complex_minus_def: "- x = Complex (- Re x) (- Im x)"
    50 
    51 definition
    52   complex_diff_def: "x - (y\<Colon>complex) = x + - y"
    53 
    54 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
    55   by (simp add: complex_zero_def)
    56 
    57 lemma complex_Re_zero [simp]: "Re 0 = 0"
    58   by (simp add: complex_zero_def)
    59 
    60 lemma complex_Im_zero [simp]: "Im 0 = 0"
    61   by (simp add: complex_zero_def)
    62 
    63 lemma complex_add [simp]:
    64   "Complex a b + Complex c d = Complex (a + c) (b + d)"
    65   by (simp add: complex_add_def)
    66 
    67 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
    68   by (simp add: complex_add_def)
    69 
    70 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
    71   by (simp add: complex_add_def)
    72 
    73 lemma complex_minus [simp]:
    74   "- (Complex a b) = Complex (- a) (- b)"
    75   by (simp add: complex_minus_def)
    76 
    77 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
    78   by (simp add: complex_minus_def)
    79 
    80 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
    81   by (simp add: complex_minus_def)
    82 
    83 lemma complex_diff [simp]:
    84   "Complex a b - Complex c d = Complex (a - c) (b - d)"
    85   by (simp add: complex_diff_def)
    86 
    87 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
    88   by (simp add: complex_diff_def)
    89 
    90 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
    91   by (simp add: complex_diff_def)
    92 
    93 instance
    94   by intro_classes (simp_all add: complex_add_def complex_diff_def)
    95 
    96 end
    97 
    98 
    99 
   100 subsection {* Multiplication and Division *}
   101 
   102 instantiation complex :: "{field, division_by_zero}"
   103 begin
   104 
   105 definition
   106   complex_one_def: "1 = Complex 1 0"
   107 
   108 definition
   109   complex_mult_def: "x * y =
   110     Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
   111 
   112 definition
   113   complex_inverse_def: "inverse x =
   114     Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"
   115 
   116 definition
   117   complex_divide_def: "x / (y\<Colon>complex) = x * inverse y"
   118 
   119 lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"
   120   by (simp add: complex_one_def)
   121 
   122 lemma complex_Re_one [simp]: "Re 1 = 1"
   123   by (simp add: complex_one_def)
   124 
   125 lemma complex_Im_one [simp]: "Im 1 = 0"
   126   by (simp add: complex_one_def)
   127 
   128 lemma complex_mult [simp]:
   129   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   130   by (simp add: complex_mult_def)
   131 
   132 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
   133   by (simp add: complex_mult_def)
   134 
   135 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
   136   by (simp add: complex_mult_def)
   137 
   138 lemma complex_inverse [simp]:
   139   "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"
   140   by (simp add: complex_inverse_def)
   141 
   142 lemma complex_Re_inverse:
   143   "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   144   by (simp add: complex_inverse_def)
   145 
   146 lemma complex_Im_inverse:
   147   "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   148   by (simp add: complex_inverse_def)
   149 
   150 instance
   151   by intro_classes (simp_all add: complex_mult_def
   152   right_distrib left_distrib right_diff_distrib left_diff_distrib
   153   complex_inverse_def complex_divide_def
   154   power2_eq_square add_divide_distrib [symmetric]
   155   expand_complex_eq)
   156 
   157 end
   158 
   159 
   160 subsection {* Numerals and Arithmetic *}
   161 
   162 instantiation complex :: number_ring
   163 begin
   164 
   165 definition number_of_complex where
   166   complex_number_of_def: "number_of w = (of_int w \<Colon> complex)"
   167 
   168 instance
   169   by intro_classes (simp only: complex_number_of_def)
   170 
   171 end
   172 
   173 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   174 by (induct n) simp_all
   175 
   176 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   177 by (induct n) simp_all
   178 
   179 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   180 by (cases z rule: int_diff_cases) simp
   181 
   182 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   183 by (cases z rule: int_diff_cases) simp
   184 
   185 lemma complex_Re_number_of [simp]: "Re (number_of v) = number_of v"
   186 unfolding number_of_eq by (rule complex_Re_of_int)
   187 
   188 lemma complex_Im_number_of [simp]: "Im (number_of v) = 0"
   189 unfolding number_of_eq by (rule complex_Im_of_int)
   190 
   191 lemma Complex_eq_number_of [simp]:
   192   "(Complex a b = number_of w) = (a = number_of w \<and> b = 0)"
   193 by (simp add: expand_complex_eq)
   194 
   195 
   196 subsection {* Scalar Multiplication *}
   197 
   198 instantiation complex :: real_field
   199 begin
   200 
   201 definition
   202   complex_scaleR_def: "scaleR r x = Complex (r * Re x) (r * Im x)"
   203 
   204 lemma complex_scaleR [simp]:
   205   "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   206   unfolding complex_scaleR_def by simp
   207 
   208 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
   209   unfolding complex_scaleR_def by simp
   210 
   211 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
   212   unfolding complex_scaleR_def by simp
   213 
   214 instance
   215 proof
   216   fix a b :: real and x y :: complex
   217   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   218     by (simp add: expand_complex_eq right_distrib)
   219   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   220     by (simp add: expand_complex_eq left_distrib)
   221   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   222     by (simp add: expand_complex_eq mult_assoc)
   223   show "scaleR 1 x = x"
   224     by (simp add: expand_complex_eq)
   225   show "scaleR a x * y = scaleR a (x * y)"
   226     by (simp add: expand_complex_eq algebra_simps)
   227   show "x * scaleR a y = scaleR a (x * y)"
   228     by (simp add: expand_complex_eq algebra_simps)
   229 qed
   230 
   231 end
   232 
   233 
   234 subsection{* Properties of Embedding from Reals *}
   235 
   236 abbreviation
   237   complex_of_real :: "real \<Rightarrow> complex" where
   238     "complex_of_real \<equiv> of_real"
   239 
   240 lemma complex_of_real_def: "complex_of_real r = Complex r 0"
   241 by (simp add: of_real_def complex_scaleR_def)
   242 
   243 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   244 by (simp add: complex_of_real_def)
   245 
   246 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   247 by (simp add: complex_of_real_def)
   248 
   249 lemma Complex_add_complex_of_real [simp]:
   250      "Complex x y + complex_of_real r = Complex (x+r) y"
   251 by (simp add: complex_of_real_def)
   252 
   253 lemma complex_of_real_add_Complex [simp]:
   254      "complex_of_real r + Complex x y = Complex (r+x) y"
   255 by (simp add: complex_of_real_def)
   256 
   257 lemma Complex_mult_complex_of_real:
   258      "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   259 by (simp add: complex_of_real_def)
   260 
   261 lemma complex_of_real_mult_Complex:
   262      "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   263 by (simp add: complex_of_real_def)
   264 
   265 
   266 subsection {* Vector Norm *}
   267 
   268 instantiation complex :: real_normed_field
   269 begin
   270 
   271 definition
   272   complex_norm_def: "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   273 
   274 abbreviation
   275   cmod :: "complex \<Rightarrow> real" where
   276   "cmod \<equiv> norm"
   277 
   278 definition
   279   complex_sgn_def: "sgn x = x /\<^sub>R cmod x"
   280 
   281 lemmas cmod_def = complex_norm_def
   282 
   283 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"
   284   by (simp add: complex_norm_def)
   285 
   286 instance
   287 proof
   288   fix r :: real and x y :: complex
   289   show "0 \<le> norm x"
   290     by (induct x) simp
   291   show "(norm x = 0) = (x = 0)"
   292     by (induct x) simp
   293   show "norm (x + y) \<le> norm x + norm y"
   294     by (induct x, induct y)
   295        (simp add: real_sqrt_sum_squares_triangle_ineq)
   296   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   297     by (induct x)
   298        (simp add: power_mult_distrib right_distrib [symmetric] real_sqrt_mult)
   299   show "norm (x * y) = norm x * norm y"
   300     by (induct x, induct y)
   301        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   302   show "sgn x = x /\<^sub>R cmod x" by(simp add: complex_sgn_def)
   303 qed
   304 
   305 end
   306 
   307 lemma cmod_unit_one [simp]: "cmod (Complex (cos a) (sin a)) = 1"
   308 by simp
   309 
   310 lemma cmod_complex_polar [simp]:
   311      "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
   312 by (simp add: norm_mult)
   313 
   314 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   315 unfolding complex_norm_def
   316 by (rule real_sqrt_sum_squares_ge1)
   317 
   318 lemma complex_mod_minus_le_complex_mod [simp]: "- cmod x \<le> cmod x"
   319 by (rule order_trans [OF _ norm_ge_zero], simp)
   320 
   321 lemma complex_mod_triangle_ineq2 [simp]: "cmod(b + a) - cmod b \<le> cmod a"
   322 by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
   323 
   324 lemmas real_sum_squared_expand = power2_sum [where 'a=real]
   325 
   326 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   327 by (cases x) simp
   328 
   329 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   330 by (cases x) simp
   331 
   332 subsection {* Completeness of the Complexes *}
   333 
   334 interpretation Re: bounded_linear "Re"
   335 apply (unfold_locales, simp, simp)
   336 apply (rule_tac x=1 in exI)
   337 apply (simp add: complex_norm_def)
   338 done
   339 
   340 interpretation Im: bounded_linear "Im"
   341 apply (unfold_locales, simp, simp)
   342 apply (rule_tac x=1 in exI)
   343 apply (simp add: complex_norm_def)
   344 done
   345 
   346 lemma LIMSEQ_Complex:
   347   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. Complex (X n) (Y n)) ----> Complex a b"
   348 apply (rule LIMSEQ_I)
   349 apply (subgoal_tac "0 < r / sqrt 2")
   350 apply (drule_tac r="r / sqrt 2" in LIMSEQ_D, safe)
   351 apply (drule_tac r="r / sqrt 2" in LIMSEQ_D, safe)
   352 apply (rename_tac M N, rule_tac x="max M N" in exI, safe)
   353 apply (simp add: real_sqrt_sum_squares_less)
   354 apply (simp add: divide_pos_pos)
   355 done
   356 
   357 instance complex :: banach
   358 proof
   359   fix X :: "nat \<Rightarrow> complex"
   360   assume X: "Cauchy X"
   361   from Re.Cauchy [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
   362     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   363   from Im.Cauchy [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
   364     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   365   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   366     using LIMSEQ_Complex [OF 1 2] by simp
   367   thus "convergent X"
   368     by (rule convergentI)
   369 qed
   370 
   371 
   372 subsection {* The Complex Number @{term "\<i>"} *}
   373 
   374 definition
   375   "ii" :: complex  ("\<i>") where
   376   i_def: "ii \<equiv> Complex 0 1"
   377 
   378 lemma complex_Re_i [simp]: "Re ii = 0"
   379 by (simp add: i_def)
   380 
   381 lemma complex_Im_i [simp]: "Im ii = 1"
   382 by (simp add: i_def)
   383 
   384 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   385 by (simp add: i_def)
   386 
   387 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   388 by (simp add: expand_complex_eq)
   389 
   390 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   391 by (simp add: expand_complex_eq)
   392 
   393 lemma complex_i_not_number_of [simp]: "ii \<noteq> number_of w"
   394 by (simp add: expand_complex_eq)
   395 
   396 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
   397 by (simp add: expand_complex_eq)
   398 
   399 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
   400 by (simp add: expand_complex_eq)
   401 
   402 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
   403 by (simp add: i_def complex_of_real_def)
   404 
   405 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
   406 by (simp add: i_def complex_of_real_def)
   407 
   408 lemma i_squared [simp]: "ii * ii = -1"
   409 by (simp add: i_def)
   410 
   411 lemma power2_i [simp]: "ii\<twosuperior> = -1"
   412 by (simp add: power2_eq_square)
   413 
   414 lemma inverse_i [simp]: "inverse ii = - ii"
   415 by (rule inverse_unique, simp)
   416 
   417 
   418 subsection {* Complex Conjugation *}
   419 
   420 definition
   421   cnj :: "complex \<Rightarrow> complex" where
   422   "cnj z = Complex (Re z) (- Im z)"
   423 
   424 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
   425 by (simp add: cnj_def)
   426 
   427 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
   428 by (simp add: cnj_def)
   429 
   430 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
   431 by (simp add: cnj_def)
   432 
   433 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   434 by (simp add: expand_complex_eq)
   435 
   436 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   437 by (simp add: cnj_def)
   438 
   439 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   440 by (simp add: expand_complex_eq)
   441 
   442 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   443 by (simp add: expand_complex_eq)
   444 
   445 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
   446 by (simp add: expand_complex_eq)
   447 
   448 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
   449 by (simp add: expand_complex_eq)
   450 
   451 lemma complex_cnj_minus: "cnj (- x) = - cnj x"
   452 by (simp add: expand_complex_eq)
   453 
   454 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   455 by (simp add: expand_complex_eq)
   456 
   457 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
   458 by (simp add: expand_complex_eq)
   459 
   460 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
   461 by (simp add: complex_inverse_def)
   462 
   463 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
   464 by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
   465 
   466 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
   467 by (induct n, simp_all add: complex_cnj_mult)
   468 
   469 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   470 by (simp add: expand_complex_eq)
   471 
   472 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   473 by (simp add: expand_complex_eq)
   474 
   475 lemma complex_cnj_number_of [simp]: "cnj (number_of w) = number_of w"
   476 by (simp add: expand_complex_eq)
   477 
   478 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
   479 by (simp add: expand_complex_eq)
   480 
   481 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   482 by (simp add: complex_norm_def)
   483 
   484 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   485 by (simp add: expand_complex_eq)
   486 
   487 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   488 by (simp add: expand_complex_eq)
   489 
   490 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   491 by (simp add: expand_complex_eq)
   492 
   493 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   494 by (simp add: expand_complex_eq)
   495 
   496 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   497 by (simp add: expand_complex_eq power2_eq_square)
   498 
   499 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"
   500 by (simp add: norm_mult power2_eq_square)
   501 
   502 interpretation cnj: bounded_linear "cnj"
   503 apply (unfold_locales)
   504 apply (rule complex_cnj_add)
   505 apply (rule complex_cnj_scaleR)
   506 apply (rule_tac x=1 in exI, simp)
   507 done
   508 
   509 
   510 subsection{*The Functions @{term sgn} and @{term arg}*}
   511 
   512 text {*------------ Argand -------------*}
   513 
   514 definition
   515   arg :: "complex => real" where
   516   "arg z = (SOME a. Re(sgn z) = cos a & Im(sgn z) = sin a & -pi < a & a \<le> pi)"
   517 
   518 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   519 by (simp add: complex_sgn_def divide_inverse scaleR_conv_of_real mult_commute)
   520 
   521 lemma i_mult_eq: "ii * ii = complex_of_real (-1)"
   522 by (simp add: i_def complex_of_real_def)
   523 
   524 lemma i_mult_eq2 [simp]: "ii * ii = -(1::complex)"
   525 by (simp add: i_def complex_one_def)
   526 
   527 lemma complex_eq_cancel_iff2 [simp]:
   528      "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   529 by (simp add: complex_of_real_def)
   530 
   531 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   532 by (simp add: complex_sgn_def divide_inverse)
   533 
   534 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   535 by (simp add: complex_sgn_def divide_inverse)
   536 
   537 lemma complex_inverse_complex_split:
   538      "inverse(complex_of_real x + ii * complex_of_real y) =
   539       complex_of_real(x/(x ^ 2 + y ^ 2)) -
   540       ii * complex_of_real(y/(x ^ 2 + y ^ 2))"
   541 by (simp add: complex_of_real_def i_def diff_minus divide_inverse)
   542 
   543 (*----------------------------------------------------------------------------*)
   544 (* Many of the theorems below need to be moved elsewhere e.g. Transc. Also *)
   545 (* many of the theorems are not used - so should they be kept?                *)
   546 (*----------------------------------------------------------------------------*)
   547 
   548 lemma cos_arg_i_mult_zero_pos:
   549    "0 < y ==> cos (arg(Complex 0 y)) = 0"
   550 apply (simp add: arg_def abs_if)
   551 apply (rule_tac a = "pi/2" in someI2, auto)
   552 apply (rule order_less_trans [of _ 0], auto)
   553 done
   554 
   555 lemma cos_arg_i_mult_zero_neg:
   556    "y < 0 ==> cos (arg(Complex 0 y)) = 0"
   557 apply (simp add: arg_def abs_if)
   558 apply (rule_tac a = "- pi/2" in someI2, auto)
   559 apply (rule order_trans [of _ 0], auto)
   560 done
   561 
   562 lemma cos_arg_i_mult_zero [simp]:
   563      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
   564 by (auto simp add: linorder_neq_iff cos_arg_i_mult_zero_pos cos_arg_i_mult_zero_neg)
   565 
   566 
   567 subsection{*Finally! Polar Form for Complex Numbers*}
   568 
   569 definition
   570 
   571   (* abbreviation for (cos a + i sin a) *)
   572   cis :: "real => complex" where
   573   "cis a = Complex (cos a) (sin a)"
   574 
   575 definition
   576   (* abbreviation for r*(cos a + i sin a) *)
   577   rcis :: "[real, real] => complex" where
   578   "rcis r a = complex_of_real r * cis a"
   579 
   580 definition
   581   (* e ^ (x + iy) *)
   582   expi :: "complex => complex" where
   583   "expi z = complex_of_real(exp (Re z)) * cis (Im z)"
   584 
   585 lemma complex_split_polar:
   586      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
   587 apply (induct z)
   588 apply (auto simp add: polar_Ex complex_of_real_mult_Complex)
   589 done
   590 
   591 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   592 apply (induct z)
   593 apply (simp add: rcis_def cis_def polar_Ex complex_of_real_mult_Complex)
   594 done
   595 
   596 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   597 by (simp add: rcis_def cis_def)
   598 
   599 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   600 by (simp add: rcis_def cis_def)
   601 
   602 lemma sin_cos_squared_add2_mult: "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior>"
   603 proof -
   604   have "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior> * ((cos a)\<twosuperior> + (sin a)\<twosuperior>)"
   605     by (simp only: power_mult_distrib right_distrib)
   606   thus ?thesis by simp
   607 qed
   608 
   609 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   610 by (simp add: rcis_def cis_def sin_cos_squared_add2_mult)
   611 
   612 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   613 by (simp add: cmod_def power2_eq_square)
   614 
   615 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   616 by simp
   617 
   618 
   619 (*---------------------------------------------------------------------------*)
   620 (*  (r1 * cis a) * (r2 * cis b) = r1 * r2 * cis (a + b)                      *)
   621 (*---------------------------------------------------------------------------*)
   622 
   623 lemma cis_rcis_eq: "cis a = rcis 1 a"
   624 by (simp add: rcis_def)
   625 
   626 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   627 by (simp add: rcis_def cis_def cos_add sin_add right_distrib right_diff_distrib
   628               complex_of_real_def)
   629 
   630 lemma cis_mult: "cis a * cis b = cis (a + b)"
   631 by (simp add: cis_rcis_eq rcis_mult)
   632 
   633 lemma cis_zero [simp]: "cis 0 = 1"
   634 by (simp add: cis_def complex_one_def)
   635 
   636 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   637 by (simp add: rcis_def)
   638 
   639 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   640 by (simp add: rcis_def)
   641 
   642 lemma complex_of_real_minus_one:
   643    "complex_of_real (-(1::real)) = -(1::complex)"
   644 by (simp add: complex_of_real_def complex_one_def)
   645 
   646 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   647 by (simp add: mult_assoc [symmetric])
   648 
   649 
   650 lemma cis_real_of_nat_Suc_mult:
   651    "cis (real (Suc n) * a) = cis a * cis (real n * a)"
   652 by (simp add: cis_def real_of_nat_Suc left_distrib cos_add sin_add right_distrib)
   653 
   654 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   655 apply (induct_tac "n")
   656 apply (auto simp add: cis_real_of_nat_Suc_mult)
   657 done
   658 
   659 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   660 by (simp add: rcis_def power_mult_distrib DeMoivre)
   661 
   662 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   663 by (simp add: cis_def complex_inverse_complex_split diff_minus)
   664 
   665 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   666 by (simp add: divide_inverse rcis_def)
   667 
   668 lemma cis_divide: "cis a / cis b = cis (a - b)"
   669 by (simp add: complex_divide_def cis_mult real_diff_def)
   670 
   671 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   672 apply (simp add: complex_divide_def)
   673 apply (case_tac "r2=0", simp)
   674 apply (simp add: rcis_inverse rcis_mult real_diff_def)
   675 done
   676 
   677 lemma Re_cis [simp]: "Re(cis a) = cos a"
   678 by (simp add: cis_def)
   679 
   680 lemma Im_cis [simp]: "Im(cis a) = sin a"
   681 by (simp add: cis_def)
   682 
   683 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   684 by (auto simp add: DeMoivre)
   685 
   686 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   687 by (auto simp add: DeMoivre)
   688 
   689 lemma expi_add: "expi(a + b) = expi(a) * expi(b)"
   690 by (simp add: expi_def exp_add cis_mult [symmetric] mult_ac)
   691 
   692 lemma expi_zero [simp]: "expi (0::complex) = 1"
   693 by (simp add: expi_def)
   694 
   695 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   696 apply (insert rcis_Ex [of z])
   697 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
   698 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   699 done
   700 
   701 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   702 by (simp add: expi_def cis_def)
   703 
   704 end