src/HOL/List.thy
author krauss
Tue Nov 07 11:53:55 2006 +0100 (2006-11-07)
changeset 21211 5370cfbf3070
parent 21193 25a5ab43a5ff
child 21404 eb85850d3eb7
permissions -rw-r--r--
Preparations for making "lexicographic_order" part of "fun"
     1 (*  Title:      HOL/List.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4 *)
     5 
     6 header {* The datatype of finite lists *}
     7 
     8 theory List
     9 imports PreList FunDef
    10 begin
    11 
    12 datatype 'a list =
    13     Nil    ("[]")
    14   | Cons 'a  "'a list"    (infixr "#" 65)
    15 
    16 subsection{*Basic list processing functions*}
    17 
    18 consts
    19   "@" :: "'a list => 'a list => 'a list"    (infixr 65)
    20   filter:: "('a => bool) => 'a list => 'a list"
    21   concat:: "'a list list => 'a list"
    22   foldl :: "('b => 'a => 'b) => 'b => 'a list => 'b"
    23   foldr :: "('a => 'b => 'b) => 'a list => 'b => 'b"
    24   hd:: "'a list => 'a"
    25   tl:: "'a list => 'a list"
    26   last:: "'a list => 'a"
    27   butlast :: "'a list => 'a list"
    28   set :: "'a list => 'a set"
    29   map :: "('a=>'b) => ('a list => 'b list)"
    30   nth :: "'a list => nat => 'a"    (infixl "!" 100)
    31   list_update :: "'a list => nat => 'a => 'a list"
    32   take:: "nat => 'a list => 'a list"
    33   drop:: "nat => 'a list => 'a list"
    34   takeWhile :: "('a => bool) => 'a list => 'a list"
    35   dropWhile :: "('a => bool) => 'a list => 'a list"
    36   rev :: "'a list => 'a list"
    37   zip :: "'a list => 'b list => ('a * 'b) list"
    38   upt :: "nat => nat => nat list" ("(1[_..</_'])")
    39   remdups :: "'a list => 'a list"
    40   remove1 :: "'a => 'a list => 'a list"
    41   "distinct":: "'a list => bool"
    42   replicate :: "nat => 'a => 'a list"
    43   splice :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list"
    44 
    45 abbreviation
    46   upto:: "nat => nat => nat list"    ("(1[_../_])")
    47   "[i..j] == [i..<(Suc j)]"
    48 
    49 
    50 nonterminals lupdbinds lupdbind
    51 
    52 syntax
    53   -- {* list Enumeration *}
    54   "@list" :: "args => 'a list"    ("[(_)]")
    55 
    56   -- {* Special syntax for filter *}
    57   "@filter" :: "[pttrn, 'a list, bool] => 'a list"    ("(1[_:_./ _])")
    58 
    59   -- {* list update *}
    60   "_lupdbind":: "['a, 'a] => lupdbind"    ("(2_ :=/ _)")
    61   "" :: "lupdbind => lupdbinds"    ("_")
    62   "_lupdbinds" :: "[lupdbind, lupdbinds] => lupdbinds"    ("_,/ _")
    63   "_LUpdate" :: "['a, lupdbinds] => 'a"    ("_/[(_)]" [900,0] 900)
    64 
    65 translations
    66   "[x, xs]" == "x#[xs]"
    67   "[x]" == "x#[]"
    68   "[x:xs . P]"== "filter (%x. P) xs"
    69 
    70   "_LUpdate xs (_lupdbinds b bs)"== "_LUpdate (_LUpdate xs b) bs"
    71   "xs[i:=x]" == "list_update xs i x"
    72 
    73 
    74 syntax (xsymbols)
    75   "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    76 syntax (HTML output)
    77   "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    78 
    79 
    80 text {*
    81   Function @{text size} is overloaded for all datatypes. Users may
    82   refer to the list version as @{text length}. *}
    83 
    84 abbreviation
    85   length :: "'a list => nat"
    86   "length == size"
    87 
    88 primrec
    89   "hd(x#xs) = x"
    90 
    91 primrec
    92   "tl([]) = []"
    93   "tl(x#xs) = xs"
    94 
    95 primrec
    96   "last(x#xs) = (if xs=[] then x else last xs)"
    97 
    98 primrec
    99   "butlast []= []"
   100   "butlast(x#xs) = (if xs=[] then [] else x#butlast xs)"
   101 
   102 primrec
   103   "set [] = {}"
   104   "set (x#xs) = insert x (set xs)"
   105 
   106 primrec
   107   "map f [] = []"
   108   "map f (x#xs) = f(x)#map f xs"
   109 
   110 primrec
   111   append_Nil:"[]@ys = ys"
   112   append_Cons: "(x#xs)@ys = x#(xs@ys)"
   113 
   114 primrec
   115   "rev([]) = []"
   116   "rev(x#xs) = rev(xs) @ [x]"
   117 
   118 primrec
   119   "filter P [] = []"
   120   "filter P (x#xs) = (if P x then x#filter P xs else filter P xs)"
   121 
   122 primrec
   123   foldl_Nil:"foldl f a [] = a"
   124   foldl_Cons: "foldl f a (x#xs) = foldl f (f a x) xs"
   125 
   126 primrec
   127   "foldr f [] a = a"
   128   "foldr f (x#xs) a = f x (foldr f xs a)"
   129 
   130 primrec
   131   "concat([]) = []"
   132   "concat(x#xs) = x @ concat(xs)"
   133 
   134 primrec
   135   drop_Nil:"drop n [] = []"
   136   drop_Cons: "drop n (x#xs) = (case n of 0 => x#xs | Suc(m) => drop m xs)"
   137   -- {*Warning: simpset does not contain this definition, but separate
   138        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   139 
   140 primrec
   141   take_Nil:"take n [] = []"
   142   take_Cons: "take n (x#xs) = (case n of 0 => [] | Suc(m) => x # take m xs)"
   143   -- {*Warning: simpset does not contain this definition, but separate
   144        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   145 
   146 primrec
   147   nth_Cons:"(x#xs)!n = (case n of 0 => x | (Suc k) => xs!k)"
   148   -- {*Warning: simpset does not contain this definition, but separate
   149        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   150 
   151 primrec
   152   "[][i:=v] = []"
   153   "(x#xs)[i:=v] = (case i of 0 => v # xs | Suc j => x # xs[j:=v])"
   154 
   155 primrec
   156   "takeWhile P [] = []"
   157   "takeWhile P (x#xs) = (if P x then x#takeWhile P xs else [])"
   158 
   159 primrec
   160   "dropWhile P [] = []"
   161   "dropWhile P (x#xs) = (if P x then dropWhile P xs else x#xs)"
   162 
   163 primrec
   164   "zip xs [] = []"
   165   zip_Cons: "zip xs (y#ys) = (case xs of [] => [] | z#zs => (z,y)#zip zs ys)"
   166   -- {*Warning: simpset does not contain this definition, but separate
   167        theorems for @{text "xs = []"} and @{text "xs = z # zs"} *}
   168 
   169 primrec
   170   upt_0: "[i..<0] = []"
   171   upt_Suc: "[i..<(Suc j)] = (if i <= j then [i..<j] @ [j] else [])"
   172 
   173 primrec
   174   "distinct [] = True"
   175   "distinct (x#xs) = (x ~: set xs \<and> distinct xs)"
   176 
   177 primrec
   178   "remdups [] = []"
   179   "remdups (x#xs) = (if x : set xs then remdups xs else x # remdups xs)"
   180 
   181 primrec
   182   "remove1 x [] = []"
   183   "remove1 x (y#xs) = (if x=y then xs else y # remove1 x xs)"
   184 
   185 primrec
   186   replicate_0: "replicate 0 x = []"
   187   replicate_Suc: "replicate (Suc n) x = x # replicate n x"
   188 
   189 definition
   190   rotate1 :: "'a list \<Rightarrow> 'a list"
   191   rotate1_def: "rotate1 xs = (case xs of [] \<Rightarrow> [] | x#xs \<Rightarrow> xs @ [x])"
   192   rotate :: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list"
   193   rotate_def:  "rotate n = rotate1 ^ n"
   194   list_all2 :: "('a => 'b => bool) => 'a list => 'b list => bool"
   195   list_all2_def: "list_all2 P xs ys =
   196     (length xs = length ys \<and> (\<forall>(x, y) \<in> set (zip xs ys). P x y))"
   197   sublist :: "'a list => nat set => 'a list"
   198   sublist_def: "sublist xs A =
   199     map fst (filter (\<lambda>p. snd p \<in> A) (zip xs [0..<size xs]))"
   200 
   201 primrec
   202   "splice [] ys = ys"
   203   "splice (x#xs) ys = (if ys=[] then x#xs else x # hd ys # splice xs (tl ys))"
   204     -- {*Warning: simpset does not contain the second eqn but a derived one. *}
   205 
   206 
   207 subsubsection {* @{const Nil} and @{const Cons} *}
   208 
   209 lemma not_Cons_self [simp]:
   210   "xs \<noteq> x # xs"
   211 by (induct xs) auto
   212 
   213 lemmas not_Cons_self2 [simp] = not_Cons_self [symmetric]
   214 
   215 lemma neq_Nil_conv: "(xs \<noteq> []) = (\<exists>y ys. xs = y # ys)"
   216 by (induct xs) auto
   217 
   218 lemma length_induct:
   219   "(\<And>xs. \<forall>ys. length ys < length xs \<longrightarrow> P ys \<Longrightarrow> P xs) \<Longrightarrow> P xs"
   220 by (rule measure_induct [of length]) iprover
   221 
   222 
   223 subsubsection {* @{const length} *}
   224 
   225 text {*
   226   Needs to come before @{text "@"} because of theorem @{text
   227   append_eq_append_conv}.
   228 *}
   229 
   230 lemma length_append [simp]: "length (xs @ ys) = length xs + length ys"
   231 by (induct xs) auto
   232 
   233 lemma length_map [simp]: "length (map f xs) = length xs"
   234 by (induct xs) auto
   235 
   236 lemma length_rev [simp]: "length (rev xs) = length xs"
   237 by (induct xs) auto
   238 
   239 lemma length_tl [simp]: "length (tl xs) = length xs - 1"
   240 by (cases xs) auto
   241 
   242 lemma length_0_conv [iff]: "(length xs = 0) = (xs = [])"
   243 by (induct xs) auto
   244 
   245 lemma length_greater_0_conv [iff]: "(0 < length xs) = (xs \<noteq> [])"
   246 by (induct xs) auto
   247 
   248 lemma length_Suc_conv:
   249 "(length xs = Suc n) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   250 by (induct xs) auto
   251 
   252 lemma Suc_length_conv:
   253 "(Suc n = length xs) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   254 apply (induct xs, simp, simp)
   255 apply blast
   256 done
   257 
   258 lemma impossible_Cons [rule_format]: 
   259   "length xs <= length ys --> xs = x # ys = False"
   260 apply (induct xs)
   261 apply auto
   262 done
   263 
   264 lemma list_induct2[consumes 1]: "\<And>ys.
   265  \<lbrakk> length xs = length ys;
   266    P [] [];
   267    \<And>x xs y ys. \<lbrakk> length xs = length ys; P xs ys \<rbrakk> \<Longrightarrow> P (x#xs) (y#ys) \<rbrakk>
   268  \<Longrightarrow> P xs ys"
   269 apply(induct xs)
   270  apply simp
   271 apply(case_tac ys)
   272  apply simp
   273 apply(simp)
   274 done
   275 
   276 subsubsection {* @{text "@"} -- append *}
   277 
   278 lemma append_assoc [simp]: "(xs @ ys) @ zs = xs @ (ys @ zs)"
   279 by (induct xs) auto
   280 
   281 lemma append_Nil2 [simp]: "xs @ [] = xs"
   282 by (induct xs) auto
   283 
   284 lemma append_is_Nil_conv [iff]: "(xs @ ys = []) = (xs = [] \<and> ys = [])"
   285 by (induct xs) auto
   286 
   287 lemma Nil_is_append_conv [iff]: "([] = xs @ ys) = (xs = [] \<and> ys = [])"
   288 by (induct xs) auto
   289 
   290 lemma append_self_conv [iff]: "(xs @ ys = xs) = (ys = [])"
   291 by (induct xs) auto
   292 
   293 lemma self_append_conv [iff]: "(xs = xs @ ys) = (ys = [])"
   294 by (induct xs) auto
   295 
   296 lemma append_eq_append_conv [simp]:
   297  "!!ys. length xs = length ys \<or> length us = length vs
   298  ==> (xs@us = ys@vs) = (xs=ys \<and> us=vs)"
   299 apply (induct xs)
   300  apply (case_tac ys, simp, force)
   301 apply (case_tac ys, force, simp)
   302 done
   303 
   304 lemma append_eq_append_conv2: "!!ys zs ts.
   305  (xs @ ys = zs @ ts) =
   306  (EX us. xs = zs @ us & us @ ys = ts | xs @ us = zs & ys = us@ ts)"
   307 apply (induct xs)
   308  apply fastsimp
   309 apply(case_tac zs)
   310  apply simp
   311 apply fastsimp
   312 done
   313 
   314 lemma same_append_eq [iff]: "(xs @ ys = xs @ zs) = (ys = zs)"
   315 by simp
   316 
   317 lemma append1_eq_conv [iff]: "(xs @ [x] = ys @ [y]) = (xs = ys \<and> x = y)"
   318 by simp
   319 
   320 lemma append_same_eq [iff]: "(ys @ xs = zs @ xs) = (ys = zs)"
   321 by simp
   322 
   323 lemma append_self_conv2 [iff]: "(xs @ ys = ys) = (xs = [])"
   324 using append_same_eq [of _ _ "[]"] by auto
   325 
   326 lemma self_append_conv2 [iff]: "(ys = xs @ ys) = (xs = [])"
   327 using append_same_eq [of "[]"] by auto
   328 
   329 lemma hd_Cons_tl [simp]: "xs \<noteq> [] ==> hd xs # tl xs = xs"
   330 by (induct xs) auto
   331 
   332 lemma hd_append: "hd (xs @ ys) = (if xs = [] then hd ys else hd xs)"
   333 by (induct xs) auto
   334 
   335 lemma hd_append2 [simp]: "xs \<noteq> [] ==> hd (xs @ ys) = hd xs"
   336 by (simp add: hd_append split: list.split)
   337 
   338 lemma tl_append: "tl (xs @ ys) = (case xs of [] => tl ys | z#zs => zs @ ys)"
   339 by (simp split: list.split)
   340 
   341 lemma tl_append2 [simp]: "xs \<noteq> [] ==> tl (xs @ ys) = tl xs @ ys"
   342 by (simp add: tl_append split: list.split)
   343 
   344 
   345 lemma Cons_eq_append_conv: "x#xs = ys@zs =
   346  (ys = [] & x#xs = zs | (EX ys'. x#ys' = ys & xs = ys'@zs))"
   347 by(cases ys) auto
   348 
   349 lemma append_eq_Cons_conv: "(ys@zs = x#xs) =
   350  (ys = [] & zs = x#xs | (EX ys'. ys = x#ys' & ys'@zs = xs))"
   351 by(cases ys) auto
   352 
   353 
   354 text {* Trivial rules for solving @{text "@"}-equations automatically. *}
   355 
   356 lemma eq_Nil_appendI: "xs = ys ==> xs = [] @ ys"
   357 by simp
   358 
   359 lemma Cons_eq_appendI:
   360 "[| x # xs1 = ys; xs = xs1 @ zs |] ==> x # xs = ys @ zs"
   361 by (drule sym) simp
   362 
   363 lemma append_eq_appendI:
   364 "[| xs @ xs1 = zs; ys = xs1 @ us |] ==> xs @ ys = zs @ us"
   365 by (drule sym) simp
   366 
   367 
   368 text {*
   369 Simplification procedure for all list equalities.
   370 Currently only tries to rearrange @{text "@"} to see if
   371 - both lists end in a singleton list,
   372 - or both lists end in the same list.
   373 *}
   374 
   375 ML_setup {*
   376 local
   377 
   378 val append_assoc = thm "append_assoc";
   379 val append_Nil = thm "append_Nil";
   380 val append_Cons = thm "append_Cons";
   381 val append1_eq_conv = thm "append1_eq_conv";
   382 val append_same_eq = thm "append_same_eq";
   383 
   384 fun last (cons as Const("List.list.Cons",_) $ _ $ xs) =
   385   (case xs of Const("List.list.Nil",_) => cons | _ => last xs)
   386   | last (Const("List.op @",_) $ _ $ ys) = last ys
   387   | last t = t;
   388 
   389 fun list1 (Const("List.list.Cons",_) $ _ $ Const("List.list.Nil",_)) = true
   390   | list1 _ = false;
   391 
   392 fun butlast ((cons as Const("List.list.Cons",_) $ x) $ xs) =
   393   (case xs of Const("List.list.Nil",_) => xs | _ => cons $ butlast xs)
   394   | butlast ((app as Const("List.op @",_) $ xs) $ ys) = app $ butlast ys
   395   | butlast xs = Const("List.list.Nil",fastype_of xs);
   396 
   397 val rearr_ss = HOL_basic_ss addsimps [append_assoc, append_Nil, append_Cons];
   398 
   399 fun list_eq ss (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   400   let
   401     val lastl = last lhs and lastr = last rhs;
   402     fun rearr conv =
   403       let
   404         val lhs1 = butlast lhs and rhs1 = butlast rhs;
   405         val Type(_,listT::_) = eqT
   406         val appT = [listT,listT] ---> listT
   407         val app = Const("List.op @",appT)
   408         val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   409         val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (F,F2));
   410         val thm = Goal.prove (Simplifier.the_context ss) [] [] eq
   411           (K (simp_tac (Simplifier.inherit_context ss rearr_ss) 1));
   412       in SOME ((conv RS (thm RS trans)) RS eq_reflection) end;
   413 
   414   in
   415     if list1 lastl andalso list1 lastr then rearr append1_eq_conv
   416     else if lastl aconv lastr then rearr append_same_eq
   417     else NONE
   418   end;
   419 
   420 in
   421 
   422 val list_eq_simproc =
   423   Simplifier.simproc (the_context ()) "list_eq" ["(xs::'a list) = ys"] (K list_eq);
   424 
   425 end;
   426 
   427 Addsimprocs [list_eq_simproc];
   428 *}
   429 
   430 
   431 subsubsection {* @{text map} *}
   432 
   433 lemma map_ext: "(!!x. x : set xs --> f x = g x) ==> map f xs = map g xs"
   434 by (induct xs) simp_all
   435 
   436 lemma map_ident [simp]: "map (\<lambda>x. x) = (\<lambda>xs. xs)"
   437 by (rule ext, induct_tac xs) auto
   438 
   439 lemma map_append [simp]: "map f (xs @ ys) = map f xs @ map f ys"
   440 by (induct xs) auto
   441 
   442 lemma map_compose: "map (f o g) xs = map f (map g xs)"
   443 by (induct xs) (auto simp add: o_def)
   444 
   445 lemma rev_map: "rev (map f xs) = map f (rev xs)"
   446 by (induct xs) auto
   447 
   448 lemma map_eq_conv[simp]: "(map f xs = map g xs) = (!x : set xs. f x = g x)"
   449 by (induct xs) auto
   450 
   451 lemma map_cong [fundef_cong, recdef_cong]:
   452 "xs = ys ==> (!!x. x : set ys ==> f x = g x) ==> map f xs = map g ys"
   453 -- {* a congruence rule for @{text map} *}
   454 by simp
   455 
   456 lemma map_is_Nil_conv [iff]: "(map f xs = []) = (xs = [])"
   457 by (cases xs) auto
   458 
   459 lemma Nil_is_map_conv [iff]: "([] = map f xs) = (xs = [])"
   460 by (cases xs) auto
   461 
   462 lemma map_eq_Cons_conv:
   463  "(map f xs = y#ys) = (\<exists>z zs. xs = z#zs \<and> f z = y \<and> map f zs = ys)"
   464 by (cases xs) auto
   465 
   466 lemma Cons_eq_map_conv:
   467  "(x#xs = map f ys) = (\<exists>z zs. ys = z#zs \<and> x = f z \<and> xs = map f zs)"
   468 by (cases ys) auto
   469 
   470 lemmas map_eq_Cons_D = map_eq_Cons_conv [THEN iffD1]
   471 lemmas Cons_eq_map_D = Cons_eq_map_conv [THEN iffD1]
   472 declare map_eq_Cons_D [dest!]  Cons_eq_map_D [dest!]
   473 
   474 lemma ex_map_conv:
   475   "(EX xs. ys = map f xs) = (ALL y : set ys. EX x. y = f x)"
   476 by(induct ys, auto simp add: Cons_eq_map_conv)
   477 
   478 lemma map_eq_imp_length_eq:
   479   "!!xs. map f xs = map f ys ==> length xs = length ys"
   480 apply (induct ys)
   481  apply simp
   482 apply(simp (no_asm_use))
   483 apply clarify
   484 apply(simp (no_asm_use))
   485 apply fast
   486 done
   487 
   488 lemma map_inj_on:
   489  "[| map f xs = map f ys; inj_on f (set xs Un set ys) |]
   490   ==> xs = ys"
   491 apply(frule map_eq_imp_length_eq)
   492 apply(rotate_tac -1)
   493 apply(induct rule:list_induct2)
   494  apply simp
   495 apply(simp)
   496 apply (blast intro:sym)
   497 done
   498 
   499 lemma inj_on_map_eq_map:
   500  "inj_on f (set xs Un set ys) \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   501 by(blast dest:map_inj_on)
   502 
   503 lemma map_injective:
   504  "!!xs. map f xs = map f ys ==> inj f ==> xs = ys"
   505 by (induct ys) (auto dest!:injD)
   506 
   507 lemma inj_map_eq_map[simp]: "inj f \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   508 by(blast dest:map_injective)
   509 
   510 lemma inj_mapI: "inj f ==> inj (map f)"
   511 by (iprover dest: map_injective injD intro: inj_onI)
   512 
   513 lemma inj_mapD: "inj (map f) ==> inj f"
   514 apply (unfold inj_on_def, clarify)
   515 apply (erule_tac x = "[x]" in ballE)
   516  apply (erule_tac x = "[y]" in ballE, simp, blast)
   517 apply blast
   518 done
   519 
   520 lemma inj_map[iff]: "inj (map f) = inj f"
   521 by (blast dest: inj_mapD intro: inj_mapI)
   522 
   523 lemma inj_on_mapI: "inj_on f (\<Union>(set ` A)) \<Longrightarrow> inj_on (map f) A"
   524 apply(rule inj_onI)
   525 apply(erule map_inj_on)
   526 apply(blast intro:inj_onI dest:inj_onD)
   527 done
   528 
   529 lemma map_idI: "(\<And>x. x \<in> set xs \<Longrightarrow> f x = x) \<Longrightarrow> map f xs = xs"
   530 by (induct xs, auto)
   531 
   532 lemma map_fun_upd [simp]: "y \<notin> set xs \<Longrightarrow> map (f(y:=v)) xs = map f xs"
   533 by (induct xs) auto
   534 
   535 lemma map_fst_zip[simp]:
   536   "length xs = length ys \<Longrightarrow> map fst (zip xs ys) = xs"
   537 by (induct rule:list_induct2, simp_all)
   538 
   539 lemma map_snd_zip[simp]:
   540   "length xs = length ys \<Longrightarrow> map snd (zip xs ys) = ys"
   541 by (induct rule:list_induct2, simp_all)
   542 
   543 
   544 subsubsection {* @{text rev} *}
   545 
   546 lemma rev_append [simp]: "rev (xs @ ys) = rev ys @ rev xs"
   547 by (induct xs) auto
   548 
   549 lemma rev_rev_ident [simp]: "rev (rev xs) = xs"
   550 by (induct xs) auto
   551 
   552 lemma rev_swap: "(rev xs = ys) = (xs = rev ys)"
   553 by auto
   554 
   555 lemma rev_is_Nil_conv [iff]: "(rev xs = []) = (xs = [])"
   556 by (induct xs) auto
   557 
   558 lemma Nil_is_rev_conv [iff]: "([] = rev xs) = (xs = [])"
   559 by (induct xs) auto
   560 
   561 lemma rev_singleton_conv [simp]: "(rev xs = [x]) = (xs = [x])"
   562 by (cases xs) auto
   563 
   564 lemma singleton_rev_conv [simp]: "([x] = rev xs) = (xs = [x])"
   565 by (cases xs) auto
   566 
   567 lemma rev_is_rev_conv [iff]: "(rev xs = rev ys) = (xs = ys)"
   568 apply (induct xs arbitrary: ys, force)
   569 apply (case_tac ys, simp, force)
   570 done
   571 
   572 lemma inj_on_rev[iff]: "inj_on rev A"
   573 by(simp add:inj_on_def)
   574 
   575 lemma rev_induct [case_names Nil snoc]:
   576   "[| P []; !!x xs. P xs ==> P (xs @ [x]) |] ==> P xs"
   577 apply(simplesubst rev_rev_ident[symmetric])
   578 apply(rule_tac list = "rev xs" in list.induct, simp_all)
   579 done
   580 
   581 ML {* val rev_induct_tac = induct_thm_tac (thm "rev_induct") *}-- "compatibility"
   582 
   583 lemma rev_exhaust [case_names Nil snoc]:
   584   "(xs = [] ==> P) ==>(!!ys y. xs = ys @ [y] ==> P) ==> P"
   585 by (induct xs rule: rev_induct) auto
   586 
   587 lemmas rev_cases = rev_exhaust
   588 
   589 lemma rev_eq_Cons_iff[iff]: "(rev xs = y#ys) = (xs = rev ys @ [y])"
   590 by(rule rev_cases[of xs]) auto
   591 
   592 
   593 subsubsection {* @{text set} *}
   594 
   595 lemma finite_set [iff]: "finite (set xs)"
   596 by (induct xs) auto
   597 
   598 lemma set_append [simp]: "set (xs @ ys) = (set xs \<union> set ys)"
   599 by (induct xs) auto
   600 
   601 lemma hd_in_set[simp]: "xs \<noteq> [] \<Longrightarrow> hd xs : set xs"
   602 by(cases xs) auto
   603 
   604 lemma set_subset_Cons: "set xs \<subseteq> set (x # xs)"
   605 by auto
   606 
   607 lemma set_ConsD: "y \<in> set (x # xs) \<Longrightarrow> y=x \<or> y \<in> set xs" 
   608 by auto
   609 
   610 lemma set_empty [iff]: "(set xs = {}) = (xs = [])"
   611 by (induct xs) auto
   612 
   613 lemma set_empty2[iff]: "({} = set xs) = (xs = [])"
   614 by(induct xs) auto
   615 
   616 lemma set_rev [simp]: "set (rev xs) = set xs"
   617 by (induct xs) auto
   618 
   619 lemma set_map [simp]: "set (map f xs) = f`(set xs)"
   620 by (induct xs) auto
   621 
   622 lemma set_filter [simp]: "set (filter P xs) = {x. x : set xs \<and> P x}"
   623 by (induct xs) auto
   624 
   625 lemma set_upt [simp]: "set[i..<j] = {k. i \<le> k \<and> k < j}"
   626 apply (induct j, simp_all)
   627 apply (erule ssubst, auto)
   628 done
   629 
   630 lemma in_set_conv_decomp: "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs)"
   631 proof (induct xs)
   632   case Nil show ?case by simp
   633   case (Cons a xs)
   634   show ?case
   635   proof 
   636     assume "x \<in> set (a # xs)"
   637     with prems show "\<exists>ys zs. a # xs = ys @ x # zs"
   638       by (simp, blast intro: Cons_eq_appendI)
   639   next
   640     assume "\<exists>ys zs. a # xs = ys @ x # zs"
   641     then obtain ys zs where eq: "a # xs = ys @ x # zs" by blast
   642     show "x \<in> set (a # xs)" 
   643       by (cases ys, auto simp add: eq)
   644   qed
   645 qed
   646 
   647 lemma in_set_conv_decomp_first:
   648  "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs \<and> x \<notin> set ys)"
   649 proof (induct xs)
   650   case Nil show ?case by simp
   651 next
   652   case (Cons a xs)
   653   show ?case
   654   proof cases
   655     assume "x = a" thus ?case using Cons by force
   656   next
   657     assume "x \<noteq> a"
   658     show ?case
   659     proof
   660       assume "x \<in> set (a # xs)"
   661       from prems show "\<exists>ys zs. a # xs = ys @ x # zs \<and> x \<notin> set ys"
   662 	by(fastsimp intro!: Cons_eq_appendI)
   663     next
   664       assume "\<exists>ys zs. a # xs = ys @ x # zs \<and> x \<notin> set ys"
   665       then obtain ys zs where eq: "a # xs = ys @ x # zs" by blast
   666       show "x \<in> set (a # xs)" by (cases ys, auto simp add: eq)
   667     qed
   668   qed
   669 qed
   670 
   671 lemmas split_list       = in_set_conv_decomp[THEN iffD1, standard]
   672 lemmas split_list_first = in_set_conv_decomp_first[THEN iffD1, standard]
   673 
   674 
   675 lemma finite_list: "finite A ==> EX l. set l = A"
   676 apply (erule finite_induct, auto)
   677 apply (rule_tac x="x#l" in exI, auto)
   678 done
   679 
   680 lemma card_length: "card (set xs) \<le> length xs"
   681 by (induct xs) (auto simp add: card_insert_if)
   682 
   683 
   684 subsubsection {* @{text filter} *}
   685 
   686 lemma filter_append [simp]: "filter P (xs @ ys) = filter P xs @ filter P ys"
   687 by (induct xs) auto
   688 
   689 lemma rev_filter: "rev (filter P xs) = filter P (rev xs)"
   690 by (induct xs) simp_all
   691 
   692 lemma filter_filter [simp]: "filter P (filter Q xs) = filter (\<lambda>x. Q x \<and> P x) xs"
   693 by (induct xs) auto
   694 
   695 lemma length_filter_le [simp]: "length (filter P xs) \<le> length xs"
   696 by (induct xs) (auto simp add: le_SucI)
   697 
   698 lemma sum_length_filter_compl:
   699   "length(filter P xs) + length(filter (%x. ~P x) xs) = length xs"
   700 by(induct xs) simp_all
   701 
   702 lemma filter_True [simp]: "\<forall>x \<in> set xs. P x ==> filter P xs = xs"
   703 by (induct xs) auto
   704 
   705 lemma filter_False [simp]: "\<forall>x \<in> set xs. \<not> P x ==> filter P xs = []"
   706 by (induct xs) auto
   707 
   708 lemma filter_empty_conv: "(filter P xs = []) = (\<forall>x\<in>set xs. \<not> P x)" 
   709   by (induct xs) simp_all
   710 
   711 lemma filter_id_conv: "(filter P xs = xs) = (\<forall>x\<in>set xs. P x)"
   712 apply (induct xs)
   713  apply auto
   714 apply(cut_tac P=P and xs=xs in length_filter_le)
   715 apply simp
   716 done
   717 
   718 lemma filter_map:
   719   "filter P (map f xs) = map f (filter (P o f) xs)"
   720 by (induct xs) simp_all
   721 
   722 lemma length_filter_map[simp]:
   723   "length (filter P (map f xs)) = length(filter (P o f) xs)"
   724 by (simp add:filter_map)
   725 
   726 lemma filter_is_subset [simp]: "set (filter P xs) \<le> set xs"
   727 by auto
   728 
   729 lemma length_filter_less:
   730   "\<lbrakk> x : set xs; ~ P x \<rbrakk> \<Longrightarrow> length(filter P xs) < length xs"
   731 proof (induct xs)
   732   case Nil thus ?case by simp
   733 next
   734   case (Cons x xs) thus ?case
   735     apply (auto split:split_if_asm)
   736     using length_filter_le[of P xs] apply arith
   737   done
   738 qed
   739 
   740 lemma length_filter_conv_card:
   741  "length(filter p xs) = card{i. i < length xs & p(xs!i)}"
   742 proof (induct xs)
   743   case Nil thus ?case by simp
   744 next
   745   case (Cons x xs)
   746   let ?S = "{i. i < length xs & p(xs!i)}"
   747   have fin: "finite ?S" by(fast intro: bounded_nat_set_is_finite)
   748   show ?case (is "?l = card ?S'")
   749   proof (cases)
   750     assume "p x"
   751     hence eq: "?S' = insert 0 (Suc ` ?S)"
   752       by(auto simp add: nth_Cons image_def split:nat.split elim:lessE)
   753     have "length (filter p (x # xs)) = Suc(card ?S)"
   754       using Cons by simp
   755     also have "\<dots> = Suc(card(Suc ` ?S))" using fin
   756       by (simp add: card_image inj_Suc)
   757     also have "\<dots> = card ?S'" using eq fin
   758       by (simp add:card_insert_if) (simp add:image_def)
   759     finally show ?thesis .
   760   next
   761     assume "\<not> p x"
   762     hence eq: "?S' = Suc ` ?S"
   763       by(auto simp add: nth_Cons image_def split:nat.split elim:lessE)
   764     have "length (filter p (x # xs)) = card ?S"
   765       using Cons by simp
   766     also have "\<dots> = card(Suc ` ?S)" using fin
   767       by (simp add: card_image inj_Suc)
   768     also have "\<dots> = card ?S'" using eq fin
   769       by (simp add:card_insert_if)
   770     finally show ?thesis .
   771   qed
   772 qed
   773 
   774 lemma Cons_eq_filterD:
   775  "x#xs = filter P ys \<Longrightarrow>
   776   \<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs"
   777   (is "_ \<Longrightarrow> \<exists>us vs. ?P ys us vs")
   778 proof(induct ys)
   779   case Nil thus ?case by simp
   780 next
   781   case (Cons y ys)
   782   show ?case (is "\<exists>x. ?Q x")
   783   proof cases
   784     assume Py: "P y"
   785     show ?thesis
   786     proof cases
   787       assume xy: "x = y"
   788       show ?thesis
   789       proof from Py xy Cons(2) show "?Q []" by simp qed
   790     next
   791       assume "x \<noteq> y" with Py Cons(2) show ?thesis by simp
   792     qed
   793   next
   794     assume Py: "\<not> P y"
   795     with Cons obtain us vs where 1 : "?P (y#ys) (y#us) vs" by fastsimp
   796     show ?thesis (is "? us. ?Q us")
   797     proof show "?Q (y#us)" using 1 by simp qed
   798   qed
   799 qed
   800 
   801 lemma filter_eq_ConsD:
   802  "filter P ys = x#xs \<Longrightarrow>
   803   \<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs"
   804 by(rule Cons_eq_filterD) simp
   805 
   806 lemma filter_eq_Cons_iff:
   807  "(filter P ys = x#xs) =
   808   (\<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs)"
   809 by(auto dest:filter_eq_ConsD)
   810 
   811 lemma Cons_eq_filter_iff:
   812  "(x#xs = filter P ys) =
   813   (\<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs)"
   814 by(auto dest:Cons_eq_filterD)
   815 
   816 lemma filter_cong[fundef_cong, recdef_cong]:
   817  "xs = ys \<Longrightarrow> (\<And>x. x \<in> set ys \<Longrightarrow> P x = Q x) \<Longrightarrow> filter P xs = filter Q ys"
   818 apply simp
   819 apply(erule thin_rl)
   820 by (induct ys) simp_all
   821 
   822 
   823 subsubsection {* @{text concat} *}
   824 
   825 lemma concat_append [simp]: "concat (xs @ ys) = concat xs @ concat ys"
   826 by (induct xs) auto
   827 
   828 lemma concat_eq_Nil_conv [simp]: "(concat xss = []) = (\<forall>xs \<in> set xss. xs = [])"
   829 by (induct xss) auto
   830 
   831 lemma Nil_eq_concat_conv [simp]: "([] = concat xss) = (\<forall>xs \<in> set xss. xs = [])"
   832 by (induct xss) auto
   833 
   834 lemma set_concat [simp]: "set (concat xs) = \<Union>(set ` set xs)"
   835 by (induct xs) auto
   836 
   837 lemma map_concat: "map f (concat xs) = concat (map (map f) xs)"
   838 by (induct xs) auto
   839 
   840 lemma filter_concat: "filter p (concat xs) = concat (map (filter p) xs)"
   841 by (induct xs) auto
   842 
   843 lemma rev_concat: "rev (concat xs) = concat (map rev (rev xs))"
   844 by (induct xs) auto
   845 
   846 
   847 subsubsection {* @{text nth} *}
   848 
   849 lemma nth_Cons_0 [simp]: "(x # xs)!0 = x"
   850 by auto
   851 
   852 lemma nth_Cons_Suc [simp]: "(x # xs)!(Suc n) = xs!n"
   853 by auto
   854 
   855 declare nth.simps [simp del]
   856 
   857 lemma nth_append:
   858 "!!n. (xs @ ys)!n = (if n < length xs then xs!n else ys!(n - length xs))"
   859 apply (induct "xs", simp)
   860 apply (case_tac n, auto)
   861 done
   862 
   863 lemma nth_append_length [simp]: "(xs @ x # ys) ! length xs = x"
   864 by (induct "xs") auto
   865 
   866 lemma nth_append_length_plus[simp]: "(xs @ ys) ! (length xs + n) = ys ! n"
   867 by (induct "xs") auto
   868 
   869 lemma nth_map [simp]: "!!n. n < length xs ==> (map f xs)!n = f(xs!n)"
   870 apply (induct xs, simp)
   871 apply (case_tac n, auto)
   872 done
   873 
   874 lemma hd_conv_nth: "xs \<noteq> [] \<Longrightarrow> hd xs = xs!0"
   875 by(cases xs) simp_all
   876 
   877 
   878 lemma list_eq_iff_nth_eq:
   879  "!!ys. (xs = ys) = (length xs = length ys \<and> (ALL i<length xs. xs!i = ys!i))"
   880 apply(induct xs)
   881  apply simp apply blast
   882 apply(case_tac ys)
   883  apply simp
   884 apply(simp add:nth_Cons split:nat.split)apply blast
   885 done
   886 
   887 lemma set_conv_nth: "set xs = {xs!i | i. i < length xs}"
   888 apply (induct xs, simp, simp)
   889 apply safe
   890 apply (rule_tac x = 0 in exI, simp)
   891  apply (rule_tac x = "Suc i" in exI, simp)
   892 apply (case_tac i, simp)
   893 apply (rename_tac j)
   894 apply (rule_tac x = j in exI, simp)
   895 done
   896 
   897 lemma in_set_conv_nth: "(x \<in> set xs) = (\<exists>i < length xs. xs!i = x)"
   898 by(auto simp:set_conv_nth)
   899 
   900 lemma list_ball_nth: "[| n < length xs; !x : set xs. P x|] ==> P(xs!n)"
   901 by (auto simp add: set_conv_nth)
   902 
   903 lemma nth_mem [simp]: "n < length xs ==> xs!n : set xs"
   904 by (auto simp add: set_conv_nth)
   905 
   906 lemma all_nth_imp_all_set:
   907 "[| !i < length xs. P(xs!i); x : set xs|] ==> P x"
   908 by (auto simp add: set_conv_nth)
   909 
   910 lemma all_set_conv_all_nth:
   911 "(\<forall>x \<in> set xs. P x) = (\<forall>i. i < length xs --> P (xs ! i))"
   912 by (auto simp add: set_conv_nth)
   913 
   914 
   915 subsubsection {* @{text list_update} *}
   916 
   917 lemma length_list_update [simp]: "!!i. length(xs[i:=x]) = length xs"
   918 by (induct xs) (auto split: nat.split)
   919 
   920 lemma nth_list_update:
   921 "!!i j. i < length xs==> (xs[i:=x])!j = (if i = j then x else xs!j)"
   922 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   923 
   924 lemma nth_list_update_eq [simp]: "i < length xs ==> (xs[i:=x])!i = x"
   925 by (simp add: nth_list_update)
   926 
   927 lemma nth_list_update_neq [simp]: "!!i j. i \<noteq> j ==> xs[i:=x]!j = xs!j"
   928 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   929 
   930 lemma list_update_overwrite [simp]:
   931 "!!i. i < size xs ==> xs[i:=x, i:=y] = xs[i:=y]"
   932 by (induct xs) (auto split: nat.split)
   933 
   934 lemma list_update_id[simp]: "!!i. i < length xs ==> xs[i := xs!i] = xs"
   935 apply (induct xs, simp)
   936 apply(simp split:nat.splits)
   937 done
   938 
   939 lemma list_update_beyond[simp]: "\<And>i. length xs \<le> i \<Longrightarrow> xs[i:=x] = xs"
   940 apply (induct xs)
   941  apply simp
   942 apply (case_tac i)
   943 apply simp_all
   944 done
   945 
   946 lemma list_update_same_conv:
   947 "!!i. i < length xs ==> (xs[i := x] = xs) = (xs!i = x)"
   948 by (induct xs) (auto split: nat.split)
   949 
   950 lemma list_update_append1:
   951  "!!i. i < size xs \<Longrightarrow> (xs @ ys)[i:=x] = xs[i:=x] @ ys"
   952 apply (induct xs, simp)
   953 apply(simp split:nat.split)
   954 done
   955 
   956 lemma list_update_append:
   957   "!!n. (xs @ ys) [n:= x] = 
   958   (if n < length xs then xs[n:= x] @ ys else xs @ (ys [n-length xs:= x]))"
   959 by (induct xs) (auto split:nat.splits)
   960 
   961 lemma list_update_length [simp]:
   962  "(xs @ x # ys)[length xs := y] = (xs @ y # ys)"
   963 by (induct xs, auto)
   964 
   965 lemma update_zip:
   966 "!!i xy xs. length xs = length ys ==>
   967 (zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])"
   968 by (induct ys) (auto, case_tac xs, auto split: nat.split)
   969 
   970 lemma set_update_subset_insert: "!!i. set(xs[i:=x]) <= insert x (set xs)"
   971 by (induct xs) (auto split: nat.split)
   972 
   973 lemma set_update_subsetI: "[| set xs <= A; x:A |] ==> set(xs[i := x]) <= A"
   974 by (blast dest!: set_update_subset_insert [THEN subsetD])
   975 
   976 lemma set_update_memI: "!!n. n < length xs \<Longrightarrow> x \<in> set (xs[n := x])"
   977 by (induct xs) (auto split:nat.splits)
   978 
   979 
   980 subsubsection {* @{text last} and @{text butlast} *}
   981 
   982 lemma last_snoc [simp]: "last (xs @ [x]) = x"
   983 by (induct xs) auto
   984 
   985 lemma butlast_snoc [simp]: "butlast (xs @ [x]) = xs"
   986 by (induct xs) auto
   987 
   988 lemma last_ConsL: "xs = [] \<Longrightarrow> last(x#xs) = x"
   989 by(simp add:last.simps)
   990 
   991 lemma last_ConsR: "xs \<noteq> [] \<Longrightarrow> last(x#xs) = last xs"
   992 by(simp add:last.simps)
   993 
   994 lemma last_append: "last(xs @ ys) = (if ys = [] then last xs else last ys)"
   995 by (induct xs) (auto)
   996 
   997 lemma last_appendL[simp]: "ys = [] \<Longrightarrow> last(xs @ ys) = last xs"
   998 by(simp add:last_append)
   999 
  1000 lemma last_appendR[simp]: "ys \<noteq> [] \<Longrightarrow> last(xs @ ys) = last ys"
  1001 by(simp add:last_append)
  1002 
  1003 lemma hd_rev: "xs \<noteq> [] \<Longrightarrow> hd(rev xs) = last xs"
  1004 by(rule rev_exhaust[of xs]) simp_all
  1005 
  1006 lemma last_rev: "xs \<noteq> [] \<Longrightarrow> last(rev xs) = hd xs"
  1007 by(cases xs) simp_all
  1008 
  1009 lemma last_in_set[simp]: "as \<noteq> [] \<Longrightarrow> last as \<in> set as"
  1010 by (induct as) auto
  1011 
  1012 lemma length_butlast [simp]: "length (butlast xs) = length xs - 1"
  1013 by (induct xs rule: rev_induct) auto
  1014 
  1015 lemma butlast_append:
  1016 "!!ys. butlast (xs @ ys) = (if ys = [] then butlast xs else xs @ butlast ys)"
  1017 by (induct xs) auto
  1018 
  1019 lemma append_butlast_last_id [simp]:
  1020 "xs \<noteq> [] ==> butlast xs @ [last xs] = xs"
  1021 by (induct xs) auto
  1022 
  1023 lemma in_set_butlastD: "x : set (butlast xs) ==> x : set xs"
  1024 by (induct xs) (auto split: split_if_asm)
  1025 
  1026 lemma in_set_butlast_appendI:
  1027 "x : set (butlast xs) | x : set (butlast ys) ==> x : set (butlast (xs @ ys))"
  1028 by (auto dest: in_set_butlastD simp add: butlast_append)
  1029 
  1030 lemma last_drop[simp]: "!!n. n < length xs \<Longrightarrow> last (drop n xs) = last xs"
  1031 apply (induct xs)
  1032  apply simp
  1033 apply (auto split:nat.split)
  1034 done
  1035 
  1036 lemma last_conv_nth: "xs\<noteq>[] \<Longrightarrow> last xs = xs!(length xs - 1)"
  1037 by(induct xs)(auto simp:neq_Nil_conv)
  1038 
  1039 subsubsection {* @{text take} and @{text drop} *}
  1040 
  1041 lemma take_0 [simp]: "take 0 xs = []"
  1042 by (induct xs) auto
  1043 
  1044 lemma drop_0 [simp]: "drop 0 xs = xs"
  1045 by (induct xs) auto
  1046 
  1047 lemma take_Suc_Cons [simp]: "take (Suc n) (x # xs) = x # take n xs"
  1048 by simp
  1049 
  1050 lemma drop_Suc_Cons [simp]: "drop (Suc n) (x # xs) = drop n xs"
  1051 by simp
  1052 
  1053 declare take_Cons [simp del] and drop_Cons [simp del]
  1054 
  1055 lemma take_Suc: "xs ~= [] ==> take (Suc n) xs = hd xs # take n (tl xs)"
  1056 by(clarsimp simp add:neq_Nil_conv)
  1057 
  1058 lemma drop_Suc: "drop (Suc n) xs = drop n (tl xs)"
  1059 by(cases xs, simp_all)
  1060 
  1061 lemma drop_tl: "!!n. drop n (tl xs) = tl(drop n xs)"
  1062 by(induct xs, simp_all add:drop_Cons drop_Suc split:nat.split)
  1063 
  1064 lemma nth_via_drop: "!!n. drop n xs = y#ys \<Longrightarrow> xs!n = y"
  1065 apply (induct xs, simp)
  1066 apply(simp add:drop_Cons nth_Cons split:nat.splits)
  1067 done
  1068 
  1069 lemma take_Suc_conv_app_nth:
  1070  "!!i. i < length xs \<Longrightarrow> take (Suc i) xs = take i xs @ [xs!i]"
  1071 apply (induct xs, simp)
  1072 apply (case_tac i, auto)
  1073 done
  1074 
  1075 lemma drop_Suc_conv_tl:
  1076   "!!i. i < length xs \<Longrightarrow> (xs!i) # (drop (Suc i) xs) = drop i xs"
  1077 apply (induct xs, simp)
  1078 apply (case_tac i, auto)
  1079 done
  1080 
  1081 lemma length_take [simp]: "!!xs. length (take n xs) = min (length xs) n"
  1082 by (induct n) (auto, case_tac xs, auto)
  1083 
  1084 lemma length_drop [simp]: "!!xs. length (drop n xs) = (length xs - n)"
  1085 by (induct n) (auto, case_tac xs, auto)
  1086 
  1087 lemma take_all [simp]: "!!xs. length xs <= n ==> take n xs = xs"
  1088 by (induct n) (auto, case_tac xs, auto)
  1089 
  1090 lemma drop_all [simp]: "!!xs. length xs <= n ==> drop n xs = []"
  1091 by (induct n) (auto, case_tac xs, auto)
  1092 
  1093 lemma take_append [simp]:
  1094 "!!xs. take n (xs @ ys) = (take n xs @ take (n - length xs) ys)"
  1095 by (induct n) (auto, case_tac xs, auto)
  1096 
  1097 lemma drop_append [simp]:
  1098 "!!xs. drop n (xs @ ys) = drop n xs @ drop (n - length xs) ys"
  1099 by (induct n) (auto, case_tac xs, auto)
  1100 
  1101 lemma take_take [simp]: "!!xs n. take n (take m xs) = take (min n m) xs"
  1102 apply (induct m, auto)
  1103 apply (case_tac xs, auto)
  1104 apply (case_tac n, auto)
  1105 done
  1106 
  1107 lemma drop_drop [simp]: "!!xs. drop n (drop m xs) = drop (n + m) xs"
  1108 apply (induct m, auto)
  1109 apply (case_tac xs, auto)
  1110 done
  1111 
  1112 lemma take_drop: "!!xs n. take n (drop m xs) = drop m (take (n + m) xs)"
  1113 apply (induct m, auto)
  1114 apply (case_tac xs, auto)
  1115 done
  1116 
  1117 lemma drop_take: "!!m n. drop n (take m xs) = take (m-n) (drop n xs)"
  1118 apply(induct xs)
  1119  apply simp
  1120 apply(simp add: take_Cons drop_Cons split:nat.split)
  1121 done
  1122 
  1123 lemma append_take_drop_id [simp]: "!!xs. take n xs @ drop n xs = xs"
  1124 apply (induct n, auto)
  1125 apply (case_tac xs, auto)
  1126 done
  1127 
  1128 lemma take_eq_Nil[simp]: "!!n. (take n xs = []) = (n = 0 \<or> xs = [])"
  1129 apply(induct xs)
  1130  apply simp
  1131 apply(simp add:take_Cons split:nat.split)
  1132 done
  1133 
  1134 lemma drop_eq_Nil[simp]: "!!n. (drop n xs = []) = (length xs <= n)"
  1135 apply(induct xs)
  1136 apply simp
  1137 apply(simp add:drop_Cons split:nat.split)
  1138 done
  1139 
  1140 lemma take_map: "!!xs. take n (map f xs) = map f (take n xs)"
  1141 apply (induct n, auto)
  1142 apply (case_tac xs, auto)
  1143 done
  1144 
  1145 lemma drop_map: "!!xs. drop n (map f xs) = map f (drop n xs)"
  1146 apply (induct n, auto)
  1147 apply (case_tac xs, auto)
  1148 done
  1149 
  1150 lemma rev_take: "!!i. rev (take i xs) = drop (length xs - i) (rev xs)"
  1151 apply (induct xs, auto)
  1152 apply (case_tac i, auto)
  1153 done
  1154 
  1155 lemma rev_drop: "!!i. rev (drop i xs) = take (length xs - i) (rev xs)"
  1156 apply (induct xs, auto)
  1157 apply (case_tac i, auto)
  1158 done
  1159 
  1160 lemma nth_take [simp]: "!!n i. i < n ==> (take n xs)!i = xs!i"
  1161 apply (induct xs, auto)
  1162 apply (case_tac n, blast)
  1163 apply (case_tac i, auto)
  1164 done
  1165 
  1166 lemma nth_drop [simp]:
  1167 "!!xs i. n + i <= length xs ==> (drop n xs)!i = xs!(n + i)"
  1168 apply (induct n, auto)
  1169 apply (case_tac xs, auto)
  1170 done
  1171 
  1172 lemma hd_drop_conv_nth: "\<lbrakk> xs \<noteq> []; n < length xs \<rbrakk> \<Longrightarrow> hd(drop n xs) = xs!n"
  1173 by(simp add: hd_conv_nth)
  1174 
  1175 lemma set_take_subset: "\<And>n. set(take n xs) \<subseteq> set xs"
  1176 by(induct xs)(auto simp:take_Cons split:nat.split)
  1177 
  1178 lemma set_drop_subset: "\<And>n. set(drop n xs) \<subseteq> set xs"
  1179 by(induct xs)(auto simp:drop_Cons split:nat.split)
  1180 
  1181 lemma in_set_takeD: "x : set(take n xs) \<Longrightarrow> x : set xs"
  1182 using set_take_subset by fast
  1183 
  1184 lemma in_set_dropD: "x : set(drop n xs) \<Longrightarrow> x : set xs"
  1185 using set_drop_subset by fast
  1186 
  1187 lemma append_eq_conv_conj:
  1188 "!!zs. (xs @ ys = zs) = (xs = take (length xs) zs \<and> ys = drop (length xs) zs)"
  1189 apply (induct xs, simp, clarsimp)
  1190 apply (case_tac zs, auto)
  1191 done
  1192 
  1193 lemma take_add [rule_format]: 
  1194     "\<forall>i. i+j \<le> length(xs) --> take (i+j) xs = take i xs @ take j (drop i xs)"
  1195 apply (induct xs, auto) 
  1196 apply (case_tac i, simp_all) 
  1197 done
  1198 
  1199 lemma append_eq_append_conv_if:
  1200  "!! ys\<^isub>1. (xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>1 @ ys\<^isub>2) =
  1201   (if size xs\<^isub>1 \<le> size ys\<^isub>1
  1202    then xs\<^isub>1 = take (size xs\<^isub>1) ys\<^isub>1 \<and> xs\<^isub>2 = drop (size xs\<^isub>1) ys\<^isub>1 @ ys\<^isub>2
  1203    else take (size ys\<^isub>1) xs\<^isub>1 = ys\<^isub>1 \<and> drop (size ys\<^isub>1) xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>2)"
  1204 apply(induct xs\<^isub>1)
  1205  apply simp
  1206 apply(case_tac ys\<^isub>1)
  1207 apply simp_all
  1208 done
  1209 
  1210 lemma take_hd_drop:
  1211   "!!n. n < length xs \<Longrightarrow> take n xs @ [hd (drop n xs)] = take (n+1) xs"
  1212 apply(induct xs)
  1213 apply simp
  1214 apply(simp add:drop_Cons split:nat.split)
  1215 done
  1216 
  1217 lemma id_take_nth_drop:
  1218  "i < length xs \<Longrightarrow> xs = take i xs @ xs!i # drop (Suc i) xs" 
  1219 proof -
  1220   assume si: "i < length xs"
  1221   hence "xs = take (Suc i) xs @ drop (Suc i) xs" by auto
  1222   moreover
  1223   from si have "take (Suc i) xs = take i xs @ [xs!i]"
  1224     apply (rule_tac take_Suc_conv_app_nth) by arith
  1225   ultimately show ?thesis by auto
  1226 qed
  1227   
  1228 lemma upd_conv_take_nth_drop:
  1229  "i < length xs \<Longrightarrow> xs[i:=a] = take i xs @ a # drop (Suc i) xs"
  1230 proof -
  1231   assume i: "i < length xs"
  1232   have "xs[i:=a] = (take i xs @ xs!i # drop (Suc i) xs)[i:=a]"
  1233     by(rule arg_cong[OF id_take_nth_drop[OF i]])
  1234   also have "\<dots> = take i xs @ a # drop (Suc i) xs"
  1235     using i by (simp add: list_update_append)
  1236   finally show ?thesis .
  1237 qed
  1238 
  1239 
  1240 subsubsection {* @{text takeWhile} and @{text dropWhile} *}
  1241 
  1242 lemma takeWhile_dropWhile_id [simp]: "takeWhile P xs @ dropWhile P xs = xs"
  1243 by (induct xs) auto
  1244 
  1245 lemma takeWhile_append1 [simp]:
  1246 "[| x:set xs; ~P(x)|] ==> takeWhile P (xs @ ys) = takeWhile P xs"
  1247 by (induct xs) auto
  1248 
  1249 lemma takeWhile_append2 [simp]:
  1250 "(!!x. x : set xs ==> P x) ==> takeWhile P (xs @ ys) = xs @ takeWhile P ys"
  1251 by (induct xs) auto
  1252 
  1253 lemma takeWhile_tail: "\<not> P x ==> takeWhile P (xs @ (x#l)) = takeWhile P xs"
  1254 by (induct xs) auto
  1255 
  1256 lemma dropWhile_append1 [simp]:
  1257 "[| x : set xs; ~P(x)|] ==> dropWhile P (xs @ ys) = (dropWhile P xs)@ys"
  1258 by (induct xs) auto
  1259 
  1260 lemma dropWhile_append2 [simp]:
  1261 "(!!x. x:set xs ==> P(x)) ==> dropWhile P (xs @ ys) = dropWhile P ys"
  1262 by (induct xs) auto
  1263 
  1264 lemma set_take_whileD: "x : set (takeWhile P xs) ==> x : set xs \<and> P x"
  1265 by (induct xs) (auto split: split_if_asm)
  1266 
  1267 lemma takeWhile_eq_all_conv[simp]:
  1268  "(takeWhile P xs = xs) = (\<forall>x \<in> set xs. P x)"
  1269 by(induct xs, auto)
  1270 
  1271 lemma dropWhile_eq_Nil_conv[simp]:
  1272  "(dropWhile P xs = []) = (\<forall>x \<in> set xs. P x)"
  1273 by(induct xs, auto)
  1274 
  1275 lemma dropWhile_eq_Cons_conv:
  1276  "(dropWhile P xs = y#ys) = (xs = takeWhile P xs @ y # ys & \<not> P y)"
  1277 by(induct xs, auto)
  1278 
  1279 text{* The following two lemmmas could be generalized to an arbitrary
  1280 property. *}
  1281 
  1282 lemma takeWhile_neq_rev: "\<lbrakk>distinct xs; x \<in> set xs\<rbrakk> \<Longrightarrow>
  1283  takeWhile (\<lambda>y. y \<noteq> x) (rev xs) = rev (tl (dropWhile (\<lambda>y. y \<noteq> x) xs))"
  1284 by(induct xs) (auto simp: takeWhile_tail[where l="[]"])
  1285 
  1286 lemma dropWhile_neq_rev: "\<lbrakk>distinct xs; x \<in> set xs\<rbrakk> \<Longrightarrow>
  1287   dropWhile (\<lambda>y. y \<noteq> x) (rev xs) = x # rev (takeWhile (\<lambda>y. y \<noteq> x) xs)"
  1288 apply(induct xs)
  1289  apply simp
  1290 apply auto
  1291 apply(subst dropWhile_append2)
  1292 apply auto
  1293 done
  1294 
  1295 lemma takeWhile_not_last:
  1296  "\<lbrakk> xs \<noteq> []; distinct xs\<rbrakk> \<Longrightarrow> takeWhile (\<lambda>y. y \<noteq> last xs) xs = butlast xs"
  1297 apply(induct xs)
  1298  apply simp
  1299 apply(case_tac xs)
  1300 apply(auto)
  1301 done
  1302 
  1303 lemma takeWhile_cong [fundef_cong, recdef_cong]:
  1304   "[| l = k; !!x. x : set l ==> P x = Q x |] 
  1305   ==> takeWhile P l = takeWhile Q k"
  1306   by (induct k arbitrary: l) (simp_all)
  1307 
  1308 lemma dropWhile_cong [fundef_cong, recdef_cong]:
  1309   "[| l = k; !!x. x : set l ==> P x = Q x |] 
  1310   ==> dropWhile P l = dropWhile Q k"
  1311   by (induct k arbitrary: l, simp_all)
  1312 
  1313 
  1314 subsubsection {* @{text zip} *}
  1315 
  1316 lemma zip_Nil [simp]: "zip [] ys = []"
  1317 by (induct ys) auto
  1318 
  1319 lemma zip_Cons_Cons [simp]: "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
  1320 by simp
  1321 
  1322 declare zip_Cons [simp del]
  1323 
  1324 lemma zip_Cons1:
  1325  "zip (x#xs) ys = (case ys of [] \<Rightarrow> [] | y#ys \<Rightarrow> (x,y)#zip xs ys)"
  1326 by(auto split:list.split)
  1327 
  1328 lemma length_zip [simp]:
  1329 "!!xs. length (zip xs ys) = min (length xs) (length ys)"
  1330 apply (induct ys, simp)
  1331 apply (case_tac xs, auto)
  1332 done
  1333 
  1334 lemma zip_append1:
  1335 "!!xs. zip (xs @ ys) zs =
  1336 zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)"
  1337 apply (induct zs, simp)
  1338 apply (case_tac xs, simp_all)
  1339 done
  1340 
  1341 lemma zip_append2:
  1342 "!!ys. zip xs (ys @ zs) =
  1343 zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs"
  1344 apply (induct xs, simp)
  1345 apply (case_tac ys, simp_all)
  1346 done
  1347 
  1348 lemma zip_append [simp]:
  1349  "[| length xs = length us; length ys = length vs |] ==>
  1350 zip (xs@ys) (us@vs) = zip xs us @ zip ys vs"
  1351 by (simp add: zip_append1)
  1352 
  1353 lemma zip_rev:
  1354 "length xs = length ys ==> zip (rev xs) (rev ys) = rev (zip xs ys)"
  1355 by (induct rule:list_induct2, simp_all)
  1356 
  1357 lemma nth_zip [simp]:
  1358 "!!i xs. [| i < length xs; i < length ys|] ==> (zip xs ys)!i = (xs!i, ys!i)"
  1359 apply (induct ys, simp)
  1360 apply (case_tac xs)
  1361  apply (simp_all add: nth.simps split: nat.split)
  1362 done
  1363 
  1364 lemma set_zip:
  1365 "set (zip xs ys) = {(xs!i, ys!i) | i. i < min (length xs) (length ys)}"
  1366 by (simp add: set_conv_nth cong: rev_conj_cong)
  1367 
  1368 lemma zip_update:
  1369 "length xs = length ys ==> zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]"
  1370 by (rule sym, simp add: update_zip)
  1371 
  1372 lemma zip_replicate [simp]:
  1373 "!!j. zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)"
  1374 apply (induct i, auto)
  1375 apply (case_tac j, auto)
  1376 done
  1377 
  1378 lemma take_zip:
  1379  "!!xs ys. take n (zip xs ys) = zip (take n xs) (take n ys)"
  1380 apply (induct n)
  1381  apply simp
  1382 apply (case_tac xs, simp)
  1383 apply (case_tac ys, simp_all)
  1384 done
  1385 
  1386 lemma drop_zip:
  1387  "!!xs ys. drop n (zip xs ys) = zip (drop n xs) (drop n ys)"
  1388 apply (induct n)
  1389  apply simp
  1390 apply (case_tac xs, simp)
  1391 apply (case_tac ys, simp_all)
  1392 done
  1393 
  1394 
  1395 subsubsection {* @{text list_all2} *}
  1396 
  1397 lemma list_all2_lengthD [intro?]: 
  1398   "list_all2 P xs ys ==> length xs = length ys"
  1399   by (simp add: list_all2_def)
  1400 
  1401 lemma list_all2_Nil [iff, code]: "list_all2 P [] ys = (ys = [])"
  1402   by (simp add: list_all2_def)
  1403 
  1404 lemma list_all2_Nil2 [iff, code]: "list_all2 P xs [] = (xs = [])"
  1405   by (simp add: list_all2_def)
  1406 
  1407 lemma list_all2_Cons [iff, code]:
  1408   "list_all2 P (x # xs) (y # ys) = (P x y \<and> list_all2 P xs ys)"
  1409   by (auto simp add: list_all2_def)
  1410 
  1411 lemma list_all2_Cons1:
  1412 "list_all2 P (x # xs) ys = (\<exists>z zs. ys = z # zs \<and> P x z \<and> list_all2 P xs zs)"
  1413 by (cases ys) auto
  1414 
  1415 lemma list_all2_Cons2:
  1416 "list_all2 P xs (y # ys) = (\<exists>z zs. xs = z # zs \<and> P z y \<and> list_all2 P zs ys)"
  1417 by (cases xs) auto
  1418 
  1419 lemma list_all2_rev [iff]:
  1420 "list_all2 P (rev xs) (rev ys) = list_all2 P xs ys"
  1421 by (simp add: list_all2_def zip_rev cong: conj_cong)
  1422 
  1423 lemma list_all2_rev1:
  1424 "list_all2 P (rev xs) ys = list_all2 P xs (rev ys)"
  1425 by (subst list_all2_rev [symmetric]) simp
  1426 
  1427 lemma list_all2_append1:
  1428 "list_all2 P (xs @ ys) zs =
  1429 (EX us vs. zs = us @ vs \<and> length us = length xs \<and> length vs = length ys \<and>
  1430 list_all2 P xs us \<and> list_all2 P ys vs)"
  1431 apply (simp add: list_all2_def zip_append1)
  1432 apply (rule iffI)
  1433  apply (rule_tac x = "take (length xs) zs" in exI)
  1434  apply (rule_tac x = "drop (length xs) zs" in exI)
  1435  apply (force split: nat_diff_split simp add: min_def, clarify)
  1436 apply (simp add: ball_Un)
  1437 done
  1438 
  1439 lemma list_all2_append2:
  1440 "list_all2 P xs (ys @ zs) =
  1441 (EX us vs. xs = us @ vs \<and> length us = length ys \<and> length vs = length zs \<and>
  1442 list_all2 P us ys \<and> list_all2 P vs zs)"
  1443 apply (simp add: list_all2_def zip_append2)
  1444 apply (rule iffI)
  1445  apply (rule_tac x = "take (length ys) xs" in exI)
  1446  apply (rule_tac x = "drop (length ys) xs" in exI)
  1447  apply (force split: nat_diff_split simp add: min_def, clarify)
  1448 apply (simp add: ball_Un)
  1449 done
  1450 
  1451 lemma list_all2_append:
  1452   "length xs = length ys \<Longrightarrow>
  1453   list_all2 P (xs@us) (ys@vs) = (list_all2 P xs ys \<and> list_all2 P us vs)"
  1454 by (induct rule:list_induct2, simp_all)
  1455 
  1456 lemma list_all2_appendI [intro?, trans]:
  1457   "\<lbrakk> list_all2 P a b; list_all2 P c d \<rbrakk> \<Longrightarrow> list_all2 P (a@c) (b@d)"
  1458   by (simp add: list_all2_append list_all2_lengthD)
  1459 
  1460 lemma list_all2_conv_all_nth:
  1461 "list_all2 P xs ys =
  1462 (length xs = length ys \<and> (\<forall>i < length xs. P (xs!i) (ys!i)))"
  1463 by (force simp add: list_all2_def set_zip)
  1464 
  1465 lemma list_all2_trans:
  1466   assumes tr: "!!a b c. P1 a b ==> P2 b c ==> P3 a c"
  1467   shows "!!bs cs. list_all2 P1 as bs ==> list_all2 P2 bs cs ==> list_all2 P3 as cs"
  1468         (is "!!bs cs. PROP ?Q as bs cs")
  1469 proof (induct as)
  1470   fix x xs bs assume I1: "!!bs cs. PROP ?Q xs bs cs"
  1471   show "!!cs. PROP ?Q (x # xs) bs cs"
  1472   proof (induct bs)
  1473     fix y ys cs assume I2: "!!cs. PROP ?Q (x # xs) ys cs"
  1474     show "PROP ?Q (x # xs) (y # ys) cs"
  1475       by (induct cs) (auto intro: tr I1 I2)
  1476   qed simp
  1477 qed simp
  1478 
  1479 lemma list_all2_all_nthI [intro?]:
  1480   "length a = length b \<Longrightarrow> (\<And>n. n < length a \<Longrightarrow> P (a!n) (b!n)) \<Longrightarrow> list_all2 P a b"
  1481   by (simp add: list_all2_conv_all_nth)
  1482 
  1483 lemma list_all2I:
  1484   "\<forall>x \<in> set (zip a b). split P x \<Longrightarrow> length a = length b \<Longrightarrow> list_all2 P a b"
  1485   by (simp add: list_all2_def)
  1486 
  1487 lemma list_all2_nthD:
  1488   "\<lbrakk> list_all2 P xs ys; p < size xs \<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  1489   by (simp add: list_all2_conv_all_nth)
  1490 
  1491 lemma list_all2_nthD2:
  1492   "\<lbrakk>list_all2 P xs ys; p < size ys\<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  1493   by (frule list_all2_lengthD) (auto intro: list_all2_nthD)
  1494 
  1495 lemma list_all2_map1: 
  1496   "list_all2 P (map f as) bs = list_all2 (\<lambda>x y. P (f x) y) as bs"
  1497   by (simp add: list_all2_conv_all_nth)
  1498 
  1499 lemma list_all2_map2: 
  1500   "list_all2 P as (map f bs) = list_all2 (\<lambda>x y. P x (f y)) as bs"
  1501   by (auto simp add: list_all2_conv_all_nth)
  1502 
  1503 lemma list_all2_refl [intro?]:
  1504   "(\<And>x. P x x) \<Longrightarrow> list_all2 P xs xs"
  1505   by (simp add: list_all2_conv_all_nth)
  1506 
  1507 lemma list_all2_update_cong:
  1508   "\<lbrakk> i<size xs; list_all2 P xs ys; P x y \<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  1509   by (simp add: list_all2_conv_all_nth nth_list_update)
  1510 
  1511 lemma list_all2_update_cong2:
  1512   "\<lbrakk>list_all2 P xs ys; P x y; i < length ys\<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  1513   by (simp add: list_all2_lengthD list_all2_update_cong)
  1514 
  1515 lemma list_all2_takeI [simp,intro?]:
  1516   "\<And>n ys. list_all2 P xs ys \<Longrightarrow> list_all2 P (take n xs) (take n ys)"
  1517   apply (induct xs)
  1518    apply simp
  1519   apply (clarsimp simp add: list_all2_Cons1)
  1520   apply (case_tac n)
  1521   apply auto
  1522   done
  1523 
  1524 lemma list_all2_dropI [simp,intro?]:
  1525   "\<And>n bs. list_all2 P as bs \<Longrightarrow> list_all2 P (drop n as) (drop n bs)"
  1526   apply (induct as, simp)
  1527   apply (clarsimp simp add: list_all2_Cons1)
  1528   apply (case_tac n, simp, simp)
  1529   done
  1530 
  1531 lemma list_all2_mono [intro?]:
  1532   "\<And>y. list_all2 P x y \<Longrightarrow> (\<And>x y. P x y \<Longrightarrow> Q x y) \<Longrightarrow> list_all2 Q x y"
  1533   apply (induct x, simp)
  1534   apply (case_tac y, auto)
  1535   done
  1536 
  1537 
  1538 subsubsection {* @{text foldl} and @{text foldr} *}
  1539 
  1540 lemma foldl_append [simp]:
  1541 "!!a. foldl f a (xs @ ys) = foldl f (foldl f a xs) ys"
  1542 by (induct xs) auto
  1543 
  1544 lemma foldr_append[simp]: "foldr f (xs @ ys) a = foldr f xs (foldr f ys a)"
  1545 by (induct xs) auto
  1546 
  1547 lemma foldl_cong [fundef_cong, recdef_cong]:
  1548   "[| a = b; l = k; !!a x. x : set l ==> f a x = g a x |] 
  1549   ==> foldl f a l = foldl g b k"
  1550   by (induct k arbitrary: a b l) simp_all
  1551 
  1552 lemma foldr_cong [fundef_cong, recdef_cong]:
  1553   "[| a = b; l = k; !!a x. x : set l ==> f x a = g x a |] 
  1554   ==> foldr f l a = foldr g k b"
  1555   by (induct k arbitrary: a b l) simp_all
  1556 
  1557 lemma foldr_foldl: "foldr f xs a = foldl (%x y. f y x) a (rev xs)"
  1558 by (induct xs) auto
  1559 
  1560 lemma foldl_foldr: "foldl f a xs = foldr (%x y. f y x) (rev xs) a"
  1561 by (simp add: foldr_foldl [of "%x y. f y x" "rev xs"])
  1562 
  1563 text {*
  1564 Note: @{text "n \<le> foldl (op +) n ns"} looks simpler, but is more
  1565 difficult to use because it requires an additional transitivity step.
  1566 *}
  1567 
  1568 lemma start_le_sum: "!!n::nat. m <= n ==> m <= foldl (op +) n ns"
  1569 by (induct ns) auto
  1570 
  1571 lemma elem_le_sum: "!!n::nat. n : set ns ==> n <= foldl (op +) 0 ns"
  1572 by (force intro: start_le_sum simp add: in_set_conv_decomp)
  1573 
  1574 lemma sum_eq_0_conv [iff]:
  1575 "!!m::nat. (foldl (op +) m ns = 0) = (m = 0 \<and> (\<forall>n \<in> set ns. n = 0))"
  1576 by (induct ns) auto
  1577 
  1578 
  1579 subsubsection {* @{text upto} *}
  1580 
  1581 lemma upt_rec[code]: "[i..<j] = (if i<j then i#[Suc i..<j] else [])"
  1582 -- {* simp does not terminate! *}
  1583 by (induct j) auto
  1584 
  1585 lemma upt_conv_Nil [simp]: "j <= i ==> [i..<j] = []"
  1586 by (subst upt_rec) simp
  1587 
  1588 lemma upt_eq_Nil_conv[simp]: "([i..<j] = []) = (j = 0 \<or> j <= i)"
  1589 by(induct j)simp_all
  1590 
  1591 lemma upt_eq_Cons_conv:
  1592  "!!x xs. ([i..<j] = x#xs) = (i < j & i = x & [i+1..<j] = xs)"
  1593 apply(induct j)
  1594  apply simp
  1595 apply(clarsimp simp add: append_eq_Cons_conv)
  1596 apply arith
  1597 done
  1598 
  1599 lemma upt_Suc_append: "i <= j ==> [i..<(Suc j)] = [i..<j]@[j]"
  1600 -- {* Only needed if @{text upt_Suc} is deleted from the simpset. *}
  1601 by simp
  1602 
  1603 lemma upt_conv_Cons: "i < j ==> [i..<j] = i # [Suc i..<j]"
  1604 apply(rule trans)
  1605 apply(subst upt_rec)
  1606  prefer 2 apply (rule refl, simp)
  1607 done
  1608 
  1609 lemma upt_add_eq_append: "i<=j ==> [i..<j+k] = [i..<j]@[j..<j+k]"
  1610 -- {* LOOPS as a simprule, since @{text "j <= j"}. *}
  1611 by (induct k) auto
  1612 
  1613 lemma length_upt [simp]: "length [i..<j] = j - i"
  1614 by (induct j) (auto simp add: Suc_diff_le)
  1615 
  1616 lemma nth_upt [simp]: "i + k < j ==> [i..<j] ! k = i + k"
  1617 apply (induct j)
  1618 apply (auto simp add: less_Suc_eq nth_append split: nat_diff_split)
  1619 done
  1620 
  1621 
  1622 lemma hd_upt[simp]: "i < j \<Longrightarrow> hd[i..<j] = i"
  1623 by(simp add:upt_conv_Cons)
  1624 
  1625 lemma last_upt[simp]: "i < j \<Longrightarrow> last[i..<j] = j - 1"
  1626 apply(cases j)
  1627  apply simp
  1628 by(simp add:upt_Suc_append)
  1629 
  1630 lemma take_upt [simp]: "!!i. i+m <= n ==> take m [i..<n] = [i..<i+m]"
  1631 apply (induct m, simp)
  1632 apply (subst upt_rec)
  1633 apply (rule sym)
  1634 apply (subst upt_rec)
  1635 apply (simp del: upt.simps)
  1636 done
  1637 
  1638 lemma drop_upt[simp]: "drop m [i..<j] = [i+m..<j]"
  1639 apply(induct j)
  1640 apply auto
  1641 done
  1642 
  1643 lemma map_Suc_upt: "map Suc [m..<n] = [Suc m..n]"
  1644 by (induct n) auto
  1645 
  1646 lemma nth_map_upt: "!!i. i < n-m ==> (map f [m..<n]) ! i = f(m+i)"
  1647 apply (induct n m rule: diff_induct)
  1648 prefer 3 apply (subst map_Suc_upt[symmetric])
  1649 apply (auto simp add: less_diff_conv nth_upt)
  1650 done
  1651 
  1652 lemma nth_take_lemma:
  1653   "!!xs ys. k <= length xs ==> k <= length ys ==>
  1654      (!!i. i < k --> xs!i = ys!i) ==> take k xs = take k ys"
  1655 apply (atomize, induct k)
  1656 apply (simp_all add: less_Suc_eq_0_disj all_conj_distrib, clarify)
  1657 txt {* Both lists must be non-empty *}
  1658 apply (case_tac xs, simp)
  1659 apply (case_tac ys, clarify)
  1660  apply (simp (no_asm_use))
  1661 apply clarify
  1662 txt {* prenexing's needed, not miniscoping *}
  1663 apply (simp (no_asm_use) add: all_simps [symmetric] del: all_simps)
  1664 apply blast
  1665 done
  1666 
  1667 lemma nth_equalityI:
  1668  "[| length xs = length ys; ALL i < length xs. xs!i = ys!i |] ==> xs = ys"
  1669 apply (frule nth_take_lemma [OF le_refl eq_imp_le])
  1670 apply (simp_all add: take_all)
  1671 done
  1672 
  1673 (* needs nth_equalityI *)
  1674 lemma list_all2_antisym:
  1675   "\<lbrakk> (\<And>x y. \<lbrakk>P x y; Q y x\<rbrakk> \<Longrightarrow> x = y); list_all2 P xs ys; list_all2 Q ys xs \<rbrakk> 
  1676   \<Longrightarrow> xs = ys"
  1677   apply (simp add: list_all2_conv_all_nth) 
  1678   apply (rule nth_equalityI, blast, simp)
  1679   done
  1680 
  1681 lemma take_equalityI: "(\<forall>i. take i xs = take i ys) ==> xs = ys"
  1682 -- {* The famous take-lemma. *}
  1683 apply (drule_tac x = "max (length xs) (length ys)" in spec)
  1684 apply (simp add: le_max_iff_disj take_all)
  1685 done
  1686 
  1687 
  1688 lemma take_Cons':
  1689      "take n (x # xs) = (if n = 0 then [] else x # take (n - 1) xs)"
  1690 by (cases n) simp_all
  1691 
  1692 lemma drop_Cons':
  1693      "drop n (x # xs) = (if n = 0 then x # xs else drop (n - 1) xs)"
  1694 by (cases n) simp_all
  1695 
  1696 lemma nth_Cons': "(x # xs)!n = (if n = 0 then x else xs!(n - 1))"
  1697 by (cases n) simp_all
  1698 
  1699 lemmas take_Cons_number_of = take_Cons'[of "number_of v",standard]
  1700 lemmas drop_Cons_number_of = drop_Cons'[of "number_of v",standard]
  1701 lemmas nth_Cons_number_of = nth_Cons'[of _ _ "number_of v",standard]
  1702 
  1703 declare take_Cons_number_of [simp] 
  1704         drop_Cons_number_of [simp] 
  1705         nth_Cons_number_of [simp] 
  1706 
  1707 
  1708 subsubsection {* @{text "distinct"} and @{text remdups} *}
  1709 
  1710 lemma distinct_append [simp]:
  1711 "distinct (xs @ ys) = (distinct xs \<and> distinct ys \<and> set xs \<inter> set ys = {})"
  1712 by (induct xs) auto
  1713 
  1714 lemma distinct_rev[simp]: "distinct(rev xs) = distinct xs"
  1715 by(induct xs) auto
  1716 
  1717 lemma set_remdups [simp]: "set (remdups xs) = set xs"
  1718 by (induct xs) (auto simp add: insert_absorb)
  1719 
  1720 lemma distinct_remdups [iff]: "distinct (remdups xs)"
  1721 by (induct xs) auto
  1722 
  1723 lemma remdups_eq_nil_iff [simp]: "(remdups x = []) = (x = [])"
  1724   by (induct x, auto) 
  1725 
  1726 lemma remdups_eq_nil_right_iff [simp]: "([] = remdups x) = (x = [])"
  1727   by (induct x, auto)
  1728 
  1729 lemma length_remdups_leq[iff]: "length(remdups xs) <= length xs"
  1730 by (induct xs) auto
  1731 
  1732 lemma length_remdups_eq[iff]:
  1733   "(length (remdups xs) = length xs) = (remdups xs = xs)"
  1734 apply(induct xs)
  1735  apply auto
  1736 apply(subgoal_tac "length (remdups xs) <= length xs")
  1737  apply arith
  1738 apply(rule length_remdups_leq)
  1739 done
  1740 
  1741 
  1742 lemma distinct_map:
  1743   "distinct(map f xs) = (distinct xs & inj_on f (set xs))"
  1744 by (induct xs) auto
  1745 
  1746 
  1747 lemma distinct_filter [simp]: "distinct xs ==> distinct (filter P xs)"
  1748 by (induct xs) auto
  1749 
  1750 lemma distinct_upt[simp]: "distinct[i..<j]"
  1751 by (induct j) auto
  1752 
  1753 lemma distinct_take[simp]: "\<And>i. distinct xs \<Longrightarrow> distinct (take i xs)"
  1754 apply(induct xs)
  1755  apply simp
  1756 apply (case_tac i)
  1757  apply simp_all
  1758 apply(blast dest:in_set_takeD)
  1759 done
  1760 
  1761 lemma distinct_drop[simp]: "\<And>i. distinct xs \<Longrightarrow> distinct (drop i xs)"
  1762 apply(induct xs)
  1763  apply simp
  1764 apply (case_tac i)
  1765  apply simp_all
  1766 done
  1767 
  1768 lemma distinct_list_update:
  1769 assumes d: "distinct xs" and a: "a \<notin> set xs - {xs!i}"
  1770 shows "distinct (xs[i:=a])"
  1771 proof (cases "i < length xs")
  1772   case True
  1773   with a have "a \<notin> set (take i xs @ xs ! i # drop (Suc i) xs) - {xs!i}"
  1774     apply (drule_tac id_take_nth_drop) by simp
  1775   with d True show ?thesis
  1776     apply (simp add: upd_conv_take_nth_drop)
  1777     apply (drule subst [OF id_take_nth_drop]) apply assumption
  1778     apply simp apply (cases "a = xs!i") apply simp by blast
  1779 next
  1780   case False with d show ?thesis by auto
  1781 qed
  1782 
  1783 
  1784 text {* It is best to avoid this indexed version of distinct, but
  1785 sometimes it is useful. *}
  1786 
  1787 lemma distinct_conv_nth:
  1788 "distinct xs = (\<forall>i < size xs. \<forall>j < size xs. i \<noteq> j --> xs!i \<noteq> xs!j)"
  1789 apply (induct xs, simp, simp)
  1790 apply (rule iffI, clarsimp)
  1791  apply (case_tac i)
  1792 apply (case_tac j, simp)
  1793 apply (simp add: set_conv_nth)
  1794  apply (case_tac j)
  1795 apply (clarsimp simp add: set_conv_nth, simp)
  1796 apply (rule conjI)
  1797  apply (clarsimp simp add: set_conv_nth)
  1798  apply (erule_tac x = 0 in allE, simp)
  1799  apply (erule_tac x = "Suc i" in allE, simp, clarsimp)
  1800 apply (erule_tac x = "Suc i" in allE, simp)
  1801 apply (erule_tac x = "Suc j" in allE, simp)
  1802 done
  1803 
  1804 lemma nth_eq_iff_index_eq:
  1805  "\<lbrakk> distinct xs; i < length xs; j < length xs \<rbrakk> \<Longrightarrow> (xs!i = xs!j) = (i = j)"
  1806 by(auto simp: distinct_conv_nth)
  1807 
  1808 lemma distinct_card: "distinct xs ==> card (set xs) = size xs"
  1809   by (induct xs) auto
  1810 
  1811 lemma card_distinct: "card (set xs) = size xs ==> distinct xs"
  1812 proof (induct xs)
  1813   case Nil thus ?case by simp
  1814 next
  1815   case (Cons x xs)
  1816   show ?case
  1817   proof (cases "x \<in> set xs")
  1818     case False with Cons show ?thesis by simp
  1819   next
  1820     case True with Cons.prems
  1821     have "card (set xs) = Suc (length xs)" 
  1822       by (simp add: card_insert_if split: split_if_asm)
  1823     moreover have "card (set xs) \<le> length xs" by (rule card_length)
  1824     ultimately have False by simp
  1825     thus ?thesis ..
  1826   qed
  1827 qed
  1828 
  1829 
  1830 lemma length_remdups_concat:
  1831  "length(remdups(concat xss)) = card(\<Union>xs \<in> set xss. set xs)"
  1832 by(simp add: distinct_card[symmetric])
  1833 
  1834 
  1835 subsubsection {* @{text remove1} *}
  1836 
  1837 lemma remove1_append:
  1838   "remove1 x (xs @ ys) =
  1839   (if x \<in> set xs then remove1 x xs @ ys else xs @ remove1 x ys)"
  1840 by (induct xs) auto
  1841 
  1842 lemma set_remove1_subset: "set(remove1 x xs) <= set xs"
  1843 apply(induct xs)
  1844  apply simp
  1845 apply simp
  1846 apply blast
  1847 done
  1848 
  1849 lemma set_remove1_eq [simp]: "distinct xs ==> set(remove1 x xs) = set xs - {x}"
  1850 apply(induct xs)
  1851  apply simp
  1852 apply simp
  1853 apply blast
  1854 done
  1855 
  1856 lemma remove1_filter_not[simp]:
  1857   "\<not> P x \<Longrightarrow> remove1 x (filter P xs) = filter P xs"
  1858 by(induct xs) auto
  1859 
  1860 lemma notin_set_remove1[simp]: "x ~: set xs ==> x ~: set(remove1 y xs)"
  1861 apply(insert set_remove1_subset)
  1862 apply fast
  1863 done
  1864 
  1865 lemma distinct_remove1[simp]: "distinct xs ==> distinct(remove1 x xs)"
  1866 by (induct xs) simp_all
  1867 
  1868 
  1869 subsubsection {* @{text replicate} *}
  1870 
  1871 lemma length_replicate [simp]: "length (replicate n x) = n"
  1872 by (induct n) auto
  1873 
  1874 lemma map_replicate [simp]: "map f (replicate n x) = replicate n (f x)"
  1875 by (induct n) auto
  1876 
  1877 lemma replicate_app_Cons_same:
  1878 "(replicate n x) @ (x # xs) = x # replicate n x @ xs"
  1879 by (induct n) auto
  1880 
  1881 lemma rev_replicate [simp]: "rev (replicate n x) = replicate n x"
  1882 apply (induct n, simp)
  1883 apply (simp add: replicate_app_Cons_same)
  1884 done
  1885 
  1886 lemma replicate_add: "replicate (n + m) x = replicate n x @ replicate m x"
  1887 by (induct n) auto
  1888 
  1889 text{* Courtesy of Matthias Daum: *}
  1890 lemma append_replicate_commute:
  1891   "replicate n x @ replicate k x = replicate k x @ replicate n x"
  1892 apply (simp add: replicate_add [THEN sym])
  1893 apply (simp add: add_commute)
  1894 done
  1895 
  1896 lemma hd_replicate [simp]: "n \<noteq> 0 ==> hd (replicate n x) = x"
  1897 by (induct n) auto
  1898 
  1899 lemma tl_replicate [simp]: "n \<noteq> 0 ==> tl (replicate n x) = replicate (n - 1) x"
  1900 by (induct n) auto
  1901 
  1902 lemma last_replicate [simp]: "n \<noteq> 0 ==> last (replicate n x) = x"
  1903 by (atomize (full), induct n) auto
  1904 
  1905 lemma nth_replicate[simp]: "!!i. i < n ==> (replicate n x)!i = x"
  1906 apply (induct n, simp)
  1907 apply (simp add: nth_Cons split: nat.split)
  1908 done
  1909 
  1910 text{* Courtesy of Matthias Daum (2 lemmas): *}
  1911 lemma take_replicate[simp]: "take i (replicate k x) = replicate (min i k) x"
  1912 apply (case_tac "k \<le> i")
  1913  apply  (simp add: min_def)
  1914 apply (drule not_leE)
  1915 apply (simp add: min_def)
  1916 apply (subgoal_tac "replicate k x = replicate i x @ replicate (k - i) x")
  1917  apply  simp
  1918 apply (simp add: replicate_add [symmetric])
  1919 done
  1920 
  1921 lemma drop_replicate[simp]: "!!i. drop i (replicate k x) = replicate (k-i) x"
  1922 apply (induct k)
  1923  apply simp
  1924 apply clarsimp
  1925 apply (case_tac i)
  1926  apply simp
  1927 apply clarsimp
  1928 done
  1929 
  1930 
  1931 lemma set_replicate_Suc: "set (replicate (Suc n) x) = {x}"
  1932 by (induct n) auto
  1933 
  1934 lemma set_replicate [simp]: "n \<noteq> 0 ==> set (replicate n x) = {x}"
  1935 by (fast dest!: not0_implies_Suc intro!: set_replicate_Suc)
  1936 
  1937 lemma set_replicate_conv_if: "set (replicate n x) = (if n = 0 then {} else {x})"
  1938 by auto
  1939 
  1940 lemma in_set_replicateD: "x : set (replicate n y) ==> x = y"
  1941 by (simp add: set_replicate_conv_if split: split_if_asm)
  1942 
  1943 
  1944 subsubsection{*@{text rotate1} and @{text rotate}*}
  1945 
  1946 lemma rotate_simps[simp]: "rotate1 [] = [] \<and> rotate1 (x#xs) = xs @ [x]"
  1947 by(simp add:rotate1_def)
  1948 
  1949 lemma rotate0[simp]: "rotate 0 = id"
  1950 by(simp add:rotate_def)
  1951 
  1952 lemma rotate_Suc[simp]: "rotate (Suc n) xs = rotate1(rotate n xs)"
  1953 by(simp add:rotate_def)
  1954 
  1955 lemma rotate_add:
  1956   "rotate (m+n) = rotate m o rotate n"
  1957 by(simp add:rotate_def funpow_add)
  1958 
  1959 lemma rotate_rotate: "rotate m (rotate n xs) = rotate (m+n) xs"
  1960 by(simp add:rotate_add)
  1961 
  1962 lemma rotate1_rotate_swap: "rotate1 (rotate n xs) = rotate n (rotate1 xs)"
  1963 by(simp add:rotate_def funpow_swap1)
  1964 
  1965 lemma rotate1_length01[simp]: "length xs <= 1 \<Longrightarrow> rotate1 xs = xs"
  1966 by(cases xs) simp_all
  1967 
  1968 lemma rotate_length01[simp]: "length xs <= 1 \<Longrightarrow> rotate n xs = xs"
  1969 apply(induct n)
  1970  apply simp
  1971 apply (simp add:rotate_def)
  1972 done
  1973 
  1974 lemma rotate1_hd_tl: "xs \<noteq> [] \<Longrightarrow> rotate1 xs = tl xs @ [hd xs]"
  1975 by(simp add:rotate1_def split:list.split)
  1976 
  1977 lemma rotate_drop_take:
  1978   "rotate n xs = drop (n mod length xs) xs @ take (n mod length xs) xs"
  1979 apply(induct n)
  1980  apply simp
  1981 apply(simp add:rotate_def)
  1982 apply(cases "xs = []")
  1983  apply (simp)
  1984 apply(case_tac "n mod length xs = 0")
  1985  apply(simp add:mod_Suc)
  1986  apply(simp add: rotate1_hd_tl drop_Suc take_Suc)
  1987 apply(simp add:mod_Suc rotate1_hd_tl drop_Suc[symmetric] drop_tl[symmetric]
  1988                 take_hd_drop linorder_not_le)
  1989 done
  1990 
  1991 lemma rotate_conv_mod: "rotate n xs = rotate (n mod length xs) xs"
  1992 by(simp add:rotate_drop_take)
  1993 
  1994 lemma rotate_id[simp]: "n mod length xs = 0 \<Longrightarrow> rotate n xs = xs"
  1995 by(simp add:rotate_drop_take)
  1996 
  1997 lemma length_rotate1[simp]: "length(rotate1 xs) = length xs"
  1998 by(simp add:rotate1_def split:list.split)
  1999 
  2000 lemma length_rotate[simp]: "!!xs. length(rotate n xs) = length xs"
  2001 by (induct n) (simp_all add:rotate_def)
  2002 
  2003 lemma distinct1_rotate[simp]: "distinct(rotate1 xs) = distinct xs"
  2004 by(simp add:rotate1_def split:list.split) blast
  2005 
  2006 lemma distinct_rotate[simp]: "distinct(rotate n xs) = distinct xs"
  2007 by (induct n) (simp_all add:rotate_def)
  2008 
  2009 lemma rotate_map: "rotate n (map f xs) = map f (rotate n xs)"
  2010 by(simp add:rotate_drop_take take_map drop_map)
  2011 
  2012 lemma set_rotate1[simp]: "set(rotate1 xs) = set xs"
  2013 by(simp add:rotate1_def split:list.split)
  2014 
  2015 lemma set_rotate[simp]: "set(rotate n xs) = set xs"
  2016 by (induct n) (simp_all add:rotate_def)
  2017 
  2018 lemma rotate1_is_Nil_conv[simp]: "(rotate1 xs = []) = (xs = [])"
  2019 by(simp add:rotate1_def split:list.split)
  2020 
  2021 lemma rotate_is_Nil_conv[simp]: "(rotate n xs = []) = (xs = [])"
  2022 by (induct n) (simp_all add:rotate_def)
  2023 
  2024 lemma rotate_rev:
  2025   "rotate n (rev xs) = rev(rotate (length xs - (n mod length xs)) xs)"
  2026 apply(simp add:rotate_drop_take rev_drop rev_take)
  2027 apply(cases "length xs = 0")
  2028  apply simp
  2029 apply(cases "n mod length xs = 0")
  2030  apply simp
  2031 apply(simp add:rotate_drop_take rev_drop rev_take)
  2032 done
  2033 
  2034 lemma hd_rotate_conv_nth: "xs \<noteq> [] \<Longrightarrow> hd(rotate n xs) = xs!(n mod length xs)"
  2035 apply(simp add:rotate_drop_take hd_append hd_drop_conv_nth hd_conv_nth)
  2036 apply(subgoal_tac "length xs \<noteq> 0")
  2037  prefer 2 apply simp
  2038 using mod_less_divisor[of "length xs" n] by arith
  2039 
  2040 
  2041 subsubsection {* @{text sublist} --- a generalization of @{text nth} to sets *}
  2042 
  2043 lemma sublist_empty [simp]: "sublist xs {} = []"
  2044 by (auto simp add: sublist_def)
  2045 
  2046 lemma sublist_nil [simp]: "sublist [] A = []"
  2047 by (auto simp add: sublist_def)
  2048 
  2049 lemma length_sublist:
  2050   "length(sublist xs I) = card{i. i < length xs \<and> i : I}"
  2051 by(simp add: sublist_def length_filter_conv_card cong:conj_cong)
  2052 
  2053 lemma sublist_shift_lemma_Suc:
  2054   "!!is. map fst (filter (%p. P(Suc(snd p))) (zip xs is)) =
  2055          map fst (filter (%p. P(snd p)) (zip xs (map Suc is)))"
  2056 apply(induct xs)
  2057  apply simp
  2058 apply (case_tac "is")
  2059  apply simp
  2060 apply simp
  2061 done
  2062 
  2063 lemma sublist_shift_lemma:
  2064      "map fst [p:zip xs [i..<i + length xs] . snd p : A] =
  2065       map fst [p:zip xs [0..<length xs] . snd p + i : A]"
  2066 by (induct xs rule: rev_induct) (simp_all add: add_commute)
  2067 
  2068 lemma sublist_append:
  2069      "sublist (l @ l') A = sublist l A @ sublist l' {j. j + length l : A}"
  2070 apply (unfold sublist_def)
  2071 apply (induct l' rule: rev_induct, simp)
  2072 apply (simp add: upt_add_eq_append[of 0] zip_append sublist_shift_lemma)
  2073 apply (simp add: add_commute)
  2074 done
  2075 
  2076 lemma sublist_Cons:
  2077 "sublist (x # l) A = (if 0:A then [x] else []) @ sublist l {j. Suc j : A}"
  2078 apply (induct l rule: rev_induct)
  2079  apply (simp add: sublist_def)
  2080 apply (simp del: append_Cons add: append_Cons[symmetric] sublist_append)
  2081 done
  2082 
  2083 lemma set_sublist: "!!I. set(sublist xs I) = {xs!i|i. i<size xs \<and> i \<in> I}"
  2084 apply(induct xs)
  2085  apply simp
  2086 apply(auto simp add:sublist_Cons nth_Cons split:nat.split elim: lessE)
  2087  apply(erule lessE)
  2088   apply auto
  2089 apply(erule lessE)
  2090 apply auto
  2091 done
  2092 
  2093 lemma set_sublist_subset: "set(sublist xs I) \<subseteq> set xs"
  2094 by(auto simp add:set_sublist)
  2095 
  2096 lemma notin_set_sublistI[simp]: "x \<notin> set xs \<Longrightarrow> x \<notin> set(sublist xs I)"
  2097 by(auto simp add:set_sublist)
  2098 
  2099 lemma in_set_sublistD: "x \<in> set(sublist xs I) \<Longrightarrow> x \<in> set xs"
  2100 by(auto simp add:set_sublist)
  2101 
  2102 lemma sublist_singleton [simp]: "sublist [x] A = (if 0 : A then [x] else [])"
  2103 by (simp add: sublist_Cons)
  2104 
  2105 
  2106 lemma distinct_sublistI[simp]: "!!I. distinct xs \<Longrightarrow> distinct(sublist xs I)"
  2107 apply(induct xs)
  2108  apply simp
  2109 apply(auto simp add:sublist_Cons)
  2110 done
  2111 
  2112 
  2113 lemma sublist_upt_eq_take [simp]: "sublist l {..<n} = take n l"
  2114 apply (induct l rule: rev_induct, simp)
  2115 apply (simp split: nat_diff_split add: sublist_append)
  2116 done
  2117 
  2118 lemma filter_in_sublist: "\<And>s. distinct xs \<Longrightarrow>
  2119   filter (%x. x \<in> set(sublist xs s)) xs = sublist xs s"
  2120 proof (induct xs)
  2121   case Nil thus ?case by simp
  2122 next
  2123   case (Cons a xs)
  2124   moreover hence "!x. x: set xs \<longrightarrow> x \<noteq> a" by auto
  2125   ultimately show ?case by(simp add: sublist_Cons cong:filter_cong)
  2126 qed
  2127 
  2128 
  2129 subsubsection {* @{const splice} *}
  2130 
  2131 lemma splice_Nil2 [simp, code]:
  2132  "splice xs [] = xs"
  2133 by (cases xs) simp_all
  2134 
  2135 lemma splice_Cons_Cons [simp, code]:
  2136  "splice (x#xs) (y#ys) = x # y # splice xs ys"
  2137 by simp
  2138 
  2139 declare splice.simps(2) [simp del, code del]
  2140 
  2141 subsubsection{*Sets of Lists*}
  2142 
  2143 subsubsection {* @{text lists}: the list-forming operator over sets *}
  2144 
  2145 consts lists :: "'a set => 'a list set"
  2146 inductive "lists A"
  2147  intros
  2148   Nil [intro!]: "[]: lists A"
  2149   Cons [intro!]: "[| a: A;l: lists A|] ==> a#l : lists A"
  2150 
  2151 inductive_cases listsE [elim!]: "x#l : lists A"
  2152 
  2153 lemma lists_mono [mono]: "A \<subseteq> B ==> lists A \<subseteq> lists B"
  2154 by (unfold lists.defs) (blast intro!: lfp_mono)
  2155 
  2156 lemma lists_IntI:
  2157   assumes l: "l: lists A" shows "l: lists B ==> l: lists (A Int B)" using l
  2158   by induct blast+
  2159 
  2160 lemma lists_Int_eq [simp]: "lists (A \<inter> B) = lists A \<inter> lists B"
  2161 proof (rule mono_Int [THEN equalityI])
  2162   show "mono lists" by (simp add: mono_def lists_mono)
  2163   show "lists A \<inter> lists B \<subseteq> lists (A \<inter> B)" by (blast intro: lists_IntI)
  2164 qed
  2165 
  2166 lemma append_in_lists_conv [iff]:
  2167      "(xs @ ys : lists A) = (xs : lists A \<and> ys : lists A)"
  2168 by (induct xs) auto
  2169 
  2170 lemma in_lists_conv_set: "(xs : lists A) = (\<forall>x \<in> set xs. x : A)"
  2171 -- {* eliminate @{text lists} in favour of @{text set} *}
  2172 by (induct xs) auto
  2173 
  2174 lemma in_listsD [dest!]: "xs \<in> lists A ==> \<forall>x\<in>set xs. x \<in> A"
  2175 by (rule in_lists_conv_set [THEN iffD1])
  2176 
  2177 lemma in_listsI [intro!]: "\<forall>x\<in>set xs. x \<in> A ==> xs \<in> lists A"
  2178 by (rule in_lists_conv_set [THEN iffD2])
  2179 
  2180 lemma lists_UNIV [simp]: "lists UNIV = UNIV"
  2181 by auto
  2182 
  2183 
  2184 
  2185 subsubsection{* Inductive definition for membership *}
  2186 
  2187 consts ListMem :: "('a \<times> 'a list)set"
  2188 inductive ListMem
  2189 intros
  2190  elem:  "(x,x#xs) \<in> ListMem"
  2191  insert:  "(x,xs) \<in> ListMem \<Longrightarrow> (x,y#xs) \<in> ListMem"
  2192 
  2193 lemma ListMem_iff: "((x,xs) \<in> ListMem) = (x \<in> set xs)"
  2194 apply (rule iffI)
  2195  apply (induct set: ListMem)
  2196   apply auto
  2197 apply (induct xs)
  2198  apply (auto intro: ListMem.intros)
  2199 done
  2200 
  2201 
  2202 
  2203 subsubsection{*Lists as Cartesian products*}
  2204 
  2205 text{*@{text"set_Cons A Xs"}: the set of lists with head drawn from
  2206 @{term A} and tail drawn from @{term Xs}.*}
  2207 
  2208 constdefs
  2209   set_Cons :: "'a set \<Rightarrow> 'a list set \<Rightarrow> 'a list set"
  2210   "set_Cons A XS == {z. \<exists>x xs. z = x#xs & x \<in> A & xs \<in> XS}"
  2211 
  2212 lemma set_Cons_sing_Nil [simp]: "set_Cons A {[]} = (%x. [x])`A"
  2213 by (auto simp add: set_Cons_def)
  2214 
  2215 text{*Yields the set of lists, all of the same length as the argument and
  2216 with elements drawn from the corresponding element of the argument.*}
  2217 
  2218 consts  listset :: "'a set list \<Rightarrow> 'a list set"
  2219 primrec
  2220    "listset []    = {[]}"
  2221    "listset(A#As) = set_Cons A (listset As)"
  2222 
  2223 
  2224 subsection{*Relations on Lists*}
  2225 
  2226 subsubsection {* Length Lexicographic Ordering *}
  2227 
  2228 text{*These orderings preserve well-foundedness: shorter lists 
  2229   precede longer lists. These ordering are not used in dictionaries.*}
  2230 
  2231 consts lexn :: "('a * 'a)set => nat => ('a list * 'a list)set"
  2232         --{*The lexicographic ordering for lists of the specified length*}
  2233 primrec
  2234   "lexn r 0 = {}"
  2235   "lexn r (Suc n) =
  2236     (prod_fun (%(x,xs). x#xs) (%(x,xs). x#xs) ` (r <*lex*> lexn r n)) Int
  2237     {(xs,ys). length xs = Suc n \<and> length ys = Suc n}"
  2238 
  2239 constdefs
  2240   lex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
  2241     "lex r == \<Union>n. lexn r n"
  2242         --{*Holds only between lists of the same length*}
  2243 
  2244   lenlex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
  2245     "lenlex r == inv_image (less_than <*lex*> lex r) (%xs. (length xs, xs))"
  2246         --{*Compares lists by their length and then lexicographically*}
  2247 
  2248 
  2249 lemma wf_lexn: "wf r ==> wf (lexn r n)"
  2250 apply (induct n, simp, simp)
  2251 apply(rule wf_subset)
  2252  prefer 2 apply (rule Int_lower1)
  2253 apply(rule wf_prod_fun_image)
  2254  prefer 2 apply (rule inj_onI, auto)
  2255 done
  2256 
  2257 lemma lexn_length:
  2258      "!!xs ys. (xs, ys) : lexn r n ==> length xs = n \<and> length ys = n"
  2259 by (induct n) auto
  2260 
  2261 lemma wf_lex [intro!]: "wf r ==> wf (lex r)"
  2262 apply (unfold lex_def)
  2263 apply (rule wf_UN)
  2264 apply (blast intro: wf_lexn, clarify)
  2265 apply (rename_tac m n)
  2266 apply (subgoal_tac "m \<noteq> n")
  2267  prefer 2 apply blast
  2268 apply (blast dest: lexn_length not_sym)
  2269 done
  2270 
  2271 lemma lexn_conv:
  2272   "lexn r n =
  2273     {(xs,ys). length xs = n \<and> length ys = n \<and>
  2274     (\<exists>xys x y xs' ys'. xs= xys @ x#xs' \<and> ys= xys @ y # ys' \<and> (x, y):r)}"
  2275 apply (induct n, simp)
  2276 apply (simp add: image_Collect lex_prod_def, safe, blast)
  2277  apply (rule_tac x = "ab # xys" in exI, simp)
  2278 apply (case_tac xys, simp_all, blast)
  2279 done
  2280 
  2281 lemma lex_conv:
  2282   "lex r =
  2283     {(xs,ys). length xs = length ys \<and>
  2284     (\<exists>xys x y xs' ys'. xs = xys @ x # xs' \<and> ys = xys @ y # ys' \<and> (x, y):r)}"
  2285 by (force simp add: lex_def lexn_conv)
  2286 
  2287 lemma wf_lenlex [intro!]: "wf r ==> wf (lenlex r)"
  2288 by (unfold lenlex_def) blast
  2289 
  2290 lemma lenlex_conv:
  2291     "lenlex r = {(xs,ys). length xs < length ys |
  2292                  length xs = length ys \<and> (xs, ys) : lex r}"
  2293 by (simp add: lenlex_def diag_def lex_prod_def inv_image_def)
  2294 
  2295 lemma Nil_notin_lex [iff]: "([], ys) \<notin> lex r"
  2296 by (simp add: lex_conv)
  2297 
  2298 lemma Nil2_notin_lex [iff]: "(xs, []) \<notin> lex r"
  2299 by (simp add:lex_conv)
  2300 
  2301 lemma Cons_in_lex [simp]:
  2302     "((x # xs, y # ys) : lex r) =
  2303       ((x, y) : r \<and> length xs = length ys | x = y \<and> (xs, ys) : lex r)"
  2304 apply (simp add: lex_conv)
  2305 apply (rule iffI)
  2306  prefer 2 apply (blast intro: Cons_eq_appendI, clarify)
  2307 apply (case_tac xys, simp, simp)
  2308 apply blast
  2309 done
  2310 
  2311 
  2312 subsubsection {* Lexicographic Ordering *}
  2313 
  2314 text {* Classical lexicographic ordering on lists, ie. "a" < "ab" < "b".
  2315     This ordering does \emph{not} preserve well-foundedness.
  2316      Author: N. Voelker, March 2005. *} 
  2317 
  2318 constdefs 
  2319   lexord :: "('a * 'a)set \<Rightarrow> ('a list * 'a list) set" 
  2320   "lexord  r == {(x,y). \<exists> a v. y = x @ a # v \<or> 
  2321             (\<exists> u a b v w. (a,b) \<in> r \<and> x = u @ (a # v) \<and> y = u @ (b # w))}"
  2322 
  2323 lemma lexord_Nil_left[simp]:  "([],y) \<in> lexord r = (\<exists> a x. y = a # x)"
  2324   by (unfold lexord_def, induct_tac y, auto) 
  2325 
  2326 lemma lexord_Nil_right[simp]: "(x,[]) \<notin> lexord r"
  2327   by (unfold lexord_def, induct_tac x, auto)
  2328 
  2329 lemma lexord_cons_cons[simp]:
  2330      "((a # x, b # y) \<in> lexord r) = ((a,b)\<in> r | (a = b & (x,y)\<in> lexord r))"
  2331   apply (unfold lexord_def, safe, simp_all)
  2332   apply (case_tac u, simp, simp)
  2333   apply (case_tac u, simp, clarsimp, blast, blast, clarsimp)
  2334   apply (erule_tac x="b # u" in allE)
  2335   by force
  2336 
  2337 lemmas lexord_simps = lexord_Nil_left lexord_Nil_right lexord_cons_cons
  2338 
  2339 lemma lexord_append_rightI: "\<exists> b z. y = b # z \<Longrightarrow> (x, x @ y) \<in> lexord r"
  2340   by (induct_tac x, auto)  
  2341 
  2342 lemma lexord_append_left_rightI:
  2343      "(a,b) \<in> r \<Longrightarrow> (u @ a # x, u @ b # y) \<in> lexord r"
  2344   by (induct_tac u, auto)
  2345 
  2346 lemma lexord_append_leftI: " (u,v) \<in> lexord r \<Longrightarrow> (x @ u, x @ v) \<in> lexord r"
  2347   by (induct x, auto)
  2348 
  2349 lemma lexord_append_leftD:
  2350      "\<lbrakk> (x @ u, x @ v) \<in> lexord r; (! a. (a,a) \<notin> r) \<rbrakk> \<Longrightarrow> (u,v) \<in> lexord r"
  2351   by (erule rev_mp, induct_tac x, auto)
  2352 
  2353 lemma lexord_take_index_conv: 
  2354    "((x,y) : lexord r) = 
  2355     ((length x < length y \<and> take (length x) y = x) \<or> 
  2356      (\<exists>i. i < min(length x)(length y) & take i x = take i y & (x!i,y!i) \<in> r))"
  2357   apply (unfold lexord_def Let_def, clarsimp) 
  2358   apply (rule_tac f = "(% a b. a \<or> b)" in arg_cong2)
  2359   apply auto 
  2360   apply (rule_tac x="hd (drop (length x) y)" in exI)
  2361   apply (rule_tac x="tl (drop (length x) y)" in exI)
  2362   apply (erule subst, simp add: min_def) 
  2363   apply (rule_tac x ="length u" in exI, simp) 
  2364   apply (rule_tac x ="take i x" in exI) 
  2365   apply (rule_tac x ="x ! i" in exI) 
  2366   apply (rule_tac x ="y ! i" in exI, safe) 
  2367   apply (rule_tac x="drop (Suc i) x" in exI)
  2368   apply (drule sym, simp add: drop_Suc_conv_tl) 
  2369   apply (rule_tac x="drop (Suc i) y" in exI)
  2370   by (simp add: drop_Suc_conv_tl) 
  2371 
  2372 -- {* lexord is extension of partial ordering List.lex *} 
  2373 lemma lexord_lex: " (x,y) \<in> lex r = ((x,y) \<in> lexord r \<and> length x = length y)"
  2374   apply (rule_tac x = y in spec) 
  2375   apply (induct_tac x, clarsimp) 
  2376   by (clarify, case_tac x, simp, force)
  2377 
  2378 lemma lexord_irreflexive: "(! x. (x,x) \<notin> r) \<Longrightarrow> (y,y) \<notin> lexord r"
  2379   by (induct y, auto)
  2380 
  2381 lemma lexord_trans: 
  2382     "\<lbrakk> (x, y) \<in> lexord r; (y, z) \<in> lexord r; trans r \<rbrakk> \<Longrightarrow> (x, z) \<in> lexord r"
  2383    apply (erule rev_mp)+
  2384    apply (rule_tac x = x in spec) 
  2385   apply (rule_tac x = z in spec) 
  2386   apply ( induct_tac y, simp, clarify)
  2387   apply (case_tac xa, erule ssubst) 
  2388   apply (erule allE, erule allE) -- {* avoid simp recursion *} 
  2389   apply (case_tac x, simp, simp) 
  2390   apply (case_tac x, erule allE, erule allE, simp) 
  2391   apply (erule_tac x = listb in allE) 
  2392   apply (erule_tac x = lista in allE, simp)
  2393   apply (unfold trans_def)
  2394   by blast
  2395 
  2396 lemma lexord_transI:  "trans r \<Longrightarrow> trans (lexord r)"
  2397   by (rule transI, drule lexord_trans, blast) 
  2398 
  2399 lemma lexord_linear: "(! a b. (a,b)\<in> r | a = b | (b,a) \<in> r) \<Longrightarrow> (x,y) : lexord r | x = y | (y,x) : lexord r"
  2400   apply (rule_tac x = y in spec) 
  2401   apply (induct_tac x, rule allI) 
  2402   apply (case_tac x, simp, simp) 
  2403   apply (rule allI, case_tac x, simp, simp) 
  2404   by blast
  2405 
  2406 
  2407 subsection {* Lexicographic combination of measure functions *}
  2408 
  2409 text {* These are useful for termination proofs *}
  2410 
  2411 definition
  2412   "measures fs = inv_image (lex less_than) (%a. map (%f. f a) fs)"
  2413 
  2414 lemma wf_measures[recdef_wf, simp]: "wf (measures fs)"
  2415   unfolding measures_def
  2416   by blast
  2417 
  2418 lemma in_measures[simp]: 
  2419   "(x, y) \<in> measures [] = False"
  2420   "(x, y) \<in> measures (f # fs)
  2421          = (f x < f y \<or> (f x = f y \<and> (x, y) \<in> measures fs))"  
  2422   unfolding measures_def
  2423   by auto
  2424 
  2425 lemma measures_less: "f x < f y ==> (x, y) \<in> measures (f#fs)"
  2426   by simp
  2427 
  2428 lemma measures_lesseq: "f x <= f y ==> (x, y) \<in> measures fs ==> (x, y) \<in> measures (f#fs)"
  2429   by auto
  2430 
  2431 (* install the lexicographic_order method and the "fun" command *)
  2432 use "Tools/function_package/lexicographic_order.ML"
  2433 use "Tools/function_package/fundef_datatype.ML"
  2434 setup LexicographicOrder.setup
  2435 setup FundefDatatype.setup
  2436 
  2437 
  2438 subsubsection{*Lifting a Relation on List Elements to the Lists*}
  2439 
  2440 consts  listrel :: "('a * 'a)set => ('a list * 'a list)set"
  2441 
  2442 inductive "listrel(r)"
  2443  intros
  2444    Nil:  "([],[]) \<in> listrel r"
  2445    Cons: "[| (x,y) \<in> r; (xs,ys) \<in> listrel r |] ==> (x#xs, y#ys) \<in> listrel r"
  2446 
  2447 inductive_cases listrel_Nil1 [elim!]: "([],xs) \<in> listrel r"
  2448 inductive_cases listrel_Nil2 [elim!]: "(xs,[]) \<in> listrel r"
  2449 inductive_cases listrel_Cons1 [elim!]: "(y#ys,xs) \<in> listrel r"
  2450 inductive_cases listrel_Cons2 [elim!]: "(xs,y#ys) \<in> listrel r"
  2451 
  2452 
  2453 lemma listrel_mono: "r \<subseteq> s \<Longrightarrow> listrel r \<subseteq> listrel s"
  2454 apply clarify  
  2455 apply (erule listrel.induct)
  2456 apply (blast intro: listrel.intros)+
  2457 done
  2458 
  2459 lemma listrel_subset: "r \<subseteq> A \<times> A \<Longrightarrow> listrel r \<subseteq> lists A \<times> lists A"
  2460 apply clarify 
  2461 apply (erule listrel.induct, auto) 
  2462 done
  2463 
  2464 lemma listrel_refl: "refl A r \<Longrightarrow> refl (lists A) (listrel r)" 
  2465 apply (simp add: refl_def listrel_subset Ball_def)
  2466 apply (rule allI) 
  2467 apply (induct_tac x) 
  2468 apply (auto intro: listrel.intros)
  2469 done
  2470 
  2471 lemma listrel_sym: "sym r \<Longrightarrow> sym (listrel r)" 
  2472 apply (auto simp add: sym_def)
  2473 apply (erule listrel.induct) 
  2474 apply (blast intro: listrel.intros)+
  2475 done
  2476 
  2477 lemma listrel_trans: "trans r \<Longrightarrow> trans (listrel r)" 
  2478 apply (simp add: trans_def)
  2479 apply (intro allI) 
  2480 apply (rule impI) 
  2481 apply (erule listrel.induct) 
  2482 apply (blast intro: listrel.intros)+
  2483 done
  2484 
  2485 theorem equiv_listrel: "equiv A r \<Longrightarrow> equiv (lists A) (listrel r)"
  2486 by (simp add: equiv_def listrel_refl listrel_sym listrel_trans) 
  2487 
  2488 lemma listrel_Nil [simp]: "listrel r `` {[]} = {[]}"
  2489 by (blast intro: listrel.intros)
  2490 
  2491 lemma listrel_Cons:
  2492      "listrel r `` {x#xs} = set_Cons (r``{x}) (listrel r `` {xs})";
  2493 by (auto simp add: set_Cons_def intro: listrel.intros) 
  2494 
  2495 
  2496 subsection{*Miscellany*}
  2497 
  2498 subsubsection {* Characters and strings *}
  2499 
  2500 datatype nibble =
  2501     Nibble0 | Nibble1 | Nibble2 | Nibble3 | Nibble4 | Nibble5 | Nibble6 | Nibble7
  2502   | Nibble8 | Nibble9 | NibbleA | NibbleB | NibbleC | NibbleD | NibbleE | NibbleF
  2503 
  2504 datatype char = Char nibble nibble
  2505   -- "Note: canonical order of character encoding coincides with standard term ordering"
  2506 
  2507 types string = "char list"
  2508 
  2509 syntax
  2510   "_Char" :: "xstr => char"    ("CHR _")
  2511   "_String" :: "xstr => string"    ("_")
  2512 
  2513 parse_ast_translation {*
  2514   let
  2515     val constants = Syntax.Appl o map Syntax.Constant;
  2516 
  2517     fun mk_nib n = "Nibble" ^ chr (n + (if n <= 9 then ord "0" else ord "A" - 10));
  2518     fun mk_char c =
  2519       if Symbol.is_ascii c andalso Symbol.is_printable c then
  2520         constants ["Char", mk_nib (ord c div 16), mk_nib (ord c mod 16)]
  2521       else error ("Printable ASCII character expected: " ^ quote c);
  2522 
  2523     fun mk_string [] = Syntax.Constant "Nil"
  2524       | mk_string (c :: cs) = Syntax.Appl [Syntax.Constant "Cons", mk_char c, mk_string cs];
  2525 
  2526     fun char_ast_tr [Syntax.Variable xstr] =
  2527         (case Syntax.explode_xstr xstr of
  2528           [c] => mk_char c
  2529         | _ => error ("Single character expected: " ^ xstr))
  2530       | char_ast_tr asts = raise AST ("char_ast_tr", asts);
  2531 
  2532     fun string_ast_tr [Syntax.Variable xstr] =
  2533         (case Syntax.explode_xstr xstr of
  2534           [] => constants [Syntax.constrainC, "Nil", "string"]
  2535         | cs => mk_string cs)
  2536       | string_ast_tr asts = raise AST ("string_tr", asts);
  2537   in [("_Char", char_ast_tr), ("_String", string_ast_tr)] end;
  2538 *}
  2539 
  2540 ML {*
  2541 structure HOList =
  2542 struct
  2543 
  2544 local
  2545   val thy = the_context ();
  2546 in
  2547   val typ_string = Type (Sign.intern_type thy "string", []);
  2548   fun typ_list ty = Type (Sign.intern_type thy "list", [ty]);
  2549   fun term_list ty f [] = Const (Sign.intern_const thy "Nil", typ_list ty)
  2550     | term_list ty f (x::xs) = Const (Sign.intern_const thy "Cons",
  2551         ty --> typ_list ty --> typ_list ty) $ f x $ term_list ty f xs;
  2552 end;
  2553 
  2554 fun int_of_nibble h =
  2555   if "0" <= h andalso h <= "9" then ord h - ord "0"
  2556   else if "A" <= h andalso h <= "F" then ord h - ord "A" + 10
  2557   else raise Match;
  2558 
  2559 fun nibble_of_int i =
  2560   if i <= 9 then chr (ord "0" + i) else chr (ord "A" + i - 10);
  2561 
  2562 fun dest_char (Const ("List.char.Char", _) $ c1 $ c2) =
  2563       let
  2564         fun dest_nibble (Const (s, _)) = (int_of_nibble o unprefix "List.nibble.Nibble") s
  2565           | dest_nibble _ = raise Match;
  2566       in
  2567         (SOME (dest_nibble c1 * 16 + dest_nibble c2)
  2568         handle Fail _ => NONE | Match => NONE)
  2569       end
  2570   | dest_char _ = NONE;
  2571 
  2572 val print_list = Pretty.enum "," "[" "]";
  2573 
  2574 fun print_char c =
  2575   let
  2576     val i = ord c
  2577   in if i < 32
  2578     then prefix "\\" (string_of_int i)
  2579     else c
  2580   end;
  2581 
  2582 val print_string = quote;
  2583 
  2584 fun term_string s =
  2585   let
  2586     val ty_n = Type ("List.nibble", []);
  2587     val ty_c = Type ("List.char", []);
  2588     val ty_l = Type ("List.list", [ty_c]);
  2589     fun mk_nib n = Const ("List.nibble.Nibble" ^ chr (n + (if n <= 9 then ord "0" else ord "A" - 10)), ty_n);
  2590     fun mk_char c =
  2591       if Symbol.is_ascii c andalso Symbol.is_printable c then
  2592         Const ("List.char.Char", ty_n --> ty_n --> ty_c) $ mk_nib (ord c div 16) $ mk_nib (ord c mod 16)
  2593       else error ("Printable ASCII character expected: " ^ quote c);
  2594     fun mk_string c t = Const ("List.list.Cons", ty_c --> ty_l --> ty_l)
  2595       $ mk_char c $ t;
  2596   in fold_rev mk_string (explode s) (Const ("List.list.Nil", ty_l)) end;
  2597 
  2598 end;
  2599 *}
  2600 
  2601 print_ast_translation {*
  2602   let
  2603     fun dest_nib (Syntax.Constant c) =
  2604         (case explode c of
  2605           ["N", "i", "b", "b", "l", "e", h] => HOList.int_of_nibble h
  2606         | _ => raise Match)
  2607       | dest_nib _ = raise Match;
  2608 
  2609     fun dest_chr c1 c2 =
  2610       let val c = chr (dest_nib c1 * 16 + dest_nib c2)
  2611       in if Symbol.is_printable c then c else raise Match end;
  2612 
  2613     fun dest_char (Syntax.Appl [Syntax.Constant "Char", c1, c2]) = dest_chr c1 c2
  2614       | dest_char _ = raise Match;
  2615 
  2616     fun xstr cs = Syntax.Appl [Syntax.Constant "_xstr", Syntax.Variable (Syntax.implode_xstr cs)];
  2617 
  2618     fun char_ast_tr' [c1, c2] = Syntax.Appl [Syntax.Constant "_Char", xstr [dest_chr c1 c2]]
  2619       | char_ast_tr' _ = raise Match;
  2620 
  2621     fun list_ast_tr' [args] = Syntax.Appl [Syntax.Constant "_String",
  2622             xstr (map dest_char (Syntax.unfold_ast "_args" args))]
  2623       | list_ast_tr' ts = raise Match;
  2624   in [("Char", char_ast_tr'), ("@list", list_ast_tr')] end;
  2625 *}
  2626 
  2627 
  2628 subsection {* Code generator *}
  2629 
  2630 subsubsection {* Setup *}
  2631 
  2632 types_code
  2633   "list" ("_ list")
  2634 attach (term_of) {*
  2635 val term_of_list = HOLogic.mk_list;
  2636 *}
  2637 attach (test) {*
  2638 fun gen_list' aG i j = frequency
  2639   [(i, fn () => aG j :: gen_list' aG (i-1) j), (1, fn () => [])] ()
  2640 and gen_list aG i = gen_list' aG i i;
  2641 *}
  2642   "char" ("string")
  2643 attach (term_of) {*
  2644 val nibbleT = Type ("List.nibble", []);
  2645 
  2646 fun term_of_char c =
  2647   Const ("List.char.Char", nibbleT --> nibbleT --> Type ("List.char", [])) $
  2648     Const ("List.nibble.Nibble" ^ HOList.nibble_of_int (ord c div 16), nibbleT) $
  2649     Const ("List.nibble.Nibble" ^ HOList.nibble_of_int (ord c mod 16), nibbleT);
  2650 *}
  2651 attach (test) {*
  2652 fun gen_char i = chr (random_range (ord "a") (Int.min (ord "a" + i, ord "z")));
  2653 *}
  2654 
  2655 consts_code "Cons" ("(_ ::/ _)")
  2656 
  2657 code_type list
  2658   (SML "_ list")
  2659   (Haskell "![_]")
  2660 
  2661 code_const Nil
  2662   (SML "[]")
  2663   (Haskell "[]")
  2664 
  2665 code_type char
  2666   (SML "char")
  2667   (Haskell "Char")
  2668 
  2669 code_const Char
  2670   (SML "!((_),/ (_))")
  2671   (Haskell "!((_),/ (_))")
  2672 
  2673 code_instance list :: eq and char :: eq
  2674   (Haskell - and -)
  2675 
  2676 code_const "Code_Generator.eq \<Colon> 'a\<Colon>eq list \<Rightarrow> 'a list \<Rightarrow> bool"
  2677   (Haskell infixl 4 "==")
  2678 
  2679 code_const "Code_Generator.eq \<Colon> char \<Rightarrow> char \<Rightarrow> bool"
  2680   (Haskell infixl 4 "==")
  2681 
  2682 code_reserved SML
  2683   list char
  2684 
  2685 code_reserved Haskell
  2686   Char
  2687 
  2688 setup {*
  2689 let
  2690 
  2691 fun list_codegen thy defs gr dep thyname b t =
  2692   let val (gr', ps) = foldl_map (Codegen.invoke_codegen thy defs dep thyname false)
  2693     (gr, HOLogic.dest_list t)
  2694   in SOME (gr', Pretty.list "[" "]" ps) end handle TERM _ => NONE;
  2695 
  2696 fun char_codegen thy defs gr dep thyname b t =
  2697   case (Option.map chr o HOList.dest_char) t 
  2698    of SOME c =>
  2699         if Symbol.is_printable c
  2700         then SOME (gr, (Pretty.quote o Pretty.str) c)
  2701         else NONE
  2702     | NONE => NONE;
  2703 
  2704 in
  2705 
  2706   Codegen.add_codegen "list_codegen" list_codegen
  2707   #> Codegen.add_codegen "char_codegen" char_codegen
  2708   #> CodegenSerializer.add_pretty_list "SML" "List.list.Nil" "List.list.Cons"
  2709        HOList.print_list NONE (7, "::")
  2710   #> CodegenSerializer.add_pretty_list "Haskell" "List.list.Nil" "List.list.Cons"
  2711        HOList.print_list (SOME (HOList.print_char, HOList.print_string)) (5, ":")
  2712   #> CodegenPackage.add_appconst
  2713        ("List.char.Char", CodegenPackage.appgen_char HOList.dest_char)
  2714 
  2715 end;
  2716 *}
  2717 
  2718 
  2719 subsubsection {* Generation of efficient code *}
  2720 
  2721 consts
  2722   memberl :: "'a \<Rightarrow> 'a list \<Rightarrow> bool" (infixl "mem" 55)
  2723   null:: "'a list \<Rightarrow> bool"
  2724   list_inter :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list"
  2725   list_ex :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> bool"
  2726   list_all :: "('a \<Rightarrow> bool) \<Rightarrow> ('a list \<Rightarrow> bool)"
  2727   itrev :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list"
  2728   filtermap :: "('a \<Rightarrow> 'b option) \<Rightarrow> 'a list \<Rightarrow> 'b list"
  2729   map_filter :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> 'b list"
  2730 
  2731 primrec
  2732   "x mem [] = False"
  2733   "x mem (y#ys) = (x = y \<or> x mem ys)"
  2734 
  2735 primrec
  2736   "null [] = True"
  2737   "null (x#xs) = False"
  2738 
  2739 primrec
  2740   "list_inter [] bs = []"
  2741   "list_inter (a#as) bs =
  2742      (if a \<in> set bs then a # list_inter as bs else list_inter as bs)"
  2743 
  2744 primrec
  2745   "list_all P [] = True"
  2746   "list_all P (x#xs) = (P x \<and> list_all P xs)"
  2747 
  2748 primrec
  2749   "list_ex P [] = False"
  2750   "list_ex P (x#xs) = (P x \<or> list_ex P xs)"
  2751 
  2752 primrec
  2753   "filtermap f [] = []"
  2754   "filtermap f (x#xs) =
  2755      (case f x of None \<Rightarrow> filtermap f xs
  2756       | Some y \<Rightarrow> y # filtermap f xs)"
  2757 
  2758 primrec
  2759   "map_filter f P [] = []"
  2760   "map_filter f P (x#xs) =
  2761      (if P x then f x # map_filter f P xs else map_filter f P xs)"
  2762 
  2763 primrec
  2764   "itrev [] ys = ys"
  2765   "itrev (x#xs) ys = itrev xs (x#ys)"
  2766 
  2767 text {*
  2768   Only use @{text mem} for generating executable code.  Otherwise
  2769   use @{prop "x : set xs"} instead --- it is much easier to reason about.
  2770   The same is true for @{const list_all} and @{const list_ex}: write
  2771   @{text "\<forall>x\<in>set xs"} and @{text "\<exists>x\<in>set xs"} instead because the HOL
  2772   quantifiers are aleady known to the automatic provers. In fact,
  2773   the declarations in the code subsection make sure that @{text "\<in>"}, @{text "\<forall>x\<in>set xs"}
  2774   and @{text "\<exists>x\<in>set xs"} are implemented efficiently.
  2775 
  2776   Efficient emptyness check is implemented by @{const null}.
  2777 
  2778   The functions @{const itrev}, @{const filtermap} and @{const map_filter}
  2779   are just there to generate efficient code. Do not use them
  2780   for modelling and proving.
  2781 *}
  2782 
  2783 lemma mem_iff [normal post]:
  2784   "(x mem xs) = (x \<in> set xs)"
  2785   by (induct xs) auto
  2786 
  2787 lemmas in_set_code [code unfold] =
  2788   mem_iff [symmetric, THEN eq_reflection]
  2789 
  2790 lemma empty_null [code inline]:
  2791   "(xs = []) = null xs"
  2792   by (cases xs) simp_all
  2793 
  2794 lemmas null_empty [normal post] =
  2795   empty_null [symmetric]
  2796 
  2797 lemma list_inter_conv:
  2798   "set (list_inter xs ys) = set xs \<inter> set ys"
  2799   by (induct xs) auto
  2800 
  2801 lemma list_all_iff [normal post]:
  2802   "list_all P xs = (\<forall>x \<in> set xs. P x)"
  2803   by (induct xs) auto
  2804 
  2805 lemmas list_ball_code [code unfold] =
  2806   list_all_iff [symmetric, THEN eq_reflection]
  2807 
  2808 lemma list_all_append [simp]:
  2809   "list_all P (xs @ ys) = (list_all P xs \<and> list_all P ys)"
  2810   by (induct xs) auto
  2811 
  2812 lemma list_all_rev [simp]:
  2813   "list_all P (rev xs) = list_all P xs"
  2814   by (simp add: list_all_iff)
  2815 
  2816 lemma list_ex_iff [normal post]:
  2817   "list_ex P xs = (\<exists>x \<in> set xs. P x)"
  2818   by (induct xs) simp_all
  2819 
  2820 lemmas list_bex_code [code unfold] =
  2821   list_ex_iff [symmetric, THEN eq_reflection]
  2822 
  2823 lemma itrev [simp]:
  2824   "itrev xs ys = rev xs @ ys"
  2825   by (induct xs arbitrary: ys) simp_all
  2826 
  2827 lemma filtermap_conv:
  2828    "filtermap f xs = map (\<lambda>x. the (f x)) (filter (\<lambda>x. f x \<noteq> None) xs)"
  2829   by (induct xs) (simp_all split: option.split) 
  2830 
  2831 lemma map_filter_conv [simp]:
  2832   "map_filter f P xs = map f (filter P xs)"
  2833   by (induct xs) auto
  2834 
  2835 lemma rev_code [code func, code unfold, code noinline]:
  2836   "rev xs == itrev xs []"
  2837   by simp
  2838 
  2839 end