src/Pure/tctical.ML
author wenzelm
Mon Jun 21 16:41:06 2004 +0200 (2004-06-21)
changeset 14990 582b655da757
parent 13664 cfe1dc32c2e5
child 15006 107e4dfd3b96
permissions -rw-r--r--
pretty_abbr;
     1 (*  Title:      tctical
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Tacticals
     7 *)
     8 
     9 infix 1 THEN THEN' THEN_ALL_NEW;
    10 infix 0 ORELSE APPEND INTLEAVE ORELSE' APPEND' INTLEAVE';
    11 infix 0 THEN_ELSE;
    12 
    13 
    14 signature TACTICAL =
    15 sig
    16   type tactic  (* = thm -> thm Seq.seq*)
    17   val all_tac           : tactic
    18   val ALLGOALS          : (int -> tactic) -> tactic
    19   val APPEND            : tactic * tactic -> tactic
    20   val APPEND'           : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    21   val CHANGED           : tactic -> tactic
    22   val CHANGED_PROP      : tactic -> tactic
    23   val CHANGED_GOAL      : (int -> tactic) -> int -> tactic
    24   val COND              : (thm -> bool) -> tactic -> tactic -> tactic
    25   val DETERM            : tactic -> tactic
    26   val EVERY             : tactic list -> tactic
    27   val EVERY'            : ('a -> tactic) list -> 'a -> tactic
    28   val EVERY1            : (int -> tactic) list -> tactic
    29   val FILTER            : (thm -> bool) -> tactic -> tactic
    30   val FIRST             : tactic list -> tactic
    31   val FIRST'            : ('a -> tactic) list -> 'a -> tactic
    32   val FIRST1            : (int -> tactic) list -> tactic
    33   val FIRSTGOAL         : (int -> tactic) -> tactic
    34   val INTLEAVE          : tactic * tactic -> tactic
    35   val INTLEAVE'         : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    36   val METAHYPS          : (thm list -> tactic) -> int -> tactic
    37   val no_tac            : tactic
    38   val ORELSE            : tactic * tactic -> tactic
    39   val ORELSE'           : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    40   val pause_tac         : tactic
    41   val print_tac         : string -> tactic
    42   val RANGE             : (int -> tactic) list -> int -> tactic
    43   val REPEAT            : tactic -> tactic
    44   val REPEAT1           : tactic -> tactic
    45   val REPEAT_FIRST      : (int -> tactic) -> tactic
    46   val REPEAT_SOME       : (int -> tactic) -> tactic
    47   val REPEAT_DETERM_N   : int -> tactic -> tactic
    48   val REPEAT_DETERM     : tactic -> tactic
    49   val REPEAT_DETERM1    : tactic -> tactic
    50   val REPEAT_DETERM_FIRST: (int -> tactic) -> tactic
    51   val REPEAT_DETERM_SOME: (int -> tactic) -> tactic
    52   val DETERM_UNTIL      : (thm -> bool) -> tactic -> tactic
    53   val SELECT_GOAL       : tactic -> int -> tactic
    54   val SOMEGOAL          : (int -> tactic) -> tactic
    55   val strip_context     : term -> (string * typ) list * term list * term
    56   val SUBGOAL           : ((term*int) -> tactic) -> int -> tactic
    57   val suppress_tracing  : bool ref
    58   val THEN              : tactic * tactic -> tactic
    59   val THEN'             : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    60   val THEN_ALL_NEW      : (int -> tactic) * (int -> tactic) -> int -> tactic
    61   val REPEAT_ALL_NEW    : (int -> tactic) -> int -> tactic
    62   val THEN_ELSE         : tactic * (tactic*tactic) -> tactic
    63   val traced_tac        : (thm -> (thm * thm Seq.seq) option) -> tactic
    64   val tracify           : bool ref -> tactic -> tactic
    65   val trace_REPEAT      : bool ref
    66   val TRY               : tactic -> tactic
    67   val TRYALL            : (int -> tactic) -> tactic
    68 end;
    69 
    70 
    71 structure Tactical : TACTICAL =
    72 struct
    73 
    74 (**** Tactics ****)
    75 
    76 (*A tactic maps a proof tree to a sequence of proof trees:
    77     if length of sequence = 0 then the tactic does not apply;
    78     if length > 1 then backtracking on the alternatives can occur.*)
    79 
    80 type tactic = thm -> thm Seq.seq;
    81 
    82 
    83 (*** LCF-style tacticals ***)
    84 
    85 (*the tactical THEN performs one tactic followed by another*)
    86 fun (tac1 THEN tac2) st = Seq.flat (Seq.map tac2 (tac1 st));
    87 
    88 
    89 (*The tactical ORELSE uses the first tactic that returns a nonempty sequence.
    90   Like in LCF, ORELSE commits to either tac1 or tac2 immediately.
    91   Does not backtrack to tac2 if tac1 was initially chosen. *)
    92 fun (tac1 ORELSE tac2) st =
    93     case Seq.pull(tac1 st) of
    94         None       => tac2 st
    95       | sequencecell => Seq.make(fn()=> sequencecell);
    96 
    97 
    98 (*The tactical APPEND combines the results of two tactics.
    99   Like ORELSE, but allows backtracking on both tac1 and tac2.
   100   The tactic tac2 is not applied until needed.*)
   101 fun (tac1 APPEND tac2) st =
   102   Seq.append(tac1 st,
   103                   Seq.make(fn()=> Seq.pull (tac2 st)));
   104 
   105 (*Like APPEND, but interleaves results of tac1 and tac2.*)
   106 fun (tac1 INTLEAVE tac2) st =
   107     Seq.interleave(tac1 st,
   108                         Seq.make(fn()=> Seq.pull (tac2 st)));
   109 
   110 (*Conditional tactic.
   111         tac1 ORELSE tac2 = tac1 THEN_ELSE (all_tac, tac2)
   112         tac1 THEN tac2   = tac1 THEN_ELSE (tac2, no_tac)
   113 *)
   114 fun (tac THEN_ELSE (tac1, tac2)) st =
   115     case Seq.pull(tac st) of
   116         None    => tac2 st              (*failed; try tactic 2*)
   117       | seqcell => Seq.flat       (*succeeded; use tactic 1*)
   118                     (Seq.map tac1 (Seq.make(fn()=> seqcell)));
   119 
   120 
   121 (*Versions for combining tactic-valued functions, as in
   122      SOMEGOAL (resolve_tac rls THEN' assume_tac) *)
   123 fun (tac1 THEN' tac2) x = tac1 x THEN tac2 x;
   124 fun (tac1 ORELSE' tac2) x = tac1 x ORELSE tac2 x;
   125 fun (tac1 APPEND' tac2) x = tac1 x APPEND tac2 x;
   126 fun (tac1 INTLEAVE' tac2) x = tac1 x INTLEAVE tac2 x;
   127 
   128 (*passes all proofs through unchanged;  identity of THEN*)
   129 fun all_tac st = Seq.single st;
   130 
   131 (*passes no proofs through;  identity of ORELSE and APPEND*)
   132 fun no_tac st  = Seq.empty;
   133 
   134 
   135 (*Make a tactic deterministic by chopping the tail of the proof sequence*)
   136 fun DETERM tac = Seq.DETERM tac;
   137 
   138 (*Conditional tactical: testfun controls which tactic to use next.
   139   Beware: due to eager evaluation, both thentac and elsetac are evaluated.*)
   140 fun COND testfun thenf elsef = (fn prf =>
   141     if testfun prf then  thenf prf   else  elsef prf);
   142 
   143 (*Do the tactic or else do nothing*)
   144 fun TRY tac = tac ORELSE all_tac;
   145 
   146 (*** List-oriented tactics ***)
   147 
   148 local
   149   (*This version of EVERY avoids backtracking over repeated states*)
   150 
   151   fun EVY (trail, []) st =
   152         Seq.make (fn()=> Some(st,
   153                         Seq.make (fn()=> Seq.pull (evyBack trail))))
   154     | EVY (trail, tac::tacs) st =
   155           case Seq.pull(tac st) of
   156               None    => evyBack trail              (*failed: backtrack*)
   157             | Some(st',q) => EVY ((st',q,tacs)::trail, tacs) st'
   158   and evyBack [] = Seq.empty (*no alternatives*)
   159     | evyBack ((st',q,tacs)::trail) =
   160           case Seq.pull q of
   161               None        => evyBack trail
   162             | Some(st,q') => if eq_thm (st',st)
   163                              then evyBack ((st',q',tacs)::trail)
   164                              else EVY ((st,q',tacs)::trail, tacs) st
   165 in
   166 
   167 (* EVERY [tac1,...,tacn]   equals    tac1 THEN ... THEN tacn   *)
   168 fun EVERY tacs = EVY ([], tacs);
   169 end;
   170 
   171 
   172 (* EVERY' [tac1,...,tacn] i  equals    tac1 i THEN ... THEN tacn i   *)
   173 fun EVERY' tacs i = EVERY (map (fn f => f i) tacs);
   174 
   175 (*Apply every tactic to 1*)
   176 fun EVERY1 tacs = EVERY' tacs 1;
   177 
   178 (* FIRST [tac1,...,tacn]   equals    tac1 ORELSE ... ORELSE tacn   *)
   179 fun FIRST tacs = foldr (op ORELSE) (tacs, no_tac);
   180 
   181 (* FIRST' [tac1,...,tacn] i  equals    tac1 i ORELSE ... ORELSE tacn i   *)
   182 fun FIRST' tacs = foldr (op ORELSE') (tacs, K no_tac);
   183 
   184 (*Apply first tactic to 1*)
   185 fun FIRST1 tacs = FIRST' tacs 1;
   186 
   187 (*Apply tactics on consecutive subgoals*)
   188 fun RANGE [] _ = all_tac
   189   | RANGE (tac :: tacs) i = RANGE tacs (i + 1) THEN tac i;
   190 
   191 
   192 (*** Tracing tactics ***)
   193 
   194 (*Print the current proof state and pass it on.*)
   195 fun print_tac msg =
   196     (fn st =>
   197      (tracing msg;
   198       Display.print_goals (! Display.goals_limit) st; Seq.single st));
   199 
   200 (*Pause until a line is typed -- if non-empty then fail. *)
   201 fun pause_tac st =
   202   (tracing "** Press RETURN to continue:";
   203    if TextIO.inputLine TextIO.stdIn = "\n" then Seq.single st
   204    else (tracing "Goodbye";  Seq.empty));
   205 
   206 exception TRACE_EXIT of thm
   207 and TRACE_QUIT;
   208 
   209 (*Tracing flags*)
   210 val trace_REPEAT= ref false
   211 and suppress_tracing = ref false;
   212 
   213 (*Handle all tracing commands for current state and tactic *)
   214 fun exec_trace_command flag (tac, st) =
   215    case TextIO.inputLine(TextIO.stdIn) of
   216        "\n" => tac st
   217      | "f\n" => Seq.empty
   218      | "o\n" => (flag:=false;  tac st)
   219      | "s\n" => (suppress_tracing:=true;  tac st)
   220      | "x\n" => (tracing "Exiting now";  raise (TRACE_EXIT st))
   221      | "quit\n" => raise TRACE_QUIT
   222      | _     => (tracing
   223 "Type RETURN to continue or...\n\
   224 \     f    - to fail here\n\
   225 \     o    - to switch tracing off\n\
   226 \     s    - to suppress tracing until next entry to a tactical\n\
   227 \     x    - to exit at this point\n\
   228 \     quit - to abort this tracing run\n\
   229 \** Well? "     ;  exec_trace_command flag (tac, st));
   230 
   231 
   232 (*Extract from a tactic, a thm->thm seq function that handles tracing*)
   233 fun tracify flag tac st =
   234   if !flag andalso not (!suppress_tracing)
   235            then (Display.print_goals (! Display.goals_limit) st;
   236                  tracing "** Press RETURN to continue:";
   237                  exec_trace_command flag (tac,st))
   238   else tac st;
   239 
   240 (*Create a tactic whose outcome is given by seqf, handling TRACE_EXIT*)
   241 fun traced_tac seqf st =
   242     (suppress_tracing := false;
   243      Seq.make (fn()=> seqf st
   244                          handle TRACE_EXIT st' => Some(st', Seq.empty)));
   245 
   246 
   247 (*Deterministic DO..UNTIL: only retains the first outcome; tail recursive.
   248   Forces repitition until predicate on state is fulfilled.*)
   249 fun DETERM_UNTIL p tac =
   250 let val tac = tracify trace_REPEAT tac
   251     fun drep st = if p st then Some (st, Seq.empty)
   252                           else (case Seq.pull(tac st) of
   253                                   None        => None
   254                                 | Some(st',_) => drep st')
   255 in  traced_tac drep  end;
   256 
   257 (*Deterministic REPEAT: only retains the first outcome;
   258   uses less space than REPEAT; tail recursive.
   259   If non-negative, n bounds the number of repetitions.*)
   260 fun REPEAT_DETERM_N n tac =
   261   let val tac = tracify trace_REPEAT tac
   262       fun drep 0 st = Some(st, Seq.empty)
   263         | drep n st =
   264            (case Seq.pull(tac st) of
   265                 None       => Some(st, Seq.empty)
   266               | Some(st',_) => drep (n-1) st')
   267   in  traced_tac (drep n)  end;
   268 
   269 (*Allows any number of repetitions*)
   270 val REPEAT_DETERM = REPEAT_DETERM_N ~1;
   271 
   272 (*General REPEAT: maintains a stack of alternatives; tail recursive*)
   273 fun REPEAT tac =
   274   let val tac = tracify trace_REPEAT tac
   275       fun rep qs st =
   276         case Seq.pull(tac st) of
   277             None       => Some(st, Seq.make(fn()=> repq qs))
   278           | Some(st',q) => rep (q::qs) st'
   279       and repq [] = None
   280         | repq(q::qs) = case Seq.pull q of
   281             None       => repq qs
   282           | Some(st,q) => rep (q::qs) st
   283   in  traced_tac (rep [])  end;
   284 
   285 (*Repeat 1 or more times*)
   286 fun REPEAT_DETERM1 tac = DETERM tac THEN REPEAT_DETERM tac;
   287 fun REPEAT1 tac = tac THEN REPEAT tac;
   288 
   289 
   290 (** Filtering tacticals **)
   291 
   292 fun FILTER pred tac st = Seq.filter pred (tac st);
   293 
   294 (*Accept only next states that change the theorem somehow*)
   295 fun CHANGED tac st =
   296   let fun diff st' = not (Thm.eq_thm (st, st'));
   297   in Seq.filter diff (tac st) end;
   298 
   299 (*Accept only next states that change the theorem's prop field
   300   (changes to signature, hyps, etc. don't count)*)
   301 fun CHANGED_PROP tac st =
   302   let fun diff st' = not (Drule.eq_thm_prop (st, st'));
   303   in Seq.filter diff (tac st) end;
   304 
   305 
   306 (*** Tacticals based on subgoal numbering ***)
   307 
   308 (*For n subgoals, performs tac(n) THEN ... THEN tac(1)
   309   Essential to work backwards since tac(i) may add/delete subgoals at i. *)
   310 fun ALLGOALS tac st =
   311   let fun doall 0 = all_tac
   312         | doall n = tac(n) THEN doall(n-1)
   313   in  doall(nprems_of st)st  end;
   314 
   315 (*For n subgoals, performs tac(n) ORELSE ... ORELSE tac(1)  *)
   316 fun SOMEGOAL tac st =
   317   let fun find 0 = no_tac
   318         | find n = tac(n) ORELSE find(n-1)
   319   in  find(nprems_of st)st  end;
   320 
   321 (*For n subgoals, performs tac(1) ORELSE ... ORELSE tac(n).
   322   More appropriate than SOMEGOAL in some cases.*)
   323 fun FIRSTGOAL tac st =
   324   let fun find (i,n) = if i>n then no_tac else  tac(i) ORELSE find (i+1,n)
   325   in  find(1, nprems_of st)st  end;
   326 
   327 (*Repeatedly solve some using tac. *)
   328 fun REPEAT_SOME tac = REPEAT1 (SOMEGOAL (REPEAT1 o tac));
   329 fun REPEAT_DETERM_SOME tac = REPEAT_DETERM1 (SOMEGOAL (REPEAT_DETERM1 o tac));
   330 
   331 (*Repeatedly solve the first possible subgoal using tac. *)
   332 fun REPEAT_FIRST tac = REPEAT1 (FIRSTGOAL (REPEAT1 o tac));
   333 fun REPEAT_DETERM_FIRST tac = REPEAT_DETERM1 (FIRSTGOAL (REPEAT_DETERM1 o tac));
   334 
   335 (*For n subgoals, tries to apply tac to n,...1  *)
   336 fun TRYALL tac = ALLGOALS (TRY o tac);
   337 
   338 
   339 (*Make a tactic for subgoal i, if there is one.  *)
   340 fun SUBGOAL goalfun i st = goalfun (List.nth(prems_of st, i-1),  i) st
   341                              handle Subscript => Seq.empty;
   342 
   343 (*Returns all states that have changed in subgoal i, counted from the LAST
   344   subgoal.  For stac, for example.*)
   345 fun CHANGED_GOAL tac i st =
   346     let val np = nprems_of st
   347         val d = np-i                 (*distance from END*)
   348         val t = List.nth(prems_of st, i-1)
   349         fun diff st' =
   350             nprems_of st' - d <= 0   (*the subgoal no longer exists*)
   351             orelse
   352              not (Pattern.aeconv (t,
   353                                   List.nth(prems_of st',
   354                                            nprems_of st' - d - 1)))
   355     in  Seq.filter diff (tac i st)  end
   356     handle Subscript => Seq.empty  (*no subgoal i*);
   357 
   358 fun (tac1 THEN_ALL_NEW tac2) i st =
   359   st |> (tac1 i THEN (fn st' => Seq.INTERVAL tac2 i (i + nprems_of st' - nprems_of st) st'));
   360 
   361 (*repeatedly dig into any emerging subgoals*)
   362 fun REPEAT_ALL_NEW tac =
   363   tac THEN_ALL_NEW (TRY o (fn i => REPEAT_ALL_NEW tac i));
   364 
   365 
   366 (*** SELECT_GOAL ***)
   367 
   368 (*Tactical for restricting the effect of a tactic to subgoal i.
   369   Works by making a new state from subgoal i, applying tac to it, and
   370   composing the resulting metathm with the original state.*)
   371 
   372 (*Does the work of SELECT_GOAL. *)
   373 fun select tac st i =
   374   let
   375     val thm = Drule.mk_triv_goal (adjust_maxidx (List.nth (cprems_of st, i-1)));
   376     fun restore th = Seq.hd (bicompose false (false, th, nprems_of th) 1
   377       (Thm.incr_indexes (#maxidx (rep_thm th) + 1) Drule.rev_triv_goal));
   378     fun next st' = bicompose false (false, restore st', nprems_of st') i st;
   379   in  Seq.flat (Seq.map next (tac thm))
   380   end;
   381 
   382 fun SELECT_GOAL tac i st =
   383   let val np = nprems_of st
   384   in  if 1<=i andalso i<=np then
   385           (*If only one subgoal, then just apply tactic*)
   386           if np=1 then tac st else select tac st i
   387       else Seq.empty
   388   end;
   389 
   390 
   391 (*Strips assumptions in goal yielding  ( [x1,...,xm], [H1,...,Hn], B )
   392     H1,...,Hn are the hypotheses;  x1...xm are variants of the parameters.
   393   Main difference from strip_assums concerns parameters:
   394     it replaces the bound variables by free variables.  *)
   395 fun strip_context_aux (params, Hs, Const("==>", _) $ H $ B) =
   396         strip_context_aux (params, H::Hs, B)
   397   | strip_context_aux (params, Hs, Const("all",_)$Abs(a,T,t)) =
   398         let val (b,u) = variant_abs(a,T,t)
   399         in  strip_context_aux ((b,T)::params, Hs, u)  end
   400   | strip_context_aux (params, Hs, B) = (rev params, rev Hs, B);
   401 
   402 fun strip_context A = strip_context_aux ([],[],A);
   403 
   404 
   405 (**** METAHYPS -- tactical for using hypotheses as meta-level assumptions
   406        METAHYPS (fn prems => tac prems) i
   407 
   408 converts subgoal i, of the form !!x1...xm. [| A1;...;An] ==> A into a new
   409 proof state A==>A, supplying A1,...,An as meta-level assumptions (in
   410 "prems").  The parameters x1,...,xm become free variables.  If the
   411 resulting proof state is [| B1;...;Bk] ==> C (possibly assuming A1,...,An)
   412 then it is lifted back into the original context, yielding k subgoals.
   413 
   414 Replaces unknowns in the context by Frees having the prefix METAHYP_
   415 New unknowns in [| B1;...;Bk] ==> C are lifted over x1,...,xm.
   416 DOES NOT HANDLE TYPE UNKNOWNS.
   417 ****)
   418 
   419 local
   420 
   421   (*Left-to-right replacements: ctpairs = [...,(vi,ti),...].
   422     Instantiates distinct free variables by terms of same type.*)
   423   fun free_instantiate ctpairs =
   424       forall_elim_list (map snd ctpairs) o forall_intr_list (map fst ctpairs);
   425 
   426   fun free_of s ((a,i), T) =
   427         Free(s ^ (case i of 0 => a | _ => a ^ "_" ^ string_of_int i),
   428              T)
   429 
   430   fun mk_inst (var as Var(v,T))  = (var,  free_of "METAHYP1_" (v,T))
   431 in
   432 
   433 fun metahyps_aux_tac tacf (prem,i) state =
   434   let val {sign,maxidx,...} = rep_thm state
   435       val cterm = cterm_of sign
   436       (*find all vars in the hyps -- should find tvars also!*)
   437       val hyps_vars = foldr add_term_vars (Logic.strip_assums_hyp prem, [])
   438       val insts = map mk_inst hyps_vars
   439       (*replace the hyps_vars by Frees*)
   440       val prem' = subst_atomic insts prem
   441       val (params,hyps,concl) = strip_context prem'
   442       val fparams = map Free params
   443       val cparams = map cterm fparams
   444       and chyps = map cterm hyps
   445       val hypths = map assume chyps
   446       fun swap_ctpair (t,u) = (cterm u, cterm t)
   447       (*Subgoal variables: make Free; lift type over params*)
   448       fun mk_subgoal_inst concl_vars (var as Var(v,T)) =
   449           if var mem concl_vars
   450           then (var, true, free_of "METAHYP2_" (v,T))
   451           else (var, false,
   452                 free_of "METAHYP2_" (v, map #2 params --->T))
   453       (*Instantiate subgoal vars by Free applied to params*)
   454       fun mk_ctpair (t,in_concl,u) =
   455           if in_concl then (cterm t,  cterm u)
   456           else (cterm t,  cterm (list_comb (u,fparams)))
   457       (*Restore Vars with higher type and index*)
   458       fun mk_subgoal_swap_ctpair
   459                 (t as Var((a,i),_), in_concl, u as Free(_,U)) =
   460           if in_concl then (cterm u, cterm t)
   461           else (cterm u, cterm(Var((a, i+maxidx), U)))
   462       (*Embed B in the original context of params and hyps*)
   463       fun embed B = list_all_free (params, Logic.list_implies (hyps, B))
   464       (*Strip the context using elimination rules*)
   465       fun elim Bhyp = implies_elim_list (forall_elim_list cparams Bhyp) hypths
   466       (*A form of lifting that discharges assumptions.*)
   467       fun relift st =
   468         let val prop = #prop(rep_thm st)
   469             val subgoal_vars = (*Vars introduced in the subgoals*)
   470                   foldr add_term_vars (Logic.strip_imp_prems prop, [])
   471             and concl_vars = add_term_vars (Logic.strip_imp_concl prop, [])
   472             val subgoal_insts = map (mk_subgoal_inst concl_vars) subgoal_vars
   473             val st' = Thm.instantiate ([], map mk_ctpair subgoal_insts) st
   474             val emBs = map (cterm o embed) (prems_of st')
   475             val Cth  = implies_elim_list st' (map (elim o assume) emBs)
   476         in  (*restore the unknowns to the hypotheses*)
   477             free_instantiate (map swap_ctpair insts @
   478                               map mk_subgoal_swap_ctpair subgoal_insts)
   479                 (*discharge assumptions from state in same order*)
   480                 (implies_intr_list emBs
   481                   (forall_intr_list cparams (implies_intr_list chyps Cth)))
   482         end
   483       val subprems = map (forall_elim_vars 0) hypths
   484       and st0 = trivial (cterm concl)
   485       (*function to replace the current subgoal*)
   486       fun next st = bicompose false (false, relift st, nprems_of st)
   487                     i state
   488   in  Seq.flat (Seq.map next (tacf subprems st0))
   489   end;
   490 end;
   491 
   492 fun METAHYPS tacf = SUBGOAL (metahyps_aux_tac tacf);
   493 
   494 end;
   495 
   496 open Tactical;