src/HOL/Inductive.thy
 author haftmann Sat Sep 10 10:29:24 2011 +0200 (2011-09-10) changeset 44860 56101fa00193 parent 43580 023a1d1f97bd child 45890 5f70aaecae26 permissions -rw-r--r--
renamed theory Complete_Lattice to Complete_Lattices, in accordance with Lattices, Orderings etc.
1 (*  Title:      HOL/Inductive.thy
2     Author:     Markus Wenzel, TU Muenchen
3 *)
5 header {* Knaster-Tarski Fixpoint Theorem and inductive definitions *}
7 theory Inductive
8 imports Complete_Lattices
9 uses
10   ("Tools/inductive.ML")
11   "Tools/dseq.ML"
12   "Tools/Datatype/datatype_aux.ML"
13   "Tools/Datatype/datatype_prop.ML"
14   "Tools/Datatype/datatype_case.ML"
15   ("Tools/Datatype/datatype_abs_proofs.ML")
16   ("Tools/Datatype/datatype_data.ML")
17   ("Tools/primrec.ML")
18   ("Tools/Datatype/datatype_codegen.ML")
19 begin
21 subsection {* Least and greatest fixed points *}
23 context complete_lattice
24 begin
26 definition
27   lfp :: "('a \<Rightarrow> 'a) \<Rightarrow> 'a" where
28   "lfp f = Inf {u. f u \<le> u}"    --{*least fixed point*}
30 definition
31   gfp :: "('a \<Rightarrow> 'a) \<Rightarrow> 'a" where
32   "gfp f = Sup {u. u \<le> f u}"    --{*greatest fixed point*}
35 subsection{* Proof of Knaster-Tarski Theorem using @{term lfp} *}
37 text{*@{term "lfp f"} is the least upper bound of
38       the set @{term "{u. f(u) \<le> u}"} *}
40 lemma lfp_lowerbound: "f A \<le> A ==> lfp f \<le> A"
41   by (auto simp add: lfp_def intro: Inf_lower)
43 lemma lfp_greatest: "(!!u. f u \<le> u ==> A \<le> u) ==> A \<le> lfp f"
44   by (auto simp add: lfp_def intro: Inf_greatest)
46 end
48 lemma lfp_lemma2: "mono f ==> f (lfp f) \<le> lfp f"
49   by (iprover intro: lfp_greatest order_trans monoD lfp_lowerbound)
51 lemma lfp_lemma3: "mono f ==> lfp f \<le> f (lfp f)"
52   by (iprover intro: lfp_lemma2 monoD lfp_lowerbound)
54 lemma lfp_unfold: "mono f ==> lfp f = f (lfp f)"
55   by (iprover intro: order_antisym lfp_lemma2 lfp_lemma3)
57 lemma lfp_const: "lfp (\<lambda>x. t) = t"
58   by (rule lfp_unfold) (simp add:mono_def)
61 subsection {* General induction rules for least fixed points *}
63 theorem lfp_induct:
64   assumes mono: "mono f" and ind: "f (inf (lfp f) P) <= P"
65   shows "lfp f <= P"
66 proof -
67   have "inf (lfp f) P <= lfp f" by (rule inf_le1)
68   with mono have "f (inf (lfp f) P) <= f (lfp f)" ..
69   also from mono have "f (lfp f) = lfp f" by (rule lfp_unfold [symmetric])
70   finally have "f (inf (lfp f) P) <= lfp f" .
71   from this and ind have "f (inf (lfp f) P) <= inf (lfp f) P" by (rule le_infI)
72   hence "lfp f <= inf (lfp f) P" by (rule lfp_lowerbound)
73   also have "inf (lfp f) P <= P" by (rule inf_le2)
74   finally show ?thesis .
75 qed
77 lemma lfp_induct_set:
78   assumes lfp: "a: lfp(f)"
79       and mono: "mono(f)"
80       and indhyp: "!!x. [| x: f(lfp(f) Int {x. P(x)}) |] ==> P(x)"
81   shows "P(a)"
82   by (rule lfp_induct [THEN subsetD, THEN CollectD, OF mono _ lfp])
83     (auto simp: intro: indhyp)
85 lemma lfp_ordinal_induct:
86   fixes f :: "'a\<Colon>complete_lattice \<Rightarrow> 'a"
87   assumes mono: "mono f"
88   and P_f: "\<And>S. P S \<Longrightarrow> P (f S)"
89   and P_Union: "\<And>M. \<forall>S\<in>M. P S \<Longrightarrow> P (Sup M)"
90   shows "P (lfp f)"
91 proof -
92   let ?M = "{S. S \<le> lfp f \<and> P S}"
93   have "P (Sup ?M)" using P_Union by simp
94   also have "Sup ?M = lfp f"
95   proof (rule antisym)
96     show "Sup ?M \<le> lfp f" by (blast intro: Sup_least)
97     hence "f (Sup ?M) \<le> f (lfp f)" by (rule mono [THEN monoD])
98     hence "f (Sup ?M) \<le> lfp f" using mono [THEN lfp_unfold] by simp
99     hence "f (Sup ?M) \<in> ?M" using P_f P_Union by simp
100     hence "f (Sup ?M) \<le> Sup ?M" by (rule Sup_upper)
101     thus "lfp f \<le> Sup ?M" by (rule lfp_lowerbound)
102   qed
103   finally show ?thesis .
104 qed
106 lemma lfp_ordinal_induct_set:
107   assumes mono: "mono f"
108   and P_f: "!!S. P S ==> P(f S)"
109   and P_Union: "!!M. !S:M. P S ==> P(Union M)"
110   shows "P(lfp f)"
111   using assms by (rule lfp_ordinal_induct [where P=P])
114 text{*Definition forms of @{text lfp_unfold} and @{text lfp_induct},
115     to control unfolding*}
117 lemma def_lfp_unfold: "[| h==lfp(f);  mono(f) |] ==> h = f(h)"
118 by (auto intro!: lfp_unfold)
120 lemma def_lfp_induct:
121     "[| A == lfp(f); mono(f);
122         f (inf A P) \<le> P
123      |] ==> A \<le> P"
124   by (blast intro: lfp_induct)
126 lemma def_lfp_induct_set:
127     "[| A == lfp(f);  mono(f);   a:A;
128         !!x. [| x: f(A Int {x. P(x)}) |] ==> P(x)
129      |] ==> P(a)"
130   by (blast intro: lfp_induct_set)
132 (*Monotonicity of lfp!*)
133 lemma lfp_mono: "(!!Z. f Z \<le> g Z) ==> lfp f \<le> lfp g"
134   by (rule lfp_lowerbound [THEN lfp_greatest], blast intro: order_trans)
137 subsection {* Proof of Knaster-Tarski Theorem using @{term gfp} *}
139 text{*@{term "gfp f"} is the greatest lower bound of
140       the set @{term "{u. u \<le> f(u)}"} *}
142 lemma gfp_upperbound: "X \<le> f X ==> X \<le> gfp f"
143   by (auto simp add: gfp_def intro: Sup_upper)
145 lemma gfp_least: "(!!u. u \<le> f u ==> u \<le> X) ==> gfp f \<le> X"
146   by (auto simp add: gfp_def intro: Sup_least)
148 lemma gfp_lemma2: "mono f ==> gfp f \<le> f (gfp f)"
149   by (iprover intro: gfp_least order_trans monoD gfp_upperbound)
151 lemma gfp_lemma3: "mono f ==> f (gfp f) \<le> gfp f"
152   by (iprover intro: gfp_lemma2 monoD gfp_upperbound)
154 lemma gfp_unfold: "mono f ==> gfp f = f (gfp f)"
155   by (iprover intro: order_antisym gfp_lemma2 gfp_lemma3)
158 subsection {* Coinduction rules for greatest fixed points *}
160 text{*weak version*}
161 lemma weak_coinduct: "[| a: X;  X \<subseteq> f(X) |] ==> a : gfp(f)"
162 by (rule gfp_upperbound [THEN subsetD], auto)
164 lemma weak_coinduct_image: "!!X. [| a : X; g`X \<subseteq> f (g`X) |] ==> g a : gfp f"
165 apply (erule gfp_upperbound [THEN subsetD])
166 apply (erule imageI)
167 done
169 lemma coinduct_lemma:
170      "[| X \<le> f (sup X (gfp f));  mono f |] ==> sup X (gfp f) \<le> f (sup X (gfp f))"
171   apply (frule gfp_lemma2)
172   apply (drule mono_sup)
173   apply (rule le_supI)
174   apply assumption
175   apply (rule order_trans)
176   apply (rule order_trans)
177   apply assumption
178   apply (rule sup_ge2)
179   apply assumption
180   done
182 text{*strong version, thanks to Coen and Frost*}
183 lemma coinduct_set: "[| mono(f);  a: X;  X \<subseteq> f(X Un gfp(f)) |] ==> a : gfp(f)"
184 by (blast intro: weak_coinduct [OF _ coinduct_lemma])
186 lemma coinduct: "[| mono(f); X \<le> f (sup X (gfp f)) |] ==> X \<le> gfp(f)"
187   apply (rule order_trans)
188   apply (rule sup_ge1)
189   apply (erule gfp_upperbound [OF coinduct_lemma])
190   apply assumption
191   done
193 lemma gfp_fun_UnI2: "[| mono(f);  a: gfp(f) |] ==> a: f(X Un gfp(f))"
194 by (blast dest: gfp_lemma2 mono_Un)
197 subsection {* Even Stronger Coinduction Rule, by Martin Coen *}
199 text{* Weakens the condition @{term "X \<subseteq> f(X)"} to one expressed using both
200   @{term lfp} and @{term gfp}*}
202 lemma coinduct3_mono_lemma: "mono(f) ==> mono(%x. f(x) Un X Un B)"
203 by (iprover intro: subset_refl monoI Un_mono monoD)
205 lemma coinduct3_lemma:
206      "[| X \<subseteq> f(lfp(%x. f(x) Un X Un gfp(f)));  mono(f) |]
207       ==> lfp(%x. f(x) Un X Un gfp(f)) \<subseteq> f(lfp(%x. f(x) Un X Un gfp(f)))"
208 apply (rule subset_trans)
209 apply (erule coinduct3_mono_lemma [THEN lfp_lemma3])
210 apply (rule Un_least [THEN Un_least])
211 apply (rule subset_refl, assumption)
212 apply (rule gfp_unfold [THEN equalityD1, THEN subset_trans], assumption)
213 apply (rule monoD [where f=f], assumption)
214 apply (subst coinduct3_mono_lemma [THEN lfp_unfold], auto)
215 done
217 lemma coinduct3:
218   "[| mono(f);  a:X;  X \<subseteq> f(lfp(%x. f(x) Un X Un gfp(f))) |] ==> a : gfp(f)"
219 apply (rule coinduct3_lemma [THEN  weak_coinduct])
220 apply (rule coinduct3_mono_lemma [THEN lfp_unfold, THEN ssubst])
221 apply (simp_all)
222 done
225 text{*Definition forms of @{text gfp_unfold} and @{text coinduct},
226     to control unfolding*}
228 lemma def_gfp_unfold: "[| A==gfp(f);  mono(f) |] ==> A = f(A)"
229 by (auto intro!: gfp_unfold)
231 lemma def_coinduct:
232      "[| A==gfp(f);  mono(f);  X \<le> f(sup X A) |] ==> X \<le> A"
233 by (iprover intro!: coinduct)
235 lemma def_coinduct_set:
236      "[| A==gfp(f);  mono(f);  a:X;  X \<subseteq> f(X Un A) |] ==> a: A"
237 by (auto intro!: coinduct_set)
239 (*The version used in the induction/coinduction package*)
240 lemma def_Collect_coinduct:
241     "[| A == gfp(%w. Collect(P(w)));  mono(%w. Collect(P(w)));
242         a: X;  !!z. z: X ==> P (X Un A) z |] ==>
243      a : A"
244 apply (erule def_coinduct_set, auto)
245 done
247 lemma def_coinduct3:
248     "[| A==gfp(f); mono(f);  a:X;  X \<subseteq> f(lfp(%x. f(x) Un X Un A)) |] ==> a: A"
249 by (auto intro!: coinduct3)
251 text{*Monotonicity of @{term gfp}!*}
252 lemma gfp_mono: "(!!Z. f Z \<le> g Z) ==> gfp f \<le> gfp g"
253   by (rule gfp_upperbound [THEN gfp_least], blast intro: order_trans)
256 subsection {* Inductive predicates and sets *}
258 text {* Package setup. *}
260 theorems basic_monos =
261   subset_refl imp_refl disj_mono conj_mono ex_mono all_mono if_bool_eq_conj
262   Collect_mono in_mono vimage_mono
264 use "Tools/inductive.ML"
265 setup Inductive.setup
267 theorems [mono] =
268   imp_refl disj_mono conj_mono ex_mono all_mono if_bool_eq_conj
269   imp_mono not_mono
270   Ball_def Bex_def
271   induct_rulify_fallback
274 subsection {* Inductive datatypes and primitive recursion *}
276 text {* Package setup. *}
278 use "Tools/Datatype/datatype_abs_proofs.ML"
279 use "Tools/Datatype/datatype_data.ML"
280 setup Datatype_Data.setup
282 use "Tools/Datatype/datatype_codegen.ML"
283 setup Datatype_Codegen.setup
285 use "Tools/primrec.ML"
287 text{* Lambda-abstractions with pattern matching: *}
289 syntax
290   "_lam_pats_syntax" :: "cases_syn => 'a => 'b"               ("(%_)" 10)
291 syntax (xsymbols)
292   "_lam_pats_syntax" :: "cases_syn => 'a => 'b"               ("(\<lambda>_)" 10)
294 parse_translation (advanced) {*
295 let
296   fun fun_tr ctxt [cs] =
297     let
298       (* FIXME proper name context!? *)
299       val x = Free (singleton (Name.variant_list (Term.add_free_names cs [])) "x", dummyT);
300       val ft = Datatype_Case.case_tr true Datatype_Data.info_of_constr_permissive ctxt [x, cs];
301     in lambda x ft end
302 in [(@{syntax_const "_lam_pats_syntax"}, fun_tr)] end
303 *}
305 end