src/Pure/thm.ML
author nipkow
Thu Oct 16 13:45:16 1997 +0200 (1997-10-16)
changeset 3893 5a1f22e7b359
parent 3812 66fa30839377
child 3895 b2463861c86a
permissions -rw-r--r--
The simplifier has been improved a little: equations s=t which used to be
rejected because of looping are now treated as (s=t) == True. The latter
translation must be done outside of Thm because it involves the object-logic
specific True. Therefore the simple loop test has been moved from Thm to
Logic.
     1 (*  Title:      Pure/thm.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1994  University of Cambridge
     5 
     6 The core of Isabelle's Meta Logic: certified types and terms, meta
     7 theorems, meta rules (including resolution and simplification).
     8 *)
     9 
    10 signature THM =
    11   sig
    12   (*certified types*)
    13   type ctyp
    14   val rep_ctyp          : ctyp -> {sign: Sign.sg, T: typ}
    15   val typ_of            : ctyp -> typ
    16   val ctyp_of           : Sign.sg -> typ -> ctyp
    17   val read_ctyp         : Sign.sg -> string -> ctyp
    18 
    19   (*certified terms*)
    20   type cterm
    21   exception CTERM of string
    22   val rep_cterm         : cterm -> {sign: Sign.sg, t: term, T: typ,
    23                                     maxidx: int}
    24   val term_of           : cterm -> term
    25   val cterm_of          : Sign.sg -> term -> cterm
    26   val ctyp_of_term      : cterm -> ctyp
    27   val read_cterm        : Sign.sg -> string * typ -> cterm
    28   val read_cterms       : Sign.sg -> string list * typ list -> cterm list
    29   val cterm_fun         : (term -> term) -> (cterm -> cterm)
    30   val dest_comb         : cterm -> cterm * cterm
    31   val dest_abs          : cterm -> cterm * cterm
    32   val adjust_maxidx     : cterm -> cterm
    33   val capply            : cterm -> cterm -> cterm
    34   val cabs              : cterm -> cterm -> cterm
    35   val read_def_cterm    :
    36     Sign.sg * (indexname -> typ option) * (indexname -> sort option) ->
    37     string list -> bool -> string * typ -> cterm * (indexname * typ) list
    38 
    39   (*theories*)
    40 
    41   (*proof terms [must DUPLICATE declaration as a specification]*)
    42   datatype deriv_kind = MinDeriv | ThmDeriv | FullDeriv;
    43   val keep_derivs       : deriv_kind ref
    44   datatype rule = 
    45       MinProof                          
    46     | Oracle of theory * string * Sign.sg * exn
    47     | Axiom               of theory * string
    48     | Theorem             of string       
    49     | Assume              of cterm
    50     | Implies_intr        of cterm
    51     | Implies_intr_shyps
    52     | Implies_intr_hyps
    53     | Implies_elim 
    54     | Forall_intr         of cterm
    55     | Forall_elim         of cterm
    56     | Reflexive           of cterm
    57     | Symmetric 
    58     | Transitive
    59     | Beta_conversion     of cterm
    60     | Extensional
    61     | Abstract_rule       of string * cterm
    62     | Combination
    63     | Equal_intr
    64     | Equal_elim
    65     | Trivial             of cterm
    66     | Lift_rule           of cterm * int 
    67     | Assumption          of int * Envir.env option
    68     | Rotate_rule         of int * int
    69     | Instantiate         of (indexname * ctyp) list * (cterm * cterm) list
    70     | Bicompose           of bool * bool * int * int * Envir.env
    71     | Flexflex_rule       of Envir.env            
    72     | Class_triv          of theory * class       
    73     | VarifyT
    74     | FreezeT
    75     | RewriteC            of cterm
    76     | CongC               of cterm
    77     | Rewrite_cterm       of cterm
    78     | Rename_params_rule  of string list * int;
    79 
    80   type deriv   (* = rule mtree *)
    81 
    82   (*meta theorems*)
    83   type thm
    84   exception THM of string * int * thm list
    85   val rep_thm           : thm -> {sign: Sign.sg, der: deriv, maxidx: int,
    86                                   shyps: sort list, hyps: term list, 
    87                                   prop: term}
    88   val crep_thm          : thm -> {sign: Sign.sg, der: deriv, maxidx: int,
    89                                   shyps: sort list, hyps: cterm list, 
    90                                   prop: cterm}
    91   val stamps_of_thm     : thm -> string ref list
    92   val tpairs_of         : thm -> (term * term) list
    93   val prems_of          : thm -> term list
    94   val nprems_of         : thm -> int
    95   val concl_of          : thm -> term
    96   val cprop_of          : thm -> cterm
    97   val extra_shyps       : thm -> sort list
    98   val force_strip_shyps : bool ref      (* FIXME tmp (since 1995/08/01) *)
    99   val strip_shyps       : thm -> thm
   100   val implies_intr_shyps: thm -> thm
   101   val get_axiom         : theory -> xstring -> thm
   102   val name_thm          : string * thm -> thm
   103   val axioms_of         : theory -> (string * thm) list
   104 
   105   (*meta rules*)
   106   val assume            : cterm -> thm
   107   val compress          : thm -> thm
   108   val implies_intr      : cterm -> thm -> thm
   109   val implies_elim      : thm -> thm -> thm
   110   val forall_intr       : cterm -> thm -> thm
   111   val forall_elim       : cterm -> thm -> thm
   112   val flexpair_def      : thm
   113   val reflexive         : cterm -> thm
   114   val symmetric         : thm -> thm
   115   val transitive        : thm -> thm -> thm
   116   val beta_conversion   : cterm -> thm
   117   val extensional       : thm -> thm
   118   val abstract_rule     : string -> cterm -> thm -> thm
   119   val combination       : thm -> thm -> thm
   120   val equal_intr        : thm -> thm -> thm
   121   val equal_elim        : thm -> thm -> thm
   122   val implies_intr_hyps : thm -> thm
   123   val flexflex_rule     : thm -> thm Sequence.seq
   124   val instantiate       :
   125     (indexname * ctyp) list * (cterm * cterm) list -> thm -> thm
   126   val trivial           : cterm -> thm
   127   val class_triv        : theory -> class -> thm
   128   val varifyT           : thm -> thm
   129   val freezeT           : thm -> thm
   130   val dest_state        : thm * int ->
   131     (term * term) list * term list * term * term
   132   val lift_rule         : (thm * int) -> thm -> thm
   133   val assumption        : int -> thm -> thm Sequence.seq
   134   val eq_assumption     : int -> thm -> thm
   135   val rotate_rule       : int -> int -> thm -> thm
   136   val rename_params_rule: string list * int -> thm -> thm
   137   val bicompose         : bool -> bool * thm * int ->
   138     int -> thm -> thm Sequence.seq
   139   val biresolution      : bool -> (bool * thm) list ->
   140     int -> thm -> thm Sequence.seq
   141 
   142   (*meta simplification*)
   143   exception SIMPLIFIER of string * thm
   144   type meta_simpset
   145   val dest_mss		: meta_simpset ->
   146     {simps: thm list, congs: thm list, procs: (string * cterm list) list}
   147   val empty_mss         : meta_simpset
   148   val merge_mss		: meta_simpset * meta_simpset -> meta_simpset
   149   val add_simps         : meta_simpset * thm list -> meta_simpset
   150   val del_simps         : meta_simpset * thm list -> meta_simpset
   151   val mss_of            : thm list -> meta_simpset
   152   val add_congs         : meta_simpset * thm list -> meta_simpset
   153   val del_congs         : meta_simpset * thm list -> meta_simpset
   154   val add_simprocs	: meta_simpset *
   155     (string * cterm list * (Sign.sg -> thm list -> term -> thm option) * stamp) list
   156       -> meta_simpset
   157   val del_simprocs	: meta_simpset *
   158     (string * cterm list * (Sign.sg -> thm list -> term -> thm option) * stamp) list
   159       -> meta_simpset
   160   val add_prems         : meta_simpset * thm list -> meta_simpset
   161   val prems_of_mss      : meta_simpset -> thm list
   162   val set_mk_rews       : meta_simpset * (thm -> thm list) -> meta_simpset
   163   val mk_rews_of_mss    : meta_simpset -> thm -> thm list
   164   val set_termless      : meta_simpset * (term * term -> bool) -> meta_simpset
   165   val trace_simp        : bool ref
   166   val rewrite_cterm     : bool * bool -> meta_simpset ->
   167                           (meta_simpset -> thm -> thm option) -> cterm -> thm
   168 
   169   val invoke_oracle     : theory -> xstring -> Sign.sg * exn -> thm
   170 end;
   171 
   172 structure Thm: THM =
   173 struct
   174 
   175 (*** Certified terms and types ***)
   176 
   177 (** certified types **)
   178 
   179 (*certified typs under a signature*)
   180 
   181 datatype ctyp = Ctyp of {sign: Sign.sg, T: typ};
   182 
   183 fun rep_ctyp (Ctyp args) = args;
   184 fun typ_of (Ctyp {T, ...}) = T;
   185 
   186 fun ctyp_of sign T =
   187   Ctyp {sign = sign, T = Sign.certify_typ sign T};
   188 
   189 fun read_ctyp sign s =
   190   Ctyp {sign = sign, T = Sign.read_typ (sign, K None) s};
   191 
   192 
   193 
   194 (** certified terms **)
   195 
   196 (*certified terms under a signature, with checked typ and maxidx of Vars*)
   197 
   198 datatype cterm = Cterm of {sign: Sign.sg, t: term, T: typ, maxidx: int};
   199 
   200 fun rep_cterm (Cterm args) = args;
   201 fun term_of (Cterm {t, ...}) = t;
   202 
   203 fun ctyp_of_term (Cterm {sign, T, ...}) = Ctyp {sign=sign, T=T};
   204 
   205 (*create a cterm by checking a "raw" term with respect to a signature*)
   206 fun cterm_of sign tm =
   207   let val (t, T, maxidx) = Sign.certify_term sign tm
   208   in  Cterm {sign = sign, t = t, T = T, maxidx = maxidx}
   209   end;
   210 
   211 fun cterm_fun f (Cterm {sign, t, ...}) = cterm_of sign (f t);
   212 
   213 
   214 exception CTERM of string;
   215 
   216 (*Destruct application in cterms*)
   217 fun dest_comb (Cterm{sign, T, maxidx, t = A $ B}) =
   218       let val typeA = fastype_of A;
   219           val typeB =
   220             case typeA of Type("fun",[S,T]) => S
   221                         | _ => error "Function type expected in dest_comb";
   222       in
   223       (Cterm {sign=sign, maxidx=maxidx, t=A, T=typeA},
   224        Cterm {sign=sign, maxidx=maxidx, t=B, T=typeB})
   225       end
   226   | dest_comb _ = raise CTERM "dest_comb";
   227 
   228 (*Destruct abstraction in cterms*)
   229 fun dest_abs (Cterm {sign, T as Type("fun",[_,S]), maxidx, t=Abs(x,ty,M)}) = 
   230       let val (y,N) = variant_abs (x,ty,M)
   231       in (Cterm {sign = sign, T = ty, maxidx = 0, t = Free(y,ty)},
   232           Cterm {sign = sign, T = S, maxidx = maxidx, t = N})
   233       end
   234   | dest_abs _ = raise CTERM "dest_abs";
   235 
   236 (*Makes maxidx precise: it is often too big*)
   237 fun adjust_maxidx (ct as Cterm {sign, T, t, maxidx, ...}) =
   238   if maxidx = ~1 then ct 
   239   else  Cterm {sign = sign, T = T, maxidx = maxidx_of_term t, t = t};
   240 
   241 (*Form cterm out of a function and an argument*)
   242 fun capply (Cterm {t=f, sign=sign1, T=Type("fun",[dty,rty]), maxidx=maxidx1})
   243            (Cterm {t=x, sign=sign2, T, maxidx=maxidx2}) =
   244       if T = dty then Cterm{t=f$x, sign=Sign.merge(sign1,sign2), T=rty,
   245                             maxidx=Int.max(maxidx1, maxidx2)}
   246       else raise CTERM "capply: types don't agree"
   247   | capply _ _ = raise CTERM "capply: first arg is not a function"
   248 
   249 fun cabs (Cterm {t=Free(a,ty), sign=sign1, T=T1, maxidx=maxidx1})
   250          (Cterm {t=t2, sign=sign2, T=T2, maxidx=maxidx2}) =
   251       Cterm {t=absfree(a,ty,t2), sign=Sign.merge(sign1,sign2),
   252              T = ty --> T2, maxidx=Int.max(maxidx1, maxidx2)}
   253   | cabs _ _ = raise CTERM "cabs: first arg is not a free variable";
   254 
   255 
   256 
   257 (** read cterms **)   (*exception ERROR*)
   258 
   259 (*read term, infer types, certify term*)
   260 fun read_def_cterm (sign, types, sorts) used freeze (a, T) =
   261   let
   262     val T' = Sign.certify_typ sign T
   263       handle TYPE (msg, _, _) => error msg;
   264     val ts = Syntax.read (#syn (Sign.rep_sg sign)) T' a;
   265     val (_, t', tye) =
   266           Sign.infer_types sign types sorts used freeze (ts, T');
   267     val ct = cterm_of sign t'
   268       handle TYPE (msg, _, _) => error msg
   269            | TERM (msg, _) => error msg;
   270   in (ct, tye) end;
   271 
   272 fun read_cterm sign = #1 o read_def_cterm (sign, K None, K None) [] true;
   273 
   274 (*read a list of terms, matching them against a list of expected types.
   275   NO disambiguation of alternative parses via type-checking -- it is just
   276   not practical.*)
   277 fun read_cterms sg (bs, Ts) =
   278   let
   279     val {tsig, syn, ...} = Sign.rep_sg sg;
   280     fun read (b, T) =
   281       (case Syntax.read syn T b of
   282         [t] => t
   283       | _  => error ("Error or ambiguity in parsing of " ^ b));
   284 
   285     val prt = setmp Syntax.show_brackets true (Sign.pretty_term sg);
   286     val prT = Sign.pretty_typ sg;
   287     val (us, _) =
   288       (* FIXME Sign.infer_types!? *)
   289       Type.infer_types prt prT tsig (Sign.const_type sg) (K None) (K None)
   290         (Sign.intern_const sg) (Sign.intern_tycons sg) (Sign.intern_sort sg)
   291         [] true (map (Sign.certify_typ sg) Ts) (ListPair.map read (bs, Ts));
   292   in map (cterm_of sg) us end
   293   handle TYPE (msg, _, _) => error msg
   294        | TERM (msg, _) => error msg;
   295 
   296 
   297 
   298 (*** Derivations ***)
   299 
   300 (*Names of rules in derivations.  Includes logically trivial rules, if 
   301   executed in ML.*)
   302 datatype rule = 
   303     MinProof                            (*for building minimal proof terms*)
   304   | Oracle              of theory * string * Sign.sg * exn       (*oracles*)
   305 (*Axioms/theorems*)
   306   | Axiom               of theory * string
   307   | Theorem             of string
   308 (*primitive inferences and compound versions of them*)
   309   | Assume              of cterm
   310   | Implies_intr        of cterm
   311   | Implies_intr_shyps
   312   | Implies_intr_hyps
   313   | Implies_elim 
   314   | Forall_intr         of cterm
   315   | Forall_elim         of cterm
   316   | Reflexive           of cterm
   317   | Symmetric 
   318   | Transitive
   319   | Beta_conversion     of cterm
   320   | Extensional
   321   | Abstract_rule       of string * cterm
   322   | Combination
   323   | Equal_intr
   324   | Equal_elim
   325 (*derived rules for tactical proof*)
   326   | Trivial             of cterm
   327         (*For lift_rule, the proof state is not a premise.
   328           Use cterm instead of thm to avoid mutual recursion.*)
   329   | Lift_rule           of cterm * int 
   330   | Assumption          of int * Envir.env option (*includes eq_assumption*)
   331   | Rotate_rule         of int * int
   332   | Instantiate         of (indexname * ctyp) list * (cterm * cterm) list
   333   | Bicompose           of bool * bool * int * int * Envir.env
   334   | Flexflex_rule       of Envir.env            (*identifies unifier chosen*)
   335 (*other derived rules*)
   336   | Class_triv          of theory * class
   337   | VarifyT
   338   | FreezeT
   339 (*for the simplifier*)
   340   | RewriteC            of cterm
   341   | CongC               of cterm
   342   | Rewrite_cterm       of cterm
   343 (*Logical identities, recorded since they are part of the proof process*)
   344   | Rename_params_rule  of string list * int;
   345 
   346 
   347 type deriv = rule mtree;
   348 
   349 datatype deriv_kind = MinDeriv | ThmDeriv | FullDeriv;
   350 
   351 val keep_derivs = ref MinDeriv;
   352 
   353 
   354 (*Build a minimal derivation.  Keep oracles; suppress atomic inferences;
   355   retain Theorems or their underlying links; keep anything else*)
   356 fun squash_derivs [] = []
   357   | squash_derivs (der::ders) =
   358      (case der of
   359           Join (Oracle _, _) => der :: squash_derivs ders
   360         | Join (Theorem _, [der']) => if !keep_derivs=ThmDeriv 
   361                                       then der :: squash_derivs ders
   362                                       else squash_derivs (der'::ders)
   363         | Join (Axiom _, _) => if !keep_derivs=ThmDeriv 
   364                                then der :: squash_derivs ders
   365                                else squash_derivs ders
   366         | Join (_, [])      => squash_derivs ders
   367         | _                 => der :: squash_derivs ders);
   368 
   369 
   370 (*Ensure sharing of the most likely derivation, the empty one!*)
   371 val min_infer = Join (MinProof, []);
   372 
   373 (*Make a minimal inference*)
   374 fun make_min_infer []    = min_infer
   375   | make_min_infer [der] = der
   376   | make_min_infer ders  = Join (MinProof, ders);
   377 
   378 fun infer_derivs (rl, [])   = Join (rl, [])
   379   | infer_derivs (rl, ders) =
   380     if !keep_derivs=FullDeriv then Join (rl, ders)
   381     else make_min_infer (squash_derivs ders);
   382 
   383 
   384 
   385 (*** Meta theorems ***)
   386 
   387 datatype thm = Thm of
   388   {sign: Sign.sg,               (*signature for hyps and prop*)
   389    der: deriv,                  (*derivation*)
   390    maxidx: int,                 (*maximum index of any Var or TVar*)
   391    shyps: sort list,            (*sort hypotheses*)
   392    hyps: term list,             (*hypotheses*)
   393    prop: term};                 (*conclusion*)
   394 
   395 fun rep_thm (Thm args) = args;
   396 
   397 (*Version of rep_thm returning cterms instead of terms*)
   398 fun crep_thm (Thm {sign, der, maxidx, shyps, hyps, prop}) =
   399   let fun ctermf max t = Cterm{sign=sign, t=t, T=propT, maxidx=max};
   400   in {sign=sign, der=der, maxidx=maxidx, shyps=shyps,
   401       hyps = map (ctermf ~1) hyps,
   402       prop = ctermf maxidx prop}
   403   end;
   404 
   405 (*errors involving theorems*)
   406 exception THM of string * int * thm list;
   407 
   408 
   409 val stamps_of_thm = #stamps o Sign.rep_sg o #sign o rep_thm;
   410 
   411 (*merge signatures of two theorems; raise exception if incompatible*)
   412 fun merge_thm_sgs (th1, th2) =
   413   Sign.merge (pairself (#sign o rep_thm) (th1, th2))
   414     handle TERM (msg, _) => raise THM (msg, 0, [th1, th2]);
   415 
   416 
   417 (*maps object-rule to tpairs*)
   418 fun tpairs_of (Thm {prop, ...}) = #1 (Logic.strip_flexpairs prop);
   419 
   420 (*maps object-rule to premises*)
   421 fun prems_of (Thm {prop, ...}) =
   422   Logic.strip_imp_prems (Logic.skip_flexpairs prop);
   423 
   424 (*counts premises in a rule*)
   425 fun nprems_of (Thm {prop, ...}) =
   426   Logic.count_prems (Logic.skip_flexpairs prop, 0);
   427 
   428 (*maps object-rule to conclusion*)
   429 fun concl_of (Thm {prop, ...}) = Logic.strip_imp_concl prop;
   430 
   431 (*the statement of any thm is a cterm*)
   432 fun cprop_of (Thm {sign, maxidx, prop, ...}) =
   433   Cterm {sign = sign, maxidx = maxidx, T = propT, t = prop};
   434 
   435 
   436 
   437 (** sort contexts of theorems **)
   438 
   439 (* basic utils *)
   440 
   441 (*accumulate sorts suppressing duplicates; these are coded low levelly
   442   to improve efficiency a bit*)
   443 
   444 fun add_typ_sorts (Type (_, Ts), Ss) = add_typs_sorts (Ts, Ss)
   445   | add_typ_sorts (TFree (_, S), Ss) = ins_sort(S,Ss)
   446   | add_typ_sorts (TVar (_, S), Ss) = ins_sort(S,Ss)
   447 and add_typs_sorts ([], Ss) = Ss
   448   | add_typs_sorts (T :: Ts, Ss) = add_typs_sorts (Ts, add_typ_sorts (T, Ss));
   449 
   450 fun add_term_sorts (Const (_, T), Ss) = add_typ_sorts (T, Ss)
   451   | add_term_sorts (Free (_, T), Ss) = add_typ_sorts (T, Ss)
   452   | add_term_sorts (Var (_, T), Ss) = add_typ_sorts (T, Ss)
   453   | add_term_sorts (Bound _, Ss) = Ss
   454   | add_term_sorts (Abs (_,T,t), Ss) = add_term_sorts (t, add_typ_sorts (T,Ss))
   455   | add_term_sorts (t $ u, Ss) = add_term_sorts (t, add_term_sorts (u, Ss));
   456 
   457 fun add_terms_sorts ([], Ss) = Ss
   458   | add_terms_sorts (t::ts, Ss) = add_terms_sorts (ts, add_term_sorts (t,Ss));
   459 
   460 fun env_codT (Envir.Envir {iTs, ...}) = map snd iTs;
   461 
   462 fun add_env_sorts (env, Ss) =
   463   add_terms_sorts (map snd (Envir.alist_of env),
   464     add_typs_sorts (env_codT env, Ss));
   465 
   466 fun add_thm_sorts (Thm {hyps, prop, ...}, Ss) =
   467   add_terms_sorts (hyps, add_term_sorts (prop, Ss));
   468 
   469 fun add_thms_shyps ([], Ss) = Ss
   470   | add_thms_shyps (Thm {shyps, ...} :: ths, Ss) =
   471       add_thms_shyps (ths, union_sort(shyps,Ss));
   472 
   473 
   474 (*get 'dangling' sort constraints of a thm*)
   475 fun extra_shyps (th as Thm {shyps, ...}) =
   476   shyps \\ add_thm_sorts (th, []);
   477 
   478 
   479 (* fix_shyps *)
   480 
   481 (*preserve sort contexts of rule premises and substituted types*)
   482 fun fix_shyps thms Ts thm =
   483   let
   484     val Thm {sign, der, maxidx, hyps, prop, ...} = thm;
   485     val shyps =
   486       add_thm_sorts (thm, add_typs_sorts (Ts, add_thms_shyps (thms, [])));
   487   in
   488     Thm {sign = sign, 
   489          der = der,             (*No new derivation, as other rules call this*)
   490          maxidx = maxidx,
   491          shyps = shyps, hyps = hyps, prop = prop}
   492   end;
   493 
   494 
   495 (* strip_shyps *)       (* FIXME improve? (e.g. only minimal extra sorts) *)
   496 
   497 val force_strip_shyps = ref true;  (* FIXME tmp (since 1995/08/01) *)
   498 
   499 (*remove extra sorts that are known to be syntactically non-empty*)
   500 fun strip_shyps thm =
   501   let
   502     val Thm {sign, der, maxidx, shyps, hyps, prop} = thm;
   503     val sorts = add_thm_sorts (thm, []);
   504     val maybe_empty = not o Sign.nonempty_sort sign sorts;
   505     val shyps' = filter (fn S => mem_sort(S,sorts) orelse maybe_empty S) shyps;
   506   in
   507     Thm {sign = sign, der = der, maxidx = maxidx,
   508          shyps =
   509          (if eq_set_sort (shyps',sorts) orelse 
   510              not (!force_strip_shyps) then shyps'
   511           else    (* FIXME tmp (since 1995/08/01) *)
   512               (warning ("Removed sort hypotheses: " ^
   513                         commas (map Sorts.str_of_sort (shyps' \\ sorts)));
   514                warning "Let's hope these sorts are non-empty!";
   515            sorts)),
   516       hyps = hyps, 
   517       prop = prop}
   518   end;
   519 
   520 
   521 (* implies_intr_shyps *)
   522 
   523 (*discharge all extra sort hypotheses*)
   524 fun implies_intr_shyps thm =
   525   (case extra_shyps thm of
   526     [] => thm
   527   | xshyps =>
   528       let
   529         val Thm {sign, der, maxidx, shyps, hyps, prop} = thm;
   530         val shyps' = ins_sort (logicS, shyps \\ xshyps);
   531         val used_names = foldr add_term_tfree_names (prop :: hyps, []);
   532         val names =
   533           tl (variantlist (replicate (length xshyps + 1) "'", used_names));
   534         val tfrees = map (TFree o rpair logicS) names;
   535 
   536         fun mk_insort (T, S) = map (Logic.mk_inclass o pair T) S;
   537         val sort_hyps = List.concat (map2 mk_insort (tfrees, xshyps));
   538       in
   539         Thm {sign = sign, 
   540              der = infer_derivs (Implies_intr_shyps, [der]), 
   541              maxidx = maxidx, 
   542              shyps = shyps',
   543              hyps = hyps, 
   544              prop = Logic.list_implies (sort_hyps, prop)}
   545       end);
   546 
   547 
   548 (** Axioms **)
   549 
   550 (*look up the named axiom in the theory*)
   551 fun get_axiom theory raw_name =
   552   let
   553     val name = Sign.intern (sign_of theory) Theory.thmK raw_name;
   554     fun get_ax [] = raise Match
   555       | get_ax (thy :: thys) =
   556           let val {sign, new_axioms, parents, ...} = rep_theory thy
   557           in case Symtab.lookup (new_axioms, name) of
   558                 Some t => fix_shyps [] []
   559                            (Thm {sign = sign, 
   560                                  der = infer_derivs (Axiom(theory,name), []),
   561                                  maxidx = maxidx_of_term t,
   562                                  shyps = [], 
   563                                  hyps = [], 
   564                                  prop = t})
   565               | None => get_ax parents handle Match => get_ax thys
   566           end;
   567   in
   568     get_ax [theory] handle Match
   569       => raise THEORY ("get_axiom: no axiom " ^ quote name, [theory])
   570   end;
   571 
   572 
   573 (*return additional axioms of this theory node*)
   574 fun axioms_of thy =
   575   map (fn (s, _) => (s, get_axiom thy s))
   576     (Symtab.dest (#new_axioms (rep_theory thy)));
   577 
   578 (*Attach a label to a theorem to make proof objects more readable*)
   579 fun name_thm (name, th as Thm {sign, der, maxidx, shyps, hyps, prop}) = 
   580     Thm {sign = sign, 
   581          der = Join (Theorem name, [der]),
   582          maxidx = maxidx,
   583          shyps = shyps, 
   584          hyps = hyps, 
   585          prop = prop};
   586 
   587 
   588 (*Compression of theorems -- a separate rule, not integrated with the others,
   589   as it could be slow.*)
   590 fun compress (Thm {sign, der, maxidx, shyps, hyps, prop}) = 
   591     Thm {sign = sign, 
   592          der = der,     (*No derivation recorded!*)
   593          maxidx = maxidx,
   594          shyps = shyps, 
   595          hyps = map Term.compress_term hyps, 
   596          prop = Term.compress_term prop};
   597 
   598 
   599 
   600 (*** Meta rules ***)
   601 
   602 (*Check that term does not contain same var with different typing/sorting.
   603   If this check must be made, recalculate maxidx in hope of preventing its
   604   recurrence.*)
   605 fun nodup_Vars (thm as Thm{sign, der, maxidx, shyps, hyps, prop}) s =
   606   (Sign.nodup_Vars prop; 
   607    Thm {sign = sign, 
   608          der = der,     
   609          maxidx = maxidx_of_term prop,
   610          shyps = shyps, 
   611          hyps = hyps, 
   612          prop = prop})
   613   handle TYPE(msg,Ts,ts) => raise TYPE(s^": "^msg,Ts,ts);
   614 
   615 (** 'primitive' rules **)
   616 
   617 (*discharge all assumptions t from ts*)
   618 val disch = gen_rem (op aconv);
   619 
   620 (*The assumption rule A|-A in a theory*)
   621 fun assume ct : thm =
   622   let val {sign, t=prop, T, maxidx} = rep_cterm ct
   623   in  if T<>propT then
   624         raise THM("assume: assumptions must have type prop", 0, [])
   625       else if maxidx <> ~1 then
   626         raise THM("assume: assumptions may not contain scheme variables",
   627                   maxidx, [])
   628       else Thm{sign   = sign, 
   629                der    = infer_derivs (Assume ct, []), 
   630                maxidx = ~1, 
   631                shyps  = add_term_sorts(prop,[]), 
   632                hyps   = [prop], 
   633                prop   = prop}
   634   end;
   635 
   636 (*Implication introduction
   637     [A]
   638      :
   639      B
   640   -------
   641   A ==> B
   642 *)
   643 fun implies_intr cA (thB as Thm{sign,der,maxidx,hyps,prop,...}) : thm =
   644   let val {sign=signA, t=A, T, maxidx=maxidxA} = rep_cterm cA
   645   in  if T<>propT then
   646         raise THM("implies_intr: assumptions must have type prop", 0, [thB])
   647       else fix_shyps [thB] []
   648         (Thm{sign = Sign.merge (sign,signA),  
   649              der = infer_derivs (Implies_intr cA, [der]),
   650              maxidx = Int.max(maxidxA, maxidx),
   651              shyps = [],
   652              hyps = disch(hyps,A),
   653              prop = implies$A$prop})
   654       handle TERM _ =>
   655         raise THM("implies_intr: incompatible signatures", 0, [thB])
   656   end;
   657 
   658 
   659 (*Implication elimination
   660   A ==> B    A
   661   ------------
   662         B
   663 *)
   664 fun implies_elim thAB thA : thm =
   665     let val Thm{maxidx=maxA, der=derA, hyps=hypsA, prop=propA,...} = thA
   666         and Thm{sign, der, maxidx, hyps, prop,...} = thAB;
   667         fun err(a) = raise THM("implies_elim: "^a, 0, [thAB,thA])
   668     in  case prop of
   669             imp$A$B =>
   670                 if imp=implies andalso  A aconv propA
   671                 then fix_shyps [thAB, thA] []
   672                        (Thm{sign= merge_thm_sgs(thAB,thA),
   673                             der = infer_derivs (Implies_elim, [der,derA]),
   674                             maxidx = Int.max(maxA,maxidx),
   675                             shyps = [],
   676                             hyps = union_term(hypsA,hyps),  (*dups suppressed*)
   677                             prop = B})
   678                 else err("major premise")
   679           | _ => err("major premise")
   680     end;
   681 
   682 (*Forall introduction.  The Free or Var x must not be free in the hypotheses.
   683     A
   684   -----
   685   !!x.A
   686 *)
   687 fun forall_intr cx (th as Thm{sign,der,maxidx,hyps,prop,...}) =
   688   let val x = term_of cx;
   689       fun result(a,T) = fix_shyps [th] []
   690         (Thm{sign = sign, 
   691              der = infer_derivs (Forall_intr cx, [der]),
   692              maxidx = maxidx,
   693              shyps = [],
   694              hyps = hyps,
   695              prop = all(T) $ Abs(a, T, abstract_over (x,prop))})
   696   in  case x of
   697         Free(a,T) =>
   698           if exists (apl(x, Logic.occs)) hyps
   699           then  raise THM("forall_intr: variable free in assumptions", 0, [th])
   700           else  result(a,T)
   701       | Var((a,_),T) => result(a,T)
   702       | _ => raise THM("forall_intr: not a variable", 0, [th])
   703   end;
   704 
   705 (*Forall elimination
   706   !!x.A
   707   ------
   708   A[t/x]
   709 *)
   710 fun forall_elim ct (th as Thm{sign,der,maxidx,hyps,prop,...}) : thm =
   711   let val {sign=signt, t, T, maxidx=maxt} = rep_cterm ct
   712   in  case prop of
   713         Const("all",Type("fun",[Type("fun",[qary,_]),_])) $ A =>
   714           if T<>qary then
   715               raise THM("forall_elim: type mismatch", 0, [th])
   716           else let val thm = fix_shyps [th] []
   717                     (Thm{sign= Sign.merge(sign,signt),
   718                          der = infer_derivs (Forall_elim ct, [der]),
   719                          maxidx = Int.max(maxidx, maxt),
   720                          shyps = [],
   721                          hyps = hyps,  
   722                          prop = betapply(A,t)})
   723                in if maxt >= 0 andalso maxidx >= 0
   724                   then nodup_Vars thm "forall_elim" 
   725                   else thm (*no new Vars: no expensive check!*)
   726                end
   727       | _ => raise THM("forall_elim: not quantified", 0, [th])
   728   end
   729   handle TERM _ =>
   730          raise THM("forall_elim: incompatible signatures", 0, [th]);
   731 
   732 
   733 (* Equality *)
   734 
   735 (* Definition of the relation =?= *)
   736 val flexpair_def = fix_shyps [] []
   737   (Thm{sign= Sign.proto_pure, 
   738        der = Join(Axiom(pure_thy, "flexpair_def"), []),
   739        shyps = [], 
   740        hyps = [], 
   741        maxidx = 0,
   742        prop = term_of (read_cterm Sign.proto_pure
   743                        ("(?t =?= ?u) == (?t == ?u::?'a::{})", propT))});
   744 
   745 (*The reflexivity rule: maps  t   to the theorem   t==t   *)
   746 fun reflexive ct =
   747   let val {sign, t, T, maxidx} = rep_cterm ct
   748   in  fix_shyps [] []
   749        (Thm{sign= sign, 
   750             der = infer_derivs (Reflexive ct, []),
   751             shyps = [],
   752             hyps = [], 
   753             maxidx = maxidx,
   754             prop = Logic.mk_equals(t,t)})
   755   end;
   756 
   757 (*The symmetry rule
   758   t==u
   759   ----
   760   u==t
   761 *)
   762 fun symmetric (th as Thm{sign,der,maxidx,shyps,hyps,prop}) =
   763   case prop of
   764       (eq as Const("==",_)) $ t $ u =>
   765         (*no fix_shyps*)
   766           Thm{sign = sign,
   767               der = infer_derivs (Symmetric, [der]),
   768               maxidx = maxidx,
   769               shyps = shyps,
   770               hyps = hyps,
   771               prop = eq$u$t}
   772     | _ => raise THM("symmetric", 0, [th]);
   773 
   774 (*The transitive rule
   775   t1==u    u==t2
   776   --------------
   777       t1==t2
   778 *)
   779 fun transitive th1 th2 =
   780   let val Thm{der=der1, maxidx=max1, hyps=hyps1, prop=prop1,...} = th1
   781       and Thm{der=der2, maxidx=max2, hyps=hyps2, prop=prop2,...} = th2;
   782       fun err(msg) = raise THM("transitive: "^msg, 0, [th1,th2])
   783   in case (prop1,prop2) of
   784        ((eq as Const("==",_)) $ t1 $ u, Const("==",_) $ u' $ t2) =>
   785           if not (u aconv u') then err"middle term"
   786           else let val thm =      
   787               fix_shyps [th1, th2] []
   788                 (Thm{sign= merge_thm_sgs(th1,th2), 
   789                      der = infer_derivs (Transitive, [der1, der2]),
   790                      maxidx = Int.max(max1,max2), 
   791                      shyps = [],
   792                      hyps = union_term(hyps1,hyps2),
   793                      prop = eq$t1$t2})
   794                  in if max1 >= 0 andalso max2 >= 0
   795                     then nodup_Vars thm "transitive" 
   796                     else thm (*no new Vars: no expensive check!*)
   797                  end
   798      | _ =>  err"premises"
   799   end;
   800 
   801 (*Beta-conversion: maps (%x.t)(u) to the theorem (%x.t)(u) == t[u/x] *)
   802 fun beta_conversion ct =
   803   let val {sign, t, T, maxidx} = rep_cterm ct
   804   in  case t of
   805           Abs(_,_,bodt) $ u => fix_shyps [] []
   806             (Thm{sign = sign,  
   807                  der = infer_derivs (Beta_conversion ct, []),
   808                  maxidx = maxidx,
   809                  shyps = [],
   810                  hyps = [],
   811                  prop = Logic.mk_equals(t, subst_bound (u,bodt))})
   812         | _ =>  raise THM("beta_conversion: not a redex", 0, [])
   813   end;
   814 
   815 (*The extensionality rule   (proviso: x not free in f, g, or hypotheses)
   816   f(x) == g(x)
   817   ------------
   818      f == g
   819 *)
   820 fun extensional (th as Thm{sign, der, maxidx,shyps,hyps,prop}) =
   821   case prop of
   822     (Const("==",_)) $ (f$x) $ (g$y) =>
   823       let fun err(msg) = raise THM("extensional: "^msg, 0, [th])
   824       in (if x<>y then err"different variables" else
   825           case y of
   826                 Free _ =>
   827                   if exists (apl(y, Logic.occs)) (f::g::hyps)
   828                   then err"variable free in hyps or functions"    else  ()
   829               | Var _ =>
   830                   if Logic.occs(y,f)  orelse  Logic.occs(y,g)
   831                   then err"variable free in functions"   else  ()
   832               | _ => err"not a variable");
   833           (*no fix_shyps*)
   834           Thm{sign = sign,
   835               der = infer_derivs (Extensional, [der]),
   836               maxidx = maxidx,
   837               shyps = shyps,
   838               hyps = hyps, 
   839               prop = Logic.mk_equals(f,g)}
   840       end
   841  | _ =>  raise THM("extensional: premise", 0, [th]);
   842 
   843 (*The abstraction rule.  The Free or Var x must not be free in the hypotheses.
   844   The bound variable will be named "a" (since x will be something like x320)
   845      t == u
   846   ------------
   847   %x.t == %x.u
   848 *)
   849 fun abstract_rule a cx (th as Thm{sign,der,maxidx,hyps,prop,...}) =
   850   let val x = term_of cx;
   851       val (t,u) = Logic.dest_equals prop
   852             handle TERM _ =>
   853                 raise THM("abstract_rule: premise not an equality", 0, [th])
   854       fun result T = fix_shyps [th] []
   855           (Thm{sign = sign,
   856                der = infer_derivs (Abstract_rule (a,cx), [der]),
   857                maxidx = maxidx, 
   858                shyps = [], 
   859                hyps = hyps,
   860                prop = Logic.mk_equals(Abs(a, T, abstract_over (x,t)),
   861                                       Abs(a, T, abstract_over (x,u)))})
   862   in  case x of
   863         Free(_,T) =>
   864          if exists (apl(x, Logic.occs)) hyps
   865          then raise THM("abstract_rule: variable free in assumptions", 0, [th])
   866          else result T
   867       | Var(_,T) => result T
   868       | _ => raise THM("abstract_rule: not a variable", 0, [th])
   869   end;
   870 
   871 (*The combination rule
   872   f == g  t == u
   873   --------------
   874    f(t) == g(u)
   875 *)
   876 fun combination th1 th2 =
   877   let val Thm{der=der1, maxidx=max1, shyps=shyps1, hyps=hyps1, 
   878               prop=prop1,...} = th1
   879       and Thm{der=der2, maxidx=max2, shyps=shyps2, hyps=hyps2, 
   880               prop=prop2,...} = th2
   881       fun chktypes (f,t) =
   882             (case fastype_of f of
   883                 Type("fun",[T1,T2]) => 
   884                     if T1 <> fastype_of t then
   885                          raise THM("combination: types", 0, [th1,th2])
   886                     else ()
   887                 | _ => raise THM("combination: not function type", 0, 
   888                                  [th1,th2]))
   889   in case (prop1,prop2)  of
   890        (Const("==",_) $ f $ g, Const("==",_) $ t $ u) =>
   891           let val _   = chktypes (f,t)
   892               val thm = (*no fix_shyps*)
   893                         Thm{sign = merge_thm_sgs(th1,th2), 
   894                             der = infer_derivs (Combination, [der1, der2]),
   895                             maxidx = Int.max(max1,max2), 
   896                             shyps = union_sort(shyps1,shyps2),
   897                             hyps = union_term(hyps1,hyps2),
   898                             prop = Logic.mk_equals(f$t, g$u)}
   899           in if max1 >= 0 andalso max2 >= 0
   900              then nodup_Vars thm "combination" 
   901              else thm (*no new Vars: no expensive check!*)  
   902           end
   903      | _ =>  raise THM("combination: premises", 0, [th1,th2])
   904   end;
   905 
   906 
   907 (* Equality introduction
   908   A ==> B  B ==> A
   909   ----------------
   910        A == B
   911 *)
   912 fun equal_intr th1 th2 =
   913   let val Thm{der=der1,maxidx=max1, shyps=shyps1, hyps=hyps1, 
   914               prop=prop1,...} = th1
   915       and Thm{der=der2, maxidx=max2, shyps=shyps2, hyps=hyps2, 
   916               prop=prop2,...} = th2;
   917       fun err(msg) = raise THM("equal_intr: "^msg, 0, [th1,th2])
   918   in case (prop1,prop2) of
   919        (Const("==>",_) $ A $ B, Const("==>",_) $ B' $ A')  =>
   920           if A aconv A' andalso B aconv B'
   921           then
   922             (*no fix_shyps*)
   923               Thm{sign = merge_thm_sgs(th1,th2),
   924                   der = infer_derivs (Equal_intr, [der1, der2]),
   925                   maxidx = Int.max(max1,max2),
   926                   shyps = union_sort(shyps1,shyps2),
   927                   hyps = union_term(hyps1,hyps2),
   928                   prop = Logic.mk_equals(A,B)}
   929           else err"not equal"
   930      | _ =>  err"premises"
   931   end;
   932 
   933 
   934 (*The equal propositions rule
   935   A == B  A
   936   ---------
   937       B
   938 *)
   939 fun equal_elim th1 th2 =
   940   let val Thm{der=der1, maxidx=max1, hyps=hyps1, prop=prop1,...} = th1
   941       and Thm{der=der2, maxidx=max2, hyps=hyps2, prop=prop2,...} = th2;
   942       fun err(msg) = raise THM("equal_elim: "^msg, 0, [th1,th2])
   943   in  case prop1  of
   944        Const("==",_) $ A $ B =>
   945           if not (prop2 aconv A) then err"not equal"  else
   946             fix_shyps [th1, th2] []
   947               (Thm{sign= merge_thm_sgs(th1,th2), 
   948                    der = infer_derivs (Equal_elim, [der1, der2]),
   949                    maxidx = Int.max(max1,max2),
   950                    shyps = [],
   951                    hyps = union_term(hyps1,hyps2),
   952                    prop = B})
   953      | _ =>  err"major premise"
   954   end;
   955 
   956 
   957 
   958 (**** Derived rules ****)
   959 
   960 (*Discharge all hypotheses.  Need not verify cterms or call fix_shyps.
   961   Repeated hypotheses are discharged only once;  fold cannot do this*)
   962 fun implies_intr_hyps (Thm{sign, der, maxidx, shyps, hyps=A::As, prop}) =
   963       implies_intr_hyps (*no fix_shyps*)
   964             (Thm{sign = sign, 
   965                  der = infer_derivs (Implies_intr_hyps, [der]), 
   966                  maxidx = maxidx, 
   967                  shyps = shyps,
   968                  hyps = disch(As,A),  
   969                  prop = implies$A$prop})
   970   | implies_intr_hyps th = th;
   971 
   972 (*Smash" unifies the list of term pairs leaving no flex-flex pairs.
   973   Instantiates the theorem and deletes trivial tpairs.
   974   Resulting sequence may contain multiple elements if the tpairs are
   975     not all flex-flex. *)
   976 fun flexflex_rule (th as Thm{sign, der, maxidx, hyps, prop,...}) =
   977   let fun newthm env =
   978           if Envir.is_empty env then th
   979           else
   980           let val (tpairs,horn) =
   981                         Logic.strip_flexpairs (Envir.norm_term env prop)
   982                 (*Remove trivial tpairs, of the form t=t*)
   983               val distpairs = filter (not o op aconv) tpairs
   984               val newprop = Logic.list_flexpairs(distpairs, horn)
   985           in  fix_shyps [th] (env_codT env)
   986                 (Thm{sign = sign, 
   987                      der = infer_derivs (Flexflex_rule env, [der]), 
   988                      maxidx = maxidx_of_term newprop, 
   989                      shyps = [], 
   990                      hyps = hyps,
   991                      prop = newprop})
   992           end;
   993       val (tpairs,_) = Logic.strip_flexpairs prop
   994   in Sequence.maps newthm
   995             (Unify.smash_unifiers(sign, Envir.empty maxidx, tpairs))
   996   end;
   997 
   998 (*Instantiation of Vars
   999            A
  1000   -------------------
  1001   A[t1/v1,....,tn/vn]
  1002 *)
  1003 
  1004 (*Check that all the terms are Vars and are distinct*)
  1005 fun instl_ok ts = forall is_Var ts andalso null(findrep ts);
  1006 
  1007 (*For instantiate: process pair of cterms, merge theories*)
  1008 fun add_ctpair ((ct,cu), (sign,tpairs)) =
  1009   let val {sign=signt, t=t, T= T, ...} = rep_cterm ct
  1010       and {sign=signu, t=u, T= U, ...} = rep_cterm cu
  1011   in  if T=U  then (Sign.merge(sign, Sign.merge(signt, signu)), (t,u)::tpairs)
  1012       else raise TYPE("add_ctpair", [T,U], [t,u])
  1013   end;
  1014 
  1015 fun add_ctyp ((v,ctyp), (sign',vTs)) =
  1016   let val {T,sign} = rep_ctyp ctyp
  1017   in (Sign.merge(sign,sign'), (v,T)::vTs) end;
  1018 
  1019 (*Left-to-right replacements: ctpairs = [...,(vi,ti),...].
  1020   Instantiates distinct Vars by terms of same type.
  1021   Normalizes the new theorem! *)
  1022 fun instantiate ([], []) th = th
  1023   | instantiate (vcTs,ctpairs)  (th as Thm{sign,der,maxidx,hyps,prop,...}) =
  1024   let val (newsign,tpairs) = foldr add_ctpair (ctpairs, (sign,[]));
  1025       val (newsign,vTs) = foldr add_ctyp (vcTs, (newsign,[]));
  1026       val newprop =
  1027             Envir.norm_term (Envir.empty 0)
  1028               (subst_atomic tpairs
  1029                (Type.inst_term_tvars(#tsig(Sign.rep_sg newsign),vTs) prop))
  1030       val newth =
  1031             fix_shyps [th] (map snd vTs)
  1032               (Thm{sign = newsign, 
  1033                    der = infer_derivs (Instantiate(vcTs,ctpairs), [der]), 
  1034                    maxidx = maxidx_of_term newprop, 
  1035                    shyps = [],
  1036                    hyps = hyps,
  1037                    prop = newprop})
  1038   in  if not(instl_ok(map #1 tpairs))
  1039       then raise THM("instantiate: variables not distinct", 0, [th])
  1040       else if not(null(findrep(map #1 vTs)))
  1041       then raise THM("instantiate: type variables not distinct", 0, [th])
  1042       else nodup_Vars newth "instantiate"
  1043   end
  1044   handle TERM _ =>
  1045            raise THM("instantiate: incompatible signatures",0,[th])
  1046        | TYPE (msg,_,_) => raise THM("instantiate: type conflict: " ^ msg, 
  1047 				     0, [th]);
  1048 
  1049 (*The trivial implication A==>A, justified by assume and forall rules.
  1050   A can contain Vars, not so for assume!   *)
  1051 fun trivial ct : thm =
  1052   let val {sign, t=A, T, maxidx} = rep_cterm ct
  1053   in  if T<>propT then
  1054             raise THM("trivial: the term must have type prop", 0, [])
  1055       else fix_shyps [] []
  1056         (Thm{sign = sign, 
  1057              der = infer_derivs (Trivial ct, []), 
  1058              maxidx = maxidx, 
  1059              shyps = [], 
  1060              hyps = [],
  1061              prop = implies$A$A})
  1062   end;
  1063 
  1064 (*Axiom-scheme reflecting signature contents: "OFCLASS(?'a::c, c_class)" *)
  1065 fun class_triv thy c =
  1066   let val sign = sign_of thy;
  1067       val Cterm {t, maxidx, ...} =
  1068           cterm_of sign (Logic.mk_inclass (TVar (("'a", 0), [c]), c))
  1069             handle TERM (msg, _) => raise THM ("class_triv: " ^ msg, 0, []);
  1070   in
  1071     fix_shyps [] []
  1072       (Thm {sign = sign, 
  1073             der = infer_derivs (Class_triv(thy,c), []), 
  1074             maxidx = maxidx, 
  1075             shyps = [], 
  1076             hyps = [], 
  1077             prop = t})
  1078   end;
  1079 
  1080 
  1081 (* Replace all TFrees not in the hyps by new TVars *)
  1082 fun varifyT(Thm{sign,der,maxidx,shyps,hyps,prop}) =
  1083   let val tfrees = foldr add_term_tfree_names (hyps,[])
  1084   in let val thm = (*no fix_shyps*)
  1085     Thm{sign = sign, 
  1086         der = infer_derivs (VarifyT, [der]), 
  1087         maxidx = Int.max(0,maxidx), 
  1088         shyps = shyps, 
  1089         hyps = hyps,
  1090         prop = Type.varify(prop,tfrees)}
  1091      in nodup_Vars thm "varifyT" end
  1092 (* this nodup_Vars check can be removed if thms are guaranteed not to contain
  1093 duplicate TVars with differnt sorts *)
  1094   end;
  1095 
  1096 (* Replace all TVars by new TFrees *)
  1097 fun freezeT(Thm{sign,der,maxidx,shyps,hyps,prop}) =
  1098   let val (prop',_) = Type.freeze_thaw prop
  1099   in (*no fix_shyps*)
  1100     Thm{sign = sign, 
  1101         der = infer_derivs (FreezeT, [der]),
  1102         maxidx = maxidx_of_term prop',
  1103         shyps = shyps,
  1104         hyps = hyps,
  1105         prop = prop'}
  1106   end;
  1107 
  1108 
  1109 (*** Inference rules for tactics ***)
  1110 
  1111 (*Destruct proof state into constraints, other goals, goal(i), rest *)
  1112 fun dest_state (state as Thm{prop,...}, i) =
  1113   let val (tpairs,horn) = Logic.strip_flexpairs prop
  1114   in  case  Logic.strip_prems(i, [], horn) of
  1115           (B::rBs, C) => (tpairs, rev rBs, B, C)
  1116         | _ => raise THM("dest_state", i, [state])
  1117   end
  1118   handle TERM _ => raise THM("dest_state", i, [state]);
  1119 
  1120 (*Increment variables and parameters of orule as required for
  1121   resolution with goal i of state. *)
  1122 fun lift_rule (state, i) orule =
  1123   let val Thm{shyps=sshyps, prop=sprop, maxidx=smax, sign=ssign,...} = state
  1124       val (Bi::_, _) = Logic.strip_prems(i, [], Logic.skip_flexpairs sprop)
  1125         handle TERM _ => raise THM("lift_rule", i, [orule,state])
  1126       val ct_Bi = Cterm {sign=ssign, maxidx=smax, T=propT, t=Bi}
  1127       val (lift_abs,lift_all) = Logic.lift_fns(Bi,smax+1)
  1128       val (Thm{sign, der, maxidx,shyps,hyps,prop}) = orule
  1129       val (tpairs,As,B) = Logic.strip_horn prop
  1130   in  (*no fix_shyps*)
  1131       Thm{sign = merge_thm_sgs(state,orule),
  1132           der = infer_derivs (Lift_rule(ct_Bi, i), [der]),
  1133           maxidx = maxidx+smax+1,
  1134           shyps=union_sort(sshyps,shyps), 
  1135           hyps=hyps, 
  1136           prop = Logic.rule_of (map (pairself lift_abs) tpairs,
  1137                                 map lift_all As,    
  1138                                 lift_all B)}
  1139   end;
  1140 
  1141 (*Solve subgoal Bi of proof state B1...Bn/C by assumption. *)
  1142 fun assumption i state =
  1143   let val Thm{sign,der,maxidx,hyps,prop,...} = state;
  1144       val (tpairs, Bs, Bi, C) = dest_state(state,i)
  1145       fun newth (env as Envir.Envir{maxidx, ...}, tpairs) =
  1146         fix_shyps [state] (env_codT env)
  1147           (Thm{sign = sign, 
  1148                der = infer_derivs (Assumption (i, Some env), [der]),
  1149                maxidx = maxidx,
  1150                shyps = [],
  1151                hyps = hyps,
  1152                prop = 
  1153                if Envir.is_empty env then (*avoid wasted normalizations*)
  1154                    Logic.rule_of (tpairs, Bs, C)
  1155                else (*normalize the new rule fully*)
  1156                    Envir.norm_term env (Logic.rule_of (tpairs, Bs, C))});
  1157       fun addprfs [] = Sequence.null
  1158         | addprfs ((t,u)::apairs) = Sequence.seqof (fn()=> Sequence.pull
  1159              (Sequence.mapp newth
  1160                 (Unify.unifiers(sign,Envir.empty maxidx, (t,u)::tpairs))
  1161                 (addprfs apairs)))
  1162   in  addprfs (Logic.assum_pairs Bi)  end;
  1163 
  1164 (*Solve subgoal Bi of proof state B1...Bn/C by assumption.
  1165   Checks if Bi's conclusion is alpha-convertible to one of its assumptions*)
  1166 fun eq_assumption i state =
  1167   let val Thm{sign,der,maxidx,hyps,prop,...} = state;
  1168       val (tpairs, Bs, Bi, C) = dest_state(state,i)
  1169   in  if exists (op aconv) (Logic.assum_pairs Bi)
  1170       then fix_shyps [state] []
  1171              (Thm{sign = sign, 
  1172                   der = infer_derivs (Assumption (i,None), [der]),
  1173                   maxidx = maxidx,
  1174                   shyps = [],
  1175                   hyps = hyps,
  1176                   prop = Logic.rule_of(tpairs, Bs, C)})
  1177       else  raise THM("eq_assumption", 0, [state])
  1178   end;
  1179 
  1180 
  1181 (*For rotate_tac: fast rotation of assumptions of subgoal i*)
  1182 fun rotate_rule k i state =
  1183   let val Thm{sign,der,maxidx,hyps,prop,shyps} = state;
  1184       val (tpairs, Bs, Bi, C) = dest_state(state,i)
  1185       val params = Logic.strip_params Bi
  1186       and asms   = Logic.strip_assums_hyp Bi
  1187       and concl  = Logic.strip_assums_concl Bi
  1188       val n      = length asms
  1189       fun rot m  = if 0=m orelse m=n then Bi
  1190 		   else if 0<m andalso m<n 
  1191 		   then list_all 
  1192 			   (params, 
  1193 			    Logic.list_implies(List.drop(asms, m) @ 
  1194 					       List.take(asms, m),
  1195 					       concl))
  1196 		   else raise THM("rotate_rule", m, [state])
  1197   in  Thm{sign = sign, 
  1198 	  der = infer_derivs (Rotate_rule (k,i), [der]),
  1199 	  maxidx = maxidx,
  1200 	  shyps = shyps,
  1201 	  hyps = hyps,
  1202 	  prop = Logic.rule_of(tpairs, Bs@[rot (if k<0 then n+k else k)], C)}
  1203   end;
  1204 
  1205 
  1206 (** User renaming of parameters in a subgoal **)
  1207 
  1208 (*Calls error rather than raising an exception because it is intended
  1209   for top-level use -- exception handling would not make sense here.
  1210   The names in cs, if distinct, are used for the innermost parameters;
  1211    preceding parameters may be renamed to make all params distinct.*)
  1212 fun rename_params_rule (cs, i) state =
  1213   let val Thm{sign,der,maxidx,hyps,...} = state
  1214       val (tpairs, Bs, Bi, C) = dest_state(state,i)
  1215       val iparams = map #1 (Logic.strip_params Bi)
  1216       val short = length iparams - length cs
  1217       val newnames =
  1218             if short<0 then error"More names than abstractions!"
  1219             else variantlist(take (short,iparams), cs) @ cs
  1220       val freenames = map (#1 o dest_Free) (term_frees Bi)
  1221       val newBi = Logic.list_rename_params (newnames, Bi)
  1222   in
  1223   case findrep cs of
  1224      c::_ => (warning ("Can't rename.  Bound variables not distinct: " ^ c); 
  1225 	      state)
  1226    | [] => (case cs inter_string freenames of
  1227        a::_ => (warning ("Can't rename.  Bound/Free variable clash: " ^ a); 
  1228 		state)
  1229      | [] => fix_shyps [state] []
  1230                 (Thm{sign = sign,
  1231                      der = infer_derivs (Rename_params_rule(cs,i), [der]),
  1232                      maxidx = maxidx,
  1233                      shyps = [],
  1234                      hyps = hyps,
  1235                      prop = Logic.rule_of(tpairs, Bs@[newBi], C)}))
  1236   end;
  1237 
  1238 (*** Preservation of bound variable names ***)
  1239 
  1240 (*Scan a pair of terms; while they are similar,
  1241   accumulate corresponding bound vars in "al"*)
  1242 fun match_bvs(Abs(x,_,s),Abs(y,_,t), al) =
  1243       match_bvs(s, t, if x="" orelse y="" then al
  1244                                           else (x,y)::al)
  1245   | match_bvs(f$s, g$t, al) = match_bvs(f,g,match_bvs(s,t,al))
  1246   | match_bvs(_,_,al) = al;
  1247 
  1248 (* strip abstractions created by parameters *)
  1249 fun match_bvars((s,t),al) = match_bvs(strip_abs_body s, strip_abs_body t, al);
  1250 
  1251 
  1252 (* strip_apply f A(,B) strips off all assumptions/parameters from A
  1253    introduced by lifting over B, and applies f to remaining part of A*)
  1254 fun strip_apply f =
  1255   let fun strip(Const("==>",_)$ A1 $ B1,
  1256                 Const("==>",_)$ _  $ B2) = implies $ A1 $ strip(B1,B2)
  1257         | strip((c as Const("all",_)) $ Abs(a,T,t1),
  1258                       Const("all",_)  $ Abs(_,_,t2)) = c$Abs(a,T,strip(t1,t2))
  1259         | strip(A,_) = f A
  1260   in strip end;
  1261 
  1262 (*Use the alist to rename all bound variables and some unknowns in a term
  1263   dpairs = current disagreement pairs;  tpairs = permanent ones (flexflex);
  1264   Preserves unknowns in tpairs and on lhs of dpairs. *)
  1265 fun rename_bvs([],_,_,_) = I
  1266   | rename_bvs(al,dpairs,tpairs,B) =
  1267     let val vars = foldr add_term_vars
  1268                         (map fst dpairs @ map fst tpairs @ map snd tpairs, [])
  1269         (*unknowns appearing elsewhere be preserved!*)
  1270         val vids = map (#1 o #1 o dest_Var) vars;
  1271         fun rename(t as Var((x,i),T)) =
  1272                 (case assoc(al,x) of
  1273                    Some(y) => if x mem_string vids orelse y mem_string vids then t
  1274                               else Var((y,i),T)
  1275                  | None=> t)
  1276           | rename(Abs(x,T,t)) =
  1277               Abs(case assoc_string(al,x) of Some(y) => y | None => x,
  1278                   T, rename t)
  1279           | rename(f$t) = rename f $ rename t
  1280           | rename(t) = t;
  1281         fun strip_ren Ai = strip_apply rename (Ai,B)
  1282     in strip_ren end;
  1283 
  1284 (*Function to rename bounds/unknowns in the argument, lifted over B*)
  1285 fun rename_bvars(dpairs, tpairs, B) =
  1286         rename_bvs(foldr match_bvars (dpairs,[]), dpairs, tpairs, B);
  1287 
  1288 
  1289 (*** RESOLUTION ***)
  1290 
  1291 (** Lifting optimizations **)
  1292 
  1293 (*strip off pairs of assumptions/parameters in parallel -- they are
  1294   identical because of lifting*)
  1295 fun strip_assums2 (Const("==>", _) $ _ $ B1,
  1296                    Const("==>", _) $ _ $ B2) = strip_assums2 (B1,B2)
  1297   | strip_assums2 (Const("all",_)$Abs(a,T,t1),
  1298                    Const("all",_)$Abs(_,_,t2)) =
  1299       let val (B1,B2) = strip_assums2 (t1,t2)
  1300       in  (Abs(a,T,B1), Abs(a,T,B2))  end
  1301   | strip_assums2 BB = BB;
  1302 
  1303 
  1304 (*Faster normalization: skip assumptions that were lifted over*)
  1305 fun norm_term_skip env 0 t = Envir.norm_term env t
  1306   | norm_term_skip env n (Const("all",_)$Abs(a,T,t)) =
  1307         let val Envir.Envir{iTs, ...} = env
  1308             val T' = typ_subst_TVars iTs T
  1309             (*Must instantiate types of parameters because they are flattened;
  1310               this could be a NEW parameter*)
  1311         in  all T' $ Abs(a, T', norm_term_skip env n t)  end
  1312   | norm_term_skip env n (Const("==>", _) $ A $ B) =
  1313         implies $ A $ norm_term_skip env (n-1) B
  1314   | norm_term_skip env n t = error"norm_term_skip: too few assumptions??";
  1315 
  1316 
  1317 (*Composition of object rule r=(A1...Am/B) with proof state s=(B1...Bn/C)
  1318   Unifies B with Bi, replacing subgoal i    (1 <= i <= n)
  1319   If match then forbid instantiations in proof state
  1320   If lifted then shorten the dpair using strip_assums2.
  1321   If eres_flg then simultaneously proves A1 by assumption.
  1322   nsubgoal is the number of new subgoals (written m above).
  1323   Curried so that resolution calls dest_state only once.
  1324 *)
  1325 local open Sequence; exception COMPOSE
  1326 in
  1327 fun bicompose_aux match (state, (stpairs, Bs, Bi, C), lifted)
  1328                         (eres_flg, orule, nsubgoal) =
  1329  let val Thm{der=sder, maxidx=smax, shyps=sshyps, hyps=shyps, ...} = state
  1330      and Thm{der=rder, maxidx=rmax, shyps=rshyps, hyps=rhyps, 
  1331              prop=rprop,...} = orule
  1332          (*How many hyps to skip over during normalization*)
  1333      and nlift = Logic.count_prems(strip_all_body Bi,
  1334                                    if eres_flg then ~1 else 0)
  1335      val sign = merge_thm_sgs(state,orule);
  1336      (** Add new theorem with prop = '[| Bs; As |] ==> C' to thq **)
  1337      fun addth As ((env as Envir.Envir {maxidx, ...}, tpairs), thq) =
  1338        let val normt = Envir.norm_term env;
  1339            (*perform minimal copying here by examining env*)
  1340            val normp =
  1341              if Envir.is_empty env then (tpairs, Bs @ As, C)
  1342              else
  1343              let val ntps = map (pairself normt) tpairs
  1344              in if Envir.above (smax, env) then
  1345                   (*no assignments in state; normalize the rule only*)
  1346                   if lifted
  1347                   then (ntps, Bs @ map (norm_term_skip env nlift) As, C)
  1348                   else (ntps, Bs @ map normt As, C)
  1349                 else if match then raise COMPOSE
  1350                 else (*normalize the new rule fully*)
  1351                   (ntps, map normt (Bs @ As), normt C)
  1352              end
  1353            val th = (*tuned fix_shyps*)
  1354              Thm{sign = sign,
  1355                  der = infer_derivs (Bicompose(match, eres_flg,
  1356                                                1 + length Bs, nsubgoal, env),
  1357                                      [rder,sder]),
  1358                  maxidx = maxidx,
  1359                  shyps = add_env_sorts (env, union_sort(rshyps,sshyps)),
  1360                  hyps = union_term(rhyps,shyps),
  1361                  prop = Logic.rule_of normp}
  1362         in  cons(th, thq)  end  handle COMPOSE => thq
  1363      val (rtpairs,rhorn) = Logic.strip_flexpairs(rprop);
  1364      val (rAs,B) = Logic.strip_prems(nsubgoal, [], rhorn)
  1365        handle TERM _ => raise THM("bicompose: rule", 0, [orule,state]);
  1366      (*Modify assumptions, deleting n-th if n>0 for e-resolution*)
  1367      fun newAs(As0, n, dpairs, tpairs) =
  1368        let val As1 = if !Logic.auto_rename orelse not lifted then As0
  1369                      else map (rename_bvars(dpairs,tpairs,B)) As0
  1370        in (map (Logic.flatten_params n) As1)
  1371           handle TERM _ =>
  1372           raise THM("bicompose: 1st premise", 0, [orule])
  1373        end;
  1374      val env = Envir.empty(Int.max(rmax,smax));
  1375      val BBi = if lifted then strip_assums2(B,Bi) else (B,Bi);
  1376      val dpairs = BBi :: (rtpairs@stpairs);
  1377      (*elim-resolution: try each assumption in turn.  Initially n=1*)
  1378      fun tryasms (_, _, []) = null
  1379        | tryasms (As, n, (t,u)::apairs) =
  1380           (case pull(Unify.unifiers(sign, env, (t,u)::dpairs))  of
  1381                None                   => tryasms (As, n+1, apairs)
  1382              | cell as Some((_,tpairs),_) =>
  1383                    its_right (addth (newAs(As, n, [BBi,(u,t)], tpairs)))
  1384                        (seqof (fn()=> cell),
  1385                         seqof (fn()=> pull (tryasms (As, n+1, apairs)))));
  1386      fun eres [] = raise THM("bicompose: no premises", 0, [orule,state])
  1387        | eres (A1::As) = tryasms (As, 1, Logic.assum_pairs A1);
  1388      (*ordinary resolution*)
  1389      fun res(None) = null
  1390        | res(cell as Some((_,tpairs),_)) =
  1391              its_right (addth(newAs(rev rAs, 0, [BBi], tpairs)))
  1392                        (seqof (fn()=> cell), null)
  1393  in  if eres_flg then eres(rev rAs)
  1394      else res(pull(Unify.unifiers(sign, env, dpairs)))
  1395  end;
  1396 end;  (*open Sequence*)
  1397 
  1398 
  1399 fun bicompose match arg i state =
  1400     bicompose_aux match (state, dest_state(state,i), false) arg;
  1401 
  1402 (*Quick test whether rule is resolvable with the subgoal with hyps Hs
  1403   and conclusion B.  If eres_flg then checks 1st premise of rule also*)
  1404 fun could_bires (Hs, B, eres_flg, rule) =
  1405     let fun could_reshyp (A1::_) = exists (apl(A1,could_unify)) Hs
  1406           | could_reshyp [] = false;  (*no premise -- illegal*)
  1407     in  could_unify(concl_of rule, B) andalso
  1408         (not eres_flg  orelse  could_reshyp (prems_of rule))
  1409     end;
  1410 
  1411 (*Bi-resolution of a state with a list of (flag,rule) pairs.
  1412   Puts the rule above:  rule/state.  Renames vars in the rules. *)
  1413 fun biresolution match brules i state =
  1414     let val lift = lift_rule(state, i);
  1415         val (stpairs, Bs, Bi, C) = dest_state(state,i)
  1416         val B = Logic.strip_assums_concl Bi;
  1417         val Hs = Logic.strip_assums_hyp Bi;
  1418         val comp = bicompose_aux match (state, (stpairs, Bs, Bi, C), true);
  1419         fun res [] = Sequence.null
  1420           | res ((eres_flg, rule)::brules) =
  1421               if could_bires (Hs, B, eres_flg, rule)
  1422               then Sequence.seqof (*delay processing remainder till needed*)
  1423                   (fn()=> Some(comp (eres_flg, lift rule, nprems_of rule),
  1424                                res brules))
  1425               else res brules
  1426     in  Sequence.flats (res brules)  end;
  1427 
  1428 
  1429 
  1430 (*** Meta Simplification ***)
  1431 
  1432 (** diagnostics **)
  1433 
  1434 exception SIMPLIFIER of string * thm;
  1435 
  1436 fun prtm a sign t = (writeln a; writeln (Sign.string_of_term sign t));
  1437 fun prtm_warning a sign t = (warning a; warning (Sign.string_of_term sign t));
  1438 
  1439 val trace_simp = ref false;
  1440 
  1441 fun trace a = if ! trace_simp then writeln a else ();
  1442 fun trace_warning a = if ! trace_simp then warning a else ();
  1443 fun trace_term a sign t = if ! trace_simp then prtm a sign t else ();
  1444 fun trace_term_warning a sign t = if ! trace_simp then prtm_warning a sign t else ();
  1445 fun trace_thm a (Thm {sign, prop, ...}) = trace_term a sign prop;
  1446 fun trace_thm_warning a (Thm {sign, prop, ...}) = trace_term_warning a sign prop;
  1447 
  1448 
  1449 
  1450 (** meta simp sets **)
  1451 
  1452 (* basic components *)
  1453 
  1454 type rrule = {thm: thm, lhs: term, perm: bool};
  1455 type cong = {thm: thm, lhs: term};
  1456 type simproc =
  1457  {name: string, proc: Sign.sg -> thm list -> term -> thm option, lhs: cterm, id: stamp};
  1458 
  1459 fun eq_rrule ({thm = Thm {prop = p1, ...}, ...}: rrule,
  1460   {thm = Thm {prop = p2, ...}, ...}: rrule) = p1 aconv p2;
  1461 
  1462 fun eq_cong ({thm = Thm {prop = p1, ...}, ...}: cong,
  1463   {thm = Thm {prop = p2, ...}, ...}: cong) = p1 aconv p2;
  1464 
  1465 fun eq_prem (Thm {prop = p1, ...}, Thm {prop = p2, ...}) = p1 aconv p2;
  1466 
  1467 fun eq_simproc ({id = s1, ...}:simproc, {id = s2, ...}:simproc) = (s1 = s2);
  1468 
  1469 fun mk_simproc (name, proc, lhs, id) =
  1470   {name = name, proc = proc, lhs = lhs, id = id};
  1471 
  1472 
  1473 (* datatype mss *)
  1474 
  1475 (*
  1476   A "mss" contains data needed during conversion:
  1477     rules: discrimination net of rewrite rules;
  1478     congs: association list of congruence rules;
  1479     procs: discrimination net of simplification procedures
  1480       (functions that prove rewrite rules on the fly);
  1481     bounds: names of bound variables already used
  1482       (for generating new names when rewriting under lambda abstractions);
  1483     prems: current premises;
  1484     mk_rews: turns simplification thms into rewrite rules;
  1485     termless: relation for ordered rewriting;
  1486 *)
  1487 
  1488 datatype meta_simpset =
  1489   Mss of {
  1490     rules: rrule Net.net,
  1491     congs: (string * cong) list,
  1492     procs: simproc Net.net,
  1493     bounds: string list,
  1494     prems: thm list,
  1495     mk_rews: thm -> thm list,
  1496     termless: term * term -> bool};
  1497 
  1498 fun mk_mss (rules, congs, procs, bounds, prems, mk_rews, termless) =
  1499   Mss {rules = rules, congs = congs, procs = procs, bounds = bounds,
  1500     prems = prems, mk_rews = mk_rews, termless = termless};
  1501 
  1502 val empty_mss =
  1503   mk_mss (Net.empty, [], Net.empty, [], [], K [], Logic.termless);
  1504 
  1505 
  1506 
  1507 (** simpset operations **)
  1508 
  1509 (* dest_mss *)
  1510 
  1511 fun dest_mss (Mss {rules, congs, procs, ...}) =
  1512   {simps = map (fn (_, {thm, ...}) => thm) (Net.dest rules),
  1513    congs = map (fn (_, {thm, ...}) => thm) congs,
  1514    procs =
  1515      map (fn (_, {name, lhs, id, ...}) => ((name, lhs), id)) (Net.dest procs)
  1516      |> partition_eq eq_snd
  1517      |> map (fn ps => (#1 (#1 (hd ps)), map (#2 o #1) ps))};
  1518 
  1519 
  1520 (* merge_mss *)		(*NOTE: ignores mk_rews and termless of 2nd mss*)
  1521 
  1522 fun merge_mss
  1523  (Mss {rules = rules1, congs = congs1, procs = procs1, bounds = bounds1,
  1524     prems = prems1, mk_rews, termless},
  1525   Mss {rules = rules2, congs = congs2, procs = procs2, bounds = bounds2,
  1526     prems = prems2, ...}) =
  1527       mk_mss
  1528        (Net.merge (rules1, rules2, eq_rrule),
  1529         generic_merge (eq_cong o pairself snd) I I congs1 congs2,
  1530         Net.merge (procs1, procs2, eq_simproc),
  1531         merge_lists bounds1 bounds2,
  1532         generic_merge eq_prem I I prems1 prems2,
  1533         mk_rews, termless);
  1534 
  1535 
  1536 (* mk_rrule *)
  1537 
  1538 fun mk_rrule (thm as Thm {sign, prop, ...}) =
  1539   let
  1540     val prems = Logic.strip_imp_prems prop;
  1541     val concl = Logic.strip_imp_concl prop;
  1542     val (lhs, rhs) = Logic.dest_equals concl handle TERM _ =>
  1543       raise SIMPLIFIER ("Rewrite rule not a meta-equality", thm);
  1544   in case Logic.loops sign prems lhs rhs of
  1545      (None,perm) => Some {thm = thm, lhs = lhs, perm = perm}
  1546    | (Some msg,_) =>
  1547         (prtm_warning("ignoring rewrite rule ("^msg^")") sign prop; None)
  1548   end;
  1549 
  1550 
  1551 (* add_simps *)
  1552 
  1553 fun add_simp
  1554   (mss as Mss {rules, congs, procs, bounds, prems, mk_rews, termless},
  1555     thm as Thm {sign, prop, ...}) =
  1556   (case mk_rrule thm of
  1557     None => mss
  1558   | Some (rrule as {lhs, ...}) =>
  1559       (trace_thm "Adding rewrite rule:" thm;
  1560         mk_mss (Net.insert_term ((lhs, rrule), rules, eq_rrule) handle Net.INSERT =>
  1561           (prtm_warning "ignoring duplicate rewrite rule" sign prop; rules),
  1562             congs, procs, bounds, prems, mk_rews, termless)));
  1563 
  1564 val add_simps = foldl add_simp;
  1565 
  1566 fun mss_of thms = add_simps (empty_mss, thms);
  1567 
  1568 
  1569 (* del_simps *)
  1570 
  1571 fun del_simp
  1572   (mss as Mss {rules, congs, procs, bounds, prems, mk_rews, termless},
  1573     thm as Thm {sign, prop, ...}) =
  1574   (case mk_rrule thm of
  1575     None => mss
  1576   | Some (rrule as {lhs, ...}) =>
  1577       mk_mss (Net.delete_term ((lhs, rrule), rules, eq_rrule) handle Net.DELETE =>
  1578         (prtm_warning "rewrite rule not in simpset" sign prop; rules),
  1579           congs, procs, bounds, prems, mk_rews, termless));
  1580 
  1581 val del_simps = foldl del_simp;
  1582 
  1583 
  1584 (* add_congs *)
  1585 
  1586 fun add_cong (Mss {rules, congs, procs, bounds, prems, mk_rews, termless}, thm) =
  1587   let
  1588     val (lhs, _) = Logic.dest_equals (concl_of thm) handle TERM _ =>
  1589       raise SIMPLIFIER ("Congruence not a meta-equality", thm);
  1590 (*   val lhs = Pattern.eta_contract lhs; *)
  1591     val (a, _) = dest_Const (head_of lhs) handle TERM _ =>
  1592       raise SIMPLIFIER ("Congruence must start with a constant", thm);
  1593   in
  1594     mk_mss (rules, (a, {lhs = lhs, thm = thm}) :: congs, procs, bounds,
  1595       prems, mk_rews, termless)
  1596   end;
  1597 
  1598 val (op add_congs) = foldl add_cong;
  1599 
  1600 
  1601 (* del_congs *)
  1602 
  1603 fun del_cong (Mss {rules, congs, procs, bounds, prems, mk_rews, termless}, thm) =
  1604   let
  1605     val (lhs, _) = Logic.dest_equals (concl_of thm) handle TERM _ =>
  1606       raise SIMPLIFIER ("Congruence not a meta-equality", thm);
  1607 (*   val lhs = Pattern.eta_contract lhs; *)
  1608     val (a, _) = dest_Const (head_of lhs) handle TERM _ =>
  1609       raise SIMPLIFIER ("Congruence must start with a constant", thm);
  1610   in
  1611     mk_mss (rules, filter (fn (x,_)=> x<>a) congs, procs, bounds,
  1612       prems, mk_rews, termless)
  1613   end;
  1614 
  1615 val (op del_congs) = foldl del_cong;
  1616 
  1617 
  1618 (* add_simprocs *)
  1619 
  1620 fun add_proc (mss as Mss {rules, congs, procs, bounds, prems, mk_rews, termless},
  1621     (name, lhs as Cterm {sign, t, ...}, proc, id)) =
  1622   (trace_term ("Adding simplification procedure " ^ name ^ " for:") sign t;
  1623     mk_mss (rules, congs,
  1624       Net.insert_term ((t, mk_simproc (name, proc, lhs, id)), procs, eq_simproc)
  1625         handle Net.INSERT => (trace_warning "ignored duplicate"; procs),
  1626         bounds, prems, mk_rews, termless));
  1627 
  1628 fun add_simproc (mss, (name, lhss, proc, id)) =
  1629   foldl add_proc (mss, map (fn lhs => (name, lhs, proc, id)) lhss);
  1630 
  1631 val add_simprocs = foldl add_simproc;
  1632 
  1633 
  1634 (* del_simprocs *)
  1635 
  1636 fun del_proc (mss as Mss {rules, congs, procs, bounds, prems, mk_rews, termless},
  1637     (name, lhs as Cterm {t, ...}, proc, id)) =
  1638   mk_mss (rules, congs,
  1639     Net.delete_term ((t, mk_simproc (name, proc, lhs, id)), procs, eq_simproc)
  1640       handle Net.DELETE => (trace_warning "simplification procedure not in simpset"; procs),
  1641       bounds, prems, mk_rews, termless);
  1642 
  1643 fun del_simproc (mss, (name, lhss, proc, id)) =
  1644   foldl del_proc (mss, map (fn lhs => (name, lhs, proc, id)) lhss);
  1645 
  1646 val del_simprocs = foldl del_simproc;
  1647 
  1648 
  1649 (* prems *)
  1650 
  1651 fun add_prems (Mss {rules, congs, procs, bounds, prems, mk_rews, termless}, thms) =
  1652   mk_mss (rules, congs, procs, bounds, thms @ prems, mk_rews, termless);
  1653 
  1654 fun prems_of_mss (Mss {prems, ...}) = prems;
  1655 
  1656 
  1657 (* mk_rews *)
  1658 
  1659 fun set_mk_rews
  1660   (Mss {rules, congs, procs, bounds, prems, mk_rews = _, termless}, mk_rews) =
  1661     mk_mss (rules, congs, procs, bounds, prems, mk_rews, termless);
  1662 
  1663 fun mk_rews_of_mss (Mss {mk_rews, ...}) = mk_rews;
  1664 
  1665 
  1666 (* termless *)
  1667 
  1668 fun set_termless
  1669   (Mss {rules, congs, procs, bounds, prems, mk_rews, termless = _}, termless) =
  1670     mk_mss (rules, congs, procs, bounds, prems, mk_rews, termless);
  1671 
  1672 
  1673 
  1674 (** rewriting **)
  1675 
  1676 (*
  1677   Uses conversions, omitting proofs for efficiency.  See:
  1678     L C Paulson, A higher-order implementation of rewriting,
  1679     Science of Computer Programming 3 (1983), pages 119-149.
  1680 *)
  1681 
  1682 type prover = meta_simpset -> thm -> thm option;
  1683 type termrec = (Sign.sg * term list) * term;
  1684 type conv = meta_simpset -> termrec -> termrec;
  1685 
  1686 fun check_conv (thm as Thm{shyps,hyps,prop,sign,der,maxidx,...}, prop0, ders) =
  1687   let fun err() = (trace_thm "Proved wrong thm (Check subgoaler?)" thm;
  1688                    trace_term "Should have proved" sign prop0;
  1689                    None)
  1690       val (lhs0,_) = Logic.dest_equals(Logic.strip_imp_concl prop0)
  1691   in case prop of
  1692        Const("==",_) $ lhs $ rhs =>
  1693          if (lhs = lhs0) orelse
  1694             (lhs aconv Envir.norm_term (Envir.empty 0) lhs0)
  1695          then (trace_thm "SUCCEEDED" thm; 
  1696                Some(shyps, hyps, maxidx, rhs, der::ders))
  1697          else err()
  1698      | _ => err()
  1699   end;
  1700 
  1701 fun ren_inst(insts,prop,pat,obj) =
  1702   let val ren = match_bvs(pat,obj,[])
  1703       fun renAbs(Abs(x,T,b)) =
  1704             Abs(case assoc_string(ren,x) of None => x | Some(y) => y, T, renAbs(b))
  1705         | renAbs(f$t) = renAbs(f) $ renAbs(t)
  1706         | renAbs(t) = t
  1707   in subst_vars insts (if null(ren) then prop else renAbs(prop)) end;
  1708 
  1709 fun add_insts_sorts ((iTs, is), Ss) =
  1710   add_typs_sorts (map snd iTs, add_terms_sorts (map snd is, Ss));
  1711 
  1712 
  1713 (* mk_procrule *)
  1714 
  1715 fun mk_procrule (thm as Thm {sign, prop, ...}) =
  1716   let
  1717     val prems = Logic.strip_imp_prems prop;
  1718     val concl = Logic.strip_imp_concl prop;
  1719     val (lhs, _) = Logic.dest_equals concl handle TERM _ =>
  1720       raise SIMPLIFIER ("Rewrite rule not a meta-equality", thm);
  1721     val econcl = Pattern.eta_contract concl;
  1722     val (elhs, erhs) = Logic.dest_equals econcl;
  1723   in
  1724     if not ((term_vars erhs) subset
  1725         (union_term (term_vars elhs, List.concat(map term_vars prems)))) 
  1726     then (prtm_warning "extra Var(s) on rhs" sign prop; [])
  1727     else [{thm = thm, lhs = lhs, perm = false}]
  1728   end;
  1729 
  1730 
  1731 (* conversion to apply the meta simpset to a term *)
  1732 
  1733 (*
  1734   we try in order:
  1735     (1) beta reduction
  1736     (2) unconditional rewrite rules
  1737     (3) conditional rewrite rules
  1738     (4) simplification procedures
  1739 *)
  1740 
  1741 fun rewritec (prover,signt) (mss as Mss{rules, procs, mk_rews, termless, prems, ...}) 
  1742              (shypst,hypst,maxt,t,ders) =
  1743   let
  1744       val tsigt = #tsig(Sign.rep_sg signt);
  1745       fun rew {thm as Thm{sign,der,maxidx,shyps,hyps,prop,...}, lhs, perm} =
  1746         let val unit = if Sign.subsig(sign,signt) then ()
  1747                   else (trace_thm_warning "rewrite rule from different theory"
  1748                           thm;
  1749                         raise Pattern.MATCH)
  1750             val rprop = if maxt = ~1 then prop
  1751                         else Logic.incr_indexes([],maxt+1) prop;
  1752             val rlhs = if maxt = ~1 then lhs
  1753                        else fst(Logic.dest_equals(Logic.strip_imp_concl rprop))
  1754             val insts = Pattern.match tsigt (rlhs,t);
  1755             val prop' = ren_inst(insts,rprop,rlhs,t);
  1756             val hyps' = union_term(hyps,hypst);
  1757             val shyps' = add_insts_sorts (insts, union_sort(shyps,shypst));
  1758             val maxidx' = maxidx_of_term prop'
  1759             val ct' = Cterm{sign = signt,       (*used for deriv only*)
  1760                             t = prop',
  1761                             T = propT,
  1762                             maxidx = maxidx'}
  1763             val der' = infer_derivs (RewriteC ct', [der]);
  1764             val thm' = Thm{sign = signt, 
  1765                            der = der',
  1766                            shyps = shyps',
  1767                            hyps = hyps',
  1768                            prop = prop',
  1769                            maxidx = maxidx'}
  1770             val (lhs',rhs') = Logic.dest_equals(Logic.strip_imp_concl prop')
  1771         in if perm andalso not(termless(rhs',lhs')) then None else
  1772            if Logic.count_prems(prop',0) = 0
  1773            then (trace_thm "Rewriting:" thm'; 
  1774                  Some(shyps', hyps', maxidx', rhs', der'::ders))
  1775            else (trace_thm "Trying to rewrite:" thm';
  1776                  case prover mss thm' of
  1777                    None       => (trace_thm "FAILED" thm'; None)
  1778                  | Some(thm2) => check_conv(thm2,prop',ders))
  1779         end
  1780 
  1781       fun rews [] = None
  1782         | rews (rrule :: rrules) =
  1783             let val opt = rew rrule handle Pattern.MATCH => None
  1784             in case opt of None => rews rrules | some => some end;
  1785 
  1786       fun sort_rrules rrs = let
  1787         fun is_simple {thm as Thm{prop,...}, lhs, perm} = case prop of 
  1788                                         Const("==",_) $ _ $ _ => true
  1789                                         | _                   => false 
  1790         fun sort []        (re1,re2) = re1 @ re2
  1791         |   sort (rr::rrs) (re1,re2) = if is_simple rr 
  1792                                        then sort rrs (rr::re1,re2)
  1793                                        else sort rrs (re1,rr::re2)
  1794       in sort rrs ([],[]) 
  1795       end
  1796 
  1797       fun proc_rews _ ([]:simproc list) = None
  1798         | proc_rews eta_t ({name, proc, lhs = Cterm {t = plhs, ...}, ...} :: ps) =
  1799             if Pattern.matches tsigt (plhs, t) then
  1800              (trace_term ("Trying procedure " ^ name ^ " on:") signt eta_t;
  1801               case proc signt prems eta_t of
  1802                 None => (trace "FAILED"; proc_rews eta_t ps)
  1803               | Some raw_thm =>
  1804                  (trace_thm ("Procedure " ^ name ^ " proved rewrite rule:") raw_thm;
  1805                    (case rews (mk_procrule raw_thm) of
  1806                      None => (trace "IGNORED"; proc_rews eta_t ps)
  1807                    | some => some)))
  1808             else proc_rews eta_t ps;
  1809   in
  1810     (case t of
  1811       Abs (_, _, body) $ u =>
  1812         Some (shypst, hypst, maxt, subst_bound (u, body), ders)
  1813      | _ =>
  1814       (case rews (sort_rrules (Net.match_term rules t)) of
  1815         None => proc_rews (Pattern.eta_contract t) (Net.match_term procs t)
  1816       | some => some))
  1817   end;
  1818 
  1819 
  1820 (* conversion to apply a congruence rule to a term *)
  1821 
  1822 fun congc (prover,signt) {thm=cong,lhs=lhs} (shypst,hypst,maxt,t,ders) =
  1823   let val Thm{sign,der,shyps,hyps,maxidx,prop,...} = cong
  1824       val unit = if Sign.subsig(sign,signt) then ()
  1825                  else error("Congruence rule from different theory")
  1826       val tsig = #tsig(Sign.rep_sg signt)
  1827       val rprop = if maxt = ~1 then prop
  1828                   else Logic.incr_indexes([],maxt+1) prop;
  1829       val rlhs = if maxt = ~1 then lhs
  1830                  else fst(Logic.dest_equals(Logic.strip_imp_concl rprop))
  1831       val insts = Pattern.match tsig (rlhs,t)
  1832       (* Pattern.match can raise Pattern.MATCH;
  1833          is handled when congc is called *)
  1834       val prop' = ren_inst(insts,rprop,rlhs,t);
  1835       val shyps' = add_insts_sorts (insts, union_sort(shyps,shypst))
  1836       val maxidx' = maxidx_of_term prop'
  1837       val ct' = Cterm{sign = signt,     (*used for deriv only*)
  1838                       t = prop',
  1839                       T = propT,
  1840                       maxidx = maxidx'}
  1841       val thm' = Thm{sign = signt, 
  1842                      der = infer_derivs (CongC ct', [der]),
  1843                      shyps = shyps',
  1844                      hyps = union_term(hyps,hypst),
  1845                      prop = prop',
  1846                      maxidx = maxidx'};
  1847       val unit = trace_thm "Applying congruence rule" thm';
  1848       fun err() = error("Failed congruence proof!")
  1849 
  1850   in case prover thm' of
  1851        None => err()
  1852      | Some(thm2) => (case check_conv(thm2,prop',ders) of
  1853                         None => err() | some => some)
  1854   end;
  1855 
  1856 
  1857 
  1858 fun bottomc ((simprem,useprem),prover,sign) =
  1859  let fun botc fail mss trec =
  1860           (case subc mss trec of
  1861              some as Some(trec1) =>
  1862                (case rewritec (prover,sign) mss trec1 of
  1863                   Some(trec2) => botc false mss trec2
  1864                 | None => some)
  1865            | None =>
  1866                (case rewritec (prover,sign) mss trec of
  1867                   Some(trec2) => botc false mss trec2
  1868                 | None => if fail then None else Some(trec)))
  1869 
  1870      and try_botc mss trec = (case botc true mss trec of
  1871                                 Some(trec1) => trec1
  1872                               | None => trec)
  1873 
  1874      and subc (mss as Mss{rules,congs,procs,bounds,prems,mk_rews,termless})
  1875               (trec as (shyps,hyps,maxidx,t0,ders)) =
  1876        (case t0 of
  1877            Abs(a,T,t) =>
  1878              let val b = variant bounds a
  1879                  val v = Free("." ^ b,T)
  1880                  val mss' = mk_mss (rules, congs, procs, b :: bounds, prems, mk_rews, termless)
  1881              in case botc true mss' 
  1882                        (shyps,hyps,maxidx,subst_bound (v,t),ders) of
  1883                   Some(shyps',hyps',maxidx',t',ders') =>
  1884                     Some(shyps', hyps', maxidx',
  1885                          Abs(a, T, abstract_over(v,t')),
  1886                          ders')
  1887                 | None => None
  1888              end
  1889          | t$u => (case t of
  1890              Const("==>",_)$s  => Some(impc(shyps,hyps,maxidx,s,u,mss,ders))
  1891            | Abs(_,_,body) =>
  1892                let val trec = (shyps,hyps,maxidx,subst_bound (u,body),ders)
  1893                in case subc mss trec of
  1894                     None => Some(trec)
  1895                   | trec => trec
  1896                end
  1897            | _  =>
  1898                let fun appc() =
  1899                      (case botc true mss (shyps,hyps,maxidx,t,ders) of
  1900                         Some(shyps1,hyps1,maxidx1,t1,ders1) =>
  1901                           (case botc true mss (shyps1,hyps1,maxidx,u,ders1) of
  1902                              Some(shyps2,hyps2,maxidx2,u1,ders2) =>
  1903                                Some(shyps2, hyps2, Int.max(maxidx1,maxidx2),
  1904                                     t1$u1, ders2)
  1905                            | None =>
  1906                                Some(shyps1, hyps1, Int.max(maxidx1,maxidx), t1$u,
  1907                                     ders1))
  1908                       | None =>
  1909                           (case botc true mss (shyps,hyps,maxidx,u,ders) of
  1910                              Some(shyps1,hyps1,maxidx1,u1,ders1) =>
  1911                                Some(shyps1, hyps1, Int.max(maxidx,maxidx1), 
  1912                                     t$u1, ders1)
  1913                            | None => None))
  1914                    val (h,ts) = strip_comb t
  1915                in case h of
  1916                     Const(a,_) =>
  1917                       (case assoc_string(congs,a) of
  1918                          None => appc()
  1919                        | Some(cong) => (congc (prover mss,sign) cong trec
  1920                                         handle Pattern.MATCH => appc() ) )
  1921                   | _ => appc()
  1922                end)
  1923          | _ => None)
  1924 
  1925      and impc(shyps, hyps, maxidx, s, u, mss as Mss{mk_rews,...}, ders) =
  1926        let val (shyps1,hyps1,_,s1,ders1) =
  1927              if simprem then try_botc mss (shyps,hyps,maxidx,s,ders)
  1928                         else (shyps,hyps,0,s,ders);
  1929            val maxidx1 = maxidx_of_term s1
  1930            val mss1 =
  1931              if not useprem then mss else
  1932              if maxidx1 <> ~1 then (trace_term_warning
  1933 "Cannot add premise as rewrite rule because it contains (type) unknowns:"
  1934                                                   sign s1; mss)
  1935              else let val thm = assume (Cterm{sign=sign, t=s1, 
  1936                                               T=propT, maxidx=maxidx1})
  1937                   in add_simps(add_prems(mss,[thm]), mk_rews thm) end
  1938            val (shyps2,hyps2,maxidx2,u1,ders2) = 
  1939                try_botc mss1 (shyps1,hyps1,maxidx,u,ders1)
  1940            val hyps3 = if gen_mem (op aconv) (s1, hyps1) 
  1941                        then hyps2 else hyps2\s1
  1942        in (shyps2, hyps3, Int.max(maxidx1,maxidx2), 
  1943            Logic.mk_implies(s1,u1), ders2) 
  1944        end
  1945 
  1946  in try_botc end;
  1947 
  1948 
  1949 (*** Meta-rewriting: rewrites t to u and returns the theorem t==u ***)
  1950 
  1951 (*
  1952   Parameters:
  1953     mode = (simplify A, use A in simplifying B) when simplifying A ==> B
  1954     mss: contains equality theorems of the form [|p1,...|] ==> t==u
  1955     prover: how to solve premises in conditional rewrites and congruences
  1956 *)
  1957 
  1958 (* FIXME: check that #bounds(mss) does not "occur" in ct alread *)
  1959 
  1960 fun rewrite_cterm mode mss prover ct =
  1961   let val {sign, t, T, maxidx} = rep_cterm ct;
  1962       val (shyps,hyps,maxu,u,ders) =
  1963         bottomc (mode,prover,sign) mss 
  1964                 (add_term_sorts(t,[]), [], maxidx, t, []);
  1965       val prop = Logic.mk_equals(t,u)
  1966   in
  1967       Thm{sign = sign, 
  1968           der = infer_derivs (Rewrite_cterm ct, ders),
  1969           maxidx = Int.max (maxidx,maxu),
  1970           shyps = shyps, 
  1971           hyps = hyps, 
  1972           prop = prop}
  1973   end
  1974 
  1975 
  1976 
  1977 (*** Oracles ***)
  1978 
  1979 fun invoke_oracle thy raw_name =
  1980   let
  1981     val {sign = sg, oracles, ...} = rep_theory thy;
  1982     val name = Sign.intern sg Theory.oracleK raw_name;
  1983     val oracle =
  1984       (case Symtab.lookup (oracles, name) of
  1985         None => raise THM ("Unknown oracle: " ^ name, 0, [])
  1986       | Some (f, _) => f);
  1987   in
  1988     fn (sign, exn) =>
  1989       let
  1990         val sign' = Sign.merge (sg, sign);
  1991         val (prop, T, maxidx) = Sign.certify_term sign' (oracle (sign', exn));
  1992       in
  1993         if T <> propT then
  1994           raise THM ("Oracle's result must have type prop: " ^ name, 0, [])
  1995         else fix_shyps [] []
  1996           (Thm {sign = sign', 
  1997             der = Join (Oracle (thy, name, sign, exn), []),
  1998             maxidx = maxidx,
  1999             shyps = [], 
  2000             hyps = [], 
  2001             prop = prop})
  2002       end
  2003   end;
  2004 
  2005 
  2006 end;
  2007 
  2008 open Thm;