src/HOL/Lattices.thy
author wenzelm
Sat Sep 01 18:17:36 2007 +0200 (2007-09-01)
changeset 24514 540eaf87e42d
parent 24345 86a3557a9ebb
child 24640 85a6c200ecd3
permissions -rw-r--r--
mono_Int/Un: proper proof, avoid illegal schematic type vars;
removed obsolete ML bindings;
     1 (*  Title:      HOL/Lattices.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4 *)
     5 
     6 header {* Abstract lattices *}
     7 
     8 theory Lattices
     9 imports Orderings
    10 begin
    11 
    12 subsection{* Lattices *}
    13 
    14 class lower_semilattice = order +
    15   fixes inf :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<sqinter>" 70)
    16   assumes inf_le1 [simp]: "x \<sqinter> y \<sqsubseteq> x"
    17   and inf_le2 [simp]: "x \<sqinter> y \<sqsubseteq> y"
    18   and inf_greatest: "x \<sqsubseteq> y \<Longrightarrow> x \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> y \<sqinter> z"
    19 
    20 class upper_semilattice = order +
    21   fixes sup :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<squnion>" 65)
    22   assumes sup_ge1 [simp]: "x \<sqsubseteq> x \<squnion> y"
    23   and sup_ge2 [simp]: "y \<sqsubseteq> x \<squnion> y"
    24   and sup_least: "y \<sqsubseteq> x \<Longrightarrow> z \<sqsubseteq> x \<Longrightarrow> y \<squnion> z \<sqsubseteq> x"
    25 
    26 class lattice = lower_semilattice + upper_semilattice
    27 
    28 subsubsection{* Intro and elim rules*}
    29 
    30 context lower_semilattice
    31 begin
    32 
    33 lemmas antisym_intro [intro!] = antisym
    34 lemmas (in -) [rule del] = antisym_intro
    35 
    36 lemma le_infI1[intro]: "a \<sqsubseteq> x \<Longrightarrow> a \<sqinter> b \<sqsubseteq> x"
    37 apply(subgoal_tac "a \<sqinter> b \<sqsubseteq> a")
    38  apply(blast intro: order_trans)
    39 apply simp
    40 done
    41 lemmas (in -) [rule del] = le_infI1
    42 
    43 lemma le_infI2[intro]: "b \<sqsubseteq> x \<Longrightarrow> a \<sqinter> b \<sqsubseteq> x"
    44 apply(subgoal_tac "a \<sqinter> b \<sqsubseteq> b")
    45  apply(blast intro: order_trans)
    46 apply simp
    47 done
    48 lemmas (in -) [rule del] = le_infI2
    49 
    50 lemma le_infI[intro!]: "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<sqinter> b"
    51 by(blast intro: inf_greatest)
    52 lemmas (in -) [rule del] = le_infI
    53 
    54 lemma le_infE [elim!]: "x \<sqsubseteq> a \<sqinter> b \<Longrightarrow> (x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> P) \<Longrightarrow> P"
    55   by (blast intro: order_trans)
    56 lemmas (in -) [rule del] = le_infE
    57 
    58 lemma le_inf_iff [simp]:
    59  "x \<sqsubseteq> y \<sqinter> z = (x \<sqsubseteq> y \<and> x \<sqsubseteq> z)"
    60 by blast
    61 
    62 lemma le_iff_inf: "(x \<sqsubseteq> y) = (x \<sqinter> y = x)"
    63 by(blast dest:eq_iff[THEN iffD1])
    64 
    65 end
    66 
    67 lemma mono_inf: "mono f \<Longrightarrow> f (inf A B) \<le> inf (f A) (f B)"
    68   by (auto simp add: mono_def)
    69 
    70 
    71 context upper_semilattice
    72 begin
    73 
    74 lemmas antisym_intro [intro!] = antisym
    75 lemmas (in -) [rule del] = antisym_intro
    76 
    77 lemma le_supI1[intro]: "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
    78 apply(subgoal_tac "a \<sqsubseteq> a \<squnion> b")
    79  apply(blast intro: order_trans)
    80 apply simp
    81 done
    82 lemmas (in -) [rule del] = le_supI1
    83 
    84 lemma le_supI2[intro]: "x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
    85 apply(subgoal_tac "b \<sqsubseteq> a \<squnion> b")
    86  apply(blast intro: order_trans)
    87 apply simp
    88 done
    89 lemmas (in -) [rule del] = le_supI2
    90 
    91 lemma le_supI[intro!]: "a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> a \<squnion> b \<sqsubseteq> x"
    92 by(blast intro: sup_least)
    93 lemmas (in -) [rule del] = le_supI
    94 
    95 lemma le_supE[elim!]: "a \<squnion> b \<sqsubseteq> x \<Longrightarrow> (a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> P) \<Longrightarrow> P"
    96   by (blast intro: order_trans)
    97 lemmas (in -) [rule del] = le_supE
    98 
    99 
   100 lemma ge_sup_conv[simp]:
   101  "x \<squnion> y \<sqsubseteq> z = (x \<sqsubseteq> z \<and> y \<sqsubseteq> z)"
   102 by blast
   103 
   104 lemma le_iff_sup: "(x \<sqsubseteq> y) = (x \<squnion> y = y)"
   105 by(blast dest:eq_iff[THEN iffD1])
   106 
   107 end
   108 
   109 lemma mono_sup: "mono f \<Longrightarrow> sup (f A) (f B) \<le> f (sup A B)"
   110   by (auto simp add: mono_def)
   111 
   112 
   113 subsubsection{* Equational laws *}
   114 
   115 
   116 context lower_semilattice
   117 begin
   118 
   119 lemma inf_commute: "(x \<sqinter> y) = (y \<sqinter> x)"
   120 by blast
   121 
   122 lemma inf_assoc: "(x \<sqinter> y) \<sqinter> z = x \<sqinter> (y \<sqinter> z)"
   123 by blast
   124 
   125 lemma inf_idem[simp]: "x \<sqinter> x = x"
   126 by blast
   127 
   128 lemma inf_left_idem[simp]: "x \<sqinter> (x \<sqinter> y) = x \<sqinter> y"
   129 by blast
   130 
   131 lemma inf_absorb1: "x \<sqsubseteq> y \<Longrightarrow> x \<sqinter> y = x"
   132 by blast
   133 
   134 lemma inf_absorb2: "y \<sqsubseteq> x \<Longrightarrow> x \<sqinter> y = y"
   135 by blast
   136 
   137 lemma inf_left_commute: "x \<sqinter> (y \<sqinter> z) = y \<sqinter> (x \<sqinter> z)"
   138 by blast
   139 
   140 lemmas inf_ACI = inf_commute inf_assoc inf_left_commute inf_left_idem
   141 
   142 end
   143 
   144 
   145 context upper_semilattice
   146 begin
   147 
   148 lemma sup_commute: "(x \<squnion> y) = (y \<squnion> x)"
   149 by blast
   150 
   151 lemma sup_assoc: "(x \<squnion> y) \<squnion> z = x \<squnion> (y \<squnion> z)"
   152 by blast
   153 
   154 lemma sup_idem[simp]: "x \<squnion> x = x"
   155 by blast
   156 
   157 lemma sup_left_idem[simp]: "x \<squnion> (x \<squnion> y) = x \<squnion> y"
   158 by blast
   159 
   160 lemma sup_absorb1: "y \<sqsubseteq> x \<Longrightarrow> x \<squnion> y = x"
   161 by blast
   162 
   163 lemma sup_absorb2: "x \<sqsubseteq> y \<Longrightarrow> x \<squnion> y = y"
   164 by blast
   165 
   166 lemma sup_left_commute: "x \<squnion> (y \<squnion> z) = y \<squnion> (x \<squnion> z)"
   167 by blast
   168 
   169 lemmas sup_ACI = sup_commute sup_assoc sup_left_commute sup_left_idem
   170 
   171 end
   172 
   173 context lattice
   174 begin
   175 
   176 lemma inf_sup_absorb: "x \<sqinter> (x \<squnion> y) = x"
   177 by(blast intro: antisym inf_le1 inf_greatest sup_ge1)
   178 
   179 lemma sup_inf_absorb: "x \<squnion> (x \<sqinter> y) = x"
   180 by(blast intro: antisym sup_ge1 sup_least inf_le1)
   181 
   182 lemmas ACI = inf_ACI sup_ACI
   183 
   184 lemmas inf_sup_ord = inf_le1 inf_le2 sup_ge1 sup_ge2
   185 
   186 text{* Towards distributivity *}
   187 
   188 lemma distrib_sup_le: "x \<squnion> (y \<sqinter> z) \<sqsubseteq> (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   189 by blast
   190 
   191 lemma distrib_inf_le: "(x \<sqinter> y) \<squnion> (x \<sqinter> z) \<sqsubseteq> x \<sqinter> (y \<squnion> z)"
   192 by blast
   193 
   194 
   195 text{* If you have one of them, you have them all. *}
   196 
   197 lemma distrib_imp1:
   198 assumes D: "!!x y z. x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   199 shows "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   200 proof-
   201   have "x \<squnion> (y \<sqinter> z) = (x \<squnion> (x \<sqinter> z)) \<squnion> (y \<sqinter> z)" by(simp add:sup_inf_absorb)
   202   also have "\<dots> = x \<squnion> (z \<sqinter> (x \<squnion> y))" by(simp add:D inf_commute sup_assoc)
   203   also have "\<dots> = ((x \<squnion> y) \<sqinter> x) \<squnion> ((x \<squnion> y) \<sqinter> z)"
   204     by(simp add:inf_sup_absorb inf_commute)
   205   also have "\<dots> = (x \<squnion> y) \<sqinter> (x \<squnion> z)" by(simp add:D)
   206   finally show ?thesis .
   207 qed
   208 
   209 lemma distrib_imp2:
   210 assumes D: "!!x y z. x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   211 shows "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   212 proof-
   213   have "x \<sqinter> (y \<squnion> z) = (x \<sqinter> (x \<squnion> z)) \<sqinter> (y \<squnion> z)" by(simp add:inf_sup_absorb)
   214   also have "\<dots> = x \<sqinter> (z \<squnion> (x \<sqinter> y))" by(simp add:D sup_commute inf_assoc)
   215   also have "\<dots> = ((x \<sqinter> y) \<squnion> x) \<sqinter> ((x \<sqinter> y) \<squnion> z)"
   216     by(simp add:sup_inf_absorb sup_commute)
   217   also have "\<dots> = (x \<sqinter> y) \<squnion> (x \<sqinter> z)" by(simp add:D)
   218   finally show ?thesis .
   219 qed
   220 
   221 (* seems unused *)
   222 lemma modular_le: "x \<sqsubseteq> z \<Longrightarrow> x \<squnion> (y \<sqinter> z) \<sqsubseteq> (x \<squnion> y) \<sqinter> z"
   223 by blast
   224 
   225 end
   226 
   227 
   228 subsection {* Distributive lattices *}
   229 
   230 class distrib_lattice = lattice +
   231   assumes sup_inf_distrib1: "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   232 
   233 context distrib_lattice
   234 begin
   235 
   236 lemma sup_inf_distrib2:
   237  "(y \<sqinter> z) \<squnion> x = (y \<squnion> x) \<sqinter> (z \<squnion> x)"
   238 by(simp add:ACI sup_inf_distrib1)
   239 
   240 lemma inf_sup_distrib1:
   241  "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   242 by(rule distrib_imp2[OF sup_inf_distrib1])
   243 
   244 lemma inf_sup_distrib2:
   245  "(y \<squnion> z) \<sqinter> x = (y \<sqinter> x) \<squnion> (z \<sqinter> x)"
   246 by(simp add:ACI inf_sup_distrib1)
   247 
   248 lemmas distrib =
   249   sup_inf_distrib1 sup_inf_distrib2 inf_sup_distrib1 inf_sup_distrib2
   250 
   251 end
   252 
   253 
   254 subsection {* Uniqueness of inf and sup *}
   255 
   256 lemma (in lower_semilattice) inf_unique:
   257   fixes f (infixl "\<triangle>" 70)
   258   assumes le1: "\<And>x y. x \<triangle> y \<^loc>\<le> x" and le2: "\<And>x y. x \<triangle> y \<^loc>\<le> y"
   259   and greatest: "\<And>x y z. x \<^loc>\<le> y \<Longrightarrow> x \<^loc>\<le> z \<Longrightarrow> x \<^loc>\<le> y \<triangle> z"
   260   shows "x \<sqinter> y = x \<triangle> y"
   261 proof (rule antisym)
   262   show "x \<triangle> y \<^loc>\<le> x \<sqinter> y" by (rule le_infI) (rule le1, rule le2)
   263 next
   264   have leI: "\<And>x y z. x \<^loc>\<le> y \<Longrightarrow> x \<^loc>\<le> z \<Longrightarrow> x \<^loc>\<le> y \<triangle> z" by (blast intro: greatest)
   265   show "x \<sqinter> y \<^loc>\<le> x \<triangle> y" by (rule leI) simp_all
   266 qed
   267 
   268 lemma (in upper_semilattice) sup_unique:
   269   fixes f (infixl "\<nabla>" 70)
   270   assumes ge1 [simp]: "\<And>x y. x \<^loc>\<le> x \<nabla> y" and ge2: "\<And>x y. y \<^loc>\<le> x \<nabla> y"
   271   and least: "\<And>x y z. y \<^loc>\<le> x \<Longrightarrow> z \<^loc>\<le> x \<Longrightarrow> y \<nabla> z \<^loc>\<le> x"
   272   shows "x \<squnion> y = x \<nabla> y"
   273 proof (rule antisym)
   274   show "x \<squnion> y \<^loc>\<le> x \<nabla> y" by (rule le_supI) (rule ge1, rule ge2)
   275 next
   276   have leI: "\<And>x y z. x \<^loc>\<le> z \<Longrightarrow> y \<^loc>\<le> z \<Longrightarrow> x \<nabla> y \<^loc>\<le> z" by (blast intro: least)
   277   show "x \<nabla> y \<^loc>\<le> x \<squnion> y" by (rule leI) simp_all
   278 qed
   279   
   280 
   281 subsection {* @{const min}/@{const max} on linear orders as
   282   special case of @{const inf}/@{const sup} *}
   283 
   284 lemma (in linorder) distrib_lattice_min_max:
   285   "distrib_lattice (op \<^loc>\<le>) (op \<^loc><) min max"
   286 proof unfold_locales
   287   have aux: "\<And>x y \<Colon> 'a. x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> x \<Longrightarrow> x = y"
   288     by (auto simp add: less_le antisym)
   289   fix x y z
   290   show "max x (min y z) = min (max x y) (max x z)"
   291   unfolding min_def max_def
   292     by (auto simp add: intro: antisym, unfold not_le,
   293       auto intro: less_trans le_less_trans aux)
   294 qed (auto simp add: min_def max_def not_le less_imp_le)
   295 
   296 interpretation min_max:
   297   distrib_lattice ["op \<le> \<Colon> 'a\<Colon>linorder \<Rightarrow> 'a \<Rightarrow> bool" "op <" min max]
   298   by (rule distrib_lattice_min_max)
   299 
   300 lemma inf_min: "inf = (min \<Colon> 'a\<Colon>{lower_semilattice, linorder} \<Rightarrow> 'a \<Rightarrow> 'a)"
   301   by (rule ext)+ auto
   302 
   303 lemma sup_max: "sup = (max \<Colon> 'a\<Colon>{upper_semilattice, linorder} \<Rightarrow> 'a \<Rightarrow> 'a)"
   304   by (rule ext)+ auto
   305 
   306 lemmas le_maxI1 = min_max.sup_ge1
   307 lemmas le_maxI2 = min_max.sup_ge2
   308  
   309 lemmas max_ac = min_max.sup_assoc min_max.sup_commute
   310   mk_left_commute [of max, OF min_max.sup_assoc min_max.sup_commute]
   311 
   312 lemmas min_ac = min_max.inf_assoc min_max.inf_commute
   313   mk_left_commute [of min, OF min_max.inf_assoc min_max.inf_commute]
   314 
   315 text {*
   316   Now we have inherited antisymmetry as an intro-rule on all
   317   linear orders. This is a problem because it applies to bool, which is
   318   undesirable.
   319 *}
   320 
   321 lemmas [rule del] = min_max.antisym_intro min_max.le_infI min_max.le_supI
   322   min_max.le_supE min_max.le_infE min_max.le_supI1 min_max.le_supI2
   323   min_max.le_infI1 min_max.le_infI2
   324 
   325 
   326 subsection {* Complete lattices *}
   327 
   328 class complete_lattice = lattice +
   329   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
   330     and Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
   331   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
   332      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
   333   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
   334      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
   335 begin
   336 
   337 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<^loc>\<le> a}"
   338   by (auto intro: Inf_lower Inf_greatest Sup_upper Sup_least)
   339 
   340 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<^loc>\<le> b}"
   341   by (auto intro: Inf_lower Inf_greatest Sup_upper Sup_least)
   342 
   343 lemma Inf_Univ: "\<Sqinter>UNIV = \<Squnion>{}"
   344   unfolding Sup_Inf by auto
   345 
   346 lemma Sup_Univ: "\<Squnion>UNIV = \<Sqinter>{}"
   347   unfolding Inf_Sup by auto
   348 
   349 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
   350   apply (rule antisym)
   351   apply (rule le_infI)
   352   apply (rule Inf_lower)
   353   apply simp
   354   apply (rule Inf_greatest)
   355   apply (rule Inf_lower)
   356   apply simp
   357   apply (rule Inf_greatest)
   358   apply (erule insertE)
   359   apply (rule le_infI1)
   360   apply simp
   361   apply (rule le_infI2)
   362   apply (erule Inf_lower)
   363   done
   364 
   365 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
   366   apply (rule antisym)
   367   apply (rule Sup_least)
   368   apply (erule insertE)
   369   apply (rule le_supI1)
   370   apply simp
   371   apply (rule le_supI2)
   372   apply (erule Sup_upper)
   373   apply (rule le_supI)
   374   apply (rule Sup_upper)
   375   apply simp
   376   apply (rule Sup_least)
   377   apply (rule Sup_upper)
   378   apply simp
   379   done
   380 
   381 lemma Inf_singleton [simp]:
   382   "\<Sqinter>{a} = a"
   383   by (auto intro: antisym Inf_lower Inf_greatest)
   384 
   385 lemma Sup_singleton [simp]:
   386   "\<Squnion>{a} = a"
   387   by (auto intro: antisym Sup_upper Sup_least)
   388 
   389 lemma Inf_insert_simp:
   390   "\<Sqinter>insert a A = (if A = {} then a else a \<sqinter> \<Sqinter>A)"
   391   by (cases "A = {}") (simp_all, simp add: Inf_insert)
   392 
   393 lemma Sup_insert_simp:
   394   "\<Squnion>insert a A = (if A = {} then a else a \<squnion> \<Squnion>A)"
   395   by (cases "A = {}") (simp_all, simp add: Sup_insert)
   396 
   397 lemma Inf_binary:
   398   "\<Sqinter>{a, b} = a \<sqinter> b"
   399   by (simp add: Inf_insert_simp)
   400 
   401 lemma Sup_binary:
   402   "\<Squnion>{a, b} = a \<squnion> b"
   403   by (simp add: Sup_insert_simp)
   404 
   405 end
   406 
   407 definition
   408   top :: "'a::complete_lattice"
   409 where
   410   "top = Inf {}"
   411 
   412 definition
   413   bot :: "'a::complete_lattice"
   414 where
   415   "bot = Sup {}"
   416 
   417 lemma top_greatest [simp]: "x \<le> top"
   418   by (unfold top_def, rule Inf_greatest, simp)
   419 
   420 lemma bot_least [simp]: "bot \<le> x"
   421   by (unfold bot_def, rule Sup_least, simp)
   422 
   423 definition
   424   SUPR :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b::complete_lattice) \<Rightarrow> 'b"
   425 where
   426   "SUPR A f == Sup (f ` A)"
   427 
   428 definition
   429   INFI :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b::complete_lattice) \<Rightarrow> 'b"
   430 where
   431   "INFI A f == Inf (f ` A)"
   432 
   433 syntax
   434   "_SUP1"     :: "pttrns => 'b => 'b"           ("(3SUP _./ _)" [0, 10] 10)
   435   "_SUP"      :: "pttrn => 'a set => 'b => 'b"  ("(3SUP _:_./ _)" [0, 10] 10)
   436   "_INF1"     :: "pttrns => 'b => 'b"           ("(3INF _./ _)" [0, 10] 10)
   437   "_INF"      :: "pttrn => 'a set => 'b => 'b"  ("(3INF _:_./ _)" [0, 10] 10)
   438 
   439 translations
   440   "SUP x y. B"   == "SUP x. SUP y. B"
   441   "SUP x. B"     == "CONST SUPR UNIV (%x. B)"
   442   "SUP x. B"     == "SUP x:UNIV. B"
   443   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   444   "INF x y. B"   == "INF x. INF y. B"
   445   "INF x. B"     == "CONST INFI UNIV (%x. B)"
   446   "INF x. B"     == "INF x:UNIV. B"
   447   "INF x:A. B"   == "CONST INFI A (%x. B)"
   448 
   449 (* To avoid eta-contraction of body: *)
   450 print_translation {*
   451 let
   452   fun btr' syn (A :: Abs abs :: ts) =
   453     let val (x,t) = atomic_abs_tr' abs
   454     in list_comb (Syntax.const syn $ x $ A $ t, ts) end
   455   val const_syntax_name = Sign.const_syntax_name @{theory} o fst o dest_Const
   456 in
   457 [(const_syntax_name @{term SUPR}, btr' "_SUP"),(const_syntax_name @{term "INFI"}, btr' "_INF")]
   458 end
   459 *}
   460 
   461 lemma le_SUPI: "i : A \<Longrightarrow> M i \<le> (SUP i:A. M i)"
   462   by (auto simp add: SUPR_def intro: Sup_upper)
   463 
   464 lemma SUP_leI: "(\<And>i. i : A \<Longrightarrow> M i \<le> u) \<Longrightarrow> (SUP i:A. M i) \<le> u"
   465   by (auto simp add: SUPR_def intro: Sup_least)
   466 
   467 lemma INF_leI: "i : A \<Longrightarrow> (INF i:A. M i) \<le> M i"
   468   by (auto simp add: INFI_def intro: Inf_lower)
   469 
   470 lemma le_INFI: "(\<And>i. i : A \<Longrightarrow> u \<le> M i) \<Longrightarrow> u \<le> (INF i:A. M i)"
   471   by (auto simp add: INFI_def intro: Inf_greatest)
   472 
   473 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (SUP i:A. M) = M"
   474   by (auto intro: order_antisym SUP_leI le_SUPI)
   475 
   476 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (INF i:A. M) = M"
   477   by (auto intro: order_antisym INF_leI le_INFI)
   478 
   479 
   480 subsection {* Bool as lattice *}
   481 
   482 instance bool :: distrib_lattice
   483   inf_bool_eq: "inf P Q \<equiv> P \<and> Q"
   484   sup_bool_eq: "sup P Q \<equiv> P \<or> Q"
   485   by intro_classes (auto simp add: inf_bool_eq sup_bool_eq le_bool_def)
   486 
   487 instance bool :: complete_lattice
   488   Inf_bool_def: "Inf A \<equiv> \<forall>x\<in>A. x"
   489   Sup_bool_def: "Sup A \<equiv> \<exists>x\<in>A. x"
   490   by intro_classes (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
   491 
   492 lemma Inf_empty_bool [simp]:
   493   "Inf {}"
   494   unfolding Inf_bool_def by auto
   495 
   496 lemma not_Sup_empty_bool [simp]:
   497   "\<not> Sup {}"
   498   unfolding Sup_bool_def by auto
   499 
   500 lemma top_bool_eq: "top = True"
   501   by (iprover intro!: order_antisym le_boolI top_greatest)
   502 
   503 lemma bot_bool_eq: "bot = False"
   504   by (iprover intro!: order_antisym le_boolI bot_least)
   505 
   506 
   507 subsection {* Set as lattice *}
   508 
   509 instance set :: (type) distrib_lattice
   510   inf_set_eq: "inf A B \<equiv> A \<inter> B"
   511   sup_set_eq: "sup A B \<equiv> A \<union> B"
   512   by intro_classes (auto simp add: inf_set_eq sup_set_eq)
   513 
   514 lemmas [code func del] = inf_set_eq sup_set_eq
   515 
   516 lemma mono_Int: "mono f \<Longrightarrow> f (A \<inter> B) \<subseteq> f A \<inter> f B"
   517   apply (fold inf_set_eq sup_set_eq)
   518   apply (erule mono_inf)
   519   done
   520 
   521 lemma mono_Un: "mono f \<Longrightarrow> f A \<union> f B \<subseteq> f (A \<union> B)"
   522   apply (fold inf_set_eq sup_set_eq)
   523   apply (erule mono_sup)
   524   done
   525 
   526 instance set :: (type) complete_lattice
   527   Inf_set_def: "Inf S \<equiv> \<Inter>S"
   528   Sup_set_def: "Sup S \<equiv> \<Union>S"
   529   by intro_classes (auto simp add: Inf_set_def Sup_set_def)
   530 
   531 lemmas [code func del] = Inf_set_def Sup_set_def
   532 
   533 lemma top_set_eq: "top = UNIV"
   534   by (iprover intro!: subset_antisym subset_UNIV top_greatest)
   535 
   536 lemma bot_set_eq: "bot = {}"
   537   by (iprover intro!: subset_antisym empty_subsetI bot_least)
   538 
   539 
   540 subsection {* Fun as lattice *}
   541 
   542 instance "fun" :: (type, lattice) lattice
   543   inf_fun_eq: "inf f g \<equiv> (\<lambda>x. inf (f x) (g x))"
   544   sup_fun_eq: "sup f g \<equiv> (\<lambda>x. sup (f x) (g x))"
   545 apply intro_classes
   546 unfolding inf_fun_eq sup_fun_eq
   547 apply (auto intro: le_funI)
   548 apply (rule le_funI)
   549 apply (auto dest: le_funD)
   550 apply (rule le_funI)
   551 apply (auto dest: le_funD)
   552 done
   553 
   554 lemmas [code func del] = inf_fun_eq sup_fun_eq
   555 
   556 instance "fun" :: (type, distrib_lattice) distrib_lattice
   557   by default (auto simp add: inf_fun_eq sup_fun_eq sup_inf_distrib1)
   558 
   559 instance "fun" :: (type, complete_lattice) complete_lattice
   560   Inf_fun_def: "Inf A \<equiv> (\<lambda>x. Inf {y. \<exists>f\<in>A. y = f x})"
   561   Sup_fun_def: "Sup A \<equiv> (\<lambda>x. Sup {y. \<exists>f\<in>A. y = f x})"
   562   by intro_classes
   563     (auto simp add: Inf_fun_def Sup_fun_def le_fun_def
   564       intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   565 
   566 lemmas [code func del] = Inf_fun_def Sup_fun_def
   567 
   568 lemma Inf_empty_fun:
   569   "Inf {} = (\<lambda>_. Inf {})"
   570   by rule (auto simp add: Inf_fun_def)
   571 
   572 lemma Sup_empty_fun:
   573   "Sup {} = (\<lambda>_. Sup {})"
   574   by rule (auto simp add: Sup_fun_def)
   575 
   576 lemma top_fun_eq: "top = (\<lambda>x. top)"
   577   by (iprover intro!: order_antisym le_funI top_greatest)
   578 
   579 lemma bot_fun_eq: "bot = (\<lambda>x. bot)"
   580   by (iprover intro!: order_antisym le_funI bot_least)
   581 
   582 
   583 text {* redundant bindings *}
   584 
   585 lemmas inf_aci = inf_ACI
   586 lemmas sup_aci = sup_ACI
   587 
   588 end