src/HOL/Map.thy
author nipkow
Wed Mar 04 10:47:20 2009 +0100 (2009-03-04)
changeset 30235 58d147683393
parent 29622 2eeb09477ed3
child 30738 0842e906300c
permissions -rw-r--r--
Made Option a separate theory and renamed option_map to Option.map
     1 (*  Title:      HOL/Map.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     4     Copyright   1997-2003 TU Muenchen
     5 
     6 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     7 *)
     8 
     9 header {* Maps *}
    10 
    11 theory Map
    12 imports List
    13 begin
    14 
    15 types ('a,'b) "~=>" = "'a => 'b option"  (infixr 0)
    16 translations (type) "a ~=> b " <= (type) "a => b option"
    17 
    18 syntax (xsymbols)
    19   "~=>" :: "[type, type] => type"  (infixr "\<rightharpoonup>" 0)
    20 
    21 abbreviation
    22   empty :: "'a ~=> 'b" where
    23   "empty == %x. None"
    24 
    25 definition
    26   map_comp :: "('b ~=> 'c) => ('a ~=> 'b) => ('a ~=> 'c)"  (infixl "o'_m" 55) where
    27   "f o_m g = (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    28 
    29 notation (xsymbols)
    30   map_comp  (infixl "\<circ>\<^sub>m" 55)
    31 
    32 definition
    33   map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)"  (infixl "++" 100) where
    34   "m1 ++ m2 = (\<lambda>x. case m2 x of None => m1 x | Some y => Some y)"
    35 
    36 definition
    37   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)"  (infixl "|`"  110) where
    38   "m|`A = (\<lambda>x. if x : A then m x else None)"
    39 
    40 notation (latex output)
    41   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    42 
    43 definition
    44   dom :: "('a ~=> 'b) => 'a set" where
    45   "dom m = {a. m a ~= None}"
    46 
    47 definition
    48   ran :: "('a ~=> 'b) => 'b set" where
    49   "ran m = {b. EX a. m a = Some b}"
    50 
    51 definition
    52   map_le :: "('a ~=> 'b) => ('a ~=> 'b) => bool"  (infix "\<subseteq>\<^sub>m" 50) where
    53   "(m\<^isub>1 \<subseteq>\<^sub>m m\<^isub>2) = (\<forall>a \<in> dom m\<^isub>1. m\<^isub>1 a = m\<^isub>2 a)"
    54 
    55 consts
    56   map_of :: "('a * 'b) list => 'a ~=> 'b"
    57   map_upds :: "('a ~=> 'b) => 'a list => 'b list => ('a ~=> 'b)"
    58 
    59 nonterminals
    60   maplets maplet
    61 
    62 syntax
    63   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    64   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    65   ""         :: "maplet => maplets"             ("_")
    66   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    67   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    68   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    69 
    70 syntax (xsymbols)
    71   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    72   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    73 
    74 translations
    75   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    76   "_MapUpd m (_maplet  x y)"    == "m(x:=Some y)"
    77   "_MapUpd m (_maplets x y)"    == "map_upds m x y"
    78   "_Map ms"                     == "_MapUpd (CONST empty) ms"
    79   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    80   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    81 
    82 primrec
    83   "map_of [] = empty"
    84   "map_of (p#ps) = (map_of ps)(fst p |-> snd p)"
    85 
    86 declare map_of.simps [code del]
    87 
    88 lemma map_of_Cons_code [code]: 
    89   "map_of [] k = None"
    90   "map_of ((l, v) # ps) k = (if l = k then Some v else map_of ps k)"
    91   by simp_all
    92 
    93 defs
    94   map_upds_def [code]: "m(xs [|->] ys) == m ++ map_of (rev(zip xs ys))"
    95 
    96 
    97 subsection {* @{term [source] empty} *}
    98 
    99 lemma empty_upd_none [simp]: "empty(x := None) = empty"
   100 by (rule ext) simp
   101 
   102 
   103 subsection {* @{term [source] map_upd} *}
   104 
   105 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   106 by (rule ext) simp
   107 
   108 lemma map_upd_nonempty [simp]: "t(k|->x) ~= empty"
   109 proof
   110   assume "t(k \<mapsto> x) = empty"
   111   then have "(t(k \<mapsto> x)) k = None" by simp
   112   then show False by simp
   113 qed
   114 
   115 lemma map_upd_eqD1:
   116   assumes "m(a\<mapsto>x) = n(a\<mapsto>y)"
   117   shows "x = y"
   118 proof -
   119   from prems have "(m(a\<mapsto>x)) a = (n(a\<mapsto>y)) a" by simp
   120   then show ?thesis by simp
   121 qed
   122 
   123 lemma map_upd_Some_unfold:
   124   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   125 by auto
   126 
   127 lemma image_map_upd [simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   128 by auto
   129 
   130 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   131 unfolding image_def
   132 apply (simp (no_asm_use) add:full_SetCompr_eq)
   133 apply (rule finite_subset)
   134  prefer 2 apply assumption
   135 apply (auto)
   136 done
   137 
   138 
   139 subsection {* @{term [source] map_of} *}
   140 
   141 lemma map_of_eq_None_iff:
   142   "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   143 by (induct xys) simp_all
   144 
   145 lemma map_of_is_SomeD: "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   146 apply (induct xys)
   147  apply simp
   148 apply (clarsimp split: if_splits)
   149 done
   150 
   151 lemma map_of_eq_Some_iff [simp]:
   152   "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   153 apply (induct xys)
   154  apply simp
   155 apply (auto simp: map_of_eq_None_iff [symmetric])
   156 done
   157 
   158 lemma Some_eq_map_of_iff [simp]:
   159   "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   160 by (auto simp del:map_of_eq_Some_iff simp add: map_of_eq_Some_iff [symmetric])
   161 
   162 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   163     \<Longrightarrow> map_of xys x = Some y"
   164 apply (induct xys)
   165  apply simp
   166 apply force
   167 done
   168 
   169 lemma map_of_zip_is_None [simp]:
   170   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   171 by (induct rule: list_induct2) simp_all
   172 
   173 lemma map_of_zip_is_Some:
   174   assumes "length xs = length ys"
   175   shows "x \<in> set xs \<longleftrightarrow> (\<exists>y. map_of (zip xs ys) x = Some y)"
   176 using assms by (induct rule: list_induct2) simp_all
   177 
   178 lemma map_of_zip_upd:
   179   fixes x :: 'a and xs :: "'a list" and ys zs :: "'b list"
   180   assumes "length ys = length xs"
   181     and "length zs = length xs"
   182     and "x \<notin> set xs"
   183     and "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)"
   184   shows "map_of (zip xs ys) = map_of (zip xs zs)"
   185 proof
   186   fix x' :: 'a
   187   show "map_of (zip xs ys) x' = map_of (zip xs zs) x'"
   188   proof (cases "x = x'")
   189     case True
   190     from assms True map_of_zip_is_None [of xs ys x']
   191       have "map_of (zip xs ys) x' = None" by simp
   192     moreover from assms True map_of_zip_is_None [of xs zs x']
   193       have "map_of (zip xs zs) x' = None" by simp
   194     ultimately show ?thesis by simp
   195   next
   196     case False from assms
   197       have "(map_of (zip xs ys)(x \<mapsto> y)) x' = (map_of (zip xs zs)(x \<mapsto> z)) x'" by auto
   198     with False show ?thesis by simp
   199   qed
   200 qed
   201 
   202 lemma map_of_zip_inject:
   203   assumes "length ys = length xs"
   204     and "length zs = length xs"
   205     and dist: "distinct xs"
   206     and map_of: "map_of (zip xs ys) = map_of (zip xs zs)"
   207   shows "ys = zs"
   208 using assms(1) assms(2)[symmetric] using dist map_of proof (induct ys xs zs rule: list_induct3)
   209   case Nil show ?case by simp
   210 next
   211   case (Cons y ys x xs z zs)
   212   from `map_of (zip (x#xs) (y#ys)) = map_of (zip (x#xs) (z#zs))`
   213     have map_of: "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)" by simp
   214   from Cons have "length ys = length xs" and "length zs = length xs"
   215     and "x \<notin> set xs" by simp_all
   216   then have "map_of (zip xs ys) = map_of (zip xs zs)" using map_of by (rule map_of_zip_upd)
   217   with Cons.hyps `distinct (x # xs)` have "ys = zs" by simp
   218   moreover from map_of have "y = z" by (rule map_upd_eqD1)
   219   ultimately show ?case by simp
   220 qed
   221 
   222 lemma finite_range_map_of: "finite (range (map_of xys))"
   223 apply (induct xys)
   224  apply (simp_all add: image_constant)
   225 apply (rule finite_subset)
   226  prefer 2 apply assumption
   227 apply auto
   228 done
   229 
   230 lemma map_of_SomeD: "map_of xs k = Some y \<Longrightarrow> (k, y) \<in> set xs"
   231 by (induct xs) (simp, atomize (full), auto)
   232 
   233 lemma map_of_mapk_SomeI:
   234   "inj f ==> map_of t k = Some x ==>
   235    map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   236 by (induct t) (auto simp add: inj_eq)
   237 
   238 lemma weak_map_of_SomeI: "(k, x) : set l ==> \<exists>x. map_of l k = Some x"
   239 by (induct l) auto
   240 
   241 lemma map_of_filter_in:
   242   "map_of xs k = Some z \<Longrightarrow> P k z \<Longrightarrow> map_of (filter (split P) xs) k = Some z"
   243 by (induct xs) auto
   244 
   245 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = Option.map f (map_of xs x)"
   246 by (induct xs) auto
   247 
   248 
   249 subsection {* @{const Option.map} related *}
   250 
   251 lemma option_map_o_empty [simp]: "Option.map f o empty = empty"
   252 by (rule ext) simp
   253 
   254 lemma option_map_o_map_upd [simp]:
   255   "Option.map f o m(a|->b) = (Option.map f o m)(a|->f b)"
   256 by (rule ext) simp
   257 
   258 
   259 subsection {* @{term [source] map_comp} related *}
   260 
   261 lemma map_comp_empty [simp]:
   262   "m \<circ>\<^sub>m empty = empty"
   263   "empty \<circ>\<^sub>m m = empty"
   264 by (auto simp add: map_comp_def intro: ext split: option.splits)
   265 
   266 lemma map_comp_simps [simp]:
   267   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   268   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'"
   269 by (auto simp add: map_comp_def)
   270 
   271 lemma map_comp_Some_iff:
   272   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)"
   273 by (auto simp add: map_comp_def split: option.splits)
   274 
   275 lemma map_comp_None_iff:
   276   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) "
   277 by (auto simp add: map_comp_def split: option.splits)
   278 
   279 
   280 subsection {* @{text "++"} *}
   281 
   282 lemma map_add_empty[simp]: "m ++ empty = m"
   283 by(simp add: map_add_def)
   284 
   285 lemma empty_map_add[simp]: "empty ++ m = m"
   286 by (rule ext) (simp add: map_add_def split: option.split)
   287 
   288 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   289 by (rule ext) (simp add: map_add_def split: option.split)
   290 
   291 lemma map_add_Some_iff:
   292   "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   293 by (simp add: map_add_def split: option.split)
   294 
   295 lemma map_add_SomeD [dest!]:
   296   "(m ++ n) k = Some x \<Longrightarrow> n k = Some x \<or> n k = None \<and> m k = Some x"
   297 by (rule map_add_Some_iff [THEN iffD1])
   298 
   299 lemma map_add_find_right [simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   300 by (subst map_add_Some_iff) fast
   301 
   302 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   303 by (simp add: map_add_def split: option.split)
   304 
   305 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   306 by (rule ext) (simp add: map_add_def)
   307 
   308 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   309 by (simp add: map_upds_def)
   310 
   311 lemma map_of_append[simp]: "map_of (xs @ ys) = map_of ys ++ map_of xs"
   312 unfolding map_add_def
   313 apply (induct xs)
   314  apply simp
   315 apply (rule ext)
   316 apply (simp split add: option.split)
   317 done
   318 
   319 lemma finite_range_map_of_map_add:
   320   "finite (range f) ==> finite (range (f ++ map_of l))"
   321 apply (induct l)
   322  apply (auto simp del: fun_upd_apply)
   323 apply (erule finite_range_updI)
   324 done
   325 
   326 lemma inj_on_map_add_dom [iff]:
   327   "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   328 by (fastsimp simp: map_add_def dom_def inj_on_def split: option.splits)
   329 
   330 
   331 subsection {* @{term [source] restrict_map} *}
   332 
   333 lemma restrict_map_to_empty [simp]: "m|`{} = empty"
   334 by (simp add: restrict_map_def)
   335 
   336 lemma restrict_map_empty [simp]: "empty|`D = empty"
   337 by (simp add: restrict_map_def)
   338 
   339 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   340 by (simp add: restrict_map_def)
   341 
   342 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   343 by (simp add: restrict_map_def)
   344 
   345 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   346 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   347 
   348 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   349 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   350 
   351 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   352 by (rule ext) (auto simp: restrict_map_def)
   353 
   354 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   355 by (rule ext) (auto simp: restrict_map_def)
   356 
   357 lemma restrict_fun_upd [simp]:
   358   "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   359 by (simp add: restrict_map_def expand_fun_eq)
   360 
   361 lemma fun_upd_None_restrict [simp]:
   362   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   363 by (simp add: restrict_map_def expand_fun_eq)
   364 
   365 lemma fun_upd_restrict: "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   366 by (simp add: restrict_map_def expand_fun_eq)
   367 
   368 lemma fun_upd_restrict_conv [simp]:
   369   "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   370 by (simp add: restrict_map_def expand_fun_eq)
   371 
   372 
   373 subsection {* @{term [source] map_upds} *}
   374 
   375 lemma map_upds_Nil1 [simp]: "m([] [|->] bs) = m"
   376 by (simp add: map_upds_def)
   377 
   378 lemma map_upds_Nil2 [simp]: "m(as [|->] []) = m"
   379 by (simp add:map_upds_def)
   380 
   381 lemma map_upds_Cons [simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   382 by (simp add:map_upds_def)
   383 
   384 lemma map_upds_append1 [simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   385   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   386 apply(induct xs)
   387  apply (clarsimp simp add: neq_Nil_conv)
   388 apply (case_tac ys)
   389  apply simp
   390 apply simp
   391 done
   392 
   393 lemma map_upds_list_update2_drop [simp]:
   394   "\<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   395     \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   396 apply (induct xs arbitrary: m ys i)
   397  apply simp
   398 apply (case_tac ys)
   399  apply simp
   400 apply (simp split: nat.split)
   401 done
   402 
   403 lemma map_upd_upds_conv_if:
   404   "(f(x|->y))(xs [|->] ys) =
   405    (if x : set(take (length ys) xs) then f(xs [|->] ys)
   406                                     else (f(xs [|->] ys))(x|->y))"
   407 apply (induct xs arbitrary: x y ys f)
   408  apply simp
   409 apply (case_tac ys)
   410  apply (auto split: split_if simp: fun_upd_twist)
   411 done
   412 
   413 lemma map_upds_twist [simp]:
   414   "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   415 using set_take_subset by (fastsimp simp add: map_upd_upds_conv_if)
   416 
   417 lemma map_upds_apply_nontin [simp]:
   418   "x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   419 apply (induct xs arbitrary: ys)
   420  apply simp
   421 apply (case_tac ys)
   422  apply (auto simp: map_upd_upds_conv_if)
   423 done
   424 
   425 lemma fun_upds_append_drop [simp]:
   426   "size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   427 apply (induct xs arbitrary: m ys)
   428  apply simp
   429 apply (case_tac ys)
   430  apply simp_all
   431 done
   432 
   433 lemma fun_upds_append2_drop [simp]:
   434   "size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   435 apply (induct xs arbitrary: m ys)
   436  apply simp
   437 apply (case_tac ys)
   438  apply simp_all
   439 done
   440 
   441 
   442 lemma restrict_map_upds[simp]:
   443   "\<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   444     \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   445 apply (induct xs arbitrary: m ys)
   446  apply simp
   447 apply (case_tac ys)
   448  apply simp
   449 apply (simp add: Diff_insert [symmetric] insert_absorb)
   450 apply (simp add: map_upd_upds_conv_if)
   451 done
   452 
   453 
   454 subsection {* @{term [source] dom} *}
   455 
   456 lemma domI: "m a = Some b ==> a : dom m"
   457 by(simp add:dom_def)
   458 (* declare domI [intro]? *)
   459 
   460 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   461 by (cases "m a") (auto simp add: dom_def)
   462 
   463 lemma domIff [iff, simp del]: "(a : dom m) = (m a ~= None)"
   464 by(simp add:dom_def)
   465 
   466 lemma dom_empty [simp]: "dom empty = {}"
   467 by(simp add:dom_def)
   468 
   469 lemma dom_fun_upd [simp]:
   470   "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   471 by(auto simp add:dom_def)
   472 
   473 lemma dom_map_of: "dom(map_of xys) = {x. \<exists>y. (x,y) : set xys}"
   474 by (induct xys) (auto simp del: fun_upd_apply)
   475 
   476 lemma dom_map_of_conv_image_fst:
   477   "dom(map_of xys) = fst ` (set xys)"
   478 by(force simp: dom_map_of)
   479 
   480 lemma dom_map_of_zip [simp]: "[| length xs = length ys; distinct xs |] ==>
   481   dom(map_of(zip xs ys)) = set xs"
   482 by (induct rule: list_induct2) simp_all
   483 
   484 lemma finite_dom_map_of: "finite (dom (map_of l))"
   485 by (induct l) (auto simp add: dom_def insert_Collect [symmetric])
   486 
   487 lemma dom_map_upds [simp]:
   488   "dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   489 apply (induct xs arbitrary: m ys)
   490  apply simp
   491 apply (case_tac ys)
   492  apply auto
   493 done
   494 
   495 lemma dom_map_add [simp]: "dom(m++n) = dom n Un dom m"
   496 by(auto simp:dom_def)
   497 
   498 lemma dom_override_on [simp]:
   499   "dom(override_on f g A) =
   500     (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   501 by(auto simp: dom_def override_on_def)
   502 
   503 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   504 by (rule ext) (force simp: map_add_def dom_def split: option.split)
   505 
   506 lemma dom_const [simp]:
   507   "dom (\<lambda>x. Some y) = UNIV"
   508   by auto
   509 
   510 lemma dom_if:
   511   "dom (\<lambda>x. if P x then f x else g x) = dom f \<inter> {x. P x} \<union> dom g \<inter> {x. \<not> P x}"
   512   by (auto split: if_splits)
   513 
   514 
   515 (* Due to John Matthews - could be rephrased with dom *)
   516 lemma finite_map_freshness:
   517   "finite (dom (f :: 'a \<rightharpoonup> 'b)) \<Longrightarrow> \<not> finite (UNIV :: 'a set) \<Longrightarrow>
   518    \<exists>x. f x = None"
   519 by(bestsimp dest:ex_new_if_finite)
   520 
   521 lemma dom_minus:
   522   "f x = None \<Longrightarrow> dom f - insert x A = dom f - A"
   523   unfolding dom_def by simp
   524 
   525 lemma insert_dom:
   526   "f x = Some y \<Longrightarrow> insert x (dom f) = dom f"
   527   unfolding dom_def by auto
   528 
   529 
   530 subsection {* @{term [source] ran} *}
   531 
   532 lemma ranI: "m a = Some b ==> b : ran m"
   533 by(auto simp: ran_def)
   534 (* declare ranI [intro]? *)
   535 
   536 lemma ran_empty [simp]: "ran empty = {}"
   537 by(auto simp: ran_def)
   538 
   539 lemma ran_map_upd [simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   540 unfolding ran_def
   541 apply auto
   542 apply (subgoal_tac "aa ~= a")
   543  apply auto
   544 done
   545 
   546 
   547 subsection {* @{text "map_le"} *}
   548 
   549 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   550 by (simp add: map_le_def)
   551 
   552 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   553 by (force simp add: map_le_def)
   554 
   555 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   556 by (fastsimp simp add: map_le_def)
   557 
   558 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   559 by (force simp add: map_le_def)
   560 
   561 lemma map_le_upds [simp]:
   562   "f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   563 apply (induct as arbitrary: f g bs)
   564  apply simp
   565 apply (case_tac bs)
   566  apply auto
   567 done
   568 
   569 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   570 by (fastsimp simp add: map_le_def dom_def)
   571 
   572 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   573 by (simp add: map_le_def)
   574 
   575 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   576 by (auto simp add: map_le_def dom_def)
   577 
   578 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   579 unfolding map_le_def
   580 apply (rule ext)
   581 apply (case_tac "x \<in> dom f", simp)
   582 apply (case_tac "x \<in> dom g", simp, fastsimp)
   583 done
   584 
   585 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   586 by (fastsimp simp add: map_le_def)
   587 
   588 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   589 by(fastsimp simp: map_add_def map_le_def expand_fun_eq split: option.splits)
   590 
   591 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   592 by (fastsimp simp add: map_le_def map_add_def dom_def)
   593 
   594 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h; f \<subseteq>\<^sub>m f++g \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   595 by (clarsimp simp add: map_le_def map_add_def dom_def split: option.splits)
   596 
   597 end