src/Pure/Isar/attrib.ML
author wenzelm
Tue Apr 05 14:25:18 2011 +0200 (2011-04-05)
changeset 42224 578a51fae383
parent 42056 160a630b2c7e
child 42277 7503beeffd8d
permissions -rw-r--r--
discontinued special treatment of structure Ast: no pervasive content, no inclusion in structure Syntax;
     1 (*  Title:      Pure/Isar/attrib.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Symbolic representation of attributes -- with name and syntax.
     5 *)
     6 
     7 signature ATTRIB =
     8 sig
     9   type src = Args.src
    10   type binding = binding * src list
    11   val empty_binding: binding
    12   val print_attributes: theory -> unit
    13   val intern: theory -> xstring -> string
    14   val intern_src: theory -> src -> src
    15   val pretty_attribs: Proof.context -> src list -> Pretty.T list
    16   val defined: theory -> string -> bool
    17   val attribute: theory -> src -> attribute
    18   val attribute_i: theory -> src -> attribute
    19   val map_specs: ('a -> 'att) ->
    20     (('c * 'a list) * 'b) list -> (('c * 'att list) * 'b) list
    21   val map_facts: ('a -> 'att) ->
    22     (('c * 'a list) * ('d * 'a list) list) list ->
    23     (('c * 'att list) * ('d * 'att list) list) list
    24   val map_facts_refs: ('a -> 'att) -> ('b -> 'fact) ->
    25     (('c * 'a list) * ('b * 'a list) list) list ->
    26     (('c * 'att list) * ('fact * 'att list) list) list
    27   val eval_thms: Proof.context -> (Facts.ref * src list) list -> thm list
    28   val crude_closure: Proof.context -> src -> src
    29   val setup: Binding.binding -> attribute context_parser -> string -> theory -> theory
    30   val attribute_setup: bstring * Position.T -> Symbol_Pos.text * Position.T -> string ->
    31     theory -> theory
    32   val add_del: attribute -> attribute -> attribute context_parser
    33   val thm_sel: Facts.interval list parser
    34   val thm: thm context_parser
    35   val thms: thm list context_parser
    36   val multi_thm: thm list context_parser
    37   val print_configs: Proof.context -> unit
    38   val internal: (morphism -> attribute) -> src
    39   val config_bool: bstring -> (Context.generic -> bool) -> bool Config.T * (theory -> theory)
    40   val config_int: bstring -> (Context.generic -> int) -> int Config.T * (theory -> theory)
    41   val config_real: bstring -> (Context.generic -> real) -> real Config.T * (theory -> theory)
    42   val config_string: bstring -> (Context.generic -> string) -> string Config.T * (theory -> theory)
    43   val config_bool_global: bstring -> (Context.generic -> bool) -> bool Config.T * (theory -> theory)
    44   val config_int_global: bstring -> (Context.generic -> int) -> int Config.T * (theory -> theory)
    45   val config_real_global: bstring -> (Context.generic -> real) -> real Config.T * (theory -> theory)
    46   val config_string_global:
    47     bstring -> (Context.generic -> string) -> string Config.T * (theory -> theory)
    48 end;
    49 
    50 structure Attrib: ATTRIB =
    51 struct
    52 
    53 (* source and bindings *)
    54 
    55 type src = Args.src;
    56 
    57 type binding = binding * src list;
    58 val empty_binding: binding = (Binding.empty, []);
    59 
    60 
    61 
    62 (** named attributes **)
    63 
    64 (* theory data *)
    65 
    66 structure Attributes = Theory_Data
    67 (
    68   type T = ((src -> attribute) * string) Name_Space.table;
    69   val empty : T = Name_Space.empty_table "attribute";
    70   val extend = I;
    71   fun merge data : T = Name_Space.merge_tables data;
    72 );
    73 
    74 fun print_attributes thy =
    75   let
    76     val attribs = Attributes.get thy;
    77     fun prt_attr (name, (_, comment)) = Pretty.block
    78       [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
    79   in
    80     [Pretty.big_list "attributes:" (map prt_attr (Name_Space.extern_table attribs))]
    81     |> Pretty.chunks |> Pretty.writeln
    82   end;
    83 
    84 fun add_attribute name att comment thy = thy
    85   |> Attributes.map (#2 o Name_Space.define true (Sign.naming_of thy) (name, (att, comment)));
    86 
    87 
    88 (* name space *)
    89 
    90 val intern = Name_Space.intern o #1 o Attributes.get;
    91 val intern_src = Args.map_name o intern;
    92 
    93 val extern = Name_Space.extern o #1 o Attributes.get o ProofContext.theory_of;
    94 
    95 
    96 (* pretty printing *)
    97 
    98 fun pretty_attribs _ [] = []
    99   | pretty_attribs ctxt srcs =
   100       [Pretty.enum "," "[" "]" (map (Args.pretty_src ctxt o Args.map_name (extern ctxt)) srcs)];
   101 
   102 
   103 (* get attributes *)
   104 
   105 val defined = Symtab.defined o #2 o Attributes.get;
   106 
   107 fun attribute_i thy =
   108   let
   109     val attrs = #2 (Attributes.get thy);
   110     fun attr src =
   111       let val ((name, _), pos) = Args.dest_src src in
   112         (case Symtab.lookup attrs name of
   113           NONE => error ("Unknown attribute: " ^ quote name ^ Position.str_of pos)
   114         | SOME (att, _) => (Position.report pos (Markup.attribute name); att src))
   115       end;
   116   in attr end;
   117 
   118 fun attribute thy = attribute_i thy o intern_src thy;
   119 
   120 
   121 (* attributed declarations *)
   122 
   123 fun map_specs f = map (apfst (apsnd (map f)));
   124 
   125 fun map_facts f = map (apfst (apsnd (map f)) o apsnd (map (apsnd (map f))));
   126 fun map_facts_refs f g = map_facts f #> map (apsnd (map (apfst g)));
   127 
   128 
   129 (* fact expressions *)
   130 
   131 fun eval_thms ctxt srcs = ctxt
   132   |> ProofContext.note_thmss ""
   133     (map_facts_refs (attribute (ProofContext.theory_of ctxt)) (ProofContext.get_fact ctxt)
   134       [((Binding.empty, []), srcs)])
   135   |> fst |> maps snd;
   136 
   137 
   138 (* crude_closure *)
   139 
   140 (*Produce closure without knowing facts in advance! The following
   141   works reasonably well for attribute parsers that do not peek at the
   142   thm structure.*)
   143 
   144 fun crude_closure ctxt src =
   145  (try (fn () => attribute_i (ProofContext.theory_of ctxt) src
   146     (Context.Proof ctxt, Drule.asm_rl)) ();
   147   Args.closure src);
   148 
   149 
   150 (* attribute setup *)
   151 
   152 fun syntax scan = Args.syntax "attribute" scan;
   153 
   154 fun setup name scan =
   155   add_attribute name
   156     (fn src => fn (ctxt, th) => let val (a, ctxt') = syntax scan src ctxt in a (ctxt', th) end);
   157 
   158 fun attribute_setup name (txt, pos) cmt =
   159   Context.theory_map (ML_Context.expression pos
   160     "val (name, scan, comment): binding * attribute context_parser * string"
   161     "Context.map_theory (Attrib.setup name scan comment)"
   162     (ML_Lex.read Position.none ("(" ^ ML_Syntax.make_binding name ^ ", ") @
   163       ML_Lex.read pos txt @
   164       ML_Lex.read Position.none (", " ^ ML_Syntax.print_string cmt ^ ")")));
   165 
   166 
   167 (* add/del syntax *)
   168 
   169 fun add_del add del = Scan.lift (Args.add >> K add || Args.del >> K del || Scan.succeed add);
   170 
   171 
   172 
   173 (** parsing attributed theorems **)
   174 
   175 val thm_sel = Parse.$$$ "(" |-- Parse.list1
   176  (Parse.nat --| Parse.minus -- Parse.nat >> Facts.FromTo ||
   177   Parse.nat --| Parse.minus >> Facts.From ||
   178   Parse.nat >> Facts.Single) --| Parse.$$$ ")";
   179 
   180 local
   181 
   182 val fact_name = Args.internal_fact >> K "<fact>" || Args.name;
   183 
   184 fun gen_thm pick = Scan.depend (fn context =>
   185   let
   186     val thy = Context.theory_of context;
   187     val get = Context.cases (Global_Theory.get_fact context) ProofContext.get_fact context;
   188     val get_fact = get o Facts.Fact;
   189     fun get_named pos name = get (Facts.Named ((name, pos), NONE));
   190   in
   191     Parse.$$$ "[" |-- Args.attribs (intern thy) --| Parse.$$$ "]" >> (fn srcs =>
   192       let
   193         val atts = map (attribute_i thy) srcs;
   194         val (context', th') = Library.apply atts (context, Drule.dummy_thm);
   195       in (context', pick "" [th']) end)
   196     ||
   197     (Scan.ahead Args.alt_name -- Args.named_fact get_fact
   198       >> (fn (s, fact) => ("", Facts.Fact s, fact)) ||
   199      Scan.ahead (Parse.position fact_name) :|-- (fn (name, pos) =>
   200       Args.named_fact (get_named pos) -- Scan.option thm_sel
   201         >> (fn (fact, sel) => (name, Facts.Named ((name, pos), sel), fact))))
   202     -- Args.opt_attribs (intern thy) >> (fn ((name, thmref, fact), srcs) =>
   203       let
   204         val ths = Facts.select thmref fact;
   205         val atts = map (attribute_i thy) srcs;
   206         val (context', ths') = Library.foldl_map (Library.apply atts) (context, ths);
   207       in (context', pick name ths') end)
   208   end);
   209 
   210 in
   211 
   212 val thm = gen_thm Facts.the_single;
   213 val multi_thm = gen_thm (K I);
   214 val thms = Scan.repeat multi_thm >> flat;
   215 
   216 end;
   217 
   218 
   219 
   220 (** basic attributes **)
   221 
   222 (* internal *)
   223 
   224 fun internal att = Args.src (("Pure.attribute", [Token.mk_attribute att]), Position.none);
   225 
   226 
   227 (* rule composition *)
   228 
   229 val COMP_att =
   230   Scan.lift (Scan.optional (Args.bracks Parse.nat) 1) -- thm
   231     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => Drule.compose_single (A, i, B)));
   232 
   233 val THEN_att =
   234   Scan.lift (Scan.optional (Args.bracks Parse.nat) 1) -- thm
   235     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => A RSN (i, B)));
   236 
   237 val OF_att =
   238   thms >> (fn Bs => Thm.rule_attribute (fn _ => fn A => Bs MRS A));
   239 
   240 
   241 (* rename_abs *)
   242 
   243 fun rename_abs x = (Scan.repeat (Args.maybe Args.name) >> (apsnd o Drule.rename_bvars')) x;
   244 
   245 
   246 (* unfold / fold definitions *)
   247 
   248 fun unfolded_syntax rule =
   249   thms >> (fn ths => Thm.rule_attribute (fn context => rule (Context.proof_of context) ths));
   250 
   251 val unfolded = unfolded_syntax Local_Defs.unfold;
   252 val folded = unfolded_syntax Local_Defs.fold;
   253 
   254 
   255 (* rule format *)
   256 
   257 val rule_format = Args.mode "no_asm"
   258   >> (fn true => Object_Logic.rule_format_no_asm | false => Object_Logic.rule_format);
   259 
   260 val elim_format = Thm.rule_attribute (K Tactic.make_elim);
   261 
   262 
   263 (* misc rules *)
   264 
   265 val no_vars = Thm.rule_attribute (fn context => fn th =>
   266   let
   267     val ctxt = Variable.set_body false (Context.proof_of context);
   268     val ((_, [th']), _) = Variable.import true [th] ctxt;
   269   in th' end);
   270 
   271 val eta_long =
   272   Thm.rule_attribute (K (Conv.fconv_rule Drule.eta_long_conversion));
   273 
   274 val rotated = Scan.optional Parse.int 1 >> (fn n => Thm.rule_attribute (K (rotate_prems n)));
   275 
   276 
   277 (* theory setup *)
   278 
   279 val _ = Context.>> (Context.map_theory
   280  (setup (Binding.name "attribute") (Scan.lift Args.internal_attribute >> Morphism.form)
   281     "internal attribute" #>
   282   setup (Binding.name "tagged") (Scan.lift (Args.name -- Args.name) >> Thm.tag) "tagged theorem" #>
   283   setup (Binding.name "untagged") (Scan.lift Args.name >> Thm.untag) "untagged theorem" #>
   284   setup (Binding.name "kind") (Scan.lift Args.name >> Thm.kind) "theorem kind" #>
   285   setup (Binding.name "COMP") COMP_att "direct composition with rules (no lifting)" #>
   286   setup (Binding.name "THEN") THEN_att "resolution with rule" #>
   287   setup (Binding.name "OF") OF_att "rule applied to facts" #>
   288   setup (Binding.name "rename_abs") (Scan.lift rename_abs)
   289     "rename bound variables in abstractions" #>
   290   setup (Binding.name "unfolded") unfolded "unfolded definitions" #>
   291   setup (Binding.name "folded") folded "folded definitions" #>
   292   setup (Binding.name "consumes") (Scan.lift (Scan.optional Parse.nat 1) >> Rule_Cases.consumes)
   293     "number of consumed facts" #>
   294   setup (Binding.name "constraints") (Scan.lift Parse.nat >> Rule_Cases.constraints)
   295     "number of equality constraints" #>
   296   setup (Binding.name "case_names") (Scan.lift (Scan.repeat1 Args.name) >> Rule_Cases.case_names)
   297     "named rule cases" #>
   298   setup (Binding.name "case_conclusion")
   299     (Scan.lift (Args.name -- Scan.repeat Args.name) >> Rule_Cases.case_conclusion)
   300     "named conclusion of rule cases" #>
   301   setup (Binding.name "params")
   302     (Scan.lift (Parse.and_list1 (Scan.repeat Args.name)) >> Rule_Cases.params)
   303     "named rule parameters" #>
   304   setup (Binding.name "standard") (Scan.succeed (Thm.rule_attribute (K Drule.export_without_context)))
   305     "result put into standard form (legacy)" #>
   306   setup (Binding.name "rule_format") rule_format "result put into canonical rule format" #>
   307   setup (Binding.name "elim_format") (Scan.succeed elim_format)
   308     "destruct rule turned into elimination rule format" #>
   309   setup (Binding.name "no_vars") (Scan.succeed no_vars) "frozen schematic vars" #>
   310   setup (Binding.name "eta_long") (Scan.succeed eta_long)
   311     "put theorem into eta long beta normal form" #>
   312   setup (Binding.name "atomize") (Scan.succeed Object_Logic.declare_atomize)
   313     "declaration of atomize rule" #>
   314   setup (Binding.name "rulify") (Scan.succeed Object_Logic.declare_rulify)
   315     "declaration of rulify rule" #>
   316   setup (Binding.name "rotated") (Scan.lift rotated) "rotated theorem premises" #>
   317   setup (Binding.name "defn") (add_del Local_Defs.defn_add Local_Defs.defn_del)
   318     "declaration of definitional transformations" #>
   319   setup (Binding.name "abs_def") (Scan.succeed (Thm.rule_attribute (K Drule.abs_def)))
   320     "abstract over free variables of a definition"));
   321 
   322 
   323 
   324 (** configuration options **)
   325 
   326 (* naming *)
   327 
   328 structure Configs = Theory_Data
   329 (
   330   type T = Config.raw Symtab.table;
   331   val empty = Symtab.empty;
   332   val extend = I;
   333   fun merge data = Symtab.merge (K true) data;
   334 );
   335 
   336 fun print_configs ctxt =
   337   let
   338     val thy = ProofContext.theory_of ctxt;
   339     fun prt (name, config) =
   340       let val value = Config.get ctxt config in
   341         Pretty.block [Pretty.str (name ^ ": " ^ Config.print_type value ^ " ="), Pretty.brk 1,
   342           Pretty.str (Config.print_value value)]
   343       end;
   344     val configs = Name_Space.extern_table (#1 (Attributes.get thy), Configs.get thy);
   345   in Pretty.writeln (Pretty.big_list "configuration options" (map prt configs)) end;
   346 
   347 
   348 (* concrete syntax *)
   349 
   350 local
   351 
   352 val equals = Parse.$$$ "=";
   353 
   354 fun scan_value (Config.Bool _) =
   355       equals -- Args.$$$ "false" >> K (Config.Bool false) ||
   356       equals -- Args.$$$ "true" >> K (Config.Bool true) ||
   357       Scan.succeed (Config.Bool true)
   358   | scan_value (Config.Int _) = equals |-- Parse.int >> Config.Int
   359   | scan_value (Config.Real _) = equals |-- Parse.real >> Config.Real
   360   | scan_value (Config.String _) = equals |-- Args.name >> Config.String;
   361 
   362 fun scan_config thy config =
   363   let val config_type = Config.get_global thy config
   364   in scan_value config_type >> (K o Thm.declaration_attribute o K o Config.put_generic config) end;
   365 
   366 in
   367 
   368 fun register_config config thy =
   369   let
   370     val bname = Config.name_of config;
   371     val name = Sign.full_bname thy bname;
   372   in
   373     thy
   374     |> setup (Binding.name bname) (Scan.lift (scan_config thy config) >> Morphism.form)
   375       "configuration option"
   376     |> Configs.map (Symtab.update (name, config))
   377   end;
   378 
   379 fun declare_config make coerce global name default =
   380   let
   381     val config_value = Config.declare_generic {global = global} name (make o default);
   382     val config = coerce config_value;
   383   in (config, register_config config_value) end;
   384 
   385 val config_bool   = declare_config Config.Bool Config.bool false;
   386 val config_int    = declare_config Config.Int Config.int false;
   387 val config_real   = declare_config Config.Real Config.real false;
   388 val config_string = declare_config Config.String Config.string false;
   389 
   390 val config_bool_global   = declare_config Config.Bool Config.bool true;
   391 val config_int_global    = declare_config Config.Int Config.int true;
   392 val config_real_global   = declare_config Config.Real Config.real true;
   393 val config_string_global = declare_config Config.String Config.string true;
   394 
   395 end;
   396 
   397 
   398 (* theory setup *)
   399 
   400 val _ = Context.>> (Context.map_theory
   401  (register_config Ast.ast_trace_raw #>
   402   register_config Ast.ast_stat_raw #>
   403   register_config Syntax.positions_raw #>
   404   register_config Syntax.show_brackets_raw #>
   405   register_config Syntax.show_sorts_raw #>
   406   register_config Syntax.show_types_raw #>
   407   register_config Syntax.show_structs_raw #>
   408   register_config Syntax.show_question_marks_raw #>
   409   register_config Syntax.ambiguity_level_raw #>
   410   register_config Syntax.eta_contract_raw #>
   411   register_config ML_Context.trace_raw #>
   412   register_config ProofContext.show_abbrevs_raw #>
   413   register_config Goal_Display.goals_limit_raw #>
   414   register_config Goal_Display.show_main_goal_raw #>
   415   register_config Goal_Display.show_consts_raw #>
   416   register_config Display.show_hyps_raw #>
   417   register_config Display.show_tags_raw #>
   418   register_config Unify.trace_bound_raw #>
   419   register_config Unify.search_bound_raw #>
   420   register_config Unify.trace_simp_raw #>
   421   register_config Unify.trace_types_raw #>
   422   register_config Raw_Simplifier.simp_depth_limit_raw #>
   423   register_config Raw_Simplifier.simp_trace_depth_limit_raw #>
   424   register_config Raw_Simplifier.simp_debug_raw #>
   425   register_config Raw_Simplifier.simp_trace_raw));
   426 
   427 end;