src/HOL/Tools/Datatype/datatype.ML
author haftmann
Thu Oct 22 10:52:07 2009 +0200 (2009-10-22)
changeset 33062 542b34b178ec
parent 33040 cffdb7b28498
child 33244 db230399f890
permissions -rw-r--r--
dropped Datatype.distinct_simproc
     1 (*  Title:      HOL/Tools/datatype.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 Datatype package for Isabelle/HOL.
     5 *)
     6 
     7 signature DATATYPE =
     8 sig
     9   include DATATYPE_COMMON
    10   val add_datatype : config -> string list -> (string list * binding * mixfix *
    11     (binding * typ list * mixfix) list) list -> theory -> string list * theory
    12   val datatype_cmd : string list -> (string list * binding * mixfix *
    13     (binding * string list * mixfix) list) list -> theory -> theory
    14   val rep_datatype : config -> (string list -> Proof.context -> Proof.context)
    15     -> string list option -> term list -> theory -> Proof.state
    16   val rep_datatype_cmd : string list option -> string list -> theory -> Proof.state
    17   val get_info : theory -> string -> info option
    18   val the_info : theory -> string -> info
    19   val the_descr : theory -> string list
    20     -> descr * (string * sort) list * string list
    21       * string * (string list * string list) * (typ list * typ list)
    22   val the_spec : theory -> string -> (string * sort) list * (string * typ list) list
    23   val all_distincts : theory -> typ list -> thm list list
    24   val get_constrs : theory -> string -> (string * typ) list option
    25   val get_all : theory -> info Symtab.table
    26   val info_of_constr : theory -> string * typ -> info option
    27   val info_of_case : theory -> string -> info option
    28   val interpretation : (config -> string list -> theory -> theory) -> theory -> theory
    29   val make_case :  Proof.context -> DatatypeCase.config -> string list -> term ->
    30     (term * term) list -> term * (term * (int * bool)) list
    31   val strip_case : Proof.context -> bool -> term -> (term * (term * term) list) option
    32   val read_typ: theory ->
    33     (typ list * (string * sort) list) * string -> typ list * (string * sort) list
    34   val setup: theory -> theory
    35 end;
    36 
    37 structure Datatype : DATATYPE =
    38 struct
    39 
    40 open DatatypeAux;
    41 
    42 (** theory data **)
    43 
    44 (* data management *)
    45 
    46 structure DatatypesData = TheoryDataFun
    47 (
    48   type T =
    49     {types: info Symtab.table,
    50      constrs: (string * info) list Symtab.table,
    51      cases: info Symtab.table};
    52 
    53   val empty =
    54     {types = Symtab.empty, constrs = Symtab.empty, cases = Symtab.empty};
    55   val copy = I;
    56   val extend = I;
    57   fun merge _
    58     ({types = types1, constrs = constrs1, cases = cases1},
    59      {types = types2, constrs = constrs2, cases = cases2}) =
    60     {types = Symtab.merge (K true) (types1, types2),
    61      constrs = Symtab.join (K (AList.merge (op =) (K true))) (constrs1, constrs2),
    62      cases = Symtab.merge (K true) (cases1, cases2)};
    63 );
    64 
    65 val get_all = #types o DatatypesData.get;
    66 val get_info = Symtab.lookup o get_all;
    67 fun the_info thy name = (case get_info thy name of
    68       SOME info => info
    69     | NONE => error ("Unknown datatype " ^ quote name));
    70 
    71 fun info_of_constr thy (c, T) =
    72   let
    73     val tab = Symtab.lookup_list ((#constrs o DatatypesData.get) thy) c;
    74     val hint = case strip_type T of (_, Type (tyco, _)) => SOME tyco | _ => NONE;
    75     val default = if null tab then NONE
    76       else SOME (snd (Library.last_elem tab))
    77         (*conservative wrt. overloaded constructors*);
    78   in case hint
    79    of NONE => default
    80     | SOME tyco => case AList.lookup (op =) tab tyco
    81        of NONE => default (*permissive*)
    82         | SOME info => SOME info
    83   end;
    84 
    85 val info_of_case = Symtab.lookup o #cases o DatatypesData.get;
    86 
    87 fun register (dt_infos : (string * info) list) =
    88   DatatypesData.map (fn {types, constrs, cases} =>
    89     {types = types |> fold Symtab.update dt_infos,
    90      constrs = constrs |> fold (fn (constr, dtname_info) =>
    91          Symtab.map_default (constr, []) (cons dtname_info))
    92        (maps (fn (dtname, info as {descr, index, ...}) =>
    93           map (rpair (dtname, info) o fst)
    94             (#3 (the (AList.lookup op = descr index)))) dt_infos),
    95      cases = cases |> fold Symtab.update
    96        (map (fn (_, info as {case_name, ...}) => (case_name, info)) dt_infos)});
    97 
    98 (* complex queries *)
    99 
   100 fun the_spec thy dtco =
   101   let
   102     val info as { descr, index, sorts = raw_sorts, ... } = the_info thy dtco;
   103     val SOME (_, dtys, raw_cos) = AList.lookup (op =) descr index;
   104     val sorts = map ((fn v => (v, (the o AList.lookup (op =) raw_sorts) v))
   105       o DatatypeAux.dest_DtTFree) dtys;
   106     val cos = map
   107       (fn (co, tys) => (co, map (DatatypeAux.typ_of_dtyp descr sorts) tys)) raw_cos;
   108   in (sorts, cos) end;
   109 
   110 fun the_descr thy (raw_tycos as raw_tyco :: _) =
   111   let
   112     val info = the_info thy raw_tyco;
   113     val descr = #descr info;
   114 
   115     val SOME (_, dtys, raw_cos) = AList.lookup (op =) descr (#index info);
   116     val vs = map ((fn v => (v, (the o AList.lookup (op =) (#sorts info)) v))
   117       o dest_DtTFree) dtys;
   118 
   119     fun is_DtTFree (DtTFree _) = true
   120       | is_DtTFree _ = false
   121     val k = find_index (fn (_, (_, dTs, _)) => not (forall is_DtTFree dTs)) descr;
   122     val protoTs as (dataTs, _) = chop k descr
   123       |> (pairself o map) (fn (_, (tyco, dTs, _)) => (tyco, map (typ_of_dtyp descr vs) dTs));
   124     
   125     val tycos = map fst dataTs;
   126     val _ = if eq_set (op =) (tycos, raw_tycos) then ()
   127       else error ("Type constructors " ^ commas (map quote raw_tycos)
   128         ^ " do not belong exhaustively to one mutual recursive datatype");
   129 
   130     val (Ts, Us) = (pairself o map) Type protoTs;
   131 
   132     val names = map Long_Name.base_name (the_default tycos (#alt_names info));
   133     val (auxnames, _) = Name.make_context names
   134       |> fold_map (yield_singleton Name.variants o name_of_typ) Us;
   135     val prefix = space_implode "_" names;
   136 
   137   in (descr, vs, tycos, prefix, (names, auxnames), (Ts, Us)) end;
   138 
   139 fun all_distincts thy Ts =
   140   let
   141     fun add_tycos (Type (tyco, Ts)) = insert (op =) tyco #> fold add_tycos Ts
   142       | add_tycos _ = I;
   143     val tycos = fold add_tycos Ts [];
   144   in map_filter (Option.map #distinct o get_info thy) tycos end;
   145 
   146 fun get_constrs thy dtco =
   147   case try (the_spec thy) dtco
   148    of SOME (sorts, cos) =>
   149         let
   150           fun subst (v, sort) = TVar ((v, 0), sort);
   151           fun subst_ty (TFree v) = subst v
   152             | subst_ty ty = ty;
   153           val dty = Type (dtco, map subst sorts);
   154           fun mk_co (co, tys) = (co, map (Term.map_atyps subst_ty) tys ---> dty);
   155         in SOME (map mk_co cos) end
   156     | NONE => NONE;
   157 
   158 
   159 (** various auxiliary **)
   160 
   161 (* prepare datatype specifications *)
   162 
   163 fun read_typ thy ((Ts, sorts), str) =
   164   let
   165     val ctxt = ProofContext.init thy
   166       |> fold (Variable.declare_typ o TFree) sorts;
   167     val T = Syntax.read_typ ctxt str;
   168   in (Ts @ [T], Term.add_tfreesT T sorts) end;
   169 
   170 fun cert_typ sign ((Ts, sorts), raw_T) =
   171   let
   172     val T = Type.no_tvars (Sign.certify_typ sign raw_T) handle
   173       TYPE (msg, _, _) => error msg;
   174     val sorts' = Term.add_tfreesT T sorts;
   175   in (Ts @ [T],
   176       case duplicates (op =) (map fst sorts') of
   177          [] => sorts'
   178        | dups => error ("Inconsistent sort constraints for " ^ commas dups))
   179   end;
   180 
   181 (* case names *)
   182 
   183 local
   184 
   185 fun dt_recs (DtTFree _) = []
   186   | dt_recs (DtType (_, dts)) = maps dt_recs dts
   187   | dt_recs (DtRec i) = [i];
   188 
   189 fun dt_cases (descr: descr) (_, args, constrs) =
   190   let
   191     fun the_bname i = Long_Name.base_name (#1 (the (AList.lookup (op =) descr i)));
   192     val bnames = map the_bname (distinct (op =) (maps dt_recs args));
   193   in map (fn (c, _) => space_implode "_" (Long_Name.base_name c :: bnames)) constrs end;
   194 
   195 fun induct_cases descr =
   196   DatatypeProp.indexify_names (maps (dt_cases descr) (map #2 descr));
   197 
   198 fun exhaust_cases descr i = dt_cases descr (the (AList.lookup (op =) descr i));
   199 
   200 in
   201 
   202 fun mk_case_names_induct descr = RuleCases.case_names (induct_cases descr);
   203 
   204 fun mk_case_names_exhausts descr new =
   205   map (RuleCases.case_names o exhaust_cases descr o #1)
   206     (filter (fn ((_, (name, _, _))) => member (op =) new name) descr);
   207 
   208 end;
   209 
   210 (* translation rules for case *)
   211 
   212 fun make_case ctxt = DatatypeCase.make_case
   213   (info_of_constr (ProofContext.theory_of ctxt)) ctxt;
   214 
   215 fun strip_case ctxt = DatatypeCase.strip_case
   216   (info_of_case (ProofContext.theory_of ctxt));
   217 
   218 fun add_case_tr' case_names thy =
   219   Sign.add_advanced_trfuns ([], [],
   220     map (fn case_name =>
   221       let val case_name' = Sign.const_syntax_name thy case_name
   222       in (case_name', DatatypeCase.case_tr' info_of_case case_name')
   223       end) case_names, []) thy;
   224 
   225 val trfun_setup =
   226   Sign.add_advanced_trfuns ([],
   227     [("_case_syntax", DatatypeCase.case_tr true info_of_constr)],
   228     [], []);
   229 
   230 
   231 (** document antiquotation **)
   232 
   233 val _ = ThyOutput.antiquotation "datatype" Args.tyname
   234   (fn {source = src, context = ctxt, ...} => fn dtco =>
   235     let
   236       val thy = ProofContext.theory_of ctxt;
   237       val (vs, cos) = the_spec thy dtco;
   238       val ty = Type (dtco, map TFree vs);
   239       fun pretty_typ_bracket (ty as Type (_, _ :: _)) =
   240             Pretty.enclose "(" ")" [Syntax.pretty_typ ctxt ty]
   241         | pretty_typ_bracket ty =
   242             Syntax.pretty_typ ctxt ty;
   243       fun pretty_constr (co, tys) =
   244         (Pretty.block o Pretty.breaks)
   245           (Syntax.pretty_term ctxt (Const (co, tys ---> ty)) ::
   246             map pretty_typ_bracket tys);
   247       val pretty_datatype =
   248         Pretty.block
   249           (Pretty.command "datatype" :: Pretty.brk 1 ::
   250            Syntax.pretty_typ ctxt ty ::
   251            Pretty.str " =" :: Pretty.brk 1 ::
   252            flat (separate [Pretty.brk 1, Pretty.str "| "]
   253              (map (single o pretty_constr) cos)));
   254     in ThyOutput.output (ThyOutput.maybe_pretty_source (K pretty_datatype) src [()]) end);
   255 
   256 
   257 (** abstract theory extensions relative to a datatype characterisation **)
   258 
   259 structure DatatypeInterpretation = InterpretationFun
   260   (type T = config * string list val eq: T * T -> bool = eq_snd op =);
   261 fun interpretation f = DatatypeInterpretation.interpretation (uncurry f);
   262 
   263 fun make_dt_info alt_names descr sorts induct inducts rec_names rec_rewrites
   264     (index, (((((((((((_, (tname, _, _))), inject), distinct),
   265       exhaust), nchotomy), case_name), case_rewrites), case_cong), weak_case_cong), (split, split_asm))) =
   266   (tname,
   267    {index = index,
   268     alt_names = alt_names,
   269     descr = descr,
   270     sorts = sorts,
   271     inject = inject,
   272     distinct = distinct,
   273     induct = induct,
   274     inducts = inducts,
   275     exhaust = exhaust,
   276     nchotomy = nchotomy,
   277     rec_names = rec_names,
   278     rec_rewrites = rec_rewrites,
   279     case_name = case_name,
   280     case_rewrites = case_rewrites,
   281     case_cong = case_cong,
   282     weak_case_cong = weak_case_cong,
   283     split = split,
   284     split_asm = split_asm});
   285 
   286 fun derive_datatype_props config dt_names alt_names descr sorts
   287     induct inject distinct thy1 =
   288   let
   289     val thy2 = thy1 |> Theory.checkpoint;
   290     val flat_descr = flat descr;
   291     val new_type_names = map Long_Name.base_name (the_default dt_names alt_names);
   292     val _ = message config ("Deriving properties for datatype(s) " ^ commas_quote new_type_names);
   293 
   294     val (exhaust, thy3) = DatatypeAbsProofs.prove_casedist_thms config new_type_names
   295       descr sorts induct (mk_case_names_exhausts flat_descr dt_names) thy2;
   296     val (nchotomys, thy4) = DatatypeAbsProofs.prove_nchotomys config new_type_names
   297       descr sorts exhaust thy3;
   298     val ((rec_names, rec_rewrites), thy5) = DatatypeAbsProofs.prove_primrec_thms
   299       config new_type_names descr sorts (#inject o the o Symtab.lookup (get_all thy4))
   300       inject (distinct, all_distincts thy2 (get_rec_types flat_descr sorts))
   301       induct thy4;
   302     val ((case_rewrites, case_names), thy6) = DatatypeAbsProofs.prove_case_thms
   303       config new_type_names descr sorts rec_names rec_rewrites thy5;
   304     val (case_congs, thy7) = DatatypeAbsProofs.prove_case_congs new_type_names
   305       descr sorts nchotomys case_rewrites thy6;
   306     val (weak_case_congs, thy8) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   307       descr sorts thy7;
   308     val (splits, thy9) = DatatypeAbsProofs.prove_split_thms
   309       config new_type_names descr sorts inject distinct exhaust case_rewrites thy8;
   310 
   311     val inducts = Project_Rule.projections (ProofContext.init thy2) induct;
   312     val dt_infos = map_index (make_dt_info alt_names flat_descr sorts induct inducts rec_names rec_rewrites)
   313       (hd descr ~~ inject ~~ distinct ~~ exhaust ~~ nchotomys ~~
   314         case_names ~~ case_rewrites ~~ case_congs ~~ weak_case_congs ~~ splits);
   315     val dt_names = map fst dt_infos;
   316     val prfx = Binding.qualify true (space_implode "_" new_type_names);
   317     val simps = flat (inject @ distinct @ case_rewrites) @ rec_rewrites;
   318     val named_rules = flat (map_index (fn (index, tname) =>
   319       [((Binding.empty, [nth inducts index]), [Induct.induct_type tname]),
   320        ((Binding.empty, [nth exhaust index]), [Induct.cases_type tname])]) dt_names);
   321     val unnamed_rules = map (fn induct =>
   322       ((Binding.empty, [induct]), [Thm.kind_internal, Induct.induct_type ""]))
   323         (Library.drop (length dt_names, inducts));
   324   in
   325     thy9
   326     |> PureThy.add_thmss ([((prfx (Binding.name "simps"), simps), []),
   327         ((prfx (Binding.name "inducts"), inducts), []),
   328         ((prfx (Binding.name "splits"), maps (fn (x, y) => [x, y]) splits), []),
   329         ((Binding.empty, flat case_rewrites @ flat distinct @ rec_rewrites),
   330           [Simplifier.simp_add]),
   331         ((Binding.empty, rec_rewrites), [Code.add_default_eqn_attribute]),
   332         ((Binding.empty, flat inject), [iff_add]),
   333         ((Binding.empty, map (fn th => th RS notE) (flat distinct)),
   334           [Classical.safe_elim NONE]),
   335         ((Binding.empty, weak_case_congs), [Simplifier.attrib (op addcongs)])]
   336         @ named_rules @ unnamed_rules)
   337     |> snd
   338     |> add_case_tr' case_names
   339     |> register dt_infos
   340     |> DatatypeInterpretation.data (config, dt_names)
   341     |> pair dt_names
   342   end;
   343 
   344 
   345 (** declare existing type as datatype **)
   346 
   347 fun prove_rep_datatype config dt_names alt_names descr sorts raw_inject half_distinct raw_induct thy1 =
   348   let
   349     val raw_distinct = (map o maps) (fn thm => [thm, thm RS not_sym]) half_distinct;
   350     val new_type_names = map Long_Name.base_name (the_default dt_names alt_names);
   351     val (((inject, distinct), [induct]), thy2) =
   352       thy1
   353       |> store_thmss "inject" new_type_names raw_inject
   354       ||>> store_thmss "distinct" new_type_names raw_distinct
   355       ||> Sign.add_path (space_implode "_" new_type_names)
   356       ||>> PureThy.add_thms [((Binding.name "induct", raw_induct), [mk_case_names_induct descr])]
   357       ||> Sign.restore_naming thy1;
   358   in
   359     thy2
   360     |> derive_datatype_props config dt_names alt_names [descr] sorts
   361          induct inject distinct
   362  end;
   363 
   364 fun gen_rep_datatype prep_term config after_qed alt_names raw_ts thy =
   365   let
   366     fun constr_of_term (Const (c, T)) = (c, T)
   367       | constr_of_term t =
   368           error ("Not a constant: " ^ Syntax.string_of_term_global thy t);
   369     fun no_constr (c, T) = error ("Bad constructor: "
   370       ^ Sign.extern_const thy c ^ "::"
   371       ^ Syntax.string_of_typ_global thy T);
   372     fun type_of_constr (cT as (_, T)) =
   373       let
   374         val frees = OldTerm.typ_tfrees T;
   375         val (tyco, vs) = ((apsnd o map) (dest_TFree) o dest_Type o snd o strip_type) T
   376           handle TYPE _ => no_constr cT
   377         val _ = if has_duplicates (eq_fst (op =)) vs then no_constr cT else ();
   378         val _ = if length frees <> length vs then no_constr cT else ();
   379       in (tyco, (vs, cT)) end;
   380 
   381     val raw_cs = AList.group (op =) (map (type_of_constr o constr_of_term o prep_term thy) raw_ts);
   382     val _ = case map_filter (fn (tyco, _) =>
   383         if Symtab.defined (get_all thy) tyco then SOME tyco else NONE) raw_cs
   384      of [] => ()
   385       | tycos => error ("Type(s) " ^ commas (map quote tycos)
   386           ^ " already represented inductivly");
   387     val raw_vss = maps (map (map snd o fst) o snd) raw_cs;
   388     val ms = case distinct (op =) (map length raw_vss)
   389      of [n] => 0 upto n - 1
   390       | _ => error ("Different types in given constructors");
   391     fun inter_sort m = map (fn xs => nth xs m) raw_vss
   392       |> Library.foldr1 (Sorts.inter_sort (Sign.classes_of thy))
   393     val sorts = map inter_sort ms;
   394     val vs = Name.names Name.context Name.aT sorts;
   395 
   396     fun norm_constr (raw_vs, (c, T)) = (c, map_atyps
   397       (TFree o (the o AList.lookup (op =) (map fst raw_vs ~~ vs)) o fst o dest_TFree) T);
   398 
   399     val cs = map (apsnd (map norm_constr)) raw_cs;
   400     val dtyps_of_typ = map (dtyp_of_typ (map (rpair (map fst vs) o fst) cs))
   401       o fst o strip_type;
   402     val dt_names = map fst cs;
   403 
   404     fun mk_spec (i, (tyco, constr)) = (i, (tyco,
   405       map (DtTFree o fst) vs,
   406       (map o apsnd) dtyps_of_typ constr))
   407     val descr = map_index mk_spec cs;
   408     val injs = DatatypeProp.make_injs [descr] vs;
   409     val half_distincts = map snd (DatatypeProp.make_distincts [descr] vs);
   410     val ind = DatatypeProp.make_ind [descr] vs;
   411     val rules = (map o map o map) Logic.close_form [[[ind]], injs, half_distincts];
   412 
   413     fun after_qed' raw_thms =
   414       let
   415         val [[[raw_induct]], raw_inject, half_distinct] =
   416           unflat rules (map Drule.zero_var_indexes_list raw_thms);
   417             (*FIXME somehow dubious*)
   418       in
   419         ProofContext.theory_result
   420           (prove_rep_datatype config dt_names alt_names descr vs raw_inject half_distinct raw_induct)
   421         #-> after_qed
   422       end;
   423   in
   424     thy
   425     |> ProofContext.init
   426     |> Proof.theorem_i NONE after_qed' ((map o map) (rpair []) (flat rules))
   427   end;
   428 
   429 val rep_datatype = gen_rep_datatype Sign.cert_term;
   430 val rep_datatype_cmd = gen_rep_datatype Syntax.read_term_global default_config (K I);
   431 
   432 
   433 (** definitional introduction of datatypes **)
   434 
   435 fun gen_add_datatype prep_typ config new_type_names dts thy =
   436   let
   437     val _ = Theory.requires thy "Datatype" "datatype definitions";
   438 
   439     (* this theory is used just for parsing *)
   440     val tmp_thy = thy |>
   441       Theory.copy |>
   442       Sign.add_types (map (fn (tvs, tname, mx, _) =>
   443         (tname, length tvs, mx)) dts);
   444 
   445     val (tyvars, _, _, _)::_ = dts;
   446     val (new_dts, types_syntax) = ListPair.unzip (map (fn (tvs, tname, mx, _) =>
   447       let val full_tname = Sign.full_name tmp_thy (Binding.map_name (Syntax.type_name mx) tname)
   448       in (case duplicates (op =) tvs of
   449             [] => if eq_set (op =) (tyvars, tvs) then ((full_tname, tvs), (tname, mx))
   450                   else error ("Mutually recursive datatypes must have same type parameters")
   451           | dups => error ("Duplicate parameter(s) for datatype " ^ quote (Binding.str_of tname) ^
   452               " : " ^ commas dups))
   453       end) dts);
   454     val dt_names = map fst new_dts;
   455 
   456     val _ = (case duplicates (op =) (map fst new_dts) @ duplicates (op =) new_type_names of
   457       [] => () | dups => error ("Duplicate datatypes: " ^ commas dups));
   458 
   459     fun prep_dt_spec ((tvs, tname, mx, constrs), tname') (dts', constr_syntax, sorts, i) =
   460       let
   461         fun prep_constr (cname, cargs, mx') (constrs, constr_syntax', sorts') =
   462           let
   463             val (cargs', sorts'') = Library.foldl (prep_typ tmp_thy) (([], sorts'), cargs);
   464             val _ = (case subtract (op =) tvs (fold (curry OldTerm.add_typ_tfree_names) cargs' []) of
   465                 [] => ()
   466               | vs => error ("Extra type variables on rhs: " ^ commas vs))
   467           in (constrs @ [(Sign.full_name_path tmp_thy tname'
   468                   (Binding.map_name (Syntax.const_name mx') cname),
   469                    map (dtyp_of_typ new_dts) cargs')],
   470               constr_syntax' @ [(cname, mx')], sorts'')
   471           end handle ERROR msg => cat_error msg
   472            ("The error above occured in constructor " ^ quote (Binding.str_of cname) ^
   473             " of datatype " ^ quote (Binding.str_of tname));
   474 
   475         val (constrs', constr_syntax', sorts') =
   476           fold prep_constr constrs ([], [], sorts)
   477 
   478       in
   479         case duplicates (op =) (map fst constrs') of
   480            [] =>
   481              (dts' @ [(i, (Sign.full_name tmp_thy (Binding.map_name (Syntax.type_name mx) tname),
   482                 map DtTFree tvs, constrs'))],
   483               constr_syntax @ [constr_syntax'], sorts', i + 1)
   484          | dups => error ("Duplicate constructors " ^ commas dups ^
   485              " in datatype " ^ quote (Binding.str_of tname))
   486       end;
   487 
   488     val (dts', constr_syntax, sorts', i) =
   489       fold prep_dt_spec (dts ~~ new_type_names) ([], [], [], 0);
   490     val sorts = sorts' @ (map (rpair (Sign.defaultS tmp_thy)) (subtract (op =) (map fst sorts') tyvars));
   491     val dt_info = get_all thy;
   492     val (descr, _) = unfold_datatypes tmp_thy dts' sorts dt_info dts' i;
   493     val _ = check_nonempty descr handle (exn as Datatype_Empty s) =>
   494       if #strict config then error ("Nonemptiness check failed for datatype " ^ s)
   495       else raise exn;
   496 
   497     val _ = message config ("Constructing datatype(s) " ^ commas_quote new_type_names);
   498     val ((inject, distinct, induct), thy') = thy |>
   499       DatatypeRepProofs.representation_proofs config dt_info new_type_names descr sorts
   500         types_syntax constr_syntax (mk_case_names_induct (flat descr));
   501   in
   502     derive_datatype_props config dt_names (SOME new_type_names) descr sorts
   503       induct inject distinct thy'
   504   end;
   505 
   506 val add_datatype = gen_add_datatype cert_typ;
   507 val datatype_cmd = snd ooo gen_add_datatype read_typ default_config;
   508 
   509 
   510 (** package setup **)
   511 
   512 (* setup theory *)
   513 
   514 val setup =
   515   trfun_setup #>
   516   DatatypeInterpretation.init;
   517 
   518 (* outer syntax *)
   519 
   520 local
   521 
   522 structure P = OuterParse and K = OuterKeyword
   523 
   524 fun prep_datatype_decls args =
   525   let
   526     val names = map
   527       (fn ((((NONE, _), t), _), _) => Binding.name_of t | ((((SOME t, _), _), _), _) => t) args;
   528     val specs = map (fn ((((_, vs), t), mx), cons) =>
   529       (vs, t, mx, map (fn ((x, y), z) => (x, y, z)) cons)) args;
   530   in (names, specs) end;
   531 
   532 val parse_datatype_decl =
   533   (Scan.option (P.$$$ "(" |-- P.name --| P.$$$ ")") -- P.type_args -- P.binding -- P.opt_infix --
   534     (P.$$$ "=" |-- P.enum1 "|" (P.binding -- Scan.repeat P.typ -- P.opt_mixfix)));
   535 
   536 val parse_datatype_decls = P.and_list1 parse_datatype_decl >> prep_datatype_decls;
   537 
   538 in
   539 
   540 val _ =
   541   OuterSyntax.command "datatype" "define inductive datatypes" K.thy_decl
   542     (parse_datatype_decls >> (fn (names, specs) => Toplevel.theory (datatype_cmd names specs)));
   543 
   544 val _ =
   545   OuterSyntax.command "rep_datatype" "represent existing types inductively" K.thy_goal
   546     (Scan.option (P.$$$ "(" |-- Scan.repeat1 P.name --| P.$$$ ")") -- Scan.repeat1 P.term
   547       >> (fn (alt_names, ts) => Toplevel.print
   548            o Toplevel.theory_to_proof (rep_datatype_cmd alt_names ts)));
   549 
   550 end;
   551 
   552 end;