src/HOL/List.thy
author nipkow
Mon May 13 15:27:28 2002 +0200 (2002-05-13)
changeset 13145 59bc43b51aa2
parent 13142 1ebd8ed5a1a0
child 13146 f43153b63361
permissions -rw-r--r--
*** empty log message ***
     1 (*Title:HOL/List.thy
     2 ID: $Id$
     3 Author: Tobias Nipkow
     4 Copyright 1994 TU Muenchen
     5 *)
     6 
     7 header {* The datatype of finite lists *}
     8 
     9 theory List = PreList:
    10 
    11 datatype 'a list =
    12 Nil("[]")
    13 | Cons 'a"'a list"(infixr "#" 65)
    14 
    15 consts
    16 "@" :: "'a list => 'a list => 'a list"(infixr 65)
    17 filter:: "('a => bool) => 'a list => 'a list"
    18 concat:: "'a list list => 'a list"
    19 foldl :: "('b => 'a => 'b) => 'b => 'a list => 'b"
    20 foldr :: "('a => 'b => 'b) => 'a list => 'b => 'b"
    21 hd:: "'a list => 'a"
    22 tl:: "'a list => 'a list"
    23 last:: "'a list => 'a"
    24 butlast :: "'a list => 'a list"
    25 set :: "'a list => 'a set"
    26 list_all:: "('a => bool) => ('a list => bool)"
    27 list_all2 :: "('a => 'b => bool) => 'a list => 'b list => bool"
    28 map :: "('a=>'b) => ('a list => 'b list)"
    29 mem :: "'a => 'a list => bool"(infixl 55)
    30 nth :: "'a list => nat => 'a" (infixl "!" 100)
    31 list_update :: "'a list => nat => 'a => 'a list"
    32 take:: "nat => 'a list => 'a list"
    33 drop:: "nat => 'a list => 'a list"
    34 takeWhile :: "('a => bool) => 'a list => 'a list"
    35 dropWhile :: "('a => bool) => 'a list => 'a list"
    36 rev :: "'a list => 'a list"
    37 zip :: "'a list => 'b list => ('a * 'b) list"
    38 upt :: "nat => nat => nat list" ("(1[_../_'(])")
    39 remdups :: "'a list => 'a list"
    40 null:: "'a list => bool"
    41 "distinct":: "'a list => bool"
    42 replicate :: "nat => 'a => 'a list"
    43 
    44 nonterminals
    45 lupdbindslupdbind
    46 
    47 syntax
    48 -- {* list Enumeration *}
    49 "@list" :: "args => 'a list"("[(_)]")
    50 
    51 -- {* Special syntax for filter *}
    52 "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_:_./ _])")
    53 
    54 -- {* list update *}
    55 "_lupdbind":: "['a, 'a] => lupdbind"("(2_ :=/ _)")
    56 "" :: "lupdbind => lupdbinds" ("_")
    57 "_lupdbinds" :: "[lupdbind, lupdbinds] => lupdbinds" ("_,/ _")
    58 "_LUpdate" :: "['a, lupdbinds] => 'a" ("_/[(_)]" [900,0] 900)
    59 
    60 upto:: "nat => nat => nat list" ("(1[_../_])")
    61 
    62 translations
    63 "[x, xs]" == "x#[xs]"
    64 "[x]" == "x#[]"
    65 "[x:xs . P]"== "filter (%x. P) xs"
    66 
    67 "_LUpdate xs (_lupdbinds b bs)"== "_LUpdate (_LUpdate xs b) bs"
    68 "xs[i:=x]" == "list_update xs i x"
    69 
    70 "[i..j]" == "[i..(Suc j)(]"
    71 
    72 
    73 syntax (xsymbols)
    74 "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    75 
    76 
    77 text {*
    78 Function @{text size} is overloaded for all datatypes.Users may
    79 refer to the list version as @{text length}. *}
    80 
    81 syntax length :: "'a list => nat"
    82 translations "length" => "size :: _ list => nat"
    83 
    84 typed_print_translation {*
    85 let
    86 fun size_tr' _ (Type ("fun", (Type ("list", _) :: _))) [t] =
    87 Syntax.const "length" $ t
    88 | size_tr' _ _ _ = raise Match;
    89 in [("size", size_tr')] end
    90 *}
    91 
    92 primrec
    93 "hd(x#xs) = x"
    94 primrec
    95 "tl([]) = []"
    96 "tl(x#xs) = xs"
    97 primrec
    98 "null([]) = True"
    99 "null(x#xs) = False"
   100 primrec
   101 "last(x#xs) = (if xs=[] then x else last xs)"
   102 primrec
   103 "butlast []= []"
   104 "butlast(x#xs) = (if xs=[] then [] else x#butlast xs)"
   105 primrec
   106 "x mem [] = False"
   107 "x mem (y#ys) = (if y=x then True else x mem ys)"
   108 primrec
   109 "set [] = {}"
   110 "set (x#xs) = insert x (set xs)"
   111 primrec
   112 list_all_Nil:"list_all P [] = True"
   113 list_all_Cons: "list_all P (x#xs) = (P(x) \<and> list_all P xs)"
   114 primrec
   115 "map f [] = []"
   116 "map f (x#xs) = f(x)#map f xs"
   117 primrec
   118 append_Nil:"[]@ys = ys"
   119 append_Cons: "(x#xs)@ys = x#(xs@ys)"
   120 primrec
   121 "rev([]) = []"
   122 "rev(x#xs) = rev(xs) @ [x]"
   123 primrec
   124 "filter P [] = []"
   125 "filter P (x#xs) = (if P x then x#filter P xs else filter P xs)"
   126 primrec
   127 foldl_Nil:"foldl f a [] = a"
   128 foldl_Cons: "foldl f a (x#xs) = foldl f (f a x) xs"
   129 primrec
   130 "foldr f [] a = a"
   131 "foldr f (x#xs) a = f x (foldr f xs a)"
   132 primrec
   133 "concat([]) = []"
   134 "concat(x#xs) = x @ concat(xs)"
   135 primrec
   136 drop_Nil:"drop n [] = []"
   137 drop_Cons: "drop n (x#xs) = (case n of 0 => x#xs | Suc(m) => drop m xs)"
   138 -- {* Warning: simpset does not contain this definition *}
   139 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   140 primrec
   141 take_Nil:"take n [] = []"
   142 take_Cons: "take n (x#xs) = (case n of 0 => [] | Suc(m) => x # take m xs)"
   143 -- {* Warning: simpset does not contain this definition *}
   144 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   145 primrec
   146 nth_Cons:"(x#xs)!n = (case n of 0 => x | (Suc k) => xs!k)"
   147 -- {* Warning: simpset does not contain this definition *}
   148 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   149 primrec
   150 "[][i:=v] = []"
   151 "(x#xs)[i:=v] =
   152 (case i of 0 => v # xs
   153 | Suc j => x # xs[j:=v])"
   154 primrec
   155 "takeWhile P [] = []"
   156 "takeWhile P (x#xs) = (if P x then x#takeWhile P xs else [])"
   157 primrec
   158 "dropWhile P [] = []"
   159 "dropWhile P (x#xs) = (if P x then dropWhile P xs else x#xs)"
   160 primrec
   161 "zip xs [] = []"
   162 zip_Cons: "zip xs (y#ys) = (case xs of [] => [] | z#zs => (z,y)#zip zs ys)"
   163 -- {* Warning: simpset does not contain this definition *}
   164 -- {* but separate theorems for @{text "xs = []"} and @{text "xs = z # zs"} *}
   165 primrec
   166 upt_0: "[i..0(] = []"
   167 upt_Suc: "[i..(Suc j)(] = (if i <= j then [i..j(] @ [j] else [])"
   168 primrec
   169 "distinct [] = True"
   170 "distinct (x#xs) = (x ~: set xs \<and> distinct xs)"
   171 primrec
   172 "remdups [] = []"
   173 "remdups (x#xs) = (if x : set xs then remdups xs else x # remdups xs)"
   174 primrec
   175 replicate_0: "replicate0x = []"
   176 replicate_Suc: "replicate (Suc n) x = x # replicate n x"
   177 defs
   178  list_all2_def:
   179  "list_all2 P xs ys == length xs = length ys \<and> (\<forall>(x, y) \<in> set (zip xs ys). P x y)"
   180 
   181 
   182 subsection {* Lexicographic orderings on lists *}
   183 
   184 consts
   185 lexn :: "('a * 'a)set => nat => ('a list * 'a list)set"
   186 primrec
   187 "lexn r 0 = {}"
   188 "lexn r (Suc n) =
   189 (prod_fun (%(x,xs). x#xs) (%(x,xs). x#xs) ` (r <*lex*> lexn r n)) Int
   190 {(xs,ys). length xs = Suc n \<and> length ys = Suc n}"
   191 
   192 constdefs
   193 lex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
   194 "lex r == \<Union>n. lexn r n"
   195 
   196 lexico :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
   197 "lexico r == inv_image (less_than <*lex*> lex r) (%xs. (length xs, xs))"
   198 
   199 sublist :: "'a list => nat set => 'a list"
   200 "sublist xs A == map fst (filter (%p. snd p : A) (zip xs [0..size xs(]))"
   201 
   202 
   203 lemma not_Cons_self [simp]: "xs \<noteq> x # xs"
   204 by (induct xs) auto
   205 
   206 lemmas not_Cons_self2 [simp] = not_Cons_self [symmetric]
   207 
   208 lemma neq_Nil_conv: "(xs \<noteq> []) = (\<exists>y ys. xs = y # ys)"
   209 by (induct xs) auto
   210 
   211 lemma length_induct:
   212 "(!!xs. \<forall>ys. length ys < length xs --> P ys ==> P xs) ==> P xs"
   213 by (rule measure_induct [of length]) rules
   214 
   215 
   216 subsection {* @{text lists}: the list-forming operator over sets *}
   217 
   218 consts lists :: "'a set => 'a list set"
   219 inductive "lists A"
   220 intros
   221 Nil [intro!]: "[]: lists A"
   222 Cons [intro!]: "[| a: A;l: lists A|] ==> a#l : lists A"
   223 
   224 inductive_cases listsE [elim!]: "x#l : lists A"
   225 
   226 lemma lists_mono: "A \<subseteq> B ==> lists A \<subseteq> lists B"
   227 by (unfold lists.defs) (blast intro!: lfp_mono)
   228 
   229 lemma lists_IntI [rule_format]:
   230 "l: lists A ==> l: lists B --> l: lists (A Int B)"
   231 apply (erule lists.induct)
   232 apply blast+
   233 done
   234 
   235 lemma lists_Int_eq [simp]: "lists (A \<inter> B) = lists A \<inter> lists B"
   236 apply (rule mono_Int [THEN equalityI])
   237 apply (simp add: mono_def lists_mono)
   238 apply (blast intro!: lists_IntI)
   239 done
   240 
   241 lemma append_in_lists_conv [iff]:
   242 "(xs @ ys : lists A) = (xs : lists A \<and> ys : lists A)"
   243 by (induct xs) auto
   244 
   245 
   246 subsection {* @{text length} *}
   247 
   248 text {*
   249 Needs to come before @{text "@"} because of theorem @{text
   250 append_eq_append_conv}.
   251 *}
   252 
   253 lemma length_append [simp]: "length (xs @ ys) = length xs + length ys"
   254 by (induct xs) auto
   255 
   256 lemma length_map [simp]: "length (map f xs) = length xs"
   257 by (induct xs) auto
   258 
   259 lemma length_rev [simp]: "length (rev xs) = length xs"
   260 by (induct xs) auto
   261 
   262 lemma length_tl [simp]: "length (tl xs) = length xs - 1"
   263 by (cases xs) auto
   264 
   265 lemma length_0_conv [iff]: "(length xs = 0) = (xs = [])"
   266 by (induct xs) auto
   267 
   268 lemma length_greater_0_conv [iff]: "(0 < length xs) = (xs \<noteq> [])"
   269 by (induct xs) auto
   270 
   271 lemma length_Suc_conv:
   272 "(length xs = Suc n) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   273 by (induct xs) auto
   274 
   275 
   276 subsection {* @{text "@"} -- append *}
   277 
   278 lemma append_assoc [simp]: "(xs @ ys) @ zs = xs @ (ys @ zs)"
   279 by (induct xs) auto
   280 
   281 lemma append_Nil2 [simp]: "xs @ [] = xs"
   282 by (induct xs) auto
   283 
   284 lemma append_is_Nil_conv [iff]: "(xs @ ys = []) = (xs = [] \<and> ys = [])"
   285 by (induct xs) auto
   286 
   287 lemma Nil_is_append_conv [iff]: "([] = xs @ ys) = (xs = [] \<and> ys = [])"
   288 by (induct xs) auto
   289 
   290 lemma append_self_conv [iff]: "(xs @ ys = xs) = (ys = [])"
   291 by (induct xs) auto
   292 
   293 lemma self_append_conv [iff]: "(xs = xs @ ys) = (ys = [])"
   294 by (induct xs) auto
   295 
   296 lemma append_eq_append_conv [rule_format, simp]:
   297  "\<forall>ys. length xs = length ys \<or> length us = length vs
   298  --> (xs@us = ys@vs) = (xs=ys \<and> us=vs)"
   299 apply (induct_tac xs)
   300  apply(rule allI)
   301  apply (case_tac ys)
   302 apply simp
   303  apply force
   304 apply (rule allI)
   305 apply (case_tac ys)
   306  apply force
   307 apply simp
   308 done
   309 
   310 lemma same_append_eq [iff]: "(xs @ ys = xs @ zs) = (ys = zs)"
   311 by simp
   312 
   313 lemma append1_eq_conv [iff]: "(xs @ [x] = ys @ [y]) = (xs = ys \<and> x = y)"
   314 by simp
   315 
   316 lemma append_same_eq [iff]: "(ys @ xs = zs @ xs) = (ys = zs)"
   317 by simp
   318 
   319 lemma append_self_conv2 [iff]: "(xs @ ys = ys) = (xs = [])"
   320 using append_same_eq [of _ _ "[]"] by auto
   321 
   322 lemma self_append_conv2 [iff]: "(ys = xs @ ys) = (xs = [])"
   323 using append_same_eq [of "[]"] by auto
   324 
   325 lemma hd_Cons_tl [simp]: "xs \<noteq> [] ==> hd xs # tl xs = xs"
   326 by (induct xs) auto
   327 
   328 lemma hd_append: "hd (xs @ ys) = (if xs = [] then hd ys else hd xs)"
   329 by (induct xs) auto
   330 
   331 lemma hd_append2 [simp]: "xs \<noteq> [] ==> hd (xs @ ys) = hd xs"
   332 by (simp add: hd_append split: list.split)
   333 
   334 lemma tl_append: "tl (xs @ ys) = (case xs of [] => tl ys | z#zs => zs @ ys)"
   335 by (simp split: list.split)
   336 
   337 lemma tl_append2 [simp]: "xs \<noteq> [] ==> tl (xs @ ys) = tl xs @ ys"
   338 by (simp add: tl_append split: list.split)
   339 
   340 
   341 text {* Trivial rules for solving @{text "@"}-equations automatically. *}
   342 
   343 lemma eq_Nil_appendI: "xs = ys ==> xs = [] @ ys"
   344 by simp
   345 
   346 lemma Cons_eq_appendI:
   347 "[| x # xs1 = ys; xs = xs1 @ zs |] ==> x # xs = ys @ zs"
   348 by (drule sym) simp
   349 
   350 lemma append_eq_appendI:
   351 "[| xs @ xs1 = zs; ys = xs1 @ us |] ==> xs @ ys = zs @ us"
   352 by (drule sym) simp
   353 
   354 
   355 text {*
   356 Simplification procedure for all list equalities.
   357 Currently only tries to rearrange @{text "@"} to see if
   358 - both lists end in a singleton list,
   359 - or both lists end in the same list.
   360 *}
   361 
   362 ML_setup {*
   363 local
   364 
   365 val append_assoc = thm "append_assoc";
   366 val append_Nil = thm "append_Nil";
   367 val append_Cons = thm "append_Cons";
   368 val append1_eq_conv = thm "append1_eq_conv";
   369 val append_same_eq = thm "append_same_eq";
   370 
   371 val list_eq_pattern =
   372 Thm.read_cterm (Theory.sign_of (the_context ())) ("(xs::'a list) = ys",HOLogic.boolT)
   373 
   374 fun last (cons as Const("List.list.Cons",_) $ _ $ xs) =
   375 (case xs of Const("List.list.Nil",_) => cons | _ => last xs)
   376 | last (Const("List.op @",_) $ _ $ ys) = last ys
   377 | last t = t
   378 
   379 fun list1 (Const("List.list.Cons",_) $ _ $ Const("List.list.Nil",_)) = true
   380 | list1 _ = false
   381 
   382 fun butlast ((cons as Const("List.list.Cons",_) $ x) $ xs) =
   383 (case xs of Const("List.list.Nil",_) => xs | _ => cons $ butlast xs)
   384 | butlast ((app as Const("List.op @",_) $ xs) $ ys) = app $ butlast ys
   385 | butlast xs = Const("List.list.Nil",fastype_of xs)
   386 
   387 val rearr_tac =
   388 simp_tac (HOL_basic_ss addsimps [append_assoc,append_Nil,append_Cons])
   389 
   390 fun list_eq sg _ (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   391 let
   392 val lastl = last lhs and lastr = last rhs
   393 fun rearr conv =
   394 let val lhs1 = butlast lhs and rhs1 = butlast rhs
   395 val Type(_,listT::_) = eqT
   396 val appT = [listT,listT] ---> listT
   397 val app = Const("List.op @",appT)
   398 val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   399 val ct = cterm_of sg (HOLogic.mk_Trueprop(HOLogic.mk_eq(F,F2)))
   400 val thm = prove_goalw_cterm [] ct (K [rearr_tac 1])
   401 handle ERROR =>
   402 error("The error(s) above occurred while trying to prove " ^
   403 string_of_cterm ct)
   404 in Some((conv RS (thm RS trans)) RS eq_reflection) end
   405 
   406 in if list1 lastl andalso list1 lastr
   407  then rearr append1_eq_conv
   408  else
   409  if lastl aconv lastr
   410  then rearr append_same_eq
   411  else None
   412 end
   413 in
   414 val list_eq_simproc = mk_simproc "list_eq" [list_eq_pattern] list_eq
   415 end;
   416 
   417 Addsimprocs [list_eq_simproc];
   418 *}
   419 
   420 
   421 subsection {* @{text map} *}
   422 
   423 lemma map_ext: "(!!x. x : set xs --> f x = g x) ==> map f xs = map g xs"
   424 by (induct xs) simp_all
   425 
   426 lemma map_ident [simp]: "map (\<lambda>x. x) = (\<lambda>xs. xs)"
   427 by (rule ext, induct_tac xs) auto
   428 
   429 lemma map_append [simp]: "map f (xs @ ys) = map f xs @ map f ys"
   430 by (induct xs) auto
   431 
   432 lemma map_compose: "map (f o g) xs = map f (map g xs)"
   433 by (induct xs) (auto simp add: o_def)
   434 
   435 lemma rev_map: "rev (map f xs) = map f (rev xs)"
   436 by (induct xs) auto
   437 
   438 lemma map_cong:
   439 "xs = ys ==> (!!x. x : set ys ==> f x = g x) ==> map f xs = map g ys"
   440 -- {* a congruence rule for @{text map} *}
   441 by (clarify, induct ys) auto
   442 
   443 lemma map_is_Nil_conv [iff]: "(map f xs = []) = (xs = [])"
   444 by (cases xs) auto
   445 
   446 lemma Nil_is_map_conv [iff]: "([] = map f xs) = (xs = [])"
   447 by (cases xs) auto
   448 
   449 lemma map_eq_Cons:
   450 "(map f xs = y # ys) = (\<exists>x xs'. xs = x # xs' \<and> f x = y \<and> map f xs' = ys)"
   451 by (cases xs) auto
   452 
   453 lemma map_injective:
   454 "!!xs. map f xs = map f ys ==> (\<forall>x y. f x = f y --> x = y) ==> xs = ys"
   455 by (induct ys) (auto simp add: map_eq_Cons)
   456 
   457 lemma inj_mapI: "inj f ==> inj (map f)"
   458 by (rules dest: map_injective injD intro: injI)
   459 
   460 lemma inj_mapD: "inj (map f) ==> inj f"
   461 apply (unfold inj_on_def)
   462 apply clarify
   463 apply (erule_tac x = "[x]" in ballE)
   464  apply (erule_tac x = "[y]" in ballE)
   465 apply simp
   466  apply blast
   467 apply blast
   468 done
   469 
   470 lemma inj_map: "inj (map f) = inj f"
   471 by (blast dest: inj_mapD intro: inj_mapI)
   472 
   473 
   474 subsection {* @{text rev} *}
   475 
   476 lemma rev_append [simp]: "rev (xs @ ys) = rev ys @ rev xs"
   477 by (induct xs) auto
   478 
   479 lemma rev_rev_ident [simp]: "rev (rev xs) = xs"
   480 by (induct xs) auto
   481 
   482 lemma rev_is_Nil_conv [iff]: "(rev xs = []) = (xs = [])"
   483 by (induct xs) auto
   484 
   485 lemma Nil_is_rev_conv [iff]: "([] = rev xs) = (xs = [])"
   486 by (induct xs) auto
   487 
   488 lemma rev_is_rev_conv [iff]: "!!ys. (rev xs = rev ys) = (xs = ys)"
   489 apply (induct xs)
   490  apply force
   491 apply (case_tac ys)
   492  apply simp
   493 apply force
   494 done
   495 
   496 lemma rev_induct: "[| P []; !!x xs. P xs ==> P (xs @ [x]) |] ==> P xs"
   497 apply(subst rev_rev_ident[symmetric])
   498 apply(rule_tac list = "rev xs" in list.induct, simp_all)
   499 done
   500 
   501 ML {* val rev_induct_tac = induct_thm_tac (thm "rev_induct") *}-- "compatibility"
   502 
   503 lemma rev_exhaust: "(xs = [] ==> P) ==>(!!ys y. xs = ys @ [y] ==> P) ==> P"
   504 by (induct xs rule: rev_induct) auto
   505 
   506 
   507 subsection {* @{text set} *}
   508 
   509 lemma finite_set [iff]: "finite (set xs)"
   510 by (induct xs) auto
   511 
   512 lemma set_append [simp]: "set (xs @ ys) = (set xs \<union> set ys)"
   513 by (induct xs) auto
   514 
   515 lemma set_subset_Cons: "set xs \<subseteq> set (x # xs)"
   516 by auto
   517 
   518 lemma set_empty [iff]: "(set xs = {}) = (xs = [])"
   519 by (induct xs) auto
   520 
   521 lemma set_rev [simp]: "set (rev xs) = set xs"
   522 by (induct xs) auto
   523 
   524 lemma set_map [simp]: "set (map f xs) = f`(set xs)"
   525 by (induct xs) auto
   526 
   527 lemma set_filter [simp]: "set (filter P xs) = {x. x : set xs \<and> P x}"
   528 by (induct xs) auto
   529 
   530 lemma set_upt [simp]: "set[i..j(] = {k. i \<le> k \<and> k < j}"
   531 apply (induct j)
   532  apply simp_all
   533 apply(erule ssubst)
   534 apply auto
   535 apply arith
   536 done
   537 
   538 lemma in_set_conv_decomp: "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs)"
   539 apply (induct xs)
   540  apply simp
   541 apply simp
   542 apply (rule iffI)
   543  apply (blast intro: eq_Nil_appendI Cons_eq_appendI)
   544 apply (erule exE)+
   545 apply (case_tac ys)
   546 apply auto
   547 done
   548 
   549 lemma in_lists_conv_set: "(xs : lists A) = (\<forall>x \<in> set xs. x : A)"
   550 -- {* eliminate @{text lists} in favour of @{text set} *}
   551 by (induct xs) auto
   552 
   553 lemma in_listsD [dest!]: "xs \<in> lists A ==> \<forall>x\<in>set xs. x \<in> A"
   554 by (rule in_lists_conv_set [THEN iffD1])
   555 
   556 lemma in_listsI [intro!]: "\<forall>x\<in>set xs. x \<in> A ==> xs \<in> lists A"
   557 by (rule in_lists_conv_set [THEN iffD2])
   558 
   559 
   560 subsection {* @{text mem} *}
   561 
   562 lemma set_mem_eq: "(x mem xs) = (x : set xs)"
   563 by (induct xs) auto
   564 
   565 
   566 subsection {* @{text list_all} *}
   567 
   568 lemma list_all_conv: "list_all P xs = (\<forall>x \<in> set xs. P x)"
   569 by (induct xs) auto
   570 
   571 lemma list_all_append [simp]:
   572 "list_all P (xs @ ys) = (list_all P xs \<and> list_all P ys)"
   573 by (induct xs) auto
   574 
   575 
   576 subsection {* @{text filter} *}
   577 
   578 lemma filter_append [simp]: "filter P (xs @ ys) = filter P xs @ filter P ys"
   579 by (induct xs) auto
   580 
   581 lemma filter_filter [simp]: "filter P (filter Q xs) = filter (\<lambda>x. Q x \<and> P x) xs"
   582 by (induct xs) auto
   583 
   584 lemma filter_True [simp]: "\<forall>x \<in> set xs. P x ==> filter P xs = xs"
   585 by (induct xs) auto
   586 
   587 lemma filter_False [simp]: "\<forall>x \<in> set xs. \<not> P x ==> filter P xs = []"
   588 by (induct xs) auto
   589 
   590 lemma length_filter [simp]: "length (filter P xs) \<le> length xs"
   591 by (induct xs) (auto simp add: le_SucI)
   592 
   593 lemma filter_is_subset [simp]: "set (filter P xs) \<le> set xs"
   594 by auto
   595 
   596 
   597 subsection {* @{text concat} *}
   598 
   599 lemma concat_append [simp]: "concat (xs @ ys) = concat xs @ concat ys"
   600 by (induct xs) auto
   601 
   602 lemma concat_eq_Nil_conv [iff]: "(concat xss = []) = (\<forall>xs \<in> set xss. xs = [])"
   603 by (induct xss) auto
   604 
   605 lemma Nil_eq_concat_conv [iff]: "([] = concat xss) = (\<forall>xs \<in> set xss. xs = [])"
   606 by (induct xss) auto
   607 
   608 lemma set_concat [simp]: "set (concat xs) = \<Union>(set ` set xs)"
   609 by (induct xs) auto
   610 
   611 lemma map_concat: "map f (concat xs) = concat (map (map f) xs)"
   612 by (induct xs) auto
   613 
   614 lemma filter_concat: "filter p (concat xs) = concat (map (filter p) xs)"
   615 by (induct xs) auto
   616 
   617 lemma rev_concat: "rev (concat xs) = concat (map rev (rev xs))"
   618 by (induct xs) auto
   619 
   620 
   621 subsection {* @{text nth} *}
   622 
   623 lemma nth_Cons_0 [simp]: "(x # xs)!0 = x"
   624 by auto
   625 
   626 lemma nth_Cons_Suc [simp]: "(x # xs)!(Suc n) = xs!n"
   627 by auto
   628 
   629 declare nth.simps [simp del]
   630 
   631 lemma nth_append:
   632 "!!n. (xs @ ys)!n = (if n < length xs then xs!n else ys!(n - length xs))"
   633 apply(induct "xs")
   634  apply simp
   635 apply (case_tac n)
   636  apply auto
   637 done
   638 
   639 lemma nth_map [simp]: "!!n. n < length xs ==> (map f xs)!n = f(xs!n)"
   640 apply(induct xs)
   641  apply simp
   642 apply (case_tac n)
   643  apply auto
   644 done
   645 
   646 lemma set_conv_nth: "set xs = {xs!i | i. i < length xs}"
   647 apply (induct_tac xs)
   648  apply simp
   649 apply simp
   650 apply safe
   651 apply (rule_tac x = 0 in exI)
   652 apply simp
   653  apply (rule_tac x = "Suc i" in exI)
   654  apply simp
   655 apply (case_tac i)
   656  apply simp
   657 apply (rename_tac j)
   658 apply (rule_tac x = j in exI)
   659 apply simp
   660 done
   661 
   662 lemma list_ball_nth: "[| n < length xs; !x : set xs. P x|] ==> P(xs!n)"
   663 by (auto simp add: set_conv_nth)
   664 
   665 lemma nth_mem [simp]: "n < length xs ==> xs!n : set xs"
   666 by (auto simp add: set_conv_nth)
   667 
   668 lemma all_nth_imp_all_set:
   669 "[| !i < length xs. P(xs!i); x : set xs|] ==> P x"
   670 by (auto simp add: set_conv_nth)
   671 
   672 lemma all_set_conv_all_nth:
   673 "(\<forall>x \<in> set xs. P x) = (\<forall>i. i < length xs --> P (xs ! i))"
   674 by (auto simp add: set_conv_nth)
   675 
   676 
   677 subsection {* @{text list_update} *}
   678 
   679 lemma length_list_update [simp]: "!!i. length(xs[i:=x]) = length xs"
   680 by (induct xs) (auto split: nat.split)
   681 
   682 lemma nth_list_update:
   683 "!!i j. i < length xs==> (xs[i:=x])!j = (if i = j then x else xs!j)"
   684 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   685 
   686 lemma nth_list_update_eq [simp]: "i < length xs ==> (xs[i:=x])!i = x"
   687 by (simp add: nth_list_update)
   688 
   689 lemma nth_list_update_neq [simp]: "!!i j. i \<noteq> j ==> xs[i:=x]!j = xs!j"
   690 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   691 
   692 lemma list_update_overwrite [simp]:
   693 "!!i. i < size xs ==> xs[i:=x, i:=y] = xs[i:=y]"
   694 by (induct xs) (auto split: nat.split)
   695 
   696 lemma list_update_same_conv:
   697 "!!i. i < length xs ==> (xs[i := x] = xs) = (xs!i = x)"
   698 by (induct xs) (auto split: nat.split)
   699 
   700 lemma update_zip:
   701 "!!i xy xs. length xs = length ys ==>
   702 (zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])"
   703 by (induct ys) (auto, case_tac xs, auto split: nat.split)
   704 
   705 lemma set_update_subset_insert: "!!i. set(xs[i:=x]) <= insert x (set xs)"
   706 by (induct xs) (auto split: nat.split)
   707 
   708 lemma set_update_subsetI: "[| set xs <= A; x:A |] ==> set(xs[i := x]) <= A"
   709 by (blast dest!: set_update_subset_insert [THEN subsetD])
   710 
   711 
   712 subsection {* @{text last} and @{text butlast} *}
   713 
   714 lemma last_snoc [simp]: "last (xs @ [x]) = x"
   715 by (induct xs) auto
   716 
   717 lemma butlast_snoc [simp]: "butlast (xs @ [x]) = xs"
   718 by (induct xs) auto
   719 
   720 lemma length_butlast [simp]: "length (butlast xs) = length xs - 1"
   721 by (induct xs rule: rev_induct) auto
   722 
   723 lemma butlast_append:
   724 "!!ys. butlast (xs @ ys) = (if ys = [] then butlast xs else xs @ butlast ys)"
   725 by (induct xs) auto
   726 
   727 lemma append_butlast_last_id [simp]:
   728 "xs \<noteq> [] ==> butlast xs @ [last xs] = xs"
   729 by (induct xs) auto
   730 
   731 lemma in_set_butlastD: "x : set (butlast xs) ==> x : set xs"
   732 by (induct xs) (auto split: split_if_asm)
   733 
   734 lemma in_set_butlast_appendI:
   735 "x : set (butlast xs) | x : set (butlast ys) ==> x : set (butlast (xs @ ys))"
   736 by (auto dest: in_set_butlastD simp add: butlast_append)
   737 
   738 
   739 subsection {* @{text take} and @{text drop} *}
   740 
   741 lemma take_0 [simp]: "take 0 xs = []"
   742 by (induct xs) auto
   743 
   744 lemma drop_0 [simp]: "drop 0 xs = xs"
   745 by (induct xs) auto
   746 
   747 lemma take_Suc_Cons [simp]: "take (Suc n) (x # xs) = x # take n xs"
   748 by simp
   749 
   750 lemma drop_Suc_Cons [simp]: "drop (Suc n) (x # xs) = drop n xs"
   751 by simp
   752 
   753 declare take_Cons [simp del] and drop_Cons [simp del]
   754 
   755 lemma length_take [simp]: "!!xs. length (take n xs) = min (length xs) n"
   756 by (induct n) (auto, case_tac xs, auto)
   757 
   758 lemma length_drop [simp]: "!!xs. length (drop n xs) = (length xs - n)"
   759 by (induct n) (auto, case_tac xs, auto)
   760 
   761 lemma take_all [simp]: "!!xs. length xs <= n ==> take n xs = xs"
   762 by (induct n) (auto, case_tac xs, auto)
   763 
   764 lemma drop_all [simp]: "!!xs. length xs <= n ==> drop n xs = []"
   765 by (induct n) (auto, case_tac xs, auto)
   766 
   767 lemma take_append [simp]:
   768 "!!xs. take n (xs @ ys) = (take n xs @ take (n - length xs) ys)"
   769 by (induct n) (auto, case_tac xs, auto)
   770 
   771 lemma drop_append [simp]:
   772 "!!xs. drop n (xs @ ys) = drop n xs @ drop (n - length xs) ys"
   773 by (induct n) (auto, case_tac xs, auto)
   774 
   775 lemma take_take [simp]: "!!xs n. take n (take m xs) = take (min n m) xs"
   776 apply (induct m)
   777  apply auto
   778 apply (case_tac xs)
   779  apply auto
   780 apply (case_tac na)
   781  apply auto
   782 done
   783 
   784 lemma drop_drop [simp]: "!!xs. drop n (drop m xs) = drop (n + m) xs"
   785 apply (induct m)
   786  apply auto
   787 apply (case_tac xs)
   788  apply auto
   789 done
   790 
   791 lemma take_drop: "!!xs n. take n (drop m xs) = drop m (take (n + m) xs)"
   792 apply (induct m)
   793  apply auto
   794 apply (case_tac xs)
   795  apply auto
   796 done
   797 
   798 lemma append_take_drop_id [simp]: "!!xs. take n xs @ drop n xs = xs"
   799 apply (induct n)
   800  apply auto
   801 apply (case_tac xs)
   802  apply auto
   803 done
   804 
   805 lemma take_map: "!!xs. take n (map f xs) = map f (take n xs)"
   806 apply (induct n)
   807  apply auto
   808 apply (case_tac xs)
   809  apply auto
   810 done
   811 
   812 lemma drop_map: "!!xs. drop n (map f xs) = map f (drop n xs)"
   813 apply (induct n)
   814  apply auto
   815 apply (case_tac xs)
   816  apply auto
   817 done
   818 
   819 lemma rev_take: "!!i. rev (take i xs) = drop (length xs - i) (rev xs)"
   820 apply (induct xs)
   821  apply auto
   822 apply (case_tac i)
   823  apply auto
   824 done
   825 
   826 lemma rev_drop: "!!i. rev (drop i xs) = take (length xs - i) (rev xs)"
   827 apply (induct xs)
   828  apply auto
   829 apply (case_tac i)
   830  apply auto
   831 done
   832 
   833 lemma nth_take [simp]: "!!n i. i < n ==> (take n xs)!i = xs!i"
   834 apply (induct xs)
   835  apply auto
   836 apply (case_tac n)
   837  apply(blast )
   838 apply (case_tac i)
   839  apply auto
   840 done
   841 
   842 lemma nth_drop [simp]:
   843 "!!xs i. n + i <= length xs ==> (drop n xs)!i = xs!(n + i)"
   844 apply (induct n)
   845  apply auto
   846 apply (case_tac xs)
   847  apply auto
   848 done
   849 
   850 lemma append_eq_conv_conj:
   851 "!!zs. (xs @ ys = zs) = (xs = take (length xs) zs \<and> ys = drop (length xs) zs)"
   852 apply(induct xs)
   853  apply simp
   854 apply clarsimp
   855 apply (case_tac zs)
   856 apply auto
   857 done
   858 
   859 
   860 subsection {* @{text takeWhile} and @{text dropWhile} *}
   861 
   862 lemma takeWhile_dropWhile_id [simp]: "takeWhile P xs @ dropWhile P xs = xs"
   863 by (induct xs) auto
   864 
   865 lemma takeWhile_append1 [simp]:
   866 "[| x:set xs; ~P(x)|] ==> takeWhile P (xs @ ys) = takeWhile P xs"
   867 by (induct xs) auto
   868 
   869 lemma takeWhile_append2 [simp]:
   870 "(!!x. x : set xs ==> P x) ==> takeWhile P (xs @ ys) = xs @ takeWhile P ys"
   871 by (induct xs) auto
   872 
   873 lemma takeWhile_tail: "\<not> P x ==> takeWhile P (xs @ (x#l)) = takeWhile P xs"
   874 by (induct xs) auto
   875 
   876 lemma dropWhile_append1 [simp]:
   877 "[| x : set xs; ~P(x)|] ==> dropWhile P (xs @ ys) = (dropWhile P xs)@ys"
   878 by (induct xs) auto
   879 
   880 lemma dropWhile_append2 [simp]:
   881 "(!!x. x:set xs ==> P(x)) ==> dropWhile P (xs @ ys) = dropWhile P ys"
   882 by (induct xs) auto
   883 
   884 lemma set_take_whileD: "x : set (takeWhile P xs) ==> x : set xs \<and> P x"
   885 by (induct xs) (auto split: split_if_asm)
   886 
   887 
   888 subsection {* @{text zip} *}
   889 
   890 lemma zip_Nil [simp]: "zip [] ys = []"
   891 by (induct ys) auto
   892 
   893 lemma zip_Cons_Cons [simp]: "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
   894 by simp
   895 
   896 declare zip_Cons [simp del]
   897 
   898 lemma length_zip [simp]:
   899 "!!xs. length (zip xs ys) = min (length xs) (length ys)"
   900 apply(induct ys)
   901  apply simp
   902 apply (case_tac xs)
   903  apply auto
   904 done
   905 
   906 lemma zip_append1:
   907 "!!xs. zip (xs @ ys) zs =
   908 zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)"
   909 apply (induct zs)
   910  apply simp
   911 apply (case_tac xs)
   912  apply simp_all
   913 done
   914 
   915 lemma zip_append2:
   916 "!!ys. zip xs (ys @ zs) =
   917 zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs"
   918 apply (induct xs)
   919  apply simp
   920 apply (case_tac ys)
   921  apply simp_all
   922 done
   923 
   924 lemma zip_append [simp]:
   925  "[| length xs = length us; length ys = length vs |] ==>
   926 zip (xs@ys) (us@vs) = zip xs us @ zip ys vs"
   927 by (simp add: zip_append1)
   928 
   929 lemma zip_rev:
   930 "!!xs. length xs = length ys ==> zip (rev xs) (rev ys) = rev (zip xs ys)"
   931 apply(induct ys)
   932  apply simp
   933 apply (case_tac xs)
   934  apply simp_all
   935 done
   936 
   937 lemma nth_zip [simp]:
   938 "!!i xs. [| i < length xs; i < length ys|] ==> (zip xs ys)!i = (xs!i, ys!i)"
   939 apply (induct ys)
   940  apply simp
   941 apply (case_tac xs)
   942  apply (simp_all add: nth.simps split: nat.split)
   943 done
   944 
   945 lemma set_zip:
   946 "set (zip xs ys) = {(xs!i, ys!i) | i. i < min (length xs) (length ys)}"
   947 by (simp add: set_conv_nth cong: rev_conj_cong)
   948 
   949 lemma zip_update:
   950 "length xs = length ys ==> zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]"
   951 by (rule sym, simp add: update_zip)
   952 
   953 lemma zip_replicate [simp]:
   954 "!!j. zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)"
   955 apply (induct i)
   956  apply auto
   957 apply (case_tac j)
   958  apply auto
   959 done
   960 
   961 
   962 subsection {* @{text list_all2} *}
   963 
   964 lemma list_all2_lengthD: "list_all2 P xs ys ==> length xs = length ys"
   965 by (simp add: list_all2_def)
   966 
   967 lemma list_all2_Nil [iff]: "list_all2 P [] ys = (ys = [])"
   968 by (simp add: list_all2_def)
   969 
   970 lemma list_all2_Nil2[iff]: "list_all2 P xs [] = (xs = [])"
   971 by (simp add: list_all2_def)
   972 
   973 lemma list_all2_Cons [iff]:
   974 "list_all2 P (x # xs) (y # ys) = (P x y \<and> list_all2 P xs ys)"
   975 by (auto simp add: list_all2_def)
   976 
   977 lemma list_all2_Cons1:
   978 "list_all2 P (x # xs) ys = (\<exists>z zs. ys = z # zs \<and> P x z \<and> list_all2 P xs zs)"
   979 by (cases ys) auto
   980 
   981 lemma list_all2_Cons2:
   982 "list_all2 P xs (y # ys) = (\<exists>z zs. xs = z # zs \<and> P z y \<and> list_all2 P zs ys)"
   983 by (cases xs) auto
   984 
   985 lemma list_all2_rev [iff]:
   986 "list_all2 P (rev xs) (rev ys) = list_all2 P xs ys"
   987 by (simp add: list_all2_def zip_rev cong: conj_cong)
   988 
   989 lemma list_all2_append1:
   990 "list_all2 P (xs @ ys) zs =
   991 (EX us vs. zs = us @ vs \<and> length us = length xs \<and> length vs = length ys \<and>
   992 list_all2 P xs us \<and> list_all2 P ys vs)"
   993 apply (simp add: list_all2_def zip_append1)
   994 apply (rule iffI)
   995  apply (rule_tac x = "take (length xs) zs" in exI)
   996  apply (rule_tac x = "drop (length xs) zs" in exI)
   997  apply (force split: nat_diff_split simp add: min_def)
   998 apply clarify
   999 apply (simp add: ball_Un)
  1000 done
  1001 
  1002 lemma list_all2_append2:
  1003 "list_all2 P xs (ys @ zs) =
  1004 (EX us vs. xs = us @ vs \<and> length us = length ys \<and> length vs = length zs \<and>
  1005 list_all2 P us ys \<and> list_all2 P vs zs)"
  1006 apply (simp add: list_all2_def zip_append2)
  1007 apply (rule iffI)
  1008  apply (rule_tac x = "take (length ys) xs" in exI)
  1009  apply (rule_tac x = "drop (length ys) xs" in exI)
  1010  apply (force split: nat_diff_split simp add: min_def)
  1011 apply clarify
  1012 apply (simp add: ball_Un)
  1013 done
  1014 
  1015 lemma list_all2_conv_all_nth:
  1016 "list_all2 P xs ys =
  1017 (length xs = length ys \<and> (\<forall>i < length xs. P (xs!i) (ys!i)))"
  1018 by (force simp add: list_all2_def set_zip)
  1019 
  1020 lemma list_all2_trans[rule_format]:
  1021 "\<forall>a b c. P1 a b --> P2 b c --> P3 a c ==>
  1022 \<forall>bs cs. list_all2 P1 as bs --> list_all2 P2 bs cs --> list_all2 P3 as cs"
  1023 apply(induct_tac as)
  1024  apply simp
  1025 apply(rule allI)
  1026 apply(induct_tac bs)
  1027  apply simp
  1028 apply(rule allI)
  1029 apply(induct_tac cs)
  1030  apply auto
  1031 done
  1032 
  1033 
  1034 subsection {* @{text foldl} *}
  1035 
  1036 lemma foldl_append [simp]:
  1037 "!!a. foldl f a (xs @ ys) = foldl f (foldl f a xs) ys"
  1038 by (induct xs) auto
  1039 
  1040 text {*
  1041 Note: @{text "n \<le> foldl (op +) n ns"} looks simpler, but is more
  1042 difficult to use because it requires an additional transitivity step.
  1043 *}
  1044 
  1045 lemma start_le_sum: "!!n::nat. m <= n ==> m <= foldl (op +) n ns"
  1046 by (induct ns) auto
  1047 
  1048 lemma elem_le_sum: "!!n::nat. n : set ns ==> n <= foldl (op +) 0 ns"
  1049 by (force intro: start_le_sum simp add: in_set_conv_decomp)
  1050 
  1051 lemma sum_eq_0_conv [iff]:
  1052 "!!m::nat. (foldl (op +) m ns = 0) = (m = 0 \<and> (\<forall>n \<in> set ns. n = 0))"
  1053 by (induct ns) auto
  1054 
  1055 
  1056 subsection {* @{text upto} *}
  1057 
  1058 lemma upt_rec: "[i..j(] = (if i<j then i#[Suc i..j(] else [])"
  1059 -- {* Does not terminate! *}
  1060 by (induct j) auto
  1061 
  1062 lemma upt_conv_Nil [simp]: "j <= i ==> [i..j(] = []"
  1063 by (subst upt_rec) simp
  1064 
  1065 lemma upt_Suc_append: "i <= j ==> [i..(Suc j)(] = [i..j(]@[j]"
  1066 -- {* Only needed if @{text upt_Suc} is deleted from the simpset. *}
  1067 by simp
  1068 
  1069 lemma upt_conv_Cons: "i < j ==> [i..j(] = i # [Suc i..j(]"
  1070 apply(rule trans)
  1071 apply(subst upt_rec)
  1072  prefer 2 apply(rule refl)
  1073 apply simp
  1074 done
  1075 
  1076 lemma upt_add_eq_append: "i<=j ==> [i..j+k(] = [i..j(]@[j..j+k(]"
  1077 -- {* LOOPS as a simprule, since @{text "j <= j"}. *}
  1078 by (induct k) auto
  1079 
  1080 lemma length_upt [simp]: "length [i..j(] = j - i"
  1081 by (induct j) (auto simp add: Suc_diff_le)
  1082 
  1083 lemma nth_upt [simp]: "i + k < j ==> [i..j(] ! k = i + k"
  1084 apply (induct j)
  1085 apply (auto simp add: less_Suc_eq nth_append split: nat_diff_split)
  1086 done
  1087 
  1088 lemma take_upt [simp]: "!!i. i+m <= n ==> take m [i..n(] = [i..i+m(]"
  1089 apply (induct m)
  1090  apply simp
  1091 apply (subst upt_rec)
  1092 apply (rule sym)
  1093 apply (subst upt_rec)
  1094 apply (simp del: upt.simps)
  1095 done
  1096 
  1097 lemma map_Suc_upt: "map Suc [m..n(] = [Suc m..n]"
  1098 by (induct n) auto
  1099 
  1100 lemma nth_map_upt: "!!i. i < n-m ==> (map f [m..n(]) ! i = f(m+i)"
  1101 apply (induct n m rule: diff_induct)
  1102 prefer 3 apply (subst map_Suc_upt[symmetric])
  1103 apply (auto simp add: less_diff_conv nth_upt)
  1104 done
  1105 
  1106 lemma nth_take_lemma [rule_format]:
  1107 "ALL xs ys. k <= length xs --> k <= length ys
  1108 --> (ALL i. i < k --> xs!i = ys!i)
  1109 --> take k xs = take k ys"
  1110 apply (induct k)
  1111 apply (simp_all add: less_Suc_eq_0_disj all_conj_distrib)
  1112 apply clarify
  1113 txt {* Both lists must be non-empty *}
  1114 apply (case_tac xs)
  1115  apply simp
  1116 apply (case_tac ys)
  1117  apply clarify
  1118  apply (simp (no_asm_use))
  1119 apply clarify
  1120 txt {* prenexing's needed, not miniscoping *}
  1121 apply (simp (no_asm_use) add: all_simps [symmetric] del: all_simps)
  1122 apply blast
  1123 done
  1124 
  1125 lemma nth_equalityI:
  1126  "[| length xs = length ys; ALL i < length xs. xs!i = ys!i |] ==> xs = ys"
  1127 apply (frule nth_take_lemma [OF le_refl eq_imp_le])
  1128 apply (simp_all add: take_all)
  1129 done
  1130 
  1131 lemma take_equalityI: "(\<forall>i. take i xs = take i ys) ==> xs = ys"
  1132 -- {* The famous take-lemma. *}
  1133 apply (drule_tac x = "max (length xs) (length ys)" in spec)
  1134 apply (simp add: le_max_iff_disj take_all)
  1135 done
  1136 
  1137 
  1138 subsection {* @{text "distinct"} and @{text remdups} *}
  1139 
  1140 lemma distinct_append [simp]:
  1141 "distinct (xs @ ys) = (distinct xs \<and> distinct ys \<and> set xs \<inter> set ys = {})"
  1142 by (induct xs) auto
  1143 
  1144 lemma set_remdups [simp]: "set (remdups xs) = set xs"
  1145 by (induct xs) (auto simp add: insert_absorb)
  1146 
  1147 lemma distinct_remdups [iff]: "distinct (remdups xs)"
  1148 by (induct xs) auto
  1149 
  1150 lemma distinct_filter [simp]: "distinct xs ==> distinct (filter P xs)"
  1151 by (induct xs) auto
  1152 
  1153 text {*
  1154 It is best to avoid this indexed version of distinct, but sometimes
  1155 it is useful. *}
  1156 lemma distinct_conv_nth:
  1157 "distinct xs = (\<forall>i j. i < size xs \<and> j < size xs \<and> i \<noteq> j --> xs!i \<noteq> xs!j)"
  1158 apply (induct_tac xs)
  1159  apply simp
  1160 apply simp
  1161 apply (rule iffI)
  1162  apply clarsimp
  1163  apply (case_tac i)
  1164 apply (case_tac j)
  1165  apply simp
  1166 apply (simp add: set_conv_nth)
  1167  apply (case_tac j)
  1168 apply (clarsimp simp add: set_conv_nth)
  1169  apply simp
  1170 apply (rule conjI)
  1171  apply (clarsimp simp add: set_conv_nth)
  1172  apply (erule_tac x = 0 in allE)
  1173  apply (erule_tac x = "Suc i" in allE)
  1174  apply simp
  1175 apply clarsimp
  1176 apply (erule_tac x = "Suc i" in allE)
  1177 apply (erule_tac x = "Suc j" in allE)
  1178 apply simp
  1179 done
  1180 
  1181 
  1182 subsection {* @{text replicate} *}
  1183 
  1184 lemma length_replicate [simp]: "length (replicate n x) = n"
  1185 by (induct n) auto
  1186 
  1187 lemma map_replicate [simp]: "map f (replicate n x) = replicate n (f x)"
  1188 by (induct n) auto
  1189 
  1190 lemma replicate_app_Cons_same:
  1191 "(replicate n x) @ (x # xs) = x # replicate n x @ xs"
  1192 by (induct n) auto
  1193 
  1194 lemma rev_replicate [simp]: "rev (replicate n x) = replicate n x"
  1195 apply(induct n)
  1196  apply simp
  1197 apply (simp add: replicate_app_Cons_same)
  1198 done
  1199 
  1200 lemma replicate_add: "replicate (n + m) x = replicate n x @ replicate m x"
  1201 by (induct n) auto
  1202 
  1203 lemma hd_replicate [simp]: "n \<noteq> 0 ==> hd (replicate n x) = x"
  1204 by (induct n) auto
  1205 
  1206 lemma tl_replicate [simp]: "n \<noteq> 0 ==> tl (replicate n x) = replicate (n - 1) x"
  1207 by (induct n) auto
  1208 
  1209 lemma last_replicate [simp]: "n \<noteq> 0 ==> last (replicate n x) = x"
  1210 by (atomize (full), induct n) auto
  1211 
  1212 lemma nth_replicate[simp]: "!!i. i < n ==> (replicate n x)!i = x"
  1213 apply(induct n)
  1214  apply simp
  1215 apply (simp add: nth_Cons split: nat.split)
  1216 done
  1217 
  1218 lemma set_replicate_Suc: "set (replicate (Suc n) x) = {x}"
  1219 by (induct n) auto
  1220 
  1221 lemma set_replicate [simp]: "n \<noteq> 0 ==> set (replicate n x) = {x}"
  1222 by (fast dest!: not0_implies_Suc intro!: set_replicate_Suc)
  1223 
  1224 lemma set_replicate_conv_if: "set (replicate n x) = (if n = 0 then {} else {x})"
  1225 by auto
  1226 
  1227 lemma in_set_replicateD: "x : set (replicate n y) ==> x = y"
  1228 by (simp add: set_replicate_conv_if split: split_if_asm)
  1229 
  1230 
  1231 subsection {* Lexcicographic orderings on lists *}
  1232 
  1233 lemma wf_lexn: "wf r ==> wf (lexn r n)"
  1234 apply (induct_tac n)
  1235  apply simp
  1236 apply simp
  1237 apply(rule wf_subset)
  1238  prefer 2 apply (rule Int_lower1)
  1239 apply(rule wf_prod_fun_image)
  1240  prefer 2 apply (rule injI)
  1241 apply auto
  1242 done
  1243 
  1244 lemma lexn_length:
  1245 "!!xs ys. (xs, ys) : lexn r n ==> length xs = n \<and> length ys = n"
  1246 by (induct n) auto
  1247 
  1248 lemma wf_lex [intro!]: "wf r ==> wf (lex r)"
  1249 apply (unfold lex_def)
  1250 apply (rule wf_UN)
  1251 apply (blast intro: wf_lexn)
  1252 apply clarify
  1253 apply (rename_tac m n)
  1254 apply (subgoal_tac "m \<noteq> n")
  1255  prefer 2 apply blast
  1256 apply (blast dest: lexn_length not_sym)
  1257 done
  1258 
  1259 lemma lexn_conv:
  1260 "lexn r n =
  1261 {(xs,ys). length xs = n \<and> length ys = n \<and>
  1262 (\<exists>xys x y xs' ys'. xs= xys @ x#xs' \<and> ys= xys @ y # ys' \<and> (x, y):r)}"
  1263 apply (induct_tac n)
  1264  apply simp
  1265  apply blast
  1266 apply (simp add: image_Collect lex_prod_def)
  1267 apply auto
  1268 apply blast
  1269  apply (rename_tac a xys x xs' y ys')
  1270  apply (rule_tac x = "a # xys" in exI)
  1271  apply simp
  1272 apply (case_tac xys)
  1273  apply simp_all
  1274 apply blast
  1275 done
  1276 
  1277 lemma lex_conv:
  1278 "lex r =
  1279 {(xs,ys). length xs = length ys \<and>
  1280 (\<exists>xys x y xs' ys'. xs = xys @ x # xs' \<and> ys = xys @ y # ys' \<and> (x, y):r)}"
  1281 by (force simp add: lex_def lexn_conv)
  1282 
  1283 lemma wf_lexico [intro!]: "wf r ==> wf (lexico r)"
  1284 by (unfold lexico_def) blast
  1285 
  1286 lemma lexico_conv:
  1287 "lexico r = {(xs,ys). length xs < length ys |
  1288 length xs = length ys \<and> (xs, ys) : lex r}"
  1289 by (simp add: lexico_def diag_def lex_prod_def measure_def inv_image_def)
  1290 
  1291 lemma Nil_notin_lex [iff]: "([], ys) \<notin> lex r"
  1292 by (simp add: lex_conv)
  1293 
  1294 lemma Nil2_notin_lex [iff]: "(xs, []) \<notin> lex r"
  1295 by (simp add:lex_conv)
  1296 
  1297 lemma Cons_in_lex [iff]:
  1298 "((x # xs, y # ys) : lex r) =
  1299 ((x, y) : r \<and> length xs = length ys | x = y \<and> (xs, ys) : lex r)"
  1300 apply (simp add: lex_conv)
  1301 apply (rule iffI)
  1302  prefer 2 apply (blast intro: Cons_eq_appendI)
  1303 apply clarify
  1304 apply (case_tac xys)
  1305  apply simp
  1306 apply simp
  1307 apply blast
  1308 done
  1309 
  1310 
  1311 subsection {* @{text sublist} --- a generalization of @{text nth} to sets *}
  1312 
  1313 lemma sublist_empty [simp]: "sublist xs {} = []"
  1314 by (auto simp add: sublist_def)
  1315 
  1316 lemma sublist_nil [simp]: "sublist [] A = []"
  1317 by (auto simp add: sublist_def)
  1318 
  1319 lemma sublist_shift_lemma:
  1320 "map fst [p:zip xs [i..i + length xs(] . snd p : A] =
  1321 map fst [p:zip xs [0..length xs(] . snd p + i : A]"
  1322 by (induct xs rule: rev_induct) (simp_all add: add_commute)
  1323 
  1324 lemma sublist_append:
  1325 "sublist (l @ l') A = sublist l A @ sublist l' {j. j + length l : A}"
  1326 apply (unfold sublist_def)
  1327 apply (induct l' rule: rev_induct)
  1328  apply simp
  1329 apply (simp add: upt_add_eq_append[of 0] zip_append sublist_shift_lemma)
  1330 apply (simp add: add_commute)
  1331 done
  1332 
  1333 lemma sublist_Cons:
  1334 "sublist (x # l) A = (if 0:A then [x] else []) @ sublist l {j. Suc j : A}"
  1335 apply (induct l rule: rev_induct)
  1336  apply (simp add: sublist_def)
  1337 apply (simp del: append_Cons add: append_Cons[symmetric] sublist_append)
  1338 done
  1339 
  1340 lemma sublist_singleton [simp]: "sublist [x] A = (if 0 : A then [x] else [])"
  1341 by (simp add: sublist_Cons)
  1342 
  1343 lemma sublist_upt_eq_take [simp]: "sublist l {..n(} = take n l"
  1344 apply (induct l rule: rev_induct)
  1345  apply simp
  1346 apply (simp split: nat_diff_split add: sublist_append)
  1347 done
  1348 
  1349 
  1350 lemma take_Cons':
  1351 "take n (x # xs) = (if n = 0 then [] else x # take (n - 1) xs)"
  1352 by (cases n) simp_all
  1353 
  1354 lemma drop_Cons':
  1355 "drop n (x # xs) = (if n = 0 then x # xs else drop (n - 1) xs)"
  1356 by (cases n) simp_all
  1357 
  1358 lemma nth_Cons': "(x # xs)!n = (if n = 0 then x else xs!(n - 1))"
  1359 by (cases n) simp_all
  1360 
  1361 lemmas [simp] = take_Cons'[of "number_of v",standard]
  1362                 drop_Cons'[of "number_of v",standard]
  1363                 nth_Cons'[of _ _ "number_of v",standard]
  1364 
  1365 end