src/Pure/variable.ML
author wenzelm
Mon Sep 24 21:07:39 2007 +0200 (2007-09-24)
changeset 24694 54f06f7feefa
parent 22846 fb79144af9a3
child 24719 21d1cdab2d8c
permissions -rw-r--r--
added polymorphic_types;
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Proof.context -> bool
    11   val set_body: bool -> Proof.context -> Proof.context
    12   val restore_body: Proof.context -> Proof.context -> Proof.context
    13   val names_of: Proof.context -> Name.context
    14   val fixes_of: Proof.context -> (string * string) list
    15   val binds_of: Proof.context -> (typ * term) Vartab.table
    16   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    17   val is_declared: Proof.context -> string -> bool
    18   val is_fixed: Proof.context -> string -> bool
    19   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    20   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    21   val default_type: Proof.context -> string -> typ option
    22   val def_type: Proof.context -> bool -> indexname -> typ option
    23   val def_sort: Proof.context -> indexname -> sort option
    24   val declare_constraints: term -> Proof.context -> Proof.context
    25   val declare_internal: term -> Proof.context -> Proof.context
    26   val declare_term: term -> Proof.context -> Proof.context
    27   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    28   val declare_thm: thm -> Proof.context -> Proof.context
    29   val thm_context: thm -> Proof.context
    30   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    31   val add_binds: (indexname * term option) list -> Proof.context -> Proof.context
    32   val expand_binds: Proof.context -> term -> term
    33   val add_fixes: string list -> Proof.context -> string list * Proof.context
    34   val add_fixes_direct: string list -> Proof.context -> Proof.context
    35   val auto_fixes: term -> Proof.context -> Proof.context
    36   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    37   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    38   val export_terms: Proof.context -> Proof.context -> term list -> term list
    39   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    40   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    41   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    42   val export: Proof.context -> Proof.context -> thm list -> thm list
    43   val export_morphism: Proof.context -> Proof.context -> morphism
    44   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    45   val import_inst: bool -> term list -> Proof.context ->
    46     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    47   val importT_terms: term list -> Proof.context -> term list * Proof.context
    48   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    49   val importT_thms: thm list -> Proof.context -> (ctyp list * thm list) * Proof.context
    50   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    51   val import_thms: bool -> thm list -> Proof.context ->
    52     ((ctyp list * cterm list) * thm list) * Proof.context
    53   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    54   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    55   val focus: cterm -> Proof.context -> (cterm list * cterm) * Proof.context
    56   val focus_subgoal: int -> thm -> Proof.context -> (cterm list * cterm) * Proof.context
    57   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    58   val polymorphic_types: Proof.context -> term list -> (indexname * sort) list * term list
    59   val polymorphic: Proof.context -> term list -> term list
    60 end;
    61 
    62 structure Variable: VARIABLE =
    63 struct
    64 
    65 (** local context data **)
    66 
    67 datatype data = Data of
    68  {is_body: bool,                        (*inner body mode*)
    69   names: Name.context,                  (*type/term variable names*)
    70   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    71   binds: (typ * term) Vartab.table,     (*term bindings*)
    72   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    73   constraints:
    74     typ Vartab.table *                  (*type constraints*)
    75     sort Vartab.table};                 (*default sorts*)
    76 
    77 fun make_data (is_body, names, fixes, binds, type_occs, constraints) =
    78   Data {is_body = is_body, names = names, fixes = fixes, binds = binds,
    79     type_occs = type_occs, constraints = constraints};
    80 
    81 structure Data = ProofDataFun
    82 (
    83   type T = data;
    84   fun init thy =
    85     make_data (false, Name.context, [], Vartab.empty, Symtab.empty, (Vartab.empty, Vartab.empty));
    86 );
    87 
    88 fun map_data f =
    89   Data.map (fn Data {is_body, names, fixes, binds, type_occs, constraints} =>
    90     make_data (f (is_body, names, fixes, binds, type_occs, constraints)));
    91 
    92 fun map_names f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    93   (is_body, f names, fixes, binds, type_occs, constraints));
    94 
    95 fun map_fixes f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    96   (is_body, names, f fixes, binds, type_occs, constraints));
    97 
    98 fun map_binds f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    99   (is_body, names, fixes, f binds, type_occs, constraints));
   100 
   101 fun map_type_occs f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   102   (is_body, names, fixes, binds, f type_occs, constraints));
   103 
   104 fun map_constraints f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   105   (is_body, names, fixes, binds, type_occs, f constraints));
   106 
   107 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   108 
   109 val is_body = #is_body o rep_data;
   110 fun set_body b = map_data (fn (_, names, fixes, binds, type_occs, constraints) =>
   111   (b, names, fixes, binds, type_occs, constraints));
   112 fun restore_body ctxt = set_body (is_body ctxt);
   113 
   114 val names_of = #names o rep_data;
   115 val fixes_of = #fixes o rep_data;
   116 val binds_of = #binds o rep_data;
   117 val type_occs_of = #type_occs o rep_data;
   118 val constraints_of = #constraints o rep_data;
   119 
   120 val is_declared = Name.is_declared o names_of;
   121 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   122 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   123 
   124 fun add_fixed ctxt = Term.fold_aterms
   125   (fn Free (x, T) => if is_fixed ctxt x then insert (op =) (x, T) else I | _ => I);
   126 
   127 
   128 
   129 (** declarations **)
   130 
   131 (* default sorts and types *)
   132 
   133 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   134 
   135 fun def_type ctxt pattern xi =
   136   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   137     (case Vartab.lookup types xi of
   138       NONE =>
   139         if pattern then NONE
   140         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   141     | some => some)
   142   end;
   143 
   144 val def_sort = Vartab.lookup o #2 o constraints_of;
   145 
   146 
   147 (* names *)
   148 
   149 val declare_type_names = map_names o
   150   fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I));
   151 
   152 fun declare_names t =
   153   declare_type_names t #>
   154   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t);
   155 
   156 
   157 (* type occurrences *)
   158 
   159 val decl_type_occs = fold_term_types
   160   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   161     | _ => fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I));
   162 
   163 val declare_type_occs = map_type_occs o decl_type_occs;
   164 
   165 
   166 (* constraints *)
   167 
   168 fun constrain_tvar (xi, S) =
   169   if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S);
   170 
   171 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   172   let
   173     val types' = fold_aterms
   174       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   175         | Var v => Vartab.update v
   176         | _ => I) t types;
   177     val sorts' = fold_types (fold_atyps
   178       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   179         | TVar v => constrain_tvar v
   180         | _ => I)) t sorts;
   181   in (types', sorts') end)
   182   #> declare_type_names t;
   183 
   184 
   185 (* common declarations *)
   186 
   187 fun declare_internal t =
   188   declare_names t #>
   189   declare_type_occs t;
   190 
   191 fun declare_term t =
   192   declare_internal t #>
   193   declare_constraints t;
   194 
   195 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   196 
   197 val declare_thm = Thm.fold_terms declare_internal;
   198 fun thm_context th = declare_thm th (ProofContext.init (Thm.theory_of_thm th));
   199 
   200 
   201 (* renaming term/type frees *)
   202 
   203 fun variant_frees ctxt ts frees =
   204   let
   205     val names = names_of (fold declare_names ts ctxt);
   206     val xs = fst (Name.variants (map #1 frees) names);
   207   in xs ~~ map snd frees end;
   208 
   209 
   210 
   211 (** term bindings **)
   212 
   213 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   214   | add_bind ((x, i), SOME t) =
   215       let
   216         val T = Term.fastype_of t;
   217         val t' =
   218           if null (Term.hidden_polymorphism t T) then t
   219           else Var ((x ^ "_has_extra_type_vars_on_rhs", i), T);
   220       in declare_term t' #> map_binds (Vartab.update ((x, i), (T, t'))) end;
   221 
   222 val add_binds = fold add_bind;
   223 
   224 fun expand_binds ctxt =
   225   let
   226     val binds = binds_of ctxt;
   227     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   228   in Envir.beta_norm o Envir.expand_term get end;
   229 
   230 
   231 
   232 (** fixes **)
   233 
   234 local
   235 
   236 fun no_dups [] = ()
   237   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   238 
   239 fun new_fixes names' xs xs' =
   240   map_names (K names') #>
   241   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   242   fold (declare_constraints o Syntax.free) xs' #>
   243   pair xs';
   244 
   245 in
   246 
   247 fun add_fixes xs ctxt =
   248   let
   249     val _ =
   250       (case filter (can Name.dest_skolem) xs of [] => ()
   251       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   252     val _ = no_dups (duplicates (op =) xs);
   253     val (ys, zs) = split_list (fixes_of ctxt);
   254     val names = names_of ctxt;
   255     val (xs', names') =
   256       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   257       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   258         (xs, fold Name.declare xs names));
   259   in ctxt |> new_fixes names' xs xs' end;
   260 
   261 fun variant_fixes raw_xs ctxt =
   262   let
   263     val names = names_of ctxt;
   264     val xs = map Name.clean raw_xs;
   265     val (xs', names') = Name.variants xs names |>> map Name.skolem;
   266   in ctxt |> new_fixes names' xs xs' end;
   267 
   268 end;
   269 
   270 
   271 fun add_fixes_direct xs ctxt = ctxt
   272   |> set_body false
   273   |> (snd o add_fixes xs)
   274   |> restore_body ctxt;
   275 
   276 fun fix_frees t ctxt = ctxt
   277   |> add_fixes_direct
   278       (rev (fold_aterms (fn Free (x, _) =>
   279         if is_fixed ctxt x then I else insert (op =) x | _ => I) t []));
   280 
   281 fun auto_fixes t ctxt =
   282   (if is_body ctxt then ctxt else fix_frees t ctxt)
   283   |> declare_term t;
   284 
   285 fun invent_types Ss ctxt =
   286   let
   287     val tfrees = Name.invents (names_of ctxt) "'a" (length Ss) ~~ Ss;
   288     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   289   in (tfrees, ctxt') end;
   290 
   291 
   292 
   293 (** export -- generalize type/term variables (beware of closure sizes) **)
   294 
   295 fun export_inst inner outer =
   296   let
   297     val declared_outer = is_declared outer;
   298     val fixes_inner = fixes_of inner;
   299     val fixes_outer = fixes_of outer;
   300 
   301     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   302     val still_fixed = not o member (op =) gen_fixes;
   303 
   304     val type_occs_inner = type_occs_of inner;
   305     fun gen_fixesT ts =
   306       Symtab.fold (fn (a, xs) =>
   307         if declared_outer a orelse exists still_fixed xs
   308         then I else cons a) (fold decl_type_occs ts type_occs_inner) [];
   309   in (gen_fixesT, gen_fixes) end;
   310 
   311 fun exportT_inst inner outer = #1 (export_inst inner outer);
   312 
   313 fun exportT_terms inner outer =
   314   let val mk_tfrees = exportT_inst inner outer in
   315     fn ts => ts |> map
   316       (TermSubst.generalize (mk_tfrees ts, [])
   317         (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1))
   318   end;
   319 
   320 fun export_terms inner outer =
   321   let val (mk_tfrees, tfrees) = export_inst inner outer in
   322     fn ts => ts |> map
   323       (TermSubst.generalize (mk_tfrees ts, tfrees)
   324         (fold Term.maxidx_term ts ~1 + 1))
   325   end;
   326 
   327 fun export_prf inner outer prf =
   328   let
   329     val (mk_tfrees, frees) = export_inst (declare_prf prf inner) outer;
   330     val tfrees = mk_tfrees [];
   331     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   332     val gen_term = TermSubst.generalize_option (tfrees, frees) idx;
   333     val gen_typ = TermSubst.generalizeT_option tfrees idx;
   334   in Proofterm.map_proof_terms_option gen_term gen_typ prf end;
   335 
   336 
   337 fun gen_export (mk_tfrees, frees) ths =
   338   let
   339     val tfrees = mk_tfrees (map Thm.full_prop_of ths);
   340     val maxidx = fold Thm.maxidx_thm ths ~1;
   341   in map (Thm.generalize (tfrees, frees) (maxidx + 1)) ths end;
   342 
   343 fun exportT inner outer = gen_export (exportT_inst inner outer, []);
   344 fun export inner outer = gen_export (export_inst inner outer);
   345 
   346 fun export_morphism inner outer =
   347   let
   348     val fact = export inner outer;
   349     val term = singleton (export_terms inner outer);
   350     val typ = Logic.type_map term;
   351   in Morphism.morphism {name = I, var = I, typ = typ, term = term, fact = fact} end;
   352 
   353 
   354 (** import -- fix schematic type/term variables **)
   355 
   356 fun importT_inst ts ctxt =
   357   let
   358     val tvars = rev (fold Term.add_tvars ts []);
   359     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   360   in (tvars ~~ map TFree tfrees, ctxt') end;
   361 
   362 fun import_inst is_open ts ctxt =
   363   let
   364     val ren = if is_open then I else Name.internal;
   365     val (instT, ctxt') = importT_inst ts ctxt;
   366     val vars = map (apsnd (TermSubst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   367     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   368     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   369   in ((instT, inst), ctxt'') end;
   370 
   371 fun importT_terms ts ctxt =
   372   let val (instT, ctxt') = importT_inst ts ctxt
   373   in (map (TermSubst.instantiate (instT, [])) ts, ctxt') end;
   374 
   375 fun import_terms is_open ts ctxt =
   376   let val (inst, ctxt') = import_inst is_open ts ctxt
   377   in (map (TermSubst.instantiate inst) ts, ctxt') end;
   378 
   379 fun importT_thms ths ctxt =
   380   let
   381     val thy = ProofContext.theory_of ctxt;
   382     val certT = Thm.ctyp_of thy;
   383     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   384     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   385     val ths' = map (Thm.instantiate (instT', [])) ths;
   386   in ((map #2 instT', ths'), ctxt') end;
   387 
   388 fun import_prf is_open prf ctxt =
   389   let
   390     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   391     val (insts, ctxt') = import_inst is_open ts ctxt;
   392   in (Proofterm.instantiate insts prf, ctxt') end;
   393 
   394 fun import_thms is_open ths ctxt =
   395   let
   396     val thy = ProofContext.theory_of ctxt;
   397     val cert = Thm.cterm_of thy;
   398     val certT = Thm.ctyp_of thy;
   399     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   400     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   401     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   402     val ths' = map (Thm.instantiate (instT', inst')) ths;
   403   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   404 
   405 
   406 (* import/export *)
   407 
   408 fun gen_trade imp exp f ctxt ths =
   409   let val ((_, ths'), ctxt') = imp ths ctxt
   410   in exp ctxt' ctxt (f ctxt' ths') end;
   411 
   412 val tradeT = gen_trade importT_thms exportT;
   413 val trade = gen_trade (import_thms true) export;
   414 
   415 
   416 (* focus on outermost parameters *)
   417 
   418 fun forall_elim_prop t prop =
   419   Thm.beta_conversion false (Thm.capply (Thm.dest_arg prop) t)
   420   |> Thm.cprop_of |> Thm.dest_arg;
   421 
   422 fun focus goal ctxt =
   423   let
   424     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   425     val t = Thm.term_of goal;
   426     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   427     val (xs, Ts) = split_list ps;
   428     val (xs', ctxt') = variant_fixes xs ctxt;
   429     val ps' = ListPair.map (cert o Free) (xs', Ts);
   430     val goal' = fold forall_elim_prop ps' goal;
   431   in ((ps', goal'), ctxt') end;
   432 
   433 fun focus_subgoal i st =
   434   let
   435     val all_vars = Thm.fold_terms Term.add_vars st [];
   436     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   437   in
   438     add_binds no_binds #>
   439     fold (declare_constraints o Var) all_vars #>
   440     focus (Thm.cprem_of st i)
   441   end;
   442 
   443 
   444 
   445 (** implicit polymorphism **)
   446 
   447 (* warn_extra_tfrees *)
   448 
   449 fun warn_extra_tfrees ctxt1 ctxt2 =
   450   let
   451     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   452     fun occs_free a x =
   453       (case def_type ctxt1 false (x, ~1) of
   454         SOME T => if occs_typ a T then I else cons (a, x)
   455       | NONE => cons (a, x));
   456 
   457     val occs1 = type_occs_of ctxt1;
   458     val occs2 = type_occs_of ctxt2;
   459     val extras = Symtab.fold (fn (a, xs) =>
   460       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   461     val tfrees = map #1 extras |> sort_distinct string_ord;
   462     val frees = map #2 extras |> sort_distinct string_ord;
   463   in
   464     if null extras then ()
   465     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   466       space_implode " or " (map quote frees))
   467   end;
   468 
   469 
   470 (* polymorphic terms *)
   471 
   472 fun polymorphic_types ctxt ts =
   473   let
   474     val ctxt' = fold declare_term ts ctxt;
   475     val occs = type_occs_of ctxt;
   476     val occs' = type_occs_of ctxt';
   477     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   478     val idx = fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1;
   479     val Ts' = (fold o fold_types o fold_atyps)
   480       (fn T as TFree _ =>
   481           (case TermSubst.generalizeT types idx T of TVar v => insert (op =) v | _ => I)
   482         | _ => I) ts [];
   483     val ts' = map (TermSubst.generalize (types, []) idx) ts;
   484   in (rev Ts', ts') end;
   485 
   486 fun polymorphic ctxt ts = snd (polymorphic_types ctxt ts);
   487 
   488 end;