src/HOL/Quickcheck_Exhaustive.thy
author bulwahn
Thu Jan 12 10:19:33 2012 +0100 (2012-01-12)
changeset 46193 55a4769d0abe
parent 45925 cd4243c025bb
child 46305 8ea02e499d53
permissions -rw-r--r--
adding exhaustive instances for type constructor set
     1 (* Author: Lukas Bulwahn, TU Muenchen *)
     2 
     3 header {* A simple counterexample generator performing exhaustive testing *}
     4 
     5 theory Quickcheck_Exhaustive
     6 imports Quickcheck
     7 uses
     8   ("Tools/Quickcheck/exhaustive_generators.ML")
     9   ("Tools/Quickcheck/abstract_generators.ML")
    10 begin
    11 
    12 subsection {* basic operations for exhaustive generators *}
    13 
    14 definition orelse :: "'a option => 'a option => 'a option" (infixr "orelse" 55)
    15 where
    16   [code_unfold]: "x orelse y = (case x of Some x' => Some x' | None => y)"
    17 
    18 subsection {* exhaustive generator type classes *}
    19 
    20 class exhaustive = term_of +
    21   fixes exhaustive :: "('a \<Rightarrow> (bool * term list) option) \<Rightarrow> code_numeral \<Rightarrow> (bool * term list) option"
    22   
    23 class full_exhaustive = term_of +
    24   fixes full_exhaustive :: "('a * (unit => term) \<Rightarrow> (bool * term list) option) \<Rightarrow> code_numeral \<Rightarrow> (bool * term list) option"
    25 
    26 instantiation code_numeral :: full_exhaustive
    27 begin
    28 
    29 function full_exhaustive_code_numeral' :: "(code_numeral * (unit => term) => (bool * term list) option) => code_numeral => code_numeral => (bool * term list) option"
    30   where "full_exhaustive_code_numeral' f d i =
    31     (if d < i then None
    32     else (f (i, %_. Code_Evaluation.term_of i)) orelse (full_exhaustive_code_numeral' f d (i + 1)))"
    33 by pat_completeness auto
    34 
    35 termination
    36   by (relation "measure (%(_, d, i). Code_Numeral.nat_of (d + 1 - i))") auto
    37 
    38 definition "full_exhaustive f d = full_exhaustive_code_numeral' f d 0"
    39 
    40 instance ..
    41 
    42 end
    43 
    44 instantiation code_numeral :: exhaustive
    45 begin
    46 
    47 function exhaustive_code_numeral' :: "(code_numeral => (bool * term list) option) => code_numeral => code_numeral => (bool * term list) option"
    48   where "exhaustive_code_numeral' f d i =
    49     (if d < i then None
    50     else (f i orelse exhaustive_code_numeral' f d (i + 1)))"
    51 by pat_completeness auto
    52 
    53 termination
    54   by (relation "measure (%(_, d, i). Code_Numeral.nat_of (d + 1 - i))") auto
    55 
    56 definition "exhaustive f d = exhaustive_code_numeral' f d 0"
    57 
    58 instance ..
    59 
    60 end
    61 
    62 instantiation nat :: exhaustive
    63 begin
    64 
    65 definition "exhaustive f d = exhaustive (%x. f (Code_Numeral.nat_of x)) d"
    66 
    67 instance ..
    68 
    69 end
    70 
    71 instantiation nat :: full_exhaustive
    72 begin
    73 
    74 definition "full_exhaustive f d = full_exhaustive (%(x, xt). f (Code_Numeral.nat_of x, %_. Code_Evaluation.term_of (Code_Numeral.nat_of x))) d"
    75 
    76 instance ..
    77 
    78 end
    79 
    80 instantiation int :: exhaustive
    81 begin
    82 
    83 function exhaustive' :: "(int => (bool * term list) option) => int => int => (bool * term list) option"
    84   where "exhaustive' f d i = (if d < i then None else (f i orelse exhaustive' f d (i + 1)))"
    85 by pat_completeness auto
    86 
    87 termination 
    88   by (relation "measure (%(_, d, i). nat (d + 1 - i))") auto
    89 
    90 definition "exhaustive f d = exhaustive' f (Code_Numeral.int_of d) (- (Code_Numeral.int_of d))"
    91 
    92 instance ..
    93 
    94 end
    95 
    96 instantiation int :: full_exhaustive
    97 begin
    98 
    99 function full_exhaustive' :: "(int * (unit => term) => (bool * term list) option) => int => int => (bool * term list) option"
   100   where "full_exhaustive' f d i = (if d < i then None else (case f (i, %_. Code_Evaluation.term_of i) of Some t => Some t | None => full_exhaustive' f d (i + 1)))"
   101 by pat_completeness auto
   102 
   103 termination 
   104   by (relation "measure (%(_, d, i). nat (d + 1 - i))") auto
   105 
   106 definition "full_exhaustive f d = full_exhaustive' f (Code_Numeral.int_of d) (- (Code_Numeral.int_of d))"
   107 
   108 instance ..
   109 
   110 end
   111 
   112 instantiation prod :: (exhaustive, exhaustive) exhaustive
   113 begin
   114 
   115 definition
   116   "exhaustive f d = exhaustive (%x. exhaustive (%y. f ((x, y))) d) d"
   117 
   118 instance ..
   119 
   120 end
   121 
   122 instantiation prod :: (full_exhaustive, full_exhaustive) full_exhaustive
   123 begin
   124 
   125 definition
   126   "full_exhaustive f d = full_exhaustive (%(x, t1). full_exhaustive (%(y, t2). f ((x, y),
   127     %u. let T1 = (Typerep.typerep (TYPE('a)));
   128             T2 = (Typerep.typerep (TYPE('b)))
   129     in Code_Evaluation.App (Code_Evaluation.App (
   130       Code_Evaluation.Const (STR ''Product_Type.Pair'') 
   131       (Typerep.Typerep (STR ''fun'') [T1, Typerep.Typerep (STR ''fun'') [T2, Typerep.Typerep (STR ''Product_Type.prod'') [T1, T2]]]))
   132       (t1 ())) (t2 ()))) d) d"
   133 
   134 instance ..
   135 
   136 end
   137 
   138 instantiation set :: (exhaustive) exhaustive
   139 begin
   140 
   141 fun exhaustive_set
   142 where
   143   "exhaustive_set f i = (if i = 0 then None else (f {} orelse exhaustive_set (%A. f A orelse Quickcheck_Exhaustive.exhaustive (%x. if x \<in> A then None else f (insert x A)) (i - 1)) (i - 1)))"
   144 
   145 instance ..
   146 
   147 end
   148 
   149 definition (in term_syntax) "valterm_emptyset = Code_Evaluation.valtermify ({} :: ('a :: typerep) set)"
   150 definition (in term_syntax) "valtermify_insert x s = Code_Evaluation.valtermify insert {\<cdot>} (x :: ('a :: typerep * _)) {\<cdot>} s"
   151 
   152 instantiation set :: (full_exhaustive) full_exhaustive
   153 begin
   154 
   155 fun full_exhaustive_set 
   156 where
   157   "full_exhaustive_set f i = (if i = 0 then None else (f valterm_emptyset orelse full_exhaustive_set (%A. f A orelse Quickcheck_Exhaustive.full_exhaustive (%x. if fst x \<in> fst A then None else f (valtermify_insert x A)) (i - 1)) (i - 1)))"
   158 
   159 instance ..
   160 
   161 end
   162 
   163 hide_const valterm_emptyset valtermify_insert
   164 
   165 instantiation "fun" :: ("{equal, exhaustive}", exhaustive) exhaustive
   166 begin
   167 
   168 fun exhaustive_fun' :: "(('a => 'b) => (bool * term list) option) => code_numeral => code_numeral => (bool * term list) option"
   169 where
   170   "exhaustive_fun' f i d = (exhaustive (%b. f (%_. b)) d)
   171    orelse (if i > 1 then
   172      exhaustive_fun' (%g. exhaustive (%a. exhaustive (%b.
   173        f (g(a := b))) d) d) (i - 1) d else None)"
   174 
   175 definition exhaustive_fun :: "(('a => 'b) => (bool * term list) option) => code_numeral => (bool * term list) option"
   176 where
   177   "exhaustive_fun f d = exhaustive_fun' f d d" 
   178 
   179 instance ..
   180 
   181 end
   182 
   183 instantiation "fun" :: ("{equal, full_exhaustive}", full_exhaustive) full_exhaustive
   184 begin
   185 
   186 fun full_exhaustive_fun' :: "(('a => 'b) * (unit => term) => (bool * term list) option) => code_numeral => code_numeral => (bool * term list) option"
   187 where
   188   "full_exhaustive_fun' f i d = (full_exhaustive (%(b, t). f (%_. b, %_. Code_Evaluation.Abs (STR ''x'') (Typerep.typerep TYPE('a)) (t ()))) d)
   189    orelse (if i > 1 then
   190      full_exhaustive_fun' (%(g, gt). full_exhaustive (%(a, at). full_exhaustive (%(b, bt).
   191        f (g(a := b),
   192          (%_. let A = (Typerep.typerep (TYPE('a)));
   193                   B = (Typerep.typerep (TYPE('b)));
   194                   fun = (%T U. Typerep.Typerep (STR ''fun'') [T, U])
   195               in
   196                 Code_Evaluation.App (Code_Evaluation.App (Code_Evaluation.App
   197                   (Code_Evaluation.Const (STR ''Fun.fun_upd'') (fun (fun A B) (fun A (fun B (fun A B)))))
   198                 (gt ())) (at ())) (bt ())))) d) d) (i - 1) d else None)"
   199 
   200 definition full_exhaustive_fun :: "(('a => 'b) * (unit => term) => (bool * term list) option) => code_numeral => (bool * term list) option"
   201 where
   202   "full_exhaustive_fun f d = full_exhaustive_fun' f d d" 
   203 
   204 instance ..
   205 
   206 end
   207 
   208 subsubsection {* A smarter enumeration scheme for functions over finite datatypes *}
   209 
   210 class check_all = enum + term_of +
   211   fixes check_all :: "('a * (unit \<Rightarrow> term) \<Rightarrow> (bool * term list) option) \<Rightarrow> (bool * term list) option"
   212   fixes enum_term_of :: "'a itself \<Rightarrow> unit \<Rightarrow> term list"
   213   
   214 fun check_all_n_lists :: "(('a :: check_all) list * (unit \<Rightarrow> term list) \<Rightarrow> (bool * term list) option) \<Rightarrow> code_numeral \<Rightarrow> (bool * term list) option"
   215 where
   216   "check_all_n_lists f n =
   217      (if n = 0 then f ([], (%_. [])) else check_all (%(x, xt). check_all_n_lists (%(xs, xst). f ((x # xs), (%_. (xt () # xst ())))) (n - 1)))"
   218 
   219 definition mk_map_term :: " (unit \<Rightarrow> typerep) \<Rightarrow> (unit \<Rightarrow> typerep) \<Rightarrow> (unit \<Rightarrow> term list) \<Rightarrow> (unit \<Rightarrow> term list) \<Rightarrow> unit \<Rightarrow> term"
   220 where
   221   "mk_map_term T1 T2 domm rng =
   222      (%_. let T1 = T1 ();
   223               T2 = T2 ();
   224               update_term = (%g (a, b).
   225                 Code_Evaluation.App (Code_Evaluation.App (Code_Evaluation.App
   226                  (Code_Evaluation.Const (STR ''Fun.fun_upd'')
   227                    (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''fun'') [T1, T2],
   228                       Typerep.Typerep (STR ''fun'') [T1,
   229                         Typerep.Typerep (STR ''fun'') [T2, Typerep.Typerep (STR ''fun'') [T1, T2]]]]))
   230                         g) a) b)
   231           in
   232              List.foldl update_term (Code_Evaluation.Abs (STR ''x'') T1 (Code_Evaluation.Const (STR ''HOL.undefined'') T2)) (zip (domm ()) (rng ())))"
   233 
   234 instantiation "fun" :: ("{equal, check_all}", check_all) check_all
   235 begin
   236 
   237 definition
   238   "check_all f =
   239     (let
   240       mk_term = mk_map_term (%_. Typerep.typerep (TYPE('a))) (%_. Typerep.typerep (TYPE('b))) (enum_term_of (TYPE('a)));
   241       enum = (Enum.enum :: 'a list)
   242     in check_all_n_lists (\<lambda>(ys, yst). f (the o map_of (zip enum ys), mk_term yst)) (Code_Numeral.of_nat (length enum)))"
   243 
   244 definition enum_term_of_fun :: "('a => 'b) itself => unit => term list"
   245 where
   246   "enum_term_of_fun = (%_ _. let
   247     enum_term_of_a = enum_term_of (TYPE('a));
   248     mk_term = mk_map_term (%_. Typerep.typerep (TYPE('a))) (%_. Typerep.typerep (TYPE('b))) enum_term_of_a
   249   in map (%ys. mk_term (%_. ys) ()) (Enum.n_lists (length (enum_term_of_a ())) (enum_term_of (TYPE('b)) ())))"
   250  
   251 instance ..
   252 
   253 end
   254 
   255 
   256 instantiation unit :: check_all
   257 begin
   258 
   259 definition
   260   "check_all f = f (Code_Evaluation.valtermify ())"
   261 
   262 definition enum_term_of_unit :: "unit itself => unit => term list"
   263 where
   264   "enum_term_of_unit = (%_ _. [Code_Evaluation.term_of ()])"
   265 
   266 instance ..
   267 
   268 end
   269 
   270 
   271 instantiation bool :: check_all
   272 begin
   273 
   274 definition
   275   "check_all f = (case f (Code_Evaluation.valtermify False) of Some x' \<Rightarrow> Some x' | None \<Rightarrow> f (Code_Evaluation.valtermify True))"
   276 
   277 definition enum_term_of_bool :: "bool itself => unit => term list"
   278 where
   279   "enum_term_of_bool = (%_ _. map Code_Evaluation.term_of (Enum.enum :: bool list))"
   280 
   281 instance ..
   282 
   283 end
   284 
   285 
   286 instantiation prod :: (check_all, check_all) check_all
   287 begin
   288 
   289 definition
   290   "check_all f = check_all (%(x, t1). check_all (%(y, t2). f ((x, y),
   291     %u. let T1 = (Typerep.typerep (TYPE('a)));
   292             T2 = (Typerep.typerep (TYPE('b)))
   293     in Code_Evaluation.App (Code_Evaluation.App (
   294       Code_Evaluation.Const (STR ''Product_Type.Pair'') 
   295       (Typerep.Typerep (STR ''fun'') [T1, Typerep.Typerep (STR ''fun'') [T2, Typerep.Typerep (STR ''Product_Type.prod'') [T1, T2]]]))
   296       (t1 ())) (t2 ()))))"
   297 
   298 definition enum_term_of_prod :: "('a * 'b) itself => unit => term list"
   299 where
   300   "enum_term_of_prod = (%_ _. map (%(x, y).
   301        let T1 = (Typerep.typerep (TYPE('a)));
   302            T2 = (Typerep.typerep (TYPE('b)))
   303        in Code_Evaluation.App (Code_Evaluation.App (
   304          Code_Evaluation.Const (STR ''Product_Type.Pair'') 
   305            (Typerep.Typerep (STR ''fun'') [T1, Typerep.Typerep (STR ''fun'') [T2, Typerep.Typerep (STR ''Product_Type.prod'') [T1, T2]]])) x) y)
   306      (Enum.product (enum_term_of (TYPE('a)) ()) (enum_term_of (TYPE('b)) ())))  "
   307 
   308 instance ..
   309 
   310 end
   311 
   312 
   313 instantiation sum :: (check_all, check_all) check_all
   314 begin
   315 
   316 definition
   317   "check_all f = (case check_all (%(a, t). f (Inl a, %_. 
   318      let T1 = (Typerep.typerep (TYPE('a)));
   319          T2 = (Typerep.typerep (TYPE('b)))
   320        in Code_Evaluation.App (Code_Evaluation.Const (STR ''Sum_Type.Inl'') 
   321            (Typerep.Typerep (STR ''fun'') [T1, Typerep.Typerep (STR ''Sum_Type.sum'') [T1, T2]])) (t ()))) of Some x' => Some x'
   322              | None => check_all (%(b, t). f (Inr b, %_. let
   323                  T1 = (Typerep.typerep (TYPE('a)));
   324                  T2 = (Typerep.typerep (TYPE('b)))
   325                in Code_Evaluation.App (Code_Evaluation.Const (STR ''Sum_Type.Inr'') 
   326                  (Typerep.Typerep (STR ''fun'') [T2, Typerep.Typerep (STR ''Sum_Type.sum'') [T1, T2]])) (t ()))))"
   327 
   328 definition enum_term_of_sum :: "('a + 'b) itself => unit => term list"
   329 where
   330   "enum_term_of_sum = (%_ _.
   331      let
   332        T1 = (Typerep.typerep (TYPE('a)));
   333        T2 = (Typerep.typerep (TYPE('b)))
   334      in
   335        map (Code_Evaluation.App (Code_Evaluation.Const (STR ''Sum_Type.Inl'') 
   336              (Typerep.Typerep (STR ''fun'') [T1, Typerep.Typerep (STR ''Sum_Type.sum'') [T1, T2]])))
   337              (enum_term_of (TYPE('a)) ()) @
   338        map (Code_Evaluation.App (Code_Evaluation.Const (STR ''Sum_Type.Inr'') 
   339              (Typerep.Typerep (STR ''fun'') [T2, Typerep.Typerep (STR ''Sum_Type.sum'') [T1, T2]])))
   340              (enum_term_of (TYPE('b)) ()))"
   341 
   342 instance ..
   343 
   344 end
   345 
   346 instantiation nibble :: check_all
   347 begin
   348 
   349 definition
   350   "check_all f =
   351     f (Code_Evaluation.valtermify Nibble0) orelse
   352     f (Code_Evaluation.valtermify Nibble1) orelse
   353     f (Code_Evaluation.valtermify Nibble2) orelse
   354     f (Code_Evaluation.valtermify Nibble3) orelse
   355     f (Code_Evaluation.valtermify Nibble4) orelse
   356     f (Code_Evaluation.valtermify Nibble5) orelse
   357     f (Code_Evaluation.valtermify Nibble6) orelse
   358     f (Code_Evaluation.valtermify Nibble7) orelse
   359     f (Code_Evaluation.valtermify Nibble8) orelse
   360     f (Code_Evaluation.valtermify Nibble9) orelse
   361     f (Code_Evaluation.valtermify NibbleA) orelse
   362     f (Code_Evaluation.valtermify NibbleB) orelse
   363     f (Code_Evaluation.valtermify NibbleC) orelse
   364     f (Code_Evaluation.valtermify NibbleD) orelse
   365     f (Code_Evaluation.valtermify NibbleE) orelse
   366     f (Code_Evaluation.valtermify NibbleF)"
   367 
   368 definition enum_term_of_nibble :: "nibble itself => unit => term list"
   369 where
   370   "enum_term_of_nibble = (%_ _. map Code_Evaluation.term_of (Enum.enum :: nibble list))"
   371 
   372 instance ..
   373 
   374 end
   375 
   376 
   377 instantiation char :: check_all
   378 begin
   379 
   380 definition
   381   "check_all f = check_all (%(x, t1). check_all (%(y, t2). f (Char x y, %_. Code_Evaluation.App (Code_Evaluation.App (Code_Evaluation.term_of Char) (t1 ())) (t2 ()))))"
   382 
   383 definition enum_term_of_char :: "char itself => unit => term list"
   384 where
   385   "enum_term_of_char = (%_ _. map Code_Evaluation.term_of (Enum.enum :: char list))"
   386 
   387 instance ..
   388 
   389 end
   390 
   391 
   392 instantiation option :: (check_all) check_all
   393 begin
   394 
   395 definition
   396   "check_all f = f (Code_Evaluation.valtermify (None :: 'a option)) orelse check_all (%(x, t). f (Some x, %_. Code_Evaluation.App
   397     (Code_Evaluation.Const (STR ''Option.option.Some'')
   398       (Typerep.Typerep (STR ''fun'') [Typerep.typerep TYPE('a),  Typerep.Typerep (STR ''Option.option'') [Typerep.typerep TYPE('a)]])) (t ())))"
   399 
   400 definition enum_term_of_option :: "'a option itself => unit => term list"
   401 where
   402   "enum_term_of_option = (% _ _. (Code_Evaluation.term_of (None :: 'a option)) # (map (Code_Evaluation.App (Code_Evaluation.Const (STR ''Option.option.Some'')
   403       (Typerep.Typerep (STR ''fun'') [Typerep.typerep TYPE('a),  Typerep.Typerep (STR ''Option.option'') [Typerep.typerep TYPE('a)]]))) (enum_term_of (TYPE('a)) ())))"
   404 
   405 instance ..
   406 
   407 end
   408 
   409 
   410 instantiation Enum.finite_1 :: check_all
   411 begin
   412 
   413 definition
   414   "check_all f = f (Code_Evaluation.valtermify Enum.finite_1.a\<^isub>1)"
   415 
   416 definition enum_term_of_finite_1 :: "Enum.finite_1 itself => unit => term list"
   417 where
   418   "enum_term_of_finite_1 = (%_ _. [Code_Evaluation.term_of Enum.finite_1.a\<^isub>1])"
   419 
   420 instance ..
   421 
   422 end
   423 
   424 instantiation Enum.finite_2 :: check_all
   425 begin
   426 
   427 definition
   428   "check_all f = (case f (Code_Evaluation.valtermify Enum.finite_2.a\<^isub>1) of Some x' \<Rightarrow> Some x' | None \<Rightarrow> f (Code_Evaluation.valtermify Enum.finite_2.a\<^isub>2))"
   429 
   430 definition enum_term_of_finite_2 :: "Enum.finite_2 itself => unit => term list"
   431 where
   432   "enum_term_of_finite_2 = (%_ _. map Code_Evaluation.term_of (Enum.enum :: Enum.finite_2 list))"
   433 
   434 instance ..
   435 
   436 end
   437 
   438 instantiation Enum.finite_3 :: check_all
   439 begin
   440 
   441 definition
   442   "check_all f = (case f (Code_Evaluation.valtermify Enum.finite_3.a\<^isub>1) of Some x' \<Rightarrow> Some x' | None \<Rightarrow> (case f (Code_Evaluation.valtermify Enum.finite_3.a\<^isub>2) of Some x' \<Rightarrow> Some x' | None \<Rightarrow> f (Code_Evaluation.valtermify Enum.finite_3.a\<^isub>3)))"
   443 
   444 definition enum_term_of_finite_3 :: "Enum.finite_3 itself => unit => term list"
   445 where
   446   "enum_term_of_finite_3 = (%_ _. map Code_Evaluation.term_of (Enum.enum :: Enum.finite_3 list))"
   447 
   448 instance ..
   449 
   450 end
   451 
   452 subsection {* Bounded universal quantifiers *}
   453 
   454 class bounded_forall =
   455   fixes bounded_forall :: "('a \<Rightarrow> bool) \<Rightarrow> code_numeral \<Rightarrow> bool"
   456 
   457 subsection {* Fast exhaustive combinators *}
   458 
   459 class fast_exhaustive = term_of +
   460   fixes fast_exhaustive :: "('a \<Rightarrow> unit) \<Rightarrow> code_numeral \<Rightarrow> unit"
   461 
   462 axiomatization throw_Counterexample :: "term list => unit"
   463 axiomatization catch_Counterexample :: "unit => term list option"
   464 
   465 code_const throw_Counterexample
   466   (Quickcheck "raise (Exhaustive'_Generators.Counterexample _)")
   467 code_const catch_Counterexample
   468   (Quickcheck "(((_); NONE) handle Exhaustive'_Generators.Counterexample ts => SOME ts)")
   469 
   470 subsection {* Continuation passing style functions as plus monad *}
   471   
   472 type_synonym 'a cps = "('a => term list option) => term list option"
   473 
   474 definition cps_empty :: "'a cps"
   475 where
   476   "cps_empty = (%cont. None)"
   477 
   478 definition cps_single :: "'a => 'a cps"
   479 where
   480   "cps_single v = (%cont. cont v)"
   481 
   482 definition cps_bind :: "'a cps => ('a => 'b cps) => 'b cps" 
   483 where
   484   "cps_bind m f = (%cont. m (%a. (f a) cont))"
   485 
   486 definition cps_plus :: "'a cps => 'a cps => 'a cps"
   487 where
   488   "cps_plus a b = (%c. case a c of None => b c | Some x => Some x)"
   489 
   490 definition cps_if :: "bool => unit cps"
   491 where
   492   "cps_if b = (if b then cps_single () else cps_empty)"
   493 
   494 definition cps_not :: "unit cps => unit cps"
   495 where
   496   "cps_not n = (%c. case n (%u. Some []) of None => c () | Some _ => None)"
   497 
   498 type_synonym 'a pos_bound_cps = "('a => (bool * term list) option) => code_numeral => (bool * term list) option"
   499 
   500 definition pos_bound_cps_empty :: "'a pos_bound_cps"
   501 where
   502   "pos_bound_cps_empty = (%cont i. None)"
   503 
   504 definition pos_bound_cps_single :: "'a => 'a pos_bound_cps"
   505 where
   506   "pos_bound_cps_single v = (%cont i. cont v)"
   507 
   508 definition pos_bound_cps_bind :: "'a pos_bound_cps => ('a => 'b pos_bound_cps) => 'b pos_bound_cps" 
   509 where
   510   "pos_bound_cps_bind m f = (%cont i. if i = 0 then None else (m (%a. (f a) cont i) (i - 1)))"
   511 
   512 definition pos_bound_cps_plus :: "'a pos_bound_cps => 'a pos_bound_cps => 'a pos_bound_cps"
   513 where
   514   "pos_bound_cps_plus a b = (%c i. case a c i of None => b c i | Some x => Some x)"
   515 
   516 definition pos_bound_cps_if :: "bool => unit pos_bound_cps"
   517 where
   518   "pos_bound_cps_if b = (if b then pos_bound_cps_single () else pos_bound_cps_empty)"
   519 
   520 datatype 'a unknown = Unknown | Known 'a
   521 datatype 'a three_valued = Unknown_value | Value 'a | No_value
   522 
   523 type_synonym 'a neg_bound_cps = "('a unknown => term list three_valued) => code_numeral => term list three_valued"
   524 
   525 definition neg_bound_cps_empty :: "'a neg_bound_cps"
   526 where
   527   "neg_bound_cps_empty = (%cont i. No_value)"
   528 
   529 definition neg_bound_cps_single :: "'a => 'a neg_bound_cps"
   530 where
   531   "neg_bound_cps_single v = (%cont i. cont (Known v))"
   532 
   533 definition neg_bound_cps_bind :: "'a neg_bound_cps => ('a => 'b neg_bound_cps) => 'b neg_bound_cps" 
   534 where
   535   "neg_bound_cps_bind m f = (%cont i. if i = 0 then cont Unknown else m (%a. case a of Unknown => cont Unknown | Known a' => f a' cont i) (i - 1))"
   536 
   537 definition neg_bound_cps_plus :: "'a neg_bound_cps => 'a neg_bound_cps => 'a neg_bound_cps"
   538 where
   539   "neg_bound_cps_plus a b = (%c i. case a c i of No_value => b c i | Value x => Value x | Unknown_value => (case b c i of No_value => Unknown_value | Value x => Value x | Unknown_value => Unknown_value))"
   540 
   541 definition neg_bound_cps_if :: "bool => unit neg_bound_cps"
   542 where
   543   "neg_bound_cps_if b = (if b then neg_bound_cps_single () else neg_bound_cps_empty)"
   544 
   545 definition neg_bound_cps_not :: "unit pos_bound_cps => unit neg_bound_cps"
   546 where
   547   "neg_bound_cps_not n = (%c i. case n (%u. Some (True, [])) i of None => c (Known ()) | Some _ => No_value)"
   548 
   549 definition pos_bound_cps_not :: "unit neg_bound_cps => unit pos_bound_cps"
   550 where
   551   "pos_bound_cps_not n = (%c i. case n (%u. Value []) i of No_value => c () | Value _ => None | Unknown_value => None)"
   552 
   553 subsection {* Defining generators for any first-order data type *}
   554 
   555 axiomatization unknown :: 'a
   556 
   557 notation (output) unknown  ("?")
   558  
   559 use "Tools/Quickcheck/exhaustive_generators.ML"
   560 
   561 setup {* Exhaustive_Generators.setup *}
   562 
   563 declare [[quickcheck_batch_tester = exhaustive]]
   564 
   565 subsection {* Defining generators for abstract types *}
   566 
   567 use "Tools/Quickcheck/abstract_generators.ML"
   568 
   569 hide_fact orelse_def
   570 no_notation orelse (infixr "orelse" 55)
   571 
   572 hide_fact
   573   exhaustive'_def
   574   exhaustive_code_numeral'_def
   575 
   576 hide_const (open)
   577   exhaustive full_exhaustive exhaustive' exhaustive_code_numeral' full_exhaustive_code_numeral'
   578   throw_Counterexample catch_Counterexample
   579   check_all enum_term_of
   580   orelse unknown mk_map_term check_all_n_lists
   581 
   582 hide_type (open) cps pos_bound_cps neg_bound_cps unknown three_valued
   583 hide_const (open) cps_empty cps_single cps_bind cps_plus cps_if cps_not
   584   pos_bound_cps_empty pos_bound_cps_single pos_bound_cps_bind pos_bound_cps_plus pos_bound_cps_if pos_bound_cps_not
   585   neg_bound_cps_empty neg_bound_cps_single neg_bound_cps_bind neg_bound_cps_plus neg_bound_cps_if neg_bound_cps_not
   586   Unknown Known Unknown_value Value No_value
   587 
   588 end