src/Pure/pattern.ML
author wenzelm
Mon Jun 21 16:41:06 2004 +0200 (2004-06-21)
changeset 14990 582b655da757
parent 14981 e73f8140af78
child 15531 08c8dad8e399
permissions -rw-r--r--
pretty_abbr;
     1 (*  Title:      Pure/pattern.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer
     4 
     5 Unification of Higher-Order Patterns.
     6 
     7 See also:
     8 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
     9 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    10 
    11 TODO: optimize red by special-casing it
    12 *)
    13 
    14 infix aeconv;
    15 
    16 signature PATTERN =
    17 sig
    18   val trace_unify_fail  : bool ref
    19   val aeconv            : term * term -> bool
    20   val eta_contract      : term -> term
    21   val eta_long          : typ list -> term -> term
    22   val beta_eta_contract : term -> term
    23   val eta_contract_atom : term -> term
    24   val match             : Type.tsig -> term * term
    25                           -> (indexname*typ)list * (indexname*term)list
    26   val first_order_match : Type.tsig -> term * term
    27                           -> (indexname*typ)list * (indexname*term)list
    28   val matches           : Type.tsig -> term * term -> bool
    29   val matches_subterm   : Type.tsig -> term * term -> bool
    30   val unify             : Sign.sg * Envir.env * (term * term)list -> Envir.env
    31   val first_order       : term -> bool
    32   val pattern           : term -> bool
    33   val rewrite_term      : Type.tsig -> (term * term) list -> (term -> term option) list
    34                           -> term -> term
    35   exception Unif
    36   exception MATCH
    37   exception Pattern
    38 end;
    39 
    40 structure Pattern : PATTERN =
    41 struct
    42 
    43 exception Unif;
    44 exception Pattern;
    45 
    46 val trace_unify_fail = ref false;
    47 
    48 fun string_of_term sg env binders t = Sign.string_of_term sg
    49   (Envir.norm_term env (subst_bounds(map Free binders,t)));
    50 
    51 fun bname binders i = fst(nth_elem(i,binders));
    52 fun bnames binders is = space_implode " " (map (bname binders) is);
    53 
    54 fun typ_clash sg (tye,T,U) =
    55   if !trace_unify_fail
    56   then let val t = Sign.string_of_typ sg (Envir.norm_type tye T)
    57            and u = Sign.string_of_typ sg (Envir.norm_type tye U)
    58        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    59   else ()
    60 
    61 fun clash a b =
    62   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    63 
    64 fun boundVar binders i =
    65   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    66 
    67 fun clashBB binders i j =
    68   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    69   else ()
    70 
    71 fun clashB binders i s =
    72   if !trace_unify_fail then clash (boundVar binders i) s
    73   else ()
    74 
    75 fun proj_fail sg (env,binders,F,is,t) =
    76   if !trace_unify_fail
    77   then let val f = Syntax.string_of_vname F
    78            val xs = bnames binders is
    79            val u = string_of_term sg env binders t
    80            val ys = bnames binders (loose_bnos t \\ is)
    81        in tracing("Cannot unify variable " ^ f ^
    82                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
    83                "\nTerm contains additional bound variable(s) " ^ ys)
    84        end
    85   else ()
    86 
    87 fun ocheck_fail sg (F,t,binders,env) =
    88   if !trace_unify_fail
    89   then let val f = Syntax.string_of_vname F
    90            val u = string_of_term sg env binders t
    91        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
    92                   "\nCannot unify!\n")
    93        end
    94   else ()
    95 
    96 fun occurs(F,t,env) =
    97     let fun occ(Var(G,_))   = (case Envir.lookup(env,G) of
    98                                  Some(t) => occ t
    99                                | None    => F=G)
   100           | occ(t1$t2)      = occ t1 orelse occ t2
   101           | occ(Abs(_,_,t)) = occ t
   102           | occ _           = false
   103     in occ t end;
   104 
   105 
   106 fun mapbnd f =
   107     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   108           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   109           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   110           | mpb _ atom           = atom
   111     in mpb 0 end;
   112 
   113 fun idx [] j     = raise Unif
   114   | idx(i::is) j = if i=j then length is else idx is j;
   115 
   116 fun at xs i = nth_elem (i,xs);
   117 
   118 fun mkabs (binders,is,t)  =
   119     let fun mk(i::is) = let val (x,T) = nth_elem(i,binders)
   120                         in Abs(x,T,mk is) end
   121           | mk []     = t
   122     in mk is end;
   123 
   124 val incr = mapbnd (fn i => i+1);
   125 
   126 fun ints_of []             = []
   127   | ints_of (Bound i ::bs) =
   128       let val is = ints_of bs
   129       in if i mem_int is then raise Pattern else i::is end
   130   | ints_of _              = raise Pattern;
   131 
   132 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   133 
   134 
   135 fun app (s,(i::is)) = app (s$Bound(i),is)
   136   | app (s,[])      = s;
   137 
   138 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   139   | red t            []      [] = t
   140   | red t            is      jn = app (mapbnd (at jn) t,is);
   141 
   142 
   143 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   144 fun split_type (T,0,Ts)                    = (Ts,T)
   145   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   146   | split_type _                           = error("split_type");
   147 
   148 fun type_of_G (env as Envir.Envir {iTs, ...}) (T,n,is) =
   149   let val (Ts, U) = split_type (Envir.norm_type iTs T, n, [])
   150   in map (at Ts) is ---> U end;
   151 
   152 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   153 
   154 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   155   let val (env',G) = Envir.genvar a (env,type_of_G env (T,length is,js))
   156   in Envir.update((F,mkhnf(binders,is,G,js)),env') end;
   157 
   158 
   159 (* mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ] *)
   160 fun mk_proj_list is =
   161     let fun mk(i::is,j) = if is_some i then j :: mk(is,j-1) else mk(is,j-1)
   162           | mk([],_)    = []
   163     in mk(is,length is - 1) end;
   164 
   165 fun proj(s,env,binders,is) =
   166     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   167         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   168               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   169                             in (Abs(a,T,t'),env') end
   170             | t => (case strip_comb t of
   171                 (c as Const _,ts) =>
   172                          let val (ts',env') = prs(ts,env,d,binders)
   173                          in (list_comb(c,ts'),env') end
   174                  | (f as Free _,ts) =>
   175                          let val (ts',env') = prs(ts,env,d,binders)
   176                          in (list_comb(f,ts'),env') end
   177                  | (Bound(i),ts) =>
   178                          let val j = trans d i
   179                              val (ts',env') = prs(ts,env,d,binders)
   180                          in (list_comb(Bound j,ts'),env') end
   181                  | (Var(F as (a,_),Fty),ts) =>
   182                       let val js = ints_of' env ts;
   183                           val js' = map (try (trans d)) js;
   184                           val ks = mk_proj_list js';
   185                           val ls = mapfilter I js'
   186                           val Hty = type_of_G env (Fty,length js,ks)
   187                           val (env',H) = Envir.genvar a (env,Hty)
   188                           val env'' =
   189                                 Envir.update((F,mkhnf(binders,js,H,ks)),env')
   190                       in (app(H,ls),env'') end
   191                  | _  => raise Pattern))
   192         and prs(s::ss,env,d,binders) =
   193               let val (s',env1) = pr(s,env,d,binders)
   194                   val (ss',env2) = prs(ss,env1,d,binders)
   195               in (s'::ss',env2) end
   196           | prs([],env,_,_) = ([],env)
   197    in if downto0(is,length binders - 1) then (s,env)
   198       else pr(s,env,0,binders)
   199    end;
   200 
   201 
   202 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   203 fun mk_ff_list(is,js) =
   204     let fun mk([],[],_)        = []
   205           | mk(i::is,j::js, k) = if i=j then k :: mk(is,js,k-1)
   206                                         else mk(is,js,k-1)
   207           | mk _               = error"mk_ff_list"
   208     in mk(is,js,length is-1) end;
   209 
   210 fun flexflex1(env,binders,F,Fty,is,js) =
   211   if is=js then env
   212   else let val ks = mk_ff_list(is,js)
   213        in mknewhnf(env,binders,is,F,Fty,ks) end;
   214 
   215 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   216   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   217             if js subset_int is
   218             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   219                  in Envir.update((F,t),env) end
   220             else let val ks = is inter_int js
   221                      val Hty = type_of_G env (Fty,length is,map (idx is) ks)
   222                      val (env',H) = Envir.genvar a (env,Hty)
   223                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   224                  in Envir.update((G,lam js), Envir.update((F,lam is),env'))
   225                  end;
   226   in if xless(G,F) then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   227 
   228 fun unify_types sg (T,U, env as Envir.Envir{asol,iTs,maxidx}) =
   229   if T=U then env
   230   else let val (iTs',maxidx') = Type.unify (Sign.tsig_of sg) (iTs, maxidx) (U, T)
   231        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   232        handle Type.TUNIFY => (typ_clash sg (iTs,T,U); raise Unif);
   233 
   234 fun unif sg binders (env,(s,t)) = case (Envir.head_norm env s, Envir.head_norm env t) of
   235       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   236          let val name = if ns = "" then nt else ns
   237          in unif sg ((name,Ts)::binders) (env,(ts,tt)) end
   238     | (Abs(ns,Ts,ts),t) => unif sg ((ns,Ts)::binders) (env,(ts,(incr t)$Bound(0)))
   239     | (t,Abs(nt,Tt,tt)) => unif sg ((nt,Tt)::binders) (env,((incr t)$Bound(0),tt))
   240     | p => cases sg (binders,env,p)
   241 
   242 and cases sg (binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   243        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   244          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   245                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   246       | ((Var(F,_),ss),_)             => flexrigid sg (env,binders,F,ints_of' env ss,t)
   247       | (_,(Var(F,_),ts))             => flexrigid sg (env,binders,F,ints_of' env ts,s)
   248       | ((Const c,ss),(Const d,ts))   => rigidrigid sg (env,binders,c,d,ss,ts)
   249       | ((Free(f),ss),(Free(g),ts))   => rigidrigid sg (env,binders,f,g,ss,ts)
   250       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB sg (env,binders,i,j,ss,ts)
   251       | ((Abs(_),_),_)                => raise Pattern
   252       | (_,(Abs(_),_))                => raise Pattern
   253       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   254       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   255       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   256       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   257       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   258       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   259 
   260 
   261 and rigidrigid sg (env,binders,(a,Ta),(b,Tb),ss,ts) =
   262       if a<>b then (clash a b; raise Unif)
   263       else foldl (unif sg binders) (unify_types sg (Ta,Tb,env), ss~~ts)
   264 
   265 and rigidrigidB sg (env,binders,i,j,ss,ts) =
   266      if i <> j then (clashBB binders i j; raise Unif)
   267      else foldl (unif sg binders) (env ,ss~~ts)
   268 
   269 and flexrigid sg (params as (env,binders,F,is,t)) =
   270       if occurs(F,t,env) then (ocheck_fail sg (F,t,binders,env); raise Unif)
   271       else (let val (u,env') = proj(t,env,binders,is)
   272             in Envir.update((F,mkabs(binders,is,u)),env') end
   273             handle Unif => (proj_fail sg params; raise Unif));
   274 
   275 fun unify(sg,env,tus) = foldl (unif sg []) (env,tus);
   276 
   277 
   278 (*Eta-contract a term (fully)*)
   279 
   280 fun eta_contract t =
   281   let
   282     exception SAME;
   283     fun eta (Abs (a, T, body)) =
   284       ((case eta body of
   285           body' as (f $ Bound 0) =>
   286             if loose_bvar1 (f, 0) then Abs(a, T, body')
   287             else incr_boundvars ~1 f
   288         | body' => Abs (a, T, body')) handle SAME =>
   289        (case body of
   290           (f $ Bound 0) =>
   291             if loose_bvar1 (f, 0) then raise SAME
   292             else incr_boundvars ~1 f
   293         | _ => raise SAME))
   294       | eta (f $ t) =
   295           (let val f' = eta f
   296            in f' $ etah t end handle SAME => f $ eta t)
   297       | eta _ = raise SAME
   298     and etah t = (eta t handle SAME => t)
   299   in etah t end;
   300 
   301 val beta_eta_contract = eta_contract o Envir.beta_norm;
   302 
   303 (*Eta-contract a term from outside: just enough to reduce it to an atom
   304 DOESN'T QUITE WORK!
   305 *)
   306 fun eta_contract_atom (t0 as Abs(a, T, body)) =
   307       (case  eta_contract2 body  of
   308         body' as (f $ Bound 0) =>
   309             if loose_bvar1(f,0) then Abs(a,T,body')
   310             else eta_contract_atom (incr_boundvars ~1 f)
   311       | _ => t0)
   312   | eta_contract_atom t = t
   313 and eta_contract2 (f$t) = f $ eta_contract_atom t
   314   | eta_contract2 t     = eta_contract_atom t;
   315 
   316 (* put a term into eta long beta normal form *)
   317 fun eta_long Ts (Abs (s, T, t)) = Abs (s, T, eta_long (T :: Ts) t)
   318   | eta_long Ts t = (case strip_comb t of
   319       (Abs _, _) => eta_long Ts (Envir.beta_norm t)
   320     | (u, ts) =>
   321       let
   322         val Us = binder_types (fastype_of1 (Ts, t));
   323         val i = length Us
   324       in list_abs (map (pair "x") Us,
   325         list_comb (incr_boundvars i u, map (eta_long (rev Us @ Ts))
   326           (map (incr_boundvars i) ts @ map Bound (i - 1 downto 0))))
   327       end);
   328 
   329 
   330 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   331   Note that Consts and Vars may have more than one type.*)
   332 fun t aeconv u = aconv_aux (eta_contract_atom t, eta_contract_atom u)
   333 and aconv_aux (Const(a,T), Const(b,U)) = a=b  andalso  T=U
   334   | aconv_aux (Free(a,T),  Free(b,U))  = a=b  andalso  T=U
   335   | aconv_aux (Var(v,T),   Var(w,U))   = eq_ix(v,w) andalso  T=U
   336   | aconv_aux (Bound i,    Bound j)    = i=j
   337   | aconv_aux (Abs(_,T,t), Abs(_,U,u)) = (t aeconv u)  andalso  T=U
   338   | aconv_aux (f$t,        g$u)        = (f aeconv g)  andalso (t aeconv u)
   339   | aconv_aux _ =  false;
   340 
   341 
   342 (*** Matching ***)
   343 
   344 exception MATCH;
   345 
   346 fun typ_match tsig args = (Type.typ_match tsig args)
   347                           handle Type.TYPE_MATCH => raise MATCH;
   348 
   349 (*First-order matching;
   350   fomatch tsig (pattern, object) returns a (tyvar,typ)list and (var,term)list.
   351   The pattern and object may have variables in common.
   352   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   353   Object is eta-contracted on the fly (by eta-expanding the pattern).
   354   Precondition: the pattern is already eta-contracted!
   355   Note: types are matched on the fly *)
   356 fun fomatch tsig =
   357   let
   358     fun mtch (instsp as (tyinsts,insts)) = fn
   359         (Var(ixn,T), t)  =>
   360           if loose_bvar(t,0) then raise MATCH
   361           else (case assoc_string_int(insts,ixn) of
   362                   None => (typ_match tsig (tyinsts, (T, fastype_of t)),
   363                            (ixn,t)::insts)
   364                 | Some u => if t aeconv u then instsp else raise MATCH)
   365       | (Free (a,T), Free (b,U)) =>
   366           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   367       | (Const (a,T), Const (b,U))  =>
   368           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   369       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   370       | (Abs(_,T,t), Abs(_,U,u))  =>
   371           mtch (typ_match tsig (tyinsts,(T,U)),insts) (t,u)
   372       | (f$t, g$u) => mtch (mtch instsp (f,g)) (t, u)
   373       | (t, Abs(_,U,u))  =>  mtch instsp ((incr t)$(Bound 0), u)
   374       | _ => raise MATCH
   375   in mtch end;
   376 
   377 fun first_order_match tsig = apfst Vartab.dest o fomatch tsig (Vartab.empty, []);
   378 
   379 (* Matching of higher-order patterns *)
   380 
   381 fun match_bind(itms,binders,ixn,is,t) =
   382   let val js = loose_bnos t
   383   in if null is
   384      then if null js then (ixn,t)::itms else raise MATCH
   385      else if js subset_int is
   386           then let val t' = if downto0(is,length binders - 1) then t
   387                             else mapbnd (idx is) t
   388                in (ixn, mkabs(binders,is,t')) :: itms end
   389           else raise MATCH
   390   end;
   391 
   392 fun match tsg (po as (pat,obj)) =
   393 let
   394   (* Pre: pat and obj have same type *)
   395   fun mtch binders (env as (iTs,itms),(pat,obj)) =
   396     case pat of
   397       Abs(ns,Ts,ts) =>
   398         (case obj of
   399            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (env,(ts,tt))
   400          | _ => let val Tt = typ_subst_TVars_Vartab iTs Ts
   401                 in mtch((ns,Tt)::binders)(env,(ts,(incr obj)$Bound(0))) end)
   402     | _ => (case obj of
   403               Abs(nt,Tt,tt) =>
   404                 mtch((nt,Tt)::binders)(env,((incr pat)$Bound(0),tt))
   405             | _ => cases(binders,env,pat,obj))
   406 
   407   and cases(binders,env as (iTs,itms),pat,obj) =
   408     let val (ph,pargs) = strip_comb pat
   409         fun rigrig1(iTs,oargs) =
   410               foldl (mtch binders) ((iTs,itms), pargs~~oargs)
   411         fun rigrig2((a,Ta),(b,Tb),oargs) =
   412               if a<> b then raise MATCH
   413               else rigrig1(typ_match tsg (iTs,(Ta,Tb)), oargs)
   414     in case ph of
   415          Var(ixn,_) =>
   416            let val is = ints_of pargs
   417            in case assoc_string_int(itms,ixn) of
   418                 None => (iTs,match_bind(itms,binders,ixn,is,obj))
   419               | Some u => if obj aeconv (red u is []) then env
   420                           else raise MATCH
   421            end
   422        | _ =>
   423            let val (oh,oargs) = strip_comb obj
   424            in case (ph,oh) of
   425                 (Const c,Const d) => rigrig2(c,d,oargs)
   426               | (Free f,Free g)   => rigrig2(f,g,oargs)
   427               | (Bound i,Bound j) => if i<>j then raise MATCH
   428                                      else rigrig1(iTs,oargs)
   429               | (Abs _, _)        => raise Pattern
   430               | (_, Abs _)        => raise Pattern
   431               | _                 => raise MATCH
   432            end
   433     end;
   434 
   435   val pT = fastype_of pat
   436   and oT = fastype_of obj
   437   val iTs = typ_match tsg (Vartab.empty, (pT,oT))
   438   val insts2 = (iTs,[])
   439 
   440 in apfst Vartab.dest (mtch [] (insts2, po)
   441    handle Pattern => fomatch tsg insts2 po)
   442 end;
   443 
   444 (*Predicate: does the pattern match the object?*)
   445 fun matches tsig po = (match tsig po; true) handle MATCH => false;
   446 
   447 (* Does pat match a subterm of obj? *)
   448 fun matches_subterm tsig (pat,obj) =
   449   let fun msub(bounds,obj) = matches tsig (pat,obj) orelse
   450             case obj of
   451               Abs(x,T,t) => let val y = variant bounds x
   452                                 val f = Free(":" ^ y,T)
   453                             in msub(x::bounds,subst_bound(f,t)) end
   454             | s$t => msub(bounds,s) orelse msub(bounds,t)
   455             | _ => false
   456   in msub([],obj) end;
   457 
   458 fun first_order(Abs(_,_,t)) = first_order t
   459   | first_order(t $ u) = first_order t andalso first_order u andalso
   460                          not(is_Var t)
   461   | first_order _ = true;
   462 
   463 fun pattern(Abs(_,_,t)) = pattern t
   464   | pattern(t) = let val (head,args) = strip_comb t
   465                  in if is_Var head
   466                     then let val _ = ints_of args in true end
   467                          handle Pattern => false
   468                     else forall pattern args
   469                  end;
   470 
   471 
   472 (* rewriting -- simple but fast *)
   473 
   474 fun rewrite_term tsig rules procs tm =
   475   let
   476     val skel0 = Bound 0;
   477 
   478     val rhs_names =
   479       foldr (fn ((_, rhs), names) => add_term_free_names (rhs, names)) (rules, []);
   480 
   481     fun variant_absfree (x, T, t) =
   482       let
   483         val x' = variant (add_term_free_names (t, rhs_names)) x;
   484         val t' = subst_bound (Free (x', T), t);
   485       in (fn u => Abs (x, T, abstract_over (Free (x', T), u)), t') end;
   486 
   487     fun match_rew tm (tm1, tm2) =
   488       let val rtm = if_none (Term.rename_abs tm1 tm tm2) tm2
   489       in Some (subst_vars (match tsig (tm1, tm)) rtm, rtm)
   490         handle MATCH => None
   491       end;
   492 
   493     fun rew (Abs (_, _, body) $ t) = Some (subst_bound (t, body), skel0)
   494       | rew tm = (case get_first (match_rew tm) rules of
   495           None => apsome (rpair skel0) (get_first (fn p => p tm) procs)
   496         | x => x);
   497 
   498     fun rew1 (Var _) _ = None
   499       | rew1 skel tm = (case rew2 skel tm of
   500           Some tm1 => (case rew tm1 of
   501               Some (tm2, skel') => Some (if_none (rew1 skel' tm2) tm2)
   502             | None => Some tm1)
   503         | None => (case rew tm of
   504               Some (tm1, skel') => Some (if_none (rew1 skel' tm1) tm1)
   505             | None => None))
   506 
   507     and rew2 skel (tm1 $ tm2) = (case tm1 of
   508             Abs (_, _, body) =>
   509               let val tm' = subst_bound (tm2, body)
   510               in Some (if_none (rew2 skel0 tm') tm') end
   511           | _ =>
   512             let val (skel1, skel2) = (case skel of
   513                 skel1 $ skel2 => (skel1, skel2)
   514               | _ => (skel0, skel0))
   515             in case rew1 skel1 tm1 of
   516                 Some tm1' => (case rew1 skel2 tm2 of
   517                     Some tm2' => Some (tm1' $ tm2')
   518                   | None => Some (tm1' $ tm2))
   519               | None => (case rew1 skel2 tm2 of
   520                     Some tm2' => Some (tm1 $ tm2')
   521                   | None => None)
   522             end)
   523       | rew2 skel (Abs (x, T, tm)) =
   524           let
   525             val (abs, tm') = variant_absfree (x, T, tm);
   526             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   527           in case rew1 skel' tm' of
   528               Some tm'' => Some (abs tm'')
   529             | None => None
   530           end
   531       | rew2 _ _ = None
   532 
   533   in if_none (rew1 skel0 tm) tm end;
   534 
   535 end;
   536 
   537 val trace_unify_fail = Pattern.trace_unify_fail;