src/HOL/SMT.thy
author boehmes
Mon Nov 29 23:41:09 2010 +0100 (2010-11-29)
changeset 40806 59d96f777da3
parent 40681 872b08416fb4
child 41059 d2b1fc1b8e19
permissions -rw-r--r--
also support higher-order rules for Z3 proof reconstruction
     1 (*  Title:      HOL/SMT.thy
     2     Author:     Sascha Boehme, TU Muenchen
     3 *)
     4 
     5 header {* Bindings to Satisfiability Modulo Theories (SMT) solvers *}
     6 
     7 theory SMT
     8 imports List
     9 uses
    10   "Tools/Datatype/datatype_selectors.ML"
    11   "Tools/SMT/smt_failure.ML"
    12   "Tools/SMT/smt_config.ML"
    13   "Tools/SMT/smt_utils.ML"
    14   "Tools/SMT/smt_monomorph.ML"
    15   ("Tools/SMT/smt_builtin.ML")
    16   ("Tools/SMT/smt_normalize.ML")
    17   ("Tools/SMT/smt_translate.ML")
    18   ("Tools/SMT/smt_solver.ML")
    19   ("Tools/SMT/smtlib_interface.ML")
    20   ("Tools/SMT/z3_proof_parser.ML")
    21   ("Tools/SMT/z3_proof_tools.ML")
    22   ("Tools/SMT/z3_proof_literals.ML")
    23   ("Tools/SMT/z3_proof_methods.ML")
    24   ("Tools/SMT/z3_proof_reconstruction.ML")
    25   ("Tools/SMT/z3_model.ML")
    26   ("Tools/SMT/z3_interface.ML")
    27   ("Tools/SMT/smt_setup_solvers.ML")
    28 begin
    29 
    30 
    31 
    32 subsection {* Triggers for quantifier instantiation *}
    33 
    34 text {*
    35 Some SMT solvers support triggers for quantifier instantiation.
    36 Each trigger consists of one ore more patterns.  A pattern may either
    37 be a list of positive subterms (each being tagged by "pat"), or a
    38 list of negative subterms (each being tagged by "nopat").
    39 
    40 When an SMT solver finds a term matching a positive pattern (a
    41 pattern with positive subterms only), it instantiates the
    42 corresponding quantifier accordingly.  Negative patterns inhibit
    43 quantifier instantiations.  Each pattern should mention all preceding
    44 bound variables.
    45 *}
    46 
    47 datatype pattern = Pattern
    48 
    49 definition pat :: "'a \<Rightarrow> pattern" where "pat _ = Pattern"
    50 definition nopat :: "'a \<Rightarrow> pattern" where "nopat _ = Pattern"
    51 
    52 definition trigger :: "pattern list list \<Rightarrow> bool \<Rightarrow> bool"
    53 where "trigger _ P = P"
    54 
    55 
    56 
    57 subsection {* Quantifier weights *}
    58 
    59 text {*
    60 Weight annotations to quantifiers influence the priority of quantifier
    61 instantiations.  They should be handled with care for solvers, which support
    62 them, because incorrect choices of weights might render a problem unsolvable.
    63 *}
    64 
    65 definition weight :: "int \<Rightarrow> bool \<Rightarrow> bool" where "weight _ P = P"
    66 
    67 text {*
    68 Weights must be non-negative.  The value @{text 0} is equivalent to providing
    69 no weight at all.
    70 
    71 Weights should only be used at quantifiers and only inside triggers (if the
    72 quantifier has triggers).  Valid usages of weights are as follows:
    73 
    74 \begin{itemize}
    75 \item
    76 @{term "\<forall>x. trigger [[pat (P x)]] (weight 2 (P x))"}
    77 \item
    78 @{term "\<forall>x. weight 3 (P x)"}
    79 \end{itemize}
    80 *}
    81 
    82 
    83 
    84 subsection {* Higher-order encoding *}
    85 
    86 text {*
    87 Application is made explicit for constants occurring with varying
    88 numbers of arguments.  This is achieved by the introduction of the
    89 following constant.
    90 *}
    91 
    92 definition fun_app where "fun_app f x = f x"
    93 
    94 text {*
    95 Some solvers support a theory of arrays which can be used to encode
    96 higher-order functions.  The following set of lemmas specifies the
    97 properties of such (extensional) arrays.
    98 *}
    99 
   100 lemmas array_rules = ext fun_upd_apply fun_upd_same fun_upd_other
   101   fun_upd_upd fun_app_def
   102 
   103 
   104 
   105 subsection {* First-order logic *}
   106 
   107 text {*
   108 Some SMT solvers require a strict separation between formulas and
   109 terms.  When translating higher-order into first-order problems,
   110 all uninterpreted constants (those not builtin in the target solver)
   111 are treated as function symbols in the first-order sense.  Their
   112 occurrences as head symbols in atoms (i.e., as predicate symbols) is
   113 turned into terms by equating such atoms with @{term True} using the
   114 following term-level equation symbol.
   115 *}
   116 
   117 definition term_eq :: "bool \<Rightarrow> bool \<Rightarrow> bool" where "term_eq x y = (x = y)"
   118 
   119 
   120 
   121 subsection {* Integer division and modulo for Z3 *}
   122 
   123 definition z3div :: "int \<Rightarrow> int \<Rightarrow> int" where
   124   "z3div k l = (if 0 \<le> l then k div l else -(k div (-l)))"
   125 
   126 definition z3mod :: "int \<Rightarrow> int \<Rightarrow> int" where
   127   "z3mod k l = (if 0 \<le> l then k mod l else k mod (-l))"
   128 
   129 lemma div_by_z3div: "k div l = (
   130      if k = 0 \<or> l = 0 then 0
   131      else if (0 < k \<and> 0 < l) \<or> (k < 0 \<and> 0 < l) then z3div k l
   132      else z3div (-k) (-l))"
   133   by (auto simp add: z3div_def)
   134 
   135 lemma mod_by_z3mod: "k mod l = (
   136      if l = 0 then k
   137      else if k = 0 then 0
   138      else if (0 < k \<and> 0 < l) \<or> (k < 0 \<and> 0 < l) then z3mod k l
   139      else - z3mod (-k) (-l))"
   140   by (auto simp add: z3mod_def)
   141 
   142 
   143 
   144 subsection {* Setup *}
   145 
   146 use "Tools/SMT/smt_builtin.ML"
   147 use "Tools/SMT/smt_normalize.ML"
   148 use "Tools/SMT/smt_translate.ML"
   149 use "Tools/SMT/smt_solver.ML"
   150 use "Tools/SMT/smtlib_interface.ML"
   151 use "Tools/SMT/z3_interface.ML"
   152 use "Tools/SMT/z3_proof_parser.ML"
   153 use "Tools/SMT/z3_proof_tools.ML"
   154 use "Tools/SMT/z3_proof_literals.ML"
   155 use "Tools/SMT/z3_proof_methods.ML"
   156 use "Tools/SMT/z3_proof_reconstruction.ML"
   157 use "Tools/SMT/z3_model.ML"
   158 use "Tools/SMT/smt_setup_solvers.ML"
   159 
   160 setup {*
   161   SMT_Config.setup #>
   162   SMT_Solver.setup #>
   163   Z3_Proof_Reconstruction.setup #>
   164   SMT_Setup_Solvers.setup
   165 *}
   166 
   167 
   168 
   169 subsection {* Configuration *}
   170 
   171 text {*
   172 The current configuration can be printed by the command
   173 @{text smt_status}, which shows the values of most options.
   174 *}
   175 
   176 
   177 
   178 subsection {* General configuration options *}
   179 
   180 text {*
   181 The option @{text smt_solver} can be used to change the target SMT
   182 solver.  The possible values are @{text cvc3}, @{text yices}, and
   183 @{text z3}.  It is advisable to locally install the selected solver,
   184 although this is not necessary for @{text cvc3} and @{text z3}, which
   185 can also be used over an Internet-based service.
   186 
   187 When using local SMT solvers, the path to their binaries should be
   188 declared by setting the following environment variables:
   189 @{text CVC3_SOLVER}, @{text YICES_SOLVER}, and @{text Z3_SOLVER}.
   190 *}
   191 
   192 declare [[ smt_solver = z3 ]]
   193 
   194 text {*
   195 Since SMT solvers are potentially non-terminating, there is a timeout
   196 (given in seconds) to restrict their runtime.  A value greater than
   197 120 (seconds) is in most cases not advisable.
   198 *}
   199 
   200 declare [[ smt_timeout = 20 ]]
   201 
   202 text {*
   203 In general, the binding to SMT solvers runs as an oracle, i.e, the SMT
   204 solvers are fully trusted without additional checks.  The following
   205 option can cause the SMT solver to run in proof-producing mode, giving
   206 a checkable certificate.  This is currently only implemented for Z3.
   207 *}
   208 
   209 declare [[ smt_oracle = false ]]
   210 
   211 text {*
   212 Each SMT solver provides several commandline options to tweak its
   213 behaviour.  They can be passed to the solver by setting the following
   214 options.
   215 *}
   216 
   217 declare [[ cvc3_options = "", yices_options = "", z3_options = "" ]]
   218 
   219 text {*
   220 Enable the following option to use built-in support for datatypes and
   221 records.  Currently, this is only implemented for Z3 running in oracle
   222 mode.
   223 *}
   224 
   225 declare [[ smt_datatypes = false ]]
   226 
   227 
   228 
   229 subsection {* Certificates *}
   230 
   231 text {*
   232 By setting the option @{text smt_certificates} to the name of a file,
   233 all following applications of an SMT solver a cached in that file.
   234 Any further application of the same SMT solver (using the very same
   235 configuration) re-uses the cached certificate instead of invoking the
   236 solver.  An empty string disables caching certificates.
   237 
   238 The filename should be given as an explicit path.  It is good
   239 practice to use the name of the current theory (with ending
   240 @{text ".certs"} instead of @{text ".thy"}) as the certificates file.
   241 *}
   242 
   243 declare [[ smt_certificates = "" ]]
   244 
   245 text {*
   246 The option @{text smt_fixed} controls whether only stored
   247 certificates are should be used or invocation of an SMT solver is
   248 allowed.  When set to @{text true}, no SMT solver will ever be
   249 invoked and only the existing certificates found in the configured
   250 cache are used;  when set to @{text false} and there is no cached
   251 certificate for some proposition, then the configured SMT solver is
   252 invoked.
   253 *}
   254 
   255 declare [[ smt_fixed = false ]]
   256 
   257 
   258 
   259 subsection {* Tracing *}
   260 
   261 text {*
   262 The SMT method, when applied, traces important information.  To
   263 make it entirely silent, set the following option to @{text false}.
   264 *}
   265 
   266 declare [[ smt_verbose = true ]]
   267 
   268 text {*
   269 For tracing the generated problem file given to the SMT solver as
   270 well as the returned result of the solver, the option
   271 @{text smt_trace} should be set to @{text true}.
   272 *}
   273 
   274 declare [[ smt_trace = false ]]
   275 
   276 text {*
   277 From the set of assumptions given to the SMT solver, those assumptions
   278 used in the proof are traced when the following option is set to
   279 @{term true}.  This only works for Z3 when it runs in non-oracle mode
   280 (see options @{text smt_solver} and @{text smt_oracle} above).
   281 *}
   282 
   283 declare [[ smt_trace_used_facts = false ]]
   284 
   285 
   286 
   287 subsection {* Schematic rules for Z3 proof reconstruction *}
   288 
   289 text {*
   290 Several prof rules of Z3 are not very well documented.  There are two
   291 lemma groups which can turn failing Z3 proof reconstruction attempts
   292 into succeeding ones: the facts in @{text z3_rule} are tried prior to
   293 any implemented reconstruction procedure for all uncertain Z3 proof
   294 rules;  the facts in @{text z3_simp} are only fed to invocations of
   295 the simplifier when reconstructing theory-specific proof steps.
   296 *}
   297 
   298 lemmas [z3_rule] =
   299   refl eq_commute conj_commute disj_commute simp_thms nnf_simps
   300   ring_distribs field_simps times_divide_eq_right times_divide_eq_left
   301   if_True if_False not_not
   302 
   303 lemma [z3_rule]:
   304   "(P \<longrightarrow> Q) = (Q \<or> \<not>P)"
   305   "(\<not>P \<longrightarrow> Q) = (P \<or> Q)"
   306   "(\<not>P \<longrightarrow> Q) = (Q \<or> P)"
   307   by auto
   308 
   309 lemma [z3_rule]:
   310   "((P = Q) \<longrightarrow> R) = (R | (Q = (\<not>P)))"
   311   by auto
   312 
   313 lemma [z3_rule]:
   314   "((\<not>P) = P) = False"
   315   "(P = (\<not>P)) = False"
   316   "(P \<noteq> Q) = (Q = (\<not>P))"
   317   "(P = Q) = ((\<not>P \<or> Q) \<and> (P \<or> \<not>Q))"
   318   "(P \<noteq> Q) = ((\<not>P \<or> \<not>Q) \<and> (P \<or> Q))"
   319   by auto
   320 
   321 lemma [z3_rule]:
   322   "(if P then P else \<not>P) = True"
   323   "(if \<not>P then \<not>P else P) = True"
   324   "(if P then True else False) = P"
   325   "(if P then False else True) = (\<not>P)"
   326   "(if \<not>P then x else y) = (if P then y else x)"
   327   "f (if P then x else y) = (if P then f x else f y)"
   328   by auto
   329 
   330 lemma [z3_rule]:
   331   "P = Q \<or> P \<or> Q"
   332   "P = Q \<or> \<not>P \<or> \<not>Q"
   333   "(\<not>P) = Q \<or> \<not>P \<or> Q"
   334   "(\<not>P) = Q \<or> P \<or> \<not>Q"
   335   "P = (\<not>Q) \<or> \<not>P \<or> Q"
   336   "P = (\<not>Q) \<or> P \<or> \<not>Q"
   337   "P \<noteq> Q \<or> P \<or> \<not>Q"
   338   "P \<noteq> Q \<or> \<not>P \<or> Q"
   339   "P \<noteq> (\<not>Q) \<or> P \<or> Q"
   340   "(\<not>P) \<noteq> Q \<or> P \<or> Q"
   341   "P \<or> Q \<or> P \<noteq> (\<not>Q)"
   342   "P \<or> Q \<or> (\<not>P) \<noteq> Q"
   343   "P \<or> \<not>Q \<or> P \<noteq> Q"
   344   "\<not>P \<or> Q \<or> P \<noteq> Q"
   345   by auto
   346 
   347 lemma [z3_rule]:
   348   "0 + (x::int) = x"
   349   "x + 0 = x"
   350   "0 * x = 0"
   351   "1 * x = x"
   352   "x + y = y + x"
   353   by auto
   354 
   355 
   356 
   357 hide_type (open) pattern
   358 hide_const Pattern term_eq
   359 hide_const (open) trigger pat nopat weight fun_app z3div z3mod
   360 
   361 
   362 
   363 subsection {* Selectors for datatypes *}
   364 
   365 setup {* Datatype_Selectors.setup *}
   366 
   367 declare [[ selector Pair 1 = fst, selector Pair 2 = snd ]]
   368 declare [[ selector Cons 1 = hd, selector Cons 2 = tl ]]
   369 
   370 end