src/HOL/Analysis/Complex_Analysis_Basics.thy
author eberlm <eberlm@in.tum.de>
Sat Aug 04 01:03:39 2018 +0200 (9 months ago)
changeset 68721 53ad5c01be3f
parent 68296 69d680e94961
child 69064 5840724b1d71
permissions -rw-r--r--
Small lemmas about analysis
     1 (*  Author: John Harrison, Marco Maggesi, Graziano Gentili, Gianni Ciolli, Valentina Bruno
     2     Ported from "hol_light/Multivariate/canal.ml" by L C Paulson (2014)
     3 *)
     4 
     5 section \<open>Complex Analysis Basics\<close>
     6 
     7 theory Complex_Analysis_Basics
     8 imports Equivalence_Lebesgue_Henstock_Integration "HOL-Library.Nonpos_Ints"
     9 begin
    10 
    11 
    12 subsection\<open>General lemmas\<close>
    13 
    14 lemma nonneg_Reals_cmod_eq_Re: "z \<in> \<real>\<^sub>\<ge>\<^sub>0 \<Longrightarrow> norm z = Re z"
    15   by (simp add: complex_nonneg_Reals_iff cmod_eq_Re)
    16 
    17 lemma has_derivative_mult_right:
    18   fixes c:: "'a :: real_normed_algebra"
    19   shows "((( * ) c) has_derivative (( * ) c)) F"
    20 by (rule has_derivative_mult_right [OF has_derivative_ident])
    21 
    22 lemma has_derivative_of_real[derivative_intros, simp]:
    23   "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_derivative (\<lambda>x. of_real (f' x))) F"
    24   using bounded_linear.has_derivative[OF bounded_linear_of_real] .
    25 
    26 lemma has_vector_derivative_real_field:
    27   "DERIV f (of_real a) :> f' \<Longrightarrow> ((\<lambda>x. f (of_real x)) has_vector_derivative f') (at a within s)"
    28   using has_derivative_compose[of of_real of_real a _ f "( * ) f'"]
    29   by (simp add: scaleR_conv_of_real ac_simps has_vector_derivative_def has_field_derivative_def)
    30 lemmas has_vector_derivative_real_complex = has_vector_derivative_real_field
    31 
    32 lemma fact_cancel:
    33   fixes c :: "'a::real_field"
    34   shows "of_nat (Suc n) * c / (fact (Suc n)) = c / (fact n)"
    35   using of_nat_neq_0 by force
    36 
    37 lemma bilinear_times:
    38   fixes c::"'a::real_algebra" shows "bilinear (\<lambda>x y::'a. x*y)"
    39   by (auto simp: bilinear_def distrib_left distrib_right intro!: linearI)
    40 
    41 lemma linear_cnj: "linear cnj"
    42   using bounded_linear.linear[OF bounded_linear_cnj] .
    43 
    44 lemma vector_derivative_cnj_within:
    45   assumes "at x within A \<noteq> bot" and "f differentiable at x within A"
    46   shows   "vector_derivative (\<lambda>z. cnj (f z)) (at x within A) = 
    47              cnj (vector_derivative f (at x within A))" (is "_ = cnj ?D")
    48 proof -
    49   let ?D = "vector_derivative f (at x within A)"
    50   from assms have "(f has_vector_derivative ?D) (at x within A)"
    51     by (subst (asm) vector_derivative_works)
    52   hence "((\<lambda>x. cnj (f x)) has_vector_derivative cnj ?D) (at x within A)"
    53     by (rule has_vector_derivative_cnj)
    54   thus ?thesis using assms by (auto dest: vector_derivative_within)
    55 qed
    56 
    57 lemma vector_derivative_cnj:
    58   assumes "f differentiable at x"
    59   shows   "vector_derivative (\<lambda>z. cnj (f z)) (at x) = cnj (vector_derivative f (at x))"
    60   using assms by (intro vector_derivative_cnj_within) auto
    61 
    62 lemma lambda_zero: "(\<lambda>h::'a::mult_zero. 0) = ( * ) 0"
    63   by auto
    64 
    65 lemma lambda_one: "(\<lambda>x::'a::monoid_mult. x) = ( * ) 1"
    66   by auto
    67 
    68 lemma uniformly_continuous_on_cmul_right [continuous_intros]:
    69   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
    70   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. f x * c)"
    71   using bounded_linear.uniformly_continuous_on[OF bounded_linear_mult_left] .
    72 
    73 lemma uniformly_continuous_on_cmul_left[continuous_intros]:
    74   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
    75   assumes "uniformly_continuous_on s f"
    76     shows "uniformly_continuous_on s (\<lambda>x. c * f x)"
    77 by (metis assms bounded_linear.uniformly_continuous_on bounded_linear_mult_right)
    78 
    79 lemma continuous_within_norm_id [continuous_intros]: "continuous (at x within S) norm"
    80   by (rule continuous_norm [OF continuous_ident])
    81 
    82 lemma continuous_on_norm_id [continuous_intros]: "continuous_on S norm"
    83   by (intro continuous_on_id continuous_on_norm)
    84 
    85 subsection\<open>DERIV stuff\<close>
    86 
    87 lemma DERIV_zero_connected_constant:
    88   fixes f :: "'a::{real_normed_field,euclidean_space} \<Rightarrow> 'a"
    89   assumes "connected S"
    90       and "open S"
    91       and "finite K"
    92       and "continuous_on S f"
    93       and "\<forall>x\<in>(S - K). DERIV f x :> 0"
    94     obtains c where "\<And>x. x \<in> S \<Longrightarrow> f(x) = c"
    95 using has_derivative_zero_connected_constant [OF assms(1-4)] assms
    96 by (metis DERIV_const has_derivative_const Diff_iff at_within_open frechet_derivative_at has_field_derivative_def)
    97 
    98 lemmas DERIV_zero_constant = has_field_derivative_zero_constant
    99 
   100 lemma DERIV_zero_unique:
   101   assumes "convex S"
   102       and d0: "\<And>x. x\<in>S \<Longrightarrow> (f has_field_derivative 0) (at x within S)"
   103       and "a \<in> S"
   104       and "x \<in> S"
   105     shows "f x = f a"
   106   by (rule has_derivative_zero_unique [OF assms(1) _ assms(4,3)])
   107      (metis d0 has_field_derivative_imp_has_derivative lambda_zero)
   108 
   109 lemma DERIV_zero_connected_unique:
   110   assumes "connected S"
   111       and "open S"
   112       and d0: "\<And>x. x\<in>S \<Longrightarrow> DERIV f x :> 0"
   113       and "a \<in> S"
   114       and "x \<in> S"
   115     shows "f x = f a"
   116     by (rule has_derivative_zero_unique_connected [OF assms(2,1) _ assms(5,4)])
   117        (metis has_field_derivative_def lambda_zero d0)
   118 
   119 lemma DERIV_transform_within:
   120   assumes "(f has_field_derivative f') (at a within S)"
   121       and "0 < d" "a \<in> S"
   122       and "\<And>x. x\<in>S \<Longrightarrow> dist x a < d \<Longrightarrow> f x = g x"
   123     shows "(g has_field_derivative f') (at a within S)"
   124   using assms unfolding has_field_derivative_def
   125   by (blast intro: has_derivative_transform_within)
   126 
   127 lemma DERIV_transform_within_open:
   128   assumes "DERIV f a :> f'"
   129       and "open S" "a \<in> S"
   130       and "\<And>x. x\<in>S \<Longrightarrow> f x = g x"
   131     shows "DERIV g a :> f'"
   132   using assms unfolding has_field_derivative_def
   133 by (metis has_derivative_transform_within_open)
   134 
   135 lemma DERIV_transform_at:
   136   assumes "DERIV f a :> f'"
   137       and "0 < d"
   138       and "\<And>x. dist x a < d \<Longrightarrow> f x = g x"
   139     shows "DERIV g a :> f'"
   140   by (blast intro: assms DERIV_transform_within)
   141 
   142 (*generalising DERIV_isconst_all, which requires type real (using the ordering)*)
   143 lemma DERIV_zero_UNIV_unique:
   144   "(\<And>x. DERIV f x :> 0) \<Longrightarrow> f x = f a"
   145   by (metis DERIV_zero_unique UNIV_I convex_UNIV)
   146 
   147 subsection \<open>Some limit theorems about real part of real series etc\<close>
   148 
   149 (*MOVE? But not to Finite_Cartesian_Product*)
   150 lemma sums_vec_nth :
   151   assumes "f sums a"
   152   shows "(\<lambda>x. f x $ i) sums a $ i"
   153 using assms unfolding sums_def
   154 by (auto dest: tendsto_vec_nth [where i=i])
   155 
   156 lemma summable_vec_nth :
   157   assumes "summable f"
   158   shows "summable (\<lambda>x. f x $ i)"
   159 using assms unfolding summable_def
   160 by (blast intro: sums_vec_nth)
   161 
   162 subsection \<open>Complex number lemmas\<close>
   163 
   164 lemma
   165   shows open_halfspace_Re_lt: "open {z. Re(z) < b}"
   166     and open_halfspace_Re_gt: "open {z. Re(z) > b}"
   167     and closed_halfspace_Re_ge: "closed {z. Re(z) \<ge> b}"
   168     and closed_halfspace_Re_le: "closed {z. Re(z) \<le> b}"
   169     and closed_halfspace_Re_eq: "closed {z. Re(z) = b}"
   170     and open_halfspace_Im_lt: "open {z. Im(z) < b}"
   171     and open_halfspace_Im_gt: "open {z. Im(z) > b}"
   172     and closed_halfspace_Im_ge: "closed {z. Im(z) \<ge> b}"
   173     and closed_halfspace_Im_le: "closed {z. Im(z) \<le> b}"
   174     and closed_halfspace_Im_eq: "closed {z. Im(z) = b}"
   175   by (intro open_Collect_less closed_Collect_le closed_Collect_eq continuous_on_Re
   176             continuous_on_Im continuous_on_id continuous_on_const)+
   177 
   178 lemma closed_complex_Reals: "closed (\<real> :: complex set)"
   179 proof -
   180   have "(\<real> :: complex set) = {z. Im z = 0}"
   181     by (auto simp: complex_is_Real_iff)
   182   then show ?thesis
   183     by (metis closed_halfspace_Im_eq)
   184 qed
   185 
   186 lemma closed_Real_halfspace_Re_le: "closed (\<real> \<inter> {w. Re w \<le> x})"
   187   by (simp add: closed_Int closed_complex_Reals closed_halfspace_Re_le)
   188 
   189 corollary closed_nonpos_Reals_complex [simp]: "closed (\<real>\<^sub>\<le>\<^sub>0 :: complex set)"
   190 proof -
   191   have "\<real>\<^sub>\<le>\<^sub>0 = \<real> \<inter> {z. Re(z) \<le> 0}"
   192     using complex_nonpos_Reals_iff complex_is_Real_iff by auto
   193   then show ?thesis
   194     by (metis closed_Real_halfspace_Re_le)
   195 qed
   196 
   197 lemma closed_Real_halfspace_Re_ge: "closed (\<real> \<inter> {w. x \<le> Re(w)})"
   198   using closed_halfspace_Re_ge
   199   by (simp add: closed_Int closed_complex_Reals)
   200 
   201 corollary closed_nonneg_Reals_complex [simp]: "closed (\<real>\<^sub>\<ge>\<^sub>0 :: complex set)"
   202 proof -
   203   have "\<real>\<^sub>\<ge>\<^sub>0 = \<real> \<inter> {z. Re(z) \<ge> 0}"
   204     using complex_nonneg_Reals_iff complex_is_Real_iff by auto
   205   then show ?thesis
   206     by (metis closed_Real_halfspace_Re_ge)
   207 qed
   208 
   209 lemma closed_real_abs_le: "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   210 proof -
   211   have "{w \<in> \<real>. \<bar>Re w\<bar> \<le> r} = (\<real> \<inter> {w. Re w \<le> r}) \<inter> (\<real> \<inter> {w. Re w \<ge> -r})"
   212     by auto
   213   then show "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   214     by (simp add: closed_Int closed_Real_halfspace_Re_ge closed_Real_halfspace_Re_le)
   215 qed
   216 
   217 lemma real_lim:
   218   fixes l::complex
   219   assumes "(f \<longlongrightarrow> l) F" and "~(trivial_limit F)" and "eventually P F" and "\<And>a. P a \<Longrightarrow> f a \<in> \<real>"
   220   shows  "l \<in> \<real>"
   221 proof (rule Lim_in_closed_set[OF closed_complex_Reals _ assms(2,1)])
   222   show "eventually (\<lambda>x. f x \<in> \<real>) F"
   223     using assms(3, 4) by (auto intro: eventually_mono)
   224 qed
   225 
   226 lemma real_lim_sequentially:
   227   fixes l::complex
   228   shows "(f \<longlongrightarrow> l) sequentially \<Longrightarrow> (\<exists>N. \<forall>n\<ge>N. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   229 by (rule real_lim [where F=sequentially]) (auto simp: eventually_sequentially)
   230 
   231 lemma real_series:
   232   fixes l::complex
   233   shows "f sums l \<Longrightarrow> (\<And>n. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   234 unfolding sums_def
   235 by (metis real_lim_sequentially sum_in_Reals)
   236 
   237 lemma Lim_null_comparison_Re:
   238   assumes "eventually (\<lambda>x. norm(f x) \<le> Re(g x)) F" "(g \<longlongrightarrow> 0) F" shows "(f \<longlongrightarrow> 0) F"
   239   by (rule Lim_null_comparison[OF assms(1)] tendsto_eq_intros assms(2))+ simp
   240 
   241 subsection\<open>Holomorphic functions\<close>
   242 
   243 definition holomorphic_on :: "[complex \<Rightarrow> complex, complex set] \<Rightarrow> bool"
   244            (infixl "(holomorphic'_on)" 50)
   245   where "f holomorphic_on s \<equiv> \<forall>x\<in>s. f field_differentiable (at x within s)"
   246 
   247 named_theorems holomorphic_intros "structural introduction rules for holomorphic_on"
   248 
   249 lemma holomorphic_onI [intro?]: "(\<And>x. x \<in> s \<Longrightarrow> f field_differentiable (at x within s)) \<Longrightarrow> f holomorphic_on s"
   250   by (simp add: holomorphic_on_def)
   251 
   252 lemma holomorphic_onD [dest?]: "\<lbrakk>f holomorphic_on s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x within s)"
   253   by (simp add: holomorphic_on_def)
   254 
   255 lemma holomorphic_on_imp_differentiable_on:
   256     "f holomorphic_on s \<Longrightarrow> f differentiable_on s"
   257   unfolding holomorphic_on_def differentiable_on_def
   258   by (simp add: field_differentiable_imp_differentiable)
   259 
   260 lemma holomorphic_on_imp_differentiable_at:
   261    "\<lbrakk>f holomorphic_on s; open s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x)"
   262 using at_within_open holomorphic_on_def by fastforce
   263 
   264 lemma holomorphic_on_empty [holomorphic_intros]: "f holomorphic_on {}"
   265   by (simp add: holomorphic_on_def)
   266 
   267 lemma holomorphic_on_open:
   268     "open s \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>f'. DERIV f x :> f')"
   269   by (auto simp: holomorphic_on_def field_differentiable_def has_field_derivative_def at_within_open [of _ s])
   270 
   271 lemma holomorphic_on_imp_continuous_on:
   272     "f holomorphic_on s \<Longrightarrow> continuous_on s f"
   273   by (metis field_differentiable_imp_continuous_at continuous_on_eq_continuous_within holomorphic_on_def)
   274 
   275 lemma holomorphic_on_subset [elim]:
   276     "f holomorphic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f holomorphic_on t"
   277   unfolding holomorphic_on_def
   278   by (metis field_differentiable_within_subset subsetD)
   279 
   280 lemma holomorphic_transform: "\<lbrakk>f holomorphic_on s; \<And>x. x \<in> s \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> g holomorphic_on s"
   281   by (metis field_differentiable_transform_within linordered_field_no_ub holomorphic_on_def)
   282 
   283 lemma holomorphic_cong: "s = t ==> (\<And>x. x \<in> s \<Longrightarrow> f x = g x) \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> g holomorphic_on t"
   284   by (metis holomorphic_transform)
   285 
   286 lemma holomorphic_on_linear [simp, holomorphic_intros]: "(( * ) c) holomorphic_on s"
   287   unfolding holomorphic_on_def by (metis field_differentiable_linear)
   288 
   289 lemma holomorphic_on_const [simp, holomorphic_intros]: "(\<lambda>z. c) holomorphic_on s"
   290   unfolding holomorphic_on_def by (metis field_differentiable_const)
   291 
   292 lemma holomorphic_on_ident [simp, holomorphic_intros]: "(\<lambda>x. x) holomorphic_on s"
   293   unfolding holomorphic_on_def by (metis field_differentiable_ident)
   294 
   295 lemma holomorphic_on_id [simp, holomorphic_intros]: "id holomorphic_on s"
   296   unfolding id_def by (rule holomorphic_on_ident)
   297 
   298 lemma holomorphic_on_compose:
   299   "f holomorphic_on s \<Longrightarrow> g holomorphic_on (f ` s) \<Longrightarrow> (g o f) holomorphic_on s"
   300   using field_differentiable_compose_within[of f _ s g]
   301   by (auto simp: holomorphic_on_def)
   302 
   303 lemma holomorphic_on_compose_gen:
   304   "f holomorphic_on s \<Longrightarrow> g holomorphic_on t \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> (g o f) holomorphic_on s"
   305   by (metis holomorphic_on_compose holomorphic_on_subset)
   306 
   307 lemma holomorphic_on_balls_imp_entire:
   308   assumes "\<not>bdd_above A" "\<And>r. r \<in> A \<Longrightarrow> f holomorphic_on ball c r"
   309   shows   "f holomorphic_on B"
   310 proof (rule holomorphic_on_subset)
   311   show "f holomorphic_on UNIV" unfolding holomorphic_on_def
   312   proof
   313     fix z :: complex
   314     from \<open>\<not>bdd_above A\<close> obtain r where r: "r \<in> A" "r > norm (z - c)"
   315       by (meson bdd_aboveI not_le)
   316     with assms(2) have "f holomorphic_on ball c r" by blast
   317     moreover from r have "z \<in> ball c r" by (auto simp: dist_norm norm_minus_commute)
   318     ultimately show "f field_differentiable at z"
   319       by (auto simp: holomorphic_on_def at_within_open[of _ "ball c r"])
   320   qed
   321 qed auto
   322 
   323 lemma holomorphic_on_balls_imp_entire':
   324   assumes "\<And>r. r > 0 \<Longrightarrow> f holomorphic_on ball c r"
   325   shows   "f holomorphic_on B"
   326 proof (rule holomorphic_on_balls_imp_entire)
   327   {
   328     fix M :: real
   329     have "\<exists>x. x > max M 0" by (intro gt_ex)
   330     hence "\<exists>x>0. x > M" by auto
   331   }
   332   thus "\<not>bdd_above {(0::real)<..}" unfolding bdd_above_def
   333     by (auto simp: not_le)
   334 qed (insert assms, auto)
   335 
   336 lemma holomorphic_on_minus [holomorphic_intros]: "f holomorphic_on s \<Longrightarrow> (\<lambda>z. -(f z)) holomorphic_on s"
   337   by (metis field_differentiable_minus holomorphic_on_def)
   338 
   339 lemma holomorphic_on_add [holomorphic_intros]:
   340   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z + g z) holomorphic_on s"
   341   unfolding holomorphic_on_def by (metis field_differentiable_add)
   342 
   343 lemma holomorphic_on_diff [holomorphic_intros]:
   344   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z - g z) holomorphic_on s"
   345   unfolding holomorphic_on_def by (metis field_differentiable_diff)
   346 
   347 lemma holomorphic_on_mult [holomorphic_intros]:
   348   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z * g z) holomorphic_on s"
   349   unfolding holomorphic_on_def by (metis field_differentiable_mult)
   350 
   351 lemma holomorphic_on_inverse [holomorphic_intros]:
   352   "\<lbrakk>f holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. inverse (f z)) holomorphic_on s"
   353   unfolding holomorphic_on_def by (metis field_differentiable_inverse)
   354 
   355 lemma holomorphic_on_divide [holomorphic_intros]:
   356   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. f z / g z) holomorphic_on s"
   357   unfolding holomorphic_on_def by (metis field_differentiable_divide)
   358 
   359 lemma holomorphic_on_power [holomorphic_intros]:
   360   "f holomorphic_on s \<Longrightarrow> (\<lambda>z. (f z)^n) holomorphic_on s"
   361   unfolding holomorphic_on_def by (metis field_differentiable_power)
   362 
   363 lemma holomorphic_on_sum [holomorphic_intros]:
   364   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) holomorphic_on s"
   365   unfolding holomorphic_on_def by (metis field_differentiable_sum)
   366 
   367 lemma holomorphic_on_prod [holomorphic_intros]:
   368   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. prod (\<lambda>i. f i x) I) holomorphic_on s"
   369   by (induction I rule: infinite_finite_induct) (auto intro: holomorphic_intros)
   370 
   371 lemma holomorphic_pochhammer [holomorphic_intros]:
   372   "f holomorphic_on A \<Longrightarrow> (\<lambda>s. pochhammer (f s) n) holomorphic_on A"
   373   by (induction n) (auto intro!: holomorphic_intros simp: pochhammer_Suc)
   374 
   375 lemma holomorphic_on_scaleR [holomorphic_intros]:
   376   "f holomorphic_on A \<Longrightarrow> (\<lambda>x. c *\<^sub>R f x) holomorphic_on A"
   377   by (auto simp: scaleR_conv_of_real intro!: holomorphic_intros)
   378 
   379 lemma holomorphic_on_Un [holomorphic_intros]:
   380   assumes "f holomorphic_on A" "f holomorphic_on B" "open A" "open B"
   381   shows   "f holomorphic_on (A \<union> B)"
   382   using assms by (auto simp: holomorphic_on_def  at_within_open[of _ A]
   383                              at_within_open[of _ B]  at_within_open[of _ "A \<union> B"] open_Un)
   384 
   385 lemma holomorphic_on_If_Un [holomorphic_intros]:
   386   assumes "f holomorphic_on A" "g holomorphic_on B" "open A" "open B"
   387   assumes "\<And>z. z \<in> A \<Longrightarrow> z \<in> B \<Longrightarrow> f z = g z"
   388   shows   "(\<lambda>z. if z \<in> A then f z else g z) holomorphic_on (A \<union> B)" (is "?h holomorphic_on _")
   389 proof (intro holomorphic_on_Un)
   390   note \<open>f holomorphic_on A\<close>
   391   also have "f holomorphic_on A \<longleftrightarrow> ?h holomorphic_on A"
   392     by (intro holomorphic_cong) auto
   393   finally show \<dots> .
   394 next
   395   note \<open>g holomorphic_on B\<close>
   396   also have "g holomorphic_on B \<longleftrightarrow> ?h holomorphic_on B"
   397     using assms by (intro holomorphic_cong) auto
   398   finally show \<dots> .
   399 qed (insert assms, auto)
   400 
   401 lemma leibniz_rule_holomorphic:
   402   fixes f::"complex \<Rightarrow> 'b::euclidean_space \<Rightarrow> complex"
   403   assumes "\<And>x t. x \<in> U \<Longrightarrow> t \<in> cbox a b \<Longrightarrow> ((\<lambda>x. f x t) has_field_derivative fx x t) (at x within U)"
   404   assumes "\<And>x. x \<in> U \<Longrightarrow> (f x) integrable_on cbox a b"
   405   assumes "continuous_on (U \<times> (cbox a b)) (\<lambda>(x, t). fx x t)"
   406   assumes "convex U"
   407   shows "(\<lambda>x. integral (cbox a b) (f x)) holomorphic_on U"
   408   using leibniz_rule_field_differentiable[OF assms(1-3) _ assms(4)]
   409   by (auto simp: holomorphic_on_def)
   410 
   411 lemma DERIV_deriv_iff_field_differentiable:
   412   "DERIV f x :> deriv f x \<longleftrightarrow> f field_differentiable at x"
   413   unfolding field_differentiable_def by (metis DERIV_imp_deriv)
   414 
   415 lemma holomorphic_derivI:
   416      "\<lbrakk>f holomorphic_on S; open S; x \<in> S\<rbrakk>
   417       \<Longrightarrow> (f has_field_derivative deriv f x) (at x within T)"
   418 by (metis DERIV_deriv_iff_field_differentiable at_within_open  holomorphic_on_def has_field_derivative_at_within)
   419 
   420 lemma complex_derivative_chain:
   421   "f field_differentiable at x \<Longrightarrow> g field_differentiable at (f x)
   422     \<Longrightarrow> deriv (g o f) x = deriv g (f x) * deriv f x"
   423   by (metis DERIV_deriv_iff_field_differentiable DERIV_chain DERIV_imp_deriv)
   424 
   425 lemma deriv_linear [simp]: "deriv (\<lambda>w. c * w) = (\<lambda>z. c)"
   426   by (metis DERIV_imp_deriv DERIV_cmult_Id)
   427 
   428 lemma deriv_ident [simp]: "deriv (\<lambda>w. w) = (\<lambda>z. 1)"
   429   by (metis DERIV_imp_deriv DERIV_ident)
   430 
   431 lemma deriv_id [simp]: "deriv id = (\<lambda>z. 1)"
   432   by (simp add: id_def)
   433 
   434 lemma deriv_const [simp]: "deriv (\<lambda>w. c) = (\<lambda>z. 0)"
   435   by (metis DERIV_imp_deriv DERIV_const)
   436 
   437 lemma deriv_add [simp]:
   438   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   439    \<Longrightarrow> deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   440   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   441   by (auto intro!: DERIV_imp_deriv derivative_intros)
   442 
   443 lemma deriv_diff [simp]:
   444   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   445    \<Longrightarrow> deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   446   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   447   by (auto intro!: DERIV_imp_deriv derivative_intros)
   448 
   449 lemma deriv_mult [simp]:
   450   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   451    \<Longrightarrow> deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   452   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   453   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   454 
   455 lemma deriv_cmult:
   456   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. c * f w) z = c * deriv f z"
   457   by simp
   458 
   459 lemma deriv_cmult_right:
   460   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w * c) z = deriv f z * c"
   461   by simp
   462 
   463 lemma deriv_inverse [simp]:
   464   "\<lbrakk>f field_differentiable at z; f z \<noteq> 0\<rbrakk>
   465    \<Longrightarrow> deriv (\<lambda>w. inverse (f w)) z = - deriv f z / f z ^ 2"
   466   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   467   by (safe intro!: DERIV_imp_deriv derivative_eq_intros) (auto simp: divide_simps power2_eq_square)
   468 
   469 lemma deriv_divide [simp]:
   470   "\<lbrakk>f field_differentiable at z; g field_differentiable at z; g z \<noteq> 0\<rbrakk>
   471    \<Longrightarrow> deriv (\<lambda>w. f w / g w) z = (deriv f z * g z - f z * deriv g z) / g z ^ 2"
   472   by (simp add: field_class.field_divide_inverse field_differentiable_inverse)
   473      (simp add: divide_simps power2_eq_square)
   474 
   475 lemma deriv_cdivide_right:
   476   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w / c) z = deriv f z / c"
   477   by (simp add: field_class.field_divide_inverse)
   478 
   479 lemma complex_derivative_transform_within_open:
   480   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; open s; z \<in> s; \<And>w. w \<in> s \<Longrightarrow> f w = g w\<rbrakk>
   481    \<Longrightarrow> deriv f z = deriv g z"
   482   unfolding holomorphic_on_def
   483   by (rule DERIV_imp_deriv)
   484      (metis DERIV_deriv_iff_field_differentiable DERIV_transform_within_open at_within_open)
   485 
   486 lemma deriv_compose_linear:
   487   "f field_differentiable at (c * z) \<Longrightarrow> deriv (\<lambda>w. f (c * w)) z = c * deriv f (c * z)"
   488 apply (rule DERIV_imp_deriv)
   489   unfolding DERIV_deriv_iff_field_differentiable [symmetric]
   490   by (metis (full_types) DERIV_chain2 DERIV_cmult_Id mult.commute)
   491 
   492 
   493 lemma nonzero_deriv_nonconstant:
   494   assumes df: "DERIV f \<xi> :> df" and S: "open S" "\<xi> \<in> S" and "df \<noteq> 0"
   495     shows "\<not> f constant_on S"
   496 unfolding constant_on_def
   497 by (metis \<open>df \<noteq> 0\<close> DERIV_transform_within_open [OF df S] DERIV_const DERIV_unique)
   498 
   499 lemma holomorphic_nonconstant:
   500   assumes holf: "f holomorphic_on S" and "open S" "\<xi> \<in> S" "deriv f \<xi> \<noteq> 0"
   501     shows "\<not> f constant_on S"
   502   by (rule nonzero_deriv_nonconstant [of f "deriv f \<xi>" \<xi> S])
   503     (use assms in \<open>auto simp: holomorphic_derivI\<close>)
   504 
   505 subsection\<open>Caratheodory characterization\<close>
   506 
   507 lemma field_differentiable_caratheodory_at:
   508   "f field_differentiable (at z) \<longleftrightarrow>
   509          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z) g)"
   510   using CARAT_DERIV [of f]
   511   by (simp add: field_differentiable_def has_field_derivative_def)
   512 
   513 lemma field_differentiable_caratheodory_within:
   514   "f field_differentiable (at z within s) \<longleftrightarrow>
   515          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z within s) g)"
   516   using DERIV_caratheodory_within [of f]
   517   by (simp add: field_differentiable_def has_field_derivative_def)
   518 
   519 subsection\<open>Analyticity on a set\<close>
   520 
   521 definition analytic_on (infixl "(analytic'_on)" 50)
   522   where "f analytic_on S \<equiv> \<forall>x \<in> S. \<exists>e. 0 < e \<and> f holomorphic_on (ball x e)"
   523 
   524 named_theorems analytic_intros "introduction rules for proving analyticity"
   525 
   526 lemma analytic_imp_holomorphic: "f analytic_on S \<Longrightarrow> f holomorphic_on S"
   527   by (simp add: at_within_open [OF _ open_ball] analytic_on_def holomorphic_on_def)
   528      (metis centre_in_ball field_differentiable_at_within)
   529 
   530 lemma analytic_on_open: "open S \<Longrightarrow> f analytic_on S \<longleftrightarrow> f holomorphic_on S"
   531 apply (auto simp: analytic_imp_holomorphic)
   532 apply (auto simp: analytic_on_def holomorphic_on_def)
   533 by (metis holomorphic_on_def holomorphic_on_subset open_contains_ball)
   534 
   535 lemma analytic_on_imp_differentiable_at:
   536   "f analytic_on S \<Longrightarrow> x \<in> S \<Longrightarrow> f field_differentiable (at x)"
   537  apply (auto simp: analytic_on_def holomorphic_on_def)
   538 by (metis open_ball centre_in_ball field_differentiable_within_open)
   539 
   540 lemma analytic_on_subset: "f analytic_on S \<Longrightarrow> T \<subseteq> S \<Longrightarrow> f analytic_on T"
   541   by (auto simp: analytic_on_def)
   542 
   543 lemma analytic_on_Un: "f analytic_on (S \<union> T) \<longleftrightarrow> f analytic_on S \<and> f analytic_on T"
   544   by (auto simp: analytic_on_def)
   545 
   546 lemma analytic_on_Union: "f analytic_on (\<Union>\<T>) \<longleftrightarrow> (\<forall>T \<in> \<T>. f analytic_on T)"
   547   by (auto simp: analytic_on_def)
   548 
   549 lemma analytic_on_UN: "f analytic_on (\<Union>i\<in>I. S i) \<longleftrightarrow> (\<forall>i\<in>I. f analytic_on (S i))"
   550   by (auto simp: analytic_on_def)
   551 
   552 lemma analytic_on_holomorphic:
   553   "f analytic_on S \<longleftrightarrow> (\<exists>T. open T \<and> S \<subseteq> T \<and> f holomorphic_on T)"
   554   (is "?lhs = ?rhs")
   555 proof -
   556   have "?lhs \<longleftrightarrow> (\<exists>T. open T \<and> S \<subseteq> T \<and> f analytic_on T)"
   557   proof safe
   558     assume "f analytic_on S"
   559     then show "\<exists>T. open T \<and> S \<subseteq> T \<and> f analytic_on T"
   560       apply (simp add: analytic_on_def)
   561       apply (rule exI [where x="\<Union>{U. open U \<and> f analytic_on U}"], auto)
   562       apply (metis open_ball analytic_on_open centre_in_ball)
   563       by (metis analytic_on_def)
   564   next
   565     fix T
   566     assume "open T" "S \<subseteq> T" "f analytic_on T"
   567     then show "f analytic_on S"
   568         by (metis analytic_on_subset)
   569   qed
   570   also have "... \<longleftrightarrow> ?rhs"
   571     by (auto simp: analytic_on_open)
   572   finally show ?thesis .
   573 qed
   574 
   575 lemma analytic_on_linear [analytic_intros,simp]: "(( * ) c) analytic_on S"
   576   by (auto simp add: analytic_on_holomorphic)
   577 
   578 lemma analytic_on_const [analytic_intros,simp]: "(\<lambda>z. c) analytic_on S"
   579   by (metis analytic_on_def holomorphic_on_const zero_less_one)
   580 
   581 lemma analytic_on_ident [analytic_intros,simp]: "(\<lambda>x. x) analytic_on S"
   582   by (simp add: analytic_on_def gt_ex)
   583 
   584 lemma analytic_on_id [analytic_intros]: "id analytic_on S"
   585   unfolding id_def by (rule analytic_on_ident)
   586 
   587 lemma analytic_on_compose:
   588   assumes f: "f analytic_on S"
   589       and g: "g analytic_on (f ` S)"
   590     shows "(g o f) analytic_on S"
   591 unfolding analytic_on_def
   592 proof (intro ballI)
   593   fix x
   594   assume x: "x \<in> S"
   595   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball x e" using f
   596     by (metis analytic_on_def)
   597   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball (f x) e'" using g
   598     by (metis analytic_on_def g image_eqI x)
   599   have "isCont f x"
   600     by (metis analytic_on_imp_differentiable_at field_differentiable_imp_continuous_at f x)
   601   with e' obtain d where d: "0 < d" and fd: "f ` ball x d \<subseteq> ball (f x) e'"
   602      by (auto simp: continuous_at_ball)
   603   have "g \<circ> f holomorphic_on ball x (min d e)"
   604     apply (rule holomorphic_on_compose)
   605     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   606     by (metis fd gh holomorphic_on_subset image_mono min.cobounded1 subset_ball)
   607   then show "\<exists>e>0. g \<circ> f holomorphic_on ball x e"
   608     by (metis d e min_less_iff_conj)
   609 qed
   610 
   611 lemma analytic_on_compose_gen:
   612   "f analytic_on S \<Longrightarrow> g analytic_on T \<Longrightarrow> (\<And>z. z \<in> S \<Longrightarrow> f z \<in> T)
   613              \<Longrightarrow> g o f analytic_on S"
   614 by (metis analytic_on_compose analytic_on_subset image_subset_iff)
   615 
   616 lemma analytic_on_neg [analytic_intros]:
   617   "f analytic_on S \<Longrightarrow> (\<lambda>z. -(f z)) analytic_on S"
   618 by (metis analytic_on_holomorphic holomorphic_on_minus)
   619 
   620 lemma analytic_on_add [analytic_intros]:
   621   assumes f: "f analytic_on S"
   622       and g: "g analytic_on S"
   623     shows "(\<lambda>z. f z + g z) analytic_on S"
   624 unfolding analytic_on_def
   625 proof (intro ballI)
   626   fix z
   627   assume z: "z \<in> S"
   628   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   629     by (metis analytic_on_def)
   630   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   631     by (metis analytic_on_def g z)
   632   have "(\<lambda>z. f z + g z) holomorphic_on ball z (min e e')"
   633     apply (rule holomorphic_on_add)
   634     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   635     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   636   then show "\<exists>e>0. (\<lambda>z. f z + g z) holomorphic_on ball z e"
   637     by (metis e e' min_less_iff_conj)
   638 qed
   639 
   640 lemma analytic_on_diff [analytic_intros]:
   641   assumes f: "f analytic_on S"
   642       and g: "g analytic_on S"
   643     shows "(\<lambda>z. f z - g z) analytic_on S"
   644 unfolding analytic_on_def
   645 proof (intro ballI)
   646   fix z
   647   assume z: "z \<in> S"
   648   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   649     by (metis analytic_on_def)
   650   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   651     by (metis analytic_on_def g z)
   652   have "(\<lambda>z. f z - g z) holomorphic_on ball z (min e e')"
   653     apply (rule holomorphic_on_diff)
   654     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   655     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   656   then show "\<exists>e>0. (\<lambda>z. f z - g z) holomorphic_on ball z e"
   657     by (metis e e' min_less_iff_conj)
   658 qed
   659 
   660 lemma analytic_on_mult [analytic_intros]:
   661   assumes f: "f analytic_on S"
   662       and g: "g analytic_on S"
   663     shows "(\<lambda>z. f z * g z) analytic_on S"
   664 unfolding analytic_on_def
   665 proof (intro ballI)
   666   fix z
   667   assume z: "z \<in> S"
   668   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   669     by (metis analytic_on_def)
   670   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   671     by (metis analytic_on_def g z)
   672   have "(\<lambda>z. f z * g z) holomorphic_on ball z (min e e')"
   673     apply (rule holomorphic_on_mult)
   674     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   675     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   676   then show "\<exists>e>0. (\<lambda>z. f z * g z) holomorphic_on ball z e"
   677     by (metis e e' min_less_iff_conj)
   678 qed
   679 
   680 lemma analytic_on_inverse [analytic_intros]:
   681   assumes f: "f analytic_on S"
   682       and nz: "(\<And>z. z \<in> S \<Longrightarrow> f z \<noteq> 0)"
   683     shows "(\<lambda>z. inverse (f z)) analytic_on S"
   684 unfolding analytic_on_def
   685 proof (intro ballI)
   686   fix z
   687   assume z: "z \<in> S"
   688   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   689     by (metis analytic_on_def)
   690   have "continuous_on (ball z e) f"
   691     by (metis fh holomorphic_on_imp_continuous_on)
   692   then obtain e' where e': "0 < e'" and nz': "\<And>y. dist z y < e' \<Longrightarrow> f y \<noteq> 0"
   693     by (metis open_ball centre_in_ball continuous_on_open_avoid e z nz)
   694   have "(\<lambda>z. inverse (f z)) holomorphic_on ball z (min e e')"
   695     apply (rule holomorphic_on_inverse)
   696     apply (metis fh holomorphic_on_subset min.cobounded2 min.commute subset_ball)
   697     by (metis nz' mem_ball min_less_iff_conj)
   698   then show "\<exists>e>0. (\<lambda>z. inverse (f z)) holomorphic_on ball z e"
   699     by (metis e e' min_less_iff_conj)
   700 qed
   701 
   702 lemma analytic_on_divide [analytic_intros]:
   703   assumes f: "f analytic_on S"
   704       and g: "g analytic_on S"
   705       and nz: "(\<And>z. z \<in> S \<Longrightarrow> g z \<noteq> 0)"
   706     shows "(\<lambda>z. f z / g z) analytic_on S"
   707 unfolding divide_inverse
   708 by (metis analytic_on_inverse analytic_on_mult f g nz)
   709 
   710 lemma analytic_on_power [analytic_intros]:
   711   "f analytic_on S \<Longrightarrow> (\<lambda>z. (f z) ^ n) analytic_on S"
   712 by (induct n) (auto simp: analytic_on_mult)
   713 
   714 lemma analytic_on_sum [analytic_intros]:
   715   "(\<And>i. i \<in> I \<Longrightarrow> (f i) analytic_on S) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) analytic_on S"
   716   by (induct I rule: infinite_finite_induct) (auto simp: analytic_on_const analytic_on_add)
   717 
   718 lemma deriv_left_inverse:
   719   assumes "f holomorphic_on S" and "g holomorphic_on T"
   720       and "open S" and "open T"
   721       and "f ` S \<subseteq> T"
   722       and [simp]: "\<And>z. z \<in> S \<Longrightarrow> g (f z) = z"
   723       and "w \<in> S"
   724     shows "deriv f w * deriv g (f w) = 1"
   725 proof -
   726   have "deriv f w * deriv g (f w) = deriv g (f w) * deriv f w"
   727     by (simp add: algebra_simps)
   728   also have "... = deriv (g o f) w"
   729     using assms
   730     by (metis analytic_on_imp_differentiable_at analytic_on_open complex_derivative_chain image_subset_iff)
   731   also have "... = deriv id w"
   732   proof (rule complex_derivative_transform_within_open [where s=S])
   733     show "g \<circ> f holomorphic_on S"
   734       by (rule assms holomorphic_on_compose_gen holomorphic_intros)+
   735   qed (use assms in auto)
   736   also have "... = 1"
   737     by simp
   738   finally show ?thesis .
   739 qed
   740 
   741 subsection\<open>analyticity at a point\<close>
   742 
   743 lemma analytic_at_ball:
   744   "f analytic_on {z} \<longleftrightarrow> (\<exists>e. 0<e \<and> f holomorphic_on ball z e)"
   745 by (metis analytic_on_def singleton_iff)
   746 
   747 lemma analytic_at:
   748     "f analytic_on {z} \<longleftrightarrow> (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s)"
   749 by (metis analytic_on_holomorphic empty_subsetI insert_subset)
   750 
   751 lemma analytic_on_analytic_at:
   752     "f analytic_on s \<longleftrightarrow> (\<forall>z \<in> s. f analytic_on {z})"
   753 by (metis analytic_at_ball analytic_on_def)
   754 
   755 lemma analytic_at_two:
   756   "f analytic_on {z} \<and> g analytic_on {z} \<longleftrightarrow>
   757    (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s \<and> g holomorphic_on s)"
   758   (is "?lhs = ?rhs")
   759 proof
   760   assume ?lhs
   761   then obtain s t
   762     where st: "open s" "z \<in> s" "f holomorphic_on s"
   763               "open t" "z \<in> t" "g holomorphic_on t"
   764     by (auto simp: analytic_at)
   765   show ?rhs
   766     apply (rule_tac x="s \<inter> t" in exI)
   767     using st
   768     apply (auto simp: Diff_subset holomorphic_on_subset)
   769     done
   770 next
   771   assume ?rhs
   772   then show ?lhs
   773     by (force simp add: analytic_at)
   774 qed
   775 
   776 subsection\<open>Combining theorems for derivative with ``analytic at'' hypotheses\<close>
   777 
   778 lemma
   779   assumes "f analytic_on {z}" "g analytic_on {z}"
   780   shows complex_derivative_add_at: "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   781     and complex_derivative_diff_at: "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   782     and complex_derivative_mult_at: "deriv (\<lambda>w. f w * g w) z =
   783            f z * deriv g z + deriv f z * g z"
   784 proof -
   785   obtain s where s: "open s" "z \<in> s" "f holomorphic_on s" "g holomorphic_on s"
   786     using assms by (metis analytic_at_two)
   787   show "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   788     apply (rule DERIV_imp_deriv [OF DERIV_add])
   789     using s
   790     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   791     done
   792   show "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   793     apply (rule DERIV_imp_deriv [OF DERIV_diff])
   794     using s
   795     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   796     done
   797   show "deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   798     apply (rule DERIV_imp_deriv [OF DERIV_mult'])
   799     using s
   800     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   801     done
   802 qed
   803 
   804 lemma deriv_cmult_at:
   805   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. c * f w) z = c * deriv f z"
   806 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   807 
   808 lemma deriv_cmult_right_at:
   809   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. f w * c) z = deriv f z * c"
   810 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   811 
   812 subsection\<open>Complex differentiation of sequences and series\<close>
   813 
   814 (* TODO: Could probably be simplified using Uniform_Limit *)
   815 lemma has_complex_derivative_sequence:
   816   fixes S :: "complex set"
   817   assumes cvs: "convex S"
   818       and df:  "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x within S)"
   819       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> S \<longrightarrow> norm (f' n x - g' x) \<le> e"
   820       and "\<exists>x l. x \<in> S \<and> ((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   821     shows "\<exists>g. \<forall>x \<in> S. ((\<lambda>n. f n x) \<longlongrightarrow> g x) sequentially \<and>
   822                        (g has_field_derivative (g' x)) (at x within S)"
   823 proof -
   824   from assms obtain x l where x: "x \<in> S" and tf: "((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   825     by blast
   826   { fix e::real assume e: "e > 0"
   827     then obtain N where N: "\<forall>n\<ge>N. \<forall>x. x \<in> S \<longrightarrow> cmod (f' n x - g' x) \<le> e"
   828       by (metis conv)
   829     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>S. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   830     proof (rule exI [of _ N], clarify)
   831       fix n y h
   832       assume "N \<le> n" "y \<in> S"
   833       then have "cmod (f' n y - g' y) \<le> e"
   834         by (metis N)
   835       then have "cmod h * cmod (f' n y - g' y) \<le> cmod h * e"
   836         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   837       then show "cmod (f' n y * h - g' y * h) \<le> e * cmod h"
   838         by (simp add: norm_mult [symmetric] field_simps)
   839     qed
   840   } note ** = this
   841   show ?thesis
   842     unfolding has_field_derivative_def
   843   proof (rule has_derivative_sequence [OF cvs _ _ x])
   844     show "(\<lambda>n. f n x) \<longlonglongrightarrow> l"
   845       by (rule tf)
   846   next show "\<And>e. e > 0 \<Longrightarrow> \<forall>\<^sub>F n in sequentially. \<forall>x\<in>S. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   847       unfolding eventually_sequentially by (blast intro: **)
   848   qed (metis has_field_derivative_def df)
   849 qed
   850 
   851 lemma has_complex_derivative_series:
   852   fixes S :: "complex set"
   853   assumes cvs: "convex S"
   854       and df:  "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x within S)"
   855       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> S
   856                 \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   857       and "\<exists>x l. x \<in> S \<and> ((\<lambda>n. f n x) sums l)"
   858     shows "\<exists>g. \<forall>x \<in> S. ((\<lambda>n. f n x) sums g x) \<and> ((g has_field_derivative g' x) (at x within S))"
   859 proof -
   860   from assms obtain x l where x: "x \<in> S" and sf: "((\<lambda>n. f n x) sums l)"
   861     by blast
   862   { fix e::real assume e: "e > 0"
   863     then obtain N where N: "\<forall>n x. n \<ge> N \<longrightarrow> x \<in> S
   864             \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   865       by (metis conv)
   866     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>S. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   867     proof (rule exI [of _ N], clarify)
   868       fix n y h
   869       assume "N \<le> n" "y \<in> S"
   870       then have "cmod ((\<Sum>i<n. f' i y) - g' y) \<le> e"
   871         by (metis N)
   872       then have "cmod h * cmod ((\<Sum>i<n. f' i y) - g' y) \<le> cmod h * e"
   873         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   874       then show "cmod ((\<Sum>i<n. h * f' i y) - g' y * h) \<le> e * cmod h"
   875         by (simp add: norm_mult [symmetric] field_simps sum_distrib_left)
   876     qed
   877   } note ** = this
   878   show ?thesis
   879   unfolding has_field_derivative_def
   880   proof (rule has_derivative_series [OF cvs _ _ x])
   881     fix n x
   882     assume "x \<in> S"
   883     then show "((f n) has_derivative (\<lambda>z. z * f' n x)) (at x within S)"
   884       by (metis df has_field_derivative_def mult_commute_abs)
   885   next show " ((\<lambda>n. f n x) sums l)"
   886     by (rule sf)
   887   next show "\<And>e. e>0 \<Longrightarrow> \<forall>\<^sub>F n in sequentially. \<forall>x\<in>S. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   888       unfolding eventually_sequentially by (blast intro: **)
   889   qed
   890 qed
   891 
   892 
   893 lemma field_differentiable_series:
   894   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach} \<Rightarrow> 'a"
   895   assumes "convex S" "open S"
   896   assumes "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   897   assumes "uniformly_convergent_on S (\<lambda>n x. \<Sum>i<n. f' i x)"
   898   assumes "x0 \<in> S" "summable (\<lambda>n. f n x0)" and x: "x \<in> S"
   899   shows  "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)"
   900 proof -
   901   from assms(4) obtain g' where A: "uniform_limit S (\<lambda>n x. \<Sum>i<n. f' i x) g' sequentially"
   902     unfolding uniformly_convergent_on_def by blast
   903   from x and \<open>open S\<close> have S: "at x within S = at x" by (rule at_within_open)
   904   have "\<exists>g. \<forall>x\<in>S. (\<lambda>n. f n x) sums g x \<and> (g has_field_derivative g' x) (at x within S)"
   905     by (intro has_field_derivative_series[of S f f' g' x0] assms A has_field_derivative_at_within)
   906   then obtain g where g: "\<And>x. x \<in> S \<Longrightarrow> (\<lambda>n. f n x) sums g x"
   907     "\<And>x. x \<in> S \<Longrightarrow> (g has_field_derivative g' x) (at x within S)" by blast
   908   from g(2)[OF x] have g': "(g has_derivative ( * ) (g' x)) (at x)"
   909     by (simp add: has_field_derivative_def S)
   910   have "((\<lambda>x. \<Sum>n. f n x) has_derivative ( * ) (g' x)) (at x)"
   911     by (rule has_derivative_transform_within_open[OF g' \<open>open S\<close> x])
   912        (insert g, auto simp: sums_iff)
   913   thus "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)" unfolding differentiable_def
   914     by (auto simp: summable_def field_differentiable_def has_field_derivative_def)
   915 qed
   916 
   917 subsection\<open>Bound theorem\<close>
   918 
   919 lemma field_differentiable_bound:
   920   fixes S :: "'a::real_normed_field set"
   921   assumes cvs: "convex S"
   922       and df:  "\<And>z. z \<in> S \<Longrightarrow> (f has_field_derivative f' z) (at z within S)"
   923       and dn:  "\<And>z. z \<in> S \<Longrightarrow> norm (f' z) \<le> B"
   924       and "x \<in> S"  "y \<in> S"
   925     shows "norm(f x - f y) \<le> B * norm(x - y)"
   926   apply (rule differentiable_bound [OF cvs])
   927   apply (erule df [unfolded has_field_derivative_def])
   928   apply (rule onorm_le, simp_all add: norm_mult mult_right_mono assms)
   929   done
   930 
   931 subsection\<open>Inverse function theorem for complex derivatives\<close>
   932 
   933 lemma has_field_derivative_inverse_basic:
   934   shows "DERIV f (g y) :> f' \<Longrightarrow>
   935         f' \<noteq> 0 \<Longrightarrow>
   936         continuous (at y) g \<Longrightarrow>
   937         open t \<Longrightarrow>
   938         y \<in> t \<Longrightarrow>
   939         (\<And>z. z \<in> t \<Longrightarrow> f (g z) = z)
   940         \<Longrightarrow> DERIV g y :> inverse (f')"
   941   unfolding has_field_derivative_def
   942   apply (rule has_derivative_inverse_basic)
   943   apply (auto simp:  bounded_linear_mult_right)
   944   done
   945 
   946 lemma has_field_derivative_inverse_strong:
   947   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   948   shows "DERIV f x :> f' \<Longrightarrow>
   949          f' \<noteq> 0 \<Longrightarrow>
   950          open S \<Longrightarrow>
   951          x \<in> S \<Longrightarrow>
   952          continuous_on S f \<Longrightarrow>
   953          (\<And>z. z \<in> S \<Longrightarrow> g (f z) = z)
   954          \<Longrightarrow> DERIV g (f x) :> inverse (f')"
   955   unfolding has_field_derivative_def
   956   apply (rule has_derivative_inverse_strong [of S x f g ])
   957   by auto
   958 
   959 lemma has_field_derivative_inverse_strong_x:
   960   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   961   shows  "DERIV f (g y) :> f' \<Longrightarrow>
   962           f' \<noteq> 0 \<Longrightarrow>
   963           open S \<Longrightarrow>
   964           continuous_on S f \<Longrightarrow>
   965           g y \<in> S \<Longrightarrow> f(g y) = y \<Longrightarrow>
   966           (\<And>z. z \<in> S \<Longrightarrow> g (f z) = z)
   967           \<Longrightarrow> DERIV g y :> inverse (f')"
   968   unfolding has_field_derivative_def
   969   apply (rule has_derivative_inverse_strong_x [of S g y f])
   970   by auto
   971 
   972 subsection \<open>Taylor on Complex Numbers\<close>
   973 
   974 lemma sum_Suc_reindex:
   975   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   976     shows  "sum f {0..n} = f 0 - f (Suc n) + sum (\<lambda>i. f (Suc i)) {0..n}"
   977 by (induct n) auto
   978 
   979 lemma field_taylor:
   980   assumes S: "convex S"
   981       and f: "\<And>i x. x \<in> S \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within S)"
   982       and B: "\<And>x. x \<in> S \<Longrightarrow> norm (f (Suc n) x) \<le> B"
   983       and w: "w \<in> S"
   984       and z: "z \<in> S"
   985     shows "norm(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
   986           \<le> B * norm(z - w)^(Suc n) / fact n"
   987 proof -
   988   have wzs: "closed_segment w z \<subseteq> S" using assms
   989     by (metis convex_contains_segment)
   990   { fix u
   991     assume "u \<in> closed_segment w z"
   992     then have "u \<in> S"
   993       by (metis wzs subsetD)
   994     have "(\<Sum>i\<le>n. f i u * (- of_nat i * (z-u)^(i - 1)) / (fact i) +
   995                       f (Suc i) u * (z-u)^i / (fact i)) =
   996               f (Suc n) u * (z-u) ^ n / (fact n)"
   997     proof (induction n)
   998       case 0 show ?case by simp
   999     next
  1000       case (Suc n)
  1001       have "(\<Sum>i\<le>Suc n. f i u * (- of_nat i * (z-u) ^ (i - 1)) / (fact i) +
  1002                              f (Suc i) u * (z-u) ^ i / (fact i)) =
  1003            f (Suc n) u * (z-u) ^ n / (fact n) +
  1004            f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n) / (fact (Suc n)) -
  1005            f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n) / (fact (Suc n))"
  1006         using Suc by simp
  1007       also have "... = f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n))"
  1008       proof -
  1009         have "(fact(Suc n)) *
  1010              (f(Suc n) u *(z-u) ^ n / (fact n) +
  1011                f(Suc(Suc n)) u *((z-u) *(z-u) ^ n) / (fact(Suc n)) -
  1012                f(Suc n) u *((1 + of_nat n) *(z-u) ^ n) / (fact(Suc n))) =
  1013             ((fact(Suc n)) *(f(Suc n) u *(z-u) ^ n)) / (fact n) +
  1014             ((fact(Suc n)) *(f(Suc(Suc n)) u *((z-u) *(z-u) ^ n)) / (fact(Suc n))) -
  1015             ((fact(Suc n)) *(f(Suc n) u *(of_nat(Suc n) *(z-u) ^ n))) / (fact(Suc n))"
  1016           by (simp add: algebra_simps del: fact_Suc)
  1017         also have "... = ((fact (Suc n)) * (f (Suc n) u * (z-u) ^ n)) / (fact n) +
  1018                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
  1019                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
  1020           by (simp del: fact_Suc)
  1021         also have "... = (of_nat (Suc n) * (f (Suc n) u * (z-u) ^ n)) +
  1022                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
  1023                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
  1024           by (simp only: fact_Suc of_nat_mult ac_simps) simp
  1025         also have "... = f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)"
  1026           by (simp add: algebra_simps)
  1027         finally show ?thesis
  1028         by (simp add: mult_left_cancel [where c = "(fact (Suc n))", THEN iffD1] del: fact_Suc)
  1029       qed
  1030       finally show ?case .
  1031     qed
  1032     then have "((\<lambda>v. (\<Sum>i\<le>n. f i v * (z - v)^i / (fact i)))
  1033                 has_field_derivative f (Suc n) u * (z-u) ^ n / (fact n))
  1034                (at u within S)"
  1035       apply (intro derivative_eq_intros)
  1036       apply (blast intro: assms \<open>u \<in> S\<close>)
  1037       apply (rule refl)+
  1038       apply (auto simp: field_simps)
  1039       done
  1040   } note sum_deriv = this
  1041   { fix u
  1042     assume u: "u \<in> closed_segment w z"
  1043     then have us: "u \<in> S"
  1044       by (metis wzs subsetD)
  1045     have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> norm (f (Suc n) u) * norm (u - z) ^ n"
  1046       by (metis norm_minus_commute order_refl)
  1047     also have "... \<le> norm (f (Suc n) u) * norm (z - w) ^ n"
  1048       by (metis mult_left_mono norm_ge_zero power_mono segment_bound [OF u])
  1049     also have "... \<le> B * norm (z - w) ^ n"
  1050       by (metis norm_ge_zero zero_le_power mult_right_mono  B [OF us])
  1051     finally have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> B * norm (z - w) ^ n" .
  1052   } note cmod_bound = this
  1053   have "(\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)) = (\<Sum>i\<le>n. (f i z / (fact i)) * 0 ^ i)"
  1054     by simp
  1055   also have "\<dots> = f 0 z / (fact 0)"
  1056     by (subst sum_zero_power) simp
  1057   finally have "norm (f 0 z - (\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)))
  1058                 \<le> norm ((\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)) -
  1059                         (\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)))"
  1060     by (simp add: norm_minus_commute)
  1061   also have "... \<le> B * norm (z - w) ^ n / (fact n) * norm (w - z)"
  1062     apply (rule field_differentiable_bound
  1063       [where f' = "\<lambda>w. f (Suc n) w * (z - w)^n / (fact n)"
  1064          and S = "closed_segment w z", OF convex_closed_segment])
  1065     apply (auto simp: ends_in_segment DERIV_subset [OF sum_deriv wzs]
  1066                   norm_divide norm_mult norm_power divide_le_cancel cmod_bound)
  1067     done
  1068   also have "...  \<le> B * norm (z - w) ^ Suc n / (fact n)"
  1069     by (simp add: algebra_simps norm_minus_commute)
  1070   finally show ?thesis .
  1071 qed
  1072 
  1073 lemma complex_taylor:
  1074   assumes S: "convex S"
  1075       and f: "\<And>i x. x \<in> S \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within S)"
  1076       and B: "\<And>x. x \<in> S \<Longrightarrow> cmod (f (Suc n) x) \<le> B"
  1077       and w: "w \<in> S"
  1078       and z: "z \<in> S"
  1079     shows "cmod(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
  1080           \<le> B * cmod(z - w)^(Suc n) / fact n"
  1081   using assms by (rule field_taylor)
  1082 
  1083 
  1084 text\<open>Something more like the traditional MVT for real components\<close>
  1085 
  1086 lemma complex_mvt_line:
  1087   assumes "\<And>u. u \<in> closed_segment w z \<Longrightarrow> (f has_field_derivative f'(u)) (at u)"
  1088     shows "\<exists>u. u \<in> closed_segment w z \<and> Re(f z) - Re(f w) = Re(f'(u) * (z - w))"
  1089 proof -
  1090   have twz: "\<And>t. (1 - t) *\<^sub>R w + t *\<^sub>R z = w + t *\<^sub>R (z - w)"
  1091     by (simp add: real_vector.scale_left_diff_distrib real_vector.scale_right_diff_distrib)
  1092   note assms[unfolded has_field_derivative_def, derivative_intros]
  1093   show ?thesis
  1094     apply (cut_tac mvt_simple
  1095                      [of 0 1 "Re o f o (\<lambda>t. (1 - t) *\<^sub>R w +  t *\<^sub>R z)"
  1096                       "\<lambda>u. Re o (\<lambda>h. f'((1 - u) *\<^sub>R w + u *\<^sub>R z) * h) o (\<lambda>t. t *\<^sub>R (z - w))"])
  1097     apply auto
  1098     apply (rule_tac x="(1 - x) *\<^sub>R w + x *\<^sub>R z" in exI)
  1099     apply (auto simp: closed_segment_def twz) []
  1100     apply (intro derivative_eq_intros has_derivative_at_withinI, simp_all)
  1101     apply (simp add: fun_eq_iff real_vector.scale_right_diff_distrib)
  1102     apply (force simp: twz closed_segment_def)
  1103     done
  1104 qed
  1105 
  1106 lemma complex_taylor_mvt:
  1107   assumes "\<And>i x. \<lbrakk>x \<in> closed_segment w z; i \<le> n\<rbrakk> \<Longrightarrow> ((f i) has_field_derivative f (Suc i) x) (at x)"
  1108     shows "\<exists>u. u \<in> closed_segment w z \<and>
  1109             Re (f 0 z) =
  1110             Re ((\<Sum>i = 0..n. f i w * (z - w) ^ i / (fact i)) +
  1111                 (f (Suc n) u * (z-u)^n / (fact n)) * (z - w))"
  1112 proof -
  1113   { fix u
  1114     assume u: "u \<in> closed_segment w z"
  1115     have "(\<Sum>i = 0..n.
  1116                (f (Suc i) u * (z-u) ^ i - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) /
  1117                (fact i)) =
  1118           f (Suc 0) u -
  1119              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1120              (fact (Suc n)) +
  1121              (\<Sum>i = 0..n.
  1122                  (f (Suc (Suc i)) u * ((z-u) ^ Suc i) - of_nat (Suc i) * (f (Suc i) u * (z-u) ^ i)) /
  1123                  (fact (Suc i)))"
  1124        by (subst sum_Suc_reindex) simp
  1125     also have "... = f (Suc 0) u -
  1126              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1127              (fact (Suc n)) +
  1128              (\<Sum>i = 0..n.
  1129                  f (Suc (Suc i)) u * ((z-u) ^ Suc i) / (fact (Suc i))  -
  1130                  f (Suc i) u * (z-u) ^ i / (fact i))"
  1131       by (simp only: diff_divide_distrib fact_cancel ac_simps)
  1132     also have "... = f (Suc 0) u -
  1133              (f (Suc (Suc n)) u * (z-u) ^ Suc n - of_nat (Suc n) * (z-u) ^ n * f (Suc n) u) /
  1134              (fact (Suc n)) +
  1135              f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n)) - f (Suc 0) u"
  1136       by (subst sum_Suc_diff) auto
  1137     also have "... = f (Suc n) u * (z-u) ^ n / (fact n)"
  1138       by (simp only: algebra_simps diff_divide_distrib fact_cancel)
  1139     finally have "(\<Sum>i = 0..n. (f (Suc i) u * (z - u) ^ i
  1140                              - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) / (fact i)) =
  1141                   f (Suc n) u * (z - u) ^ n / (fact n)" .
  1142     then have "((\<lambda>u. \<Sum>i = 0..n. f i u * (z - u) ^ i / (fact i)) has_field_derivative
  1143                 f (Suc n) u * (z - u) ^ n / (fact n))  (at u)"
  1144       apply (intro derivative_eq_intros)+
  1145       apply (force intro: u assms)
  1146       apply (rule refl)+
  1147       apply (auto simp: ac_simps)
  1148       done
  1149   }
  1150   then show ?thesis
  1151     apply (cut_tac complex_mvt_line [of w z "\<lambda>u. \<Sum>i = 0..n. f i u * (z-u) ^ i / (fact i)"
  1152                "\<lambda>u. (f (Suc n) u * (z-u)^n / (fact n))"])
  1153     apply (auto simp add: intro: open_closed_segment)
  1154     done
  1155 qed
  1156 
  1157 
  1158 subsection \<open>Polynomal function extremal theorem, from HOL Light\<close>
  1159 
  1160 lemma polyfun_extremal_lemma: (*COMPLEX_POLYFUN_EXTREMAL_LEMMA in HOL Light*)
  1161     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1162   assumes "0 < e"
  1163     shows "\<exists>M. \<forall>z. M \<le> norm(z) \<longrightarrow> norm (\<Sum>i\<le>n. c(i) * z^i) \<le> e * norm(z) ^ (Suc n)"
  1164 proof (induct n)
  1165   case 0 with assms
  1166   show ?case
  1167     apply (rule_tac x="norm (c 0) / e" in exI)
  1168     apply (auto simp: field_simps)
  1169     done
  1170 next
  1171   case (Suc n)
  1172   obtain M where M: "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1173     using Suc assms by blast
  1174   show ?case
  1175   proof (rule exI [where x= "max M (1 + norm(c(Suc n)) / e)"], clarsimp simp del: power_Suc)
  1176     fix z::'a
  1177     assume z1: "M \<le> norm z" and "1 + norm (c (Suc n)) / e \<le> norm z"
  1178     then have z2: "e + norm (c (Suc n)) \<le> e * norm z"
  1179       using assms by (simp add: field_simps)
  1180     have "norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1181       using M [OF z1] by simp
  1182     then have "norm (\<Sum>i\<le>n. c i * z^i) + norm (c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1183       by simp
  1184     then have "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1185       by (blast intro: norm_triangle_le elim: )
  1186     also have "... \<le> (e + norm (c (Suc n))) * norm z ^ Suc n"
  1187       by (simp add: norm_power norm_mult algebra_simps)
  1188     also have "... \<le> (e * norm z) * norm z ^ Suc n"
  1189       by (metis z2 mult.commute mult_left_mono norm_ge_zero norm_power)
  1190     finally show "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc (Suc n)"
  1191       by simp
  1192   qed
  1193 qed
  1194 
  1195 lemma polyfun_extremal: (*COMPLEX_POLYFUN_EXTREMAL in HOL Light*)
  1196     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1197   assumes k: "c k \<noteq> 0" "1\<le>k" and kn: "k\<le>n"
  1198     shows "eventually (\<lambda>z. norm (\<Sum>i\<le>n. c(i) * z^i) \<ge> B) at_infinity"
  1199 using kn
  1200 proof (induction n)
  1201   case 0
  1202   then show ?case
  1203     using k  by simp
  1204 next
  1205   case (Suc m)
  1206   let ?even = ?case
  1207   show ?even
  1208   proof (cases "c (Suc m) = 0")
  1209     case True
  1210     then show ?even using Suc k
  1211       by auto (metis antisym_conv less_eq_Suc_le not_le)
  1212   next
  1213     case False
  1214     then obtain M where M:
  1215           "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>m. c i * z^i) \<le> norm (c (Suc m)) / 2 * norm z ^ Suc m"
  1216       using polyfun_extremal_lemma [of "norm(c (Suc m)) / 2" c m] Suc
  1217       by auto
  1218     have "\<exists>b. \<forall>z. b \<le> norm z \<longrightarrow> B \<le> norm (\<Sum>i\<le>Suc m. c i * z^i)"
  1219     proof (rule exI [where x="max M (max 1 (\<bar>B\<bar> / (norm(c (Suc m)) / 2)))"], clarsimp simp del: power_Suc)
  1220       fix z::'a
  1221       assume z1: "M \<le> norm z" "1 \<le> norm z"
  1222          and "\<bar>B\<bar> * 2 / norm (c (Suc m)) \<le> norm z"
  1223       then have z2: "\<bar>B\<bar> \<le> norm (c (Suc m)) * norm z / 2"
  1224         using False by (simp add: field_simps)
  1225       have nz: "norm z \<le> norm z ^ Suc m"
  1226         by (metis \<open>1 \<le> norm z\<close> One_nat_def less_eq_Suc_le power_increasing power_one_right zero_less_Suc)
  1227       have *: "\<And>y x. norm (c (Suc m)) * norm z / 2 \<le> norm y - norm x \<Longrightarrow> B \<le> norm (x + y)"
  1228         by (metis abs_le_iff add.commute norm_diff_ineq order_trans z2)
  1229       have "norm z * norm (c (Suc m)) + 2 * norm (\<Sum>i\<le>m. c i * z^i)
  1230             \<le> norm (c (Suc m)) * norm z + norm (c (Suc m)) * norm z ^ Suc m"
  1231         using M [of z] Suc z1  by auto
  1232       also have "... \<le> 2 * (norm (c (Suc m)) * norm z ^ Suc m)"
  1233         using nz by (simp add: mult_mono del: power_Suc)
  1234       finally show "B \<le> norm ((\<Sum>i\<le>m. c i * z^i) + c (Suc m) * z ^ Suc m)"
  1235         using Suc.IH
  1236         apply (auto simp: eventually_at_infinity)
  1237         apply (rule *)
  1238         apply (simp add: field_simps norm_mult norm_power)
  1239         done
  1240     qed
  1241     then show ?even
  1242       by (simp add: eventually_at_infinity)
  1243   qed
  1244 qed
  1245 
  1246 end