src/Pure/variable.ML
author wenzelm
Tue Aug 20 11:01:05 2019 +0200 (10 months ago)
changeset 70586 57df8a85317a
parent 70311 e49bf4ebf330
child 70733 ce1afe0f3071
permissions -rw-r--r--
clarified signature;
     1 (*  Title:      Pure/variable.ML
     2     Author:     Makarius
     3 
     4 Fixed type/term variables and polymorphic term abbreviations.
     5 *)
     6 
     7 signature VARIABLE =
     8 sig
     9   val names_of: Proof.context -> Name.context
    10   val binds_of: Proof.context -> (typ * term) Vartab.table
    11   val maxidx_of: Proof.context -> int
    12   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    13   val is_declared: Proof.context -> string -> bool
    14   val check_name: binding -> string
    15   val default_type: Proof.context -> string -> typ option
    16   val def_type: Proof.context -> bool -> indexname -> typ option
    17   val def_sort: Proof.context -> indexname -> sort option
    18   val declare_maxidx: int -> Proof.context -> Proof.context
    19   val declare_names: term -> Proof.context -> Proof.context
    20   val declare_constraints: term -> Proof.context -> Proof.context
    21   val declare_internal: term -> Proof.context -> Proof.context
    22   val declare_term: term -> Proof.context -> Proof.context
    23   val declare_typ: typ -> Proof.context -> Proof.context
    24   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    25   val declare_thm: thm -> Proof.context -> Proof.context
    26   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    27   val bind_term: indexname * term -> Proof.context -> Proof.context
    28   val unbind_term: indexname -> Proof.context -> Proof.context
    29   val maybe_bind_term: indexname * term option -> Proof.context -> Proof.context
    30   val expand_binds: Proof.context -> term -> term
    31   val lookup_const: Proof.context -> string -> string option
    32   val is_const: Proof.context -> string -> bool
    33   val declare_const: string * string -> Proof.context -> Proof.context
    34   val next_bound: string * typ -> Proof.context -> term * Proof.context
    35   val revert_bounds: Proof.context -> term -> term
    36   val is_body: Proof.context -> bool
    37   val set_body: bool -> Proof.context -> Proof.context
    38   val restore_body: Proof.context -> Proof.context -> Proof.context
    39   val improper_fixes: Proof.context -> Proof.context
    40   val restore_proper_fixes: Proof.context -> Proof.context -> Proof.context
    41   val is_improper: Proof.context -> string -> bool
    42   val is_fixed: Proof.context -> string -> bool
    43   val is_newly_fixed: Proof.context -> Proof.context -> string -> bool
    44   val fixed_ord: Proof.context -> string ord
    45   val intern_fixed: Proof.context -> string -> string
    46   val lookup_fixed: Proof.context -> string -> string option
    47   val revert_fixed: Proof.context -> string -> string
    48   val markup_fixed: Proof.context -> string -> Markup.T
    49   val markup: Proof.context -> string -> Markup.T
    50   val markup_entity_def: Proof.context -> string -> Markup.T
    51   val dest_fixes: Proof.context -> (string * string) list
    52   val add_fixed_names: Proof.context -> term -> string list -> string list
    53   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    54   val add_newly_fixed: Proof.context -> Proof.context ->
    55     term -> (string * typ) list -> (string * typ) list
    56   val add_free_names: Proof.context -> term -> string list -> string list
    57   val add_frees: Proof.context -> term -> (string * typ) list -> (string * typ) list
    58   val add_fixes_binding: binding list -> Proof.context -> string list * Proof.context
    59   val add_fixes: string list -> Proof.context -> string list * Proof.context
    60   val add_fixes_direct: string list -> Proof.context -> Proof.context
    61   val fix_dummy_patterns: term -> Proof.context -> term * Proof.context
    62   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    63   val gen_all: Proof.context -> thm -> thm
    64   val export_terms: Proof.context -> Proof.context -> term list -> term list
    65   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    66   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    67   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    68   val export: Proof.context -> Proof.context -> thm list -> thm list
    69   val export_morphism: Proof.context -> Proof.context -> morphism
    70   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    71   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    72   val import_inst: bool -> term list -> Proof.context ->
    73     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    74   val importT_terms: term list -> Proof.context -> term list * Proof.context
    75   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    76   val importT: thm list -> Proof.context ->
    77     (((indexname * sort) * ctyp) list * thm list) * Proof.context
    78   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    79   val import: bool -> thm list -> Proof.context ->
    80     ((((indexname * sort) * ctyp) list * ((indexname * typ) * cterm) list) * thm list) * Proof.context
    81   val import_vars: Proof.context -> thm -> thm
    82   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    83   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    84   val is_bound_focus: Proof.context -> bool
    85   val set_bound_focus: bool -> Proof.context -> Proof.context
    86   val restore_bound_focus: Proof.context -> Proof.context -> Proof.context
    87   val focus_params: binding list option -> term -> Proof.context ->
    88     (string list * (string * typ) list) * Proof.context
    89   val focus: binding list option -> term -> Proof.context ->
    90     ((string * (string * typ)) list * term) * Proof.context
    91   val focus_cterm: binding list option -> cterm -> Proof.context ->
    92     ((string * cterm) list * cterm) * Proof.context
    93   val focus_subgoal: binding list option -> int -> thm -> Proof.context ->
    94     ((string * cterm) list * cterm) * Proof.context
    95   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    96   val polymorphic_types: Proof.context -> term list -> (indexname * sort) list * term list
    97   val polymorphic: Proof.context -> term list -> term list
    98 end;
    99 
   100 structure Variable: VARIABLE =
   101 struct
   102 
   103 (** local context data **)
   104 
   105 type fixes = (string * bool) Name_Space.table;
   106 val empty_fixes: fixes = Name_Space.empty_table Markup.fixedN;
   107 
   108 datatype data = Data of
   109  {names: Name.context,                  (*type/term variable names*)
   110   consts: string Symtab.table,          (*consts within the local scope*)
   111   bounds: int * ((string * typ) * string) list,  (*next index, internal name, type, external name*)
   112   fixes: fixes,                         (*term fixes -- global name space, intern ~> extern*)
   113   binds: (typ * term) Vartab.table,     (*term bindings*)
   114   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
   115   maxidx: int,                          (*maximum var index*)
   116   constraints:
   117     typ Vartab.table *                  (*type constraints*)
   118     sort Vartab.table};                 (*default sorts*)
   119 
   120 fun make_data (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =
   121   Data {names = names, consts = consts, bounds = bounds, fixes = fixes, binds = binds,
   122     type_occs = type_occs, maxidx = maxidx, constraints = constraints};
   123 
   124 val empty_data =
   125   make_data (Name.context, Symtab.empty, (0, []), empty_fixes, Vartab.empty,
   126     Symtab.empty, ~1, (Vartab.empty, Vartab.empty));
   127 
   128 structure Data = Proof_Data
   129 (
   130   type T = data;
   131   fun init _ = empty_data;
   132 );
   133 
   134 fun map_data f =
   135   Data.map (fn Data {names, consts, bounds, fixes, binds, type_occs, maxidx, constraints} =>
   136     make_data (f (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints)));
   137 
   138 fun map_names f =
   139   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   140     (f names, consts, bounds, fixes, binds, type_occs, maxidx, constraints));
   141 
   142 fun map_consts f =
   143   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   144     (names, f consts, bounds, fixes, binds, type_occs, maxidx, constraints));
   145 
   146 fun map_bounds f =
   147   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   148     (names, consts, f bounds, fixes, binds, type_occs, maxidx, constraints));
   149 
   150 fun map_fixes f =
   151   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   152     (names, consts, bounds, f fixes, binds, type_occs, maxidx, constraints));
   153 
   154 fun map_binds f =
   155   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   156     (names, consts, bounds, fixes, f binds, type_occs, maxidx, constraints));
   157 
   158 fun map_type_occs f =
   159   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   160     (names, consts, bounds, fixes, binds, f type_occs, maxidx, constraints));
   161 
   162 fun map_maxidx f =
   163   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   164     (names, consts, bounds, fixes, binds, type_occs, f maxidx, constraints));
   165 
   166 fun map_constraints f =
   167   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   168     (names, consts, bounds, fixes, binds, type_occs, maxidx, f constraints));
   169 
   170 fun rep_data ctxt = Data.get ctxt |> (fn Data rep => rep);
   171 
   172 val names_of = #names o rep_data;
   173 val fixes_of = #fixes o rep_data;
   174 val fixes_space = Name_Space.space_of_table o fixes_of;
   175 val binds_of = #binds o rep_data;
   176 val type_occs_of = #type_occs o rep_data;
   177 val maxidx_of = #maxidx o rep_data;
   178 val constraints_of = #constraints o rep_data;
   179 
   180 val is_declared = Name.is_declared o names_of;
   181 
   182 val check_name = Name_Space.base_name o tap Binding.check;
   183 
   184 
   185 
   186 (** declarations **)
   187 
   188 (* default sorts and types *)
   189 
   190 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   191 
   192 fun def_type ctxt pattern xi =
   193   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   194     (case Vartab.lookup types xi of
   195       NONE =>
   196         if pattern then NONE
   197         else Vartab.lookup binds xi |> Option.map (Type.mark_polymorphic o #1)
   198     | some => some)
   199   end;
   200 
   201 val def_sort = Vartab.lookup o #2 o constraints_of;
   202 
   203 
   204 (* maxidx *)
   205 
   206 val declare_maxidx = map_maxidx o Integer.max;
   207 
   208 
   209 (* names *)
   210 
   211 fun declare_type_names t =
   212   map_names (fold_types (fold_atyps Term.declare_typ_names) t) #>
   213   map_maxidx (fold_types Term.maxidx_typ t);
   214 
   215 fun declare_names t =
   216   declare_type_names t #>
   217   map_names (fold_aterms Term.declare_term_frees t) #>
   218   map_maxidx (Term.maxidx_term t);
   219 
   220 
   221 (* type occurrences *)
   222 
   223 fun decl_type_occsT T = fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I) T;
   224 
   225 val decl_type_occs = fold_term_types
   226   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   227     | _ => decl_type_occsT);
   228 
   229 val declare_type_occsT = map_type_occs o fold_types decl_type_occsT;
   230 val declare_type_occs = map_type_occs o decl_type_occs;
   231 
   232 
   233 (* constraints *)
   234 
   235 fun constrain_tvar (xi, raw_S) =
   236   let val S = #2 (Term_Position.decode_positionS raw_S)
   237   in if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S) end;
   238 
   239 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   240   let
   241     val types' = fold_aterms
   242       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   243         | Var v => Vartab.update v
   244         | _ => I) t types;
   245     val sorts' = (fold_types o fold_atyps)
   246       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   247         | TVar v => constrain_tvar v
   248         | _ => I) t sorts;
   249   in (types', sorts') end)
   250   #> declare_type_occsT t
   251   #> declare_type_names t;
   252 
   253 
   254 (* common declarations *)
   255 
   256 fun declare_internal t =
   257   declare_names t #>
   258   declare_type_occs t #>
   259   Thm.declare_term_sorts t;
   260 
   261 fun declare_term t =
   262   declare_internal t #>
   263   declare_constraints t;
   264 
   265 val declare_typ = declare_term o Logic.mk_type;
   266 
   267 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   268 
   269 val declare_thm = Thm.fold_terms declare_internal;
   270 
   271 
   272 (* renaming term/type frees *)
   273 
   274 fun variant_frees ctxt ts frees =
   275   let
   276     val names = names_of (fold declare_names ts ctxt);
   277     val xs = fst (fold_map Name.variant (map #1 frees) names);
   278   in xs ~~ map snd frees end;
   279 
   280 
   281 
   282 (** term bindings **)
   283 
   284 fun bind_term ((x, i), t) =
   285   let
   286     val u = Term.close_schematic_term t;
   287     val U = Term.fastype_of u;
   288   in declare_term u #> map_binds (Vartab.update ((x, i), (U, u))) end;
   289 
   290 val unbind_term = map_binds o Vartab.delete_safe;
   291 
   292 fun maybe_bind_term (xi, SOME t) = bind_term (xi, t)
   293   | maybe_bind_term (xi, NONE) = unbind_term xi;
   294 
   295 fun expand_binds ctxt =
   296   let
   297     val binds = binds_of ctxt;
   298     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   299   in Envir.beta_norm o Envir.expand_term get end;
   300 
   301 
   302 
   303 (** consts **)
   304 
   305 val lookup_const = Symtab.lookup o #consts o rep_data;
   306 val is_const = is_some oo lookup_const;
   307 
   308 val declare_fixed = map_consts o Symtab.delete_safe;
   309 val declare_const = map_consts o Symtab.update;
   310 
   311 
   312 
   313 (** bounds **)
   314 
   315 fun next_bound (a, T) ctxt =
   316   let
   317     val b = Name.bound (#1 (#bounds (rep_data ctxt)));
   318     val ctxt' = ctxt |> map_bounds (fn (next, bounds) => (next + 1, ((b, T), a) :: bounds));
   319   in (Free (b, T), ctxt') end;
   320 
   321 fun revert_bounds ctxt t =
   322   (case #2 (#bounds (rep_data ctxt)) of
   323     [] => t
   324   | bounds =>
   325       let
   326         val names = Term.declare_term_names t (names_of ctxt);
   327         val xs = rev (#1 (fold_map Name.variant (rev (map #2 bounds)) names));
   328         fun subst ((b, T), _) x' = (Free (b, T), Syntax_Trans.mark_bound_abs (x', T));
   329       in Term.subst_atomic (map2 subst bounds xs) t end);
   330 
   331 
   332 
   333 (** fixes **)
   334 
   335 (* inner body mode *)
   336 
   337 val inner_body = Config.declare_bool ("inner_body", \<^here>) (K false);
   338 val is_body = Config.apply inner_body;
   339 val set_body = Config.put inner_body;
   340 val restore_body = set_body o is_body;
   341 
   342 
   343 (* proper mode *)
   344 
   345 val proper_fixes = Config.declare_bool ("proper_fixes", \<^here>) (K true);
   346 val improper_fixes = Config.put proper_fixes false;
   347 val restore_proper_fixes = Config.put proper_fixes o Config.apply proper_fixes;
   348 
   349 fun is_improper ctxt x =
   350   (case Name_Space.lookup (fixes_of ctxt) x of
   351     SOME (_, proper) => not proper
   352   | NONE => false);
   353 
   354 
   355 (* specialized name space *)
   356 
   357 val is_fixed = Name_Space.defined o fixes_of;
   358 fun is_newly_fixed inner outer = is_fixed inner andf (not o is_fixed outer);
   359 
   360 val fixed_ord = Name_Space.entry_ord o fixes_space;
   361 val intern_fixed = Name_Space.intern o fixes_space;
   362 
   363 fun lookup_fixed ctxt x =
   364   let val x' = intern_fixed ctxt x
   365   in if is_fixed ctxt x' then SOME x' else NONE end;
   366 
   367 fun revert_fixed ctxt x =
   368   (case Name_Space.lookup (fixes_of ctxt) x of
   369     SOME (x', _) => if intern_fixed ctxt x' = x then x' else x
   370   | NONE => x);
   371 
   372 fun markup_fixed ctxt x =
   373   Name_Space.markup (fixes_space ctxt) x
   374   |> Markup.name (revert_fixed ctxt x);
   375 
   376 fun markup ctxt x =
   377   if is_improper ctxt x then Markup.improper
   378   else if Name.is_skolem x then Markup.skolem
   379   else Markup.free;
   380 
   381 val markup_entity_def = Name_Space.markup_def o fixes_space;
   382 
   383 fun dest_fixes ctxt =
   384   Name_Space.fold_table (fn (x, (y, _)) => cons (y, x)) (fixes_of ctxt) []
   385   |> sort (Name_Space.entry_ord (fixes_space ctxt) o apply2 #2);
   386 
   387 
   388 (* collect variables *)
   389 
   390 fun add_free_names ctxt =
   391   fold_aterms (fn Free (x, _) => not (is_fixed ctxt x) ? insert (op =) x | _ => I);
   392 
   393 fun add_frees ctxt =
   394   fold_aterms (fn Free (x, T) => not (is_fixed ctxt x) ? insert (op =) (x, T) | _ => I);
   395 
   396 fun add_fixed_names ctxt =
   397   fold_aterms (fn Free (x, _) => is_fixed ctxt x ? insert (op =) x | _ => I);
   398 
   399 fun add_fixed ctxt =
   400   fold_aterms (fn Free (x, T) => is_fixed ctxt x ? insert (op =) (x, T) | _ => I);
   401 
   402 fun add_newly_fixed ctxt' ctxt =
   403   fold_aterms (fn Free (x, T) => is_newly_fixed ctxt' ctxt x ? insert (op =) (x, T) | _ => I);
   404 
   405 
   406 (* declarations *)
   407 
   408 local
   409 
   410 fun err_dups dups =
   411   error ("Duplicate fixed variable(s): " ^ commas (map Binding.print dups));
   412 
   413 fun new_fixed ((x, x'), pos) ctxt =
   414   if is_some (lookup_fixed ctxt x') then err_dups [Binding.make (x, pos)]
   415   else
   416     let
   417       val proper = Config.get ctxt proper_fixes;
   418       val context = Context.Proof ctxt
   419         |> Name_Space.map_naming (K Name_Space.global_naming)
   420         |> Context_Position.set_visible_generic false;
   421     in
   422       ctxt
   423       |> map_fixes
   424         (Name_Space.define context true (Binding.make (x', pos), (x, proper)) #> snd #>
   425           Name_Space.alias_table Name_Space.global_naming (Binding.make (x, pos)) x')
   426       |> declare_fixed x
   427       |> declare_constraints (Syntax.free x')
   428   end;
   429 
   430 fun new_fixes names' xs xs' ps =
   431   map_names (K names') #>
   432   fold new_fixed ((xs ~~ xs') ~~ ps) #>
   433   pair xs';
   434 
   435 in
   436 
   437 fun add_fixes_binding bs ctxt =
   438   let
   439     val _ =
   440       (case filter (Name.is_skolem o Binding.name_of) bs of
   441         [] => ()
   442       | bads => error ("Illegal internal Skolem constant(s): " ^ commas (map Binding.print bads)));
   443     val _ =
   444       (case duplicates (op = o apply2 Binding.name_of) bs of
   445         [] => ()
   446       | dups => err_dups dups);
   447 
   448     val xs = map check_name bs;
   449     val names = names_of ctxt;
   450     val (xs', names') =
   451       if is_body ctxt then fold_map Name.variant xs names |>> map Name.skolem
   452       else (xs, fold Name.declare xs names);
   453   in ctxt |> new_fixes names' xs xs' (map Binding.pos_of bs) end;
   454 
   455 fun bound_fixes xs ctxt =
   456   let
   457     val (xs', ctxt') = fold_map next_bound xs ctxt;
   458     val no_ps = replicate (length xs) Position.none;
   459   in ctxt' |> new_fixes (names_of ctxt') (map #1 xs) (map (#1 o dest_Free) xs') no_ps end;
   460 
   461 fun variant_fixes raw_xs ctxt =
   462   let
   463     val names = names_of ctxt;
   464     val xs = map (fn x => Name.clean x |> Name.is_internal x ? Name.internal) raw_xs;
   465     val (xs', names') = fold_map Name.variant xs names |>> (is_body ctxt ? map Name.skolem);
   466     val no_ps = replicate (length xs) Position.none;
   467   in ctxt |> new_fixes names' xs xs' no_ps end;
   468 
   469 end;
   470 
   471 val add_fixes = add_fixes_binding o map Binding.name;
   472 
   473 fun add_fixes_direct xs ctxt = ctxt
   474   |> set_body false
   475   |> (snd o add_fixes xs)
   476   |> restore_body ctxt;
   477 
   478 
   479 (* dummy patterns *)
   480 
   481 fun fix_dummy_patterns (Const ("Pure.dummy_pattern", T)) ctxt =
   482       let val ([x], ctxt') = ctxt |> set_body true |> add_fixes [Name.uu_] ||> restore_body ctxt
   483       in (Free (x, T), ctxt') end
   484   | fix_dummy_patterns (Abs (x, T, b)) ctxt =
   485       let val (b', ctxt') = fix_dummy_patterns b ctxt
   486       in (Abs (x, T, b'), ctxt') end
   487   | fix_dummy_patterns (t $ u) ctxt =
   488       let
   489         val (t', ctxt') = fix_dummy_patterns t ctxt;
   490         val (u', ctxt'') = fix_dummy_patterns u ctxt';
   491       in (t' $ u', ctxt'') end
   492   | fix_dummy_patterns a ctxt = (a, ctxt);
   493 
   494 
   495 
   496 (** export -- generalize type/term variables (beware of closure sizes) **)
   497 
   498 fun gen_all ctxt th =
   499   let
   500     val i = Thm.maxidx_thm th (maxidx_of ctxt) + 1;
   501     fun gen (x, T) = Thm.forall_elim (Thm.cterm_of ctxt (Var ((x, i), T)));
   502   in fold gen (Drule.outer_params (Thm.prop_of th)) th end;
   503 
   504 fun export_inst inner outer =
   505   let
   506     val declared_outer = is_declared outer;
   507     val still_fixed = not o is_newly_fixed inner outer;
   508 
   509     val gen_fixes =
   510       Name_Space.fold_table (fn (y, _) => not (is_fixed outer y) ? cons y)
   511         (fixes_of inner) [];
   512 
   513     val type_occs_inner = type_occs_of inner;
   514     fun gen_fixesT ts =
   515       Symtab.fold (fn (a, xs) =>
   516         if declared_outer a orelse exists still_fixed xs
   517         then I else cons a) (fold decl_type_occs ts type_occs_inner) [];
   518   in (gen_fixesT, gen_fixes) end;
   519 
   520 fun exportT_inst inner outer = #1 (export_inst inner outer);
   521 
   522 fun exportT_terms inner outer =
   523   let
   524     val mk_tfrees = exportT_inst inner outer;
   525     val maxidx = maxidx_of outer;
   526   in
   527     fn ts => ts |> map
   528       (Term_Subst.generalize (mk_tfrees ts, [])
   529         (fold (Term.fold_types Term.maxidx_typ) ts maxidx + 1))
   530   end;
   531 
   532 fun export_terms inner outer =
   533   let
   534     val (mk_tfrees, tfrees) = export_inst inner outer;
   535     val maxidx = maxidx_of outer;
   536   in
   537     fn ts => ts |> map
   538       (Term_Subst.generalize (mk_tfrees ts, tfrees)
   539         (fold Term.maxidx_term ts maxidx + 1))
   540   end;
   541 
   542 fun export_prf inner outer prf =
   543   let
   544     val (mk_tfrees, frees) = export_inst (declare_prf prf inner) outer;
   545     val tfrees = mk_tfrees [];
   546     val maxidx = maxidx_of outer;
   547     val idx = Proofterm.maxidx_proof prf maxidx + 1;
   548     val gen_term = Term_Subst.generalize_same (tfrees, frees) idx;
   549     val gen_typ = Term_Subst.generalizeT_same tfrees idx;
   550   in Same.commit (Proofterm.map_proof_terms_same gen_term gen_typ) prf end;
   551 
   552 
   553 fun gen_export (mk_tfrees, frees) maxidx ths =
   554   let
   555     val tfrees = mk_tfrees (map Thm.full_prop_of ths);
   556     val idx = fold Thm.maxidx_thm ths maxidx + 1;
   557   in map (Thm.generalize (tfrees, frees) idx) ths end;
   558 
   559 fun exportT inner outer = gen_export (exportT_inst inner outer, []) (maxidx_of outer);
   560 fun export inner outer = gen_export (export_inst inner outer) (maxidx_of outer);
   561 
   562 fun export_morphism inner outer =
   563   let
   564     val fact = export inner outer;
   565     val term = singleton (export_terms inner outer);
   566     val typ = Logic.type_map term;
   567   in
   568     Morphism.transfer_morphism' inner $>
   569     Morphism.transfer_morphism' outer $>
   570     Morphism.morphism "Variable.export" {binding = [], typ = [typ], term = [term], fact = [fact]}
   571   end;
   572 
   573 
   574 
   575 (** import -- fix schematic type/term variables **)
   576 
   577 fun invent_types Ss ctxt =
   578   let
   579     val tfrees = Name.invent (names_of ctxt) Name.aT (length Ss) ~~ Ss;
   580     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   581   in (tfrees, ctxt') end;
   582 
   583 fun importT_inst ts ctxt =
   584   let
   585     val tvars = rev (fold Term.add_tvars ts []);
   586     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   587   in (tvars ~~ map TFree tfrees, ctxt') end;
   588 
   589 fun import_inst is_open ts ctxt =
   590   let
   591     val ren = Name.clean #> (if is_open then I else Name.internal);
   592     val (instT, ctxt') = importT_inst ts ctxt;
   593     val vars = map (apsnd (Term_Subst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   594     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   595     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   596   in ((instT, inst), ctxt'') end;
   597 
   598 fun importT_terms ts ctxt =
   599   let val (instT, ctxt') = importT_inst ts ctxt
   600   in (map (Term_Subst.instantiate (instT, [])) ts, ctxt') end;
   601 
   602 fun import_terms is_open ts ctxt =
   603   let val (inst, ctxt') = import_inst is_open ts ctxt
   604   in (map (Term_Subst.instantiate inst) ts, ctxt') end;
   605 
   606 fun importT ths ctxt =
   607   let
   608     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   609     val instT' = map (apsnd (Thm.ctyp_of ctxt')) instT;
   610     val ths' = map (Thm.instantiate (instT', [])) ths;
   611   in ((instT', ths'), ctxt') end;
   612 
   613 fun import_prf is_open prf ctxt =
   614   let
   615     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   616     val (insts, ctxt') = import_inst is_open ts ctxt;
   617   in (Proofterm.instantiate insts prf, ctxt') end;
   618 
   619 fun import is_open ths ctxt =
   620   let
   621     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   622     val insts' =
   623      (map (apsnd (Thm.ctyp_of ctxt')) instT,
   624       map (apsnd (Thm.cterm_of ctxt')) inst);
   625     val ths' = map (Thm.instantiate insts') ths;
   626   in ((insts', ths'), ctxt') end;
   627 
   628 fun import_vars ctxt th =
   629   let val ((_, [th']), _) = ctxt |> set_body false |> import true [th];
   630   in th' end;
   631 
   632 
   633 (* import/export *)
   634 
   635 fun gen_trade imp exp f ctxt ths =
   636   let val ((_, ths'), ctxt') = imp ths ctxt
   637   in exp ctxt' ctxt (f ctxt' ths') end;
   638 
   639 val tradeT = gen_trade importT exportT;
   640 val trade = gen_trade (import true) export;
   641 
   642 
   643 (* focus on outermost parameters: \<And>x y z. B *)
   644 
   645 val bound_focus = Config.declare_bool ("bound_focus", \<^here>) (K false);
   646 val is_bound_focus = Config.apply bound_focus;
   647 val set_bound_focus = Config.put bound_focus;
   648 val restore_bound_focus = set_bound_focus o is_bound_focus;
   649 
   650 fun focus_params bindings t ctxt =
   651   let
   652     val ps = Term.variant_frees t (Term.strip_all_vars t);  (*as they are printed :-*)
   653     val (xs, Ts) = split_list ps;
   654     val (xs', ctxt') =
   655       (case bindings of
   656         SOME bs => ctxt |> set_body true |> add_fixes_binding bs ||> restore_body ctxt
   657       | NONE => if is_bound_focus ctxt then bound_fixes ps ctxt else variant_fixes xs ctxt);
   658     val ps' = xs' ~~ Ts;
   659     val ctxt'' = ctxt' |> fold (declare_constraints o Free) ps';
   660   in ((xs, ps'), ctxt'') end;
   661 
   662 fun focus bindings t ctxt =
   663   let
   664     val ((xs, ps), ctxt') = focus_params bindings t ctxt;
   665     val t' = Term.subst_bounds (rev (map Free ps), Term.strip_all_body t);
   666   in (((xs ~~ ps), t'), ctxt') end;
   667 
   668 fun forall_elim_prop t prop =
   669   Thm.beta_conversion false (Thm.apply (Thm.dest_arg prop) t)
   670   |> Thm.cprop_of |> Thm.dest_arg;
   671 
   672 fun focus_cterm bindings goal ctxt =
   673   let
   674     val ((xs, ps), ctxt') = focus_params bindings (Thm.term_of goal) ctxt;
   675     val ps' = map (Thm.cterm_of ctxt' o Free) ps;
   676     val goal' = fold forall_elim_prop ps' goal;
   677   in ((xs ~~ ps', goal'), ctxt') end;
   678 
   679 fun focus_subgoal bindings i st =
   680   let
   681     val all_vars = Thm.fold_terms Term.add_vars st [];
   682   in
   683     fold (unbind_term o #1) all_vars #>
   684     fold (declare_constraints o Var) all_vars #>
   685     focus_cterm bindings (Thm.cprem_of st i)
   686   end;
   687 
   688 
   689 
   690 (** implicit polymorphism **)
   691 
   692 (* warn_extra_tfrees *)
   693 
   694 fun warn_extra_tfrees ctxt1 ctxt2 =
   695   let
   696     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   697     fun occs_free a x =
   698       (case def_type ctxt1 false (x, ~1) of
   699         SOME T => if occs_typ a T then I else cons (a, x)
   700       | NONE => cons (a, x));
   701 
   702     val occs1 = type_occs_of ctxt1;
   703     val occs2 = type_occs_of ctxt2;
   704     val extras = Symtab.fold (fn (a, xs) =>
   705       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   706     val tfrees = map #1 extras |> sort_distinct string_ord;
   707     val frees = map #2 extras |> sort_distinct string_ord;
   708   in
   709     if null extras orelse not (Context_Position.is_visible ctxt2) then ()
   710     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   711       space_implode " or " (map quote frees))
   712   end;
   713 
   714 
   715 (* polymorphic terms *)
   716 
   717 fun polymorphic_types ctxt ts =
   718   let
   719     val ctxt' = fold declare_term ts ctxt;
   720     val occs = type_occs_of ctxt;
   721     val occs' = type_occs_of ctxt';
   722     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   723     val idx = maxidx_of ctxt' + 1;
   724     val Ts' = (fold o fold_types o fold_atyps)
   725       (fn T as TFree _ =>
   726           (case Term_Subst.generalizeT types idx T of TVar v => insert (op =) v | _ => I)
   727         | _ => I) ts [];
   728     val ts' = map (Term_Subst.generalize (types, []) idx) ts;
   729   in (rev Ts', ts') end;
   730 
   731 fun polymorphic ctxt ts = snd (polymorphic_types ctxt ts);
   732 
   733 end;