src/HOL/Lattices.thy
author wenzelm
Sat Jan 20 14:09:27 2007 +0100 (2007-01-20)
changeset 22139 539a63b98f76
parent 22068 00bed5ac9884
child 22168 627e7aee1b82
permissions -rw-r--r--
tuned ML setup;
     1 (*  Title:      HOL/Lattices.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4 *)
     5 
     6 header {* Lattices via Locales *}
     7 
     8 theory Lattices
     9 imports Orderings
    10 begin
    11 
    12 subsection{* Lattices *}
    13 
    14 text{* This theory of lattice locales only defines binary sup and inf
    15 operations. The extension to finite sets is done in theory @{text
    16 Finite_Set}. In the longer term it may be better to define arbitrary
    17 sups and infs via @{text THE}. *}
    18 
    19 locale lower_semilattice = order +
    20   fixes inf :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<sqinter>" 70)
    21   assumes inf_le1[simp]: "x \<sqinter> y \<sqsubseteq> x" and inf_le2[simp]: "x \<sqinter> y \<sqsubseteq> y"
    22   and inf_greatest: "x \<sqsubseteq> y \<Longrightarrow> x \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> y \<sqinter> z"
    23 
    24 locale upper_semilattice = order +
    25   fixes sup :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<squnion>" 65)
    26   assumes sup_ge1[simp]: "x \<sqsubseteq> x \<squnion> y" and sup_ge2[simp]: "y \<sqsubseteq> x \<squnion> y"
    27   and sup_least: "y \<sqsubseteq> x \<Longrightarrow> z \<sqsubseteq> x \<Longrightarrow> y \<squnion> z \<sqsubseteq> x"
    28 
    29 locale lattice = lower_semilattice + upper_semilattice
    30 
    31 subsubsection{* Intro and elim rules*}
    32 
    33 context lower_semilattice
    34 begin
    35 
    36 lemmas antisym_intro[intro!] = antisym
    37 
    38 lemma le_infI1[intro]: "a \<sqsubseteq> x \<Longrightarrow> a \<sqinter> b \<sqsubseteq> x"
    39 apply(subgoal_tac "a \<sqinter> b \<sqsubseteq> a")
    40  apply(blast intro:trans)
    41 apply simp
    42 done
    43 
    44 lemma le_infI2[intro]: "b \<sqsubseteq> x \<Longrightarrow> a \<sqinter> b \<sqsubseteq> x"
    45 apply(subgoal_tac "a \<sqinter> b \<sqsubseteq> b")
    46  apply(blast intro:trans)
    47 apply simp
    48 done
    49 
    50 lemma le_infI[intro!]: "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<sqinter> b"
    51 by(blast intro: inf_greatest)
    52 
    53 lemma le_infE[elim!]: "x \<sqsubseteq> a \<sqinter> b \<Longrightarrow> (x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> P) \<Longrightarrow> P"
    54 by(blast intro: trans)
    55 
    56 lemma le_inf_iff [simp]:
    57  "x \<sqsubseteq> y \<sqinter> z = (x \<sqsubseteq> y \<and> x \<sqsubseteq> z)"
    58 by blast
    59 
    60 lemma le_iff_inf: "(x \<sqsubseteq> y) = (x \<sqinter> y = x)"
    61 apply rule
    62  apply(simp add: antisym)
    63 apply(subgoal_tac "x \<sqinter> y \<sqsubseteq> y")
    64  apply(simp)
    65 apply(simp (no_asm))
    66 done
    67 
    68 end
    69 
    70 
    71 context upper_semilattice
    72 begin
    73 
    74 lemmas antisym_intro[intro!] = antisym
    75 
    76 lemma le_supI1[intro]: "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
    77 apply(subgoal_tac "a \<sqsubseteq> a \<squnion> b")
    78  apply(blast intro:trans)
    79 apply simp
    80 done
    81 
    82 lemma le_supI2[intro]: "x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
    83 apply(subgoal_tac "b \<sqsubseteq> a \<squnion> b")
    84  apply(blast intro:trans)
    85 apply simp
    86 done
    87 
    88 lemma le_supI[intro!]: "a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> a \<squnion> b \<sqsubseteq> x"
    89 by(blast intro: sup_least)
    90 
    91 lemma le_supE[elim!]: "a \<squnion> b \<sqsubseteq> x \<Longrightarrow> (a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> P) \<Longrightarrow> P"
    92 by(blast intro: trans)
    93 
    94 lemma ge_sup_conv[simp]:
    95  "x \<squnion> y \<sqsubseteq> z = (x \<sqsubseteq> z \<and> y \<sqsubseteq> z)"
    96 by blast
    97 
    98 lemma le_iff_sup: "(x \<sqsubseteq> y) = (x \<squnion> y = y)"
    99 apply rule
   100  apply(simp add: antisym)
   101 apply(subgoal_tac "x \<sqsubseteq> x \<squnion> y")
   102 apply(simp)
   103  apply(simp (no_asm))
   104 done
   105 
   106 end
   107 
   108 
   109 subsubsection{* Equational laws *}
   110 
   111 
   112 context lower_semilattice
   113 begin
   114 
   115 lemma inf_commute: "(x \<sqinter> y) = (y \<sqinter> x)"
   116 by blast
   117 
   118 lemma inf_assoc: "(x \<sqinter> y) \<sqinter> z = x \<sqinter> (y \<sqinter> z)"
   119 by blast
   120 
   121 lemma inf_idem[simp]: "x \<sqinter> x = x"
   122 by blast
   123 
   124 lemma inf_left_idem[simp]: "x \<sqinter> (x \<sqinter> y) = x \<sqinter> y"
   125 by blast
   126 
   127 lemma inf_absorb1: "x \<sqsubseteq> y \<Longrightarrow> x \<sqinter> y = x"
   128 by blast
   129 
   130 lemma inf_absorb2: "y \<sqsubseteq> x \<Longrightarrow> x \<sqinter> y = y"
   131 by blast
   132 
   133 lemma inf_left_commute: "x \<sqinter> (y \<sqinter> z) = y \<sqinter> (x \<sqinter> z)"
   134 by blast
   135 
   136 lemmas inf_ACI = inf_commute inf_assoc inf_left_commute inf_left_idem
   137 
   138 end
   139 
   140 
   141 context upper_semilattice
   142 begin
   143 
   144 lemma sup_commute: "(x \<squnion> y) = (y \<squnion> x)"
   145 by blast
   146 
   147 lemma sup_assoc: "(x \<squnion> y) \<squnion> z = x \<squnion> (y \<squnion> z)"
   148 by blast
   149 
   150 lemma sup_idem[simp]: "x \<squnion> x = x"
   151 by blast
   152 
   153 lemma sup_left_idem[simp]: "x \<squnion> (x \<squnion> y) = x \<squnion> y"
   154 by blast
   155 
   156 lemma sup_absorb1: "y \<sqsubseteq> x \<Longrightarrow> x \<squnion> y = x"
   157 by blast
   158 
   159 lemma sup_absorb2: "x \<sqsubseteq> y \<Longrightarrow> x \<squnion> y = y"
   160 by blast
   161 
   162 lemma sup_left_commute: "x \<squnion> (y \<squnion> z) = y \<squnion> (x \<squnion> z)"
   163 by blast
   164 
   165 lemmas sup_ACI = sup_commute sup_assoc sup_left_commute sup_left_idem
   166 
   167 end
   168 
   169 context lattice
   170 begin
   171 
   172 lemma inf_sup_absorb: "x \<sqinter> (x \<squnion> y) = x"
   173 by(blast intro: antisym inf_le1 inf_greatest sup_ge1)
   174 
   175 lemma sup_inf_absorb: "x \<squnion> (x \<sqinter> y) = x"
   176 by(blast intro: antisym sup_ge1 sup_least inf_le1)
   177 
   178 lemmas ACI = inf_ACI sup_ACI
   179 
   180 text{* Towards distributivity *}
   181 
   182 lemma distrib_sup_le: "x \<squnion> (y \<sqinter> z) \<sqsubseteq> (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   183 by blast
   184 
   185 lemma distrib_inf_le: "(x \<sqinter> y) \<squnion> (x \<sqinter> z) \<sqsubseteq> x \<sqinter> (y \<squnion> z)"
   186 by blast
   187 
   188 
   189 text{* If you have one of them, you have them all. *}
   190 
   191 lemma distrib_imp1:
   192 assumes D: "!!x y z. x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   193 shows "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   194 proof-
   195   have "x \<squnion> (y \<sqinter> z) = (x \<squnion> (x \<sqinter> z)) \<squnion> (y \<sqinter> z)" by(simp add:sup_inf_absorb)
   196   also have "\<dots> = x \<squnion> (z \<sqinter> (x \<squnion> y))" by(simp add:D inf_commute sup_assoc)
   197   also have "\<dots> = ((x \<squnion> y) \<sqinter> x) \<squnion> ((x \<squnion> y) \<sqinter> z)"
   198     by(simp add:inf_sup_absorb inf_commute)
   199   also have "\<dots> = (x \<squnion> y) \<sqinter> (x \<squnion> z)" by(simp add:D)
   200   finally show ?thesis .
   201 qed
   202 
   203 lemma distrib_imp2:
   204 assumes D: "!!x y z. x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   205 shows "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   206 proof-
   207   have "x \<sqinter> (y \<squnion> z) = (x \<sqinter> (x \<squnion> z)) \<sqinter> (y \<squnion> z)" by(simp add:inf_sup_absorb)
   208   also have "\<dots> = x \<sqinter> (z \<squnion> (x \<sqinter> y))" by(simp add:D sup_commute inf_assoc)
   209   also have "\<dots> = ((x \<sqinter> y) \<squnion> x) \<sqinter> ((x \<sqinter> y) \<squnion> z)"
   210     by(simp add:sup_inf_absorb sup_commute)
   211   also have "\<dots> = (x \<sqinter> y) \<squnion> (x \<sqinter> z)" by(simp add:D)
   212   finally show ?thesis .
   213 qed
   214 
   215 (* seems unused *)
   216 lemma modular_le: "x \<sqsubseteq> z \<Longrightarrow> x \<squnion> (y \<sqinter> z) \<sqsubseteq> (x \<squnion> y) \<sqinter> z"
   217 by blast
   218 
   219 end
   220 
   221 
   222 subsection{* Distributive lattices *}
   223 
   224 locale distrib_lattice = lattice +
   225   assumes sup_inf_distrib1: "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   226 
   227 context distrib_lattice
   228 begin
   229 
   230 lemma sup_inf_distrib2:
   231  "(y \<sqinter> z) \<squnion> x = (y \<squnion> x) \<sqinter> (z \<squnion> x)"
   232 by(simp add:ACI sup_inf_distrib1)
   233 
   234 lemma inf_sup_distrib1:
   235  "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   236 by(rule distrib_imp2[OF sup_inf_distrib1])
   237 
   238 lemma inf_sup_distrib2:
   239  "(y \<squnion> z) \<sqinter> x = (y \<sqinter> x) \<squnion> (z \<sqinter> x)"
   240 by(simp add:ACI inf_sup_distrib1)
   241 
   242 lemmas distrib =
   243   sup_inf_distrib1 sup_inf_distrib2 inf_sup_distrib1 inf_sup_distrib2
   244 
   245 end
   246 
   247 
   248 subsection {* min/max on linear orders as special case of inf/sup *}
   249 
   250 interpretation min_max:
   251   distrib_lattice ["op \<le>" "op <" "min \<Colon> 'a\<Colon>linorder \<Rightarrow> 'a \<Rightarrow> 'a" "max"]
   252 apply unfold_locales
   253 apply (simp add: min_def linorder_not_le order_less_imp_le)
   254 apply (simp add: min_def linorder_not_le order_less_imp_le)
   255 apply (simp add: min_def linorder_not_le order_less_imp_le)
   256 apply (simp add: max_def linorder_not_le order_less_imp_le)
   257 apply (simp add: max_def linorder_not_le order_less_imp_le)
   258 unfolding min_def max_def by auto
   259 
   260 text{* Now we have inherited antisymmetry as an intro-rule on all
   261 linear orders. This is a problem because it applies to bool, which is
   262 undesirable. *}
   263 
   264 declare
   265  min_max.antisym_intro[rule del]
   266  min_max.le_infI[rule del] min_max.le_supI[rule del]
   267  min_max.le_supE[rule del] min_max.le_infE[rule del]
   268  min_max.le_supI1[rule del] min_max.le_supI2[rule del]
   269  min_max.le_infI1[rule del] min_max.le_infI2[rule del]
   270 
   271 lemmas le_maxI1 = min_max.sup_ge1
   272 lemmas le_maxI2 = min_max.sup_ge2
   273  
   274 lemmas max_ac = min_max.sup_assoc min_max.sup_commute
   275                mk_left_commute[of max,OF min_max.sup_assoc min_max.sup_commute]
   276 
   277 lemmas min_ac = min_max.inf_assoc min_max.inf_commute
   278                mk_left_commute[of min,OF min_max.inf_assoc min_max.inf_commute]
   279 
   280 text {* ML legacy bindings *}
   281 
   282 ML {*
   283 val Least_def = @{thm Least_def}
   284 val Least_equality = @{thm Least_equality}
   285 val min_def = @{thm min_def}
   286 val min_of_mono = @{thm min_of_mono}
   287 val max_def = @{thm max_def}
   288 val max_of_mono = @{thm max_of_mono}
   289 val min_leastL = @{thm min_leastL}
   290 val max_leastL = @{thm max_leastL}
   291 val min_leastR = @{thm min_leastR}
   292 val max_leastR = @{thm max_leastR}
   293 val le_max_iff_disj = @{thm le_max_iff_disj}
   294 val le_maxI1 = @{thm le_maxI1}
   295 val le_maxI2 = @{thm le_maxI2}
   296 val less_max_iff_disj = @{thm less_max_iff_disj}
   297 val max_less_iff_conj = @{thm max_less_iff_conj}
   298 val min_less_iff_conj = @{thm min_less_iff_conj}
   299 val min_le_iff_disj = @{thm min_le_iff_disj}
   300 val min_less_iff_disj = @{thm min_less_iff_disj}
   301 val split_min = @{thm split_min}
   302 val split_max = @{thm split_max}
   303 *}
   304 
   305 end