src/HOL/Orderings.thy
author huffman
Sat Jun 06 09:11:12 2009 -0700 (2009-06-06)
changeset 31488 5691ccb8d6b5
parent 30929 d9343c0aac11
child 31998 2c7a24f74db9
permissions -rw-r--r--
generalize tendsto to class topological_space
     1 (*  Title:      HOL/Orderings.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* Abstract orderings *}
     6 
     7 theory Orderings
     8 imports HOL
     9 uses "~~/src/Provers/order.ML"
    10 begin
    11 
    12 subsection {* Quasi orders *}
    13 
    14 class preorder = ord +
    15   assumes less_le_not_le: "x < y \<longleftrightarrow> x \<le> y \<and> \<not> (y \<le> x)"
    16   and order_refl [iff]: "x \<le> x"
    17   and order_trans: "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
    18 begin
    19 
    20 text {* Reflexivity. *}
    21 
    22 lemma eq_refl: "x = y \<Longrightarrow> x \<le> y"
    23     -- {* This form is useful with the classical reasoner. *}
    24 by (erule ssubst) (rule order_refl)
    25 
    26 lemma less_irrefl [iff]: "\<not> x < x"
    27 by (simp add: less_le_not_le)
    28 
    29 lemma less_imp_le: "x < y \<Longrightarrow> x \<le> y"
    30 unfolding less_le_not_le by blast
    31 
    32 
    33 text {* Asymmetry. *}
    34 
    35 lemma less_not_sym: "x < y \<Longrightarrow> \<not> (y < x)"
    36 by (simp add: less_le_not_le)
    37 
    38 lemma less_asym: "x < y \<Longrightarrow> (\<not> P \<Longrightarrow> y < x) \<Longrightarrow> P"
    39 by (drule less_not_sym, erule contrapos_np) simp
    40 
    41 
    42 text {* Transitivity. *}
    43 
    44 lemma less_trans: "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    45 by (auto simp add: less_le_not_le intro: order_trans) 
    46 
    47 lemma le_less_trans: "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    48 by (auto simp add: less_le_not_le intro: order_trans) 
    49 
    50 lemma less_le_trans: "x < y \<Longrightarrow> y \<le> z \<Longrightarrow> x < z"
    51 by (auto simp add: less_le_not_le intro: order_trans) 
    52 
    53 
    54 text {* Useful for simplification, but too risky to include by default. *}
    55 
    56 lemma less_imp_not_less: "x < y \<Longrightarrow> (\<not> y < x) \<longleftrightarrow> True"
    57 by (blast elim: less_asym)
    58 
    59 lemma less_imp_triv: "x < y \<Longrightarrow> (y < x \<longrightarrow> P) \<longleftrightarrow> True"
    60 by (blast elim: less_asym)
    61 
    62 
    63 text {* Transitivity rules for calculational reasoning *}
    64 
    65 lemma less_asym': "a < b \<Longrightarrow> b < a \<Longrightarrow> P"
    66 by (rule less_asym)
    67 
    68 
    69 text {* Dual order *}
    70 
    71 lemma dual_preorder:
    72   "preorder (op \<ge>) (op >)"
    73 proof qed (auto simp add: less_le_not_le intro: order_trans)
    74 
    75 end
    76 
    77 
    78 subsection {* Partial orders *}
    79 
    80 class order = preorder +
    81   assumes antisym: "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
    82 begin
    83 
    84 text {* Reflexivity. *}
    85 
    86 lemma less_le: "x < y \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
    87 by (auto simp add: less_le_not_le intro: antisym)
    88 
    89 lemma le_less: "x \<le> y \<longleftrightarrow> x < y \<or> x = y"
    90     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
    91 by (simp add: less_le) blast
    92 
    93 lemma le_imp_less_or_eq: "x \<le> y \<Longrightarrow> x < y \<or> x = y"
    94 unfolding less_le by blast
    95 
    96 
    97 text {* Useful for simplification, but too risky to include by default. *}
    98 
    99 lemma less_imp_not_eq: "x < y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   100 by auto
   101 
   102 lemma less_imp_not_eq2: "x < y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   103 by auto
   104 
   105 
   106 text {* Transitivity rules for calculational reasoning *}
   107 
   108 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<le> b \<Longrightarrow> a < b"
   109 by (simp add: less_le)
   110 
   111 lemma le_neq_trans: "a \<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a < b"
   112 by (simp add: less_le)
   113 
   114 
   115 text {* Asymmetry. *}
   116 
   117 lemma eq_iff: "x = y \<longleftrightarrow> x \<le> y \<and> y \<le> x"
   118 by (blast intro: antisym)
   119 
   120 lemma antisym_conv: "y \<le> x \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   121 by (blast intro: antisym)
   122 
   123 lemma less_imp_neq: "x < y \<Longrightarrow> x \<noteq> y"
   124 by (erule contrapos_pn, erule subst, rule less_irrefl)
   125 
   126 
   127 text {* Least value operator *}
   128 
   129 definition (in ord)
   130   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   131   "Least P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<le> y))"
   132 
   133 lemma Least_equality:
   134   assumes "P x"
   135     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   136   shows "Least P = x"
   137 unfolding Least_def by (rule the_equality)
   138   (blast intro: assms antisym)+
   139 
   140 lemma LeastI2_order:
   141   assumes "P x"
   142     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   143     and "\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> x \<le> y \<Longrightarrow> Q x"
   144   shows "Q (Least P)"
   145 unfolding Least_def by (rule theI2)
   146   (blast intro: assms antisym)+
   147 
   148 
   149 text {* Dual order *}
   150 
   151 lemma dual_order:
   152   "order (op \<ge>) (op >)"
   153 by (intro_locales, rule dual_preorder) (unfold_locales, rule antisym)
   154 
   155 end
   156 
   157 
   158 subsection {* Linear (total) orders *}
   159 
   160 class linorder = order +
   161   assumes linear: "x \<le> y \<or> y \<le> x"
   162 begin
   163 
   164 lemma less_linear: "x < y \<or> x = y \<or> y < x"
   165 unfolding less_le using less_le linear by blast
   166 
   167 lemma le_less_linear: "x \<le> y \<or> y < x"
   168 by (simp add: le_less less_linear)
   169 
   170 lemma le_cases [case_names le ge]:
   171   "(x \<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   172 using linear by blast
   173 
   174 lemma linorder_cases [case_names less equal greater]:
   175   "(x < y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y < x \<Longrightarrow> P) \<Longrightarrow> P"
   176 using less_linear by blast
   177 
   178 lemma not_less: "\<not> x < y \<longleftrightarrow> y \<le> x"
   179 apply (simp add: less_le)
   180 using linear apply (blast intro: antisym)
   181 done
   182 
   183 lemma not_less_iff_gr_or_eq:
   184  "\<not>(x < y) \<longleftrightarrow> (x > y | x = y)"
   185 apply(simp add:not_less le_less)
   186 apply blast
   187 done
   188 
   189 lemma not_le: "\<not> x \<le> y \<longleftrightarrow> y < x"
   190 apply (simp add: less_le)
   191 using linear apply (blast intro: antisym)
   192 done
   193 
   194 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x < y \<or> y < x"
   195 by (cut_tac x = x and y = y in less_linear, auto)
   196 
   197 lemma neqE: "x \<noteq> y \<Longrightarrow> (x < y \<Longrightarrow> R) \<Longrightarrow> (y < x \<Longrightarrow> R) \<Longrightarrow> R"
   198 by (simp add: neq_iff) blast
   199 
   200 lemma antisym_conv1: "\<not> x < y \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   201 by (blast intro: antisym dest: not_less [THEN iffD1])
   202 
   203 lemma antisym_conv2: "x \<le> y \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   204 by (blast intro: antisym dest: not_less [THEN iffD1])
   205 
   206 lemma antisym_conv3: "\<not> y < x \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   207 by (blast intro: antisym dest: not_less [THEN iffD1])
   208 
   209 lemma leI: "\<not> x < y \<Longrightarrow> y \<le> x"
   210 unfolding not_less .
   211 
   212 lemma leD: "y \<le> x \<Longrightarrow> \<not> x < y"
   213 unfolding not_less .
   214 
   215 (*FIXME inappropriate name (or delete altogether)*)
   216 lemma not_leE: "\<not> y \<le> x \<Longrightarrow> x < y"
   217 unfolding not_le .
   218 
   219 
   220 text {* Dual order *}
   221 
   222 lemma dual_linorder:
   223   "linorder (op \<ge>) (op >)"
   224 by (rule linorder.intro, rule dual_order) (unfold_locales, rule linear)
   225 
   226 
   227 text {* min/max *}
   228 
   229 definition (in ord) min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   230   [code del]: "min a b = (if a \<le> b then a else b)"
   231 
   232 definition (in ord) max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   233   [code del]: "max a b = (if a \<le> b then b else a)"
   234 
   235 lemma min_le_iff_disj:
   236   "min x y \<le> z \<longleftrightarrow> x \<le> z \<or> y \<le> z"
   237 unfolding min_def using linear by (auto intro: order_trans)
   238 
   239 lemma le_max_iff_disj:
   240   "z \<le> max x y \<longleftrightarrow> z \<le> x \<or> z \<le> y"
   241 unfolding max_def using linear by (auto intro: order_trans)
   242 
   243 lemma min_less_iff_disj:
   244   "min x y < z \<longleftrightarrow> x < z \<or> y < z"
   245 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   246 
   247 lemma less_max_iff_disj:
   248   "z < max x y \<longleftrightarrow> z < x \<or> z < y"
   249 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   250 
   251 lemma min_less_iff_conj [simp]:
   252   "z < min x y \<longleftrightarrow> z < x \<and> z < y"
   253 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   254 
   255 lemma max_less_iff_conj [simp]:
   256   "max x y < z \<longleftrightarrow> x < z \<and> y < z"
   257 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   258 
   259 lemma split_min [noatp]:
   260   "P (min i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P i) \<and> (\<not> i \<le> j \<longrightarrow> P j)"
   261 by (simp add: min_def)
   262 
   263 lemma split_max [noatp]:
   264   "P (max i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P j) \<and> (\<not> i \<le> j \<longrightarrow> P i)"
   265 by (simp add: max_def)
   266 
   267 end
   268 
   269 text {* Explicit dictionaries for code generation *}
   270 
   271 lemma min_ord_min [code, code unfold, code inline del]:
   272   "min = ord.min (op \<le>)"
   273   by (rule ext)+ (simp add: min_def ord.min_def)
   274 
   275 declare ord.min_def [code]
   276 
   277 lemma max_ord_max [code, code unfold, code inline del]:
   278   "max = ord.max (op \<le>)"
   279   by (rule ext)+ (simp add: max_def ord.max_def)
   280 
   281 declare ord.max_def [code]
   282 
   283 
   284 subsection {* Reasoning tools setup *}
   285 
   286 ML {*
   287 
   288 signature ORDERS =
   289 sig
   290   val print_structures: Proof.context -> unit
   291   val setup: theory -> theory
   292   val order_tac: thm list -> Proof.context -> int -> tactic
   293 end;
   294 
   295 structure Orders: ORDERS =
   296 struct
   297 
   298 (** Theory and context data **)
   299 
   300 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   301   (s1 = s2) andalso eq_list (op aconv) (ts1, ts2);
   302 
   303 structure Data = GenericDataFun
   304 (
   305   type T = ((string * term list) * Order_Tac.less_arith) list;
   306     (* Order structures:
   307        identifier of the structure, list of operations and record of theorems
   308        needed to set up the transitivity reasoner,
   309        identifier and operations identify the structure uniquely. *)
   310   val empty = [];
   311   val extend = I;
   312   fun merge _ = AList.join struct_eq (K fst);
   313 );
   314 
   315 fun print_structures ctxt =
   316   let
   317     val structs = Data.get (Context.Proof ctxt);
   318     fun pretty_term t = Pretty.block
   319       [Pretty.quote (Syntax.pretty_term ctxt t), Pretty.brk 1,
   320         Pretty.str "::", Pretty.brk 1,
   321         Pretty.quote (Syntax.pretty_typ ctxt (type_of t))];
   322     fun pretty_struct ((s, ts), _) = Pretty.block
   323       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   324        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   325   in
   326     Pretty.writeln (Pretty.big_list "Order structures:" (map pretty_struct structs))
   327   end;
   328 
   329 
   330 (** Method **)
   331 
   332 fun struct_tac ((s, [eq, le, less]), thms) prems =
   333   let
   334     fun decomp thy (@{const Trueprop} $ t) =
   335       let
   336         fun excluded t =
   337           (* exclude numeric types: linear arithmetic subsumes transitivity *)
   338           let val T = type_of t
   339           in
   340 	    T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   341           end;
   342 	fun rel (bin_op $ t1 $ t2) =
   343               if excluded t1 then NONE
   344               else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   345               else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   346               else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   347               else NONE
   348 	  | rel _ = NONE;
   349 	fun dec (Const (@{const_name Not}, _) $ t) = (case rel t
   350 	      of NONE => NONE
   351 	       | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   352           | dec x = rel x;
   353       in dec t end
   354       | decomp thy _ = NONE;
   355   in
   356     case s of
   357       "order" => Order_Tac.partial_tac decomp thms prems
   358     | "linorder" => Order_Tac.linear_tac decomp thms prems
   359     | _ => error ("Unknown kind of order `" ^ s ^ "' encountered in transitivity reasoner.")
   360   end
   361 
   362 fun order_tac prems ctxt =
   363   FIRST' (map (fn s => CHANGED o struct_tac s prems) (Data.get (Context.Proof ctxt)));
   364 
   365 
   366 (** Attribute **)
   367 
   368 fun add_struct_thm s tag =
   369   Thm.declaration_attribute
   370     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   371 fun del_struct s =
   372   Thm.declaration_attribute
   373     (fn _ => Data.map (AList.delete struct_eq s));
   374 
   375 val attrib_setup =
   376   Attrib.setup @{binding order}
   377     (Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) || Args.del >> K NONE) --|
   378       Args.colon (* FIXME || Scan.succeed true *) ) -- Scan.lift Args.name --
   379       Scan.repeat Args.term
   380       >> (fn ((SOME tag, n), ts) => add_struct_thm (n, ts) tag
   381            | ((NONE, n), ts) => del_struct (n, ts)))
   382     "theorems controlling transitivity reasoner";
   383 
   384 
   385 (** Diagnostic command **)
   386 
   387 val _ =
   388   OuterSyntax.improper_command "print_orders"
   389     "print order structures available to transitivity reasoner" OuterKeyword.diag
   390     (Scan.succeed (Toplevel.no_timing o Toplevel.unknown_context o
   391         Toplevel.keep (print_structures o Toplevel.context_of)));
   392 
   393 
   394 (** Setup **)
   395 
   396 val setup =
   397   Method.setup @{binding order} (Scan.succeed (SIMPLE_METHOD' o order_tac []))
   398     "transitivity reasoner" #>
   399   attrib_setup;
   400 
   401 end;
   402 
   403 *}
   404 
   405 setup Orders.setup
   406 
   407 
   408 text {* Declarations to set up transitivity reasoner of partial and linear orders. *}
   409 
   410 context order
   411 begin
   412 
   413 (* The type constraint on @{term op =} below is necessary since the operation
   414    is not a parameter of the locale. *)
   415 
   416 declare less_irrefl [THEN notE, order add less_reflE: order "op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool" "op <=" "op <"]
   417   
   418 declare order_refl  [order add le_refl: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   419   
   420 declare less_imp_le [order add less_imp_le: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   421   
   422 declare antisym [order add eqI: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   423 
   424 declare eq_refl [order add eqD1: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   425 
   426 declare sym [THEN eq_refl, order add eqD2: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   427 
   428 declare less_trans [order add less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   429   
   430 declare less_le_trans [order add less_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   431   
   432 declare le_less_trans [order add le_less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   433 
   434 declare order_trans [order add le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   435 
   436 declare le_neq_trans [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   437 
   438 declare neq_le_trans [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   439 
   440 declare less_imp_neq [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   441 
   442 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   443 
   444 declare not_sym [order add not_sym: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   445 
   446 end
   447 
   448 context linorder
   449 begin
   450 
   451 declare [[order del: order "op = :: 'a => 'a => bool" "op <=" "op <"]]
   452 
   453 declare less_irrefl [THEN notE, order add less_reflE: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   454 
   455 declare order_refl [order add le_refl: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   456 
   457 declare less_imp_le [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   458 
   459 declare not_less [THEN iffD2, order add not_lessI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   460 
   461 declare not_le [THEN iffD2, order add not_leI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   462 
   463 declare not_less [THEN iffD1, order add not_lessD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   464 
   465 declare not_le [THEN iffD1, order add not_leD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   466 
   467 declare antisym [order add eqI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   468 
   469 declare eq_refl [order add eqD1: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   470 
   471 declare sym [THEN eq_refl, order add eqD2: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   472 
   473 declare less_trans [order add less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   474 
   475 declare less_le_trans [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   476 
   477 declare le_less_trans [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   478 
   479 declare order_trans [order add le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   480 
   481 declare le_neq_trans [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   482 
   483 declare neq_le_trans [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   484 
   485 declare less_imp_neq [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   486 
   487 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   488 
   489 declare not_sym [order add not_sym: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   490 
   491 end
   492 
   493 
   494 setup {*
   495 let
   496 
   497 fun prp t thm = (#prop (rep_thm thm) = t);
   498 
   499 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   500   let val prems = prems_of_ss ss;
   501       val less = Const (@{const_name less}, T);
   502       val t = HOLogic.mk_Trueprop(le $ s $ r);
   503   in case find_first (prp t) prems of
   504        NONE =>
   505          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   506          in case find_first (prp t) prems of
   507               NONE => NONE
   508             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1}))
   509          end
   510      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_class.antisym_conv}))
   511   end
   512   handle THM _ => NONE;
   513 
   514 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   515   let val prems = prems_of_ss ss;
   516       val le = Const (@{const_name less_eq}, T);
   517       val t = HOLogic.mk_Trueprop(le $ r $ s);
   518   in case find_first (prp t) prems of
   519        NONE =>
   520          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   521          in case find_first (prp t) prems of
   522               NONE => NONE
   523             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3}))
   524          end
   525      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv2}))
   526   end
   527   handle THM _ => NONE;
   528 
   529 fun add_simprocs procs thy =
   530   Simplifier.map_simpset (fn ss => ss
   531     addsimprocs (map (fn (name, raw_ts, proc) =>
   532       Simplifier.simproc thy name raw_ts proc) procs)) thy;
   533 fun add_solver name tac =
   534   Simplifier.map_simpset (fn ss => ss addSolver
   535     mk_solver' name (fn ss => tac (Simplifier.prems_of_ss ss) (Simplifier.the_context ss)));
   536 
   537 in
   538   add_simprocs [
   539        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   540        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   541      ]
   542   #> add_solver "Transitivity" Orders.order_tac
   543   (* Adding the transitivity reasoners also as safe solvers showed a slight
   544      speed up, but the reasoning strength appears to be not higher (at least
   545      no breaking of additional proofs in the entire HOL distribution, as
   546      of 5 March 2004, was observed). *)
   547 end
   548 *}
   549 
   550 
   551 subsection {* Name duplicates *}
   552 
   553 lemmas order_less_le = less_le
   554 lemmas order_eq_refl = preorder_class.eq_refl
   555 lemmas order_less_irrefl = preorder_class.less_irrefl
   556 lemmas order_le_less = order_class.le_less
   557 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
   558 lemmas order_less_imp_le = preorder_class.less_imp_le
   559 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
   560 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
   561 lemmas order_neq_le_trans = order_class.neq_le_trans
   562 lemmas order_le_neq_trans = order_class.le_neq_trans
   563 
   564 lemmas order_antisym = antisym
   565 lemmas order_less_not_sym = preorder_class.less_not_sym
   566 lemmas order_less_asym = preorder_class.less_asym
   567 lemmas order_eq_iff = order_class.eq_iff
   568 lemmas order_antisym_conv = order_class.antisym_conv
   569 lemmas order_less_trans = preorder_class.less_trans
   570 lemmas order_le_less_trans = preorder_class.le_less_trans
   571 lemmas order_less_le_trans = preorder_class.less_le_trans
   572 lemmas order_less_imp_not_less = preorder_class.less_imp_not_less
   573 lemmas order_less_imp_triv = preorder_class.less_imp_triv
   574 lemmas order_less_asym' = preorder_class.less_asym'
   575 
   576 lemmas linorder_linear = linear
   577 lemmas linorder_less_linear = linorder_class.less_linear
   578 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   579 lemmas linorder_le_cases = linorder_class.le_cases
   580 lemmas linorder_not_less = linorder_class.not_less
   581 lemmas linorder_not_le = linorder_class.not_le
   582 lemmas linorder_neq_iff = linorder_class.neq_iff
   583 lemmas linorder_neqE = linorder_class.neqE
   584 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   585 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   586 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   587 
   588 
   589 subsection {* Bounded quantifiers *}
   590 
   591 syntax
   592   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   593   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   594   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   595   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   596 
   597   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   598   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   599   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   600   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   601 
   602 syntax (xsymbols)
   603   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   604   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   605   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   606   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   607 
   608   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   609   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   610   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   611   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   612 
   613 syntax (HOL)
   614   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   615   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   616   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   617   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   618 
   619 syntax (HTML output)
   620   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   621   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   622   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   623   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   624 
   625   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   626   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   627   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   628   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   629 
   630 translations
   631   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   632   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   633   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   634   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   635   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   636   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   637   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   638   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   639 
   640 print_translation {*
   641 let
   642   val All_binder = Syntax.binder_name @{const_syntax All};
   643   val Ex_binder = Syntax.binder_name @{const_syntax Ex};
   644   val impl = @{const_syntax "op -->"};
   645   val conj = @{const_syntax "op &"};
   646   val less = @{const_syntax less};
   647   val less_eq = @{const_syntax less_eq};
   648 
   649   val trans =
   650    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   651     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   652     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   653     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   654 
   655   fun matches_bound v t = 
   656      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   657               | _ => false
   658   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   659   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   660 
   661   fun tr' q = (q,
   662     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   663       (case AList.lookup (op =) trans (q, c, d) of
   664         NONE => raise Match
   665       | SOME (l, g) =>
   666           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   667           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   668           else raise Match)
   669      | _ => raise Match);
   670 in [tr' All_binder, tr' Ex_binder] end
   671 *}
   672 
   673 
   674 subsection {* Transitivity reasoning *}
   675 
   676 context ord
   677 begin
   678 
   679 lemma ord_le_eq_trans: "a \<le> b \<Longrightarrow> b = c \<Longrightarrow> a \<le> c"
   680   by (rule subst)
   681 
   682 lemma ord_eq_le_trans: "a = b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   683   by (rule ssubst)
   684 
   685 lemma ord_less_eq_trans: "a < b \<Longrightarrow> b = c \<Longrightarrow> a < c"
   686   by (rule subst)
   687 
   688 lemma ord_eq_less_trans: "a = b \<Longrightarrow> b < c \<Longrightarrow> a < c"
   689   by (rule ssubst)
   690 
   691 end
   692 
   693 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   694   (!!x y. x < y ==> f x < f y) ==> f a < c"
   695 proof -
   696   assume r: "!!x y. x < y ==> f x < f y"
   697   assume "a < b" hence "f a < f b" by (rule r)
   698   also assume "f b < c"
   699   finally (order_less_trans) show ?thesis .
   700 qed
   701 
   702 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   703   (!!x y. x < y ==> f x < f y) ==> a < f c"
   704 proof -
   705   assume r: "!!x y. x < y ==> f x < f y"
   706   assume "a < f b"
   707   also assume "b < c" hence "f b < f c" by (rule r)
   708   finally (order_less_trans) show ?thesis .
   709 qed
   710 
   711 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   712   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   713 proof -
   714   assume r: "!!x y. x <= y ==> f x <= f y"
   715   assume "a <= b" hence "f a <= f b" by (rule r)
   716   also assume "f b < c"
   717   finally (order_le_less_trans) show ?thesis .
   718 qed
   719 
   720 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   721   (!!x y. x < y ==> f x < f y) ==> a < f c"
   722 proof -
   723   assume r: "!!x y. x < y ==> f x < f y"
   724   assume "a <= f b"
   725   also assume "b < c" hence "f b < f c" by (rule r)
   726   finally (order_le_less_trans) show ?thesis .
   727 qed
   728 
   729 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   730   (!!x y. x < y ==> f x < f y) ==> f a < c"
   731 proof -
   732   assume r: "!!x y. x < y ==> f x < f y"
   733   assume "a < b" hence "f a < f b" by (rule r)
   734   also assume "f b <= c"
   735   finally (order_less_le_trans) show ?thesis .
   736 qed
   737 
   738 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   739   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   740 proof -
   741   assume r: "!!x y. x <= y ==> f x <= f y"
   742   assume "a < f b"
   743   also assume "b <= c" hence "f b <= f c" by (rule r)
   744   finally (order_less_le_trans) show ?thesis .
   745 qed
   746 
   747 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   748   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   749 proof -
   750   assume r: "!!x y. x <= y ==> f x <= f y"
   751   assume "a <= f b"
   752   also assume "b <= c" hence "f b <= f c" by (rule r)
   753   finally (order_trans) show ?thesis .
   754 qed
   755 
   756 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   757   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   758 proof -
   759   assume r: "!!x y. x <= y ==> f x <= f y"
   760   assume "a <= b" hence "f a <= f b" by (rule r)
   761   also assume "f b <= c"
   762   finally (order_trans) show ?thesis .
   763 qed
   764 
   765 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   766   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   767 proof -
   768   assume r: "!!x y. x <= y ==> f x <= f y"
   769   assume "a <= b" hence "f a <= f b" by (rule r)
   770   also assume "f b = c"
   771   finally (ord_le_eq_trans) show ?thesis .
   772 qed
   773 
   774 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   775   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   776 proof -
   777   assume r: "!!x y. x <= y ==> f x <= f y"
   778   assume "a = f b"
   779   also assume "b <= c" hence "f b <= f c" by (rule r)
   780   finally (ord_eq_le_trans) show ?thesis .
   781 qed
   782 
   783 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   784   (!!x y. x < y ==> f x < f y) ==> f a < c"
   785 proof -
   786   assume r: "!!x y. x < y ==> f x < f y"
   787   assume "a < b" hence "f a < f b" by (rule r)
   788   also assume "f b = c"
   789   finally (ord_less_eq_trans) show ?thesis .
   790 qed
   791 
   792 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   793   (!!x y. x < y ==> f x < f y) ==> a < f c"
   794 proof -
   795   assume r: "!!x y. x < y ==> f x < f y"
   796   assume "a = f b"
   797   also assume "b < c" hence "f b < f c" by (rule r)
   798   finally (ord_eq_less_trans) show ?thesis .
   799 qed
   800 
   801 text {*
   802   Note that this list of rules is in reverse order of priorities.
   803 *}
   804 
   805 lemmas [trans] =
   806   order_less_subst2
   807   order_less_subst1
   808   order_le_less_subst2
   809   order_le_less_subst1
   810   order_less_le_subst2
   811   order_less_le_subst1
   812   order_subst2
   813   order_subst1
   814   ord_le_eq_subst
   815   ord_eq_le_subst
   816   ord_less_eq_subst
   817   ord_eq_less_subst
   818   forw_subst
   819   back_subst
   820   rev_mp
   821   mp
   822 
   823 lemmas (in order) [trans] =
   824   neq_le_trans
   825   le_neq_trans
   826 
   827 lemmas (in preorder) [trans] =
   828   less_trans
   829   less_asym'
   830   le_less_trans
   831   less_le_trans
   832   order_trans
   833 
   834 lemmas (in order) [trans] =
   835   antisym
   836 
   837 lemmas (in ord) [trans] =
   838   ord_le_eq_trans
   839   ord_eq_le_trans
   840   ord_less_eq_trans
   841   ord_eq_less_trans
   842 
   843 lemmas [trans] =
   844   trans
   845 
   846 lemmas order_trans_rules =
   847   order_less_subst2
   848   order_less_subst1
   849   order_le_less_subst2
   850   order_le_less_subst1
   851   order_less_le_subst2
   852   order_less_le_subst1
   853   order_subst2
   854   order_subst1
   855   ord_le_eq_subst
   856   ord_eq_le_subst
   857   ord_less_eq_subst
   858   ord_eq_less_subst
   859   forw_subst
   860   back_subst
   861   rev_mp
   862   mp
   863   neq_le_trans
   864   le_neq_trans
   865   less_trans
   866   less_asym'
   867   le_less_trans
   868   less_le_trans
   869   order_trans
   870   antisym
   871   ord_le_eq_trans
   872   ord_eq_le_trans
   873   ord_less_eq_trans
   874   ord_eq_less_trans
   875   trans
   876 
   877 (* FIXME cleanup *)
   878 
   879 text {* These support proving chains of decreasing inequalities
   880     a >= b >= c ... in Isar proofs. *}
   881 
   882 lemma xt1:
   883   "a = b ==> b > c ==> a > c"
   884   "a > b ==> b = c ==> a > c"
   885   "a = b ==> b >= c ==> a >= c"
   886   "a >= b ==> b = c ==> a >= c"
   887   "(x::'a::order) >= y ==> y >= x ==> x = y"
   888   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   889   "(x::'a::order) > y ==> y >= z ==> x > z"
   890   "(x::'a::order) >= y ==> y > z ==> x > z"
   891   "(a::'a::order) > b ==> b > a ==> P"
   892   "(x::'a::order) > y ==> y > z ==> x > z"
   893   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   894   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   895   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   896   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   897   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   898   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   899   by auto
   900 
   901 lemma xt2:
   902   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   903 by (subgoal_tac "f b >= f c", force, force)
   904 
   905 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   906     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   907 by (subgoal_tac "f a >= f b", force, force)
   908 
   909 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   910   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   911 by (subgoal_tac "f b >= f c", force, force)
   912 
   913 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   914     (!!x y. x > y ==> f x > f y) ==> f a > c"
   915 by (subgoal_tac "f a > f b", force, force)
   916 
   917 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   918     (!!x y. x > y ==> f x > f y) ==> a > f c"
   919 by (subgoal_tac "f b > f c", force, force)
   920 
   921 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   922     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   923 by (subgoal_tac "f a >= f b", force, force)
   924 
   925 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   926     (!!x y. x > y ==> f x > f y) ==> a > f c"
   927 by (subgoal_tac "f b > f c", force, force)
   928 
   929 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   930     (!!x y. x > y ==> f x > f y) ==> f a > c"
   931 by (subgoal_tac "f a > f b", force, force)
   932 
   933 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   934 
   935 (* 
   936   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   937   for the wrong thing in an Isar proof.
   938 
   939   The extra transitivity rules can be used as follows: 
   940 
   941 lemma "(a::'a::order) > z"
   942 proof -
   943   have "a >= b" (is "_ >= ?rhs")
   944     sorry
   945   also have "?rhs >= c" (is "_ >= ?rhs")
   946     sorry
   947   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   948     sorry
   949   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   950     sorry
   951   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   952     sorry
   953   also (xtrans) have "?rhs > z"
   954     sorry
   955   finally (xtrans) show ?thesis .
   956 qed
   957 
   958   Alternatively, one can use "declare xtrans [trans]" and then
   959   leave out the "(xtrans)" above.
   960 *)
   961 
   962 
   963 subsection {* Monotonicity, least value operator and min/max *}
   964 
   965 context order
   966 begin
   967 
   968 definition mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
   969   "mono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<le> f y)"
   970 
   971 lemma monoI [intro?]:
   972   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
   973   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<le> f y) \<Longrightarrow> mono f"
   974   unfolding mono_def by iprover
   975 
   976 lemma monoD [dest?]:
   977   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
   978   shows "mono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   979   unfolding mono_def by iprover
   980 
   981 definition strict_mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
   982   "strict_mono f \<longleftrightarrow> (\<forall>x y. x < y \<longrightarrow> f x < f y)"
   983 
   984 lemma strict_monoI [intro?]:
   985   assumes "\<And>x y. x < y \<Longrightarrow> f x < f y"
   986   shows "strict_mono f"
   987   using assms unfolding strict_mono_def by auto
   988 
   989 lemma strict_monoD [dest?]:
   990   "strict_mono f \<Longrightarrow> x < y \<Longrightarrow> f x < f y"
   991   unfolding strict_mono_def by auto
   992 
   993 lemma strict_mono_mono [dest?]:
   994   assumes "strict_mono f"
   995   shows "mono f"
   996 proof (rule monoI)
   997   fix x y
   998   assume "x \<le> y"
   999   show "f x \<le> f y"
  1000   proof (cases "x = y")
  1001     case True then show ?thesis by simp
  1002   next
  1003     case False with `x \<le> y` have "x < y" by simp
  1004     with assms strict_monoD have "f x < f y" by auto
  1005     then show ?thesis by simp
  1006   qed
  1007 qed
  1008 
  1009 end
  1010 
  1011 context linorder
  1012 begin
  1013 
  1014 lemma strict_mono_eq:
  1015   assumes "strict_mono f"
  1016   shows "f x = f y \<longleftrightarrow> x = y"
  1017 proof
  1018   assume "f x = f y"
  1019   show "x = y" proof (cases x y rule: linorder_cases)
  1020     case less with assms strict_monoD have "f x < f y" by auto
  1021     with `f x = f y` show ?thesis by simp
  1022   next
  1023     case equal then show ?thesis .
  1024   next
  1025     case greater with assms strict_monoD have "f y < f x" by auto
  1026     with `f x = f y` show ?thesis by simp
  1027   qed
  1028 qed simp
  1029 
  1030 lemma strict_mono_less_eq:
  1031   assumes "strict_mono f"
  1032   shows "f x \<le> f y \<longleftrightarrow> x \<le> y"
  1033 proof
  1034   assume "x \<le> y"
  1035   with assms strict_mono_mono monoD show "f x \<le> f y" by auto
  1036 next
  1037   assume "f x \<le> f y"
  1038   show "x \<le> y" proof (rule ccontr)
  1039     assume "\<not> x \<le> y" then have "y < x" by simp
  1040     with assms strict_monoD have "f y < f x" by auto
  1041     with `f x \<le> f y` show False by simp
  1042   qed
  1043 qed
  1044   
  1045 lemma strict_mono_less:
  1046   assumes "strict_mono f"
  1047   shows "f x < f y \<longleftrightarrow> x < y"
  1048   using assms
  1049     by (auto simp add: less_le Orderings.less_le strict_mono_eq strict_mono_less_eq)
  1050 
  1051 lemma min_of_mono:
  1052   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1053   shows "mono f \<Longrightarrow> min (f m) (f n) = f (min m n)"
  1054   by (auto simp: mono_def Orderings.min_def min_def intro: Orderings.antisym)
  1055 
  1056 lemma max_of_mono:
  1057   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1058   shows "mono f \<Longrightarrow> max (f m) (f n) = f (max m n)"
  1059   by (auto simp: mono_def Orderings.max_def max_def intro: Orderings.antisym)
  1060 
  1061 end
  1062 
  1063 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
  1064 by (simp add: min_def)
  1065 
  1066 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
  1067 by (simp add: max_def)
  1068 
  1069 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
  1070 apply (simp add: min_def)
  1071 apply (blast intro: order_antisym)
  1072 done
  1073 
  1074 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
  1075 apply (simp add: max_def)
  1076 apply (blast intro: order_antisym)
  1077 done
  1078 
  1079 
  1080 subsection {* Top and bottom elements *}
  1081 
  1082 class top = preorder +
  1083   fixes top :: 'a
  1084   assumes top_greatest [simp]: "x \<le> top"
  1085 
  1086 class bot = preorder +
  1087   fixes bot :: 'a
  1088   assumes bot_least [simp]: "bot \<le> x"
  1089 
  1090 
  1091 subsection {* Dense orders *}
  1092 
  1093 class dense_linear_order = linorder + 
  1094   assumes gt_ex: "\<exists>y. x < y" 
  1095   and lt_ex: "\<exists>y. y < x"
  1096   and dense: "x < y \<Longrightarrow> (\<exists>z. x < z \<and> z < y)"
  1097 
  1098 
  1099 subsection {* Wellorders *}
  1100 
  1101 class wellorder = linorder +
  1102   assumes less_induct [case_names less]: "(\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x) \<Longrightarrow> P a"
  1103 begin
  1104 
  1105 lemma wellorder_Least_lemma:
  1106   fixes k :: 'a
  1107   assumes "P k"
  1108   shows "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k"
  1109 proof -
  1110   have "P (LEAST x. P x) \<and> (LEAST x. P x) \<le> k"
  1111   using assms proof (induct k rule: less_induct)
  1112     case (less x) then have "P x" by simp
  1113     show ?case proof (rule classical)
  1114       assume assm: "\<not> (P (LEAST a. P a) \<and> (LEAST a. P a) \<le> x)"
  1115       have "\<And>y. P y \<Longrightarrow> x \<le> y"
  1116       proof (rule classical)
  1117         fix y
  1118         assume "P y" and "\<not> x \<le> y" 
  1119         with less have "P (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1120           by (auto simp add: not_le)
  1121         with assm have "x < (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1122           by auto
  1123         then show "x \<le> y" by auto
  1124       qed
  1125       with `P x` have Least: "(LEAST a. P a) = x"
  1126         by (rule Least_equality)
  1127       with `P x` show ?thesis by simp
  1128     qed
  1129   qed
  1130   then show "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k" by auto
  1131 qed
  1132 
  1133 lemmas LeastI   = wellorder_Least_lemma(1)
  1134 lemmas Least_le = wellorder_Least_lemma(2)
  1135 
  1136 -- "The following 3 lemmas are due to Brian Huffman"
  1137 lemma LeastI_ex: "\<exists>x. P x \<Longrightarrow> P (Least P)"
  1138   by (erule exE) (erule LeastI)
  1139 
  1140 lemma LeastI2:
  1141   "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1142   by (blast intro: LeastI)
  1143 
  1144 lemma LeastI2_ex:
  1145   "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1146   by (blast intro: LeastI_ex)
  1147 
  1148 lemma not_less_Least: "k < (LEAST x. P x) \<Longrightarrow> \<not> P k"
  1149 apply (simp (no_asm_use) add: not_le [symmetric])
  1150 apply (erule contrapos_nn)
  1151 apply (erule Least_le)
  1152 done
  1153 
  1154 end  
  1155 
  1156 
  1157 subsection {* Order on bool *}
  1158 
  1159 instantiation bool :: "{order, top, bot}"
  1160 begin
  1161 
  1162 definition
  1163   le_bool_def [code del]: "P \<le> Q \<longleftrightarrow> P \<longrightarrow> Q"
  1164 
  1165 definition
  1166   less_bool_def [code del]: "(P\<Colon>bool) < Q \<longleftrightarrow> \<not> P \<and> Q"
  1167 
  1168 definition
  1169   top_bool_eq: "top = True"
  1170 
  1171 definition
  1172   bot_bool_eq: "bot = False"
  1173 
  1174 instance proof
  1175 qed (auto simp add: le_bool_def less_bool_def top_bool_eq bot_bool_eq)
  1176 
  1177 end
  1178 
  1179 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
  1180 by (simp add: le_bool_def)
  1181 
  1182 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
  1183 by (simp add: le_bool_def)
  1184 
  1185 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
  1186 by (simp add: le_bool_def)
  1187 
  1188 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
  1189 by (simp add: le_bool_def)
  1190 
  1191 lemma [code]:
  1192   "False \<le> b \<longleftrightarrow> True"
  1193   "True \<le> b \<longleftrightarrow> b"
  1194   "False < b \<longleftrightarrow> b"
  1195   "True < b \<longleftrightarrow> False"
  1196   unfolding le_bool_def less_bool_def by simp_all
  1197 
  1198 
  1199 subsection {* Order on functions *}
  1200 
  1201 instantiation "fun" :: (type, ord) ord
  1202 begin
  1203 
  1204 definition
  1205   le_fun_def [code del]: "f \<le> g \<longleftrightarrow> (\<forall>x. f x \<le> g x)"
  1206 
  1207 definition
  1208   less_fun_def [code del]: "(f\<Colon>'a \<Rightarrow> 'b) < g \<longleftrightarrow> f \<le> g \<and> \<not> (g \<le> f)"
  1209 
  1210 instance ..
  1211 
  1212 end
  1213 
  1214 instance "fun" :: (type, preorder) preorder proof
  1215 qed (auto simp add: le_fun_def less_fun_def
  1216   intro: order_trans order_antisym intro!: ext)
  1217 
  1218 instance "fun" :: (type, order) order proof
  1219 qed (auto simp add: le_fun_def intro: order_antisym ext)
  1220 
  1221 instantiation "fun" :: (type, top) top
  1222 begin
  1223 
  1224 definition
  1225   top_fun_eq: "top = (\<lambda>x. top)"
  1226 
  1227 instance proof
  1228 qed (simp add: top_fun_eq le_fun_def)
  1229 
  1230 end
  1231 
  1232 instantiation "fun" :: (type, bot) bot
  1233 begin
  1234 
  1235 definition
  1236   bot_fun_eq: "bot = (\<lambda>x. bot)"
  1237 
  1238 instance proof
  1239 qed (simp add: bot_fun_eq le_fun_def)
  1240 
  1241 end
  1242 
  1243 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
  1244   unfolding le_fun_def by simp
  1245 
  1246 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
  1247   unfolding le_fun_def by simp
  1248 
  1249 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
  1250   unfolding le_fun_def by simp
  1251 
  1252 text {*
  1253   Handy introduction and elimination rules for @{text "\<le>"}
  1254   on unary and binary predicates
  1255 *}
  1256 
  1257 lemma predicate1I:
  1258   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
  1259   shows "P \<le> Q"
  1260   apply (rule le_funI)
  1261   apply (rule le_boolI)
  1262   apply (rule PQ)
  1263   apply assumption
  1264   done
  1265 
  1266 lemma predicate1D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
  1267   apply (erule le_funE)
  1268   apply (erule le_boolE)
  1269   apply assumption+
  1270   done
  1271 
  1272 lemma predicate2I [Pure.intro!, intro!]:
  1273   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1274   shows "P \<le> Q"
  1275   apply (rule le_funI)+
  1276   apply (rule le_boolI)
  1277   apply (rule PQ)
  1278   apply assumption
  1279   done
  1280 
  1281 lemma predicate2D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1282   apply (erule le_funE)+
  1283   apply (erule le_boolE)
  1284   apply assumption+
  1285   done
  1286 
  1287 lemma rev_predicate1D: "P x ==> P <= Q ==> Q x"
  1288   by (rule predicate1D)
  1289 
  1290 lemma rev_predicate2D: "P x y ==> P <= Q ==> Q x y"
  1291   by (rule predicate2D)
  1292 
  1293 end