src/Pure/sign.ML
author wenzelm
Wed Jun 29 15:13:27 2005 +0200 (2005-06-29)
changeset 16597 5a5229a55964
parent 16536 c5744af6b28a
child 16655 3e4d726aaed1
permissions -rw-r--r--
eliminated separate syn type -- advanced trfuns already part of Syntax.syntax;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, constant declarations.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_arities: (xstring * string list * string) list -> theory -> theory
    19   val add_arities_i: (string * sort list * sort) list -> theory -> theory
    20   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    21   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    22   val add_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    23   val add_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    24   val del_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    25   val del_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    26   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    27   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    28   val add_classes: (bstring * xstring list) list -> theory -> theory
    29   val add_classes_i: (bstring * class list) list -> theory -> theory
    30   val add_classrel: (xstring * xstring) list -> theory -> theory
    31   val add_classrel_i: (class * class) list -> theory -> theory
    32   val add_trfuns:
    33     (string * (ast list -> ast)) list *
    34     (string * (term list -> term)) list *
    35     (string * (term list -> term)) list *
    36     (string * (ast list -> ast)) list -> theory -> theory
    37   val add_trfunsT:
    38     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    39   val add_advanced_trfuns:
    40     (string * (theory -> ast list -> ast)) list *
    41     (string * (theory -> term list -> term)) list *
    42     (string * (theory -> term list -> term)) list *
    43     (string * (theory -> ast list -> ast)) list -> theory -> theory
    44   val add_advanced_trfunsT:
    45     (string * (theory -> bool -> typ -> term list -> term)) list -> theory -> theory
    46   val add_tokentrfuns:
    47     (string * string * (string -> string * real)) list -> theory -> theory
    48   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    49     -> theory -> theory
    50   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    51   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    52   val add_path: string -> theory -> theory
    53   val parent_path: theory -> theory
    54   val root_path: theory -> theory
    55   val absolute_path: theory -> theory
    56   val local_path: theory -> theory
    57   val qualified_names: theory -> theory
    58   val no_base_names: theory -> theory
    59   val custom_accesses: (string list -> string list list) -> theory -> theory
    60   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    61     theory -> theory
    62   val restore_naming: theory -> theory -> theory
    63   val hide_classes: bool -> xstring list -> theory -> theory
    64   val hide_classes_i: bool -> string list -> theory -> theory
    65   val hide_types: bool -> xstring list -> theory -> theory
    66   val hide_types_i: bool -> string list -> theory -> theory
    67   val hide_consts: bool -> xstring list -> theory -> theory
    68   val hide_consts_i: bool -> string list -> theory -> theory
    69 end
    70 
    71 signature SIGN =
    72 sig
    73   type sg    (*obsolete*)
    74   val init_data: theory -> theory
    75   val rep_sg: theory ->
    76    {naming: NameSpace.naming,
    77     syn: Syntax.syntax,
    78     tsig: Type.tsig,
    79     consts: (typ * stamp) NameSpace.table}
    80   val naming_of: theory -> NameSpace.naming
    81   val base_name: string -> bstring
    82   val full_name: theory -> bstring -> string
    83   val full_name_path: theory -> string -> bstring -> string
    84   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    85   val syn_of: theory -> Syntax.syntax
    86   val tsig_of: theory -> Type.tsig
    87   val classes: theory -> class list
    88   val defaultS: theory -> sort
    89   val subsort: theory -> sort * sort -> bool
    90   val of_sort: theory -> typ * sort -> bool
    91   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    92   val universal_witness: theory -> (typ * sort) option
    93   val typ_instance: theory -> typ * typ -> bool
    94   val is_logtype: theory -> string -> bool
    95   val const_type: theory -> string -> typ option
    96   val the_const_type: theory -> string -> typ
    97   val declared_tyname: theory -> string -> bool
    98   val declared_const: theory -> string -> bool
    99   val class_space: theory -> NameSpace.T
   100   val type_space: theory -> NameSpace.T
   101   val const_space: theory -> NameSpace.T
   102   val intern_class: theory -> xstring -> string
   103   val extern_class: theory -> string -> xstring
   104   val intern_type: theory -> xstring -> string
   105   val extern_type: theory -> string -> xstring
   106   val intern_const: theory -> xstring -> string
   107   val extern_const: theory -> string -> xstring
   108   val intern_sort: theory -> sort -> sort
   109   val extern_sort: theory -> sort -> sort
   110   val intern_typ: theory -> typ -> typ
   111   val extern_typ: theory -> typ -> typ
   112   val intern_term: theory -> term -> term
   113   val extern_term: theory -> term -> term
   114   val intern_tycons: theory -> typ -> typ
   115   val pretty_term': Syntax.syntax -> theory -> term -> Pretty.T
   116   val pretty_term: theory -> term -> Pretty.T
   117   val pretty_typ: theory -> typ -> Pretty.T
   118   val pretty_sort: theory -> sort -> Pretty.T
   119   val pretty_classrel: theory -> class list -> Pretty.T
   120   val pretty_arity: theory -> arity -> Pretty.T
   121   val string_of_term: theory -> term -> string
   122   val string_of_typ: theory -> typ -> string
   123   val string_of_sort: theory -> sort -> string
   124   val string_of_classrel: theory -> class list -> string
   125   val string_of_arity: theory -> arity -> string
   126   val pprint_term: theory -> term -> pprint_args -> unit
   127   val pprint_typ: theory -> typ -> pprint_args -> unit
   128   val pp: theory -> Pretty.pp
   129   val certify_class: theory -> class -> class
   130   val certify_sort: theory -> sort -> sort
   131   val certify_typ: theory -> typ -> typ
   132   val certify_typ_syntax: theory -> typ -> typ
   133   val certify_typ_abbrev: theory -> typ -> typ
   134   val certify_term: Pretty.pp -> theory -> term -> term * typ * int
   135   val certify_prop: Pretty.pp -> theory -> term -> term * typ * int
   136   val cert_term: theory -> term -> term
   137   val cert_prop: theory -> term -> term
   138   val read_sort': Syntax.syntax -> theory -> string -> sort
   139   val read_sort: theory -> string -> sort
   140   val read_typ': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   141   val read_typ_syntax': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   142   val read_typ_abbrev': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   143   val read_typ: theory * (indexname -> sort option) -> string -> typ
   144   val read_typ_syntax: theory * (indexname -> sort option) -> string -> typ
   145   val read_typ_abbrev: theory * (indexname -> sort option) -> string -> typ
   146   val read_tyname: theory -> string -> typ
   147   val read_const: theory -> string -> term
   148   val infer_types_simult: Pretty.pp -> theory -> (indexname -> typ option) ->
   149     (indexname -> sort option) -> string list -> bool
   150     -> (term list * typ) list -> term list * (indexname * typ) list
   151   val infer_types: Pretty.pp -> theory -> (indexname -> typ option) ->
   152     (indexname -> sort option) -> string list -> bool
   153     -> term list * typ -> term * (indexname * typ) list
   154   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax ->
   155     theory * (indexname -> typ option) * (indexname -> sort option) ->
   156     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   157   val read_def_terms:
   158     theory * (indexname -> typ option) * (indexname -> sort option) ->
   159     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   160   val simple_read_term: theory -> typ -> string -> term
   161   val read_term: theory -> string -> term
   162   val read_prop: theory -> string -> term
   163   val const_of_class: class -> string
   164   val class_of_const: string -> class
   165   include SIGN_THEORY
   166 end
   167 
   168 structure Sign: SIGN =
   169 struct
   170 
   171 type sg = theory;
   172 
   173 
   174 (** datatype sign **)
   175 
   176 datatype sign = Sign of
   177  {naming: NameSpace.naming,                 (*common naming conventions*)
   178   syn: Syntax.syntax,                       (*concrete syntax for terms, types, sorts*)
   179   tsig: Type.tsig,                          (*order-sorted signature of types*)
   180   consts: (typ * stamp) NameSpace.table};   (*type schemes of term constants*)
   181 
   182 fun make_sign (naming, syn, tsig, consts) =
   183   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   184 
   185 fun err_dup_consts cs =
   186   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   187 
   188 structure SignData = TheoryDataFun
   189 (struct
   190   val name = "Pure/sign";
   191   type T = sign;
   192   val copy = I;
   193   val extend = I;
   194 
   195   val empty =
   196     make_sign (NameSpace.default_naming, Syntax.pure_syn, Type.empty_tsig, NameSpace.empty_table);
   197 
   198   fun merge pp (sign1, sign2) =
   199     let
   200       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   201       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   202 
   203       val naming = NameSpace.default_naming;
   204       val syn = Syntax.merge_syntaxes syn1 syn2;
   205       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   206       val consts = NameSpace.merge_tables eq_snd (consts1, consts2)
   207         handle Symtab.DUPS cs => err_dup_consts cs;
   208     in make_sign (naming, syn, tsig, consts) end;
   209 
   210   fun print _ _ = ();
   211 end);
   212 
   213 val init_data = SignData.init;
   214 
   215 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   216 
   217 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   218   make_sign (f (naming, syn, tsig, consts)));
   219 
   220 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   221 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   222 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   223 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   224 
   225 
   226 (* naming *)
   227 
   228 val naming_of = #naming o rep_sg;
   229 val base_name = NameSpace.base;
   230 val full_name = NameSpace.full o naming_of;
   231 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   232 val declare_name = NameSpace.declare o naming_of;
   233 
   234 
   235 (* syntax *)
   236 
   237 val syn_of = #syn o rep_sg;
   238 
   239 
   240 (* type signature *)
   241 
   242 val tsig_of = #tsig o rep_sg;
   243 val classes = Type.classes o tsig_of;
   244 val defaultS = Type.defaultS o tsig_of;
   245 val subsort = Type.subsort o tsig_of;
   246 val of_sort = Type.of_sort o tsig_of;
   247 val witness_sorts = Type.witness_sorts o tsig_of;
   248 val universal_witness = Type.universal_witness o tsig_of;
   249 val typ_instance = Type.typ_instance o tsig_of;
   250 fun is_logtype thy c = c mem_string Type.logical_types (tsig_of thy);
   251 
   252 
   253 (* consts signature *)
   254 
   255 fun const_type thy c = Option.map #1 (Symtab.lookup (#2 (#consts (rep_sg thy)), c));
   256 
   257 fun the_const_type thy c =
   258   (case const_type thy c of SOME T => T
   259   | NONE => raise TYPE ("Undeclared constant " ^ quote c, [], []));
   260 
   261 fun declared_tyname thy c =
   262   is_some (Symtab.lookup (#2 (#types (Type.rep_tsig (tsig_of thy))), c));
   263 
   264 val declared_const = is_some oo const_type;
   265 
   266 
   267 
   268 (** intern / extern names **)
   269 
   270 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   271 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   272 val const_space = #1 o #consts o rep_sg
   273 
   274 val intern_class = NameSpace.intern o class_space;
   275 val extern_class = NameSpace.extern o class_space;
   276 val intern_type = NameSpace.intern o type_space;
   277 val extern_type = NameSpace.extern o type_space;
   278 val intern_const = NameSpace.intern o const_space;
   279 val extern_const = NameSpace.extern o const_space;
   280 
   281 val intern_sort = map o intern_class;
   282 val extern_sort = map o extern_class;
   283 
   284 local
   285 
   286 fun mapping add_names f t =
   287   let
   288     fun f' x = let val y = f x in if x = y then NONE else SOME (x, y) end;
   289     val tab = List.mapPartial f' (add_names (t, []));
   290     fun get x = if_none (assoc_string (tab, x)) x;
   291   in get end;
   292 
   293 fun typ_mapping f g thy T =
   294   T |> Term.map_typ
   295     (mapping add_typ_classes (f thy) T)
   296     (mapping add_typ_tycons (g thy) T);
   297 
   298 fun term_mapping f g h thy t =
   299   t |> Term.map_term
   300     (mapping add_term_classes (f thy) t)
   301     (mapping add_term_tycons (g thy) t)
   302     (mapping add_term_consts (h thy) t);
   303 
   304 in
   305 
   306 val intern_typ = typ_mapping intern_class intern_type;
   307 val extern_typ = typ_mapping extern_class extern_type;
   308 val intern_term = term_mapping intern_class intern_type intern_const;
   309 val extern_term = term_mapping extern_class extern_type extern_const;
   310 val intern_tycons = typ_mapping (K I) intern_type;
   311 
   312 end;
   313 
   314 
   315 
   316 (** pretty printing of terms, types etc. **)
   317 
   318 fun pretty_term' syn thy t =
   319   Syntax.pretty_term thy syn (Context.exists_name Context.CPureN thy) (extern_term thy t);
   320 fun pretty_term thy t = pretty_term' (syn_of thy) thy t;
   321 fun pretty_typ thy T = Syntax.pretty_typ thy (syn_of thy) (extern_typ thy T);
   322 fun pretty_sort thy S = Syntax.pretty_sort thy (syn_of thy) (extern_sort thy S);
   323 
   324 fun pretty_classrel thy cs = Pretty.block (List.concat
   325   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   326 
   327 fun pretty_arity thy (a, Ss, S) =
   328   let
   329     val a' = extern_type thy a;
   330     val dom =
   331       if null Ss then []
   332       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   333   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   334 
   335 val string_of_term = Pretty.string_of oo pretty_term;
   336 val string_of_typ = Pretty.string_of oo pretty_typ;
   337 val string_of_sort = Pretty.string_of oo pretty_sort;
   338 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   339 val string_of_arity = Pretty.string_of oo pretty_arity;
   340 
   341 val pprint_term = (Pretty.pprint o Pretty.quote) oo pretty_term;
   342 val pprint_typ = (Pretty.pprint o Pretty.quote) oo pretty_typ;
   343 
   344 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   345   pretty_classrel thy, pretty_arity thy);
   346 
   347 
   348 
   349 (** certify entities **)    (*exception TYPE*)
   350 
   351 (* certify wrt. type signature *)
   352 
   353 fun certify cert = cert o tsig_of o Context.check_thy "Sign.certify";
   354 
   355 val certify_class      = certify Type.cert_class;
   356 val certify_sort       = certify Type.cert_sort;
   357 val certify_typ        = certify Type.cert_typ;
   358 val certify_typ_syntax = certify Type.cert_typ_syntax;
   359 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   360 
   361 
   362 (* certify_term *)
   363 
   364 local
   365 
   366 (*determine and check the type of a term*)
   367 fun type_check pp tm =
   368   let
   369     fun err_appl why bs t T u U =
   370       let
   371         val xs = map Free bs;           (*we do not rename here*)
   372         val t' = subst_bounds (xs, t);
   373         val u' = subst_bounds (xs, u);
   374         val msg = cat_lines
   375           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   376       in raise TYPE (msg, [T, U], [t', u']) end;
   377 
   378     fun typ_of (_, Const (_, T)) = T
   379       | typ_of (_, Free  (_, T)) = T
   380       | typ_of (_, Var (_, T)) = T
   381       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   382           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   383       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   384       | typ_of (bs, t $ u) =
   385           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   386             (case T of
   387               Type ("fun", [T1, T2]) =>
   388                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   389             | _ => err_appl "Operator not of function type" bs t T u U)
   390           end;
   391 
   392   in typ_of ([], tm) end;
   393 
   394 in
   395 
   396 fun certify_term pp thy tm =
   397   let
   398     val _ = Context.check_thy "Sign.certify_term" thy;
   399 
   400     val tm' = map_term_types (certify_typ thy) tm;
   401     val tm' = if tm = tm' then tm else tm';  (*avoid copying of already normal term*)
   402 
   403     fun err msg = raise TYPE (msg, [], [tm']);
   404 
   405     fun show_const a T = quote a ^ " :: " ^ Pretty.string_of_typ pp T;
   406 
   407     fun check_atoms (t $ u) = (check_atoms t; check_atoms u)
   408       | check_atoms (Abs (_, _, t)) = check_atoms t
   409       | check_atoms (Const (a, T)) =
   410           (case const_type thy a of
   411             NONE => err ("Undeclared constant " ^ show_const a T)
   412           | SOME U =>
   413               if typ_instance thy (T, U) then ()
   414               else err ("Illegal type for constant " ^ show_const a T))
   415       | check_atoms (Var ((x, i), _)) =
   416           if i < 0 then err ("Malformed variable: " ^ quote x) else ()
   417       | check_atoms _ = ();
   418   in
   419     check_atoms tm';
   420     (tm', type_check pp tm', maxidx_of_term tm')
   421   end;
   422 
   423 end;
   424 
   425 fun certify_prop pp thy tm =
   426   let val res as (tm', T, _) = certify_term pp thy tm
   427   in if T <> propT then raise TYPE ("Term not of type prop", [T], [tm']) else res end;
   428 
   429 fun cert_term thy tm = #1 (certify_term (pp thy) thy tm);
   430 fun cert_prop thy tm = #1 (certify_prop (pp thy) thy tm);
   431 
   432 
   433 
   434 (** read and certify entities **)    (*exception ERROR*)
   435 
   436 (* sorts *)
   437 
   438 fun read_sort' syn thy str =
   439   let
   440     val _ = Context.check_thy "Sign.read_sort'" thy;
   441     val S = intern_sort thy (Syntax.read_sort thy syn str);
   442   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   443 
   444 fun read_sort thy str = read_sort' (syn_of thy) thy str;
   445 
   446 
   447 (* types *)
   448 
   449 local
   450 
   451 fun gen_read_typ' cert syn (thy, def_sort) str =
   452   let
   453     val _ = Context.check_thy "Sign.gen_read_typ'" thy;
   454     val get_sort = TypeInfer.get_sort (tsig_of thy) def_sort (intern_sort thy);
   455     val T = intern_tycons thy (Syntax.read_typ thy syn get_sort (intern_sort thy) str);
   456   in cert thy T handle TYPE (msg, _, _) => error msg end
   457   handle ERROR => error ("The error(s) above occurred in type " ^ quote str);
   458 
   459 fun gen_read_typ cert (thy, def_sort) str =
   460   gen_read_typ' cert (syn_of thy) (thy, def_sort) str;
   461 
   462 in
   463 
   464 fun no_def_sort thy = (thy: theory, K NONE);
   465 
   466 val read_typ'        = gen_read_typ' certify_typ;
   467 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   468 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   469 val read_typ         = gen_read_typ certify_typ;
   470 val read_typ_syntax  = gen_read_typ certify_typ_syntax;
   471 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev;
   472 
   473 end;
   474 
   475 
   476 (* type and constant names *)
   477 
   478 fun read_tyname thy raw_c =
   479   let val c = intern_type thy raw_c in
   480     (case Symtab.lookup (#2 (#types (Type.rep_tsig (tsig_of thy))), c) of
   481       SOME (Type.LogicalType n, _) => Type (c, replicate n dummyT)
   482     | _ => error ("Undeclared type constructor: " ^ quote c))
   483   end;
   484 
   485 fun read_const thy raw_c =
   486   let
   487     val c = intern_const thy raw_c;
   488     val _ = the_const_type thy c handle TYPE (msg, _, _) => error msg;
   489   in Const (c, dummyT) end;
   490 
   491 
   492 
   493 (** infer_types **)         (*exception ERROR*)
   494 
   495 (*
   496   def_type: partial map from indexnames to types (constrains Frees and Vars)
   497   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   498   used: list of already used type variables
   499   freeze: if true then generated parameters are turned into TFrees, else TVars
   500 
   501   termss: lists of alternative parses (only one combination should be type-correct)
   502   typs: expected types
   503 *)
   504 
   505 fun infer_types_simult pp thy def_type def_sort used freeze args =
   506   let
   507     val termss = foldr multiply [[]] (map fst args);
   508     val typs =
   509       map (fn (_, T) => certify_typ thy T handle TYPE (msg, _, _) => error msg) args;
   510 
   511     fun infer ts = OK (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   512         (const_type thy) def_type def_sort (intern_const thy) (intern_tycons thy)
   513         (intern_sort thy) used freeze typs ts)
   514       handle TYPE (msg, _, _) => Error msg;
   515 
   516     val err_results = map infer termss;
   517     val errs = List.mapPartial get_error err_results;
   518     val results = List.mapPartial get_ok err_results;
   519 
   520     val ambiguity = length termss;
   521 
   522     fun ambig_msg () =
   523       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level
   524       then
   525         error_msg "Got more than one parse tree.\n\
   526           \Retry with smaller Syntax.ambiguity_level for more information."
   527       else ();
   528   in
   529     if null results then (ambig_msg (); error (cat_lines errs))
   530     else if length results = 1 then
   531       (if ambiguity > ! Syntax.ambiguity_level then
   532         warning "Fortunately, only one parse tree is type correct.\n\
   533           \You may still want to disambiguate your grammar or your input."
   534       else (); hd results)
   535     else (ambig_msg (); error ("More than one term is type correct:\n" ^
   536       cat_lines (map (Pretty.string_of_term pp) (List.concat (map fst results)))))
   537   end;
   538 
   539 fun infer_types pp thy def_type def_sort used freeze tsT =
   540   apfst hd (infer_types_simult pp thy def_type def_sort used freeze [tsT]);
   541 
   542 
   543 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   544 
   545 fun read_def_terms' pp is_logtype syn (thy, types, sorts) used freeze sTs =
   546   let
   547     fun read (s, T) =
   548       let val T' = certify_typ thy T handle TYPE (msg, _, _) => error msg
   549       in (Syntax.read thy is_logtype syn T' s, T') end;
   550   in infer_types_simult pp thy types sorts used freeze (map read sTs) end;
   551 
   552 fun read_def_terms (thy, types, sorts) =
   553   read_def_terms' (pp thy) (is_logtype thy) (syn_of thy) (thy, types, sorts);
   554 
   555 fun simple_read_term thy T s =
   556   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   557   in t end
   558   handle ERROR => error ("The error(s) above occurred for term " ^ s);
   559 
   560 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   561 fun read_prop thy = simple_read_term thy propT;
   562 
   563 
   564 
   565 (** signature extension functions **)  (*exception ERROR/TYPE*)
   566 
   567 (* add default sort *)
   568 
   569 fun gen_add_defsort prep_sort s thy =
   570   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   571 
   572 val add_defsort = gen_add_defsort read_sort;
   573 val add_defsort_i = gen_add_defsort certify_sort;
   574 
   575 
   576 (* add type constructors *)
   577 
   578 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   579   let
   580     val syn' = Syntax.extend_type_gram types syn;
   581     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   582     val tsig' = Type.add_types naming decls tsig;
   583   in (naming, syn', tsig', consts) end);
   584 
   585 fun add_typedecls decls thy =
   586   let
   587     fun type_of (a, vs, mx) =
   588       if null (duplicates vs) then (a, length vs, mx)
   589       else error ("Duplicate parameters in type declaration: " ^ quote a);
   590   in add_types (map type_of decls) thy end;
   591 
   592 
   593 (* add nonterminals *)
   594 
   595 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   596   let
   597     val syn' = Syntax.extend_consts ns syn;
   598     val tsig' = Type.add_nonterminals naming ns tsig;
   599   in (naming, syn', tsig', consts) end);
   600 
   601 
   602 (* add type abbreviations *)
   603 
   604 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   605   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   606     let
   607       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   608       val a' = Syntax.type_name a mx;
   609       val abbr = (a', vs, prep_typ thy rhs)
   610         handle ERROR => error ("in type abbreviation " ^ quote a');
   611       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   612     in (naming, syn', tsig', consts) end);
   613 
   614 val add_tyabbrs = fold (gen_add_tyabbr (read_typ_syntax o no_def_sort));
   615 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   616 
   617 
   618 (* add type arities *)
   619 
   620 fun gen_add_arities int_type prep_sort arities thy = thy |> map_tsig (fn tsig =>
   621   let
   622     fun prep_arity (a, Ss, S) = (int_type thy a, map (prep_sort thy) Ss, prep_sort thy S)
   623       handle ERROR => error ("in arity for type " ^ quote a);
   624     val tsig' = Type.add_arities (pp thy) (map prep_arity arities) tsig;
   625   in tsig' end);
   626 
   627 val add_arities = gen_add_arities intern_type read_sort;
   628 val add_arities_i = gen_add_arities (K I) certify_sort;
   629 
   630 
   631 (* modify syntax *)
   632 
   633 fun gen_syntax change_gram prep_typ prmode args thy =
   634   let
   635     fun prep (c, T, mx) = (c, prep_typ thy T, mx)
   636       handle ERROR => error ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   637   in thy |> map_syn (change_gram (is_logtype thy) prmode (map prep args)) end;
   638 
   639 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   640 
   641 val add_modesyntax = gen_add_syntax (read_typ_syntax o no_def_sort);
   642 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   643 val add_syntax = add_modesyntax Syntax.default_mode;
   644 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   645 val del_modesyntax = gen_syntax Syntax.remove_const_gram (read_typ_syntax o no_def_sort);
   646 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   647 
   648 
   649 (* add constants *)
   650 
   651 fun gen_add_consts prep_typ raw_args thy =
   652   let
   653     val prepT = compress_type o Type.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   654     fun prep (c, T, mx) = ((c, prepT T, mx) handle TYPE (msg, _, _) => error msg)
   655       handle ERROR => error ("in declaration of constant " ^ quote (Syntax.const_name c mx));
   656     val args = map prep raw_args;
   657     val decls = args |> map (fn (c, T, mx) => (Syntax.const_name c mx, (T, stamp ())));
   658 
   659     fun extend_consts consts = NameSpace.extend_table (naming_of thy) (consts, decls)
   660       handle Symtab.DUPS cs => err_dup_consts cs;
   661   in
   662     thy
   663     |> map_consts extend_consts
   664     |> add_syntax_i args
   665   end;
   666 
   667 val add_consts = gen_add_consts (read_typ o no_def_sort);
   668 val add_consts_i = gen_add_consts certify_typ;
   669 
   670 
   671 (* add type classes *)
   672 
   673 val classN = "_class";
   674 
   675 val const_of_class = suffix classN;
   676 fun class_of_const c = unsuffix classN c
   677   handle Fail _ => raise TERM ("class_of_const: bad name " ^ quote c, []);
   678 
   679 fun gen_add_class int_class (bclass, raw_classes) thy =
   680   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   681     let
   682       val classes = map (int_class thy) raw_classes;
   683       val syn' = Syntax.extend_consts [bclass] syn;
   684       val tsig' = Type.add_classes (pp thy) naming [(bclass, classes)] tsig;
   685     in (naming, syn', tsig', consts) end)
   686   |> add_consts_i [(const_of_class bclass, a_itselfT --> propT, Syntax.NoSyn)];
   687 
   688 val add_classes = fold (gen_add_class intern_class);
   689 val add_classes_i = fold (gen_add_class (K I));
   690 
   691 
   692 (* add to classrel *)
   693 
   694 fun gen_add_classrel int_class raw_pairs thy = thy |> map_tsig (fn tsig =>
   695   let
   696     val pairs = map (pairself (int_class thy)) raw_pairs;
   697     val tsig' = Type.add_classrel (pp thy) pairs tsig;
   698   in tsig' end);
   699 
   700 val add_classrel = gen_add_classrel intern_class;
   701 val add_classrel_i = gen_add_classrel (K I);
   702 
   703 
   704 (* add translation functions *)
   705 
   706 local
   707 
   708 fun mk trs = map Syntax.mk_trfun trs;
   709 
   710 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   711   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   712 
   713 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   714 
   715 in
   716 
   717 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   718 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   719 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   720 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   721 
   722 end;
   723 
   724 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   725 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   726 
   727 
   728 (* add translation rules *)
   729 
   730 fun add_trrules args thy = thy |> map_syn (fn syn =>
   731   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   732   in Syntax.extend_trrules thy (is_logtype thy) syn rules syn end);
   733 
   734 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   735 
   736 
   737 (* modify naming *)
   738 
   739 val add_path        = map_naming o NameSpace.add_path;
   740 val qualified_names = map_naming NameSpace.qualified_names;
   741 val no_base_names   = map_naming NameSpace.no_base_names;
   742 val custom_accesses = map_naming o NameSpace.custom_accesses;
   743 val set_policy      = map_naming o NameSpace.set_policy;
   744 val restore_naming  = map_naming o K o naming_of;
   745 
   746 val parent_path     = add_path "..";
   747 val root_path       = add_path "/";
   748 val absolute_path   = add_path "//";
   749 
   750 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   751 
   752 
   753 (* hide names *)
   754 
   755 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   756 val hide_classes_i = map_tsig oo Type.hide_classes;
   757 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   758 val hide_types_i = map_tsig oo Type.hide_types;
   759 fun hide_consts b xs thy =
   760   thy |> map_consts (apfst (fold (NameSpace.hide b o intern_const thy) xs));
   761 val hide_consts_i = (map_consts o apfst) oo (fold o NameSpace.hide);
   762 
   763 end;