src/HOL/Library/Product_Vector.thy
author huffman
Sun Jun 07 17:59:54 2009 -0700 (2009-06-07)
changeset 31492 5400beeddb55
parent 31491 f7310185481d
child 31562 10d0fb526643
permissions -rw-r--r--
replace 'topo' with 'open'; add extra type constraint for 'open'
     1 (*  Title:      HOL/Library/Product_Vector.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Cartesian Products as Vector Spaces *}
     6 
     7 theory Product_Vector
     8 imports Inner_Product Product_plus
     9 begin
    10 
    11 subsection {* Product is a real vector space *}
    12 
    13 instantiation "*" :: (real_vector, real_vector) real_vector
    14 begin
    15 
    16 definition scaleR_prod_def:
    17   "scaleR r A = (scaleR r (fst A), scaleR r (snd A))"
    18 
    19 lemma fst_scaleR [simp]: "fst (scaleR r A) = scaleR r (fst A)"
    20   unfolding scaleR_prod_def by simp
    21 
    22 lemma snd_scaleR [simp]: "snd (scaleR r A) = scaleR r (snd A)"
    23   unfolding scaleR_prod_def by simp
    24 
    25 lemma scaleR_Pair [simp]: "scaleR r (a, b) = (scaleR r a, scaleR r b)"
    26   unfolding scaleR_prod_def by simp
    27 
    28 instance proof
    29   fix a b :: real and x y :: "'a \<times> 'b"
    30   show "scaleR a (x + y) = scaleR a x + scaleR a y"
    31     by (simp add: expand_prod_eq scaleR_right_distrib)
    32   show "scaleR (a + b) x = scaleR a x + scaleR b x"
    33     by (simp add: expand_prod_eq scaleR_left_distrib)
    34   show "scaleR a (scaleR b x) = scaleR (a * b) x"
    35     by (simp add: expand_prod_eq)
    36   show "scaleR 1 x = x"
    37     by (simp add: expand_prod_eq)
    38 qed
    39 
    40 end
    41 
    42 subsection {* Product is a topological space *}
    43 
    44 instantiation
    45   "*" :: (topological_space, topological_space) topological_space
    46 begin
    47 
    48 definition open_prod_def:
    49   "open (S :: ('a \<times> 'b) set) \<longleftrightarrow>
    50     (\<forall>x\<in>S. \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S)"
    51 
    52 instance proof
    53   show "open (UNIV :: ('a \<times> 'b) set)"
    54     unfolding open_prod_def by auto
    55 next
    56   fix S T :: "('a \<times> 'b) set"
    57   assume "open S" "open T" thus "open (S \<inter> T)"
    58     unfolding open_prod_def
    59     apply clarify
    60     apply (drule (1) bspec)+
    61     apply (clarify, rename_tac Sa Ta Sb Tb)
    62     apply (rule_tac x="Sa \<inter> Ta" in exI)
    63     apply (rule_tac x="Sb \<inter> Tb" in exI)
    64     apply (simp add: open_Int)
    65     apply fast
    66     done
    67 next
    68   fix K :: "('a \<times> 'b) set set"
    69   assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
    70     unfolding open_prod_def by fast
    71 qed
    72 
    73 end
    74 
    75 subsection {* Product is a metric space *}
    76 
    77 instantiation
    78   "*" :: (metric_space, metric_space) metric_space
    79 begin
    80 
    81 definition dist_prod_def:
    82   "dist (x::'a \<times> 'b) y = sqrt ((dist (fst x) (fst y))\<twosuperior> + (dist (snd x) (snd y))\<twosuperior>)"
    83 
    84 lemma dist_Pair_Pair: "dist (a, b) (c, d) = sqrt ((dist a c)\<twosuperior> + (dist b d)\<twosuperior>)"
    85   unfolding dist_prod_def by simp
    86 
    87 instance proof
    88   fix x y :: "'a \<times> 'b"
    89   show "dist x y = 0 \<longleftrightarrow> x = y"
    90     unfolding dist_prod_def
    91     by (simp add: expand_prod_eq)
    92 next
    93   fix x y z :: "'a \<times> 'b"
    94   show "dist x y \<le> dist x z + dist y z"
    95     unfolding dist_prod_def
    96     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
    97     apply (rule real_sqrt_le_mono)
    98     apply (rule order_trans [OF add_mono])
    99     apply (rule power_mono [OF dist_triangle2 [of _ _ "fst z"] zero_le_dist])
   100     apply (rule power_mono [OF dist_triangle2 [of _ _ "snd z"] zero_le_dist])
   101     apply (simp only: real_sum_squared_expand)
   102     done
   103 next
   104   (* FIXME: long proof! *)
   105   (* Maybe it would be easier to define topological spaces *)
   106   (* in terms of neighborhoods instead of open sets? *)
   107   fix S :: "('a \<times> 'b) set"
   108   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   109     unfolding open_prod_def open_dist
   110     apply safe
   111     apply (drule (1) bspec)
   112     apply clarify
   113     apply (drule (1) bspec)+
   114     apply (clarify, rename_tac r s)
   115     apply (rule_tac x="min r s" in exI, simp)
   116     apply (clarify, rename_tac c d)
   117     apply (erule subsetD)
   118     apply (simp add: dist_Pair_Pair)
   119     apply (rule conjI)
   120     apply (drule spec, erule mp)
   121     apply (erule le_less_trans [OF real_sqrt_sum_squares_ge1])
   122     apply (drule spec, erule mp)
   123     apply (erule le_less_trans [OF real_sqrt_sum_squares_ge2])
   124 
   125     apply (drule (1) bspec)
   126     apply clarify
   127     apply (subgoal_tac "\<exists>r>0. \<exists>s>0. e = sqrt (r\<twosuperior> + s\<twosuperior>)")
   128     apply clarify
   129     apply (rule_tac x="{y. dist y a < r}" in exI)
   130     apply (rule_tac x="{y. dist y b < s}" in exI)
   131     apply (rule conjI)
   132     apply clarify
   133     apply (rule_tac x="r - dist x a" in exI, rule conjI, simp)
   134     apply clarify
   135     apply (rule le_less_trans [OF dist_triangle])
   136     apply (erule less_le_trans [OF add_strict_right_mono], simp)
   137     apply (rule conjI)
   138     apply clarify
   139     apply (rule_tac x="s - dist x b" in exI, rule conjI, simp)
   140     apply clarify
   141     apply (rule le_less_trans [OF dist_triangle])
   142     apply (erule less_le_trans [OF add_strict_right_mono], simp)
   143     apply (rule conjI)
   144     apply simp
   145     apply (clarify, rename_tac c d)
   146     apply (drule spec, erule mp)
   147     apply (simp add: dist_Pair_Pair add_strict_mono power_strict_mono)
   148     apply (rule_tac x="e / sqrt 2" in exI, simp add: divide_pos_pos)
   149     apply (rule_tac x="e / sqrt 2" in exI, simp add: divide_pos_pos)
   150     apply (simp add: power_divide)
   151     done
   152 qed
   153 
   154 end
   155 
   156 subsection {* Continuity of operations *}
   157 
   158 lemma dist_fst_le: "dist (fst x) (fst y) \<le> dist x y"
   159 unfolding dist_prod_def by simp
   160 
   161 lemma dist_snd_le: "dist (snd x) (snd y) \<le> dist x y"
   162 unfolding dist_prod_def by simp
   163 
   164 lemma tendsto_fst:
   165   assumes "(f ---> a) net"
   166   shows "((\<lambda>x. fst (f x)) ---> fst a) net"
   167 proof (rule topological_tendstoI)
   168   fix S assume "open S" "fst a \<in> S"
   169   then have "open (fst -` S)" "a \<in> fst -` S"
   170     unfolding open_prod_def
   171     apply simp_all
   172     apply clarify
   173     apply (rule exI, erule conjI)
   174     apply (rule exI, rule conjI [OF open_UNIV])
   175     apply auto
   176     done
   177   with assms have "eventually (\<lambda>x. f x \<in> fst -` S) net"
   178     by (rule topological_tendstoD)
   179   then show "eventually (\<lambda>x. fst (f x) \<in> S) net"
   180     by simp
   181 qed
   182 
   183 lemma tendsto_snd:
   184   assumes "(f ---> a) net"
   185   shows "((\<lambda>x. snd (f x)) ---> snd a) net"
   186 proof (rule topological_tendstoI)
   187   fix S assume "open S" "snd a \<in> S"
   188   then have "open (snd -` S)" "a \<in> snd -` S"
   189     unfolding open_prod_def
   190     apply simp_all
   191     apply clarify
   192     apply (rule exI, rule conjI [OF open_UNIV])
   193     apply (rule exI, erule conjI)
   194     apply auto
   195     done
   196   with assms have "eventually (\<lambda>x. f x \<in> snd -` S) net"
   197     by (rule topological_tendstoD)
   198   then show "eventually (\<lambda>x. snd (f x) \<in> S) net"
   199     by simp
   200 qed
   201 
   202 lemma tendsto_Pair:
   203   assumes "(f ---> a) net" and "(g ---> b) net"
   204   shows "((\<lambda>x. (f x, g x)) ---> (a, b)) net"
   205 proof (rule topological_tendstoI)
   206   fix S assume "open S" "(a, b) \<in> S"
   207   then obtain A B where "open A" "open B" "a \<in> A" "b \<in> B" "A \<times> B \<subseteq> S"
   208     unfolding open_prod_def by auto
   209   have "eventually (\<lambda>x. f x \<in> A) net"
   210     using `(f ---> a) net` `open A` `a \<in> A`
   211     by (rule topological_tendstoD)
   212   moreover
   213   have "eventually (\<lambda>x. g x \<in> B) net"
   214     using `(g ---> b) net` `open B` `b \<in> B`
   215     by (rule topological_tendstoD)
   216   ultimately
   217   show "eventually (\<lambda>x. (f x, g x) \<in> S) net"
   218     by (rule eventually_elim2)
   219        (simp add: subsetD [OF `A \<times> B \<subseteq> S`])
   220 qed
   221 
   222 lemma LIMSEQ_fst: "(X ----> a) \<Longrightarrow> (\<lambda>n. fst (X n)) ----> fst a"
   223 unfolding LIMSEQ_conv_tendsto by (rule tendsto_fst)
   224 
   225 lemma LIMSEQ_snd: "(X ----> a) \<Longrightarrow> (\<lambda>n. snd (X n)) ----> snd a"
   226 unfolding LIMSEQ_conv_tendsto by (rule tendsto_snd)
   227 
   228 lemma LIMSEQ_Pair:
   229   assumes "X ----> a" and "Y ----> b"
   230   shows "(\<lambda>n. (X n, Y n)) ----> (a, b)"
   231 using assms unfolding LIMSEQ_conv_tendsto
   232 by (rule tendsto_Pair)
   233 
   234 lemma LIM_fst: "f -- x --> a \<Longrightarrow> (\<lambda>x. fst (f x)) -- x --> fst a"
   235 unfolding LIM_conv_tendsto by (rule tendsto_fst)
   236 
   237 lemma LIM_snd: "f -- x --> a \<Longrightarrow> (\<lambda>x. snd (f x)) -- x --> snd a"
   238 unfolding LIM_conv_tendsto by (rule tendsto_snd)
   239 
   240 lemma LIM_Pair:
   241   assumes "f -- x --> a" and "g -- x --> b"
   242   shows "(\<lambda>x. (f x, g x)) -- x --> (a, b)"
   243 using assms unfolding LIM_conv_tendsto
   244 by (rule tendsto_Pair)
   245 
   246 lemma Cauchy_fst: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. fst (X n))"
   247 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_fst_le])
   248 
   249 lemma Cauchy_snd: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. snd (X n))"
   250 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_snd_le])
   251 
   252 lemma Cauchy_Pair:
   253   assumes "Cauchy X" and "Cauchy Y"
   254   shows "Cauchy (\<lambda>n. (X n, Y n))"
   255 proof (rule metric_CauchyI)
   256   fix r :: real assume "0 < r"
   257   then have "0 < r / sqrt 2" (is "0 < ?s")
   258     by (simp add: divide_pos_pos)
   259   obtain M where M: "\<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < ?s"
   260     using metric_CauchyD [OF `Cauchy X` `0 < ?s`] ..
   261   obtain N where N: "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (Y m) (Y n) < ?s"
   262     using metric_CauchyD [OF `Cauchy Y` `0 < ?s`] ..
   263   have "\<forall>m\<ge>max M N. \<forall>n\<ge>max M N. dist (X m, Y m) (X n, Y n) < r"
   264     using M N by (simp add: real_sqrt_sum_squares_less dist_Pair_Pair)
   265   then show "\<exists>n0. \<forall>m\<ge>n0. \<forall>n\<ge>n0. dist (X m, Y m) (X n, Y n) < r" ..
   266 qed
   267 
   268 lemma isCont_Pair [simp]:
   269   "\<lbrakk>isCont f x; isCont g x\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. (f x, g x)) x"
   270   unfolding isCont_def by (rule LIM_Pair)
   271 
   272 subsection {* Product is a complete metric space *}
   273 
   274 instance "*" :: (complete_space, complete_space) complete_space
   275 proof
   276   fix X :: "nat \<Rightarrow> 'a \<times> 'b" assume "Cauchy X"
   277   have 1: "(\<lambda>n. fst (X n)) ----> lim (\<lambda>n. fst (X n))"
   278     using Cauchy_fst [OF `Cauchy X`]
   279     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   280   have 2: "(\<lambda>n. snd (X n)) ----> lim (\<lambda>n. snd (X n))"
   281     using Cauchy_snd [OF `Cauchy X`]
   282     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   283   have "X ----> (lim (\<lambda>n. fst (X n)), lim (\<lambda>n. snd (X n)))"
   284     using LIMSEQ_Pair [OF 1 2] by simp
   285   then show "convergent X"
   286     by (rule convergentI)
   287 qed
   288 
   289 subsection {* Product is a normed vector space *}
   290 
   291 instantiation
   292   "*" :: (real_normed_vector, real_normed_vector) real_normed_vector
   293 begin
   294 
   295 definition norm_prod_def:
   296   "norm x = sqrt ((norm (fst x))\<twosuperior> + (norm (snd x))\<twosuperior>)"
   297 
   298 definition sgn_prod_def:
   299   "sgn (x::'a \<times> 'b) = scaleR (inverse (norm x)) x"
   300 
   301 lemma norm_Pair: "norm (a, b) = sqrt ((norm a)\<twosuperior> + (norm b)\<twosuperior>)"
   302   unfolding norm_prod_def by simp
   303 
   304 instance proof
   305   fix r :: real and x y :: "'a \<times> 'b"
   306   show "0 \<le> norm x"
   307     unfolding norm_prod_def by simp
   308   show "norm x = 0 \<longleftrightarrow> x = 0"
   309     unfolding norm_prod_def
   310     by (simp add: expand_prod_eq)
   311   show "norm (x + y) \<le> norm x + norm y"
   312     unfolding norm_prod_def
   313     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
   314     apply (simp add: add_mono power_mono norm_triangle_ineq)
   315     done
   316   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   317     unfolding norm_prod_def
   318     apply (simp add: norm_scaleR power_mult_distrib)
   319     apply (simp add: right_distrib [symmetric])
   320     apply (simp add: real_sqrt_mult_distrib)
   321     done
   322   show "sgn x = scaleR (inverse (norm x)) x"
   323     by (rule sgn_prod_def)
   324   show "dist x y = norm (x - y)"
   325     unfolding dist_prod_def norm_prod_def
   326     by (simp add: dist_norm)
   327 qed
   328 
   329 end
   330 
   331 instance "*" :: (banach, banach) banach ..
   332 
   333 subsection {* Product is an inner product space *}
   334 
   335 instantiation "*" :: (real_inner, real_inner) real_inner
   336 begin
   337 
   338 definition inner_prod_def:
   339   "inner x y = inner (fst x) (fst y) + inner (snd x) (snd y)"
   340 
   341 lemma inner_Pair [simp]: "inner (a, b) (c, d) = inner a c + inner b d"
   342   unfolding inner_prod_def by simp
   343 
   344 instance proof
   345   fix r :: real
   346   fix x y z :: "'a::real_inner * 'b::real_inner"
   347   show "inner x y = inner y x"
   348     unfolding inner_prod_def
   349     by (simp add: inner_commute)
   350   show "inner (x + y) z = inner x z + inner y z"
   351     unfolding inner_prod_def
   352     by (simp add: inner_left_distrib)
   353   show "inner (scaleR r x) y = r * inner x y"
   354     unfolding inner_prod_def
   355     by (simp add: inner_scaleR_left right_distrib)
   356   show "0 \<le> inner x x"
   357     unfolding inner_prod_def
   358     by (intro add_nonneg_nonneg inner_ge_zero)
   359   show "inner x x = 0 \<longleftrightarrow> x = 0"
   360     unfolding inner_prod_def expand_prod_eq
   361     by (simp add: add_nonneg_eq_0_iff)
   362   show "norm x = sqrt (inner x x)"
   363     unfolding norm_prod_def inner_prod_def
   364     by (simp add: power2_norm_eq_inner)
   365 qed
   366 
   367 end
   368 
   369 subsection {* Pair operations are linear *}
   370 
   371 interpretation fst: bounded_linear fst
   372   apply (unfold_locales)
   373   apply (rule fst_add)
   374   apply (rule fst_scaleR)
   375   apply (rule_tac x="1" in exI, simp add: norm_Pair)
   376   done
   377 
   378 interpretation snd: bounded_linear snd
   379   apply (unfold_locales)
   380   apply (rule snd_add)
   381   apply (rule snd_scaleR)
   382   apply (rule_tac x="1" in exI, simp add: norm_Pair)
   383   done
   384 
   385 text {* TODO: move to NthRoot *}
   386 lemma sqrt_add_le_add_sqrt:
   387   assumes x: "0 \<le> x" and y: "0 \<le> y"
   388   shows "sqrt (x + y) \<le> sqrt x + sqrt y"
   389 apply (rule power2_le_imp_le)
   390 apply (simp add: real_sum_squared_expand add_nonneg_nonneg x y)
   391 apply (simp add: mult_nonneg_nonneg x y)
   392 apply (simp add: add_nonneg_nonneg x y)
   393 done
   394 
   395 lemma bounded_linear_Pair:
   396   assumes f: "bounded_linear f"
   397   assumes g: "bounded_linear g"
   398   shows "bounded_linear (\<lambda>x. (f x, g x))"
   399 proof
   400   interpret f: bounded_linear f by fact
   401   interpret g: bounded_linear g by fact
   402   fix x y and r :: real
   403   show "(f (x + y), g (x + y)) = (f x, g x) + (f y, g y)"
   404     by (simp add: f.add g.add)
   405   show "(f (r *\<^sub>R x), g (r *\<^sub>R x)) = r *\<^sub>R (f x, g x)"
   406     by (simp add: f.scaleR g.scaleR)
   407   obtain Kf where "0 < Kf" and norm_f: "\<And>x. norm (f x) \<le> norm x * Kf"
   408     using f.pos_bounded by fast
   409   obtain Kg where "0 < Kg" and norm_g: "\<And>x. norm (g x) \<le> norm x * Kg"
   410     using g.pos_bounded by fast
   411   have "\<forall>x. norm (f x, g x) \<le> norm x * (Kf + Kg)"
   412     apply (rule allI)
   413     apply (simp add: norm_Pair)
   414     apply (rule order_trans [OF sqrt_add_le_add_sqrt], simp, simp)
   415     apply (simp add: right_distrib)
   416     apply (rule add_mono [OF norm_f norm_g])
   417     done
   418   then show "\<exists>K. \<forall>x. norm (f x, g x) \<le> norm x * K" ..
   419 qed
   420 
   421 subsection {* Frechet derivatives involving pairs *}
   422 
   423 lemma FDERIV_Pair:
   424   assumes f: "FDERIV f x :> f'" and g: "FDERIV g x :> g'"
   425   shows "FDERIV (\<lambda>x. (f x, g x)) x :> (\<lambda>h. (f' h, g' h))"
   426 apply (rule FDERIV_I)
   427 apply (rule bounded_linear_Pair)
   428 apply (rule FDERIV_bounded_linear [OF f])
   429 apply (rule FDERIV_bounded_linear [OF g])
   430 apply (simp add: norm_Pair)
   431 apply (rule real_LIM_sandwich_zero)
   432 apply (rule LIM_add_zero)
   433 apply (rule FDERIV_D [OF f])
   434 apply (rule FDERIV_D [OF g])
   435 apply (rename_tac h)
   436 apply (simp add: divide_nonneg_pos)
   437 apply (rename_tac h)
   438 apply (subst add_divide_distrib [symmetric])
   439 apply (rule divide_right_mono [OF _ norm_ge_zero])
   440 apply (rule order_trans [OF sqrt_add_le_add_sqrt])
   441 apply simp
   442 apply simp
   443 apply simp
   444 done
   445 
   446 end