src/HOL/Presburger.thy
author haftmann
Mon May 10 14:18:41 2010 +0200 (2010-05-10)
changeset 36800 59b50c691b75
parent 36799 628fe06cbeff
child 36802 5f9fe7b3295d
permissions -rw-r--r--
tuned theory text; dropped unused lemma
     1 (* Title:      HOL/Presburger.thy
     2    Author:     Amine Chaieb, TU Muenchen
     3 *)
     4 
     5 header {* Decision Procedure for Presburger Arithmetic *}
     6 
     7 theory Presburger
     8 imports Groebner_Basis SetInterval
     9 uses
    10   "Tools/Qelim/qelim.ML"
    11   "Tools/Qelim/cooper_procedure.ML"
    12   ("Tools/Qelim/cooper.ML")
    13   ("Tools/Qelim/presburger.ML")
    14 begin
    15 
    16 subsection{* The @{text "-\<infinity>"} and @{text "+\<infinity>"} Properties *}
    17 
    18 lemma minf:
    19   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x<z. P x = P' x; \<exists>z.\<forall>x<z. Q x = Q' x\<rbrakk> 
    20      \<Longrightarrow> \<exists>z.\<forall>x<z. (P x \<and> Q x) = (P' x \<and> Q' x)"
    21   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x<z. P x = P' x; \<exists>z.\<forall>x<z. Q x = Q' x\<rbrakk> 
    22      \<Longrightarrow> \<exists>z.\<forall>x<z. (P x \<or> Q x) = (P' x \<or> Q' x)"
    23   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x = t) = False"
    24   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x \<noteq> t) = True"
    25   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x < t) = True"
    26   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x \<le> t) = True"
    27   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x > t) = False"
    28   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x \<ge> t) = False"
    29   "\<exists>z.\<forall>(x::'a::{linorder,plus,Rings.dvd})<z. (d dvd x + s) = (d dvd x + s)"
    30   "\<exists>z.\<forall>(x::'a::{linorder,plus,Rings.dvd})<z. (\<not> d dvd x + s) = (\<not> d dvd x + s)"
    31   "\<exists>z.\<forall>x<z. F = F"
    32   by ((erule exE, erule exE,rule_tac x="min z za" in exI,simp)+, (rule_tac x="t" in exI,fastsimp)+) simp_all
    33 
    34 lemma pinf:
    35   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x>z. P x = P' x; \<exists>z.\<forall>x>z. Q x = Q' x\<rbrakk> 
    36      \<Longrightarrow> \<exists>z.\<forall>x>z. (P x \<and> Q x) = (P' x \<and> Q' x)"
    37   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x>z. P x = P' x; \<exists>z.\<forall>x>z. Q x = Q' x\<rbrakk> 
    38      \<Longrightarrow> \<exists>z.\<forall>x>z. (P x \<or> Q x) = (P' x \<or> Q' x)"
    39   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x = t) = False"
    40   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x \<noteq> t) = True"
    41   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x < t) = False"
    42   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x \<le> t) = False"
    43   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x > t) = True"
    44   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x \<ge> t) = True"
    45   "\<exists>z.\<forall>(x::'a::{linorder,plus,Rings.dvd})>z. (d dvd x + s) = (d dvd x + s)"
    46   "\<exists>z.\<forall>(x::'a::{linorder,plus,Rings.dvd})>z. (\<not> d dvd x + s) = (\<not> d dvd x + s)"
    47   "\<exists>z.\<forall>x>z. F = F"
    48   by ((erule exE, erule exE,rule_tac x="max z za" in exI,simp)+,(rule_tac x="t" in exI,fastsimp)+) simp_all
    49 
    50 lemma inf_period:
    51   "\<lbrakk>\<forall>x k. P x = P (x - k*D); \<forall>x k. Q x = Q (x - k*D)\<rbrakk> 
    52     \<Longrightarrow> \<forall>x k. (P x \<and> Q x) = (P (x - k*D) \<and> Q (x - k*D))"
    53   "\<lbrakk>\<forall>x k. P x = P (x - k*D); \<forall>x k. Q x = Q (x - k*D)\<rbrakk> 
    54     \<Longrightarrow> \<forall>x k. (P x \<or> Q x) = (P (x - k*D) \<or> Q (x - k*D))"
    55   "(d::'a::{comm_ring,Rings.dvd}) dvd D \<Longrightarrow> \<forall>x k. (d dvd x + t) = (d dvd (x - k*D) + t)"
    56   "(d::'a::{comm_ring,Rings.dvd}) dvd D \<Longrightarrow> \<forall>x k. (\<not>d dvd x + t) = (\<not>d dvd (x - k*D) + t)"
    57   "\<forall>x k. F = F"
    58 apply (auto elim!: dvdE simp add: algebra_simps)
    59 unfolding mult_assoc [symmetric] left_distrib [symmetric] left_diff_distrib [symmetric]
    60 unfolding dvd_def mult_commute [of d] 
    61 by auto
    62 
    63 subsection{* The A and B sets *}
    64 lemma bset:
    65   "\<lbrakk>\<forall>x.(\<forall>j \<in> {1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> P x \<longrightarrow> P(x - D) ;
    66      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> Q x \<longrightarrow> Q(x - D)\<rbrakk> \<Longrightarrow> 
    67   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j) \<longrightarrow> (P x \<and> Q x) \<longrightarrow> (P(x - D) \<and> Q (x - D))"
    68   "\<lbrakk>\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> P x \<longrightarrow> P(x - D) ;
    69      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> Q x \<longrightarrow> Q(x - D)\<rbrakk> \<Longrightarrow> 
    70   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (P x \<or> Q x) \<longrightarrow> (P(x - D) \<or> Q (x - D))"
    71   "\<lbrakk>D>0; t - 1\<in> B\<rbrakk> \<Longrightarrow> (\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x = t) \<longrightarrow> (x - D = t))"
    72   "\<lbrakk>D>0 ; t \<in> B\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x - D \<noteq> t))"
    73   "D>0 \<Longrightarrow> (\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x < t) \<longrightarrow> (x - D < t))"
    74   "D>0 \<Longrightarrow> (\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x - D \<le> t))"
    75   "\<lbrakk>D>0 ; t \<in> B\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x > t) \<longrightarrow> (x - D > t))"
    76   "\<lbrakk>D>0 ; t - 1 \<in> B\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x - D \<ge> t))"
    77   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x - D) + t))"
    78   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not> d dvd (x - D) + t))"
    79   "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j) \<longrightarrow> F \<longrightarrow> F"
    80 proof (blast, blast)
    81   assume dp: "D > 0" and tB: "t - 1\<in> B"
    82   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x = t) \<longrightarrow> (x - D = t))" 
    83     apply (rule allI, rule impI,erule ballE[where x="1"],erule ballE[where x="t - 1"]) 
    84     apply algebra using dp tB by simp_all
    85 next
    86   assume dp: "D > 0" and tB: "t \<in> B"
    87   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x - D \<noteq> t))" 
    88     apply (rule allI, rule impI,erule ballE[where x="D"],erule ballE[where x="t"])
    89     apply algebra
    90     using dp tB by simp_all
    91 next
    92   assume dp: "D > 0" thus "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x < t) \<longrightarrow> (x - D < t))" by arith
    93 next
    94   assume dp: "D > 0" thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x - D \<le> t)" by arith
    95 next
    96   assume dp: "D > 0" and tB:"t \<in> B"
    97   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j" and g: "x > t" and ng: "\<not> (x - D) > t"
    98     hence "x -t \<le> D" and "1 \<le> x - t" by simp+
    99       hence "\<exists>j \<in> {1 .. D}. x - t = j" by auto
   100       hence "\<exists>j \<in> {1 .. D}. x = t + j" by (simp add: algebra_simps)
   101       with nob tB have "False" by simp}
   102   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x > t) \<longrightarrow> (x - D > t)" by blast
   103 next
   104   assume dp: "D > 0" and tB:"t - 1\<in> B"
   105   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j" and g: "x \<ge> t" and ng: "\<not> (x - D) \<ge> t"
   106     hence "x - (t - 1) \<le> D" and "1 \<le> x - (t - 1)" by simp+
   107       hence "\<exists>j \<in> {1 .. D}. x - (t - 1) = j" by auto
   108       hence "\<exists>j \<in> {1 .. D}. x = (t - 1) + j" by (simp add: algebra_simps)
   109       with nob tB have "False" by simp}
   110   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x - D \<ge> t)" by blast
   111 next
   112   assume d: "d dvd D"
   113   {fix x assume H: "d dvd x + t" with d have "d dvd (x - D) + t" by algebra}
   114   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x - D) + t)" by simp
   115 next
   116   assume d: "d dvd D"
   117   {fix x assume H: "\<not>(d dvd x + t)" with d have "\<not> d dvd (x - D) + t"
   118       by (clarsimp simp add: dvd_def,erule_tac x= "ka + k" in allE,simp add: algebra_simps)}
   119   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not>d dvd (x - D) + t)" by auto
   120 qed blast
   121 
   122 lemma aset:
   123   "\<lbrakk>\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> P x \<longrightarrow> P(x + D) ;
   124      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> Q x \<longrightarrow> Q(x + D)\<rbrakk> \<Longrightarrow> 
   125   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j) \<longrightarrow> (P x \<and> Q x) \<longrightarrow> (P(x + D) \<and> Q (x + D))"
   126   "\<lbrakk>\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> P x \<longrightarrow> P(x + D) ;
   127      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> Q x \<longrightarrow> Q(x + D)\<rbrakk> \<Longrightarrow> 
   128   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (P x \<or> Q x) \<longrightarrow> (P(x + D) \<or> Q (x + D))"
   129   "\<lbrakk>D>0; t + 1\<in> A\<rbrakk> \<Longrightarrow> (\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x = t) \<longrightarrow> (x + D = t))"
   130   "\<lbrakk>D>0 ; t \<in> A\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x + D \<noteq> t))"
   131   "\<lbrakk>D>0; t\<in> A\<rbrakk> \<Longrightarrow>(\<forall>(x::int). (\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x < t) \<longrightarrow> (x + D < t))"
   132   "\<lbrakk>D>0; t + 1 \<in> A\<rbrakk> \<Longrightarrow> (\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x + D \<le> t))"
   133   "D>0 \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x > t) \<longrightarrow> (x + D > t))"
   134   "D>0 \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x + D \<ge> t))"
   135   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x + D) + t))"
   136   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not> d dvd (x + D) + t))"
   137   "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j) \<longrightarrow> F \<longrightarrow> F"
   138 proof (blast, blast)
   139   assume dp: "D > 0" and tA: "t + 1 \<in> A"
   140   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x = t) \<longrightarrow> (x + D = t))" 
   141     apply (rule allI, rule impI,erule ballE[where x="1"],erule ballE[where x="t + 1"])
   142     using dp tA by simp_all
   143 next
   144   assume dp: "D > 0" and tA: "t \<in> A"
   145   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x + D \<noteq> t))" 
   146     apply (rule allI, rule impI,erule ballE[where x="D"],erule ballE[where x="t"])
   147     using dp tA by simp_all
   148 next
   149   assume dp: "D > 0" thus "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x > t) \<longrightarrow> (x + D > t))" by arith
   150 next
   151   assume dp: "D > 0" thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x + D \<ge> t)" by arith
   152 next
   153   assume dp: "D > 0" and tA:"t \<in> A"
   154   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j" and g: "x < t" and ng: "\<not> (x + D) < t"
   155     hence "t - x \<le> D" and "1 \<le> t - x" by simp+
   156       hence "\<exists>j \<in> {1 .. D}. t - x = j" by auto
   157       hence "\<exists>j \<in> {1 .. D}. x = t - j" by (auto simp add: algebra_simps) 
   158       with nob tA have "False" by simp}
   159   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x < t) \<longrightarrow> (x + D < t)" by blast
   160 next
   161   assume dp: "D > 0" and tA:"t + 1\<in> A"
   162   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j" and g: "x \<le> t" and ng: "\<not> (x + D) \<le> t"
   163     hence "(t + 1) - x \<le> D" and "1 \<le> (t + 1) - x" by (simp_all add: algebra_simps)
   164       hence "\<exists>j \<in> {1 .. D}. (t + 1) - x = j" by auto
   165       hence "\<exists>j \<in> {1 .. D}. x = (t + 1) - j" by (auto simp add: algebra_simps)
   166       with nob tA have "False" by simp}
   167   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x + D \<le> t)" by blast
   168 next
   169   assume d: "d dvd D"
   170   {fix x assume H: "d dvd x + t" with d have "d dvd (x + D) + t"
   171       by (clarsimp simp add: dvd_def,rule_tac x= "ka + k" in exI,simp add: algebra_simps)}
   172   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x + D) + t)" by simp
   173 next
   174   assume d: "d dvd D"
   175   {fix x assume H: "\<not>(d dvd x + t)" with d have "\<not>d dvd (x + D) + t"
   176       by (clarsimp simp add: dvd_def,erule_tac x= "ka - k" in allE,simp add: algebra_simps)}
   177   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not>d dvd (x + D) + t)" by auto
   178 qed blast
   179 
   180 subsection{* Cooper's Theorem @{text "-\<infinity>"} and @{text "+\<infinity>"} Version *}
   181 
   182 subsubsection{* First some trivial facts about periodic sets or predicates *}
   183 lemma periodic_finite_ex:
   184   assumes dpos: "(0::int) < d" and modd: "ALL x k. P x = P(x - k*d)"
   185   shows "(EX x. P x) = (EX j : {1..d}. P j)"
   186   (is "?LHS = ?RHS")
   187 proof
   188   assume ?LHS
   189   then obtain x where P: "P x" ..
   190   have "x mod d = x - (x div d)*d" by(simp add:zmod_zdiv_equality mult_ac eq_diff_eq)
   191   hence Pmod: "P x = P(x mod d)" using modd by simp
   192   show ?RHS
   193   proof (cases)
   194     assume "x mod d = 0"
   195     hence "P 0" using P Pmod by simp
   196     moreover have "P 0 = P(0 - (-1)*d)" using modd by blast
   197     ultimately have "P d" by simp
   198     moreover have "d : {1..d}" using dpos by simp
   199     ultimately show ?RHS ..
   200   next
   201     assume not0: "x mod d \<noteq> 0"
   202     have "P(x mod d)" using dpos P Pmod by simp
   203     moreover have "x mod d : {1..d}"
   204     proof -
   205       from dpos have "0 \<le> x mod d" by(rule pos_mod_sign)
   206       moreover from dpos have "x mod d < d" by(rule pos_mod_bound)
   207       ultimately show ?thesis using not0 by simp
   208     qed
   209     ultimately show ?RHS ..
   210   qed
   211 qed auto
   212 
   213 subsubsection{* The @{text "-\<infinity>"} Version*}
   214 
   215 lemma decr_lemma: "0 < (d::int) \<Longrightarrow> x - (abs(x-z)+1) * d < z"
   216 by(induct rule: int_gr_induct,simp_all add:int_distrib)
   217 
   218 lemma incr_lemma: "0 < (d::int) \<Longrightarrow> z < x + (abs(x-z)+1) * d"
   219 by(induct rule: int_gr_induct, simp_all add:int_distrib)
   220 
   221 theorem int_induct[case_names base step1 step2]:
   222   assumes 
   223   base: "P(k::int)" and step1: "\<And>i. \<lbrakk>k \<le> i; P i\<rbrakk> \<Longrightarrow> P(i+1)" and
   224   step2: "\<And>i. \<lbrakk>k \<ge> i; P i\<rbrakk> \<Longrightarrow> P(i - 1)"
   225   shows "P i"
   226 proof -
   227   have "i \<le> k \<or> i\<ge> k" by arith
   228   thus ?thesis using prems int_ge_induct[where P="P" and k="k" and i="i"] int_le_induct[where P="P" and k="k" and i="i"] by blast
   229 qed
   230 
   231 lemma decr_mult_lemma:
   232   assumes dpos: "(0::int) < d" and minus: "\<forall>x. P x \<longrightarrow> P(x - d)" and knneg: "0 <= k"
   233   shows "ALL x. P x \<longrightarrow> P(x - k*d)"
   234 using knneg
   235 proof (induct rule:int_ge_induct)
   236   case base thus ?case by simp
   237 next
   238   case (step i)
   239   {fix x
   240     have "P x \<longrightarrow> P (x - i * d)" using step.hyps by blast
   241     also have "\<dots> \<longrightarrow> P(x - (i + 1) * d)" using minus[THEN spec, of "x - i * d"]
   242       by (simp add: algebra_simps)
   243     ultimately have "P x \<longrightarrow> P(x - (i + 1) * d)" by blast}
   244   thus ?case ..
   245 qed
   246 
   247 lemma  minusinfinity:
   248   assumes dpos: "0 < d" and
   249     P1eqP1: "ALL x k. P1 x = P1(x - k*d)" and ePeqP1: "EX z::int. ALL x. x < z \<longrightarrow> (P x = P1 x)"
   250   shows "(EX x. P1 x) \<longrightarrow> (EX x. P x)"
   251 proof
   252   assume eP1: "EX x. P1 x"
   253   then obtain x where P1: "P1 x" ..
   254   from ePeqP1 obtain z where P1eqP: "ALL x. x < z \<longrightarrow> (P x = P1 x)" ..
   255   let ?w = "x - (abs(x-z)+1) * d"
   256   from dpos have w: "?w < z" by(rule decr_lemma)
   257   have "P1 x = P1 ?w" using P1eqP1 by blast
   258   also have "\<dots> = P(?w)" using w P1eqP by blast
   259   finally have "P ?w" using P1 by blast
   260   thus "EX x. P x" ..
   261 qed
   262 
   263 lemma cpmi: 
   264   assumes dp: "0 < D" and p1:"\<exists>z. \<forall> x< z. P x = P' x"
   265   and nb:"\<forall>x.(\<forall> j\<in> {1..D}. \<forall>(b::int) \<in> B. x \<noteq> b+j) --> P (x) --> P (x - D)"
   266   and pd: "\<forall> x k. P' x = P' (x-k*D)"
   267   shows "(\<exists>x. P x) = ((\<exists> j\<in> {1..D} . P' j) | (\<exists> j \<in> {1..D}.\<exists> b\<in> B. P (b+j)))" 
   268          (is "?L = (?R1 \<or> ?R2)")
   269 proof-
   270  {assume "?R2" hence "?L"  by blast}
   271  moreover
   272  {assume H:"?R1" hence "?L" using minusinfinity[OF dp pd p1] periodic_finite_ex[OF dp pd] by simp}
   273  moreover 
   274  { fix x
   275    assume P: "P x" and H: "\<not> ?R2"
   276    {fix y assume "\<not> (\<exists>j\<in>{1..D}. \<exists>b\<in>B. P (b + j))" and P: "P y"
   277      hence "~(EX (j::int) : {1..D}. EX (b::int) : B. y = b+j)" by auto
   278      with nb P  have "P (y - D)" by auto }
   279    hence "ALL x.~(EX (j::int) : {1..D}. EX (b::int) : B. P(b+j)) --> P (x) --> P (x - D)" by blast
   280    with H P have th: " \<forall>x. P x \<longrightarrow> P (x - D)" by auto
   281    from p1 obtain z where z: "ALL x. x < z --> (P x = P' x)" by blast
   282    let ?y = "x - (\<bar>x - z\<bar> + 1)*D"
   283    have zp: "0 <= (\<bar>x - z\<bar> + 1)" by arith
   284    from dp have yz: "?y < z" using decr_lemma[OF dp] by simp   
   285    from z[rule_format, OF yz] decr_mult_lemma[OF dp th zp, rule_format, OF P] have th2: " P' ?y" by auto
   286    with periodic_finite_ex[OF dp pd]
   287    have "?R1" by blast}
   288  ultimately show ?thesis by blast
   289 qed
   290 
   291 subsubsection {* The @{text "+\<infinity>"} Version*}
   292 
   293 lemma  plusinfinity:
   294   assumes dpos: "(0::int) < d" and
   295     P1eqP1: "\<forall>x k. P' x = P'(x - k*d)" and ePeqP1: "\<exists> z. \<forall> x>z. P x = P' x"
   296   shows "(\<exists> x. P' x) \<longrightarrow> (\<exists> x. P x)"
   297 proof
   298   assume eP1: "EX x. P' x"
   299   then obtain x where P1: "P' x" ..
   300   from ePeqP1 obtain z where P1eqP: "\<forall>x>z. P x = P' x" ..
   301   let ?w' = "x + (abs(x-z)+1) * d"
   302   let ?w = "x - (-(abs(x-z) + 1))*d"
   303   have ww'[simp]: "?w = ?w'" by (simp add: algebra_simps)
   304   from dpos have w: "?w > z" by(simp only: ww' incr_lemma)
   305   hence "P' x = P' ?w" using P1eqP1 by blast
   306   also have "\<dots> = P(?w)" using w P1eqP by blast
   307   finally have "P ?w" using P1 by blast
   308   thus "EX x. P x" ..
   309 qed
   310 
   311 lemma incr_mult_lemma:
   312   assumes dpos: "(0::int) < d" and plus: "ALL x::int. P x \<longrightarrow> P(x + d)" and knneg: "0 <= k"
   313   shows "ALL x. P x \<longrightarrow> P(x + k*d)"
   314 using knneg
   315 proof (induct rule:int_ge_induct)
   316   case base thus ?case by simp
   317 next
   318   case (step i)
   319   {fix x
   320     have "P x \<longrightarrow> P (x + i * d)" using step.hyps by blast
   321     also have "\<dots> \<longrightarrow> P(x + (i + 1) * d)" using plus[THEN spec, of "x + i * d"]
   322       by (simp add:int_distrib zadd_ac)
   323     ultimately have "P x \<longrightarrow> P(x + (i + 1) * d)" by blast}
   324   thus ?case ..
   325 qed
   326 
   327 lemma cppi: 
   328   assumes dp: "0 < D" and p1:"\<exists>z. \<forall> x> z. P x = P' x"
   329   and nb:"\<forall>x.(\<forall> j\<in> {1..D}. \<forall>(b::int) \<in> A. x \<noteq> b - j) --> P (x) --> P (x + D)"
   330   and pd: "\<forall> x k. P' x= P' (x-k*D)"
   331   shows "(\<exists>x. P x) = ((\<exists> j\<in> {1..D} . P' j) | (\<exists> j \<in> {1..D}.\<exists> b\<in> A. P (b - j)))" (is "?L = (?R1 \<or> ?R2)")
   332 proof-
   333  {assume "?R2" hence "?L"  by blast}
   334  moreover
   335  {assume H:"?R1" hence "?L" using plusinfinity[OF dp pd p1] periodic_finite_ex[OF dp pd] by simp}
   336  moreover 
   337  { fix x
   338    assume P: "P x" and H: "\<not> ?R2"
   339    {fix y assume "\<not> (\<exists>j\<in>{1..D}. \<exists>b\<in>A. P (b - j))" and P: "P y"
   340      hence "~(EX (j::int) : {1..D}. EX (b::int) : A. y = b - j)" by auto
   341      with nb P  have "P (y + D)" by auto }
   342    hence "ALL x.~(EX (j::int) : {1..D}. EX (b::int) : A. P(b-j)) --> P (x) --> P (x + D)" by blast
   343    with H P have th: " \<forall>x. P x \<longrightarrow> P (x + D)" by auto
   344    from p1 obtain z where z: "ALL x. x > z --> (P x = P' x)" by blast
   345    let ?y = "x + (\<bar>x - z\<bar> + 1)*D"
   346    have zp: "0 <= (\<bar>x - z\<bar> + 1)" by arith
   347    from dp have yz: "?y > z" using incr_lemma[OF dp] by simp
   348    from z[rule_format, OF yz] incr_mult_lemma[OF dp th zp, rule_format, OF P] have th2: " P' ?y" by auto
   349    with periodic_finite_ex[OF dp pd]
   350    have "?R1" by blast}
   351  ultimately show ?thesis by blast
   352 qed
   353 
   354 lemma simp_from_to: "{i..j::int} = (if j < i then {} else insert i {i+1..j})"
   355 apply(simp add:atLeastAtMost_def atLeast_def atMost_def)
   356 apply(fastsimp)
   357 done
   358 
   359 theorem unity_coeff_ex: "(\<exists>(x::'a::{semiring_0,Rings.dvd}). P (l * x)) \<equiv> (\<exists>x. l dvd (x + 0) \<and> P x)"
   360   apply (rule eq_reflection [symmetric])
   361   apply (rule iffI)
   362   defer
   363   apply (erule exE)
   364   apply (rule_tac x = "l * x" in exI)
   365   apply (simp add: dvd_def)
   366   apply (rule_tac x = x in exI, simp)
   367   apply (erule exE)
   368   apply (erule conjE)
   369   apply simp
   370   apply (erule dvdE)
   371   apply (rule_tac x = k in exI)
   372   apply simp
   373   done
   374 
   375 lemma zdvd_mono: assumes not0: "(k::int) \<noteq> 0"
   376 shows "((m::int) dvd t) \<equiv> (k*m dvd k*t)" 
   377   using not0 by (simp add: dvd_def)
   378 
   379 lemma uminus_dvd_conv: "(d dvd (t::int)) \<equiv> (-d dvd t)" "(d dvd (t::int)) \<equiv> (d dvd -t)"
   380   by simp_all
   381 
   382 text {* \bigskip Theorems for transforming predicates on nat to predicates on @{text int}*}
   383 
   384 lemma zdiff_int_split: "P (int (x - y)) =
   385   ((y \<le> x \<longrightarrow> P (int x - int y)) \<and> (x < y \<longrightarrow> P 0))"
   386   by (cases "y \<le> x") (simp_all add: zdiff_int)
   387 
   388 lemma number_of1: "(0::int) <= number_of n \<Longrightarrow> (0::int) <= number_of (Int.Bit0 n) \<and> (0::int) <= number_of (Int.Bit1 n)"
   389 by simp
   390 
   391 lemma number_of2: "(0::int) <= Numeral0" by simp
   392 
   393 text {*
   394   \medskip Specific instances of congruence rules, to prevent
   395   simplifier from looping. *}
   396 
   397 theorem imp_le_cong: "(0 <= x \<Longrightarrow> P = P') \<Longrightarrow> (0 <= (x::int) \<longrightarrow> P) = (0 <= x \<longrightarrow> P')" by simp
   398 
   399 theorem conj_le_cong: "(0 <= x \<Longrightarrow> P = P') \<Longrightarrow> (0 <= (x::int) \<and> P) = (0 <= x \<and> P')" 
   400   by (simp cong: conj_cong)
   401 
   402 use "Tools/Qelim/cooper.ML"
   403 
   404 setup Cooper.setup
   405 oracle linzqe_oracle = Cooper.cooper_oracle
   406 
   407 use "Tools/Qelim/presburger.ML"
   408 
   409 setup {* Arith_Data.add_tactic "Presburger arithmetic" (K (Presburger.cooper_tac true [] [])) *}
   410 
   411 method_setup presburger = {*
   412 let
   413  fun keyword k = Scan.lift (Args.$$$ k -- Args.colon) >> K ()
   414  fun simple_keyword k = Scan.lift (Args.$$$ k) >> K ()
   415  val addN = "add"
   416  val delN = "del"
   417  val elimN = "elim"
   418  val any_keyword = keyword addN || keyword delN || simple_keyword elimN
   419  val thms = Scan.repeat (Scan.unless any_keyword Attrib.multi_thm) >> flat;
   420 in
   421   Scan.optional (simple_keyword elimN >> K false) true --
   422   Scan.optional (keyword addN |-- thms) [] --
   423   Scan.optional (keyword delN |-- thms) [] >>
   424   (fn ((elim, add_ths), del_ths) => fn ctxt =>
   425     SIMPLE_METHOD' (Presburger.cooper_tac elim add_ths del_ths ctxt))
   426 end
   427 *} "Cooper's algorithm for Presburger arithmetic"
   428 
   429 declare dvd_eq_mod_eq_0[symmetric, presburger]
   430 declare mod_1[presburger] 
   431 declare mod_0[presburger]
   432 declare mod_by_1[presburger]
   433 declare zmod_zero[presburger]
   434 declare zmod_self[presburger]
   435 declare mod_self[presburger]
   436 declare mod_by_0[presburger]
   437 declare mod_div_trivial[presburger]
   438 declare div_mod_equality2[presburger]
   439 declare div_mod_equality[presburger]
   440 declare mod_div_equality2[presburger]
   441 declare mod_div_equality[presburger]
   442 declare mod_mult_self1[presburger]
   443 declare mod_mult_self2[presburger]
   444 declare zdiv_zmod_equality2[presburger]
   445 declare zdiv_zmod_equality[presburger]
   446 declare mod2_Suc_Suc[presburger]
   447 lemma [presburger]: "(a::int) div 0 = 0" and [presburger]: "a mod 0 = a"
   448 by simp_all
   449 
   450 lemma [presburger, algebra]: "m mod 2 = (1::nat) \<longleftrightarrow> \<not> 2 dvd m " by presburger
   451 lemma [presburger, algebra]: "m mod 2 = Suc 0 \<longleftrightarrow> \<not> 2 dvd m " by presburger
   452 lemma [presburger, algebra]: "m mod (Suc (Suc 0)) = (1::nat) \<longleftrightarrow> \<not> 2 dvd m " by presburger
   453 lemma [presburger, algebra]: "m mod (Suc (Suc 0)) = Suc 0 \<longleftrightarrow> \<not> 2 dvd m " by presburger
   454 lemma [presburger, algebra]: "m mod 2 = (1::int) \<longleftrightarrow> \<not> 2 dvd m " by presburger
   455 
   456 end