src/HOL/Typedef.thy
 author haftmann Wed Jan 21 23:40:23 2009 +0100 (2009-01-21) changeset 29608 564ea783ace8 parent 29056 dc08e3990c77 child 29797 08ef36ed2f8a permissions -rw-r--r--
no base sort in class import
1 (*  Title:      HOL/Typedef.thy
2     Author:     Markus Wenzel, TU Munich
3 *)
5 header {* HOL type definitions *}
7 theory Typedef
8 imports Set
9 uses
10   ("Tools/typedef_package.ML")
11   ("Tools/typecopy_package.ML")
12   ("Tools/typedef_codegen.ML")
13 begin
15 ML {*
16 structure HOL = struct val thy = theory "HOL" end;
17 *}  -- "belongs to theory HOL"
19 locale type_definition =
20   fixes Rep and Abs and A
21   assumes Rep: "Rep x \<in> A"
22     and Rep_inverse: "Abs (Rep x) = x"
23     and Abs_inverse: "y \<in> A ==> Rep (Abs y) = y"
24   -- {* This will be axiomatized for each typedef! *}
25 begin
27 lemma Rep_inject:
28   "(Rep x = Rep y) = (x = y)"
29 proof
30   assume "Rep x = Rep y"
31   then have "Abs (Rep x) = Abs (Rep y)" by (simp only:)
32   moreover have "Abs (Rep x) = x" by (rule Rep_inverse)
33   moreover have "Abs (Rep y) = y" by (rule Rep_inverse)
34   ultimately show "x = y" by simp
35 next
36   assume "x = y"
37   thus "Rep x = Rep y" by (simp only:)
38 qed
40 lemma Abs_inject:
41   assumes x: "x \<in> A" and y: "y \<in> A"
42   shows "(Abs x = Abs y) = (x = y)"
43 proof
44   assume "Abs x = Abs y"
45   then have "Rep (Abs x) = Rep (Abs y)" by (simp only:)
46   moreover from x have "Rep (Abs x) = x" by (rule Abs_inverse)
47   moreover from y have "Rep (Abs y) = y" by (rule Abs_inverse)
48   ultimately show "x = y" by simp
49 next
50   assume "x = y"
51   thus "Abs x = Abs y" by (simp only:)
52 qed
54 lemma Rep_cases [cases set]:
55   assumes y: "y \<in> A"
56     and hyp: "!!x. y = Rep x ==> P"
57   shows P
58 proof (rule hyp)
59   from y have "Rep (Abs y) = y" by (rule Abs_inverse)
60   thus "y = Rep (Abs y)" ..
61 qed
63 lemma Abs_cases [cases type]:
64   assumes r: "!!y. x = Abs y ==> y \<in> A ==> P"
65   shows P
66 proof (rule r)
67   have "Abs (Rep x) = x" by (rule Rep_inverse)
68   thus "x = Abs (Rep x)" ..
69   show "Rep x \<in> A" by (rule Rep)
70 qed
72 lemma Rep_induct [induct set]:
73   assumes y: "y \<in> A"
74     and hyp: "!!x. P (Rep x)"
75   shows "P y"
76 proof -
77   have "P (Rep (Abs y))" by (rule hyp)
78   moreover from y have "Rep (Abs y) = y" by (rule Abs_inverse)
79   ultimately show "P y" by simp
80 qed
82 lemma Abs_induct [induct type]:
83   assumes r: "!!y. y \<in> A ==> P (Abs y)"
84   shows "P x"
85 proof -
86   have "Rep x \<in> A" by (rule Rep)
87   then have "P (Abs (Rep x))" by (rule r)
88   moreover have "Abs (Rep x) = x" by (rule Rep_inverse)
89   ultimately show "P x" by simp
90 qed
92 lemma Rep_range: "range Rep = A"
93 proof
94   show "range Rep <= A" using Rep by (auto simp add: image_def)
95   show "A <= range Rep"
96   proof
97     fix x assume "x : A"
98     hence "x = Rep (Abs x)" by (rule Abs_inverse [symmetric])
99     thus "x : range Rep" by (rule range_eqI)
100   qed
101 qed
103 lemma Abs_image: "Abs ` A = UNIV"
104 proof
105   show "Abs ` A <= UNIV" by (rule subset_UNIV)
106 next
107   show "UNIV <= Abs ` A"
108   proof
109     fix x
110     have "x = Abs (Rep x)" by (rule Rep_inverse [symmetric])
111     moreover have "Rep x : A" by (rule Rep)
112     ultimately show "x : Abs ` A" by (rule image_eqI)
113   qed
114 qed
116 end
118 use "Tools/typedef_package.ML" setup TypedefPackage.setup
119 use "Tools/typecopy_package.ML" setup TypecopyPackage.setup
120 use "Tools/typedef_codegen.ML" setup TypedefCodegen.setup
123 text {* This class is just a workaround for classes without parameters;
124   it shall disappear as soon as possible. *}
126 class itself =
127   fixes itself :: "'a itself"
129 setup {*
130 let fun add_itself tyco thy =
131   let
132     val vs = Name.names Name.context "'a"
133       (replicate (Sign.arity_number thy tyco) @{sort type});
134     val ty = Type (tyco, map TFree vs);
135     val lhs = Const (@{const_name itself}, Term.itselfT ty);
136     val rhs = Logic.mk_type ty;
137     val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs));
138   in
139     thy
140     |> TheoryTarget.instantiation ([tyco], vs, @{sort itself})
141     |> `(fn lthy => Syntax.check_term lthy eq)
142     |-> (fn eq => Specification.definition (NONE, (Attrib.empty_binding, eq)))
143     |> snd
144     |> Class.prove_instantiation_instance (K (Class.intro_classes_tac []))
145     |> LocalTheory.exit_global
146   end