src/HOL/Fun.thy
author haftmann
Sun Mar 09 22:45:09 2014 +0100 (2014-03-09)
changeset 56015 57e2cfba9c6e
parent 55990 41c6b99c5fb7
child 56077 d397030fb27e
permissions -rw-r--r--
bootstrap fundamental Fun theory immediately after Set theory, without dependency on complete lattices
* * *
tuned
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Author:     Andrei Popescu, TU Muenchen
     4     Copyright   1994, 2012
     5 *)
     6 
     7 header {* Notions about functions *}
     8 
     9 theory Fun
    10 imports Set
    11 keywords "functor" :: thy_goal
    12 begin
    13 
    14 lemma apply_inverse:
    15   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    16   by auto
    17 
    18 
    19 subsection {* The Identity Function @{text id} *}
    20 
    21 definition id :: "'a \<Rightarrow> 'a" where
    22   "id = (\<lambda>x. x)"
    23 
    24 lemma id_apply [simp]: "id x = x"
    25   by (simp add: id_def)
    26 
    27 lemma image_id [simp]: "image id = id"
    28   by (simp add: id_def fun_eq_iff)
    29 
    30 lemma vimage_id [simp]: "vimage id = id"
    31   by (simp add: id_def fun_eq_iff)
    32 
    33 code_printing
    34   constant id \<rightharpoonup> (Haskell) "id"
    35 
    36 
    37 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    38 
    39 definition comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55) where
    40   "f o g = (\<lambda>x. f (g x))"
    41 
    42 notation (xsymbols)
    43   comp  (infixl "\<circ>" 55)
    44 
    45 notation (HTML output)
    46   comp  (infixl "\<circ>" 55)
    47 
    48 lemma comp_apply [simp]: "(f o g) x = f (g x)"
    49   by (simp add: comp_def)
    50 
    51 lemma comp_assoc: "(f o g) o h = f o (g o h)"
    52   by (simp add: fun_eq_iff)
    53 
    54 lemma id_comp [simp]: "id o g = g"
    55   by (simp add: fun_eq_iff)
    56 
    57 lemma comp_id [simp]: "f o id = f"
    58   by (simp add: fun_eq_iff)
    59 
    60 lemma comp_eq_dest:
    61   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    62   by (simp add: fun_eq_iff)
    63 
    64 lemma comp_eq_elim:
    65   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    66   by (simp add: fun_eq_iff) 
    67 
    68 lemma comp_eq_dest_lhs: "a o b = c \<Longrightarrow> a (b v) = c v"
    69   by clarsimp
    70 
    71 lemma comp_eq_id_dest: "a o b = id o c \<Longrightarrow> a (b v) = c v"
    72   by clarsimp
    73 
    74 lemma image_comp:
    75   "(f o g) ` r = f ` (g ` r)"
    76   by auto
    77 
    78 lemma vimage_comp:
    79   "(g \<circ> f) -` x = f -` (g -` x)"
    80   by auto
    81 
    82 code_printing
    83   constant comp \<rightharpoonup> (SML) infixl 5 "o" and (Haskell) infixr 9 "."
    84 
    85 
    86 subsection {* The Forward Composition Operator @{text fcomp} *}
    87 
    88 definition fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60) where
    89   "f \<circ>> g = (\<lambda>x. g (f x))"
    90 
    91 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
    92   by (simp add: fcomp_def)
    93 
    94 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
    95   by (simp add: fcomp_def)
    96 
    97 lemma id_fcomp [simp]: "id \<circ>> g = g"
    98   by (simp add: fcomp_def)
    99 
   100 lemma fcomp_id [simp]: "f \<circ>> id = f"
   101   by (simp add: fcomp_def)
   102 
   103 code_printing
   104   constant fcomp \<rightharpoonup> (Eval) infixl 1 "#>"
   105 
   106 no_notation fcomp (infixl "\<circ>>" 60)
   107 
   108 
   109 subsection {* Mapping functions *}
   110 
   111 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   112   "map_fun f g h = g \<circ> h \<circ> f"
   113 
   114 lemma map_fun_apply [simp]:
   115   "map_fun f g h x = g (h (f x))"
   116   by (simp add: map_fun_def)
   117 
   118 
   119 subsection {* Injectivity and Bijectivity *}
   120 
   121 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   122   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   123 
   124 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   125   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   126 
   127 text{*A common special case: functions injective, surjective or bijective over
   128 the entire domain type.*}
   129 
   130 abbreviation
   131   "inj f \<equiv> inj_on f UNIV"
   132 
   133 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   134   "surj f \<equiv> (range f = UNIV)"
   135 
   136 abbreviation
   137   "bij f \<equiv> bij_betw f UNIV UNIV"
   138 
   139 text{* The negated case: *}
   140 translations
   141 "\<not> CONST surj f" <= "CONST range f \<noteq> CONST UNIV"
   142 
   143 lemma injI:
   144   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   145   shows "inj f"
   146   using assms unfolding inj_on_def by auto
   147 
   148 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   149   by (unfold inj_on_def, blast)
   150 
   151 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   152 by (simp add: inj_on_def)
   153 
   154 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   155 by (force simp add: inj_on_def)
   156 
   157 lemma inj_on_cong:
   158   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   159 unfolding inj_on_def by auto
   160 
   161 lemma inj_on_strict_subset:
   162   "\<lbrakk> inj_on f B; A < B \<rbrakk> \<Longrightarrow> f`A < f`B"
   163 unfolding inj_on_def unfolding image_def by blast
   164 
   165 lemma inj_comp:
   166   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   167   by (simp add: inj_on_def)
   168 
   169 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   170   by (simp add: inj_on_def fun_eq_iff)
   171 
   172 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   173 by (simp add: inj_on_eq_iff)
   174 
   175 lemma inj_on_id[simp]: "inj_on id A"
   176   by (simp add: inj_on_def)
   177 
   178 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   179 by (simp add: inj_on_def)
   180 
   181 lemma inj_on_Int: "inj_on f A \<or> inj_on f B \<Longrightarrow> inj_on f (A \<inter> B)"
   182 unfolding inj_on_def by blast
   183 
   184 lemma surj_id: "surj id"
   185 by simp
   186 
   187 lemma bij_id[simp]: "bij id"
   188 by (simp add: bij_betw_def)
   189 
   190 lemma inj_onI:
   191     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   192 by (simp add: inj_on_def)
   193 
   194 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   195 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   196 
   197 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   198 by (unfold inj_on_def, blast)
   199 
   200 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   201 by (blast dest!: inj_onD)
   202 
   203 lemma comp_inj_on:
   204      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   205 by (simp add: comp_def inj_on_def)
   206 
   207 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   208 apply(simp add:inj_on_def image_def)
   209 apply blast
   210 done
   211 
   212 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   213   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   214 apply(unfold inj_on_def)
   215 apply blast
   216 done
   217 
   218 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   219 by (unfold inj_on_def, blast)
   220 
   221 lemma inj_singleton: "inj (%s. {s})"
   222 by (simp add: inj_on_def)
   223 
   224 lemma inj_on_empty[iff]: "inj_on f {}"
   225 by(simp add: inj_on_def)
   226 
   227 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   228 by (unfold inj_on_def, blast)
   229 
   230 lemma inj_on_Un:
   231  "inj_on f (A Un B) =
   232   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   233 apply(unfold inj_on_def)
   234 apply (blast intro:sym)
   235 done
   236 
   237 lemma inj_on_insert[iff]:
   238   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   239 apply(unfold inj_on_def)
   240 apply (blast intro:sym)
   241 done
   242 
   243 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   244 apply(unfold inj_on_def)
   245 apply (blast)
   246 done
   247 
   248 lemma comp_inj_on_iff:
   249   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   250 by(auto simp add: comp_inj_on inj_on_def)
   251 
   252 lemma inj_on_imageI2:
   253   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   254 by(auto simp add: comp_inj_on inj_on_def)
   255 
   256 lemma inj_img_insertE:
   257   assumes "inj_on f A"
   258   assumes "x \<notin> B" and "insert x B = f ` A"
   259   obtains x' A' where "x' \<notin> A'" and "A = insert x' A'"
   260     and "x = f x'" and "B = f ` A'"
   261 proof -
   262   from assms have "x \<in> f ` A" by auto
   263   then obtain x' where *: "x' \<in> A" "x = f x'" by auto
   264   then have "A = insert x' (A - {x'})" by auto
   265   with assms * have "B = f ` (A - {x'})"
   266     by (auto dest: inj_on_contraD)
   267   have "x' \<notin> A - {x'}" by simp
   268   from `x' \<notin> A - {x'}` `A = insert x' (A - {x'})` `x = f x'` `B = image f (A - {x'})`
   269   show ?thesis ..
   270 qed
   271 
   272 lemma linorder_injI:
   273   assumes hyp: "\<And>x y. x < (y::'a::linorder) \<Longrightarrow> f x \<noteq> f y"
   274   shows "inj f"
   275   -- {* Courtesy of Stephan Merz *}
   276 proof (rule inj_onI)
   277   fix x y
   278   assume f_eq: "f x = f y"
   279   show "x = y" by (rule linorder_cases) (auto dest: hyp simp: f_eq)
   280 qed
   281 
   282 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   283   by auto
   284 
   285 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   286   using *[symmetric] by auto
   287 
   288 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   289   by (simp add: surj_def)
   290 
   291 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   292   by (simp add: surj_def, blast)
   293 
   294 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   295 apply (simp add: comp_def surj_def, clarify)
   296 apply (drule_tac x = y in spec, clarify)
   297 apply (drule_tac x = x in spec, blast)
   298 done
   299 
   300 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   301   unfolding bij_betw_def by auto
   302 
   303 lemma bij_betw_empty1:
   304   assumes "bij_betw f {} A"
   305   shows "A = {}"
   306 using assms unfolding bij_betw_def by blast
   307 
   308 lemma bij_betw_empty2:
   309   assumes "bij_betw f A {}"
   310   shows "A = {}"
   311 using assms unfolding bij_betw_def by blast
   312 
   313 lemma inj_on_imp_bij_betw:
   314   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   315 unfolding bij_betw_def by simp
   316 
   317 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   318   unfolding bij_betw_def ..
   319 
   320 lemma bijI: "[| inj f; surj f |] ==> bij f"
   321 by (simp add: bij_def)
   322 
   323 lemma bij_is_inj: "bij f ==> inj f"
   324 by (simp add: bij_def)
   325 
   326 lemma bij_is_surj: "bij f ==> surj f"
   327 by (simp add: bij_def)
   328 
   329 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   330 by (simp add: bij_betw_def)
   331 
   332 lemma bij_betw_trans:
   333   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   334 by(auto simp add:bij_betw_def comp_inj_on)
   335 
   336 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   337   by (rule bij_betw_trans)
   338 
   339 lemma bij_betw_comp_iff:
   340   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   341 by(auto simp add: bij_betw_def inj_on_def)
   342 
   343 lemma bij_betw_comp_iff2:
   344   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   345   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   346 using assms
   347 proof(auto simp add: bij_betw_comp_iff)
   348   assume *: "bij_betw (f' \<circ> f) A A''"
   349   thus "bij_betw f A A'"
   350   using IM
   351   proof(auto simp add: bij_betw_def)
   352     assume "inj_on (f' \<circ> f) A"
   353     thus "inj_on f A" using inj_on_imageI2 by blast
   354   next
   355     fix a' assume **: "a' \<in> A'"
   356     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   357     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   358     unfolding bij_betw_def by force
   359     hence "f a \<in> A'" using IM by auto
   360     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   361     thus "a' \<in> f ` A" using 1 by auto
   362   qed
   363 qed
   364 
   365 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   366 proof -
   367   have i: "inj_on f A" and s: "f ` A = B"
   368     using assms by(auto simp:bij_betw_def)
   369   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   370   { fix a b assume P: "?P b a"
   371     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   372     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   373     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   374   } note g = this
   375   have "inj_on ?g B"
   376   proof(rule inj_onI)
   377     fix x y assume "x:B" "y:B" "?g x = ?g y"
   378     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   379     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   380     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   381   qed
   382   moreover have "?g ` B = A"
   383   proof(auto simp:image_def)
   384     fix b assume "b:B"
   385     with s obtain a where P: "?P b a" unfolding image_def by blast
   386     thus "?g b \<in> A" using g[OF P] by auto
   387   next
   388     fix a assume "a:A"
   389     then obtain b where P: "?P b a" using s unfolding image_def by blast
   390     then have "b:B" using s unfolding image_def by blast
   391     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   392   qed
   393   ultimately show ?thesis by(auto simp:bij_betw_def)
   394 qed
   395 
   396 lemma bij_betw_cong:
   397   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   398 unfolding bij_betw_def inj_on_def by force
   399 
   400 lemma bij_betw_id[intro, simp]:
   401   "bij_betw id A A"
   402 unfolding bij_betw_def id_def by auto
   403 
   404 lemma bij_betw_id_iff:
   405   "bij_betw id A B \<longleftrightarrow> A = B"
   406 by(auto simp add: bij_betw_def)
   407 
   408 lemma bij_betw_combine:
   409   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   410   shows "bij_betw f (A \<union> C) (B \<union> D)"
   411   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   412 
   413 lemma bij_betw_subset:
   414   assumes BIJ: "bij_betw f A A'" and
   415           SUB: "B \<le> A" and IM: "f ` B = B'"
   416   shows "bij_betw f B B'"
   417 using assms
   418 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   419 
   420 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   421 by simp
   422 
   423 lemma surj_vimage_empty:
   424   assumes "surj f" shows "f -` A = {} \<longleftrightarrow> A = {}"
   425   using surj_image_vimage_eq[OF `surj f`, of A]
   426   by (intro iffI) fastforce+
   427 
   428 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   429 by (simp add: inj_on_def, blast)
   430 
   431 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   432 by (blast intro: sym)
   433 
   434 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   435 by (unfold inj_on_def, blast)
   436 
   437 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   438 apply (unfold bij_def)
   439 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   440 done
   441 
   442 lemma inj_on_image_eq_iff: "\<lbrakk> inj_on f C; A \<subseteq> C; B \<subseteq> C \<rbrakk> \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   443 by(fastforce simp add: inj_on_def)
   444 
   445 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   446 by(erule inj_on_image_eq_iff) simp_all
   447 
   448 lemma inj_on_image_Int:
   449    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   450 apply (simp add: inj_on_def, blast)
   451 done
   452 
   453 lemma inj_on_image_set_diff:
   454    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   455 apply (simp add: inj_on_def, blast)
   456 done
   457 
   458 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   459 by (simp add: inj_on_def, blast)
   460 
   461 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   462 by (simp add: inj_on_def, blast)
   463 
   464 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   465 by (blast dest: injD)
   466 
   467 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   468 by (simp add: inj_on_def, blast)
   469 
   470 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   471 by (blast dest: injD)
   472 
   473 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   474 by auto
   475 
   476 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   477 by (auto simp add: inj_on_def)
   478 
   479 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   480 apply (simp add: bij_def)
   481 apply (rule equalityI)
   482 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   483 done
   484 
   485 lemma inj_vimage_singleton: "inj f \<Longrightarrow> f -` {a} \<subseteq> {THE x. f x = a}"
   486   -- {* The inverse image of a singleton under an injective function
   487          is included in a singleton. *}
   488   apply (auto simp add: inj_on_def)
   489   apply (blast intro: the_equality [symmetric])
   490   done
   491 
   492 lemma inj_on_vimage_singleton:
   493   "inj_on f A \<Longrightarrow> f -` {a} \<inter> A \<subseteq> {THE x. x \<in> A \<and> f x = a}"
   494   by (auto simp add: inj_on_def intro: the_equality [symmetric])
   495 
   496 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   497   by (auto intro!: inj_onI)
   498 
   499 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   500   by (auto intro!: inj_onI dest: strict_mono_eq)
   501 
   502 lemma bij_betw_byWitness:
   503 assumes LEFT: "\<forall>a \<in> A. f'(f a) = a" and
   504         RIGHT: "\<forall>a' \<in> A'. f(f' a') = a'" and
   505         IM1: "f ` A \<le> A'" and IM2: "f' ` A' \<le> A"
   506 shows "bij_betw f A A'"
   507 using assms
   508 proof(unfold bij_betw_def inj_on_def, safe)
   509   fix a b assume *: "a \<in> A" "b \<in> A" and **: "f a = f b"
   510   have "a = f'(f a) \<and> b = f'(f b)" using * LEFT by simp
   511   with ** show "a = b" by simp
   512 next
   513   fix a' assume *: "a' \<in> A'"
   514   hence "f' a' \<in> A" using IM2 by blast
   515   moreover
   516   have "a' = f(f' a')" using * RIGHT by simp
   517   ultimately show "a' \<in> f ` A" by blast
   518 qed
   519 
   520 corollary notIn_Un_bij_betw:
   521 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'" and
   522        BIJ: "bij_betw f A A'"
   523 shows "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   524 proof-
   525   have "bij_betw f {b} {f b}"
   526   unfolding bij_betw_def inj_on_def by simp
   527   with assms show ?thesis
   528   using bij_betw_combine[of f A A' "{b}" "{f b}"] by blast
   529 qed
   530 
   531 lemma notIn_Un_bij_betw3:
   532 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'"
   533 shows "bij_betw f A A' = bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   534 proof
   535   assume "bij_betw f A A'"
   536   thus "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   537   using assms notIn_Un_bij_betw[of b A f A'] by blast
   538 next
   539   assume *: "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   540   have "f ` A = A'"
   541   proof(auto)
   542     fix a assume **: "a \<in> A"
   543     hence "f a \<in> A' \<union> {f b}" using * unfolding bij_betw_def by blast
   544     moreover
   545     {assume "f a = f b"
   546      hence "a = b" using * ** unfolding bij_betw_def inj_on_def by blast
   547      with NIN ** have False by blast
   548     }
   549     ultimately show "f a \<in> A'" by blast
   550   next
   551     fix a' assume **: "a' \<in> A'"
   552     hence "a' \<in> f`(A \<union> {b})"
   553     using * by (auto simp add: bij_betw_def)
   554     then obtain a where 1: "a \<in> A \<union> {b} \<and> f a = a'" by blast
   555     moreover
   556     {assume "a = b" with 1 ** NIN' have False by blast
   557     }
   558     ultimately have "a \<in> A" by blast
   559     with 1 show "a' \<in> f ` A" by blast
   560   qed
   561   thus "bij_betw f A A'" using * bij_betw_subset[of f "A \<union> {b}" _ A] by blast
   562 qed
   563 
   564 
   565 subsection{*Function Updating*}
   566 
   567 definition fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   568   "fun_upd f a b == % x. if x=a then b else f x"
   569 
   570 nonterminal updbinds and updbind
   571 
   572 syntax
   573   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   574   ""         :: "updbind => updbinds"             ("_")
   575   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   576   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   577 
   578 translations
   579   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   580   "f(x:=y)" == "CONST fun_upd f x y"
   581 
   582 (* Hint: to define the sum of two functions (or maps), use case_sum.
   583          A nice infix syntax could be defined (in Datatype.thy or below) by
   584 notation
   585   case_sum  (infixr "'(+')"80)
   586 *)
   587 
   588 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   589 apply (simp add: fun_upd_def, safe)
   590 apply (erule subst)
   591 apply (rule_tac [2] ext, auto)
   592 done
   593 
   594 lemma fun_upd_idem: "f x = y ==> f(x:=y) = f"
   595   by (simp only: fun_upd_idem_iff)
   596 
   597 lemma fun_upd_triv [iff]: "f(x := f x) = f"
   598   by (simp only: fun_upd_idem)
   599 
   600 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   601 by (simp add: fun_upd_def)
   602 
   603 (* fun_upd_apply supersedes these two,   but they are useful
   604    if fun_upd_apply is intentionally removed from the simpset *)
   605 lemma fun_upd_same: "(f(x:=y)) x = y"
   606 by simp
   607 
   608 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   609 by simp
   610 
   611 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   612 by (simp add: fun_eq_iff)
   613 
   614 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   615 by (rule ext, auto)
   616 
   617 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   618 by (fastforce simp:inj_on_def image_def)
   619 
   620 lemma fun_upd_image:
   621      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   622 by auto
   623 
   624 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   625   by auto
   626 
   627 
   628 subsection {* @{text override_on} *}
   629 
   630 definition override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b" where
   631   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   632 
   633 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   634 by(simp add:override_on_def)
   635 
   636 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   637 by(simp add:override_on_def)
   638 
   639 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   640 by(simp add:override_on_def)
   641 
   642 
   643 subsection {* @{text swap} *}
   644 
   645 definition swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)" where
   646   "swap a b f = f (a := f b, b:= f a)"
   647 
   648 lemma swap_self [simp]: "swap a a f = f"
   649 by (simp add: swap_def)
   650 
   651 lemma swap_commute: "swap a b f = swap b a f"
   652 by (rule ext, simp add: fun_upd_def swap_def)
   653 
   654 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   655 by (rule ext, simp add: fun_upd_def swap_def)
   656 
   657 lemma swap_triple:
   658   assumes "a \<noteq> c" and "b \<noteq> c"
   659   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   660   using assms by (simp add: fun_eq_iff swap_def)
   661 
   662 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   663 by (rule ext, simp add: fun_upd_def swap_def)
   664 
   665 lemma swap_image_eq [simp]:
   666   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   667 proof -
   668   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   669     using assms by (auto simp: image_iff swap_def)
   670   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   671   with subset[of f] show ?thesis by auto
   672 qed
   673 
   674 lemma inj_on_imp_inj_on_swap:
   675   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   676   by (simp add: inj_on_def swap_def, blast)
   677 
   678 lemma inj_on_swap_iff [simp]:
   679   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   680 proof
   681   assume "inj_on (swap a b f) A"
   682   with A have "inj_on (swap a b (swap a b f)) A"
   683     by (iprover intro: inj_on_imp_inj_on_swap)
   684   thus "inj_on f A" by simp
   685 next
   686   assume "inj_on f A"
   687   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   688 qed
   689 
   690 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   691   by simp
   692 
   693 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   694   by simp
   695 
   696 lemma bij_betw_swap_iff [simp]:
   697   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   698   by (auto simp: bij_betw_def)
   699 
   700 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   701   by simp
   702 
   703 hide_const (open) swap
   704 
   705 subsection {* Inversion of injective functions *}
   706 
   707 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   708   "the_inv_into A f == %x. THE y. y : A & f y = x"
   709 
   710 lemma the_inv_into_f_f:
   711   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   712 apply (simp add: the_inv_into_def inj_on_def)
   713 apply blast
   714 done
   715 
   716 lemma f_the_inv_into_f:
   717   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   718 apply (simp add: the_inv_into_def)
   719 apply (rule the1I2)
   720  apply(blast dest: inj_onD)
   721 apply blast
   722 done
   723 
   724 lemma the_inv_into_into:
   725   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   726 apply (simp add: the_inv_into_def)
   727 apply (rule the1I2)
   728  apply(blast dest: inj_onD)
   729 apply blast
   730 done
   731 
   732 lemma the_inv_into_onto[simp]:
   733   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   734 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   735 
   736 lemma the_inv_into_f_eq:
   737   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   738   apply (erule subst)
   739   apply (erule the_inv_into_f_f, assumption)
   740   done
   741 
   742 lemma the_inv_into_comp:
   743   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   744   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   745 apply (rule the_inv_into_f_eq)
   746   apply (fast intro: comp_inj_on)
   747  apply (simp add: f_the_inv_into_f the_inv_into_into)
   748 apply (simp add: the_inv_into_into)
   749 done
   750 
   751 lemma inj_on_the_inv_into:
   752   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   753 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   754 
   755 lemma bij_betw_the_inv_into:
   756   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   757 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   758 
   759 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   760   "the_inv f \<equiv> the_inv_into UNIV f"
   761 
   762 lemma the_inv_f_f:
   763   assumes "inj f"
   764   shows "the_inv f (f x) = x" using assms UNIV_I
   765   by (rule the_inv_into_f_f)
   766 
   767 
   768 subsection {* Cantor's Paradox *}
   769 
   770 lemma Cantors_paradox:
   771   "\<not>(\<exists>f. f ` A = Pow A)"
   772 proof clarify
   773   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   774   let ?X = "{a \<in> A. a \<notin> f a}"
   775   have "?X \<in> Pow A" unfolding Pow_def by auto
   776   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   777   thus False by best
   778 qed
   779 
   780 subsection {* Setup *} 
   781 
   782 subsubsection {* Proof tools *}
   783 
   784 text {* simplifies terms of the form
   785   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   786 
   787 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   788 let
   789   fun gen_fun_upd NONE T _ _ = NONE
   790     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   791   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   792   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   793     let
   794       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   795             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   796         | find t = NONE
   797     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   798 
   799   val ss = simpset_of @{context}
   800 
   801   fun proc ctxt ct =
   802     let
   803       val t = Thm.term_of ct
   804     in
   805       case find_double t of
   806         (T, NONE) => NONE
   807       | (T, SOME rhs) =>
   808           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   809             (fn _ =>
   810               rtac eq_reflection 1 THEN
   811               rtac @{thm ext} 1 THEN
   812               simp_tac (put_simpset ss ctxt) 1))
   813     end
   814 in proc end
   815 *}
   816 
   817 
   818 subsubsection {* Functorial structure of types *}
   819 
   820 ML_file "Tools/functor.ML"
   821 
   822 functor map_fun: map_fun
   823   by (simp_all add: fun_eq_iff)
   824 
   825 functor vimage
   826   by (simp_all add: fun_eq_iff vimage_comp)
   827 
   828 text {* Legacy theorem names *}
   829 
   830 lemmas o_def = comp_def
   831 lemmas o_apply = comp_apply
   832 lemmas o_assoc = comp_assoc [symmetric]
   833 lemmas id_o = id_comp
   834 lemmas o_id = comp_id
   835 lemmas o_eq_dest = comp_eq_dest
   836 lemmas o_eq_elim = comp_eq_elim
   837 lemmas o_eq_dest_lhs = comp_eq_dest_lhs
   838 lemmas o_eq_id_dest = comp_eq_id_dest
   839 lemmas image_compose = image_comp
   840 lemmas vimage_compose = vimage_comp
   841 
   842 end
   843