src/HOL/Imperative_HOL/Array.thy
author haftmann
Sun Mar 10 15:16:45 2019 +0000 (5 weeks ago)
changeset 69906 55534affe445
parent 66003 5b2fab45db92
permissions -rw-r--r--
migrated from Nums to Zarith as library for OCaml integer arithmetic
     1 (*  Title:      HOL/Imperative_HOL/Array.thy
     2     Author:     John Matthews, Galois Connections; Alexander Krauss, Lukas Bulwahn & Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 section \<open>Monadic arrays\<close>
     6 
     7 theory Array
     8 imports Heap_Monad
     9 begin
    10 
    11 subsection \<open>Primitives\<close>
    12 
    13 definition present :: "heap \<Rightarrow> 'a::heap array \<Rightarrow> bool" where
    14   "present h a \<longleftrightarrow> addr_of_array a < lim h"
    15 
    16 definition get :: "heap \<Rightarrow> 'a::heap array \<Rightarrow> 'a list" where
    17   "get h a = map from_nat (arrays h (TYPEREP('a)) (addr_of_array a))"
    18 
    19 definition set :: "'a::heap array \<Rightarrow> 'a list \<Rightarrow> heap \<Rightarrow> heap" where
    20   "set a x = arrays_update (\<lambda>h. h(TYPEREP('a) := ((h(TYPEREP('a))) (addr_of_array a:=map to_nat x))))"
    21 
    22 definition alloc :: "'a list \<Rightarrow> heap \<Rightarrow> 'a::heap array \<times> heap" where
    23   "alloc xs h = (let
    24      l = lim h;
    25      r = Array l;
    26      h'' = set r xs (h\<lparr>lim := l + 1\<rparr>)
    27    in (r, h''))"
    28 
    29 definition length :: "heap \<Rightarrow> 'a::heap array \<Rightarrow> nat" where
    30   "length h a = List.length (get h a)"
    31   
    32 definition update :: "'a::heap array \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> heap \<Rightarrow> heap" where
    33   "update a i x h = set a ((get h a)[i:=x]) h"
    34 
    35 definition noteq :: "'a::heap array \<Rightarrow> 'b::heap array \<Rightarrow> bool" (infix "=!!=" 70) where
    36   "r =!!= s \<longleftrightarrow> TYPEREP('a) \<noteq> TYPEREP('b) \<or> addr_of_array r \<noteq> addr_of_array s"
    37 
    38 
    39 subsection \<open>Monad operations\<close>
    40 
    41 definition new :: "nat \<Rightarrow> 'a::heap \<Rightarrow> 'a array Heap" where
    42   [code del]: "new n x = Heap_Monad.heap (alloc (replicate n x))"
    43 
    44 definition of_list :: "'a::heap list \<Rightarrow> 'a array Heap" where
    45   [code del]: "of_list xs = Heap_Monad.heap (alloc xs)"
    46 
    47 definition make :: "nat \<Rightarrow> (nat \<Rightarrow> 'a::heap) \<Rightarrow> 'a array Heap" where
    48   [code del]: "make n f = Heap_Monad.heap (alloc (map f [0 ..< n]))"
    49 
    50 definition len :: "'a::heap array \<Rightarrow> nat Heap" where
    51   [code del]: "len a = Heap_Monad.tap (\<lambda>h. length h a)"
    52 
    53 definition nth :: "'a::heap array \<Rightarrow> nat \<Rightarrow> 'a Heap" where
    54   [code del]: "nth a i = Heap_Monad.guard (\<lambda>h. i < length h a)
    55     (\<lambda>h. (get h a ! i, h))"
    56 
    57 definition upd :: "nat \<Rightarrow> 'a \<Rightarrow> 'a::heap array \<Rightarrow> 'a::heap array Heap" where
    58   [code del]: "upd i x a = Heap_Monad.guard (\<lambda>h. i < length h a)
    59     (\<lambda>h. (a, update a i x h))"
    60 
    61 definition map_entry :: "nat \<Rightarrow> ('a::heap \<Rightarrow> 'a) \<Rightarrow> 'a array \<Rightarrow> 'a array Heap" where
    62   [code del]: "map_entry i f a = Heap_Monad.guard (\<lambda>h. i < length h a)
    63     (\<lambda>h. (a, update a i (f (get h a ! i)) h))"
    64 
    65 definition swap :: "nat \<Rightarrow> 'a \<Rightarrow> 'a::heap array \<Rightarrow> 'a Heap" where
    66   [code del]: "swap i x a = Heap_Monad.guard (\<lambda>h. i < length h a)
    67     (\<lambda>h. (get h a ! i, update a i x h))"
    68 
    69 definition freeze :: "'a::heap array \<Rightarrow> 'a list Heap" where
    70   [code del]: "freeze a = Heap_Monad.tap (\<lambda>h. get h a)"
    71 
    72 
    73 subsection \<open>Properties\<close>
    74 
    75 text \<open>FIXME: Does there exist a "canonical" array axiomatisation in
    76 the literature?\<close>
    77 
    78 text \<open>Primitives\<close>
    79 
    80 lemma noteq_sym: "a =!!= b \<Longrightarrow> b =!!= a"
    81   and unequal [simp]: "a \<noteq> a' \<longleftrightarrow> a =!!= a'"
    82   unfolding noteq_def by auto
    83 
    84 lemma noteq_irrefl: "r =!!= r \<Longrightarrow> False"
    85   unfolding noteq_def by auto
    86 
    87 lemma present_alloc_noteq: "present h a \<Longrightarrow> a =!!= fst (alloc xs h)"
    88   by (simp add: present_def noteq_def alloc_def Let_def)
    89 
    90 lemma get_set_eq [simp]: "get (set r x h) r = x"
    91   by (simp add: get_def set_def o_def)
    92 
    93 lemma get_set_neq [simp]: "r =!!= s \<Longrightarrow> get (set s x h) r = get h r"
    94   by (simp add: noteq_def get_def set_def)
    95 
    96 lemma set_same [simp]:
    97   "set r x (set r y h) = set r x h"
    98   by (simp add: set_def)
    99 
   100 lemma set_set_swap:
   101   "r =!!= r' \<Longrightarrow> set r x (set r' x' h) = set r' x' (set r x h)"
   102   by (simp add: Let_def fun_eq_iff noteq_def set_def)
   103 
   104 lemma get_update_eq [simp]:
   105   "get (update a i v h) a = (get h a) [i := v]"
   106   by (simp add: update_def)
   107 
   108 lemma nth_update_neq [simp]:
   109   "a =!!= b \<Longrightarrow> get (update b j v h) a ! i = get h a ! i"
   110   by (simp add: update_def noteq_def)
   111 
   112 lemma get_update_elem_neqIndex [simp]:
   113   "i \<noteq> j \<Longrightarrow> get (update a j v h) a ! i = get h a ! i"
   114   by simp
   115 
   116 lemma length_update [simp]: 
   117   "length (update b i v h) = length h"
   118   by (simp add: update_def length_def set_def get_def fun_eq_iff)
   119 
   120 lemma update_swap_neq:
   121   "a =!!= a' \<Longrightarrow> 
   122   update a i v (update a' i' v' h) 
   123   = update a' i' v' (update a i v h)"
   124 apply (unfold update_def)
   125 apply simp
   126 apply (subst set_set_swap, assumption)
   127 apply (subst get_set_neq)
   128 apply (erule noteq_sym)
   129 apply simp
   130 done
   131 
   132 lemma update_swap_neqIndex:
   133   "\<lbrakk> i \<noteq> i' \<rbrakk> \<Longrightarrow> update a i v (update a i' v' h) = update a i' v' (update a i v h)"
   134   by (auto simp add: update_def set_set_swap list_update_swap)
   135 
   136 lemma get_alloc:
   137   "get (snd (alloc xs h)) (fst (alloc ys h)) = xs"
   138   by (simp add: Let_def split_def alloc_def)
   139 
   140 lemma length_alloc:
   141   "length (snd (alloc (xs :: 'a::heap list) h)) (fst (alloc (ys :: 'a list) h)) = List.length xs"
   142   by (simp add: Array.length_def get_alloc)
   143 
   144 lemma set:
   145   "set (fst (alloc ls h))
   146      new_ls (snd (alloc ls h))
   147        = snd (alloc new_ls h)"
   148   by (simp add: Let_def split_def alloc_def)
   149 
   150 lemma present_update [simp]: 
   151   "present (update b i v h) = present h"
   152   by (simp add: update_def present_def set_def get_def fun_eq_iff)
   153 
   154 lemma present_alloc [simp]:
   155   "present (snd (alloc xs h)) (fst (alloc xs h))"
   156   by (simp add: present_def alloc_def set_def Let_def)
   157 
   158 lemma not_present_alloc [simp]:
   159   "\<not> present h (fst (alloc xs h))"
   160   by (simp add: present_def alloc_def Let_def)
   161 
   162 
   163 text \<open>Monad operations\<close>
   164 
   165 lemma execute_new [execute_simps]:
   166   "execute (new n x) h = Some (alloc (replicate n x) h)"
   167   by (simp add: new_def execute_simps)
   168 
   169 lemma success_newI [success_intros]:
   170   "success (new n x) h"
   171   by (auto intro: success_intros simp add: new_def)
   172 
   173 lemma effect_newI [effect_intros]:
   174   assumes "(a, h') = alloc (replicate n x) h"
   175   shows "effect (new n x) h h' a"
   176   by (rule effectI) (simp add: assms execute_simps)
   177 
   178 lemma effect_newE [effect_elims]:
   179   assumes "effect (new n x) h h' r"
   180   obtains "r = fst (alloc (replicate n x) h)" "h' = snd (alloc (replicate n x) h)" 
   181     "get h' r = replicate n x" "present h' r" "\<not> present h r"
   182   using assms by (rule effectE) (simp add: get_alloc execute_simps)
   183 
   184 lemma execute_of_list [execute_simps]:
   185   "execute (of_list xs) h = Some (alloc xs h)"
   186   by (simp add: of_list_def execute_simps)
   187 
   188 lemma success_of_listI [success_intros]:
   189   "success (of_list xs) h"
   190   by (auto intro: success_intros simp add: of_list_def)
   191 
   192 lemma effect_of_listI [effect_intros]:
   193   assumes "(a, h') = alloc xs h"
   194   shows "effect (of_list xs) h h' a"
   195   by (rule effectI) (simp add: assms execute_simps)
   196 
   197 lemma effect_of_listE [effect_elims]:
   198   assumes "effect (of_list xs) h h' r"
   199   obtains "r = fst (alloc xs h)" "h' = snd (alloc xs h)" 
   200     "get h' r = xs" "present h' r" "\<not> present h r"
   201   using assms by (rule effectE) (simp add: get_alloc execute_simps)
   202 
   203 lemma execute_make [execute_simps]:
   204   "execute (make n f) h = Some (alloc (map f [0 ..< n]) h)"
   205   by (simp add: make_def execute_simps)
   206 
   207 lemma success_makeI [success_intros]:
   208   "success (make n f) h"
   209   by (auto intro: success_intros simp add: make_def)
   210 
   211 lemma effect_makeI [effect_intros]:
   212   assumes "(a, h') = alloc (map f [0 ..< n]) h"
   213   shows "effect (make n f) h h' a"
   214   by (rule effectI) (simp add: assms execute_simps)
   215 
   216 lemma effect_makeE [effect_elims]:
   217   assumes "effect (make n f) h h' r"
   218   obtains "r = fst (alloc (map f [0 ..< n]) h)" "h' = snd (alloc (map f [0 ..< n]) h)" 
   219     "get h' r = map f [0 ..< n]" "present h' r" "\<not> present h r"
   220   using assms by (rule effectE) (simp add: get_alloc execute_simps)
   221 
   222 lemma execute_len [execute_simps]:
   223   "execute (len a) h = Some (length h a, h)"
   224   by (simp add: len_def execute_simps)
   225 
   226 lemma success_lenI [success_intros]:
   227   "success (len a) h"
   228   by (auto intro: success_intros simp add: len_def)
   229 
   230 lemma effect_lengthI [effect_intros]:
   231   assumes "h' = h" "r = length h a"
   232   shows "effect (len a) h h' r"
   233   by (rule effectI) (simp add: assms execute_simps)
   234 
   235 lemma effect_lengthE [effect_elims]:
   236   assumes "effect (len a) h h' r"
   237   obtains "r = length h' a" "h' = h" 
   238   using assms by (rule effectE) (simp add: execute_simps)
   239 
   240 lemma execute_nth [execute_simps]:
   241   "i < length h a \<Longrightarrow>
   242     execute (nth a i) h = Some (get h a ! i, h)"
   243   "i \<ge> length h a \<Longrightarrow> execute (nth a i) h = None"
   244   by (simp_all add: nth_def execute_simps)
   245 
   246 lemma success_nthI [success_intros]:
   247   "i < length h a \<Longrightarrow> success (nth a i) h"
   248   by (auto intro: success_intros simp add: nth_def)
   249 
   250 lemma effect_nthI [effect_intros]:
   251   assumes "i < length h a" "h' = h" "r = get h a ! i"
   252   shows "effect (nth a i) h h' r"
   253   by (rule effectI) (insert assms, simp add: execute_simps)
   254 
   255 lemma effect_nthE [effect_elims]:
   256   assumes "effect (nth a i) h h' r"
   257   obtains "i < length h a" "r = get h a ! i" "h' = h"
   258   using assms by (rule effectE) (cases "i < length h a", auto simp: execute_simps elim: successE)
   259 
   260 lemma execute_upd [execute_simps]:
   261   "i < length h a \<Longrightarrow>
   262     execute (upd i x a) h = Some (a, update a i x h)"
   263   "i \<ge> length h a \<Longrightarrow> execute (upd i x a) h = None"
   264   by (simp_all add: upd_def execute_simps)
   265 
   266 lemma success_updI [success_intros]:
   267   "i < length h a \<Longrightarrow> success (upd i x a) h"
   268   by (auto intro: success_intros simp add: upd_def)
   269 
   270 lemma effect_updI [effect_intros]:
   271   assumes "i < length h a" "h' = update a i v h"
   272   shows "effect (upd i v a) h h' a"
   273   by (rule effectI) (insert assms, simp add: execute_simps)
   274 
   275 lemma effect_updE [effect_elims]:
   276   assumes "effect (upd i v a) h h' r"
   277   obtains "r = a" "h' = update a i v h" "i < length h a"
   278   using assms by (rule effectE) (cases "i < length h a", auto simp: execute_simps elim: successE)
   279 
   280 lemma execute_map_entry [execute_simps]:
   281   "i < length h a \<Longrightarrow>
   282    execute (map_entry i f a) h =
   283       Some (a, update a i (f (get h a ! i)) h)"
   284   "i \<ge> length h a \<Longrightarrow> execute (map_entry i f a) h = None"
   285   by (simp_all add: map_entry_def execute_simps)
   286 
   287 lemma success_map_entryI [success_intros]:
   288   "i < length h a \<Longrightarrow> success (map_entry i f a) h"
   289   by (auto intro: success_intros simp add: map_entry_def)
   290 
   291 lemma effect_map_entryI [effect_intros]:
   292   assumes "i < length h a" "h' = update a i (f (get h a ! i)) h" "r = a"
   293   shows "effect (map_entry i f a) h h' r"
   294   by (rule effectI) (insert assms, simp add: execute_simps)
   295 
   296 lemma effect_map_entryE [effect_elims]:
   297   assumes "effect (map_entry i f a) h h' r"
   298   obtains "r = a" "h' = update a i (f (get h a ! i)) h" "i < length h a"
   299   using assms by (rule effectE) (cases "i < length h a", auto simp: execute_simps elim: successE)
   300 
   301 lemma execute_swap [execute_simps]:
   302   "i < length h a \<Longrightarrow>
   303    execute (swap i x a) h =
   304       Some (get h a ! i, update a i x h)"
   305   "i \<ge> length h a \<Longrightarrow> execute (swap i x a) h = None"
   306   by (simp_all add: swap_def execute_simps)
   307 
   308 lemma success_swapI [success_intros]:
   309   "i < length h a \<Longrightarrow> success (swap i x a) h"
   310   by (auto intro: success_intros simp add: swap_def)
   311 
   312 lemma effect_swapI [effect_intros]:
   313   assumes "i < length h a" "h' = update a i x h" "r = get h a ! i"
   314   shows "effect (swap i x a) h h' r"
   315   by (rule effectI) (insert assms, simp add: execute_simps)
   316 
   317 lemma effect_swapE [effect_elims]:
   318   assumes "effect (swap i x a) h h' r"
   319   obtains "r = get h a ! i" "h' = update a i x h" "i < length h a"
   320   using assms by (rule effectE) (cases "i < length h a", auto simp: execute_simps elim: successE)
   321 
   322 lemma execute_freeze [execute_simps]:
   323   "execute (freeze a) h = Some (get h a, h)"
   324   by (simp add: freeze_def execute_simps)
   325 
   326 lemma success_freezeI [success_intros]:
   327   "success (freeze a) h"
   328   by (auto intro: success_intros simp add: freeze_def)
   329 
   330 lemma effect_freezeI [effect_intros]:
   331   assumes "h' = h" "r = get h a"
   332   shows "effect (freeze a) h h' r"
   333   by (rule effectI) (insert assms, simp add: execute_simps)
   334 
   335 lemma effect_freezeE [effect_elims]:
   336   assumes "effect (freeze a) h h' r"
   337   obtains "h' = h" "r = get h a"
   338   using assms by (rule effectE) (simp add: execute_simps)
   339 
   340 lemma upd_return:
   341   "upd i x a \<then> return a = upd i x a"
   342   by (rule Heap_eqI) (simp add: bind_def guard_def upd_def execute_simps)
   343 
   344 lemma array_make:
   345   "new n x = make n (\<lambda>_. x)"
   346   by (rule Heap_eqI) (simp add: map_replicate_trivial execute_simps)
   347 
   348 lemma array_of_list_make [code]:
   349   "of_list xs = make (List.length xs) (\<lambda>n. xs ! n)"
   350   by (rule Heap_eqI) (simp add: map_nth execute_simps)
   351 
   352 hide_const (open) present get set alloc length update noteq new of_list make len nth upd map_entry swap freeze
   353 
   354 
   355 subsection \<open>Code generator setup\<close>
   356 
   357 subsubsection \<open>Logical intermediate layer\<close>
   358 
   359 definition new' where
   360   [code del]: "new' = Array.new o nat_of_integer"
   361 
   362 lemma [code]:
   363   "Array.new = new' o of_nat"
   364   by (simp add: new'_def o_def)
   365 
   366 definition make' where
   367   [code del]: "make' i f = Array.make (nat_of_integer i) (f o of_nat)"
   368 
   369 lemma [code]:
   370   "Array.make n f = make' (of_nat n) (f o nat_of_integer)"
   371   by (simp add: make'_def o_def)
   372 
   373 definition len' where
   374   [code del]: "len' a = Array.len a \<bind> (\<lambda>n. return (of_nat n))"
   375 
   376 lemma [code]:
   377   "Array.len a = len' a \<bind> (\<lambda>i. return (nat_of_integer i))"
   378   by (simp add: len'_def)
   379 
   380 definition nth' where
   381   [code del]: "nth' a = Array.nth a o nat_of_integer"
   382 
   383 lemma [code]:
   384   "Array.nth a n = nth' a (of_nat n)"
   385   by (simp add: nth'_def)
   386 
   387 definition upd' where
   388   [code del]: "upd' a i x = Array.upd (nat_of_integer i) x a \<then> return ()"
   389 
   390 lemma [code]:
   391   "Array.upd i x a = upd' a (of_nat i) x \<then> return a"
   392   by (simp add: upd'_def upd_return)
   393 
   394 lemma [code]:
   395   "Array.map_entry i f a = do {
   396      x \<leftarrow> Array.nth a i;
   397      Array.upd i (f x) a
   398    }"
   399   by (rule Heap_eqI) (simp add: bind_def guard_def map_entry_def execute_simps)
   400 
   401 lemma [code]:
   402   "Array.swap i x a = do {
   403      y \<leftarrow> Array.nth a i;
   404      Array.upd i x a;
   405      return y
   406    }"
   407   by (rule Heap_eqI) (simp add: bind_def guard_def swap_def execute_simps)
   408 
   409 lemma [code]:
   410   "Array.freeze a = do {
   411      n \<leftarrow> Array.len a;
   412      Heap_Monad.fold_map (\<lambda>i. Array.nth a i) [0..<n]
   413    }"
   414 proof (rule Heap_eqI)
   415   fix h
   416   have *: "List.map
   417      (\<lambda>x. fst (the (if x < Array.length h a
   418                     then Some (Array.get h a ! x, h) else None)))
   419      [0..<Array.length h a] =
   420        List.map (List.nth (Array.get h a)) [0..<Array.length h a]"
   421     by simp
   422   have "execute (Heap_Monad.fold_map (Array.nth a) [0..<Array.length h a]) h =
   423     Some (Array.get h a, h)"
   424     apply (subst execute_fold_map_unchanged_heap)
   425     apply (simp_all add: nth_def guard_def *)
   426     apply (simp add: length_def map_nth)
   427     done
   428   then have "execute (do {
   429       n \<leftarrow> Array.len a;
   430       Heap_Monad.fold_map (Array.nth a) [0..<n]
   431     }) h = Some (Array.get h a, h)"
   432     by (auto intro: execute_bind_eq_SomeI simp add: execute_simps)
   433   then show "execute (Array.freeze a) h = execute (do {
   434       n \<leftarrow> Array.len a;
   435       Heap_Monad.fold_map (Array.nth a) [0..<n]
   436     }) h" by (simp add: execute_simps)
   437 qed
   438 
   439 hide_const (open) new' make' len' nth' upd'
   440 
   441 
   442 text \<open>SML\<close>
   443 
   444 code_printing type_constructor array \<rightharpoonup> (SML) "_/ array"
   445 code_printing constant Array \<rightharpoonup> (SML) "raise/ (Fail/ \"bare Array\")"
   446 code_printing constant Array.new' \<rightharpoonup> (SML) "(fn/ ()/ =>/ Array.array/ (IntInf.toInt _,/ (_)))"
   447 code_printing constant Array.of_list \<rightharpoonup> (SML) "(fn/ ()/ =>/ Array.fromList/ _)"
   448 code_printing constant Array.make' \<rightharpoonup> (SML) "(fn/ ()/ =>/ Array.tabulate/ (IntInf.toInt _,/ _ o IntInf.fromInt))"
   449 code_printing constant Array.len' \<rightharpoonup> (SML) "(fn/ ()/ =>/ IntInf.fromInt (Array.length/ _))"
   450 code_printing constant Array.nth' \<rightharpoonup> (SML) "(fn/ ()/ =>/ Array.sub/ ((_),/ IntInf.toInt _))"
   451 code_printing constant Array.upd' \<rightharpoonup> (SML) "(fn/ ()/ =>/ Array.update/ ((_),/ IntInf.toInt _,/ (_)))"
   452 code_printing constant "HOL.equal :: 'a array \<Rightarrow> 'a array \<Rightarrow> bool" \<rightharpoonup> (SML) infixl 6 "="
   453   
   454 code_reserved SML Array
   455 
   456 
   457 text \<open>OCaml\<close>
   458 
   459 code_printing type_constructor array \<rightharpoonup> (OCaml) "_/ array"
   460 code_printing constant Array \<rightharpoonup> (OCaml) "failwith/ \"bare Array\""
   461 code_printing constant Array.new' \<rightharpoonup> (OCaml) "(fun/ ()/ ->/ Array.make/ (Z.to'_int/ _)/ _)"
   462 code_printing constant Array.of_list \<rightharpoonup> (OCaml) "(fun/ ()/ ->/ Array.of'_list/ _)"
   463 code_printing constant Array.make' \<rightharpoonup> (OCaml)
   464   "(fun/ ()/ ->/ Array.init/ (Z.to'_int/ _)/ (fun k'_ ->/ _/ (Z.of'_int/ k'_)))"
   465 code_printing constant Array.len' \<rightharpoonup> (OCaml) "(fun/ ()/ ->/ Z.of'_int/ (Array.length/ _))"
   466 code_printing constant Array.nth' \<rightharpoonup> (OCaml) "(fun/ ()/ ->/ Array.get/ _/ (Z.to'_int/ _))"
   467 code_printing constant Array.upd' \<rightharpoonup> (OCaml) "(fun/ ()/ ->/ Array.set/ _/ (Z.to'_int/ _)/ _)"
   468 code_printing constant "HOL.equal :: 'a array \<Rightarrow> 'a array \<Rightarrow> bool" \<rightharpoonup> (OCaml) infixl 4 "="
   469 
   470 code_reserved OCaml Array
   471 
   472 
   473 text \<open>Haskell\<close>
   474 
   475 code_printing type_constructor array \<rightharpoonup> (Haskell) "Heap.STArray/ Heap.RealWorld/ _"
   476 code_printing constant Array \<rightharpoonup> (Haskell) "error/ \"bare Array\""
   477 code_printing constant Array.new' \<rightharpoonup> (Haskell) "Heap.newArray"
   478 code_printing constant Array.of_list \<rightharpoonup> (Haskell) "Heap.newListArray"
   479 code_printing constant Array.make' \<rightharpoonup> (Haskell) "Heap.newFunArray"
   480 code_printing constant Array.len' \<rightharpoonup> (Haskell) "Heap.lengthArray"
   481 code_printing constant Array.nth' \<rightharpoonup> (Haskell) "Heap.readArray"
   482 code_printing constant Array.upd' \<rightharpoonup> (Haskell) "Heap.writeArray"
   483 code_printing constant "HOL.equal :: 'a array \<Rightarrow> 'a array \<Rightarrow> bool" \<rightharpoonup> (Haskell) infix 4 "=="
   484 code_printing class_instance array :: HOL.equal \<rightharpoonup> (Haskell) -
   485 
   486 
   487 text \<open>Scala\<close>
   488 
   489 code_printing type_constructor array \<rightharpoonup> (Scala) "!collection.mutable.ArraySeq[_]"
   490 code_printing constant Array \<rightharpoonup> (Scala) "!sys.error(\"bare Array\")"
   491 code_printing constant Array.new' \<rightharpoonup> (Scala) "('_: Unit)/ => / Array.alloc((_))((_))"
   492 code_printing constant Array.make' \<rightharpoonup> (Scala) "('_: Unit)/ =>/ Array.make((_))((_))"
   493 code_printing constant Array.len' \<rightharpoonup> (Scala) "('_: Unit)/ =>/ Array.len((_))"
   494 code_printing constant Array.nth' \<rightharpoonup> (Scala) "('_: Unit)/ =>/ Array.nth((_), (_))"
   495 code_printing constant Array.upd' \<rightharpoonup> (Scala) "('_: Unit)/ =>/ Array.upd((_), (_), (_))"
   496 code_printing constant Array.freeze \<rightharpoonup> (Scala) "('_: Unit)/ =>/ Array.freeze((_))"
   497 code_printing constant "HOL.equal :: 'a array \<Rightarrow> 'a array \<Rightarrow> bool" \<rightharpoonup> (Scala) infixl 5 "=="
   498 
   499 end