src/Pure/Proof/proof_syntax.ML
author wenzelm
Sun Mar 08 17:26:14 2009 +0100 (2009-03-08)
changeset 30364 577edc39b501
parent 30344 10a67c5ddddb
child 30435 e62d6ecab6ad
permissions -rw-r--r--
moved basic algebra of long names from structure NameSpace to Long_Name;
     1 (*  Title:      Pure/Proof/proof_syntax.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 Function for parsing and printing proof terms.
     5 *)
     6 
     7 signature PROOF_SYNTAX =
     8 sig
     9   val proofT: typ
    10   val add_proof_syntax: theory -> theory
    11   val proof_of_term: theory -> bool -> term -> Proofterm.proof
    12   val term_of_proof: Proofterm.proof -> term
    13   val cterm_of_proof: theory -> Proofterm.proof -> cterm * (cterm -> Proofterm.proof)
    14   val read_term: theory -> typ -> string -> term
    15   val read_proof: theory -> bool -> string -> Proofterm.proof
    16   val proof_syntax: Proofterm.proof -> theory -> theory
    17   val proof_of: bool -> thm -> Proofterm.proof
    18   val pretty_proof: Proof.context -> Proofterm.proof -> Pretty.T
    19   val pretty_proof_of: Proof.context -> bool -> thm -> Pretty.T
    20 end;
    21 
    22 structure ProofSyntax : PROOF_SYNTAX =
    23 struct
    24 
    25 open Proofterm;
    26 
    27 (**** add special syntax for embedding proof terms ****)
    28 
    29 val proofT = Type ("proof", []);
    30 val paramT = Type ("param", []);
    31 val paramsT = Type ("params", []);
    32 val idtT = Type ("idt", []);
    33 val aT = TFree (Name.aT, []);
    34 
    35 (** constants for theorems and axioms **)
    36 
    37 fun add_proof_atom_consts names thy =
    38   thy
    39   |> Sign.absolute_path
    40   |> Sign.add_consts_i (map (fn name => (Binding.name name, proofT, NoSyn)) names);
    41 
    42 (** constants for application and abstraction **)
    43 
    44 fun add_proof_syntax thy =
    45   thy
    46   |> Theory.copy
    47   |> Sign.root_path
    48   |> Sign.add_defsort_i []
    49   |> Sign.add_types [(Binding.name "proof", 0, NoSyn)]
    50   |> Sign.add_consts_i
    51       [(Binding.name "Appt", [proofT, aT] ---> proofT, Mixfix ("(1_ %/ _)", [4, 5], 4)),
    52        (Binding.name "AppP", [proofT, proofT] ---> proofT, Mixfix ("(1_ %%/ _)", [4, 5], 4)),
    53        (Binding.name "Abst", (aT --> proofT) --> proofT, NoSyn),
    54        (Binding.name "AbsP", [propT, proofT --> proofT] ---> proofT, NoSyn),
    55        (Binding.name "Hyp", propT --> proofT, NoSyn),
    56        (Binding.name "Oracle", propT --> proofT, NoSyn),
    57        (Binding.name "MinProof", proofT, Delimfix "?")]
    58   |> Sign.add_nonterminals [Binding.name "param", Binding.name "params"]
    59   |> Sign.add_syntax_i
    60       [("_Lam", [paramsT, proofT] ---> proofT, Mixfix ("(1Lam _./ _)", [0, 3], 3)),
    61        ("_Lam0", [paramT, paramsT] ---> paramsT, Mixfix ("_/ _", [1, 0], 0)),
    62        ("_Lam0", [idtT, paramsT] ---> paramsT, Mixfix ("_/ _", [1, 0], 0)),
    63        ("_Lam1", [idtT, propT] ---> paramT, Mixfix ("_: _", [0, 0], 0)),
    64        ("", paramT --> paramT, Delimfix "'(_')"),
    65        ("", idtT --> paramsT, Delimfix "_"),
    66        ("", paramT --> paramsT, Delimfix "_")]
    67   |> Sign.add_modesyntax_i ("xsymbols", true)
    68       [("_Lam", [paramsT, proofT] ---> proofT, Mixfix ("(1\\<Lambda>_./ _)", [0, 3], 3)),
    69        ("Appt", [proofT, aT] ---> proofT, Mixfix ("(1_ \\<cdot>/ _)", [4, 5], 4)),
    70        ("AppP", [proofT, proofT] ---> proofT, Mixfix ("(1_ \\<bullet>/ _)", [4, 5], 4))]
    71   |> Sign.add_modesyntax_i ("latex", false)
    72       [("_Lam", [paramsT, proofT] ---> proofT, Mixfix ("(1\\<^bold>\\<lambda>_./ _)", [0, 3], 3))]
    73   |> Sign.add_trrules_i (map Syntax.ParsePrintRule
    74       [(Syntax.mk_appl (Constant "_Lam")
    75           [Syntax.mk_appl (Constant "_Lam0") [Variable "l", Variable "m"], Variable "A"],
    76         Syntax.mk_appl (Constant "_Lam")
    77           [Variable "l", Syntax.mk_appl (Constant "_Lam") [Variable "m", Variable "A"]]),
    78        (Syntax.mk_appl (Constant "_Lam")
    79           [Syntax.mk_appl (Constant "_Lam1") [Variable "x", Variable "A"], Variable "B"],
    80         Syntax.mk_appl (Constant "AbsP") [Variable "A",
    81           (Syntax.mk_appl (Constant "_abs") [Variable "x", Variable "B"])]),
    82        (Syntax.mk_appl (Constant "_Lam") [Variable "x", Variable "A"],
    83         Syntax.mk_appl (Constant "Abst")
    84           [(Syntax.mk_appl (Constant "_abs") [Variable "x", Variable "A"])])]);
    85 
    86 
    87 (**** translation between proof terms and pure terms ****)
    88 
    89 fun proof_of_term thy ty =
    90   let
    91     val thms = PureThy.all_thms_of thy;
    92     val axms = Theory.all_axioms_of thy;
    93 
    94     fun mk_term t = (if ty then I else map_types (K dummyT))
    95       (Term.no_dummy_patterns t);
    96 
    97     fun prf_of [] (Bound i) = PBound i
    98       | prf_of Ts (Const (s, Type ("proof", _))) =
    99           change_type (if ty then SOME Ts else NONE)
   100             (case Long_Name.explode s of
   101                "axm" :: xs =>
   102                  let
   103                    val name = Long_Name.implode xs;
   104                    val prop = (case AList.lookup (op =) axms name of
   105                        SOME prop => prop
   106                      | NONE => error ("Unknown axiom " ^ quote name))
   107                  in PAxm (name, prop, NONE) end
   108              | "thm" :: xs =>
   109                  let val name = Long_Name.implode xs;
   110                  in (case AList.lookup (op =) thms name of
   111                      SOME thm => fst (strip_combt (Thm.proof_of thm))
   112                    | NONE => error ("Unknown theorem " ^ quote name))
   113                  end
   114              | _ => error ("Illegal proof constant name: " ^ quote s))
   115       | prf_of Ts (Const ("Hyp", _) $ prop) = Hyp prop
   116       | prf_of Ts (v as Var ((_, Type ("proof", _)))) = Hyp v
   117       | prf_of [] (Const ("Abst", _) $ Abs (s, T, prf)) =
   118           if T = proofT then
   119             error ("Term variable abstraction may not bind proof variable " ^ quote s)
   120           else Abst (s, if ty then SOME T else NONE,
   121             incr_pboundvars (~1) 0 (prf_of [] prf))
   122       | prf_of [] (Const ("AbsP", _) $ t $ Abs (s, _, prf)) =
   123           AbsP (s, case t of
   124                 Const ("dummy_pattern", _) => NONE
   125               | _ $ Const ("dummy_pattern", _) => NONE
   126               | _ => SOME (mk_term t),
   127             incr_pboundvars 0 (~1) (prf_of [] prf))
   128       | prf_of [] (Const ("AppP", _) $ prf1 $ prf2) =
   129           prf_of [] prf1 %% prf_of [] prf2
   130       | prf_of Ts (Const ("Appt", _) $ prf $ Const ("TYPE", Type (_, [T]))) =
   131           prf_of (T::Ts) prf
   132       | prf_of [] (Const ("Appt", _) $ prf $ t) = prf_of [] prf %
   133           (case t of Const ("dummy_pattern", _) => NONE | _ => SOME (mk_term t))
   134       | prf_of _ t = error ("Not a proof term:\n" ^
   135           Syntax.string_of_term_global thy t)
   136 
   137   in prf_of [] end;
   138 
   139 
   140 val AbsPt = Const ("AbsP", [propT, proofT --> proofT] ---> proofT);
   141 val AppPt = Const ("AppP", [proofT, proofT] ---> proofT);
   142 val Hypt = Const ("Hyp", propT --> proofT);
   143 val Oraclet = Const ("Oracle", propT --> proofT);
   144 val MinProoft = Const ("MinProof", proofT);
   145 
   146 val mk_tyapp = fold (fn T => fn prf => Const ("Appt",
   147   [proofT, Term.itselfT T] ---> proofT) $ prf $ Logic.mk_type T);
   148 
   149 fun term_of _ (PThm (_, ((name, _, NONE), _))) =
   150       Const (Long_Name.append "thm" name, proofT)
   151   | term_of _ (PThm (_, ((name, _, SOME Ts), _))) =
   152       mk_tyapp Ts (Const (Long_Name.append "thm" name, proofT))
   153   | term_of _ (PAxm (name, _, NONE)) = Const (Long_Name.append "axm" name, proofT)
   154   | term_of _ (PAxm (name, _, SOME Ts)) =
   155       mk_tyapp Ts (Const (Long_Name.append "axm" name, proofT))
   156   | term_of _ (PBound i) = Bound i
   157   | term_of Ts (Abst (s, opT, prf)) =
   158       let val T = the_default dummyT opT
   159       in Const ("Abst", (T --> proofT) --> proofT) $
   160         Abs (s, T, term_of (T::Ts) (incr_pboundvars 1 0 prf))
   161       end
   162   | term_of Ts (AbsP (s, t, prf)) =
   163       AbsPt $ the_default (Term.dummy_pattern propT) t $
   164         Abs (s, proofT, term_of (proofT::Ts) (incr_pboundvars 0 1 prf))
   165   | term_of Ts (prf1 %% prf2) =
   166       AppPt $ term_of Ts prf1 $ term_of Ts prf2
   167   | term_of Ts (prf % opt) =
   168       let val t = the_default (Term.dummy_pattern dummyT) opt
   169       in Const ("Appt",
   170         [proofT, fastype_of1 (Ts, t) handle TERM _ => dummyT] ---> proofT) $
   171           term_of Ts prf $ t
   172       end
   173   | term_of Ts (Hyp t) = Hypt $ t
   174   | term_of Ts (Oracle (_, t, _)) = Oraclet $ t
   175   | term_of Ts MinProof = MinProoft;
   176 
   177 val term_of_proof = term_of [];
   178 
   179 fun cterm_of_proof thy prf =
   180   let
   181     val thm_names = map fst (PureThy.all_thms_of thy);
   182     val axm_names = map fst (Theory.all_axioms_of thy);
   183     val thy' = thy
   184       |> add_proof_syntax
   185       |> add_proof_atom_consts
   186         (map (Long_Name.append "axm") axm_names @ map (Long_Name.append "thm") thm_names);
   187   in
   188     (cterm_of thy' (term_of_proof prf), proof_of_term thy true o Thm.term_of)
   189   end;
   190 
   191 fun read_term thy =
   192   let
   193     val thm_names = filter_out (fn s => s = "") (map fst (PureThy.all_thms_of thy));
   194     val axm_names = map fst (Theory.all_axioms_of thy);
   195     val ctxt = thy
   196       |> add_proof_syntax
   197       |> add_proof_atom_consts
   198         (map (Long_Name.append "axm") axm_names @ map (Long_Name.append "thm") thm_names)
   199       |> ProofContext.init
   200       |> ProofContext.allow_dummies
   201       |> ProofContext.set_mode ProofContext.mode_schematic;
   202   in
   203     fn ty => fn s =>
   204       (if ty = propT then Syntax.parse_prop else Syntax.parse_term) ctxt s
   205       |> TypeInfer.constrain ty |> Syntax.check_term ctxt
   206   end;
   207 
   208 fun read_proof thy =
   209   let val rd = read_term thy proofT
   210   in fn ty => fn s => proof_of_term thy ty (Logic.varify (rd s)) end;
   211 
   212 fun proof_syntax prf =
   213   let
   214     val thm_names = Symtab.keys (fold_proof_atoms true
   215       (fn PThm (_, ((name, _, _), _)) => if name <> "" then Symtab.update (name, ()) else I
   216         | _ => I) [prf] Symtab.empty);
   217     val axm_names = Symtab.keys (fold_proof_atoms true
   218       (fn PAxm (name, _, _) => Symtab.update (name, ()) | _ => I) [prf] Symtab.empty);
   219   in
   220     add_proof_syntax #>
   221     add_proof_atom_consts
   222       (map (Long_Name.append "thm") thm_names @ map (Long_Name.append "axm") axm_names)
   223   end;
   224 
   225 fun proof_of full thm =
   226   let
   227     val thy = Thm.theory_of_thm thm;
   228     val prop = Thm.full_prop_of thm;
   229     val prf = Thm.proof_of thm;
   230     val prf' = (case strip_combt (fst (strip_combP prf)) of
   231         (PThm (_, ((_, prop', _), body)), _) => if prop = prop' then join_proof body else prf
   232       | _ => prf)
   233   in if full then Reconstruct.reconstruct_proof thy prop prf' else prf' end;
   234 
   235 fun pretty_proof ctxt prf =
   236   ProofContext.pretty_term_abbrev
   237     (ProofContext.transfer_syntax (proof_syntax prf (ProofContext.theory_of ctxt)) ctxt)
   238     (term_of_proof prf);
   239 
   240 fun pretty_proof_of ctxt full th =
   241   pretty_proof ctxt (proof_of full th);
   242 
   243 end;