src/HOL/Set.thy
author oheimb
Fri Jul 11 14:11:56 2003 +0200 (2003-07-11)
changeset 14098 54f130df1136
parent 13865 0a6bf71955b0
child 14208 144f45277d5a
permissions -rw-r--r--
added rev_ballE
     1 (*  Title:      HOL/Set.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 *)
     6 
     7 header {* Set theory for higher-order logic *}
     8 
     9 theory Set = HOL:
    10 
    11 text {* A set in HOL is simply a predicate. *}
    12 
    13 
    14 subsection {* Basic syntax *}
    15 
    16 global
    17 
    18 typedecl 'a set
    19 arities set :: (type) type
    20 
    21 consts
    22   "{}"          :: "'a set"                             ("{}")
    23   UNIV          :: "'a set"
    24   insert        :: "'a => 'a set => 'a set"
    25   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    26   Int           :: "'a set => 'a set => 'a set"          (infixl 70)
    27   Un            :: "'a set => 'a set => 'a set"          (infixl 65)
    28   UNION         :: "'a set => ('a => 'b set) => 'b set"  -- "general union"
    29   INTER         :: "'a set => ('a => 'b set) => 'b set"  -- "general intersection"
    30   Union         :: "'a set set => 'a set"                -- "union of a set"
    31   Inter         :: "'a set set => 'a set"                -- "intersection of a set"
    32   Pow           :: "'a set => 'a set set"                -- "powerset"
    33   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    34   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    35   image         :: "('a => 'b) => 'a set => 'b set"      (infixr "`" 90)
    36 
    37 syntax
    38   "op :"        :: "'a => 'a set => bool"                ("op :")
    39 consts
    40   "op :"        :: "'a => 'a set => bool"                ("(_/ : _)" [50, 51] 50)  -- "membership"
    41 
    42 local
    43 
    44 instance set :: (type) ord ..
    45 instance set :: (type) minus ..
    46 
    47 
    48 subsection {* Additional concrete syntax *}
    49 
    50 syntax
    51   range         :: "('a => 'b) => 'b set"             -- "of function"
    52 
    53   "op ~:"       :: "'a => 'a set => bool"                 ("op ~:")  -- "non-membership"
    54   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ ~: _)" [50, 51] 50)
    55 
    56   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    57   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    58   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
    59 
    60   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" 10)
    61   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" 10)
    62   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" 10)
    63   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" 10)
    64 
    65   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    66   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    67 
    68 syntax (HOL)
    69   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    70   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    71 
    72 translations
    73   "range f"     == "f`UNIV"
    74   "x ~: y"      == "~ (x : y)"
    75   "{x, xs}"     == "insert x {xs}"
    76   "{x}"         == "insert x {}"
    77   "{x. P}"      == "Collect (%x. P)"
    78   "UN x y. B"   == "UN x. UN y. B"
    79   "UN x. B"     == "UNION UNIV (%x. B)"
    80   "UN x. B"     == "UN x:UNIV. B"
    81   "INT x y. B"  == "INT x. INT y. B"
    82   "INT x. B"    == "INTER UNIV (%x. B)"
    83   "INT x. B"    == "INT x:UNIV. B"
    84   "UN x:A. B"   == "UNION A (%x. B)"
    85   "INT x:A. B"  == "INTER A (%x. B)"
    86   "ALL x:A. P"  == "Ball A (%x. P)"
    87   "EX x:A. P"   == "Bex A (%x. P)"
    88 
    89 syntax (output)
    90   "_setle"      :: "'a set => 'a set => bool"             ("op <=")
    91   "_setle"      :: "'a set => 'a set => bool"             ("(_/ <= _)" [50, 51] 50)
    92   "_setless"    :: "'a set => 'a set => bool"             ("op <")
    93   "_setless"    :: "'a set => 'a set => bool"             ("(_/ < _)" [50, 51] 50)
    94 
    95 syntax (xsymbols)
    96   "_setle"      :: "'a set => 'a set => bool"             ("op \<subseteq>")
    97   "_setle"      :: "'a set => 'a set => bool"             ("(_/ \<subseteq> _)" [50, 51] 50)
    98   "_setless"    :: "'a set => 'a set => bool"             ("op \<subset>")
    99   "_setless"    :: "'a set => 'a set => bool"             ("(_/ \<subset> _)" [50, 51] 50)
   100   "op Int"      :: "'a set => 'a set => 'a set"           (infixl "\<inter>" 70)
   101   "op Un"       :: "'a set => 'a set => 'a set"           (infixl "\<union>" 65)
   102   "op :"        :: "'a => 'a set => bool"                 ("op \<in>")
   103   "op :"        :: "'a => 'a set => bool"                 ("(_/ \<in> _)" [50, 51] 50)
   104   "op ~:"       :: "'a => 'a set => bool"                 ("op \<notin>")
   105   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ \<notin> _)" [50, 51] 50)
   106   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" 10)
   107   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" 10)
   108   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" 10)
   109   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" 10)
   110   Union         :: "'a set set => 'a set"                 ("\<Union>_" [90] 90)
   111   Inter         :: "'a set set => 'a set"                 ("\<Inter>_" [90] 90)
   112   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   113   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   114 
   115 translations
   116   "op \<subseteq>" => "op <= :: _ set => _ set => bool"
   117   "op \<subset>" => "op <  :: _ set => _ set => bool"
   118 
   119 
   120 typed_print_translation {*
   121   let
   122     fun le_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   123           list_comb (Syntax.const "_setle", ts)
   124       | le_tr' _ _ _ = raise Match;
   125 
   126     fun less_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   127           list_comb (Syntax.const "_setless", ts)
   128       | less_tr' _ _ _ = raise Match;
   129   in [("op <=", le_tr'), ("op <", less_tr')] end
   130 *}
   131 
   132 text {*
   133   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   134   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   135   only translated if @{text "[0..n] subset bvs(e)"}.
   136 *}
   137 
   138 parse_translation {*
   139   let
   140     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   141 
   142     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   143       | nvars _ = 1;
   144 
   145     fun setcompr_tr [e, idts, b] =
   146       let
   147         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   148         val P = Syntax.const "op &" $ eq $ b;
   149         val exP = ex_tr [idts, P];
   150       in Syntax.const "Collect" $ Abs ("", dummyT, exP) end;
   151 
   152   in [("@SetCompr", setcompr_tr)] end;
   153 *}
   154 
   155 (* To avoid eta-contraction of body: *)
   156 print_translation {*
   157 let
   158   fun btr' syn [A,Abs abs] =
   159     let val (x,t) = atomic_abs_tr' abs
   160     in Syntax.const syn $ x $ A $ t end
   161 in
   162 [("Ball", btr' "_Ball"),("Bex", btr' "_Bex"),
   163  ("UNION", btr' "@UNION"),("INTER", btr' "@INTER")]
   164 end
   165 *}
   166 
   167 print_translation {*
   168 let
   169   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   170 
   171   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   172     let
   173       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   174         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   175             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   176             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   177         | check _ = false
   178 
   179         fun tr' (_ $ abs) =
   180           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   181           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   182     in if check (P, 0) then tr' P
   183        else let val (x,t) = atomic_abs_tr' abs
   184             in Syntax.const "@Coll" $ x $ t end
   185     end;
   186   in [("Collect", setcompr_tr')] end;
   187 *}
   188 
   189 
   190 subsection {* Rules and definitions *}
   191 
   192 text {* Isomorphisms between predicates and sets. *}
   193 
   194 axioms
   195   mem_Collect_eq [iff]: "(a : {x. P(x)}) = P(a)"
   196   Collect_mem_eq [simp]: "{x. x:A} = A"
   197 
   198 defs
   199   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   200   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   201 
   202 defs (overloaded)
   203   subset_def:   "A <= B         == ALL x:A. x:B"
   204   psubset_def:  "A < B          == (A::'a set) <= B & ~ A=B"
   205   Compl_def:    "- A            == {x. ~x:A}"
   206   set_diff_def: "A - B          == {x. x:A & ~x:B}"
   207 
   208 defs
   209   Un_def:       "A Un B         == {x. x:A | x:B}"
   210   Int_def:      "A Int B        == {x. x:A & x:B}"
   211   INTER_def:    "INTER A B      == {y. ALL x:A. y: B(x)}"
   212   UNION_def:    "UNION A B      == {y. EX x:A. y: B(x)}"
   213   Inter_def:    "Inter S        == (INT x:S. x)"
   214   Union_def:    "Union S        == (UN x:S. x)"
   215   Pow_def:      "Pow A          == {B. B <= A}"
   216   empty_def:    "{}             == {x. False}"
   217   UNIV_def:     "UNIV           == {x. True}"
   218   insert_def:   "insert a B     == {x. x=a} Un B"
   219   image_def:    "f`A            == {y. EX x:A. y = f(x)}"
   220 
   221 
   222 subsection {* Lemmas and proof tool setup *}
   223 
   224 subsubsection {* Relating predicates and sets *}
   225 
   226 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   227   by simp
   228 
   229 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   230   by simp
   231 
   232 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   233   by simp
   234 
   235 lemmas CollectE = CollectD [elim_format]
   236 
   237 
   238 subsubsection {* Bounded quantifiers *}
   239 
   240 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   241   by (simp add: Ball_def)
   242 
   243 lemmas strip = impI allI ballI
   244 
   245 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   246   by (simp add: Ball_def)
   247 
   248 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   249   by (unfold Ball_def) blast
   250 ML {* bind_thm("rev_ballE",permute_prems 1 1 (thm "ballE")) *}
   251 
   252 text {*
   253   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   254   @{prop "a:A"}; creates assumption @{prop "P a"}.
   255 *}
   256 
   257 ML {*
   258   local val ballE = thm "ballE"
   259   in fun ball_tac i = etac ballE i THEN contr_tac (i + 1) end;
   260 *}
   261 
   262 text {*
   263   Gives better instantiation for bound:
   264 *}
   265 
   266 ML_setup {*
   267   claset_ref() := claset() addbefore ("bspec", datac (thm "bspec") 1);
   268 *}
   269 
   270 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   271   -- {* Normally the best argument order: @{prop "P x"} constrains the
   272     choice of @{prop "x:A"}. *}
   273   by (unfold Bex_def) blast
   274 
   275 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   276   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   277   by (unfold Bex_def) blast
   278 
   279 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   280   by (unfold Bex_def) blast
   281 
   282 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   283   by (unfold Bex_def) blast
   284 
   285 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   286   -- {* Trival rewrite rule. *}
   287   by (simp add: Ball_def)
   288 
   289 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   290   -- {* Dual form for existentials. *}
   291   by (simp add: Bex_def)
   292 
   293 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   294   by blast
   295 
   296 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   297   by blast
   298 
   299 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   300   by blast
   301 
   302 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   303   by blast
   304 
   305 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   306   by blast
   307 
   308 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   309   by blast
   310 
   311 ML_setup {*
   312   local
   313     val Ball_def = thm "Ball_def";
   314     val Bex_def = thm "Bex_def";
   315 
   316     val prove_bex_tac =
   317       rewrite_goals_tac [Bex_def] THEN Quantifier1.prove_one_point_ex_tac;
   318     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   319 
   320     val prove_ball_tac =
   321       rewrite_goals_tac [Ball_def] THEN Quantifier1.prove_one_point_all_tac;
   322     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   323   in
   324     val defBEX_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   325       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   326     val defBALL_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   327       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   328   end;
   329 
   330   Addsimprocs [defBALL_regroup, defBEX_regroup];
   331 *}
   332 
   333 
   334 subsubsection {* Congruence rules *}
   335 
   336 lemma ball_cong [cong]:
   337   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   338     (ALL x:A. P x) = (ALL x:B. Q x)"
   339   by (simp add: Ball_def)
   340 
   341 lemma bex_cong [cong]:
   342   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   343     (EX x:A. P x) = (EX x:B. Q x)"
   344   by (simp add: Bex_def cong: conj_cong)
   345 
   346 
   347 subsubsection {* Subsets *}
   348 
   349 lemma subsetI [intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   350   by (simp add: subset_def)
   351 
   352 text {*
   353   \medskip Map the type @{text "'a set => anything"} to just @{typ
   354   'a}; for overloading constants whose first argument has type @{typ
   355   "'a set"}.
   356 *}
   357 
   358 lemma subsetD [elim]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   359   -- {* Rule in Modus Ponens style. *}
   360   by (unfold subset_def) blast
   361 
   362 declare subsetD [intro?] -- FIXME
   363 
   364 lemma rev_subsetD: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   365   -- {* The same, with reversed premises for use with @{text erule} --
   366       cf @{text rev_mp}. *}
   367   by (rule subsetD)
   368 
   369 declare rev_subsetD [intro?] -- FIXME
   370 
   371 text {*
   372   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   373 *}
   374 
   375 ML {*
   376   local val rev_subsetD = thm "rev_subsetD"
   377   in fun impOfSubs th = th RSN (2, rev_subsetD) end;
   378 *}
   379 
   380 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   381   -- {* Classical elimination rule. *}
   382   by (unfold subset_def) blast
   383 
   384 text {*
   385   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   386   creates the assumption @{prop "c \<in> B"}.
   387 *}
   388 
   389 ML {*
   390   local val subsetCE = thm "subsetCE"
   391   in fun set_mp_tac i = etac subsetCE i THEN mp_tac i end;
   392 *}
   393 
   394 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   395   by blast
   396 
   397 lemma subset_refl: "A \<subseteq> A"
   398   by fast
   399 
   400 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   401   by blast
   402 
   403 
   404 subsubsection {* Equality *}
   405 
   406 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   407   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   408    apply (rule Collect_mem_eq)
   409   apply (rule Collect_mem_eq)
   410   done
   411 
   412 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   413   -- {* Anti-symmetry of the subset relation. *}
   414   by (rules intro: set_ext subsetD)
   415 
   416 lemmas equalityI [intro!] = subset_antisym
   417 
   418 text {*
   419   \medskip Equality rules from ZF set theory -- are they appropriate
   420   here?
   421 *}
   422 
   423 lemma equalityD1: "A = B ==> A \<subseteq> B"
   424   by (simp add: subset_refl)
   425 
   426 lemma equalityD2: "A = B ==> B \<subseteq> A"
   427   by (simp add: subset_refl)
   428 
   429 text {*
   430   \medskip Be careful when adding this to the claset as @{text
   431   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   432   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   433 *}
   434 
   435 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   436   by (simp add: subset_refl)
   437 
   438 lemma equalityCE [elim]:
   439     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   440   by blast
   441 
   442 text {*
   443   \medskip Lemma for creating induction formulae -- for "pattern
   444   matching" on @{text p}.  To make the induction hypotheses usable,
   445   apply @{text spec} or @{text bspec} to put universal quantifiers over the free
   446   variables in @{text p}.
   447 *}
   448 
   449 lemma setup_induction: "p:A ==> (!!z. z:A ==> p = z --> R) ==> R"
   450   by simp
   451 
   452 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   453   by simp
   454 
   455 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   456   by simp
   457 
   458 
   459 subsubsection {* The universal set -- UNIV *}
   460 
   461 lemma UNIV_I [simp]: "x : UNIV"
   462   by (simp add: UNIV_def)
   463 
   464 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   465 
   466 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   467   by simp
   468 
   469 lemma subset_UNIV: "A \<subseteq> UNIV"
   470   by (rule subsetI) (rule UNIV_I)
   471 
   472 text {*
   473   \medskip Eta-contracting these two rules (to remove @{text P})
   474   causes them to be ignored because of their interaction with
   475   congruence rules.
   476 *}
   477 
   478 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   479   by (simp add: Ball_def)
   480 
   481 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   482   by (simp add: Bex_def)
   483 
   484 
   485 subsubsection {* The empty set *}
   486 
   487 lemma empty_iff [simp]: "(c : {}) = False"
   488   by (simp add: empty_def)
   489 
   490 lemma emptyE [elim!]: "a : {} ==> P"
   491   by simp
   492 
   493 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   494     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   495   by blast
   496 
   497 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   498   by blast
   499 
   500 lemma equals0D: "A = {} ==> a \<notin> A"
   501     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   502   by blast
   503 
   504 lemma ball_empty [simp]: "Ball {} P = True"
   505   by (simp add: Ball_def)
   506 
   507 lemma bex_empty [simp]: "Bex {} P = False"
   508   by (simp add: Bex_def)
   509 
   510 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   511   by (blast elim: equalityE)
   512 
   513 
   514 subsubsection {* The Powerset operator -- Pow *}
   515 
   516 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   517   by (simp add: Pow_def)
   518 
   519 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   520   by (simp add: Pow_def)
   521 
   522 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   523   by (simp add: Pow_def)
   524 
   525 lemma Pow_bottom: "{} \<in> Pow B"
   526   by simp
   527 
   528 lemma Pow_top: "A \<in> Pow A"
   529   by (simp add: subset_refl)
   530 
   531 
   532 subsubsection {* Set complement *}
   533 
   534 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   535   by (unfold Compl_def) blast
   536 
   537 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   538   by (unfold Compl_def) blast
   539 
   540 text {*
   541   \medskip This form, with negated conclusion, works well with the
   542   Classical prover.  Negated assumptions behave like formulae on the
   543   right side of the notional turnstile ... *}
   544 
   545 lemma ComplD: "c : -A ==> c~:A"
   546   by (unfold Compl_def) blast
   547 
   548 lemmas ComplE [elim!] = ComplD [elim_format]
   549 
   550 
   551 subsubsection {* Binary union -- Un *}
   552 
   553 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   554   by (unfold Un_def) blast
   555 
   556 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   557   by simp
   558 
   559 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   560   by simp
   561 
   562 text {*
   563   \medskip Classical introduction rule: no commitment to @{prop A} vs
   564   @{prop B}.
   565 *}
   566 
   567 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   568   by auto
   569 
   570 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   571   by (unfold Un_def) blast
   572 
   573 
   574 subsubsection {* Binary intersection -- Int *}
   575 
   576 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   577   by (unfold Int_def) blast
   578 
   579 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   580   by simp
   581 
   582 lemma IntD1: "c : A Int B ==> c:A"
   583   by simp
   584 
   585 lemma IntD2: "c : A Int B ==> c:B"
   586   by simp
   587 
   588 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   589   by simp
   590 
   591 
   592 subsubsection {* Set difference *}
   593 
   594 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   595   by (unfold set_diff_def) blast
   596 
   597 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   598   by simp
   599 
   600 lemma DiffD1: "c : A - B ==> c : A"
   601   by simp
   602 
   603 lemma DiffD2: "c : A - B ==> c : B ==> P"
   604   by simp
   605 
   606 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   607   by simp
   608 
   609 
   610 subsubsection {* Augmenting a set -- insert *}
   611 
   612 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   613   by (unfold insert_def) blast
   614 
   615 lemma insertI1: "a : insert a B"
   616   by simp
   617 
   618 lemma insertI2: "a : B ==> a : insert b B"
   619   by simp
   620 
   621 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   622   by (unfold insert_def) blast
   623 
   624 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   625   -- {* Classical introduction rule. *}
   626   by auto
   627 
   628 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   629   by auto
   630 
   631 
   632 subsubsection {* Singletons, using insert *}
   633 
   634 lemma singletonI [intro!]: "a : {a}"
   635     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   636   by (rule insertI1)
   637 
   638 lemma singletonD: "b : {a} ==> b = a"
   639   by blast
   640 
   641 lemmas singletonE [elim!] = singletonD [elim_format]
   642 
   643 lemma singleton_iff: "(b : {a}) = (b = a)"
   644   by blast
   645 
   646 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   647   by blast
   648 
   649 lemma singleton_insert_inj_eq [iff]: "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   650   by blast
   651 
   652 lemma singleton_insert_inj_eq' [iff]: "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   653   by blast
   654 
   655 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   656   by fast
   657 
   658 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   659   by blast
   660 
   661 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   662   by blast
   663 
   664 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   665   by blast
   666 
   667 
   668 subsubsection {* Unions of families *}
   669 
   670 text {*
   671   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   672 *}
   673 
   674 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   675   by (unfold UNION_def) blast
   676 
   677 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   678   -- {* The order of the premises presupposes that @{term A} is rigid;
   679     @{term b} may be flexible. *}
   680   by auto
   681 
   682 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   683   by (unfold UNION_def) blast
   684 
   685 lemma UN_cong [cong]:
   686     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   687   by (simp add: UNION_def)
   688 
   689 
   690 subsubsection {* Intersections of families *}
   691 
   692 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   693 
   694 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   695   by (unfold INTER_def) blast
   696 
   697 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   698   by (unfold INTER_def) blast
   699 
   700 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   701   by auto
   702 
   703 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   704   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   705   by (unfold INTER_def) blast
   706 
   707 lemma INT_cong [cong]:
   708     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   709   by (simp add: INTER_def)
   710 
   711 
   712 subsubsection {* Union *}
   713 
   714 lemma Union_iff [simp]: "(A : Union C) = (EX X:C. A:X)"
   715   by (unfold Union_def) blast
   716 
   717 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   718   -- {* The order of the premises presupposes that @{term C} is rigid;
   719     @{term A} may be flexible. *}
   720   by auto
   721 
   722 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   723   by (unfold Union_def) blast
   724 
   725 
   726 subsubsection {* Inter *}
   727 
   728 lemma Inter_iff [simp]: "(A : Inter C) = (ALL X:C. A:X)"
   729   by (unfold Inter_def) blast
   730 
   731 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   732   by (simp add: Inter_def)
   733 
   734 text {*
   735   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   736   contains @{term A} as an element, but @{prop "A:X"} can hold when
   737   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   738 *}
   739 
   740 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   741   by auto
   742 
   743 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   744   -- {* ``Classical'' elimination rule -- does not require proving
   745     @{prop "X:C"}. *}
   746   by (unfold Inter_def) blast
   747 
   748 text {*
   749   \medskip Image of a set under a function.  Frequently @{term b} does
   750   not have the syntactic form of @{term "f x"}.
   751 *}
   752 
   753 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   754   by (unfold image_def) blast
   755 
   756 lemma imageI: "x : A ==> f x : f ` A"
   757   by (rule image_eqI) (rule refl)
   758 
   759 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   760   -- {* This version's more effective when we already have the
   761     required @{term x}. *}
   762   by (unfold image_def) blast
   763 
   764 lemma imageE [elim!]:
   765   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   766   -- {* The eta-expansion gives variable-name preservation. *}
   767   by (unfold image_def) blast
   768 
   769 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   770   by blast
   771 
   772 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
   773   by blast
   774 
   775 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
   776   -- {* This rewrite rule would confuse users if made default. *}
   777   by blast
   778 
   779 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
   780   apply safe
   781    prefer 2 apply fast
   782   apply (rule_tac x = "{a. a : A & f a : B}" in exI)
   783   apply fast
   784   done
   785 
   786 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
   787   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
   788     @{text hypsubst}, but breaks too many existing proofs. *}
   789   by blast
   790 
   791 text {*
   792   \medskip Range of a function -- just a translation for image!
   793 *}
   794 
   795 lemma range_eqI: "b = f x ==> b \<in> range f"
   796   by simp
   797 
   798 lemma rangeI: "f x \<in> range f"
   799   by simp
   800 
   801 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
   802   by blast
   803 
   804 
   805 subsubsection {* Set reasoning tools *}
   806 
   807 text {*
   808   Rewrite rules for boolean case-splitting: faster than @{text
   809   "split_if [split]"}.
   810 *}
   811 
   812 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
   813   by (rule split_if)
   814 
   815 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
   816   by (rule split_if)
   817 
   818 text {*
   819   Split ifs on either side of the membership relation.  Not for @{text
   820   "[simp]"} -- can cause goals to blow up!
   821 *}
   822 
   823 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
   824   by (rule split_if)
   825 
   826 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
   827   by (rule split_if)
   828 
   829 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
   830 
   831 lemmas mem_simps =
   832   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   833   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   834   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   835 
   836 (*Would like to add these, but the existing code only searches for the
   837   outer-level constant, which in this case is just "op :"; we instead need
   838   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   839   apply, then the formula should be kept.
   840   [("uminus", Compl_iff RS iffD1), ("op -", [Diff_iff RS iffD1]),
   841    ("op Int", [IntD1,IntD2]),
   842    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   843  *)
   844 
   845 ML_setup {*
   846   val mksimps_pairs = [("Ball", [thm "bspec"])] @ mksimps_pairs;
   847   simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   848 *}
   849 
   850 declare subset_UNIV [simp] subset_refl [simp]
   851 
   852 
   853 subsubsection {* The ``proper subset'' relation *}
   854 
   855 lemma psubsetI [intro!]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
   856   by (unfold psubset_def) blast
   857 
   858 lemma psubsetE [elim!]: 
   859     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
   860   by (unfold psubset_def) blast
   861 
   862 lemma psubset_insert_iff:
   863   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
   864   by (auto simp add: psubset_def subset_insert_iff)
   865 
   866 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
   867   by (simp only: psubset_def)
   868 
   869 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
   870   by (simp add: psubset_eq)
   871 
   872 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
   873   by (auto simp add: psubset_eq)
   874 
   875 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
   876   by (auto simp add: psubset_eq)
   877 
   878 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
   879   by (unfold psubset_def) blast
   880 
   881 lemma atomize_ball:
   882     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
   883   by (simp only: Ball_def atomize_all atomize_imp)
   884 
   885 declare atomize_ball [symmetric, rulify]
   886 
   887 
   888 subsection {* Further set-theory lemmas *}
   889 
   890 subsubsection {* Derived rules involving subsets. *}
   891 
   892 text {* @{text insert}. *}
   893 
   894 lemma subset_insertI: "B \<subseteq> insert a B"
   895   apply (rule subsetI)
   896   apply (erule insertI2)
   897   done
   898 
   899 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
   900   by blast
   901 
   902 
   903 text {* \medskip Big Union -- least upper bound of a set. *}
   904 
   905 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
   906   by (rules intro: subsetI UnionI)
   907 
   908 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
   909   by (rules intro: subsetI elim: UnionE dest: subsetD)
   910 
   911 
   912 text {* \medskip General union. *}
   913 
   914 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
   915   by blast
   916 
   917 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
   918   by (rules intro: subsetI elim: UN_E dest: subsetD)
   919 
   920 
   921 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
   922 
   923 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
   924   by blast
   925 
   926 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
   927   by (rules intro: InterI subsetI dest: subsetD)
   928 
   929 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   930   by blast
   931 
   932 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
   933   by (rules intro: INT_I subsetI dest: subsetD)
   934 
   935 
   936 text {* \medskip Finite Union -- the least upper bound of two sets. *}
   937 
   938 lemma Un_upper1: "A \<subseteq> A \<union> B"
   939   by blast
   940 
   941 lemma Un_upper2: "B \<subseteq> A \<union> B"
   942   by blast
   943 
   944 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
   945   by blast
   946 
   947 
   948 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
   949 
   950 lemma Int_lower1: "A \<inter> B \<subseteq> A"
   951   by blast
   952 
   953 lemma Int_lower2: "A \<inter> B \<subseteq> B"
   954   by blast
   955 
   956 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
   957   by blast
   958 
   959 
   960 text {* \medskip Set difference. *}
   961 
   962 lemma Diff_subset: "A - B \<subseteq> A"
   963   by blast
   964 
   965 
   966 text {* \medskip Monotonicity. *}
   967 
   968 lemma mono_Un: includes mono shows "f A \<union> f B \<subseteq> f (A \<union> B)"
   969   apply (rule Un_least)
   970    apply (rule Un_upper1 [THEN mono])
   971   apply (rule Un_upper2 [THEN mono])
   972   done
   973 
   974 lemma mono_Int: includes mono shows "f (A \<inter> B) \<subseteq> f A \<inter> f B"
   975   apply (rule Int_greatest)
   976    apply (rule Int_lower1 [THEN mono])
   977   apply (rule Int_lower2 [THEN mono])
   978   done
   979 
   980 
   981 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
   982 
   983 text {* @{text "{}"}. *}
   984 
   985 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
   986   -- {* supersedes @{text "Collect_False_empty"} *}
   987   by auto
   988 
   989 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
   990   by blast
   991 
   992 lemma not_psubset_empty [iff]: "\<not> (A < {})"
   993   by (unfold psubset_def) blast
   994 
   995 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
   996   by auto
   997 
   998 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
   999   by blast
  1000 
  1001 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1002   by blast
  1003 
  1004 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1005   by blast
  1006 
  1007 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1008   by blast
  1009 
  1010 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1011   by blast
  1012 
  1013 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1014   by blast
  1015 
  1016 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1017   by blast
  1018 
  1019 
  1020 text {* \medskip @{text insert}. *}
  1021 
  1022 lemma insert_is_Un: "insert a A = {a} Un A"
  1023   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1024   by blast
  1025 
  1026 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1027   by blast
  1028 
  1029 lemmas empty_not_insert [simp] = insert_not_empty [symmetric, standard]
  1030 
  1031 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1032   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1033   -- {* with \emph{quadratic} running time *}
  1034   by blast
  1035 
  1036 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1037   by blast
  1038 
  1039 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1040   by blast
  1041 
  1042 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1043   by blast
  1044 
  1045 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1046   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1047   apply (rule_tac x = "A - {a}" in exI)
  1048   apply blast
  1049   done
  1050 
  1051 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1052   by auto
  1053 
  1054 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1055   by blast
  1056 
  1057 lemma insert_disjoint[simp]:
  1058  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1059 by blast
  1060 
  1061 lemma disjoint_insert[simp]:
  1062  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1063 by blast
  1064 
  1065 text {* \medskip @{text image}. *}
  1066 
  1067 lemma image_empty [simp]: "f`{} = {}"
  1068   by blast
  1069 
  1070 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1071   by blast
  1072 
  1073 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1074   by blast
  1075 
  1076 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1077   by blast
  1078 
  1079 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1080   by blast
  1081 
  1082 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1083   by blast
  1084 
  1085 lemma image_Collect: "f ` {x. P x} = {f x | x. P x}"
  1086   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS, *}
  1087   -- {* with its implicit quantifier and conjunction.  Also image enjoys better *}
  1088   -- {* equational properties than does the RHS. *}
  1089   by blast
  1090 
  1091 lemma if_image_distrib [simp]:
  1092   "(\<lambda>x. if P x then f x else g x) ` S
  1093     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1094   by (auto simp add: image_def)
  1095 
  1096 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1097   by (simp add: image_def)
  1098 
  1099 
  1100 text {* \medskip @{text range}. *}
  1101 
  1102 lemma full_SetCompr_eq: "{u. \<exists>x. u = f x} = range f"
  1103   by auto
  1104 
  1105 lemma range_composition [simp]: "range (\<lambda>x. f (g x)) = f`range g"
  1106   apply (subst image_image)
  1107   apply simp
  1108   done
  1109 
  1110 
  1111 text {* \medskip @{text Int} *}
  1112 
  1113 lemma Int_absorb [simp]: "A \<inter> A = A"
  1114   by blast
  1115 
  1116 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1117   by blast
  1118 
  1119 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1120   by blast
  1121 
  1122 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1123   by blast
  1124 
  1125 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1126   by blast
  1127 
  1128 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1129   -- {* Intersection is an AC-operator *}
  1130 
  1131 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1132   by blast
  1133 
  1134 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1135   by blast
  1136 
  1137 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1138   by blast
  1139 
  1140 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1141   by blast
  1142 
  1143 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1144   by blast
  1145 
  1146 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1147   by blast
  1148 
  1149 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1150   by blast
  1151 
  1152 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1153   by blast
  1154 
  1155 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1156   by blast
  1157 
  1158 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1159   by blast
  1160 
  1161 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1162   by blast
  1163 
  1164 lemma Int_UNIV [simp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1165   by blast
  1166 
  1167 lemma Int_subset_iff: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1168   by blast
  1169 
  1170 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1171   by blast
  1172 
  1173 
  1174 text {* \medskip @{text Un}. *}
  1175 
  1176 lemma Un_absorb [simp]: "A \<union> A = A"
  1177   by blast
  1178 
  1179 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1180   by blast
  1181 
  1182 lemma Un_commute: "A \<union> B = B \<union> A"
  1183   by blast
  1184 
  1185 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1186   by blast
  1187 
  1188 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1189   by blast
  1190 
  1191 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1192   -- {* Union is an AC-operator *}
  1193 
  1194 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1195   by blast
  1196 
  1197 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1198   by blast
  1199 
  1200 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1201   by blast
  1202 
  1203 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1204   by blast
  1205 
  1206 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1207   by blast
  1208 
  1209 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1210   by blast
  1211 
  1212 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1213   by blast
  1214 
  1215 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1216   by blast
  1217 
  1218 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1219   by blast
  1220 
  1221 lemma Int_insert_left:
  1222     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1223   by auto
  1224 
  1225 lemma Int_insert_right:
  1226     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1227   by auto
  1228 
  1229 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1230   by blast
  1231 
  1232 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1233   by blast
  1234 
  1235 lemma Un_Int_crazy:
  1236     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1237   by blast
  1238 
  1239 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1240   by blast
  1241 
  1242 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1243   by blast
  1244 
  1245 lemma Un_subset_iff: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1246   by blast
  1247 
  1248 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1249   by blast
  1250 
  1251 
  1252 text {* \medskip Set complement *}
  1253 
  1254 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1255   by blast
  1256 
  1257 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1258   by blast
  1259 
  1260 lemma Compl_partition: "A \<union> -A = UNIV"
  1261   by blast
  1262 
  1263 lemma Compl_partition2: "-A \<union> A = UNIV"
  1264   by blast
  1265 
  1266 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1267   by blast
  1268 
  1269 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1270   by blast
  1271 
  1272 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1273   by blast
  1274 
  1275 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1276   by blast
  1277 
  1278 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1279   by blast
  1280 
  1281 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1282   by blast
  1283 
  1284 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1285   -- {* Halmos, Naive Set Theory, page 16. *}
  1286   by blast
  1287 
  1288 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1289   by blast
  1290 
  1291 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1292   by blast
  1293 
  1294 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1295   by blast
  1296 
  1297 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1298   by blast
  1299 
  1300 
  1301 text {* \medskip @{text Union}. *}
  1302 
  1303 lemma Union_empty [simp]: "Union({}) = {}"
  1304   by blast
  1305 
  1306 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1307   by blast
  1308 
  1309 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1310   by blast
  1311 
  1312 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1313   by blast
  1314 
  1315 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1316   by blast
  1317 
  1318 lemma Union_empty_conv [iff]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1319   by blast
  1320 
  1321 lemma empty_Union_conv [iff]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1322   by blast
  1323 
  1324 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1325   by blast
  1326 
  1327 
  1328 text {* \medskip @{text Inter}. *}
  1329 
  1330 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1331   by blast
  1332 
  1333 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1334   by blast
  1335 
  1336 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1337   by blast
  1338 
  1339 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1340   by blast
  1341 
  1342 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1343   by blast
  1344 
  1345 lemma Inter_UNIV_conv [iff]:
  1346   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1347   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1348   by(blast)+
  1349 
  1350 
  1351 text {*
  1352   \medskip @{text UN} and @{text INT}.
  1353 
  1354   Basic identities: *}
  1355 
  1356 lemma UN_empty [simp]: "(\<Union>x\<in>{}. B x) = {}"
  1357   by blast
  1358 
  1359 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1360   by blast
  1361 
  1362 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1363   by blast
  1364 
  1365 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1366   by blast
  1367 
  1368 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1369   by blast
  1370 
  1371 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1372   by blast
  1373 
  1374 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1375   by blast
  1376 
  1377 lemma UN_Un: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1378   by blast
  1379 
  1380 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1381   by blast
  1382 
  1383 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1384   by blast
  1385 
  1386 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1387   by blast
  1388 
  1389 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1390   by blast
  1391 
  1392 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1393   by blast
  1394 
  1395 lemma INT_insert_distrib:
  1396     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1397   by blast
  1398 
  1399 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1400   by blast
  1401 
  1402 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1403   by blast
  1404 
  1405 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1406   by blast
  1407 
  1408 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1409   by auto
  1410 
  1411 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1412   by auto
  1413 
  1414 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1415   by blast
  1416 
  1417 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1418   -- {* Look: it has an \emph{existential} quantifier *}
  1419   by blast
  1420 
  1421 lemma UNION_empty_conv[iff]:
  1422   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1423   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1424 by blast+
  1425 
  1426 lemma INTER_UNIV_conv[iff]:
  1427  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1428  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1429 by blast+
  1430 
  1431 
  1432 text {* \medskip Distributive laws: *}
  1433 
  1434 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1435   by blast
  1436 
  1437 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1438   by blast
  1439 
  1440 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1441   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1442   -- {* Union of a family of unions *}
  1443   by blast
  1444 
  1445 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1446   -- {* Equivalent version *}
  1447   by blast
  1448 
  1449 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1450   by blast
  1451 
  1452 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1453   by blast
  1454 
  1455 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1456   -- {* Equivalent version *}
  1457   by blast
  1458 
  1459 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1460   -- {* Halmos, Naive Set Theory, page 35. *}
  1461   by blast
  1462 
  1463 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1464   by blast
  1465 
  1466 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1467   by blast
  1468 
  1469 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1470   by blast
  1471 
  1472 
  1473 text {* \medskip Bounded quantifiers.
  1474 
  1475   The following are not added to the default simpset because
  1476   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1477 
  1478 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1479   by blast
  1480 
  1481 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1482   by blast
  1483 
  1484 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1485   by blast
  1486 
  1487 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1488   by blast
  1489 
  1490 
  1491 text {* \medskip Set difference. *}
  1492 
  1493 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1494   by blast
  1495 
  1496 lemma Diff_eq_empty_iff [simp]: "(A - B = {}) = (A \<subseteq> B)"
  1497   by blast
  1498 
  1499 lemma Diff_cancel [simp]: "A - A = {}"
  1500   by blast
  1501 
  1502 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1503   by (blast elim: equalityE)
  1504 
  1505 lemma empty_Diff [simp]: "{} - A = {}"
  1506   by blast
  1507 
  1508 lemma Diff_empty [simp]: "A - {} = A"
  1509   by blast
  1510 
  1511 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1512   by blast
  1513 
  1514 lemma Diff_insert0 [simp]: "x \<notin> A ==> A - insert x B = A - B"
  1515   by blast
  1516 
  1517 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1518   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1519   by blast
  1520 
  1521 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1522   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1523   by blast
  1524 
  1525 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1526   by auto
  1527 
  1528 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1529   by blast
  1530 
  1531 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1532   by blast
  1533 
  1534 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1535   by auto
  1536 
  1537 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1538   by blast
  1539 
  1540 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1541   by blast
  1542 
  1543 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1544   by blast
  1545 
  1546 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1547   by blast
  1548 
  1549 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1550   by blast
  1551 
  1552 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1553   by blast
  1554 
  1555 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1556   by blast
  1557 
  1558 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1559   by blast
  1560 
  1561 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1562   by blast
  1563 
  1564 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1565   by blast
  1566 
  1567 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1568   by blast
  1569 
  1570 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1571   by auto
  1572 
  1573 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1574   by blast
  1575 
  1576 
  1577 text {* \medskip Quantification over type @{typ bool}. *}
  1578 
  1579 lemma all_bool_eq: "(\<forall>b::bool. P b) = (P True & P False)"
  1580   apply auto
  1581   apply (tactic {* case_tac "b" 1 *})
  1582    apply auto
  1583   done
  1584 
  1585 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1586   by (rule conjI [THEN all_bool_eq [THEN iffD2], THEN spec])
  1587 
  1588 lemma ex_bool_eq: "(\<exists>b::bool. P b) = (P True | P False)"
  1589   apply auto
  1590   apply (tactic {* case_tac "b" 1 *})
  1591    apply auto
  1592   done
  1593 
  1594 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1595   by (auto simp add: split_if_mem2)
  1596 
  1597 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1598   apply auto
  1599   apply (tactic {* case_tac "b" 1 *})
  1600    apply auto
  1601   done
  1602 
  1603 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1604   apply auto
  1605   apply (tactic {* case_tac "b" 1 *})
  1606   apply auto
  1607   done
  1608 
  1609 
  1610 text {* \medskip @{text Pow} *}
  1611 
  1612 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1613   by (auto simp add: Pow_def)
  1614 
  1615 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1616   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1617 
  1618 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1619   by (blast intro: exI [where ?x = "- u", standard])
  1620 
  1621 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1622   by blast
  1623 
  1624 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1625   by blast
  1626 
  1627 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1628   by blast
  1629 
  1630 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1631   by blast
  1632 
  1633 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1634   by blast
  1635 
  1636 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1637   by blast
  1638 
  1639 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1640   by blast
  1641 
  1642 
  1643 text {* \medskip Miscellany. *}
  1644 
  1645 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1646   by blast
  1647 
  1648 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1649   by blast
  1650 
  1651 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1652   by (unfold psubset_def) blast
  1653 
  1654 lemma all_not_in_conv [iff]: "(\<forall>x. x \<notin> A) = (A = {})"
  1655   by blast
  1656 
  1657 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1658   by blast
  1659 
  1660 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1661   by rules
  1662 
  1663 
  1664 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1665            and Intersections. *}
  1666 
  1667 lemma UN_simps [simp]:
  1668   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1669   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1670   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1671   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1672   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1673   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1674   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1675   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1676   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1677   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1678   by auto
  1679 
  1680 lemma INT_simps [simp]:
  1681   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1682   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1683   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1684   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1685   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1686   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1687   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1688   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1689   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1690   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1691   by auto
  1692 
  1693 lemma ball_simps [simp]:
  1694   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1695   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1696   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1697   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1698   "!!P. (ALL x:{}. P x) = True"
  1699   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1700   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1701   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1702   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1703   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1704   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1705   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1706   by auto
  1707 
  1708 lemma bex_simps [simp]:
  1709   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1710   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1711   "!!P. (EX x:{}. P x) = False"
  1712   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1713   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1714   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1715   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1716   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1717   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1718   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1719   by auto
  1720 
  1721 lemma ball_conj_distrib:
  1722   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1723   by blast
  1724 
  1725 lemma bex_disj_distrib:
  1726   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  1727   by blast
  1728 
  1729 
  1730 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1731 
  1732 lemma UN_extend_simps:
  1733   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
  1734   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
  1735   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
  1736   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
  1737   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
  1738   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
  1739   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
  1740   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
  1741   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
  1742   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
  1743   by auto
  1744 
  1745 lemma INT_extend_simps:
  1746   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
  1747   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
  1748   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
  1749   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
  1750   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
  1751   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
  1752   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
  1753   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
  1754   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
  1755   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
  1756   by auto
  1757 
  1758 
  1759 subsubsection {* Monotonicity of various operations *}
  1760 
  1761 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  1762   by blast
  1763 
  1764 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  1765   by blast
  1766 
  1767 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  1768   by blast
  1769 
  1770 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  1771   by blast
  1772 
  1773 lemma UN_mono:
  1774   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1775     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1776   by (blast dest: subsetD)
  1777 
  1778 lemma INT_anti_mono:
  1779   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1780     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  1781   -- {* The last inclusion is POSITIVE! *}
  1782   by (blast dest: subsetD)
  1783 
  1784 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  1785   by blast
  1786 
  1787 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  1788   by blast
  1789 
  1790 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  1791   by blast
  1792 
  1793 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  1794   by blast
  1795 
  1796 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  1797   by blast
  1798 
  1799 text {* \medskip Monotonicity of implications. *}
  1800 
  1801 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  1802   apply (rule impI)
  1803   apply (erule subsetD)
  1804   apply assumption
  1805   done
  1806 
  1807 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  1808   by rules
  1809 
  1810 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  1811   by rules
  1812 
  1813 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  1814   by rules
  1815 
  1816 lemma imp_refl: "P --> P" ..
  1817 
  1818 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  1819   by rules
  1820 
  1821 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  1822   by rules
  1823 
  1824 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  1825   by blast
  1826 
  1827 lemma Int_Collect_mono:
  1828     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  1829   by blast
  1830 
  1831 lemmas basic_monos =
  1832   subset_refl imp_refl disj_mono conj_mono
  1833   ex_mono Collect_mono in_mono
  1834 
  1835 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  1836   by rules
  1837 
  1838 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  1839   by rules
  1840 
  1841 lemma Least_mono:
  1842   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  1843     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  1844     -- {* Courtesy of Stephan Merz *}
  1845   apply clarify
  1846   apply (erule_tac P = "%x. x : S" in LeastI2)
  1847    apply fast
  1848   apply (rule LeastI2)
  1849   apply (auto elim: monoD intro!: order_antisym)
  1850   done
  1851 
  1852 
  1853 subsection {* Inverse image of a function *}
  1854 
  1855 constdefs
  1856   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  1857   "f -` B == {x. f x : B}"
  1858 
  1859 
  1860 subsubsection {* Basic rules *}
  1861 
  1862 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  1863   by (unfold vimage_def) blast
  1864 
  1865 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  1866   by simp
  1867 
  1868 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  1869   by (unfold vimage_def) blast
  1870 
  1871 lemma vimageI2: "f a : A ==> a : f -` A"
  1872   by (unfold vimage_def) fast
  1873 
  1874 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  1875   by (unfold vimage_def) blast
  1876 
  1877 lemma vimageD: "a : f -` A ==> f a : A"
  1878   by (unfold vimage_def) fast
  1879 
  1880 
  1881 subsubsection {* Equations *}
  1882 
  1883 lemma vimage_empty [simp]: "f -` {} = {}"
  1884   by blast
  1885 
  1886 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  1887   by blast
  1888 
  1889 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  1890   by blast
  1891 
  1892 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  1893   by fast
  1894 
  1895 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  1896   by blast
  1897 
  1898 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  1899   by blast
  1900 
  1901 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  1902   by blast
  1903 
  1904 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  1905   by blast
  1906 
  1907 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  1908   by blast
  1909 
  1910 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  1911   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  1912   by blast
  1913 
  1914 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  1915   by blast
  1916 
  1917 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  1918   by blast
  1919 
  1920 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  1921   -- {* NOT suitable for rewriting *}
  1922   by blast
  1923 
  1924 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  1925   -- {* monotonicity *}
  1926   by blast
  1927 
  1928 
  1929 subsection {* Transitivity rules for calculational reasoning *}
  1930 
  1931 lemma forw_subst: "a = b ==> P b ==> P a"
  1932   by (rule ssubst)
  1933 
  1934 lemma back_subst: "P a ==> a = b ==> P b"
  1935   by (rule subst)
  1936 
  1937 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  1938   by (rule subsetD)
  1939 
  1940 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  1941   by (rule subsetD)
  1942 
  1943 lemma order_neq_le_trans: "a ~= b ==> (a::'a::order) <= b ==> a < b"
  1944   by (simp add: order_less_le)
  1945 
  1946 lemma order_le_neq_trans: "(a::'a::order) <= b ==> a ~= b ==> a < b"
  1947   by (simp add: order_less_le)
  1948 
  1949 lemma order_less_asym': "(a::'a::order) < b ==> b < a ==> P"
  1950   by (rule order_less_asym)
  1951 
  1952 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
  1953   by (rule subst)
  1954 
  1955 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
  1956   by (rule ssubst)
  1957 
  1958 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
  1959   by (rule subst)
  1960 
  1961 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
  1962   by (rule ssubst)
  1963 
  1964 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
  1965   (!!x y. x < y ==> f x < f y) ==> f a < c"
  1966 proof -
  1967   assume r: "!!x y. x < y ==> f x < f y"
  1968   assume "a < b" hence "f a < f b" by (rule r)
  1969   also assume "f b < c"
  1970   finally (order_less_trans) show ?thesis .
  1971 qed
  1972 
  1973 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
  1974   (!!x y. x < y ==> f x < f y) ==> a < f c"
  1975 proof -
  1976   assume r: "!!x y. x < y ==> f x < f y"
  1977   assume "a < f b"
  1978   also assume "b < c" hence "f b < f c" by (rule r)
  1979   finally (order_less_trans) show ?thesis .
  1980 qed
  1981 
  1982 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
  1983   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
  1984 proof -
  1985   assume r: "!!x y. x <= y ==> f x <= f y"
  1986   assume "a <= b" hence "f a <= f b" by (rule r)
  1987   also assume "f b < c"
  1988   finally (order_le_less_trans) show ?thesis .
  1989 qed
  1990 
  1991 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
  1992   (!!x y. x < y ==> f x < f y) ==> a < f c"
  1993 proof -
  1994   assume r: "!!x y. x < y ==> f x < f y"
  1995   assume "a <= f b"
  1996   also assume "b < c" hence "f b < f c" by (rule r)
  1997   finally (order_le_less_trans) show ?thesis .
  1998 qed
  1999 
  2000 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
  2001   (!!x y. x < y ==> f x < f y) ==> f a < c"
  2002 proof -
  2003   assume r: "!!x y. x < y ==> f x < f y"
  2004   assume "a < b" hence "f a < f b" by (rule r)
  2005   also assume "f b <= c"
  2006   finally (order_less_le_trans) show ?thesis .
  2007 qed
  2008 
  2009 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
  2010   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
  2011 proof -
  2012   assume r: "!!x y. x <= y ==> f x <= f y"
  2013   assume "a < f b"
  2014   also assume "b <= c" hence "f b <= f c" by (rule r)
  2015   finally (order_less_le_trans) show ?thesis .
  2016 qed
  2017 
  2018 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
  2019   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  2020 proof -
  2021   assume r: "!!x y. x <= y ==> f x <= f y"
  2022   assume "a <= f b"
  2023   also assume "b <= c" hence "f b <= f c" by (rule r)
  2024   finally (order_trans) show ?thesis .
  2025 qed
  2026 
  2027 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
  2028   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  2029 proof -
  2030   assume r: "!!x y. x <= y ==> f x <= f y"
  2031   assume "a <= b" hence "f a <= f b" by (rule r)
  2032   also assume "f b <= c"
  2033   finally (order_trans) show ?thesis .
  2034 qed
  2035 
  2036 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
  2037   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  2038 proof -
  2039   assume r: "!!x y. x <= y ==> f x <= f y"
  2040   assume "a <= b" hence "f a <= f b" by (rule r)
  2041   also assume "f b = c"
  2042   finally (ord_le_eq_trans) show ?thesis .
  2043 qed
  2044 
  2045 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
  2046   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  2047 proof -
  2048   assume r: "!!x y. x <= y ==> f x <= f y"
  2049   assume "a = f b"
  2050   also assume "b <= c" hence "f b <= f c" by (rule r)
  2051   finally (ord_eq_le_trans) show ?thesis .
  2052 qed
  2053 
  2054 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
  2055   (!!x y. x < y ==> f x < f y) ==> f a < c"
  2056 proof -
  2057   assume r: "!!x y. x < y ==> f x < f y"
  2058   assume "a < b" hence "f a < f b" by (rule r)
  2059   also assume "f b = c"
  2060   finally (ord_less_eq_trans) show ?thesis .
  2061 qed
  2062 
  2063 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
  2064   (!!x y. x < y ==> f x < f y) ==> a < f c"
  2065 proof -
  2066   assume r: "!!x y. x < y ==> f x < f y"
  2067   assume "a = f b"
  2068   also assume "b < c" hence "f b < f c" by (rule r)
  2069   finally (ord_eq_less_trans) show ?thesis .
  2070 qed
  2071 
  2072 text {*
  2073   Note that this list of rules is in reverse order of priorities.
  2074 *}
  2075 
  2076 lemmas basic_trans_rules [trans] =
  2077   order_less_subst2
  2078   order_less_subst1
  2079   order_le_less_subst2
  2080   order_le_less_subst1
  2081   order_less_le_subst2
  2082   order_less_le_subst1
  2083   order_subst2
  2084   order_subst1
  2085   ord_le_eq_subst
  2086   ord_eq_le_subst
  2087   ord_less_eq_subst
  2088   ord_eq_less_subst
  2089   forw_subst
  2090   back_subst
  2091   rev_mp
  2092   mp
  2093   set_rev_mp
  2094   set_mp
  2095   order_neq_le_trans
  2096   order_le_neq_trans
  2097   order_less_trans
  2098   order_less_asym'
  2099   order_le_less_trans
  2100   order_less_le_trans
  2101   order_trans
  2102   order_antisym
  2103   ord_le_eq_trans
  2104   ord_eq_le_trans
  2105   ord_less_eq_trans
  2106   ord_eq_less_trans
  2107   trans
  2108 
  2109 end