src/Pure/Isar/attrib.ML
author wenzelm
Sun Aug 10 12:38:24 2008 +0200 (2008-08-10)
changeset 27820 56515e560104
parent 27812 af8edf3ab68c
child 27865 27a8ad9612a3
permissions -rw-r--r--
pass position to get_fact;
tuned;
     1 (*  Title:      Pure/Isar/attrib.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Symbolic representation of attributes -- with name and syntax.
     6 *)
     7 
     8 signature ATTRIB =
     9 sig
    10   type src = Args.src
    11   val print_attributes: theory -> unit
    12   val intern: theory -> xstring -> string
    13   val intern_src: theory -> src -> src
    14   val pretty_attribs: Proof.context -> src list -> Pretty.T list
    15   val defined: theory -> string -> bool
    16   val attribute: theory -> src -> attribute
    17   val attribute_i: theory -> src -> attribute
    18   val eval_thms: Proof.context -> (Facts.ref * src list) list -> thm list
    19   val map_specs: ('a -> 'att) ->
    20     (('c * 'a list) * 'd) list -> (('c * 'att list) * 'd) list
    21   val map_facts: ('a -> 'att) ->
    22     (('c * 'a list) * ('d * 'a list) list) list ->
    23     (('c * 'att list) * ('d * 'att list) list) list
    24   val crude_closure: Proof.context -> src -> src
    25   val add_attributes: (bstring * (src -> attribute) * string) list -> theory -> theory
    26   val syntax: (Context.generic * Args.T list ->
    27     attribute * (Context.generic * Args.T list)) -> src -> attribute
    28   val no_args: attribute -> src -> attribute
    29   val add_del_args: attribute -> attribute -> src -> attribute
    30   val thm_sel: Args.T list -> Facts.interval list * Args.T list
    31   val thm: Context.generic * Args.T list -> thm * (Context.generic * Args.T list)
    32   val thms: Context.generic * Args.T list -> thm list * (Context.generic * Args.T list)
    33   val multi_thm: Context.generic * Args.T list -> thm list * (Context.generic * Args.T list)
    34   val print_configs: Proof.context -> unit
    35   val internal: (morphism -> attribute) -> src
    36   val register_config: Config.value Config.T -> theory -> theory
    37   val config_bool: bstring -> bool -> bool Config.T * (theory -> theory)
    38   val config_int: bstring -> int -> int Config.T * (theory -> theory)
    39   val config_string: bstring -> string -> string Config.T * (theory -> theory)
    40   val config_bool_global: bstring -> bool -> bool Config.T * (theory -> theory)
    41   val config_int_global: bstring -> int -> int Config.T * (theory -> theory)
    42   val config_string_global: bstring -> string -> string Config.T * (theory -> theory)
    43 end;
    44 
    45 structure Attrib: ATTRIB =
    46 struct
    47 
    48 structure T = OuterLex;
    49 structure P = OuterParse;
    50 
    51 type src = Args.src;
    52 
    53 
    54 (** named attributes **)
    55 
    56 (* theory data *)
    57 
    58 structure Attributes = TheoryDataFun
    59 (
    60   type T = (((src -> attribute) * string) * stamp) NameSpace.table;
    61   val empty = NameSpace.empty_table;
    62   val copy = I;
    63   val extend = I;
    64   fun merge _ tables : T = NameSpace.merge_tables (eq_snd (op =)) tables handle Symtab.DUP dup =>
    65     error ("Attempt to merge different versions of attribute " ^ quote dup);
    66 );
    67 
    68 fun print_attributes thy =
    69   let
    70     val attribs = Attributes.get thy;
    71     fun prt_attr (name, ((_, comment), _)) = Pretty.block
    72       [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
    73   in
    74     [Pretty.big_list "attributes:" (map prt_attr (NameSpace.extern_table attribs))]
    75     |> Pretty.chunks |> Pretty.writeln
    76   end;
    77 
    78 
    79 (* name space *)
    80 
    81 val intern = NameSpace.intern o #1 o Attributes.get;
    82 val intern_src = Args.map_name o intern;
    83 
    84 val extern = NameSpace.extern o #1 o Attributes.get o ProofContext.theory_of;
    85 
    86 
    87 (* pretty printing *)
    88 
    89 fun pretty_attribs _ [] = []
    90   | pretty_attribs ctxt srcs =
    91       [Pretty.enclose "[" "]"
    92         (Pretty.commas (map (Args.pretty_src ctxt o Args.map_name (extern ctxt)) srcs))];
    93 
    94 
    95 (* get attributes *)
    96 
    97 val defined = Symtab.defined o #2 o Attributes.get;
    98 
    99 fun attribute_i thy =
   100   let
   101     val attrs = #2 (Attributes.get thy);
   102     fun attr src =
   103       let val ((name, _), pos) = Args.dest_src src in
   104         (case Symtab.lookup attrs name of
   105           NONE => error ("Unknown attribute: " ^ quote name ^ Position.str_of pos)
   106         | SOME ((att, _), _) => (Position.report (Markup.attribute name) pos; att src))
   107       end;
   108   in attr end;
   109 
   110 fun attribute thy = attribute_i thy o intern_src thy;
   111 
   112 fun eval_thms ctxt args = ProofContext.note_thmss Thm.theoremK
   113     [(("", []), map (apsnd (map (attribute (ProofContext.theory_of ctxt)))) args)] ctxt
   114   |> fst |> maps snd;
   115 
   116 
   117 (* attributed declarations *)
   118 
   119 fun map_specs f = map (apfst (apsnd (map f)));
   120 fun map_facts f = map (apfst (apsnd (map f)) o apsnd (map (apsnd (map f))));
   121 
   122 
   123 (* crude_closure *)
   124 
   125 (*Produce closure without knowing facts in advance! The following
   126   works reasonably well for attribute parsers that do not peek at the
   127   thm structure.*)
   128 
   129 fun crude_closure ctxt src =
   130  (try (fn () => attribute_i (ProofContext.theory_of ctxt) src
   131     (Context.Proof ctxt, Drule.asm_rl)) ();
   132   Args.closure src);
   133 
   134 
   135 (* add_attributes *)
   136 
   137 fun add_attributes raw_attrs thy =
   138   let
   139     val new_attrs =
   140       raw_attrs |> map (fn (name, att, comment) => (name, ((att, comment), stamp ())));
   141     fun add attrs = NameSpace.extend_table (Sign.naming_of thy) new_attrs attrs
   142       handle Symtab.DUP dup => error ("Duplicate declaration of attributes " ^ quote dup);
   143   in Attributes.map add thy end;
   144 
   145 
   146 (* attribute syntax *)
   147 
   148 fun syntax scan src (st, th) =
   149   let val (f: attribute, st') = Args.syntax "attribute" scan src st
   150   in f (st', th) end;
   151 
   152 fun no_args x = syntax (Scan.succeed x);
   153 
   154 fun add_del_args add del = syntax
   155   (Scan.lift (Args.add >> K add || Args.del >> K del || Scan.succeed add));
   156 
   157 
   158 
   159 (** parsing attributed theorems **)
   160 
   161 val thm_sel = P.$$$ "(" |-- P.list1
   162  (P.nat --| P.minus -- P.nat >> Facts.FromTo ||
   163   P.nat --| P.minus >> Facts.From ||
   164   P.nat >> Facts.Single) --| P.$$$ ")";
   165 
   166 local
   167 
   168 val fact_name = Args.internal_fact >> K "<fact>" || Args.name;
   169 
   170 fun gen_thm pick = Scan.depend (fn context =>
   171   let
   172     val thy = Context.theory_of context;
   173     val get = Context.cases (PureThy.get_fact context) ProofContext.get_fact context;
   174     val get_fact = get o Facts.Fact;
   175     fun get_named pos name = get (Facts.Named ((name, pos), NONE));
   176   in
   177     P.$$$ "[" |-- Args.attribs (intern thy) --| P.$$$ "]" >> (fn srcs =>
   178       let
   179         val atts = map (attribute_i thy) srcs;
   180         val (context', th') = Library.apply atts (context, Drule.dummy_thm);
   181       in (context', pick "" [th']) end)
   182     ||
   183     (Scan.ahead Args.alt_name -- Args.named_fact get_fact
   184       >> (fn (s, fact) => ("", Facts.Fact s, fact)) ||
   185      Scan.ahead (P.position fact_name) :|-- (fn (name, pos) =>
   186       Args.named_fact (get_named pos) -- Scan.option thm_sel
   187         >> (fn (fact, sel) => (name, Facts.Named ((name, pos), sel), fact))))
   188     -- Args.opt_attribs (intern thy) >> (fn ((name, thmref, fact), srcs) =>
   189       let
   190         val ths = Facts.select thmref fact;
   191         val atts = map (attribute_i thy) srcs;
   192         val (context', ths') = foldl_map (Library.apply atts) (context, ths);
   193       in (context', pick name ths') end)
   194   end);
   195 
   196 in
   197 
   198 val thm = gen_thm Facts.the_single;
   199 val multi_thm = gen_thm (K I);
   200 val thms = Scan.repeat multi_thm >> flat;
   201 
   202 end;
   203 
   204 
   205 
   206 (** basic attributes **)
   207 
   208 (* internal *)
   209 
   210 fun internal att = Args.src (("Pure.attribute", [T.mk_attribute att]), Position.none);
   211 
   212 val internal_att =
   213   syntax (Scan.lift Args.internal_attribute >> Morphism.form);
   214 
   215 
   216 (* tags *)
   217 
   218 val tagged = syntax (Scan.lift (Args.name -- Args.name) >> PureThy.tag);
   219 val untagged = syntax (Scan.lift Args.name >> PureThy.untag);
   220 
   221 val kind = syntax (Scan.lift Args.name >> PureThy.kind);
   222 
   223 
   224 (* rule composition *)
   225 
   226 val COMP_att =
   227   syntax (Scan.lift (Scan.optional (Args.bracks P.nat) 1) -- thm
   228     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => Drule.compose_single (A, i, B))));
   229 
   230 val THEN_att =
   231   syntax (Scan.lift (Scan.optional (Args.bracks P.nat) 1) -- thm
   232     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => A RSN (i, B))));
   233 
   234 val OF_att =
   235   syntax (thms >> (fn Bs => Thm.rule_attribute (fn _ => fn A => Bs MRS A)));
   236 
   237 
   238 (* rename_abs *)
   239 
   240 val rename_abs = syntax
   241   (Scan.lift (Scan.repeat (Args.maybe Args.name) >> (apsnd o Drule.rename_bvars')));
   242 
   243 
   244 (* unfold / fold definitions *)
   245 
   246 fun unfolded_syntax rule =
   247   syntax (thms >>
   248     (fn ths => Thm.rule_attribute (fn context => rule (Context.proof_of context) ths)));
   249 
   250 val unfolded = unfolded_syntax LocalDefs.unfold;
   251 val folded = unfolded_syntax LocalDefs.fold;
   252 
   253 
   254 (* rule cases *)
   255 
   256 val consumes = syntax (Scan.lift (Scan.optional P.nat 1) >> RuleCases.consumes);
   257 val case_names = syntax (Scan.lift (Scan.repeat1 Args.name) >> RuleCases.case_names);
   258 val case_conclusion =
   259   syntax (Scan.lift (Args.name -- Scan.repeat Args.name) >> RuleCases.case_conclusion);
   260 val params = syntax (Scan.lift (P.and_list1 (Scan.repeat Args.name)) >> RuleCases.params);
   261 
   262 
   263 (* rule format *)
   264 
   265 val rule_format = syntax (Args.mode "no_asm"
   266   >> (fn true => ObjectLogic.rule_format_no_asm | false => ObjectLogic.rule_format));
   267 
   268 val elim_format = no_args (Thm.rule_attribute (K Tactic.make_elim));
   269 
   270 
   271 (* misc rules *)
   272 
   273 val standard = no_args (Thm.rule_attribute (K Drule.standard));
   274 
   275 val no_vars = no_args (Thm.rule_attribute (fn context => fn th =>
   276   let
   277     val ctxt = Variable.set_body false (Context.proof_of context);
   278     val ((_, [th']), _) = Variable.import_thms true [th] ctxt;
   279   in th' end));
   280 
   281 val eta_long =
   282   no_args (Thm.rule_attribute (K (Conv.fconv_rule Drule.eta_long_conversion)));
   283 
   284 val rotated = syntax
   285   (Scan.lift (Scan.optional P.int 1) >> (fn n => Thm.rule_attribute (K (rotate_prems n))));
   286 
   287 
   288 (* theory setup *)
   289 
   290 val _ = Context.>> (Context.map_theory
   291  (add_attributes
   292    [("attribute", internal_att, "internal attribute"),
   293     ("tagged", tagged, "tagged theorem"),
   294     ("untagged", untagged, "untagged theorem"),
   295     ("kind", kind, "theorem kind"),
   296     ("COMP", COMP_att, "direct composition with rules (no lifting)"),
   297     ("THEN", THEN_att, "resolution with rule"),
   298     ("OF", OF_att, "rule applied to facts"),
   299     ("rename_abs", rename_abs, "rename bound variables in abstractions"),
   300     ("unfolded", unfolded, "unfolded definitions"),
   301     ("folded", folded, "folded definitions"),
   302     ("standard", standard, "result put into standard form"),
   303     ("elim_format", elim_format, "destruct rule turned into elimination rule format"),
   304     ("no_vars", no_vars, "frozen schematic vars"),
   305     ("eta_long", eta_long, "put theorem into eta long beta normal form"),
   306     ("consumes", consumes, "number of consumed facts"),
   307     ("case_names", case_names, "named rule cases"),
   308     ("case_conclusion", case_conclusion, "named conclusion of rule cases"),
   309     ("params", params, "named rule parameters"),
   310     ("atomize", no_args ObjectLogic.declare_atomize, "declaration of atomize rule"),
   311     ("rulify", no_args ObjectLogic.declare_rulify, "declaration of rulify rule"),
   312     ("rule_format", rule_format, "result put into standard rule format"),
   313     ("rotated", rotated, "rotated theorem premises"),
   314     ("defn", add_del_args LocalDefs.defn_add LocalDefs.defn_del,
   315       "declaration of definitional transformations")]));
   316 
   317 
   318 
   319 (** configuration options **)
   320 
   321 (* naming *)
   322 
   323 structure Configs = TheoryDataFun
   324 (
   325   type T = Config.value Config.T Symtab.table;
   326   val empty = Symtab.empty;
   327   val copy = I;
   328   val extend = I;
   329   fun merge _ = Symtab.merge (K true);
   330 );
   331 
   332 fun print_configs ctxt =
   333   let
   334     val thy = ProofContext.theory_of ctxt;
   335     fun prt (name, config) =
   336       let val value = Config.get ctxt config in
   337         Pretty.block [Pretty.str (name ^ ": " ^ Config.print_type value ^ " ="), Pretty.brk 1,
   338           Pretty.str (Config.print_value value)]
   339       end;
   340     val configs = NameSpace.extern_table (#1 (Attributes.get thy), Configs.get thy);
   341   in Pretty.writeln (Pretty.big_list "configuration options" (map prt configs)) end;
   342 
   343 
   344 (* concrete syntax *)
   345 
   346 local
   347 
   348 val equals = P.$$$ "=";
   349 
   350 fun scan_value (Config.Bool _) =
   351       equals -- Args.$$$ "false" >> K (Config.Bool false) ||
   352       equals -- Args.$$$ "true" >> K (Config.Bool true) ||
   353       Scan.succeed (Config.Bool true)
   354   | scan_value (Config.Int _) = equals |-- P.int >> Config.Int
   355   | scan_value (Config.String _) = equals |-- Args.name >> Config.String;
   356 
   357 fun scan_config thy config =
   358   let val config_type = Config.get_thy thy config
   359   in scan_value config_type >> (K o Thm.declaration_attribute o K o Config.put_generic config) end;
   360 
   361 in
   362 
   363 fun register_config config thy =
   364   let
   365     val bname = Config.name_of config;
   366     val name = Sign.full_name thy bname;
   367   in
   368     thy
   369     |> add_attributes [(bname, syntax (Scan.lift (scan_config thy config) >> Morphism.form),
   370       "configuration option")]
   371     |> Configs.map (Symtab.update (name, config))
   372   end;
   373 
   374 fun declare_config make coerce global name default =
   375   let
   376     val config_value = Config.declare global name (make default);
   377     val config = coerce config_value;
   378   in (config, register_config config_value) end;
   379 
   380 val config_bool   = declare_config Config.Bool Config.bool false;
   381 val config_int    = declare_config Config.Int Config.int false;
   382 val config_string = declare_config Config.String Config.string false;
   383 
   384 val config_bool_global   = declare_config Config.Bool Config.bool true;
   385 val config_int_global    = declare_config Config.Int Config.int true;
   386 val config_string_global = declare_config Config.String Config.string true;
   387 
   388 end;
   389 
   390 
   391 (* theory setup *)
   392 
   393 val _ = Context.>> (Context.map_theory
   394  (register_config Unify.trace_bound_value #>
   395   register_config Unify.search_bound_value #>
   396   register_config Unify.trace_simp_value #>
   397   register_config Unify.trace_types_value #>
   398   register_config MetaSimplifier.simp_depth_limit_value));
   399 
   400 end;