src/HOLCF/Tools/fixrec_package.ML
author wenzelm
Sun Mar 08 17:26:14 2009 +0100 (2009-03-08)
changeset 30364 577edc39b501
parent 30280 eb98b49ef835
child 30485 99def5248e7f
permissions -rw-r--r--
moved basic algebra of long names from structure NameSpace to Long_Name;
     1 (*  Title:      HOLCF/Tools/fixrec_package.ML
     2     Author:     Amber Telfer and Brian Huffman
     3 
     4 Recursive function definition package for HOLCF.
     5 *)
     6 
     7 signature FIXREC_PACKAGE =
     8 sig
     9   val legacy_infer_term: theory -> term -> term
    10   val legacy_infer_prop: theory -> term -> term
    11 
    12   val add_fixrec: bool -> (binding * string option * mixfix) list
    13     -> (Attrib.binding * string) list -> local_theory -> local_theory
    14 
    15   val add_fixrec_i: bool -> (binding * typ option * mixfix) list
    16     -> (Attrib.binding * term) list -> local_theory -> local_theory
    17 
    18   val add_fixpat: Attrib.binding * string list -> theory -> theory
    19   val add_fixpat_i: Thm.binding * term list -> theory -> theory
    20   val add_matchers: (string * string) list -> theory -> theory
    21   val setup: theory -> theory
    22 end;
    23 
    24 structure FixrecPackage: FIXREC_PACKAGE =
    25 struct
    26 
    27 (* legacy type inference *)
    28 (* used by the domain package *)
    29 fun legacy_infer_term thy t =
    30   singleton (Syntax.check_terms (ProofContext.init thy)) (Sign.intern_term thy t);
    31 
    32 fun legacy_infer_prop thy t = legacy_infer_term thy (TypeInfer.constrain propT t);
    33 
    34 
    35 val fix_eq2 = @{thm fix_eq2};
    36 val def_fix_ind = @{thm def_fix_ind};
    37 
    38 
    39 fun fixrec_err s = error ("fixrec definition error:\n" ^ s);
    40 fun fixrec_eq_err thy s eq =
    41   fixrec_err (s ^ "\nin\n" ^ quote (Syntax.string_of_term_global thy eq));
    42 
    43 (*************************************************************************)
    44 (***************************** building types ****************************)
    45 (*************************************************************************)
    46 
    47 (* ->> is taken from holcf_logic.ML *)
    48 fun cfunT (T, U) = Type(@{type_name "->"}, [T, U]);
    49 
    50 infixr 6 ->>; val (op ->>) = cfunT;
    51 
    52 fun dest_cfunT (Type(@{type_name "->"}, [T, U])) = (T, U)
    53   | dest_cfunT T = raise TYPE ("dest_cfunT", [T], []);
    54 
    55 fun binder_cfun (Type(@{type_name "->"},[T, U])) = T :: binder_cfun U
    56   | binder_cfun _   =  [];
    57 
    58 fun body_cfun (Type(@{type_name "->"},[T, U])) = body_cfun U
    59   | body_cfun T   =  T;
    60 
    61 fun strip_cfun T : typ list * typ =
    62   (binder_cfun T, body_cfun T);
    63 
    64 fun maybeT T = Type(@{type_name "maybe"}, [T]);
    65 
    66 fun dest_maybeT (Type(@{type_name "maybe"}, [T])) = T
    67   | dest_maybeT T = raise TYPE ("dest_maybeT", [T], []);
    68 
    69 fun tupleT [] = @{typ "unit"}
    70   | tupleT [T] = T
    71   | tupleT (T :: Ts) = HOLogic.mk_prodT (T, tupleT Ts);
    72 
    73 fun matchT T = body_cfun T ->> maybeT (tupleT (binder_cfun T));
    74 
    75 (*************************************************************************)
    76 (***************************** building terms ****************************)
    77 (*************************************************************************)
    78 
    79 val mk_trp = HOLogic.mk_Trueprop;
    80 
    81 (* splits a cterm into the right and lefthand sides of equality *)
    82 fun dest_eqs t = HOLogic.dest_eq (HOLogic.dest_Trueprop t);
    83 
    84 (* similar to Thm.head_of, but for continuous application *)
    85 fun chead_of (Const(@{const_name Rep_CFun},_)$f$t) = chead_of f
    86   | chead_of u = u;
    87 
    88 fun capply_const (S, T) =
    89   Const(@{const_name Rep_CFun}, (S ->> T) --> (S --> T));
    90 
    91 fun cabs_const (S, T) =
    92   Const(@{const_name Abs_CFun}, (S --> T) --> (S ->> T));
    93 
    94 fun mk_capply (t, u) =
    95   let val (S, T) =
    96     case Term.fastype_of t of
    97         Type(@{type_name "->"}, [S, T]) => (S, T)
    98       | _ => raise TERM ("mk_capply " ^ ML_Syntax.print_list ML_Syntax.print_term [t, u], [t, u]);
    99   in capply_const (S, T) $ t $ u end;
   100 
   101 infix 0 ==;  val (op ==) = Logic.mk_equals;
   102 infix 1 ===; val (op ===) = HOLogic.mk_eq;
   103 infix 9 `  ; val (op `) = mk_capply;
   104 
   105 
   106 fun mk_cpair (t, u) =
   107   let val T = Term.fastype_of t
   108       val U = Term.fastype_of u
   109       val cpairT = T ->> U ->> HOLogic.mk_prodT (T, U)
   110   in Const(@{const_name cpair}, cpairT) ` t ` u end;
   111 
   112 fun mk_cfst t =
   113   let val T = Term.fastype_of t;
   114       val (U, _) = HOLogic.dest_prodT T;
   115   in Const(@{const_name cfst}, T ->> U) ` t end;
   116 
   117 fun mk_csnd t =
   118   let val T = Term.fastype_of t;
   119       val (_, U) = HOLogic.dest_prodT T;
   120   in Const(@{const_name csnd}, T ->> U) ` t end;
   121 
   122 fun mk_csplit t =
   123   let val (S, TU) = dest_cfunT (Term.fastype_of t);
   124       val (T, U) = dest_cfunT TU;
   125       val csplitT = (S ->> T ->> U) ->> HOLogic.mk_prodT (S, T) ->> U;
   126   in Const(@{const_name csplit}, csplitT) ` t end;
   127 
   128 (* builds the expression (LAM v. rhs) *)
   129 fun big_lambda v rhs =
   130   cabs_const (Term.fastype_of v, Term.fastype_of rhs) $ Term.lambda v rhs;
   131 
   132 (* builds the expression (LAM v1 v2 .. vn. rhs) *)
   133 fun big_lambdas [] rhs = rhs
   134   | big_lambdas (v::vs) rhs = big_lambda v (big_lambdas vs rhs);
   135 
   136 (* builds the expression (LAM <v1,v2,..,vn>. rhs) *)
   137 fun lambda_ctuple [] rhs = big_lambda (Free("unit", HOLogic.unitT)) rhs
   138   | lambda_ctuple (v::[]) rhs = big_lambda v rhs
   139   | lambda_ctuple (v::vs) rhs =
   140       mk_csplit (big_lambda v (lambda_ctuple vs rhs));
   141 
   142 (* builds the expression <v1,v2,..,vn> *)
   143 fun mk_ctuple [] = @{term "UU::unit"}
   144 |   mk_ctuple (t::[]) = t
   145 |   mk_ctuple (t::ts) = mk_cpair (t, mk_ctuple ts);
   146 
   147 fun mk_return t =
   148   let val T = Term.fastype_of t
   149   in Const(@{const_name Fixrec.return}, T ->> maybeT T) ` t end;
   150 
   151 fun mk_bind (t, u) =
   152   let val (T, mU) = dest_cfunT (Term.fastype_of u);
   153       val bindT = maybeT T ->> (T ->> mU) ->> mU;
   154   in Const(@{const_name Fixrec.bind}, bindT) ` t ` u end;
   155 
   156 fun mk_mplus (t, u) =
   157   let val mT = Term.fastype_of t
   158   in Const(@{const_name Fixrec.mplus}, mT ->> mT ->> mT) ` t ` u end;
   159 
   160 fun mk_run t =
   161   let val mT = Term.fastype_of t
   162       val T = dest_maybeT mT
   163   in Const(@{const_name Fixrec.run}, mT ->> T) ` t end;
   164 
   165 fun mk_fix t =
   166   let val (T, _) = dest_cfunT (Term.fastype_of t)
   167   in Const(@{const_name fix}, (T ->> T) ->> T) ` t end;
   168 
   169 (*************************************************************************)
   170 (************* fixed-point definitions and unfolding theorems ************)
   171 (*************************************************************************)
   172 
   173 fun add_fixdefs
   174   (fixes : ((binding * typ) * mixfix) list)
   175   (spec : (Attrib.binding * term) list)
   176   (lthy : local_theory) =
   177   let
   178     val names = map (Binding.name_of o fst o fst) fixes;
   179     val all_names = space_implode "_" names;
   180     val (lhss,rhss) = ListPair.unzip (map (dest_eqs o snd) spec);
   181     val fixpoint = mk_fix (lambda_ctuple lhss (mk_ctuple rhss));
   182     
   183     fun one_def (l as Free(n,_)) r =
   184           let val b = Long_Name.base_name n
   185           in ((Binding.name (b^"_def"), []), r) end
   186       | one_def _ _ = fixrec_err "fixdefs: lhs not of correct form";
   187     fun defs [] _ = []
   188       | defs (l::[]) r = [one_def l r]
   189       | defs (l::ls) r = one_def l (mk_cfst r) :: defs ls (mk_csnd r);
   190     val fixdefs = defs lhss fixpoint;
   191     val define_all = fold_map (LocalTheory.define Thm.definitionK);
   192     val (fixdef_thms : (term * (string * thm)) list, lthy') = lthy
   193       |> define_all (map (apfst fst) fixes ~~ fixdefs);
   194     fun cpair_equalI (thm1, thm2) = @{thm cpair_equalI} OF [thm1, thm2];
   195     val ctuple_fixdef_thm = foldr1 cpair_equalI (map (snd o snd) fixdef_thms);
   196     val ctuple_induct_thm = ctuple_fixdef_thm RS def_fix_ind;
   197     val ctuple_unfold_thm =
   198       Goal.prove lthy' [] [] (mk_trp (mk_ctuple lhss === mk_ctuple rhss))
   199         (fn _ => EVERY [rtac (ctuple_fixdef_thm RS fix_eq2 RS trans) 1,
   200                    simp_tac (local_simpset_of lthy') 1]);
   201     fun unfolds [] thm = []
   202       | unfolds (n::[]) thm = [(n^"_unfold", thm)]
   203       | unfolds (n::ns) thm = let
   204           val thmL = thm RS @{thm cpair_eqD1};
   205           val thmR = thm RS @{thm cpair_eqD2};
   206         in (n^"_unfold", thmL) :: unfolds ns thmR end;
   207     val unfold_thms = unfolds names ctuple_unfold_thm;
   208     fun mk_note (n, thm) = ((Binding.name n, []), [thm]);
   209     val (thmss, lthy'') = lthy'
   210       |> fold_map (LocalTheory.note Thm.theoremK o mk_note)
   211         ((all_names ^ "_induct", ctuple_induct_thm) :: unfold_thms);
   212   in
   213     (lthy'', names, fixdef_thms, map snd unfold_thms)
   214   end;
   215 
   216 (*************************************************************************)
   217 (*********** monadic notation and pattern matching compilation ***********)
   218 (*************************************************************************)
   219 
   220 structure FixrecMatchData = TheoryDataFun (
   221   type T = string Symtab.table;
   222   val empty = Symtab.empty;
   223   val copy = I;
   224   val extend = I;
   225   fun merge _ tabs : T = Symtab.merge (K true) tabs;
   226 );
   227 
   228 (* associate match functions with pattern constants *)
   229 fun add_matchers ms = FixrecMatchData.map (fold Symtab.update ms);
   230 
   231 fun taken_names (t : term) : bstring list =
   232   let
   233     fun taken (Const(a,_), bs) = insert (op =) (Long_Name.base_name a) bs
   234       | taken (Free(a,_) , bs) = insert (op =) a bs
   235       | taken (f $ u     , bs) = taken (f, taken (u, bs))
   236       | taken (Abs(a,_,t), bs) = taken (t, insert (op =) a bs)
   237       | taken (_         , bs) = bs;
   238   in
   239     taken (t, [])
   240   end;
   241 
   242 (* builds a monadic term for matching a constructor pattern *)
   243 fun pre_build match_name pat rhs vs taken =
   244   case pat of
   245     Const(@{const_name Rep_CFun},_)$f$(v as Free(n,T)) =>
   246       pre_build match_name f rhs (v::vs) taken
   247   | Const(@{const_name Rep_CFun},_)$f$x =>
   248       let val (rhs', v, taken') = pre_build match_name x rhs [] taken;
   249       in pre_build match_name f rhs' (v::vs) taken' end
   250   | Const(c,T) =>
   251       let
   252         val n = Name.variant taken "v";
   253         fun result_type (Type(@{type_name "->"},[_,T])) (x::xs) = result_type T xs
   254           | result_type T _ = T;
   255         val v = Free(n, result_type T vs);
   256         val m = Const(match_name c, matchT T);
   257         val k = lambda_ctuple vs rhs;
   258       in
   259         (mk_bind (m`v, k), v, n::taken)
   260       end
   261   | Free(n,_) => fixrec_err ("expected constructor, found free variable " ^ quote n)
   262   | _ => fixrec_err "pre_build: invalid pattern";
   263 
   264 (* builds a monadic term for matching a function definition pattern *)
   265 (* returns (name, arity, matcher) *)
   266 fun building match_name pat rhs vs taken =
   267   case pat of
   268     Const(@{const_name Rep_CFun}, _)$f$(v as Free(n,T)) =>
   269       building match_name f rhs (v::vs) taken
   270   | Const(@{const_name Rep_CFun}, _)$f$x =>
   271       let val (rhs', v, taken') = pre_build match_name x rhs [] taken;
   272       in building match_name f rhs' (v::vs) taken' end
   273   | Free(_,_) => ((pat, length vs), big_lambdas vs rhs)
   274   | Const(_,_) => ((pat, length vs), big_lambdas vs rhs)
   275   | _ => fixrec_err ("function is not declared as constant in theory: "
   276                     ^ ML_Syntax.print_term pat);
   277 
   278 fun strip_alls t =
   279   if Logic.is_all t then strip_alls (snd (Logic.dest_all t)) else t;
   280 
   281 fun match_eq match_name eq =
   282   let
   283     val (lhs,rhs) = dest_eqs (Logic.strip_imp_concl (strip_alls eq));
   284   in
   285     building match_name lhs (mk_return rhs) [] (taken_names eq)
   286   end;
   287 
   288 (* returns the sum (using +++) of the terms in ms *)
   289 (* also applies "run" to the result! *)
   290 fun fatbar arity ms =
   291   let
   292     fun LAM_Ts 0 t = ([], Term.fastype_of t)
   293       | LAM_Ts n (_ $ Abs(_,T,t)) =
   294           let val (Ts, U) = LAM_Ts (n-1) t in (T::Ts, U) end
   295       | LAM_Ts _ _ = fixrec_err "fatbar: internal error, not enough LAMs";
   296     fun unLAM 0 t = t
   297       | unLAM n (_$Abs(_,_,t)) = unLAM (n-1) t
   298       | unLAM _ _ = fixrec_err "fatbar: internal error, not enough LAMs";
   299     fun reLAM ([], U) t = t
   300       | reLAM (T::Ts, U) t = reLAM (Ts, T ->> U) (cabs_const(T,U)$Abs("",T,t));
   301     val msum = foldr1 mk_mplus (map (unLAM arity) ms);
   302     val (Ts, U) = LAM_Ts arity (hd ms)
   303   in
   304     reLAM (rev Ts, dest_maybeT U) (mk_run msum)
   305   end;
   306 
   307 (* this is the pattern-matching compiler function *)
   308 fun compile_pats match_name eqs =
   309   let
   310     val (((n::names),(a::arities)),mats) =
   311       apfst ListPair.unzip (ListPair.unzip (map (match_eq match_name) eqs));
   312     val cname = if forall (fn x => n=x) names then n
   313           else fixrec_err "all equations in block must define the same function";
   314     val arity = if forall (fn x => a=x) arities then a
   315           else fixrec_err "all equations in block must have the same arity";
   316     val rhs = fatbar arity mats;
   317   in
   318     mk_trp (cname === rhs)
   319   end;
   320 
   321 (*************************************************************************)
   322 (********************** Proving associated theorems **********************)
   323 (*************************************************************************)
   324 
   325 (* proves a block of pattern matching equations as theorems, using unfold *)
   326 fun make_simps lthy (unfold_thm, eqns : (Attrib.binding * term) list) =
   327   let
   328     val tacs =
   329       [rtac (unfold_thm RS @{thm ssubst_lhs}) 1,
   330        asm_simp_tac (local_simpset_of lthy) 1];
   331     fun prove_term t = Goal.prove lthy [] [] t (K (EVERY tacs));
   332     fun prove_eqn (bind, eqn_t) = (bind, prove_term eqn_t);
   333   in
   334     map prove_eqn eqns
   335   end;
   336 
   337 (*************************************************************************)
   338 (************************* Main fixrec function **************************)
   339 (*************************************************************************)
   340 
   341 local
   342 (* code adapted from HOL/Tools/primrec_package.ML *)
   343 
   344 fun prepare_spec prep_spec ctxt raw_fixes raw_spec =
   345   let
   346     val ((fixes, spec), _) = prep_spec
   347       raw_fixes (map (single o apsnd single) raw_spec) ctxt
   348   in (fixes, map (apsnd the_single) spec) end;
   349 
   350 fun gen_fixrec
   351   (set_group : bool)
   352   (prep_spec : (binding * 'a option * mixfix) list ->
   353        (Attrib.binding * 'b list) list list ->
   354       Proof.context ->
   355    (((binding * typ) * mixfix) list * (Attrib.binding * term list) list)
   356     * Proof.context
   357   )
   358   (strict : bool)
   359   raw_fixes
   360   raw_spec
   361   (lthy : local_theory) =
   362   let
   363     val (fixes : ((binding * typ) * mixfix) list,
   364          spec : (Attrib.binding * term) list) =
   365           prepare_spec prep_spec lthy raw_fixes raw_spec;
   366     val chead_of_spec =
   367       chead_of o fst o dest_eqs o Logic.strip_imp_concl o strip_alls o snd;
   368     fun name_of (Free (n, _)) = n
   369       | name_of t = fixrec_err ("unknown term");
   370     val all_names = map (name_of o chead_of_spec) spec;
   371     val names = distinct (op =) all_names;
   372     fun block_of_name n =
   373       map_filter
   374         (fn (m,eq) => if m = n then SOME eq else NONE)
   375         (all_names ~~ spec);
   376     val blocks = map block_of_name names;
   377 
   378     val matcher_tab = FixrecMatchData.get (ProofContext.theory_of lthy);
   379     fun match_name c =
   380       case Symtab.lookup matcher_tab c of SOME m => m
   381         | NONE => fixrec_err ("unknown pattern constructor: " ^ c);
   382 
   383     val matches = map (compile_pats match_name) (map (map snd) blocks);
   384     val spec' = map (pair Attrib.empty_binding) matches;
   385     val (lthy', cnames, fixdef_thms, unfold_thms) =
   386       add_fixdefs fixes spec' lthy;
   387   in
   388     if strict then let (* only prove simp rules if strict = true *)
   389       val simps : (Attrib.binding * thm) list list =
   390         map (make_simps lthy') (unfold_thms ~~ blocks);
   391       fun mk_bind n : Attrib.binding =
   392        (Binding.name (n ^ "_simps"),
   393          [Attrib.internal (K Simplifier.simp_add)]);
   394       val simps1 : (Attrib.binding * thm list) list =
   395         map (fn (n,xs) => (mk_bind n, map snd xs)) (names ~~ simps);
   396       val simps2 : (Attrib.binding * thm list) list =
   397         map (apsnd (fn thm => [thm])) (List.concat simps);
   398       val (_, lthy'') = lthy'
   399         |> fold_map (LocalTheory.note Thm.theoremK) (simps1 @ simps2);
   400     in
   401       lthy''
   402     end
   403     else lthy'
   404   end;
   405 
   406 in
   407 
   408 val add_fixrec_i = gen_fixrec false Specification.check_specification;
   409 val add_fixrec = gen_fixrec true Specification.read_specification;
   410 
   411 end; (* local *)
   412 
   413 (*************************************************************************)
   414 (******************************** Fixpat *********************************)
   415 (*************************************************************************)
   416 
   417 fun fix_pat thy t = 
   418   let
   419     val T = fastype_of t;
   420     val eq = mk_trp (HOLogic.eq_const T $ t $ Var (("x",0),T));
   421     val cname = case chead_of t of Const(c,_) => c | _ =>
   422               fixrec_err "function is not declared as constant in theory";
   423     val unfold_thm = PureThy.get_thm thy (cname^"_unfold");
   424     val simp = Goal.prove_global thy [] [] eq
   425           (fn _ => EVERY [stac unfold_thm 1, simp_tac (simpset_of thy) 1]);
   426   in simp end;
   427 
   428 fun gen_add_fixpat prep_term prep_attrib ((name, srcs), strings) thy =
   429   let
   430     val atts = map (prep_attrib thy) srcs;
   431     val ts = map (prep_term thy) strings;
   432     val simps = map (fix_pat thy) ts;
   433   in
   434     (snd o PureThy.add_thmss [((name, simps), atts)]) thy
   435   end;
   436 
   437 val add_fixpat = gen_add_fixpat Syntax.read_term_global Attrib.attribute;
   438 val add_fixpat_i = gen_add_fixpat Sign.cert_term (K I);
   439 
   440 
   441 (*************************************************************************)
   442 (******************************** Parsers ********************************)
   443 (*************************************************************************)
   444 
   445 local structure P = OuterParse and K = OuterKeyword in
   446 
   447 (* bool parser *)
   448 val fixrec_strict = P.opt_keyword "permissive" >> not;
   449 
   450 fun pipe_error t = P.!!! (Scan.fail_with (K
   451   (cat_lines ["Equations must be separated by " ^ quote "|", quote t])));
   452 
   453 (* (Attrib.binding * string) parser *)
   454 val statement = SpecParse.opt_thm_name ":" -- P.prop --| Scan.ahead
   455   ((P.term :-- pipe_error) || Scan.succeed ("",""));
   456 
   457 (* ((Attrib.binding * string) list) parser *)
   458 val statements = P.enum1 "|" statement;
   459 
   460 (* (((xstring option * bool) * (Binding.binding * string option * Mixfix.mixfix) list)
   461    * (Attrib.binding * string) list) parser *)
   462 val fixrec_decl =
   463   P.opt_target -- fixrec_strict -- P.fixes --| P.$$$ "where" -- statements;
   464 
   465 (* this builds a parser for a new keyword, fixrec, whose functionality 
   466 is defined by add_fixrec *)
   467 val _ =
   468   let
   469     val desc = "define recursive functions (HOLCF)";
   470     fun fixrec (((opt_target, strict), raw_fixes), raw_spec) =
   471       Toplevel.local_theory opt_target (add_fixrec strict raw_fixes raw_spec);
   472   in
   473     OuterSyntax.command "fixrec" desc K.thy_decl (fixrec_decl >> fixrec)
   474   end;
   475 
   476 (* fixpat parser *)
   477 val fixpat_decl = SpecParse.opt_thm_name ":" -- Scan.repeat1 P.prop;
   478 
   479 val _ =
   480   OuterSyntax.command "fixpat" "define rewrites for fixrec functions" K.thy_decl
   481     (fixpat_decl >> (Toplevel.theory o add_fixpat));
   482   
   483 end; (* local structure *)
   484 
   485 val setup = FixrecMatchData.init;
   486 
   487 end;