src/HOL/Algebra/UnivPoly.thy
author wenzelm
Sun Mar 21 16:51:37 2010 +0100 (2010-03-21)
changeset 35848 5443079512ea
parent 34915 7894c7dab132
child 35849 b5522b51cb1e
permissions -rw-r--r--
slightly more uniform definitions -- eliminated old-style meta-equality;
     1 (*
     2   Title:     HOL/Algebra/UnivPoly.thy
     3   Author:    Clemens Ballarin, started 9 December 1996
     4   Copyright: Clemens Ballarin
     5 
     6 Contributions, in particular on long division, by Jesus Aransay.
     7 *)
     8 
     9 theory UnivPoly
    10 imports Module RingHom
    11 begin
    12 
    13 
    14 section {* Univariate Polynomials *}
    15 
    16 text {*
    17   Polynomials are formalised as modules with additional operations for
    18   extracting coefficients from polynomials and for obtaining monomials
    19   from coefficients and exponents (record @{text "up_ring"}).  The
    20   carrier set is a set of bounded functions from Nat to the
    21   coefficient domain.  Bounded means that these functions return zero
    22   above a certain bound (the degree).  There is a chapter on the
    23   formalisation of polynomials in the PhD thesis \cite{Ballarin:1999},
    24   which was implemented with axiomatic type classes.  This was later
    25   ported to Locales.
    26 *}
    27 
    28 
    29 subsection {* The Constructor for Univariate Polynomials *}
    30 
    31 text {*
    32   Functions with finite support.
    33 *}
    34 
    35 locale bound =
    36   fixes z :: 'a
    37     and n :: nat
    38     and f :: "nat => 'a"
    39   assumes bound: "!!m. n < m \<Longrightarrow> f m = z"
    40 
    41 declare bound.intro [intro!]
    42   and bound.bound [dest]
    43 
    44 lemma bound_below:
    45   assumes bound: "bound z m f" and nonzero: "f n \<noteq> z" shows "n \<le> m"
    46 proof (rule classical)
    47   assume "~ ?thesis"
    48   then have "m < n" by arith
    49   with bound have "f n = z" ..
    50   with nonzero show ?thesis by contradiction
    51 qed
    52 
    53 record ('a, 'p) up_ring = "('a, 'p) module" +
    54   monom :: "['a, nat] => 'p"
    55   coeff :: "['p, nat] => 'a"
    56 
    57 definition
    58   up :: "('a, 'm) ring_scheme => (nat => 'a) set"
    59   where "up R = {f. f \<in> UNIV -> carrier R & (EX n. bound \<zero>\<^bsub>R\<^esub> n f)}"
    60 
    61 definition UP :: "('a, 'm) ring_scheme => ('a, nat => 'a) up_ring"
    62   where "UP R = (|
    63    carrier = up R,
    64    mult = (%p:up R. %q:up R. %n. \<Oplus>\<^bsub>R\<^esub>i \<in> {..n}. p i \<otimes>\<^bsub>R\<^esub> q (n-i)),
    65    one = (%i. if i=0 then \<one>\<^bsub>R\<^esub> else \<zero>\<^bsub>R\<^esub>),
    66    zero = (%i. \<zero>\<^bsub>R\<^esub>),
    67    add = (%p:up R. %q:up R. %i. p i \<oplus>\<^bsub>R\<^esub> q i),
    68    smult = (%a:carrier R. %p:up R. %i. a \<otimes>\<^bsub>R\<^esub> p i),
    69    monom = (%a:carrier R. %n i. if i=n then a else \<zero>\<^bsub>R\<^esub>),
    70    coeff = (%p:up R. %n. p n) |)"
    71 
    72 text {*
    73   Properties of the set of polynomials @{term up}.
    74 *}
    75 
    76 lemma mem_upI [intro]:
    77   "[| !!n. f n \<in> carrier R; EX n. bound (zero R) n f |] ==> f \<in> up R"
    78   by (simp add: up_def Pi_def)
    79 
    80 lemma mem_upD [dest]:
    81   "f \<in> up R ==> f n \<in> carrier R"
    82   by (simp add: up_def Pi_def)
    83 
    84 context ring
    85 begin
    86 
    87 lemma bound_upD [dest]: "f \<in> up R ==> EX n. bound \<zero> n f" by (simp add: up_def)
    88 
    89 lemma up_one_closed: "(%n. if n = 0 then \<one> else \<zero>) \<in> up R" using up_def by force
    90 
    91 lemma up_smult_closed: "[| a \<in> carrier R; p \<in> up R |] ==> (%i. a \<otimes> p i) \<in> up R" by force
    92 
    93 lemma up_add_closed:
    94   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<oplus> q i) \<in> up R"
    95 proof
    96   fix n
    97   assume "p \<in> up R" and "q \<in> up R"
    98   then show "p n \<oplus> q n \<in> carrier R"
    99     by auto
   100 next
   101   assume UP: "p \<in> up R" "q \<in> up R"
   102   show "EX n. bound \<zero> n (%i. p i \<oplus> q i)"
   103   proof -
   104     from UP obtain n where boundn: "bound \<zero> n p" by fast
   105     from UP obtain m where boundm: "bound \<zero> m q" by fast
   106     have "bound \<zero> (max n m) (%i. p i \<oplus> q i)"
   107     proof
   108       fix i
   109       assume "max n m < i"
   110       with boundn and boundm and UP show "p i \<oplus> q i = \<zero>" by fastsimp
   111     qed
   112     then show ?thesis ..
   113   qed
   114 qed
   115 
   116 lemma up_a_inv_closed:
   117   "p \<in> up R ==> (%i. \<ominus> (p i)) \<in> up R"
   118 proof
   119   assume R: "p \<in> up R"
   120   then obtain n where "bound \<zero> n p" by auto
   121   then have "bound \<zero> n (%i. \<ominus> p i)" by auto
   122   then show "EX n. bound \<zero> n (%i. \<ominus> p i)" by auto
   123 qed auto
   124 
   125 lemma up_minus_closed:
   126   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<ominus> q i) \<in> up R"
   127   using mem_upD [of p R] mem_upD [of q R] up_add_closed up_a_inv_closed a_minus_def [of _ R]
   128   by auto
   129 
   130 lemma up_mult_closed:
   131   "[| p \<in> up R; q \<in> up R |] ==>
   132   (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> up R"
   133 proof
   134   fix n
   135   assume "p \<in> up R" "q \<in> up R"
   136   then show "(\<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> carrier R"
   137     by (simp add: mem_upD  funcsetI)
   138 next
   139   assume UP: "p \<in> up R" "q \<in> up R"
   140   show "EX n. bound \<zero> n (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i))"
   141   proof -
   142     from UP obtain n where boundn: "bound \<zero> n p" by fast
   143     from UP obtain m where boundm: "bound \<zero> m q" by fast
   144     have "bound \<zero> (n + m) (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n - i))"
   145     proof
   146       fix k assume bound: "n + m < k"
   147       {
   148         fix i
   149         have "p i \<otimes> q (k-i) = \<zero>"
   150         proof (cases "n < i")
   151           case True
   152           with boundn have "p i = \<zero>" by auto
   153           moreover from UP have "q (k-i) \<in> carrier R" by auto
   154           ultimately show ?thesis by simp
   155         next
   156           case False
   157           with bound have "m < k-i" by arith
   158           with boundm have "q (k-i) = \<zero>" by auto
   159           moreover from UP have "p i \<in> carrier R" by auto
   160           ultimately show ?thesis by simp
   161         qed
   162       }
   163       then show "(\<Oplus>i \<in> {..k}. p i \<otimes> q (k-i)) = \<zero>"
   164         by (simp add: Pi_def)
   165     qed
   166     then show ?thesis by fast
   167   qed
   168 qed
   169 
   170 end
   171 
   172 
   173 subsection {* Effect of Operations on Coefficients *}
   174 
   175 locale UP =
   176   fixes R (structure) and P (structure)
   177   defines P_def: "P == UP R"
   178 
   179 locale UP_ring = UP + R: ring R
   180 
   181 locale UP_cring = UP + R: cring R
   182 
   183 sublocale UP_cring < UP_ring
   184   by intro_locales [1] (rule P_def)
   185 
   186 locale UP_domain = UP + R: "domain" R
   187 
   188 sublocale UP_domain < UP_cring
   189   by intro_locales [1] (rule P_def)
   190 
   191 context UP
   192 begin
   193 
   194 text {*Temporarily declare @{thm P_def} as simp rule.*}
   195 
   196 declare P_def [simp]
   197 
   198 lemma up_eqI:
   199   assumes prem: "!!n. coeff P p n = coeff P q n" and R: "p \<in> carrier P" "q \<in> carrier P"
   200   shows "p = q"
   201 proof
   202   fix x
   203   from prem and R show "p x = q x" by (simp add: UP_def)
   204 qed
   205 
   206 lemma coeff_closed [simp]:
   207   "p \<in> carrier P ==> coeff P p n \<in> carrier R" by (auto simp add: UP_def)
   208 
   209 end
   210 
   211 context UP_ring 
   212 begin
   213 
   214 (* Theorems generalised from commutative rings to rings by Jesus Aransay. *)
   215 
   216 lemma coeff_monom [simp]:
   217   "a \<in> carrier R ==> coeff P (monom P a m) n = (if m=n then a else \<zero>)"
   218 proof -
   219   assume R: "a \<in> carrier R"
   220   then have "(%n. if n = m then a else \<zero>) \<in> up R"
   221     using up_def by force
   222   with R show ?thesis by (simp add: UP_def)
   223 qed
   224 
   225 lemma coeff_zero [simp]: "coeff P \<zero>\<^bsub>P\<^esub> n = \<zero>" by (auto simp add: UP_def)
   226 
   227 lemma coeff_one [simp]: "coeff P \<one>\<^bsub>P\<^esub> n = (if n=0 then \<one> else \<zero>)"
   228   using up_one_closed by (simp add: UP_def)
   229 
   230 lemma coeff_smult [simp]:
   231   "[| a \<in> carrier R; p \<in> carrier P |] ==> coeff P (a \<odot>\<^bsub>P\<^esub> p) n = a \<otimes> coeff P p n"
   232   by (simp add: UP_def up_smult_closed)
   233 
   234 lemma coeff_add [simp]:
   235   "[| p \<in> carrier P; q \<in> carrier P |] ==> coeff P (p \<oplus>\<^bsub>P\<^esub> q) n = coeff P p n \<oplus> coeff P q n"
   236   by (simp add: UP_def up_add_closed)
   237 
   238 lemma coeff_mult [simp]:
   239   "[| p \<in> carrier P; q \<in> carrier P |] ==> coeff P (p \<otimes>\<^bsub>P\<^esub> q) n = (\<Oplus>i \<in> {..n}. coeff P p i \<otimes> coeff P q (n-i))"
   240   by (simp add: UP_def up_mult_closed)
   241 
   242 end
   243 
   244 
   245 subsection {* Polynomials Form a Ring. *}
   246 
   247 context UP_ring
   248 begin
   249 
   250 text {* Operations are closed over @{term P}. *}
   251 
   252 lemma UP_mult_closed [simp]:
   253   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<otimes>\<^bsub>P\<^esub> q \<in> carrier P" by (simp add: UP_def up_mult_closed)
   254 
   255 lemma UP_one_closed [simp]:
   256   "\<one>\<^bsub>P\<^esub> \<in> carrier P" by (simp add: UP_def up_one_closed)
   257 
   258 lemma UP_zero_closed [intro, simp]:
   259   "\<zero>\<^bsub>P\<^esub> \<in> carrier P" by (auto simp add: UP_def)
   260 
   261 lemma UP_a_closed [intro, simp]:
   262   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<oplus>\<^bsub>P\<^esub> q \<in> carrier P" by (simp add: UP_def up_add_closed)
   263 
   264 lemma monom_closed [simp]:
   265   "a \<in> carrier R ==> monom P a n \<in> carrier P" by (auto simp add: UP_def up_def Pi_def)
   266 
   267 lemma UP_smult_closed [simp]:
   268   "[| a \<in> carrier R; p \<in> carrier P |] ==> a \<odot>\<^bsub>P\<^esub> p \<in> carrier P" by (simp add: UP_def up_smult_closed)
   269 
   270 end
   271 
   272 declare (in UP) P_def [simp del]
   273 
   274 text {* Algebraic ring properties *}
   275 
   276 context UP_ring
   277 begin
   278 
   279 lemma UP_a_assoc:
   280   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   281   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<oplus>\<^bsub>P\<^esub> r = p \<oplus>\<^bsub>P\<^esub> (q \<oplus>\<^bsub>P\<^esub> r)" by (rule up_eqI, simp add: a_assoc R, simp_all add: R)
   282 
   283 lemma UP_l_zero [simp]:
   284   assumes R: "p \<in> carrier P"
   285   shows "\<zero>\<^bsub>P\<^esub> \<oplus>\<^bsub>P\<^esub> p = p" by (rule up_eqI, simp_all add: R)
   286 
   287 lemma UP_l_neg_ex:
   288   assumes R: "p \<in> carrier P"
   289   shows "EX q : carrier P. q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   290 proof -
   291   let ?q = "%i. \<ominus> (p i)"
   292   from R have closed: "?q \<in> carrier P"
   293     by (simp add: UP_def P_def up_a_inv_closed)
   294   from R have coeff: "!!n. coeff P ?q n = \<ominus> (coeff P p n)"
   295     by (simp add: UP_def P_def up_a_inv_closed)
   296   show ?thesis
   297   proof
   298     show "?q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   299       by (auto intro!: up_eqI simp add: R closed coeff R.l_neg)
   300   qed (rule closed)
   301 qed
   302 
   303 lemma UP_a_comm:
   304   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   305   shows "p \<oplus>\<^bsub>P\<^esub> q = q \<oplus>\<^bsub>P\<^esub> p" by (rule up_eqI, simp add: a_comm R, simp_all add: R)
   306 
   307 lemma UP_m_assoc:
   308   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   309   shows "(p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   310 proof (rule up_eqI)
   311   fix n
   312   {
   313     fix k and a b c :: "nat=>'a"
   314     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   315       "c \<in> UNIV -> carrier R"
   316     then have "k <= n ==>
   317       (\<Oplus>j \<in> {..k}. (\<Oplus>i \<in> {..j}. a i \<otimes> b (j-i)) \<otimes> c (n-j)) =
   318       (\<Oplus>j \<in> {..k}. a j \<otimes> (\<Oplus>i \<in> {..k-j}. b i \<otimes> c (n-j-i)))"
   319       (is "_ \<Longrightarrow> ?eq k")
   320     proof (induct k)
   321       case 0 then show ?case by (simp add: Pi_def m_assoc)
   322     next
   323       case (Suc k)
   324       then have "k <= n" by arith
   325       from this R have "?eq k" by (rule Suc)
   326       with R show ?case
   327         by (simp cong: finsum_cong
   328              add: Suc_diff_le Pi_def l_distr r_distr m_assoc)
   329            (simp cong: finsum_cong add: Pi_def a_ac finsum_ldistr m_assoc)
   330     qed
   331   }
   332   with R show "coeff P ((p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r) n = coeff P (p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)) n"
   333     by (simp add: Pi_def)
   334 qed (simp_all add: R)
   335 
   336 lemma UP_r_one [simp]:
   337   assumes R: "p \<in> carrier P" shows "p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub> = p"
   338 proof (rule up_eqI)
   339   fix n
   340   show "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) n = coeff P p n"
   341   proof (cases n)
   342     case 0 
   343     {
   344       with R show ?thesis by simp
   345     }
   346   next
   347     case Suc
   348     {
   349       (*JE: in the locale UP_cring the proof was solved only with "by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)", but I did not get it to work here*)
   350       fix nn assume Succ: "n = Suc nn"
   351       have "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) (Suc nn) = coeff P p (Suc nn)"
   352       proof -
   353         have "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) (Suc nn) = (\<Oplus>i\<in>{..Suc nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" using R by simp
   354         also have "\<dots> = coeff P p (Suc nn) \<otimes> (if Suc nn \<le> Suc nn then \<one> else \<zero>) \<oplus> (\<Oplus>i\<in>{..nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))"
   355           using finsum_Suc [of "(\<lambda>i::nat. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" "nn"] unfolding Pi_def using R by simp
   356         also have "\<dots> = coeff P p (Suc nn) \<otimes> (if Suc nn \<le> Suc nn then \<one> else \<zero>)"
   357         proof -
   358           have "(\<Oplus>i\<in>{..nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>)) = (\<Oplus>i\<in>{..nn}. \<zero>)"
   359             using finsum_cong [of "{..nn}" "{..nn}" "(\<lambda>i::nat. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" "(\<lambda>i::nat. \<zero>)"] using R 
   360             unfolding Pi_def by simp
   361           also have "\<dots> = \<zero>" by simp
   362           finally show ?thesis using r_zero R by simp
   363         qed
   364         also have "\<dots> = coeff P p (Suc nn)" using R by simp
   365         finally show ?thesis by simp
   366       qed
   367       then show ?thesis using Succ by simp
   368     }
   369   qed
   370 qed (simp_all add: R)
   371   
   372 lemma UP_l_one [simp]:
   373   assumes R: "p \<in> carrier P"
   374   shows "\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p = p"
   375 proof (rule up_eqI)
   376   fix n
   377   show "coeff P (\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p) n = coeff P p n"
   378   proof (cases n)
   379     case 0 with R show ?thesis by simp
   380   next
   381     case Suc with R show ?thesis
   382       by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)
   383   qed
   384 qed (simp_all add: R)
   385 
   386 lemma UP_l_distr:
   387   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   388   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = (p \<otimes>\<^bsub>P\<^esub> r) \<oplus>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   389   by (rule up_eqI) (simp add: l_distr R Pi_def, simp_all add: R)
   390 
   391 lemma UP_r_distr:
   392   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   393   shows "r \<otimes>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = (r \<otimes>\<^bsub>P\<^esub> p) \<oplus>\<^bsub>P\<^esub> (r \<otimes>\<^bsub>P\<^esub> q)"
   394   by (rule up_eqI) (simp add: r_distr R Pi_def, simp_all add: R)
   395 
   396 theorem UP_ring: "ring P"
   397   by (auto intro!: ringI abelian_groupI monoidI UP_a_assoc)
   398     (auto intro: UP_a_comm UP_l_neg_ex UP_m_assoc UP_l_distr UP_r_distr)
   399 
   400 end
   401 
   402 
   403 subsection {* Polynomials Form a Commutative Ring. *}
   404 
   405 context UP_cring
   406 begin
   407 
   408 lemma UP_m_comm:
   409   assumes R1: "p \<in> carrier P" and R2: "q \<in> carrier P" shows "p \<otimes>\<^bsub>P\<^esub> q = q \<otimes>\<^bsub>P\<^esub> p"
   410 proof (rule up_eqI)
   411   fix n
   412   {
   413     fix k and a b :: "nat=>'a"
   414     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   415     then have "k <= n ==>
   416       (\<Oplus>i \<in> {..k}. a i \<otimes> b (n-i)) = (\<Oplus>i \<in> {..k}. a (k-i) \<otimes> b (i+n-k))"
   417       (is "_ \<Longrightarrow> ?eq k")
   418     proof (induct k)
   419       case 0 then show ?case by (simp add: Pi_def)
   420     next
   421       case (Suc k) then show ?case
   422         by (subst (2) finsum_Suc2) (simp add: Pi_def a_comm)+
   423     qed
   424   }
   425   note l = this
   426   from R1 R2 show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) n =  coeff P (q \<otimes>\<^bsub>P\<^esub> p) n"
   427     unfolding coeff_mult [OF R1 R2, of n] 
   428     unfolding coeff_mult [OF R2 R1, of n] 
   429     using l [of "(\<lambda>i. coeff P p i)" "(\<lambda>i. coeff P q i)" "n"] by (simp add: Pi_def m_comm)
   430 qed (simp_all add: R1 R2)
   431 
   432 subsection{*Polynomials over a commutative ring for a commutative ring*}
   433 
   434 theorem UP_cring:
   435   "cring P" using UP_ring unfolding cring_def by (auto intro!: comm_monoidI UP_m_assoc UP_m_comm)
   436 
   437 end
   438 
   439 context UP_ring
   440 begin
   441 
   442 lemma UP_a_inv_closed [intro, simp]:
   443   "p \<in> carrier P ==> \<ominus>\<^bsub>P\<^esub> p \<in> carrier P"
   444   by (rule abelian_group.a_inv_closed [OF ring.is_abelian_group [OF UP_ring]])
   445 
   446 lemma coeff_a_inv [simp]:
   447   assumes R: "p \<in> carrier P"
   448   shows "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> (coeff P p n)"
   449 proof -
   450   from R coeff_closed UP_a_inv_closed have
   451     "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> coeff P p n \<oplus> (coeff P p n \<oplus> coeff P (\<ominus>\<^bsub>P\<^esub> p) n)"
   452     by algebra
   453   also from R have "... =  \<ominus> (coeff P p n)"
   454     by (simp del: coeff_add add: coeff_add [THEN sym]
   455       abelian_group.r_neg [OF ring.is_abelian_group [OF UP_ring]])
   456   finally show ?thesis .
   457 qed
   458 
   459 end
   460 
   461 sublocale UP_ring < P: ring P using UP_ring .
   462 sublocale UP_cring < P: cring P using UP_cring .
   463 
   464 
   465 subsection {* Polynomials Form an Algebra *}
   466 
   467 context UP_ring
   468 begin
   469 
   470 lemma UP_smult_l_distr:
   471   "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   472   (a \<oplus> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> b \<odot>\<^bsub>P\<^esub> p"
   473   by (rule up_eqI) (simp_all add: R.l_distr)
   474 
   475 lemma UP_smult_r_distr:
   476   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   477   a \<odot>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> a \<odot>\<^bsub>P\<^esub> q"
   478   by (rule up_eqI) (simp_all add: R.r_distr)
   479 
   480 lemma UP_smult_assoc1:
   481       "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   482       (a \<otimes> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> p)"
   483   by (rule up_eqI) (simp_all add: R.m_assoc)
   484 
   485 lemma UP_smult_zero [simp]:
   486       "p \<in> carrier P ==> \<zero> \<odot>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   487   by (rule up_eqI) simp_all
   488 
   489 lemma UP_smult_one [simp]:
   490       "p \<in> carrier P ==> \<one> \<odot>\<^bsub>P\<^esub> p = p"
   491   by (rule up_eqI) simp_all
   492 
   493 lemma UP_smult_assoc2:
   494   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   495   (a \<odot>\<^bsub>P\<^esub> p) \<otimes>\<^bsub>P\<^esub> q = a \<odot>\<^bsub>P\<^esub> (p \<otimes>\<^bsub>P\<^esub> q)"
   496   by (rule up_eqI) (simp_all add: R.finsum_rdistr R.m_assoc Pi_def)
   497 
   498 end
   499 
   500 text {*
   501   Interpretation of lemmas from @{term algebra}.
   502 *}
   503 
   504 lemma (in cring) cring:
   505   "cring R" ..
   506 
   507 lemma (in UP_cring) UP_algebra:
   508   "algebra R P" by (auto intro!: algebraI R.cring UP_cring UP_smult_l_distr UP_smult_r_distr
   509     UP_smult_assoc1 UP_smult_assoc2)
   510 
   511 sublocale UP_cring < algebra R P using UP_algebra .
   512 
   513 
   514 subsection {* Further Lemmas Involving Monomials *}
   515 
   516 context UP_ring
   517 begin
   518 
   519 lemma monom_zero [simp]:
   520   "monom P \<zero> n = \<zero>\<^bsub>P\<^esub>" by (simp add: UP_def P_def)
   521 
   522 lemma monom_mult_is_smult:
   523   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   524   shows "monom P a 0 \<otimes>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p"
   525 proof (rule up_eqI)
   526   fix n
   527   show "coeff P (monom P a 0 \<otimes>\<^bsub>P\<^esub> p) n = coeff P (a \<odot>\<^bsub>P\<^esub> p) n"
   528   proof (cases n)
   529     case 0 with R show ?thesis by simp
   530   next
   531     case Suc with R show ?thesis
   532       using R.finsum_Suc2 by (simp del: R.finsum_Suc add: R.r_null Pi_def)
   533   qed
   534 qed (simp_all add: R)
   535 
   536 lemma monom_one [simp]:
   537   "monom P \<one> 0 = \<one>\<^bsub>P\<^esub>"
   538   by (rule up_eqI) simp_all
   539 
   540 lemma monom_add [simp]:
   541   "[| a \<in> carrier R; b \<in> carrier R |] ==>
   542   monom P (a \<oplus> b) n = monom P a n \<oplus>\<^bsub>P\<^esub> monom P b n"
   543   by (rule up_eqI) simp_all
   544 
   545 lemma monom_one_Suc:
   546   "monom P \<one> (Suc n) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   547 proof (rule up_eqI)
   548   fix k
   549   show "coeff P (monom P \<one> (Suc n)) k = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   550   proof (cases "k = Suc n")
   551     case True show ?thesis
   552     proof -
   553       fix m
   554       from True have less_add_diff:
   555         "!!i. [| n < i; i <= n + m |] ==> n + m - i < m" by arith
   556       from True have "coeff P (monom P \<one> (Suc n)) k = \<one>" by simp
   557       also from True
   558       have "... = (\<Oplus>i \<in> {..<n} \<union> {n}. coeff P (monom P \<one> n) i \<otimes>
   559         coeff P (monom P \<one> 1) (k - i))"
   560         by (simp cong: R.finsum_cong add: Pi_def)
   561       also have "... = (\<Oplus>i \<in>  {..n}. coeff P (monom P \<one> n) i \<otimes>
   562         coeff P (monom P \<one> 1) (k - i))"
   563         by (simp only: ivl_disj_un_singleton)
   564       also from True
   565       have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. coeff P (monom P \<one> n) i \<otimes>
   566         coeff P (monom P \<one> 1) (k - i))"
   567         by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one
   568           order_less_imp_not_eq Pi_def)
   569       also from True have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   570         by (simp add: ivl_disj_un_one)
   571       finally show ?thesis .
   572     qed
   573   next
   574     case False
   575     note neq = False
   576     let ?s =
   577       "\<lambda>i. (if n = i then \<one> else \<zero>) \<otimes> (if Suc 0 = k - i then \<one> else \<zero>)"
   578     from neq have "coeff P (monom P \<one> (Suc n)) k = \<zero>" by simp
   579     also have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   580     proof -
   581       have f1: "(\<Oplus>i \<in> {..<n}. ?s i) = \<zero>"
   582         by (simp cong: R.finsum_cong add: Pi_def)
   583       from neq have f2: "(\<Oplus>i \<in> {n}. ?s i) = \<zero>"
   584         by (simp cong: R.finsum_cong add: Pi_def) arith
   585       have f3: "n < k ==> (\<Oplus>i \<in> {n<..k}. ?s i) = \<zero>"
   586         by (simp cong: R.finsum_cong add: order_less_imp_not_eq Pi_def)
   587       show ?thesis
   588       proof (cases "k < n")
   589         case True then show ?thesis by (simp cong: R.finsum_cong add: Pi_def)
   590       next
   591         case False then have n_le_k: "n <= k" by arith
   592         show ?thesis
   593         proof (cases "n = k")
   594           case True
   595           then have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   596             by (simp cong: R.finsum_cong add: Pi_def)
   597           also from True have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   598             by (simp only: ivl_disj_un_singleton)
   599           finally show ?thesis .
   600         next
   601           case False with n_le_k have n_less_k: "n < k" by arith
   602           with neq have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   603             by (simp add: R.finsum_Un_disjoint f1 f2 Pi_def del: Un_insert_right)
   604           also have "... = (\<Oplus>i \<in> {..n}. ?s i)"
   605             by (simp only: ivl_disj_un_singleton)
   606           also from n_less_k neq have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. ?s i)"
   607             by (simp add: R.finsum_Un_disjoint f3 ivl_disj_int_one Pi_def)
   608           also from n_less_k have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   609             by (simp only: ivl_disj_un_one)
   610           finally show ?thesis .
   611         qed
   612       qed
   613     qed
   614     also have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k" by simp
   615     finally show ?thesis .
   616   qed
   617 qed (simp_all)
   618 
   619 lemma monom_one_Suc2:
   620   "monom P \<one> (Suc n) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> n"
   621 proof (induct n)
   622   case 0 show ?case by simp
   623 next
   624   case Suc
   625   {
   626     fix k:: nat
   627     assume hypo: "monom P \<one> (Suc k) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k"
   628     then show "monom P \<one> (Suc (Suc k)) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> (Suc k)"
   629     proof -
   630       have lhs: "monom P \<one> (Suc (Suc k)) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   631         unfolding monom_one_Suc [of "Suc k"] unfolding hypo ..
   632       note cl = monom_closed [OF R.one_closed, of 1]
   633       note clk = monom_closed [OF R.one_closed, of k]
   634       have rhs: "monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> (Suc k) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   635         unfolding monom_one_Suc [of k] unfolding sym [OF m_assoc  [OF cl clk cl]] ..
   636       from lhs rhs show ?thesis by simp
   637     qed
   638   }
   639 qed
   640 
   641 text{*The following corollary follows from lemmas @{thm "monom_one_Suc"} 
   642   and @{thm "monom_one_Suc2"}, and is trivial in @{term UP_cring}*}
   643 
   644 corollary monom_one_comm: shows "monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k"
   645   unfolding monom_one_Suc [symmetric] monom_one_Suc2 [symmetric] ..
   646 
   647 lemma monom_mult_smult:
   648   "[| a \<in> carrier R; b \<in> carrier R |] ==> monom P (a \<otimes> b) n = a \<odot>\<^bsub>P\<^esub> monom P b n"
   649   by (rule up_eqI) simp_all
   650 
   651 lemma monom_one_mult:
   652   "monom P \<one> (n + m) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m"
   653 proof (induct n)
   654   case 0 show ?case by simp
   655 next
   656   case Suc then show ?case
   657     unfolding add_Suc unfolding monom_one_Suc unfolding Suc.hyps
   658     using m_assoc monom_one_comm [of m] by simp
   659 qed
   660 
   661 lemma monom_one_mult_comm: "monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m = monom P \<one> m \<otimes>\<^bsub>P\<^esub> monom P \<one> n"
   662   unfolding monom_one_mult [symmetric] by (rule up_eqI) simp_all
   663 
   664 lemma monom_mult [simp]:
   665   assumes a_in_R: "a \<in> carrier R" and b_in_R: "b \<in> carrier R"
   666   shows "monom P (a \<otimes> b) (n + m) = monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m"
   667 proof (rule up_eqI)
   668   fix k 
   669   show "coeff P (monom P (a \<otimes> b) (n + m)) k = coeff P (monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m) k"
   670   proof (cases "n + m = k")
   671     case True 
   672     {
   673       show ?thesis
   674         unfolding True [symmetric]
   675           coeff_mult [OF monom_closed [OF a_in_R, of n] monom_closed [OF b_in_R, of m], of "n + m"] 
   676           coeff_monom [OF a_in_R, of n] coeff_monom [OF b_in_R, of m]
   677         using R.finsum_cong [of "{.. n + m}" "{.. n + m}" "(\<lambda>i. (if n = i then a else \<zero>) \<otimes> (if m = n + m - i then b else \<zero>))" 
   678           "(\<lambda>i. if n = i then a \<otimes> b else \<zero>)"]
   679           a_in_R b_in_R
   680         unfolding simp_implies_def
   681         using R.finsum_singleton [of n "{.. n + m}" "(\<lambda>i. a \<otimes> b)"]
   682         unfolding Pi_def by auto
   683     }
   684   next
   685     case False
   686     {
   687       show ?thesis
   688         unfolding coeff_monom [OF R.m_closed [OF a_in_R b_in_R], of "n + m" k] apply (simp add: False)
   689         unfolding coeff_mult [OF monom_closed [OF a_in_R, of n] monom_closed [OF b_in_R, of m], of k]
   690         unfolding coeff_monom [OF a_in_R, of n] unfolding coeff_monom [OF b_in_R, of m] using False
   691         using R.finsum_cong [of "{..k}" "{..k}" "(\<lambda>i. (if n = i then a else \<zero>) \<otimes> (if m = k - i then b else \<zero>))" "(\<lambda>i. \<zero>)"]
   692         unfolding Pi_def simp_implies_def using a_in_R b_in_R by force
   693     }
   694   qed
   695 qed (simp_all add: a_in_R b_in_R)
   696 
   697 lemma monom_a_inv [simp]:
   698   "a \<in> carrier R ==> monom P (\<ominus> a) n = \<ominus>\<^bsub>P\<^esub> monom P a n"
   699   by (rule up_eqI) simp_all
   700 
   701 lemma monom_inj:
   702   "inj_on (%a. monom P a n) (carrier R)"
   703 proof (rule inj_onI)
   704   fix x y
   705   assume R: "x \<in> carrier R" "y \<in> carrier R" and eq: "monom P x n = monom P y n"
   706   then have "coeff P (monom P x n) n = coeff P (monom P y n) n" by simp
   707   with R show "x = y" by simp
   708 qed
   709 
   710 end
   711 
   712 
   713 subsection {* The Degree Function *}
   714 
   715 definition
   716   deg :: "[('a, 'm) ring_scheme, nat => 'a] => nat"
   717   where "deg R p = (LEAST n. bound \<zero>\<^bsub>R\<^esub> n (coeff (UP R) p))"
   718 
   719 context UP_ring
   720 begin
   721 
   722 lemma deg_aboveI:
   723   "[| (!!m. n < m ==> coeff P p m = \<zero>); p \<in> carrier P |] ==> deg R p <= n"
   724   by (unfold deg_def P_def) (fast intro: Least_le)
   725 
   726 (*
   727 lemma coeff_bound_ex: "EX n. bound n (coeff p)"
   728 proof -
   729   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   730   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   731   then show ?thesis ..
   732 qed
   733 
   734 lemma bound_coeff_obtain:
   735   assumes prem: "(!!n. bound n (coeff p) ==> P)" shows "P"
   736 proof -
   737   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   738   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   739   with prem show P .
   740 qed
   741 *)
   742 
   743 lemma deg_aboveD:
   744   assumes "deg R p < m" and "p \<in> carrier P"
   745   shows "coeff P p m = \<zero>"
   746 proof -
   747   from `p \<in> carrier P` obtain n where "bound \<zero> n (coeff P p)"
   748     by (auto simp add: UP_def P_def)
   749   then have "bound \<zero> (deg R p) (coeff P p)"
   750     by (auto simp: deg_def P_def dest: LeastI)
   751   from this and `deg R p < m` show ?thesis ..
   752 qed
   753 
   754 lemma deg_belowI:
   755   assumes non_zero: "n ~= 0 ==> coeff P p n ~= \<zero>"
   756     and R: "p \<in> carrier P"
   757   shows "n <= deg R p"
   758 -- {* Logically, this is a slightly stronger version of
   759    @{thm [source] deg_aboveD} *}
   760 proof (cases "n=0")
   761   case True then show ?thesis by simp
   762 next
   763   case False then have "coeff P p n ~= \<zero>" by (rule non_zero)
   764   then have "~ deg R p < n" by (fast dest: deg_aboveD intro: R)
   765   then show ?thesis by arith
   766 qed
   767 
   768 lemma lcoeff_nonzero_deg:
   769   assumes deg: "deg R p ~= 0" and R: "p \<in> carrier P"
   770   shows "coeff P p (deg R p) ~= \<zero>"
   771 proof -
   772   from R obtain m where "deg R p <= m" and m_coeff: "coeff P p m ~= \<zero>"
   773   proof -
   774     have minus: "!!(n::nat) m. n ~= 0 ==> (n - Suc 0 < m) = (n <= m)"
   775       by arith
   776     from deg have "deg R p - 1 < (LEAST n. bound \<zero> n (coeff P p))"
   777       by (unfold deg_def P_def) simp
   778     then have "~ bound \<zero> (deg R p - 1) (coeff P p)" by (rule not_less_Least)
   779     then have "EX m. deg R p - 1 < m & coeff P p m ~= \<zero>"
   780       by (unfold bound_def) fast
   781     then have "EX m. deg R p <= m & coeff P p m ~= \<zero>" by (simp add: deg minus)
   782     then show ?thesis by (auto intro: that)
   783   qed
   784   with deg_belowI R have "deg R p = m" by fastsimp
   785   with m_coeff show ?thesis by simp
   786 qed
   787 
   788 lemma lcoeff_nonzero_nonzero:
   789   assumes deg: "deg R p = 0" and nonzero: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   790   shows "coeff P p 0 ~= \<zero>"
   791 proof -
   792   have "EX m. coeff P p m ~= \<zero>"
   793   proof (rule classical)
   794     assume "~ ?thesis"
   795     with R have "p = \<zero>\<^bsub>P\<^esub>" by (auto intro: up_eqI)
   796     with nonzero show ?thesis by contradiction
   797   qed
   798   then obtain m where coeff: "coeff P p m ~= \<zero>" ..
   799   from this and R have "m <= deg R p" by (rule deg_belowI)
   800   then have "m = 0" by (simp add: deg)
   801   with coeff show ?thesis by simp
   802 qed
   803 
   804 lemma lcoeff_nonzero:
   805   assumes neq: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   806   shows "coeff P p (deg R p) ~= \<zero>"
   807 proof (cases "deg R p = 0")
   808   case True with neq R show ?thesis by (simp add: lcoeff_nonzero_nonzero)
   809 next
   810   case False with neq R show ?thesis by (simp add: lcoeff_nonzero_deg)
   811 qed
   812 
   813 lemma deg_eqI:
   814   "[| !!m. n < m ==> coeff P p m = \<zero>;
   815       !!n. n ~= 0 ==> coeff P p n ~= \<zero>; p \<in> carrier P |] ==> deg R p = n"
   816 by (fast intro: le_antisym deg_aboveI deg_belowI)
   817 
   818 text {* Degree and polynomial operations *}
   819 
   820 lemma deg_add [simp]:
   821   "p \<in> carrier P \<Longrightarrow> q \<in> carrier P \<Longrightarrow>
   822   deg R (p \<oplus>\<^bsub>P\<^esub> q) <= max (deg R p) (deg R q)"
   823 by(rule deg_aboveI)(simp_all add: deg_aboveD)
   824 
   825 lemma deg_monom_le:
   826   "a \<in> carrier R ==> deg R (monom P a n) <= n"
   827   by (intro deg_aboveI) simp_all
   828 
   829 lemma deg_monom [simp]:
   830   "[| a ~= \<zero>; a \<in> carrier R |] ==> deg R (monom P a n) = n"
   831   by (fastsimp intro: le_antisym deg_aboveI deg_belowI)
   832 
   833 lemma deg_const [simp]:
   834   assumes R: "a \<in> carrier R" shows "deg R (monom P a 0) = 0"
   835 proof (rule le_antisym)
   836   show "deg R (monom P a 0) <= 0" by (rule deg_aboveI) (simp_all add: R)
   837 next
   838   show "0 <= deg R (monom P a 0)" by (rule deg_belowI) (simp_all add: R)
   839 qed
   840 
   841 lemma deg_zero [simp]:
   842   "deg R \<zero>\<^bsub>P\<^esub> = 0"
   843 proof (rule le_antisym)
   844   show "deg R \<zero>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   845 next
   846   show "0 <= deg R \<zero>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   847 qed
   848 
   849 lemma deg_one [simp]:
   850   "deg R \<one>\<^bsub>P\<^esub> = 0"
   851 proof (rule le_antisym)
   852   show "deg R \<one>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   853 next
   854   show "0 <= deg R \<one>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   855 qed
   856 
   857 lemma deg_uminus [simp]:
   858   assumes R: "p \<in> carrier P" shows "deg R (\<ominus>\<^bsub>P\<^esub> p) = deg R p"
   859 proof (rule le_antisym)
   860   show "deg R (\<ominus>\<^bsub>P\<^esub> p) <= deg R p" by (simp add: deg_aboveI deg_aboveD R)
   861 next
   862   show "deg R p <= deg R (\<ominus>\<^bsub>P\<^esub> p)"
   863     by (simp add: deg_belowI lcoeff_nonzero_deg
   864       inj_on_iff [OF R.a_inv_inj, of _ "\<zero>", simplified] R)
   865 qed
   866 
   867 text{*The following lemma is later \emph{overwritten} by the most
   868   specific one for domains, @{text deg_smult}.*}
   869 
   870 lemma deg_smult_ring [simp]:
   871   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   872   deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   873   by (cases "a = \<zero>") (simp add: deg_aboveI deg_aboveD)+
   874 
   875 end
   876 
   877 context UP_domain
   878 begin
   879 
   880 lemma deg_smult [simp]:
   881   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   882   shows "deg R (a \<odot>\<^bsub>P\<^esub> p) = (if a = \<zero> then 0 else deg R p)"
   883 proof (rule le_antisym)
   884   show "deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   885     using R by (rule deg_smult_ring)
   886 next
   887   show "(if a = \<zero> then 0 else deg R p) <= deg R (a \<odot>\<^bsub>P\<^esub> p)"
   888   proof (cases "a = \<zero>")
   889   qed (simp, simp add: deg_belowI lcoeff_nonzero_deg integral_iff R)
   890 qed
   891 
   892 end
   893 
   894 context UP_ring
   895 begin
   896 
   897 lemma deg_mult_ring:
   898   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   899   shows "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q"
   900 proof (rule deg_aboveI)
   901   fix m
   902   assume boundm: "deg R p + deg R q < m"
   903   {
   904     fix k i
   905     assume boundk: "deg R p + deg R q < k"
   906     then have "coeff P p i \<otimes> coeff P q (k - i) = \<zero>"
   907     proof (cases "deg R p < i")
   908       case True then show ?thesis by (simp add: deg_aboveD R)
   909     next
   910       case False with boundk have "deg R q < k - i" by arith
   911       then show ?thesis by (simp add: deg_aboveD R)
   912     qed
   913   }
   914   with boundm R show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) m = \<zero>" by simp
   915 qed (simp add: R)
   916 
   917 end
   918 
   919 context UP_domain
   920 begin
   921 
   922 lemma deg_mult [simp]:
   923   "[| p ~= \<zero>\<^bsub>P\<^esub>; q ~= \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==>
   924   deg R (p \<otimes>\<^bsub>P\<^esub> q) = deg R p + deg R q"
   925 proof (rule le_antisym)
   926   assume "p \<in> carrier P" " q \<in> carrier P"
   927   then show "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q" by (rule deg_mult_ring)
   928 next
   929   let ?s = "(%i. coeff P p i \<otimes> coeff P q (deg R p + deg R q - i))"
   930   assume R: "p \<in> carrier P" "q \<in> carrier P" and nz: "p ~= \<zero>\<^bsub>P\<^esub>" "q ~= \<zero>\<^bsub>P\<^esub>"
   931   have less_add_diff: "!!(k::nat) n m. k < n ==> m < n + m - k" by arith
   932   show "deg R p + deg R q <= deg R (p \<otimes>\<^bsub>P\<^esub> q)"
   933   proof (rule deg_belowI, simp add: R)
   934     have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   935       = (\<Oplus>i \<in> {..< deg R p} \<union> {deg R p .. deg R p + deg R q}. ?s i)"
   936       by (simp only: ivl_disj_un_one)
   937     also have "... = (\<Oplus>i \<in> {deg R p .. deg R p + deg R q}. ?s i)"
   938       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one
   939         deg_aboveD less_add_diff R Pi_def)
   940     also have "...= (\<Oplus>i \<in> {deg R p} \<union> {deg R p <.. deg R p + deg R q}. ?s i)"
   941       by (simp only: ivl_disj_un_singleton)
   942     also have "... = coeff P p (deg R p) \<otimes> coeff P q (deg R q)"
   943       by (simp cong: R.finsum_cong add: deg_aboveD R Pi_def)
   944     finally have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   945       = coeff P p (deg R p) \<otimes> coeff P q (deg R q)" .
   946     with nz show "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i) ~= \<zero>"
   947       by (simp add: integral_iff lcoeff_nonzero R)
   948   qed (simp add: R)
   949 qed
   950 
   951 end
   952 
   953 text{*The following lemmas also can be lifted to @{term UP_ring}.*}
   954 
   955 context UP_ring
   956 begin
   957 
   958 lemma coeff_finsum:
   959   assumes fin: "finite A"
   960   shows "p \<in> A -> carrier P ==>
   961     coeff P (finsum P p A) k = (\<Oplus>i \<in> A. coeff P (p i) k)"
   962   using fin by induct (auto simp: Pi_def)
   963 
   964 lemma up_repr:
   965   assumes R: "p \<in> carrier P"
   966   shows "(\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. monom P (coeff P p i) i) = p"
   967 proof (rule up_eqI)
   968   let ?s = "(%i. monom P (coeff P p i) i)"
   969   fix k
   970   from R have RR: "!!i. (if i = k then coeff P p i else \<zero>) \<in> carrier R"
   971     by simp
   972   show "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k = coeff P p k"
   973   proof (cases "k <= deg R p")
   974     case True
   975     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
   976           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k} \<union> {k<..deg R p}. ?s i) k"
   977       by (simp only: ivl_disj_un_one)
   978     also from True
   979     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k}. ?s i) k"
   980       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint
   981         ivl_disj_int_one order_less_imp_not_eq2 coeff_finsum R RR Pi_def)
   982     also
   983     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<k} \<union> {k}. ?s i) k"
   984       by (simp only: ivl_disj_un_singleton)
   985     also have "... = coeff P p k"
   986       by (simp cong: R.finsum_cong add: coeff_finsum deg_aboveD R RR Pi_def)
   987     finally show ?thesis .
   988   next
   989     case False
   990     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
   991           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<deg R p} \<union> {deg R p}. ?s i) k"
   992       by (simp only: ivl_disj_un_singleton)
   993     also from False have "... = coeff P p k"
   994       by (simp cong: R.finsum_cong add: coeff_finsum deg_aboveD R Pi_def)
   995     finally show ?thesis .
   996   qed
   997 qed (simp_all add: R Pi_def)
   998 
   999 lemma up_repr_le:
  1000   "[| deg R p <= n; p \<in> carrier P |] ==>
  1001   (\<Oplus>\<^bsub>P\<^esub> i \<in> {..n}. monom P (coeff P p i) i) = p"
  1002 proof -
  1003   let ?s = "(%i. monom P (coeff P p i) i)"
  1004   assume R: "p \<in> carrier P" and "deg R p <= n"
  1005   then have "finsum P ?s {..n} = finsum P ?s ({..deg R p} \<union> {deg R p<..n})"
  1006     by (simp only: ivl_disj_un_one)
  1007   also have "... = finsum P ?s {..deg R p}"
  1008     by (simp cong: P.finsum_cong add: P.finsum_Un_disjoint ivl_disj_int_one
  1009       deg_aboveD R Pi_def)
  1010   also have "... = p" using R by (rule up_repr)
  1011   finally show ?thesis .
  1012 qed
  1013 
  1014 end
  1015 
  1016 
  1017 subsection {* Polynomials over Integral Domains *}
  1018 
  1019 lemma domainI:
  1020   assumes cring: "cring R"
  1021     and one_not_zero: "one R ~= zero R"
  1022     and integral: "!!a b. [| mult R a b = zero R; a \<in> carrier R;
  1023       b \<in> carrier R |] ==> a = zero R | b = zero R"
  1024   shows "domain R"
  1025   by (auto intro!: domain.intro domain_axioms.intro cring.axioms assms
  1026     del: disjCI)
  1027 
  1028 context UP_domain
  1029 begin
  1030 
  1031 lemma UP_one_not_zero:
  1032   "\<one>\<^bsub>P\<^esub> ~= \<zero>\<^bsub>P\<^esub>"
  1033 proof
  1034   assume "\<one>\<^bsub>P\<^esub> = \<zero>\<^bsub>P\<^esub>"
  1035   hence "coeff P \<one>\<^bsub>P\<^esub> 0 = (coeff P \<zero>\<^bsub>P\<^esub> 0)" by simp
  1036   hence "\<one> = \<zero>" by simp
  1037   with R.one_not_zero show "False" by contradiction
  1038 qed
  1039 
  1040 lemma UP_integral:
  1041   "[| p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==> p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
  1042 proof -
  1043   fix p q
  1044   assume pq: "p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P" "q \<in> carrier P"
  1045   show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
  1046   proof (rule classical)
  1047     assume c: "~ (p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>)"
  1048     with R have "deg R p + deg R q = deg R (p \<otimes>\<^bsub>P\<^esub> q)" by simp
  1049     also from pq have "... = 0" by simp
  1050     finally have "deg R p + deg R q = 0" .
  1051     then have f1: "deg R p = 0 & deg R q = 0" by simp
  1052     from f1 R have "p = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P p i) i)"
  1053       by (simp only: up_repr_le)
  1054     also from R have "... = monom P (coeff P p 0) 0" by simp
  1055     finally have p: "p = monom P (coeff P p 0) 0" .
  1056     from f1 R have "q = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P q i) i)"
  1057       by (simp only: up_repr_le)
  1058     also from R have "... = monom P (coeff P q 0) 0" by simp
  1059     finally have q: "q = monom P (coeff P q 0) 0" .
  1060     from R have "coeff P p 0 \<otimes> coeff P q 0 = coeff P (p \<otimes>\<^bsub>P\<^esub> q) 0" by simp
  1061     also from pq have "... = \<zero>" by simp
  1062     finally have "coeff P p 0 \<otimes> coeff P q 0 = \<zero>" .
  1063     with R have "coeff P p 0 = \<zero> | coeff P q 0 = \<zero>"
  1064       by (simp add: R.integral_iff)
  1065     with p q show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>" by fastsimp
  1066   qed
  1067 qed
  1068 
  1069 theorem UP_domain:
  1070   "domain P"
  1071   by (auto intro!: domainI UP_cring UP_one_not_zero UP_integral del: disjCI)
  1072 
  1073 end
  1074 
  1075 text {*
  1076   Interpretation of theorems from @{term domain}.
  1077 *}
  1078 
  1079 sublocale UP_domain < "domain" P
  1080   by intro_locales (rule domain.axioms UP_domain)+
  1081 
  1082 
  1083 subsection {* The Evaluation Homomorphism and Universal Property*}
  1084 
  1085 (* alternative congruence rule (possibly more efficient)
  1086 lemma (in abelian_monoid) finsum_cong2:
  1087   "[| !!i. i \<in> A ==> f i \<in> carrier G = True; A = B;
  1088   !!i. i \<in> B ==> f i = g i |] ==> finsum G f A = finsum G g B"
  1089   sorry*)
  1090 
  1091 lemma (in abelian_monoid) boundD_carrier:
  1092   "[| bound \<zero> n f; n < m |] ==> f m \<in> carrier G"
  1093   by auto
  1094 
  1095 context ring
  1096 begin
  1097 
  1098 theorem diagonal_sum:
  1099   "[| f \<in> {..n + m::nat} -> carrier R; g \<in> {..n + m} -> carrier R |] ==>
  1100   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1101   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1102 proof -
  1103   assume Rf: "f \<in> {..n + m} -> carrier R" and Rg: "g \<in> {..n + m} -> carrier R"
  1104   {
  1105     fix j
  1106     have "j <= n + m ==>
  1107       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1108       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..j - k}. f k \<otimes> g i)"
  1109     proof (induct j)
  1110       case 0 from Rf Rg show ?case by (simp add: Pi_def)
  1111     next
  1112       case (Suc j)
  1113       have R6: "!!i k. [| k <= j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1114         using Suc by (auto intro!: funcset_mem [OF Rg])
  1115       have R8: "!!i k. [| k <= Suc j; i <= k |] ==> g (k - i) \<in> carrier R"
  1116         using Suc by (auto intro!: funcset_mem [OF Rg])
  1117       have R9: "!!i k. [| k <= Suc j |] ==> f k \<in> carrier R"
  1118         using Suc by (auto intro!: funcset_mem [OF Rf])
  1119       have R10: "!!i k. [| k <= Suc j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1120         using Suc by (auto intro!: funcset_mem [OF Rg])
  1121       have R11: "g 0 \<in> carrier R"
  1122         using Suc by (auto intro!: funcset_mem [OF Rg])
  1123       from Suc show ?case
  1124         by (simp cong: finsum_cong add: Suc_diff_le a_ac
  1125           Pi_def R6 R8 R9 R10 R11)
  1126     qed
  1127   }
  1128   then show ?thesis by fast
  1129 qed
  1130 
  1131 theorem cauchy_product:
  1132   assumes bf: "bound \<zero> n f" and bg: "bound \<zero> m g"
  1133     and Rf: "f \<in> {..n} -> carrier R" and Rg: "g \<in> {..m} -> carrier R"
  1134   shows "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1135     (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"      (* State reverse direction? *)
  1136 proof -
  1137   have f: "!!x. f x \<in> carrier R"
  1138   proof -
  1139     fix x
  1140     show "f x \<in> carrier R"
  1141       using Rf bf boundD_carrier by (cases "x <= n") (auto simp: Pi_def)
  1142   qed
  1143   have g: "!!x. g x \<in> carrier R"
  1144   proof -
  1145     fix x
  1146     show "g x \<in> carrier R"
  1147       using Rg bg boundD_carrier by (cases "x <= m") (auto simp: Pi_def)
  1148   qed
  1149   from f g have "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1150       (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1151     by (simp add: diagonal_sum Pi_def)
  1152   also have "... = (\<Oplus>k \<in> {..n} \<union> {n<..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1153     by (simp only: ivl_disj_un_one)
  1154   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1155     by (simp cong: finsum_cong
  1156       add: bound.bound [OF bf] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1157   also from f g
  1158   have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m} \<union> {m<..n + m - k}. f k \<otimes> g i)"
  1159     by (simp cong: finsum_cong add: ivl_disj_un_one le_add_diff Pi_def)
  1160   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m}. f k \<otimes> g i)"
  1161     by (simp cong: finsum_cong
  1162       add: bound.bound [OF bg] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1163   also from f g have "... = (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"
  1164     by (simp add: finsum_ldistr diagonal_sum Pi_def,
  1165       simp cong: finsum_cong add: finsum_rdistr Pi_def)
  1166   finally show ?thesis .
  1167 qed
  1168 
  1169 end
  1170 
  1171 lemma (in UP_ring) const_ring_hom:
  1172   "(%a. monom P a 0) \<in> ring_hom R P"
  1173   by (auto intro!: ring_hom_memI intro: up_eqI simp: monom_mult_is_smult)
  1174 
  1175 definition
  1176   eval :: "[('a, 'm) ring_scheme, ('b, 'n) ring_scheme,
  1177            'a => 'b, 'b, nat => 'a] => 'b"
  1178   where "eval R S phi s = (\<lambda>p \<in> carrier (UP R).
  1179     \<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. phi (coeff (UP R) p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1180 
  1181 context UP
  1182 begin
  1183 
  1184 lemma eval_on_carrier:
  1185   fixes S (structure)
  1186   shows "p \<in> carrier P ==>
  1187   eval R S phi s p = (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. phi (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1188   by (unfold eval_def, fold P_def) simp
  1189 
  1190 lemma eval_extensional:
  1191   "eval R S phi p \<in> extensional (carrier P)"
  1192   by (unfold eval_def, fold P_def) simp
  1193 
  1194 end
  1195 
  1196 text {* The universal property of the polynomial ring *}
  1197 
  1198 locale UP_pre_univ_prop = ring_hom_cring + UP_cring
  1199 
  1200 (* FIXME print_locale ring_hom_cring fails *)
  1201 
  1202 locale UP_univ_prop = UP_pre_univ_prop +
  1203   fixes s and Eval
  1204   assumes indet_img_carrier [simp, intro]: "s \<in> carrier S"
  1205   defines Eval_def: "Eval == eval R S h s"
  1206 
  1207 text{*JE: I have moved the following lemma from Ring.thy and lifted then to the locale @{term ring_hom_ring} from @{term ring_hom_cring}.*}
  1208 text{*JE: I was considering using it in @{text eval_ring_hom}, but that property does not hold for non commutative rings, so 
  1209   maybe it is not that necessary.*}
  1210 
  1211 lemma (in ring_hom_ring) hom_finsum [simp]:
  1212   "[| finite A; f \<in> A -> carrier R |] ==>
  1213   h (finsum R f A) = finsum S (h o f) A"
  1214 proof (induct set: finite)
  1215   case empty then show ?case by simp
  1216 next
  1217   case insert then show ?case by (simp add: Pi_def)
  1218 qed
  1219 
  1220 context UP_pre_univ_prop
  1221 begin
  1222 
  1223 theorem eval_ring_hom:
  1224   assumes S: "s \<in> carrier S"
  1225   shows "eval R S h s \<in> ring_hom P S"
  1226 proof (rule ring_hom_memI)
  1227   fix p
  1228   assume R: "p \<in> carrier P"
  1229   then show "eval R S h s p \<in> carrier S"
  1230     by (simp only: eval_on_carrier) (simp add: S Pi_def)
  1231 next
  1232   fix p q
  1233   assume R: "p \<in> carrier P" "q \<in> carrier P"
  1234   then show "eval R S h s (p \<oplus>\<^bsub>P\<^esub> q) = eval R S h s p \<oplus>\<^bsub>S\<^esub> eval R S h s q"
  1235   proof (simp only: eval_on_carrier P.a_closed)
  1236     from S R have
  1237       "(\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1238       (\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<oplus>\<^bsub>P\<^esub> q)<..max (deg R p) (deg R q)}.
  1239         h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1240       by (simp cong: S.finsum_cong
  1241         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def del: coeff_add)
  1242     also from R have "... =
  1243         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..max (deg R p) (deg R q)}.
  1244           h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1245       by (simp add: ivl_disj_un_one)
  1246     also from R S have "... =
  1247       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1248       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1249       by (simp cong: S.finsum_cong
  1250         add: S.l_distr deg_aboveD ivl_disj_int_one Pi_def)
  1251     also have "... =
  1252         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p} \<union> {deg R p<..max (deg R p) (deg R q)}.
  1253           h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1254         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q} \<union> {deg R q<..max (deg R p) (deg R q)}.
  1255           h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1256       by (simp only: ivl_disj_un_one le_maxI1 le_maxI2)
  1257     also from R S have "... =
  1258       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1259       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1260       by (simp cong: S.finsum_cong
  1261         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1262     finally show
  1263       "(\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1264       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1265       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1266   qed
  1267 next
  1268   show "eval R S h s \<one>\<^bsub>P\<^esub> = \<one>\<^bsub>S\<^esub>"
  1269     by (simp only: eval_on_carrier UP_one_closed) simp
  1270 next
  1271   fix p q
  1272   assume R: "p \<in> carrier P" "q \<in> carrier P"
  1273   then show "eval R S h s (p \<otimes>\<^bsub>P\<^esub> q) = eval R S h s p \<otimes>\<^bsub>S\<^esub> eval R S h s q"
  1274   proof (simp only: eval_on_carrier UP_mult_closed)
  1275     from R S have
  1276       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1277       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<otimes>\<^bsub>P\<^esub> q)<..deg R p + deg R q}.
  1278         h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1279       by (simp cong: S.finsum_cong
  1280         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def
  1281         del: coeff_mult)
  1282     also from R have "... =
  1283       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1284       by (simp only: ivl_disj_un_one deg_mult_ring)
  1285     also from R S have "... =
  1286       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}.
  1287          \<Oplus>\<^bsub>S\<^esub> k \<in> {..i}.
  1288            h (coeff P p k) \<otimes>\<^bsub>S\<^esub> h (coeff P q (i - k)) \<otimes>\<^bsub>S\<^esub>
  1289            (s (^)\<^bsub>S\<^esub> k \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> (i - k)))"
  1290       by (simp cong: S.finsum_cong add: S.nat_pow_mult Pi_def
  1291         S.m_ac S.finsum_rdistr)
  1292     also from R S have "... =
  1293       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1294       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1295       by (simp add: S.cauchy_product [THEN sym] bound.intro deg_aboveD S.m_ac
  1296         Pi_def)
  1297     finally show
  1298       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1299       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1300       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1301   qed
  1302 qed
  1303 
  1304 text {*
  1305   The following lemma could be proved in @{text UP_cring} with the additional
  1306   assumption that @{text h} is closed. *}
  1307 
  1308 lemma (in UP_pre_univ_prop) eval_const:
  1309   "[| s \<in> carrier S; r \<in> carrier R |] ==> eval R S h s (monom P r 0) = h r"
  1310   by (simp only: eval_on_carrier monom_closed) simp
  1311 
  1312 text {* Further properties of the evaluation homomorphism. *}
  1313 
  1314 text {* The following proof is complicated by the fact that in arbitrary
  1315   rings one might have @{term "one R = zero R"}. *}
  1316 
  1317 (* TODO: simplify by cases "one R = zero R" *)
  1318 
  1319 lemma (in UP_pre_univ_prop) eval_monom1:
  1320   assumes S: "s \<in> carrier S"
  1321   shows "eval R S h s (monom P \<one> 1) = s"
  1322 proof (simp only: eval_on_carrier monom_closed R.one_closed)
  1323    from S have
  1324     "(\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1325     (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)} \<union> {deg R (monom P \<one> 1)<..1}.
  1326       h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1327     by (simp cong: S.finsum_cong del: coeff_monom
  1328       add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1329   also have "... =
  1330     (\<Oplus>\<^bsub>S\<^esub> i \<in> {..1}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1331     by (simp only: ivl_disj_un_one deg_monom_le R.one_closed)
  1332   also have "... = s"
  1333   proof (cases "s = \<zero>\<^bsub>S\<^esub>")
  1334     case True then show ?thesis by (simp add: Pi_def)
  1335   next
  1336     case False then show ?thesis by (simp add: S Pi_def)
  1337   qed
  1338   finally show "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (monom P \<one> 1)}.
  1339     h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) = s" .
  1340 qed
  1341 
  1342 end
  1343 
  1344 text {* Interpretation of ring homomorphism lemmas. *}
  1345 
  1346 sublocale UP_univ_prop < ring_hom_cring P S Eval
  1347   apply (unfold Eval_def)
  1348   apply intro_locales
  1349   apply (rule ring_hom_cring.axioms)
  1350   apply (rule ring_hom_cring.intro)
  1351   apply unfold_locales
  1352   apply (rule eval_ring_hom)
  1353   apply rule
  1354   done
  1355 
  1356 lemma (in UP_cring) monom_pow:
  1357   assumes R: "a \<in> carrier R"
  1358   shows "(monom P a n) (^)\<^bsub>P\<^esub> m = monom P (a (^) m) (n * m)"
  1359 proof (induct m)
  1360   case 0 from R show ?case by simp
  1361 next
  1362   case Suc with R show ?case
  1363     by (simp del: monom_mult add: monom_mult [THEN sym] add_commute)
  1364 qed
  1365 
  1366 lemma (in ring_hom_cring) hom_pow [simp]:
  1367   "x \<in> carrier R ==> h (x (^) n) = h x (^)\<^bsub>S\<^esub> (n::nat)"
  1368   by (induct n) simp_all
  1369 
  1370 lemma (in UP_univ_prop) Eval_monom:
  1371   "r \<in> carrier R ==> Eval (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1372 proof -
  1373   assume R: "r \<in> carrier R"
  1374   from R have "Eval (monom P r n) = Eval (monom P r 0 \<otimes>\<^bsub>P\<^esub> (monom P \<one> 1) (^)\<^bsub>P\<^esub> n)"
  1375     by (simp del: monom_mult add: monom_mult [THEN sym] monom_pow)
  1376   also
  1377   from R eval_monom1 [where s = s, folded Eval_def]
  1378   have "... = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1379     by (simp add: eval_const [where s = s, folded Eval_def])
  1380   finally show ?thesis .
  1381 qed
  1382 
  1383 lemma (in UP_pre_univ_prop) eval_monom:
  1384   assumes R: "r \<in> carrier R" and S: "s \<in> carrier S"
  1385   shows "eval R S h s (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1386 proof -
  1387   interpret UP_univ_prop R S h P s "eval R S h s"
  1388     using UP_pre_univ_prop_axioms P_def R S
  1389     by (auto intro: UP_univ_prop.intro UP_univ_prop_axioms.intro)
  1390   from R
  1391   show ?thesis by (rule Eval_monom)
  1392 qed
  1393 
  1394 lemma (in UP_univ_prop) Eval_smult:
  1395   "[| r \<in> carrier R; p \<in> carrier P |] ==> Eval (r \<odot>\<^bsub>P\<^esub> p) = h r \<otimes>\<^bsub>S\<^esub> Eval p"
  1396 proof -
  1397   assume R: "r \<in> carrier R" and P: "p \<in> carrier P"
  1398   then show ?thesis
  1399     by (simp add: monom_mult_is_smult [THEN sym]
  1400       eval_const [where s = s, folded Eval_def])
  1401 qed
  1402 
  1403 lemma ring_hom_cringI:
  1404   assumes "cring R"
  1405     and "cring S"
  1406     and "h \<in> ring_hom R S"
  1407   shows "ring_hom_cring R S h"
  1408   by (fast intro: ring_hom_cring.intro ring_hom_cring_axioms.intro
  1409     cring.axioms assms)
  1410 
  1411 context UP_pre_univ_prop
  1412 begin
  1413 
  1414 lemma UP_hom_unique:
  1415   assumes "ring_hom_cring P S Phi"
  1416   assumes Phi: "Phi (monom P \<one> (Suc 0)) = s"
  1417       "!!r. r \<in> carrier R ==> Phi (monom P r 0) = h r"
  1418   assumes "ring_hom_cring P S Psi"
  1419   assumes Psi: "Psi (monom P \<one> (Suc 0)) = s"
  1420       "!!r. r \<in> carrier R ==> Psi (monom P r 0) = h r"
  1421     and P: "p \<in> carrier P" and S: "s \<in> carrier S"
  1422   shows "Phi p = Psi p"
  1423 proof -
  1424   interpret ring_hom_cring P S Phi by fact
  1425   interpret ring_hom_cring P S Psi by fact
  1426   have "Phi p =
  1427       Phi (\<Oplus>\<^bsub>P \<^esub>i \<in> {..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1428     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)
  1429   also
  1430   have "... =
  1431       Psi (\<Oplus>\<^bsub>P \<^esub>i\<in>{..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1432     by (simp add: Phi Psi P Pi_def comp_def)
  1433   also have "... = Psi p"
  1434     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)
  1435   finally show ?thesis .
  1436 qed
  1437 
  1438 lemma ring_homD:
  1439   assumes Phi: "Phi \<in> ring_hom P S"
  1440   shows "ring_hom_cring P S Phi"
  1441 proof (rule ring_hom_cring.intro)
  1442   show "ring_hom_cring_axioms P S Phi"
  1443   by (rule ring_hom_cring_axioms.intro) (rule Phi)
  1444 qed unfold_locales
  1445 
  1446 theorem UP_universal_property:
  1447   assumes S: "s \<in> carrier S"
  1448   shows "EX! Phi. Phi \<in> ring_hom P S \<inter> extensional (carrier P) &
  1449     Phi (monom P \<one> 1) = s &
  1450     (ALL r : carrier R. Phi (monom P r 0) = h r)"
  1451   using S eval_monom1
  1452   apply (auto intro: eval_ring_hom eval_const eval_extensional)
  1453   apply (rule extensionalityI)
  1454   apply (auto intro: UP_hom_unique ring_homD)
  1455   done
  1456 
  1457 end
  1458 
  1459 text{*JE: The following lemma was added by me; it might be even lifted to a simpler locale*}
  1460 
  1461 context monoid
  1462 begin
  1463 
  1464 lemma nat_pow_eone[simp]: assumes x_in_G: "x \<in> carrier G" shows "x (^) (1::nat) = x"
  1465   using nat_pow_Suc [of x 0] unfolding nat_pow_0 [of x] unfolding l_one [OF x_in_G] by simp
  1466 
  1467 end
  1468 
  1469 context UP_ring
  1470 begin
  1471 
  1472 abbreviation lcoeff :: "(nat =>'a) => 'a" where "lcoeff p == coeff P p (deg R p)"
  1473 
  1474 lemma lcoeff_nonzero2: assumes p_in_R: "p \<in> carrier P" and p_not_zero: "p \<noteq> \<zero>\<^bsub>P\<^esub>" shows "lcoeff p \<noteq> \<zero>" 
  1475   using lcoeff_nonzero [OF p_not_zero p_in_R] .
  1476 
  1477 subsection{*The long division algorithm: some previous facts.*}
  1478 
  1479 lemma coeff_minus [simp]:
  1480   assumes p: "p \<in> carrier P" and q: "q \<in> carrier P" shows "coeff P (p \<ominus>\<^bsub>P\<^esub> q) n = coeff P p n \<ominus> coeff P q n" 
  1481   unfolding a_minus_def [OF p q] unfolding coeff_add [OF p a_inv_closed [OF q]] unfolding coeff_a_inv [OF q]
  1482   using coeff_closed [OF p, of n] using coeff_closed [OF q, of n] by algebra
  1483 
  1484 lemma lcoeff_closed [simp]: assumes p: "p \<in> carrier P" shows "lcoeff p \<in> carrier R"
  1485   using coeff_closed [OF p, of "deg R p"] by simp
  1486 
  1487 lemma deg_smult_decr: assumes a_in_R: "a \<in> carrier R" and f_in_P: "f \<in> carrier P" shows "deg R (a \<odot>\<^bsub>P\<^esub> f) \<le> deg R f"
  1488   using deg_smult_ring [OF a_in_R f_in_P] by (cases "a = \<zero>", auto)
  1489 
  1490 lemma coeff_monom_mult: assumes R: "c \<in> carrier R" and P: "p \<in> carrier P" 
  1491   shows "coeff P (monom P c n \<otimes>\<^bsub>P\<^esub> p) (m + n) = c \<otimes> (coeff P p m)"
  1492 proof -
  1493   have "coeff P (monom P c n \<otimes>\<^bsub>P\<^esub> p) (m + n) = (\<Oplus>i\<in>{..m + n}. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i))"
  1494     unfolding coeff_mult [OF monom_closed [OF R, of n] P, of "m + n"] unfolding coeff_monom [OF R, of n] by simp
  1495   also have "(\<Oplus>i\<in>{..m + n}. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i)) = 
  1496     (\<Oplus>i\<in>{..m + n}. (if n = i then c \<otimes> coeff P p (m + n - i) else \<zero>))"
  1497     using  R.finsum_cong [of "{..m + n}" "{..m + n}" "(\<lambda>i::nat. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i))" 
  1498       "(\<lambda>i::nat. (if n = i then c \<otimes> coeff P p (m + n - i) else \<zero>))"]
  1499     using coeff_closed [OF P] unfolding Pi_def simp_implies_def using R by auto
  1500   also have "\<dots> = c \<otimes> coeff P p m" using R.finsum_singleton [of n "{..m + n}" "(\<lambda>i. c \<otimes> coeff P p (m + n - i))"]
  1501     unfolding Pi_def using coeff_closed [OF P] using P R by auto
  1502   finally show ?thesis by simp
  1503 qed
  1504 
  1505 lemma deg_lcoeff_cancel: 
  1506   assumes p_in_P: "p \<in> carrier P" and q_in_P: "q \<in> carrier P" and r_in_P: "r \<in> carrier P" 
  1507   and deg_r_nonzero: "deg R r \<noteq> 0"
  1508   and deg_R_p: "deg R p \<le> deg R r" and deg_R_q: "deg R q \<le> deg R r" 
  1509   and coeff_R_p_eq_q: "coeff P p (deg R r) = \<ominus>\<^bsub>R\<^esub> (coeff P q (deg R r))"
  1510   shows "deg R (p \<oplus>\<^bsub>P\<^esub> q) < deg R r"
  1511 proof -
  1512   have deg_le: "deg R (p \<oplus>\<^bsub>P\<^esub> q) \<le> deg R r"
  1513   proof (rule deg_aboveI)
  1514     fix m
  1515     assume deg_r_le: "deg R r < m"
  1516     show "coeff P (p \<oplus>\<^bsub>P\<^esub> q) m = \<zero>"
  1517     proof -
  1518       have slp: "deg R p < m" and "deg R q < m" using deg_R_p deg_R_q using deg_r_le by auto
  1519       then have max_sl: "max (deg R p) (deg R q) < m" by simp
  1520       then have "deg R (p \<oplus>\<^bsub>P\<^esub> q) < m" using deg_add [OF p_in_P q_in_P] by arith
  1521       with deg_R_p deg_R_q show ?thesis using coeff_add [OF p_in_P q_in_P, of m]
  1522         using deg_aboveD [of "p \<oplus>\<^bsub>P\<^esub> q" m] using p_in_P q_in_P by simp 
  1523     qed
  1524   qed (simp add: p_in_P q_in_P)
  1525   moreover have deg_ne: "deg R (p \<oplus>\<^bsub>P\<^esub> q) \<noteq> deg R r"
  1526   proof (rule ccontr)
  1527     assume nz: "\<not> deg R (p \<oplus>\<^bsub>P\<^esub> q) \<noteq> deg R r" then have deg_eq: "deg R (p \<oplus>\<^bsub>P\<^esub> q) = deg R r" by simp
  1528     from deg_r_nonzero have r_nonzero: "r \<noteq> \<zero>\<^bsub>P\<^esub>" by (cases "r = \<zero>\<^bsub>P\<^esub>", simp_all)
  1529     have "coeff P (p \<oplus>\<^bsub>P\<^esub> q) (deg R r) = \<zero>\<^bsub>R\<^esub>" using coeff_add [OF p_in_P q_in_P, of "deg R r"] using coeff_R_p_eq_q
  1530       using coeff_closed [OF p_in_P, of "deg R r"] coeff_closed [OF q_in_P, of "deg R r"] by algebra
  1531     with lcoeff_nonzero [OF r_nonzero r_in_P]  and deg_eq show False using lcoeff_nonzero [of "p \<oplus>\<^bsub>P\<^esub> q"] using p_in_P q_in_P
  1532       using deg_r_nonzero by (cases "p \<oplus>\<^bsub>P\<^esub> q \<noteq> \<zero>\<^bsub>P\<^esub>", auto)
  1533   qed
  1534   ultimately show ?thesis by simp
  1535 qed
  1536 
  1537 lemma monom_deg_mult: 
  1538   assumes f_in_P: "f \<in> carrier P" and g_in_P: "g \<in> carrier P" and deg_le: "deg R g \<le> deg R f"
  1539   and a_in_R: "a \<in> carrier R"
  1540   shows "deg R (g \<otimes>\<^bsub>P\<^esub> monom P a (deg R f - deg R g)) \<le> deg R f"
  1541   using deg_mult_ring [OF g_in_P monom_closed [OF a_in_R, of "deg R f - deg R g"]]
  1542   apply (cases "a = \<zero>") using g_in_P apply simp 
  1543   using deg_monom [OF _ a_in_R, of "deg R f - deg R g"] using deg_le by simp
  1544 
  1545 lemma deg_zero_impl_monom:
  1546   assumes f_in_P: "f \<in> carrier P" and deg_f: "deg R f = 0" 
  1547   shows "f = monom P (coeff P f 0) 0"
  1548   apply (rule up_eqI) using coeff_monom [OF coeff_closed [OF f_in_P], of 0 0]
  1549   using f_in_P deg_f using deg_aboveD [of f _] by auto
  1550 
  1551 end
  1552 
  1553 
  1554 subsection {* The long division proof for commutative rings *}
  1555 
  1556 context UP_cring
  1557 begin
  1558 
  1559 lemma exI3: assumes exist: "Pred x y z" 
  1560   shows "\<exists> x y z. Pred x y z"
  1561   using exist by blast
  1562 
  1563 text {* Jacobson's Theorem 2.14 *}
  1564 
  1565 lemma long_div_theorem: 
  1566   assumes g_in_P [simp]: "g \<in> carrier P" and f_in_P [simp]: "f \<in> carrier P"
  1567   and g_not_zero: "g \<noteq> \<zero>\<^bsub>P\<^esub>"
  1568   shows "\<exists> q r (k::nat). (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> (lcoeff g)(^)\<^bsub>R\<^esub>k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g)"
  1569 proof -
  1570   let ?pred = "(\<lambda> q r (k::nat).
  1571     (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> (lcoeff g)(^)\<^bsub>R\<^esub>k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g))"
  1572     and ?lg = "lcoeff g"
  1573   show ?thesis
  1574     (*JE: we distinguish some particular cases where the solution is almost direct.*)
  1575   proof (cases "deg R f < deg R g")
  1576     case True     
  1577       (*JE: if the degree of f is smaller than the one of g the solution is straightforward.*)
  1578       (* CB: avoid exI3 *)
  1579       have "?pred \<zero>\<^bsub>P\<^esub> f 0" using True by force
  1580       then show ?thesis by fast
  1581   next
  1582     case False then have deg_g_le_deg_f: "deg R g \<le> deg R f" by simp
  1583     {
  1584       (*JE: we now apply the induction hypothesis with some additional facts required*)
  1585       from f_in_P deg_g_le_deg_f show ?thesis
  1586       proof (induct "deg R f" arbitrary: "f" rule: less_induct)
  1587         case less
  1588         note f_in_P [simp] = `f \<in> carrier P`
  1589           and deg_g_le_deg_f = `deg R g \<le> deg R f`
  1590         let ?k = "1::nat" and ?r = "(g \<otimes>\<^bsub>P\<^esub> (monom P (lcoeff f) (deg R f - deg R g))) \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)"
  1591           and ?q = "monom P (lcoeff f) (deg R f - deg R g)"
  1592         show "\<exists> q r (k::nat). q \<in> carrier P \<and> r \<in> carrier P \<and> lcoeff g (^) k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r & (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g)"
  1593         proof -
  1594           (*JE: we first extablish the existence of a triple satisfying the previous equation. 
  1595             Then we will have to prove the second part of the predicate.*)
  1596           have exist: "lcoeff g (^) ?k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r"
  1597             using minus_add
  1598             using sym [OF a_assoc [of "g \<otimes>\<^bsub>P\<^esub> ?q" "\<ominus>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q)" "lcoeff g \<odot>\<^bsub>P\<^esub> f"]]
  1599             using r_neg by auto
  1600           show ?thesis
  1601           proof (cases "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R g")
  1602             (*JE: if the degree of the remainder satisfies the statement property we are done*)
  1603             case True
  1604             {
  1605               show ?thesis
  1606               proof (rule exI3 [of _ ?q "\<ominus>\<^bsub>P\<^esub> ?r" ?k], intro conjI)
  1607                 show "lcoeff g (^) ?k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r" using exist by simp
  1608                 show "\<ominus>\<^bsub>P\<^esub> ?r = \<zero>\<^bsub>P\<^esub> \<or> deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R g" using True by simp
  1609               qed (simp_all)
  1610             }
  1611           next
  1612             case False note n_deg_r_l_deg_g = False
  1613             {
  1614               (*JE: otherwise, we verify the conditions of the induction hypothesis.*)
  1615               show ?thesis
  1616               proof (cases "deg R f = 0")
  1617                 (*JE: the solutions are different if the degree of f is zero or not*)
  1618                 case True
  1619                 {
  1620                   have deg_g: "deg R g = 0" using True using deg_g_le_deg_f by simp
  1621                   have "lcoeff g (^) (1::nat) \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> f \<oplus>\<^bsub>P\<^esub> \<zero>\<^bsub>P\<^esub>"
  1622                     unfolding deg_g apply simp
  1623                     unfolding sym [OF monom_mult_is_smult [OF coeff_closed [OF g_in_P, of 0] f_in_P]]
  1624                     using deg_zero_impl_monom [OF g_in_P deg_g] by simp
  1625                   then show ?thesis using f_in_P by blast
  1626                 }
  1627               next
  1628                 case False note deg_f_nzero = False
  1629                 {
  1630                   (*JE: now it only remains the case where the induction hypothesis can be used.*)
  1631                   (*JE: we first prove that the degree of the remainder is smaller than the one of f*)
  1632                   have deg_remainder_l_f: "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R f"
  1633                   proof -
  1634                     have "deg R (\<ominus>\<^bsub>P\<^esub> ?r) = deg R ?r" using deg_uminus [of ?r] by simp
  1635                     also have "\<dots> < deg R f"
  1636                     proof (rule deg_lcoeff_cancel)
  1637                       show "deg R (\<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)) \<le> deg R f"
  1638                         using deg_smult_ring [of "lcoeff g" f]
  1639                         using lcoeff_nonzero2 [OF g_in_P g_not_zero] by simp
  1640                       show "deg R (g \<otimes>\<^bsub>P\<^esub> ?q) \<le> deg R f"
  1641                         using monom_deg_mult [OF _ g_in_P, of f "lcoeff f"] and deg_g_le_deg_f
  1642                         by simp
  1643                       show "coeff P (g \<otimes>\<^bsub>P\<^esub> ?q) (deg R f) = \<ominus> coeff P (\<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)) (deg R f)"
  1644                         unfolding coeff_mult [OF g_in_P monom_closed [OF lcoeff_closed [OF f_in_P], of "deg R f - deg R g"], of "deg R f"]
  1645                         unfolding coeff_monom [OF lcoeff_closed [OF f_in_P], of "(deg R f - deg R g)"]
  1646                         using R.finsum_cong' [of "{..deg R f}" "{..deg R f}" 
  1647                           "(\<lambda>i. coeff P g i \<otimes> (if deg R f - deg R g = deg R f - i then lcoeff f else \<zero>))" 
  1648                           "(\<lambda>i. if deg R g = i then coeff P g i \<otimes> lcoeff f else \<zero>)"]
  1649                         using R.finsum_singleton [of "deg R g" "{.. deg R f}" "(\<lambda>i. coeff P g i \<otimes> lcoeff f)"]
  1650                         unfolding Pi_def using deg_g_le_deg_f by force
  1651                     qed (simp_all add: deg_f_nzero)
  1652                     finally show "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R f" .
  1653                   qed
  1654                   moreover have "\<ominus>\<^bsub>P\<^esub> ?r \<in> carrier P" by simp
  1655                   moreover obtain m where deg_rem_eq_m: "deg R (\<ominus>\<^bsub>P\<^esub> ?r) = m" by auto
  1656                   moreover have "deg R g \<le> deg R (\<ominus>\<^bsub>P\<^esub> ?r)" using n_deg_r_l_deg_g by simp
  1657                     (*JE: now, by applying the induction hypothesis, we obtain new quotient, remainder and exponent.*)
  1658                   ultimately obtain q' r' k'
  1659                     where rem_desc: "lcoeff g (^) (k'::nat) \<odot>\<^bsub>P\<^esub> (\<ominus>\<^bsub>P\<^esub> ?r) = g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r'"and rem_deg: "(r' = \<zero>\<^bsub>P\<^esub> \<or> deg R r' < deg R g)"
  1660                     and q'_in_carrier: "q' \<in> carrier P" and r'_in_carrier: "r' \<in> carrier P"
  1661                     using less by blast
  1662                       (*JE: we now prove that the new quotient, remainder and exponent can be used to get 
  1663                       the quotient, remainder and exponent of the long division theorem*)
  1664                   show ?thesis
  1665                   proof (rule exI3 [of _ "((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q')" r' "Suc k'"], intro conjI)
  1666                     show "(lcoeff g (^) (Suc k')) \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q') \<oplus>\<^bsub>P\<^esub> r'"
  1667                     proof -
  1668                       have "(lcoeff g (^) (Suc k')) \<odot>\<^bsub>P\<^esub> f = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r)" 
  1669                         using smult_assoc1 exist by simp
  1670                       also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ( \<ominus>\<^bsub>P\<^esub> ?r))"
  1671                         using UP_smult_r_distr by simp
  1672                       also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r')"
  1673                         using rem_desc by simp
  1674                       also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r'"
  1675                         using sym [OF a_assoc [of "lcoeff g (^) k' \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q)" "g \<otimes>\<^bsub>P\<^esub> q'" "r'"]]
  1676                         using q'_in_carrier r'_in_carrier by simp
  1677                       also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (?q \<otimes>\<^bsub>P\<^esub> g) \<oplus>\<^bsub>P\<^esub> q' \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"
  1678                         using q'_in_carrier by (auto simp add: m_comm)
  1679                       also have "\<dots> = (((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q) \<otimes>\<^bsub>P\<^esub> g) \<oplus>\<^bsub>P\<^esub> q' \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'" 
  1680                         using smult_assoc2 q'_in_carrier by auto
  1681                       also have "\<dots> = ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q') \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"
  1682                         using sym [OF l_distr] and q'_in_carrier by auto
  1683                       finally show ?thesis using m_comm q'_in_carrier by auto
  1684                     qed
  1685                   qed (simp_all add: rem_deg q'_in_carrier r'_in_carrier)
  1686                 }
  1687               qed
  1688             }
  1689           qed
  1690         qed
  1691       qed
  1692     }
  1693   qed
  1694 qed
  1695 
  1696 end
  1697 
  1698 
  1699 text {*The remainder theorem as corollary of the long division theorem.*}
  1700 
  1701 context UP_cring
  1702 begin
  1703 
  1704 lemma deg_minus_monom:
  1705   assumes a: "a \<in> carrier R"
  1706   and R_not_trivial: "(carrier R \<noteq> {\<zero>})"
  1707   shows "deg R (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = 1"
  1708   (is "deg R ?g = 1")
  1709 proof -
  1710   have "deg R ?g \<le> 1"
  1711   proof (rule deg_aboveI)
  1712     fix m
  1713     assume "(1::nat) < m" 
  1714     then show "coeff P ?g m = \<zero>" 
  1715       using coeff_minus using a by auto algebra
  1716   qed (simp add: a)
  1717   moreover have "deg R ?g \<ge> 1"
  1718   proof (rule deg_belowI)
  1719     show "coeff P ?g 1 \<noteq> \<zero>"
  1720       using a using R.carrier_one_not_zero R_not_trivial by simp algebra
  1721   qed (simp add: a)
  1722   ultimately show ?thesis by simp
  1723 qed
  1724 
  1725 lemma lcoeff_monom:
  1726   assumes a: "a \<in> carrier R" and R_not_trivial: "(carrier R \<noteq> {\<zero>})"
  1727   shows "lcoeff (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = \<one>"
  1728   using deg_minus_monom [OF a R_not_trivial]
  1729   using coeff_minus a by auto algebra
  1730 
  1731 lemma deg_nzero_nzero:
  1732   assumes deg_p_nzero: "deg R p \<noteq> 0"
  1733   shows "p \<noteq> \<zero>\<^bsub>P\<^esub>"
  1734   using deg_zero deg_p_nzero by auto
  1735 
  1736 lemma deg_monom_minus:
  1737   assumes a: "a \<in> carrier R"
  1738   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1739   shows "deg R (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = 1"
  1740   (is "deg R ?g = 1")
  1741 proof -
  1742   have "deg R ?g \<le> 1"
  1743   proof (rule deg_aboveI)
  1744     fix m::nat assume "1 < m" then show "coeff P ?g m = \<zero>" 
  1745       using coeff_minus [OF monom_closed [OF R.one_closed, of 1] monom_closed [OF a, of 0], of m] 
  1746       using coeff_monom [OF R.one_closed, of 1 m] using coeff_monom [OF a, of 0 m] by auto algebra
  1747   qed (simp add: a)
  1748   moreover have "1 \<le> deg R ?g"
  1749   proof (rule deg_belowI)
  1750     show "coeff P ?g 1 \<noteq> \<zero>" 
  1751       using coeff_minus [OF monom_closed [OF R.one_closed, of 1] monom_closed [OF a, of 0], of 1]
  1752       using coeff_monom [OF R.one_closed, of 1 1] using coeff_monom [OF a, of 0 1] 
  1753       using R_not_trivial using R.carrier_one_not_zero
  1754       by auto algebra
  1755   qed (simp add: a)
  1756   ultimately show ?thesis by simp
  1757 qed
  1758 
  1759 lemma eval_monom_expr:
  1760   assumes a: "a \<in> carrier R"
  1761   shows "eval R R id a (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = \<zero>"
  1762   (is "eval R R id a ?g = _")
  1763 proof -
  1764   interpret UP_pre_univ_prop R R id proof qed simp
  1765   have eval_ring_hom: "eval R R id a \<in> ring_hom P R" using eval_ring_hom [OF a] by simp
  1766   interpret ring_hom_cring P R "eval R R id a" proof qed (simp add: eval_ring_hom)
  1767   have mon1_closed: "monom P \<one>\<^bsub>R\<^esub> 1 \<in> carrier P" 
  1768     and mon0_closed: "monom P a 0 \<in> carrier P" 
  1769     and min_mon0_closed: "\<ominus>\<^bsub>P\<^esub> monom P a 0 \<in> carrier P"
  1770     using a R.a_inv_closed by auto
  1771   have "eval R R id a ?g = eval R R id a (monom P \<one> 1) \<ominus> eval R R id a (monom P a 0)"
  1772     unfolding P.minus_eq [OF mon1_closed mon0_closed]
  1773     unfolding hom_add [OF mon1_closed min_mon0_closed]
  1774     unfolding hom_a_inv [OF mon0_closed] 
  1775     using R.minus_eq [symmetric] mon1_closed mon0_closed by auto
  1776   also have "\<dots> = a \<ominus> a"
  1777     using eval_monom [OF R.one_closed a, of 1] using eval_monom [OF a a, of 0] using a by simp
  1778   also have "\<dots> = \<zero>"
  1779     using a by algebra
  1780   finally show ?thesis by simp
  1781 qed
  1782 
  1783 lemma remainder_theorem_exist:
  1784   assumes f: "f \<in> carrier P" and a: "a \<in> carrier R"
  1785   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1786   shows "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (deg R r = 0)"
  1787   (is "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (deg R r = 0)")
  1788 proof -
  1789   let ?g = "monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0"
  1790   from deg_minus_monom [OF a R_not_trivial]
  1791   have deg_g_nzero: "deg R ?g \<noteq> 0" by simp
  1792   have "\<exists>q r (k::nat). q \<in> carrier P \<and> r \<in> carrier P \<and>
  1793     lcoeff ?g (^) k \<odot>\<^bsub>P\<^esub> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> \<or> deg R r < deg R ?g)"
  1794     using long_div_theorem [OF _ f deg_nzero_nzero [OF deg_g_nzero]] a
  1795     by auto
  1796   then show ?thesis
  1797     unfolding lcoeff_monom [OF a R_not_trivial]
  1798     unfolding deg_monom_minus [OF a R_not_trivial]
  1799     using smult_one [OF f] using deg_zero by force
  1800 qed
  1801 
  1802 lemma remainder_theorem_expression:
  1803   assumes f [simp]: "f \<in> carrier P" and a [simp]: "a \<in> carrier R"
  1804   and q [simp]: "q \<in> carrier P" and r [simp]: "r \<in> carrier P"
  1805   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1806   and f_expr: "f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r"
  1807   (is "f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r" is "f = ?gq \<oplus>\<^bsub>P\<^esub> r")
  1808     and deg_r_0: "deg R r = 0"
  1809     shows "r = monom P (eval R R id a f) 0"
  1810 proof -
  1811   interpret UP_pre_univ_prop R R id P proof qed simp
  1812   have eval_ring_hom: "eval R R id a \<in> ring_hom P R"
  1813     using eval_ring_hom [OF a] by simp
  1814   have "eval R R id a f = eval R R id a ?gq \<oplus>\<^bsub>R\<^esub> eval R R id a r"
  1815     unfolding f_expr using ring_hom_add [OF eval_ring_hom] by auto
  1816   also have "\<dots> = ((eval R R id a ?g) \<otimes> (eval R R id a q)) \<oplus>\<^bsub>R\<^esub> eval R R id a r"
  1817     using ring_hom_mult [OF eval_ring_hom] by auto
  1818   also have "\<dots> = \<zero> \<oplus> eval R R id a r"
  1819     unfolding eval_monom_expr [OF a] using eval_ring_hom 
  1820     unfolding ring_hom_def using q unfolding Pi_def by simp
  1821   also have "\<dots> = eval R R id a r"
  1822     using eval_ring_hom unfolding ring_hom_def using r unfolding Pi_def by simp
  1823   finally have eval_eq: "eval R R id a f = eval R R id a r" by simp
  1824   from deg_zero_impl_monom [OF r deg_r_0]
  1825   have "r = monom P (coeff P r 0) 0" by simp
  1826   with eval_const [OF a, of "coeff P r 0"] eval_eq 
  1827   show ?thesis by auto
  1828 qed
  1829 
  1830 corollary remainder_theorem:
  1831   assumes f [simp]: "f \<in> carrier P" and a [simp]: "a \<in> carrier R"
  1832   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1833   shows "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> 
  1834      f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> monom P (eval R R id a f) 0"
  1835   (is "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> monom P (eval R R id a f) 0")
  1836 proof -
  1837   from remainder_theorem_exist [OF f a R_not_trivial]
  1838   obtain q r
  1839     where q_r: "q \<in> carrier P \<and> r \<in> carrier P \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r"
  1840     and deg_r: "deg R r = 0" by force
  1841   with remainder_theorem_expression [OF f a _ _ R_not_trivial, of q r]
  1842   show ?thesis by auto
  1843 qed
  1844 
  1845 end
  1846 
  1847 
  1848 subsection {* Sample Application of Evaluation Homomorphism *}
  1849 
  1850 lemma UP_pre_univ_propI:
  1851   assumes "cring R"
  1852     and "cring S"
  1853     and "h \<in> ring_hom R S"
  1854   shows "UP_pre_univ_prop R S h"
  1855   using assms
  1856   by (auto intro!: UP_pre_univ_prop.intro ring_hom_cring.intro
  1857     ring_hom_cring_axioms.intro UP_cring.intro)
  1858 
  1859 definition
  1860   INTEG :: "int ring"
  1861   where "INTEG = (| carrier = UNIV, mult = op *, one = 1, zero = 0, add = op + |)"
  1862 
  1863 lemma INTEG_cring: "cring INTEG"
  1864   by (unfold INTEG_def) (auto intro!: cringI abelian_groupI comm_monoidI
  1865     zadd_zminus_inverse2 zadd_zmult_distrib)
  1866 
  1867 lemma INTEG_id_eval:
  1868   "UP_pre_univ_prop INTEG INTEG id"
  1869   by (fast intro: UP_pre_univ_propI INTEG_cring id_ring_hom)
  1870 
  1871 text {*
  1872   Interpretation now enables to import all theorems and lemmas
  1873   valid in the context of homomorphisms between @{term INTEG} and @{term
  1874   "UP INTEG"} globally.
  1875 *}
  1876 
  1877 interpretation INTEG: UP_pre_univ_prop INTEG INTEG id "UP INTEG"
  1878   using INTEG_id_eval by simp_all
  1879 
  1880 lemma INTEG_closed [intro, simp]:
  1881   "z \<in> carrier INTEG"
  1882   by (unfold INTEG_def) simp
  1883 
  1884 lemma INTEG_mult [simp]:
  1885   "mult INTEG z w = z * w"
  1886   by (unfold INTEG_def) simp
  1887 
  1888 lemma INTEG_pow [simp]:
  1889   "pow INTEG z n = z ^ n"
  1890   by (induct n) (simp_all add: INTEG_def nat_pow_def)
  1891 
  1892 lemma "eval INTEG INTEG id 10 (monom (UP INTEG) 5 2) = 500"
  1893   by (simp add: INTEG.eval_monom)
  1894 
  1895 end