src/HOL/Algebra/UnivPoly.thy
author berghofe
Fri Jul 01 14:03:50 2005 +0200 (2005-07-01)
changeset 16639 5a89d3622ac0
parent 16417 9bc16273c2d4
child 17094 7a3c2efecffe
permissions -rw-r--r--
Removed setsubgoaler hack (thanks to strengthened finsum_cong).
     1 (*
     2   Title:     HOL/Algebra/UnivPoly.thy
     3   Id:        $Id$
     4   Author:    Clemens Ballarin, started 9 December 1996
     5   Copyright: Clemens Ballarin
     6 *)
     7 
     8 header {* Univariate Polynomials *}
     9 
    10 theory UnivPoly imports Module begin
    11 
    12 text {*
    13   Polynomials are formalised as modules with additional operations for
    14   extracting coefficients from polynomials and for obtaining monomials
    15   from coefficients and exponents (record @{text "up_ring"}).  The
    16   carrier set is a set of bounded functions from Nat to the
    17   coefficient domain.  Bounded means that these functions return zero
    18   above a certain bound (the degree).  There is a chapter on the
    19   formalisation of polynomials in the PhD thesis \cite{Ballarin:1999},
    20   which was implemented with axiomatic type classes.  This was later
    21   ported to Locales.
    22 *}
    23 
    24 
    25 subsection {* The Constructor for Univariate Polynomials *}
    26 
    27 text {*
    28   Functions with finite support.
    29 *}
    30 
    31 locale bound =
    32   fixes z :: 'a
    33     and n :: nat
    34     and f :: "nat => 'a"
    35   assumes bound: "!!m. n < m \<Longrightarrow> f m = z"
    36 
    37 declare bound.intro [intro!]
    38   and bound.bound [dest]
    39 
    40 lemma bound_below:
    41   assumes bound: "bound z m f" and nonzero: "f n \<noteq> z" shows "n \<le> m"
    42 proof (rule classical)
    43   assume "~ ?thesis"
    44   then have "m < n" by arith
    45   with bound have "f n = z" ..
    46   with nonzero show ?thesis by contradiction
    47 qed
    48 
    49 record ('a, 'p) up_ring = "('a, 'p) module" +
    50   monom :: "['a, nat] => 'p"
    51   coeff :: "['p, nat] => 'a"
    52 
    53 constdefs (structure R)
    54   up :: "('a, 'm) ring_scheme => (nat => 'a) set"
    55   "up R == {f. f \<in> UNIV -> carrier R & (EX n. bound \<zero> n f)}"
    56   UP :: "('a, 'm) ring_scheme => ('a, nat => 'a) up_ring"
    57   "UP R == (|
    58     carrier = up R,
    59     mult = (%p:up R. %q:up R. %n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)),
    60     one = (%i. if i=0 then \<one> else \<zero>),
    61     zero = (%i. \<zero>),
    62     add = (%p:up R. %q:up R. %i. p i \<oplus> q i),
    63     smult = (%a:carrier R. %p:up R. %i. a \<otimes> p i),
    64     monom = (%a:carrier R. %n i. if i=n then a else \<zero>),
    65     coeff = (%p:up R. %n. p n) |)"
    66 
    67 text {*
    68   Properties of the set of polynomials @{term up}.
    69 *}
    70 
    71 lemma mem_upI [intro]:
    72   "[| !!n. f n \<in> carrier R; EX n. bound (zero R) n f |] ==> f \<in> up R"
    73   by (simp add: up_def Pi_def)
    74 
    75 lemma mem_upD [dest]:
    76   "f \<in> up R ==> f n \<in> carrier R"
    77   by (simp add: up_def Pi_def)
    78 
    79 lemma (in cring) bound_upD [dest]:
    80   "f \<in> up R ==> EX n. bound \<zero> n f"
    81   by (simp add: up_def)
    82 
    83 lemma (in cring) up_one_closed:
    84    "(%n. if n = 0 then \<one> else \<zero>) \<in> up R"
    85   using up_def by force
    86 
    87 lemma (in cring) up_smult_closed:
    88   "[| a \<in> carrier R; p \<in> up R |] ==> (%i. a \<otimes> p i) \<in> up R"
    89   by force
    90 
    91 lemma (in cring) up_add_closed:
    92   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<oplus> q i) \<in> up R"
    93 proof
    94   fix n
    95   assume "p \<in> up R" and "q \<in> up R"
    96   then show "p n \<oplus> q n \<in> carrier R"
    97     by auto
    98 next
    99   assume UP: "p \<in> up R" "q \<in> up R"
   100   show "EX n. bound \<zero> n (%i. p i \<oplus> q i)"
   101   proof -
   102     from UP obtain n where boundn: "bound \<zero> n p" by fast
   103     from UP obtain m where boundm: "bound \<zero> m q" by fast
   104     have "bound \<zero> (max n m) (%i. p i \<oplus> q i)"
   105     proof
   106       fix i
   107       assume "max n m < i"
   108       with boundn and boundm and UP show "p i \<oplus> q i = \<zero>" by fastsimp
   109     qed
   110     then show ?thesis ..
   111   qed
   112 qed
   113 
   114 lemma (in cring) up_a_inv_closed:
   115   "p \<in> up R ==> (%i. \<ominus> (p i)) \<in> up R"
   116 proof
   117   assume R: "p \<in> up R"
   118   then obtain n where "bound \<zero> n p" by auto
   119   then have "bound \<zero> n (%i. \<ominus> p i)" by auto
   120   then show "EX n. bound \<zero> n (%i. \<ominus> p i)" by auto
   121 qed auto
   122 
   123 lemma (in cring) up_mult_closed:
   124   "[| p \<in> up R; q \<in> up R |] ==>
   125   (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> up R"
   126 proof
   127   fix n
   128   assume "p \<in> up R" "q \<in> up R"
   129   then show "(\<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> carrier R"
   130     by (simp add: mem_upD  funcsetI)
   131 next
   132   assume UP: "p \<in> up R" "q \<in> up R"
   133   show "EX n. bound \<zero> n (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i))"
   134   proof -
   135     from UP obtain n where boundn: "bound \<zero> n p" by fast
   136     from UP obtain m where boundm: "bound \<zero> m q" by fast
   137     have "bound \<zero> (n + m) (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n - i))"
   138     proof
   139       fix k assume bound: "n + m < k"
   140       {
   141         fix i
   142         have "p i \<otimes> q (k-i) = \<zero>"
   143         proof (cases "n < i")
   144           case True
   145           with boundn have "p i = \<zero>" by auto
   146           moreover from UP have "q (k-i) \<in> carrier R" by auto
   147           ultimately show ?thesis by simp
   148         next
   149           case False
   150           with bound have "m < k-i" by arith
   151           with boundm have "q (k-i) = \<zero>" by auto
   152           moreover from UP have "p i \<in> carrier R" by auto
   153           ultimately show ?thesis by simp
   154         qed
   155       }
   156       then show "(\<Oplus>i \<in> {..k}. p i \<otimes> q (k-i)) = \<zero>"
   157         by (simp add: Pi_def)
   158     qed
   159     then show ?thesis by fast
   160   qed
   161 qed
   162 
   163 
   164 subsection {* Effect of operations on coefficients *}
   165 
   166 locale UP = struct R + struct P +
   167   defines P_def: "P == UP R"
   168 
   169 locale UP_cring = UP + cring R
   170 
   171 locale UP_domain = UP_cring + "domain" R
   172 
   173 text {*
   174   Temporarily declare @{thm [locale=UP] P_def} as simp rule.
   175 *}
   176 
   177 declare (in UP) P_def [simp]
   178 
   179 lemma (in UP_cring) coeff_monom [simp]:
   180   "a \<in> carrier R ==>
   181   coeff P (monom P a m) n = (if m=n then a else \<zero>)"
   182 proof -
   183   assume R: "a \<in> carrier R"
   184   then have "(%n. if n = m then a else \<zero>) \<in> up R"
   185     using up_def by force
   186   with R show ?thesis by (simp add: UP_def)
   187 qed
   188 
   189 lemma (in UP_cring) coeff_zero [simp]:
   190   "coeff P \<zero>\<^bsub>P\<^esub> n = \<zero>"
   191   by (auto simp add: UP_def)
   192 
   193 lemma (in UP_cring) coeff_one [simp]:
   194   "coeff P \<one>\<^bsub>P\<^esub> n = (if n=0 then \<one> else \<zero>)"
   195   using up_one_closed by (simp add: UP_def)
   196 
   197 lemma (in UP_cring) coeff_smult [simp]:
   198   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   199   coeff P (a \<odot>\<^bsub>P\<^esub> p) n = a \<otimes> coeff P p n"
   200   by (simp add: UP_def up_smult_closed)
   201 
   202 lemma (in UP_cring) coeff_add [simp]:
   203   "[| p \<in> carrier P; q \<in> carrier P |] ==>
   204   coeff P (p \<oplus>\<^bsub>P\<^esub> q) n = coeff P p n \<oplus> coeff P q n"
   205   by (simp add: UP_def up_add_closed)
   206 
   207 lemma (in UP_cring) coeff_mult [simp]:
   208   "[| p \<in> carrier P; q \<in> carrier P |] ==>
   209   coeff P (p \<otimes>\<^bsub>P\<^esub> q) n = (\<Oplus>i \<in> {..n}. coeff P p i \<otimes> coeff P q (n-i))"
   210   by (simp add: UP_def up_mult_closed)
   211 
   212 lemma (in UP) up_eqI:
   213   assumes prem: "!!n. coeff P p n = coeff P q n"
   214     and R: "p \<in> carrier P" "q \<in> carrier P"
   215   shows "p = q"
   216 proof
   217   fix x
   218   from prem and R show "p x = q x" by (simp add: UP_def)
   219 qed
   220 
   221 subsection {* Polynomials form a commutative ring. *}
   222 
   223 text {* Operations are closed over @{term P}. *}
   224 
   225 lemma (in UP_cring) UP_mult_closed [simp]:
   226   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<otimes>\<^bsub>P\<^esub> q \<in> carrier P"
   227   by (simp add: UP_def up_mult_closed)
   228 
   229 lemma (in UP_cring) UP_one_closed [simp]:
   230   "\<one>\<^bsub>P\<^esub> \<in> carrier P"
   231   by (simp add: UP_def up_one_closed)
   232 
   233 lemma (in UP_cring) UP_zero_closed [intro, simp]:
   234   "\<zero>\<^bsub>P\<^esub> \<in> carrier P"
   235   by (auto simp add: UP_def)
   236 
   237 lemma (in UP_cring) UP_a_closed [intro, simp]:
   238   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<oplus>\<^bsub>P\<^esub> q \<in> carrier P"
   239   by (simp add: UP_def up_add_closed)
   240 
   241 lemma (in UP_cring) monom_closed [simp]:
   242   "a \<in> carrier R ==> monom P a n \<in> carrier P"
   243   by (auto simp add: UP_def up_def Pi_def)
   244 
   245 lemma (in UP_cring) UP_smult_closed [simp]:
   246   "[| a \<in> carrier R; p \<in> carrier P |] ==> a \<odot>\<^bsub>P\<^esub> p \<in> carrier P"
   247   by (simp add: UP_def up_smult_closed)
   248 
   249 lemma (in UP) coeff_closed [simp]:
   250   "p \<in> carrier P ==> coeff P p n \<in> carrier R"
   251   by (auto simp add: UP_def)
   252 
   253 declare (in UP) P_def [simp del]
   254 
   255 text {* Algebraic ring properties *}
   256 
   257 lemma (in UP_cring) UP_a_assoc:
   258   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   259   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<oplus>\<^bsub>P\<^esub> r = p \<oplus>\<^bsub>P\<^esub> (q \<oplus>\<^bsub>P\<^esub> r)"
   260   by (rule up_eqI, simp add: a_assoc R, simp_all add: R)
   261 
   262 lemma (in UP_cring) UP_l_zero [simp]:
   263   assumes R: "p \<in> carrier P"
   264   shows "\<zero>\<^bsub>P\<^esub> \<oplus>\<^bsub>P\<^esub> p = p"
   265   by (rule up_eqI, simp_all add: R)
   266 
   267 lemma (in UP_cring) UP_l_neg_ex:
   268   assumes R: "p \<in> carrier P"
   269   shows "EX q : carrier P. q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   270 proof -
   271   let ?q = "%i. \<ominus> (p i)"
   272   from R have closed: "?q \<in> carrier P"
   273     by (simp add: UP_def P_def up_a_inv_closed)
   274   from R have coeff: "!!n. coeff P ?q n = \<ominus> (coeff P p n)"
   275     by (simp add: UP_def P_def up_a_inv_closed)
   276   show ?thesis
   277   proof
   278     show "?q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   279       by (auto intro!: up_eqI simp add: R closed coeff R.l_neg)
   280   qed (rule closed)
   281 qed
   282 
   283 lemma (in UP_cring) UP_a_comm:
   284   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   285   shows "p \<oplus>\<^bsub>P\<^esub> q = q \<oplus>\<^bsub>P\<^esub> p"
   286   by (rule up_eqI, simp add: a_comm R, simp_all add: R)
   287 
   288 lemma (in UP_cring) UP_m_assoc:
   289   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   290   shows "(p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   291 proof (rule up_eqI)
   292   fix n
   293   {
   294     fix k and a b c :: "nat=>'a"
   295     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   296       "c \<in> UNIV -> carrier R"
   297     then have "k <= n ==>
   298       (\<Oplus>j \<in> {..k}. (\<Oplus>i \<in> {..j}. a i \<otimes> b (j-i)) \<otimes> c (n-j)) =
   299       (\<Oplus>j \<in> {..k}. a j \<otimes> (\<Oplus>i \<in> {..k-j}. b i \<otimes> c (n-j-i)))"
   300       (concl is "?eq k")
   301     proof (induct k)
   302       case 0 then show ?case by (simp add: Pi_def m_assoc)
   303     next
   304       case (Suc k)
   305       then have "k <= n" by arith
   306       then have "?eq k" by (rule Suc)
   307       with R show ?case
   308         by (simp cong: finsum_cong
   309              add: Suc_diff_le Pi_def l_distr r_distr m_assoc)
   310           (simp cong: finsum_cong add: Pi_def a_ac finsum_ldistr m_assoc)
   311     qed
   312   }
   313   with R show "coeff P ((p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r) n = coeff P (p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)) n"
   314     by (simp add: Pi_def)
   315 qed (simp_all add: R)
   316 
   317 lemma (in UP_cring) UP_l_one [simp]:
   318   assumes R: "p \<in> carrier P"
   319   shows "\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p = p"
   320 proof (rule up_eqI)
   321   fix n
   322   show "coeff P (\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p) n = coeff P p n"
   323   proof (cases n)
   324     case 0 with R show ?thesis by simp
   325   next
   326     case Suc with R show ?thesis
   327       by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)
   328   qed
   329 qed (simp_all add: R)
   330 
   331 lemma (in UP_cring) UP_l_distr:
   332   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   333   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = (p \<otimes>\<^bsub>P\<^esub> r) \<oplus>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   334   by (rule up_eqI) (simp add: l_distr R Pi_def, simp_all add: R)
   335 
   336 lemma (in UP_cring) UP_m_comm:
   337   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   338   shows "p \<otimes>\<^bsub>P\<^esub> q = q \<otimes>\<^bsub>P\<^esub> p"
   339 proof (rule up_eqI)
   340   fix n
   341   {
   342     fix k and a b :: "nat=>'a"
   343     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   344     then have "k <= n ==>
   345       (\<Oplus>i \<in> {..k}. a i \<otimes> b (n-i)) =
   346       (\<Oplus>i \<in> {..k}. a (k-i) \<otimes> b (i+n-k))"
   347       (concl is "?eq k")
   348     proof (induct k)
   349       case 0 then show ?case by (simp add: Pi_def)
   350     next
   351       case (Suc k) then show ?case
   352         by (subst (2) finsum_Suc2) (simp add: Pi_def a_comm)+
   353     qed
   354   }
   355   note l = this
   356   from R show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) n =  coeff P (q \<otimes>\<^bsub>P\<^esub> p) n"
   357     apply (simp add: Pi_def)
   358     apply (subst l)
   359     apply (auto simp add: Pi_def)
   360     apply (simp add: m_comm)
   361     done
   362 qed (simp_all add: R)
   363 
   364 (*
   365 Strange phenomenon in Isar:
   366 
   367 theorem (in UP_cring) UP_cring:
   368   "cring P"
   369 proof (rule cringI)
   370   show "abelian_group P" proof (rule abelian_groupI)
   371   fix x y z
   372   assume "x \<in> carrier P" and "y \<in> carrier P" and "z \<in> carrier P"
   373   {
   374   show "x \<oplus>\<^bsub>P\<^esub> y \<in> carrier P" sorry
   375   next
   376   show "x \<oplus>\<^bsub>P\<^esub> y \<oplus>\<^bsub>P\<^esub> z = x \<oplus>\<^bsub>P\<^esub> (y \<oplus>\<^bsub>P\<^esub> z)" sorry
   377   next
   378   show "x \<oplus>\<^bsub>P\<^esub> y = y \<oplus>\<^bsub>P\<^esub> x" sorry
   379   next
   380   show "\<zero>\<^bsub>P\<^esub> \<oplus>\<^bsub>P\<^esub> x = x" sorry
   381   next
   382   show "\<exists>y\<in>carrier P. y \<oplus>\<^bsub>P\<^esub> x = \<zero>\<^bsub>P\<^esub>" sorry
   383   next
   384   show "\<zero>\<^bsub>P\<^esub> \<in> carrier P" sorry  last goal rejected!!!
   385 *)
   386 
   387 theorem (in UP_cring) UP_cring:
   388   "cring P"
   389   by (auto intro!: cringI abelian_groupI comm_monoidI UP_a_assoc UP_l_zero
   390     UP_l_neg_ex UP_a_comm UP_m_assoc UP_l_one UP_m_comm UP_l_distr)
   391 
   392 lemma (in UP_cring) UP_ring:  (* preliminary *)
   393   "ring P"
   394   by (auto intro: ring.intro cring.axioms UP_cring)
   395 
   396 lemma (in UP_cring) UP_a_inv_closed [intro, simp]:
   397   "p \<in> carrier P ==> \<ominus>\<^bsub>P\<^esub> p \<in> carrier P"
   398   by (rule abelian_group.a_inv_closed
   399     [OF ring.is_abelian_group [OF UP_ring]])
   400 
   401 lemma (in UP_cring) coeff_a_inv [simp]:
   402   assumes R: "p \<in> carrier P"
   403   shows "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> (coeff P p n)"
   404 proof -
   405   from R coeff_closed UP_a_inv_closed have
   406     "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> coeff P p n \<oplus> (coeff P p n \<oplus> coeff P (\<ominus>\<^bsub>P\<^esub> p) n)"
   407     by algebra
   408   also from R have "... =  \<ominus> (coeff P p n)"
   409     by (simp del: coeff_add add: coeff_add [THEN sym]
   410       abelian_group.r_neg [OF ring.is_abelian_group [OF UP_ring]])
   411   finally show ?thesis .
   412 qed
   413 
   414 text {*
   415   Instantiation of lemmas from @{term cring}.
   416 *}
   417 
   418 (* TODO: this should be automated with an instantiation command. *)
   419 
   420 lemma (in UP_cring) UP_monoid:
   421   "monoid P"
   422   by (fast intro!: cring.is_comm_monoid comm_monoid.axioms monoid.intro
   423     UP_cring)
   424 (* TODO: provide cring.is_monoid *)
   425 
   426 lemma (in UP_cring) UP_comm_monoid:
   427   "comm_monoid P"
   428   by (fast intro!: cring.is_comm_monoid UP_cring)
   429 
   430 lemma (in UP_cring) UP_abelian_monoid:
   431   "abelian_monoid P"
   432   by (fast intro!: abelian_group.axioms ring.is_abelian_group UP_ring)
   433 
   434 lemma (in UP_cring) UP_abelian_group:
   435   "abelian_group P"
   436   by (fast intro!: ring.is_abelian_group UP_ring)
   437 
   438 lemmas (in UP_cring) UP_r_one [simp] =
   439   monoid.r_one [OF UP_monoid]
   440 
   441 lemmas (in UP_cring) UP_nat_pow_closed [intro, simp] =
   442   monoid.nat_pow_closed [OF UP_monoid]
   443 
   444 lemmas (in UP_cring) UP_nat_pow_0 [simp] =
   445   monoid.nat_pow_0 [OF UP_monoid]
   446 
   447 lemmas (in UP_cring) UP_nat_pow_Suc [simp] =
   448   monoid.nat_pow_Suc [OF UP_monoid]
   449 
   450 lemmas (in UP_cring) UP_nat_pow_one [simp] =
   451   monoid.nat_pow_one [OF UP_monoid]
   452 
   453 lemmas (in UP_cring) UP_nat_pow_mult =
   454   monoid.nat_pow_mult [OF UP_monoid]
   455 
   456 lemmas (in UP_cring) UP_nat_pow_pow =
   457   monoid.nat_pow_pow [OF UP_monoid]
   458 
   459 lemmas (in UP_cring) UP_m_lcomm =
   460   comm_monoid.m_lcomm [OF UP_comm_monoid]
   461 
   462 lemmas (in UP_cring) UP_m_ac = UP_m_assoc UP_m_comm UP_m_lcomm
   463 
   464 lemmas (in UP_cring) UP_nat_pow_distr =
   465   comm_monoid.nat_pow_distr [OF UP_comm_monoid]
   466 
   467 lemmas (in UP_cring) UP_a_lcomm = abelian_monoid.a_lcomm [OF UP_abelian_monoid]
   468 
   469 lemmas (in UP_cring) UP_r_zero [simp] =
   470   abelian_monoid.r_zero [OF UP_abelian_monoid]
   471 
   472 lemmas (in UP_cring) UP_a_ac = UP_a_assoc UP_a_comm UP_a_lcomm
   473 
   474 lemmas (in UP_cring) UP_finsum_empty [simp] =
   475   abelian_monoid.finsum_empty [OF UP_abelian_monoid]
   476 
   477 lemmas (in UP_cring) UP_finsum_insert [simp] =
   478   abelian_monoid.finsum_insert [OF UP_abelian_monoid]
   479 
   480 lemmas (in UP_cring) UP_finsum_zero [simp] =
   481   abelian_monoid.finsum_zero [OF UP_abelian_monoid]
   482 
   483 lemmas (in UP_cring) UP_finsum_closed [simp] =
   484   abelian_monoid.finsum_closed [OF UP_abelian_monoid]
   485 
   486 lemmas (in UP_cring) UP_finsum_Un_Int =
   487   abelian_monoid.finsum_Un_Int [OF UP_abelian_monoid]
   488 
   489 lemmas (in UP_cring) UP_finsum_Un_disjoint =
   490   abelian_monoid.finsum_Un_disjoint [OF UP_abelian_monoid]
   491 
   492 lemmas (in UP_cring) UP_finsum_addf =
   493   abelian_monoid.finsum_addf [OF UP_abelian_monoid]
   494 
   495 lemmas (in UP_cring) UP_finsum_cong' =
   496   abelian_monoid.finsum_cong' [OF UP_abelian_monoid]
   497 
   498 lemmas (in UP_cring) UP_finsum_0 [simp] =
   499   abelian_monoid.finsum_0 [OF UP_abelian_monoid]
   500 
   501 lemmas (in UP_cring) UP_finsum_Suc [simp] =
   502   abelian_monoid.finsum_Suc [OF UP_abelian_monoid]
   503 
   504 lemmas (in UP_cring) UP_finsum_Suc2 =
   505   abelian_monoid.finsum_Suc2 [OF UP_abelian_monoid]
   506 
   507 lemmas (in UP_cring) UP_finsum_add [simp] =
   508   abelian_monoid.finsum_add [OF UP_abelian_monoid]
   509 
   510 lemmas (in UP_cring) UP_finsum_cong =
   511   abelian_monoid.finsum_cong [OF UP_abelian_monoid]
   512 
   513 lemmas (in UP_cring) UP_minus_closed [intro, simp] =
   514   abelian_group.minus_closed [OF UP_abelian_group]
   515 
   516 lemmas (in UP_cring) UP_a_l_cancel [simp] =
   517   abelian_group.a_l_cancel [OF UP_abelian_group]
   518 
   519 lemmas (in UP_cring) UP_a_r_cancel [simp] =
   520   abelian_group.a_r_cancel [OF UP_abelian_group]
   521 
   522 lemmas (in UP_cring) UP_l_neg =
   523   abelian_group.l_neg [OF UP_abelian_group]
   524 
   525 lemmas (in UP_cring) UP_r_neg =
   526   abelian_group.r_neg [OF UP_abelian_group]
   527 
   528 lemmas (in UP_cring) UP_minus_zero [simp] =
   529   abelian_group.minus_zero [OF UP_abelian_group]
   530 
   531 lemmas (in UP_cring) UP_minus_minus [simp] =
   532   abelian_group.minus_minus [OF UP_abelian_group]
   533 
   534 lemmas (in UP_cring) UP_minus_add =
   535   abelian_group.minus_add [OF UP_abelian_group]
   536 
   537 lemmas (in UP_cring) UP_r_neg2 =
   538   abelian_group.r_neg2 [OF UP_abelian_group]
   539 
   540 lemmas (in UP_cring) UP_r_neg1 =
   541   abelian_group.r_neg1 [OF UP_abelian_group]
   542 
   543 lemmas (in UP_cring) UP_r_distr =
   544   ring.r_distr [OF UP_ring]
   545 
   546 lemmas (in UP_cring) UP_l_null [simp] =
   547   ring.l_null [OF UP_ring]
   548 
   549 lemmas (in UP_cring) UP_r_null [simp] =
   550   ring.r_null [OF UP_ring]
   551 
   552 lemmas (in UP_cring) UP_l_minus =
   553   ring.l_minus [OF UP_ring]
   554 
   555 lemmas (in UP_cring) UP_r_minus =
   556   ring.r_minus [OF UP_ring]
   557 
   558 lemmas (in UP_cring) UP_finsum_ldistr =
   559   cring.finsum_ldistr [OF UP_cring]
   560 
   561 lemmas (in UP_cring) UP_finsum_rdistr =
   562   cring.finsum_rdistr [OF UP_cring]
   563 
   564 
   565 subsection {* Polynomials form an Algebra *}
   566 
   567 lemma (in UP_cring) UP_smult_l_distr:
   568   "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   569   (a \<oplus> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> b \<odot>\<^bsub>P\<^esub> p"
   570   by (rule up_eqI) (simp_all add: R.l_distr)
   571 
   572 lemma (in UP_cring) UP_smult_r_distr:
   573   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   574   a \<odot>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> a \<odot>\<^bsub>P\<^esub> q"
   575   by (rule up_eqI) (simp_all add: R.r_distr)
   576 
   577 lemma (in UP_cring) UP_smult_assoc1:
   578       "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   579       (a \<otimes> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> p)"
   580   by (rule up_eqI) (simp_all add: R.m_assoc)
   581 
   582 lemma (in UP_cring) UP_smult_one [simp]:
   583       "p \<in> carrier P ==> \<one> \<odot>\<^bsub>P\<^esub> p = p"
   584   by (rule up_eqI) simp_all
   585 
   586 lemma (in UP_cring) UP_smult_assoc2:
   587   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   588   (a \<odot>\<^bsub>P\<^esub> p) \<otimes>\<^bsub>P\<^esub> q = a \<odot>\<^bsub>P\<^esub> (p \<otimes>\<^bsub>P\<^esub> q)"
   589   by (rule up_eqI) (simp_all add: R.finsum_rdistr R.m_assoc Pi_def)
   590 
   591 text {*
   592   Instantiation of lemmas from @{term algebra}.
   593 *}
   594 
   595 (* TODO: this should be automated with an instantiation command. *)
   596 
   597 (* TODO: move to CRing.thy, really a fact missing from the locales package *)
   598 lemma (in cring) cring:
   599   "cring R"
   600   by (fast intro: cring.intro prems)
   601 
   602 lemma (in UP_cring) UP_algebra:
   603   "algebra R P"
   604   by (auto intro: algebraI cring UP_cring UP_smult_l_distr UP_smult_r_distr
   605     UP_smult_assoc1 UP_smult_assoc2)
   606 
   607 lemmas (in UP_cring) UP_smult_l_null [simp] =
   608   algebra.smult_l_null [OF UP_algebra]
   609 
   610 lemmas (in UP_cring) UP_smult_r_null [simp] =
   611   algebra.smult_r_null [OF UP_algebra]
   612 
   613 lemmas (in UP_cring) UP_smult_l_minus =
   614   algebra.smult_l_minus [OF UP_algebra]
   615 
   616 lemmas (in UP_cring) UP_smult_r_minus =
   617   algebra.smult_r_minus [OF UP_algebra]
   618 
   619 subsection {* Further lemmas involving monomials *}
   620 
   621 lemma (in UP_cring) monom_zero [simp]:
   622   "monom P \<zero> n = \<zero>\<^bsub>P\<^esub>"
   623   by (simp add: UP_def P_def)
   624 
   625 lemma (in UP_cring) monom_mult_is_smult:
   626   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   627   shows "monom P a 0 \<otimes>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p"
   628 proof (rule up_eqI)
   629   fix n
   630   have "coeff P (p \<otimes>\<^bsub>P\<^esub> monom P a 0) n = coeff P (a \<odot>\<^bsub>P\<^esub> p) n"
   631   proof (cases n)
   632     case 0 with R show ?thesis by (simp add: R.m_comm)
   633   next
   634     case Suc with R show ?thesis
   635       by (simp cong: finsum_cong add: R.r_null Pi_def)
   636         (simp add: m_comm)
   637   qed
   638   with R show "coeff P (monom P a 0 \<otimes>\<^bsub>P\<^esub> p) n = coeff P (a \<odot>\<^bsub>P\<^esub> p) n"
   639     by (simp add: UP_m_comm)
   640 qed (simp_all add: R)
   641 
   642 lemma (in UP_cring) monom_add [simp]:
   643   "[| a \<in> carrier R; b \<in> carrier R |] ==>
   644   monom P (a \<oplus> b) n = monom P a n \<oplus>\<^bsub>P\<^esub> monom P b n"
   645   by (rule up_eqI) simp_all
   646 
   647 lemma (in UP_cring) monom_one_Suc:
   648   "monom P \<one> (Suc n) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   649 proof (rule up_eqI)
   650   fix k
   651   show "coeff P (monom P \<one> (Suc n)) k = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   652   proof (cases "k = Suc n")
   653     case True show ?thesis
   654     proof -
   655       from True have less_add_diff:
   656         "!!i. [| n < i; i <= n + m |] ==> n + m - i < m" by arith
   657       from True have "coeff P (monom P \<one> (Suc n)) k = \<one>" by simp
   658       also from True
   659       have "... = (\<Oplus>i \<in> {..<n} \<union> {n}. coeff P (monom P \<one> n) i \<otimes>
   660         coeff P (monom P \<one> 1) (k - i))"
   661         by (simp cong: finsum_cong add: finsum_Un_disjoint Pi_def)
   662       also have "... = (\<Oplus>i \<in>  {..n}. coeff P (monom P \<one> n) i \<otimes>
   663         coeff P (monom P \<one> 1) (k - i))"
   664         by (simp only: ivl_disj_un_singleton)
   665       also from True
   666       have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. coeff P (monom P \<one> n) i \<otimes>
   667         coeff P (monom P \<one> 1) (k - i))"
   668         by (simp cong: finsum_cong add: finsum_Un_disjoint ivl_disj_int_one
   669           order_less_imp_not_eq Pi_def)
   670       also from True have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   671         by (simp add: ivl_disj_un_one)
   672       finally show ?thesis .
   673     qed
   674   next
   675     case False
   676     note neq = False
   677     let ?s =
   678       "\<lambda>i. (if n = i then \<one> else \<zero>) \<otimes> (if Suc 0 = k - i then \<one> else \<zero>)"
   679     from neq have "coeff P (monom P \<one> (Suc n)) k = \<zero>" by simp
   680     also have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   681     proof -
   682       have f1: "(\<Oplus>i \<in> {..<n}. ?s i) = \<zero>"
   683         by (simp cong: finsum_cong add: Pi_def)
   684       from neq have f2: "(\<Oplus>i \<in> {n}. ?s i) = \<zero>"
   685         by (simp cong: finsum_cong add: Pi_def) arith
   686       have f3: "n < k ==> (\<Oplus>i \<in> {n<..k}. ?s i) = \<zero>"
   687         by (simp cong: finsum_cong add: order_less_imp_not_eq Pi_def)
   688       show ?thesis
   689       proof (cases "k < n")
   690         case True then show ?thesis by (simp cong: finsum_cong add: Pi_def)
   691       next
   692         case False then have n_le_k: "n <= k" by arith
   693         show ?thesis
   694         proof (cases "n = k")
   695           case True
   696           then have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   697             by (simp cong: finsum_cong add: finsum_Un_disjoint
   698               ivl_disj_int_singleton Pi_def)
   699           also from True have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   700             by (simp only: ivl_disj_un_singleton)
   701           finally show ?thesis .
   702         next
   703           case False with n_le_k have n_less_k: "n < k" by arith
   704           with neq have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   705             by (simp add: finsum_Un_disjoint f1 f2
   706               ivl_disj_int_singleton Pi_def del: Un_insert_right)
   707           also have "... = (\<Oplus>i \<in> {..n}. ?s i)"
   708             by (simp only: ivl_disj_un_singleton)
   709           also from n_less_k neq have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. ?s i)"
   710             by (simp add: finsum_Un_disjoint f3 ivl_disj_int_one Pi_def)
   711           also from n_less_k have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   712             by (simp only: ivl_disj_un_one)
   713           finally show ?thesis .
   714         qed
   715       qed
   716     qed
   717     also have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k" by simp
   718     finally show ?thesis .
   719   qed
   720 qed (simp_all)
   721 
   722 lemma (in UP_cring) monom_mult_smult:
   723   "[| a \<in> carrier R; b \<in> carrier R |] ==> monom P (a \<otimes> b) n = a \<odot>\<^bsub>P\<^esub> monom P b n"
   724   by (rule up_eqI) simp_all
   725 
   726 lemma (in UP_cring) monom_one [simp]:
   727   "monom P \<one> 0 = \<one>\<^bsub>P\<^esub>"
   728   by (rule up_eqI) simp_all
   729 
   730 lemma (in UP_cring) monom_one_mult:
   731   "monom P \<one> (n + m) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m"
   732 proof (induct n)
   733   case 0 show ?case by simp
   734 next
   735   case Suc then show ?case
   736     by (simp only: add_Suc monom_one_Suc) (simp add: UP_m_ac)
   737 qed
   738 
   739 lemma (in UP_cring) monom_mult [simp]:
   740   assumes R: "a \<in> carrier R" "b \<in> carrier R"
   741   shows "monom P (a \<otimes> b) (n + m) = monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m"
   742 proof -
   743   from R have "monom P (a \<otimes> b) (n + m) = monom P (a \<otimes> b \<otimes> \<one>) (n + m)" by simp
   744   also from R have "... = a \<otimes> b \<odot>\<^bsub>P\<^esub> monom P \<one> (n + m)"
   745     by (simp add: monom_mult_smult del: r_one)
   746   also have "... = a \<otimes> b \<odot>\<^bsub>P\<^esub> (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m)"
   747     by (simp only: monom_one_mult)
   748   also from R have "... = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m))"
   749     by (simp add: UP_smult_assoc1)
   750   also from R have "... = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> (monom P \<one> m \<otimes>\<^bsub>P\<^esub> monom P \<one> n))"
   751     by (simp add: UP_m_comm)
   752   also from R have "... = a \<odot>\<^bsub>P\<^esub> ((b \<odot>\<^bsub>P\<^esub> monom P \<one> m) \<otimes>\<^bsub>P\<^esub> monom P \<one> n)"
   753     by (simp add: UP_smult_assoc2)
   754   also from R have "... = a \<odot>\<^bsub>P\<^esub> (monom P \<one> n \<otimes>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> monom P \<one> m))"
   755     by (simp add: UP_m_comm)
   756   also from R have "... = (a \<odot>\<^bsub>P\<^esub> monom P \<one> n) \<otimes>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> monom P \<one> m)"
   757     by (simp add: UP_smult_assoc2)
   758   also from R have "... = monom P (a \<otimes> \<one>) n \<otimes>\<^bsub>P\<^esub> monom P (b \<otimes> \<one>) m"
   759     by (simp add: monom_mult_smult del: r_one)
   760   also from R have "... = monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m" by simp
   761   finally show ?thesis .
   762 qed
   763 
   764 lemma (in UP_cring) monom_a_inv [simp]:
   765   "a \<in> carrier R ==> monom P (\<ominus> a) n = \<ominus>\<^bsub>P\<^esub> monom P a n"
   766   by (rule up_eqI) simp_all
   767 
   768 lemma (in UP_cring) monom_inj:
   769   "inj_on (%a. monom P a n) (carrier R)"
   770 proof (rule inj_onI)
   771   fix x y
   772   assume R: "x \<in> carrier R" "y \<in> carrier R" and eq: "monom P x n = monom P y n"
   773   then have "coeff P (monom P x n) n = coeff P (monom P y n) n" by simp
   774   with R show "x = y" by simp
   775 qed
   776 
   777 subsection {* The degree function *}
   778 
   779 constdefs (structure R)
   780   deg :: "[('a, 'm) ring_scheme, nat => 'a] => nat"
   781   "deg R p == LEAST n. bound \<zero> n (coeff (UP R) p)"
   782 
   783 lemma (in UP_cring) deg_aboveI:
   784   "[| (!!m. n < m ==> coeff P p m = \<zero>); p \<in> carrier P |] ==> deg R p <= n"
   785   by (unfold deg_def P_def) (fast intro: Least_le)
   786 
   787 (*
   788 lemma coeff_bound_ex: "EX n. bound n (coeff p)"
   789 proof -
   790   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   791   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   792   then show ?thesis ..
   793 qed
   794 
   795 lemma bound_coeff_obtain:
   796   assumes prem: "(!!n. bound n (coeff p) ==> P)" shows "P"
   797 proof -
   798   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   799   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   800   with prem show P .
   801 qed
   802 *)
   803 
   804 lemma (in UP_cring) deg_aboveD:
   805   "[| deg R p < m; p \<in> carrier P |] ==> coeff P p m = \<zero>"
   806 proof -
   807   assume R: "p \<in> carrier P" and "deg R p < m"
   808   from R obtain n where "bound \<zero> n (coeff P p)"
   809     by (auto simp add: UP_def P_def)
   810   then have "bound \<zero> (deg R p) (coeff P p)"
   811     by (auto simp: deg_def P_def dest: LeastI)
   812   then show ?thesis ..
   813 qed
   814 
   815 lemma (in UP_cring) deg_belowI:
   816   assumes non_zero: "n ~= 0 ==> coeff P p n ~= \<zero>"
   817     and R: "p \<in> carrier P"
   818   shows "n <= deg R p"
   819 -- {* Logically, this is a slightly stronger version of
   820    @{thm [source] deg_aboveD} *}
   821 proof (cases "n=0")
   822   case True then show ?thesis by simp
   823 next
   824   case False then have "coeff P p n ~= \<zero>" by (rule non_zero)
   825   then have "~ deg R p < n" by (fast dest: deg_aboveD intro: R)
   826   then show ?thesis by arith
   827 qed
   828 
   829 lemma (in UP_cring) lcoeff_nonzero_deg:
   830   assumes deg: "deg R p ~= 0" and R: "p \<in> carrier P"
   831   shows "coeff P p (deg R p) ~= \<zero>"
   832 proof -
   833   from R obtain m where "deg R p <= m" and m_coeff: "coeff P p m ~= \<zero>"
   834   proof -
   835     have minus: "!!(n::nat) m. n ~= 0 ==> (n - Suc 0 < m) = (n <= m)"
   836       by arith
   837 (* TODO: why does simplification below not work with "1" *)
   838     from deg have "deg R p - 1 < (LEAST n. bound \<zero> n (coeff P p))"
   839       by (unfold deg_def P_def) arith
   840     then have "~ bound \<zero> (deg R p - 1) (coeff P p)" by (rule not_less_Least)
   841     then have "EX m. deg R p - 1 < m & coeff P p m ~= \<zero>"
   842       by (unfold bound_def) fast
   843     then have "EX m. deg R p <= m & coeff P p m ~= \<zero>" by (simp add: deg minus)
   844     then show ?thesis by auto
   845   qed
   846   with deg_belowI R have "deg R p = m" by fastsimp
   847   with m_coeff show ?thesis by simp
   848 qed
   849 
   850 lemma (in UP_cring) lcoeff_nonzero_nonzero:
   851   assumes deg: "deg R p = 0" and nonzero: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   852   shows "coeff P p 0 ~= \<zero>"
   853 proof -
   854   have "EX m. coeff P p m ~= \<zero>"
   855   proof (rule classical)
   856     assume "~ ?thesis"
   857     with R have "p = \<zero>\<^bsub>P\<^esub>" by (auto intro: up_eqI)
   858     with nonzero show ?thesis by contradiction
   859   qed
   860   then obtain m where coeff: "coeff P p m ~= \<zero>" ..
   861   then have "m <= deg R p" by (rule deg_belowI)
   862   then have "m = 0" by (simp add: deg)
   863   with coeff show ?thesis by simp
   864 qed
   865 
   866 lemma (in UP_cring) lcoeff_nonzero:
   867   assumes neq: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   868   shows "coeff P p (deg R p) ~= \<zero>"
   869 proof (cases "deg R p = 0")
   870   case True with neq R show ?thesis by (simp add: lcoeff_nonzero_nonzero)
   871 next
   872   case False with neq R show ?thesis by (simp add: lcoeff_nonzero_deg)
   873 qed
   874 
   875 lemma (in UP_cring) deg_eqI:
   876   "[| !!m. n < m ==> coeff P p m = \<zero>;
   877       !!n. n ~= 0 ==> coeff P p n ~= \<zero>; p \<in> carrier P |] ==> deg R p = n"
   878 by (fast intro: le_anti_sym deg_aboveI deg_belowI)
   879 
   880 (* Degree and polynomial operations *)
   881 
   882 lemma (in UP_cring) deg_add [simp]:
   883   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   884   shows "deg R (p \<oplus>\<^bsub>P\<^esub> q) <= max (deg R p) (deg R q)"
   885 proof (cases "deg R p <= deg R q")
   886   case True show ?thesis
   887     by (rule deg_aboveI) (simp_all add: True R deg_aboveD)
   888 next
   889   case False show ?thesis
   890     by (rule deg_aboveI) (simp_all add: False R deg_aboveD)
   891 qed
   892 
   893 lemma (in UP_cring) deg_monom_le:
   894   "a \<in> carrier R ==> deg R (monom P a n) <= n"
   895   by (intro deg_aboveI) simp_all
   896 
   897 lemma (in UP_cring) deg_monom [simp]:
   898   "[| a ~= \<zero>; a \<in> carrier R |] ==> deg R (monom P a n) = n"
   899   by (fastsimp intro: le_anti_sym deg_aboveI deg_belowI)
   900 
   901 lemma (in UP_cring) deg_const [simp]:
   902   assumes R: "a \<in> carrier R" shows "deg R (monom P a 0) = 0"
   903 proof (rule le_anti_sym)
   904   show "deg R (monom P a 0) <= 0" by (rule deg_aboveI) (simp_all add: R)
   905 next
   906   show "0 <= deg R (monom P a 0)" by (rule deg_belowI) (simp_all add: R)
   907 qed
   908 
   909 lemma (in UP_cring) deg_zero [simp]:
   910   "deg R \<zero>\<^bsub>P\<^esub> = 0"
   911 proof (rule le_anti_sym)
   912   show "deg R \<zero>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   913 next
   914   show "0 <= deg R \<zero>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   915 qed
   916 
   917 lemma (in UP_cring) deg_one [simp]:
   918   "deg R \<one>\<^bsub>P\<^esub> = 0"
   919 proof (rule le_anti_sym)
   920   show "deg R \<one>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   921 next
   922   show "0 <= deg R \<one>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   923 qed
   924 
   925 lemma (in UP_cring) deg_uminus [simp]:
   926   assumes R: "p \<in> carrier P" shows "deg R (\<ominus>\<^bsub>P\<^esub> p) = deg R p"
   927 proof (rule le_anti_sym)
   928   show "deg R (\<ominus>\<^bsub>P\<^esub> p) <= deg R p" by (simp add: deg_aboveI deg_aboveD R)
   929 next
   930   show "deg R p <= deg R (\<ominus>\<^bsub>P\<^esub> p)"
   931     by (simp add: deg_belowI lcoeff_nonzero_deg
   932       inj_on_iff [OF a_inv_inj, of _ "\<zero>", simplified] R)
   933 qed
   934 
   935 lemma (in UP_domain) deg_smult_ring:
   936   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   937   deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   938   by (cases "a = \<zero>") (simp add: deg_aboveI deg_aboveD)+
   939 
   940 lemma (in UP_domain) deg_smult [simp]:
   941   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   942   shows "deg R (a \<odot>\<^bsub>P\<^esub> p) = (if a = \<zero> then 0 else deg R p)"
   943 proof (rule le_anti_sym)
   944   show "deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   945     by (rule deg_smult_ring)
   946 next
   947   show "(if a = \<zero> then 0 else deg R p) <= deg R (a \<odot>\<^bsub>P\<^esub> p)"
   948   proof (cases "a = \<zero>")
   949   qed (simp, simp add: deg_belowI lcoeff_nonzero_deg integral_iff R)
   950 qed
   951 
   952 lemma (in UP_cring) deg_mult_cring:
   953   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   954   shows "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q"
   955 proof (rule deg_aboveI)
   956   fix m
   957   assume boundm: "deg R p + deg R q < m"
   958   {
   959     fix k i
   960     assume boundk: "deg R p + deg R q < k"
   961     then have "coeff P p i \<otimes> coeff P q (k - i) = \<zero>"
   962     proof (cases "deg R p < i")
   963       case True then show ?thesis by (simp add: deg_aboveD R)
   964     next
   965       case False with boundk have "deg R q < k - i" by arith
   966       then show ?thesis by (simp add: deg_aboveD R)
   967     qed
   968   }
   969   with boundm R show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) m = \<zero>" by simp
   970 qed (simp add: R)
   971 
   972 lemma (in UP_domain) deg_mult [simp]:
   973   "[| p ~= \<zero>\<^bsub>P\<^esub>; q ~= \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==>
   974   deg R (p \<otimes>\<^bsub>P\<^esub> q) = deg R p + deg R q"
   975 proof (rule le_anti_sym)
   976   assume "p \<in> carrier P" " q \<in> carrier P"
   977   show "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q" by (rule deg_mult_cring)
   978 next
   979   let ?s = "(%i. coeff P p i \<otimes> coeff P q (deg R p + deg R q - i))"
   980   assume R: "p \<in> carrier P" "q \<in> carrier P" and nz: "p ~= \<zero>\<^bsub>P\<^esub>" "q ~= \<zero>\<^bsub>P\<^esub>"
   981   have less_add_diff: "!!(k::nat) n m. k < n ==> m < n + m - k" by arith
   982   show "deg R p + deg R q <= deg R (p \<otimes>\<^bsub>P\<^esub> q)"
   983   proof (rule deg_belowI, simp add: R)
   984     have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   985       = (\<Oplus>i \<in> {..< deg R p} \<union> {deg R p .. deg R p + deg R q}. ?s i)"
   986       by (simp only: ivl_disj_un_one)
   987     also have "... = (\<Oplus>i \<in> {deg R p .. deg R p + deg R q}. ?s i)"
   988       by (simp cong: finsum_cong add: finsum_Un_disjoint ivl_disj_int_one
   989         deg_aboveD less_add_diff R Pi_def)
   990     also have "...= (\<Oplus>i \<in> {deg R p} \<union> {deg R p <.. deg R p + deg R q}. ?s i)"
   991       by (simp only: ivl_disj_un_singleton)
   992     also have "... = coeff P p (deg R p) \<otimes> coeff P q (deg R q)"
   993       by (simp cong: finsum_cong add: finsum_Un_disjoint
   994         ivl_disj_int_singleton deg_aboveD R Pi_def)
   995     finally have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   996       = coeff P p (deg R p) \<otimes> coeff P q (deg R q)" .
   997     with nz show "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i) ~= \<zero>"
   998       by (simp add: integral_iff lcoeff_nonzero R)
   999     qed (simp add: R)
  1000   qed
  1001 
  1002 lemma (in UP_cring) coeff_finsum:
  1003   assumes fin: "finite A"
  1004   shows "p \<in> A -> carrier P ==>
  1005     coeff P (finsum P p A) k = (\<Oplus>i \<in> A. coeff P (p i) k)"
  1006   using fin by induct (auto simp: Pi_def)
  1007 
  1008 lemma (in UP_cring) up_repr:
  1009   assumes R: "p \<in> carrier P"
  1010   shows "(\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. monom P (coeff P p i) i) = p"
  1011 proof (rule up_eqI)
  1012   let ?s = "(%i. monom P (coeff P p i) i)"
  1013   fix k
  1014   from R have RR: "!!i. (if i = k then coeff P p i else \<zero>) \<in> carrier R"
  1015     by simp
  1016   show "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k = coeff P p k"
  1017   proof (cases "k <= deg R p")
  1018     case True
  1019     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
  1020           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k} \<union> {k<..deg R p}. ?s i) k"
  1021       by (simp only: ivl_disj_un_one)
  1022     also from True
  1023     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k}. ?s i) k"
  1024       by (simp cong: finsum_cong add: finsum_Un_disjoint
  1025         ivl_disj_int_one order_less_imp_not_eq2 coeff_finsum R RR Pi_def)
  1026     also
  1027     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<k} \<union> {k}. ?s i) k"
  1028       by (simp only: ivl_disj_un_singleton)
  1029     also have "... = coeff P p k"
  1030       by (simp cong: finsum_cong add: setsum_Un_disjoint
  1031         ivl_disj_int_singleton coeff_finsum deg_aboveD R RR Pi_def)
  1032     finally show ?thesis .
  1033   next
  1034     case False
  1035     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
  1036           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<deg R p} \<union> {deg R p}. ?s i) k"
  1037       by (simp only: ivl_disj_un_singleton)
  1038     also from False have "... = coeff P p k"
  1039       by (simp cong: finsum_cong add: setsum_Un_disjoint ivl_disj_int_singleton
  1040         coeff_finsum deg_aboveD R Pi_def)
  1041     finally show ?thesis .
  1042   qed
  1043 qed (simp_all add: R Pi_def)
  1044 
  1045 lemma (in UP_cring) up_repr_le:
  1046   "[| deg R p <= n; p \<in> carrier P |] ==>
  1047   (\<Oplus>\<^bsub>P\<^esub> i \<in> {..n}. monom P (coeff P p i) i) = p"
  1048 proof -
  1049   let ?s = "(%i. monom P (coeff P p i) i)"
  1050   assume R: "p \<in> carrier P" and "deg R p <= n"
  1051   then have "finsum P ?s {..n} = finsum P ?s ({..deg R p} \<union> {deg R p<..n})"
  1052     by (simp only: ivl_disj_un_one)
  1053   also have "... = finsum P ?s {..deg R p}"
  1054     by (simp cong: UP_finsum_cong add: UP_finsum_Un_disjoint ivl_disj_int_one
  1055       deg_aboveD R Pi_def)
  1056   also have "... = p" by (rule up_repr)
  1057   finally show ?thesis .
  1058 qed
  1059 
  1060 subsection {* Polynomials over an integral domain form an integral domain *}
  1061 
  1062 lemma domainI:
  1063   assumes cring: "cring R"
  1064     and one_not_zero: "one R ~= zero R"
  1065     and integral: "!!a b. [| mult R a b = zero R; a \<in> carrier R;
  1066       b \<in> carrier R |] ==> a = zero R | b = zero R"
  1067   shows "domain R"
  1068   by (auto intro!: domain.intro domain_axioms.intro cring.axioms prems
  1069     del: disjCI)
  1070 
  1071 lemma (in UP_domain) UP_one_not_zero:
  1072   "\<one>\<^bsub>P\<^esub> ~= \<zero>\<^bsub>P\<^esub>"
  1073 proof
  1074   assume "\<one>\<^bsub>P\<^esub> = \<zero>\<^bsub>P\<^esub>"
  1075   hence "coeff P \<one>\<^bsub>P\<^esub> 0 = (coeff P \<zero>\<^bsub>P\<^esub> 0)" by simp
  1076   hence "\<one> = \<zero>" by simp
  1077   with one_not_zero show "False" by contradiction
  1078 qed
  1079 
  1080 lemma (in UP_domain) UP_integral:
  1081   "[| p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==> p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
  1082 proof -
  1083   fix p q
  1084   assume pq: "p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P" "q \<in> carrier P"
  1085   show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
  1086   proof (rule classical)
  1087     assume c: "~ (p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>)"
  1088     with R have "deg R p + deg R q = deg R (p \<otimes>\<^bsub>P\<^esub> q)" by simp
  1089     also from pq have "... = 0" by simp
  1090     finally have "deg R p + deg R q = 0" .
  1091     then have f1: "deg R p = 0 & deg R q = 0" by simp
  1092     from f1 R have "p = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P p i) i)"
  1093       by (simp only: up_repr_le)
  1094     also from R have "... = monom P (coeff P p 0) 0" by simp
  1095     finally have p: "p = monom P (coeff P p 0) 0" .
  1096     from f1 R have "q = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P q i) i)"
  1097       by (simp only: up_repr_le)
  1098     also from R have "... = monom P (coeff P q 0) 0" by simp
  1099     finally have q: "q = monom P (coeff P q 0) 0" .
  1100     from R have "coeff P p 0 \<otimes> coeff P q 0 = coeff P (p \<otimes>\<^bsub>P\<^esub> q) 0" by simp
  1101     also from pq have "... = \<zero>" by simp
  1102     finally have "coeff P p 0 \<otimes> coeff P q 0 = \<zero>" .
  1103     with R have "coeff P p 0 = \<zero> | coeff P q 0 = \<zero>"
  1104       by (simp add: R.integral_iff)
  1105     with p q show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>" by fastsimp
  1106   qed
  1107 qed
  1108 
  1109 theorem (in UP_domain) UP_domain:
  1110   "domain P"
  1111   by (auto intro!: domainI UP_cring UP_one_not_zero UP_integral del: disjCI)
  1112 
  1113 text {*
  1114   Instantiation of theorems from @{term domain}.
  1115 *}
  1116 
  1117 (* TODO: this should be automated with an instantiation command. *)
  1118 
  1119 lemmas (in UP_domain) UP_zero_not_one [simp] =
  1120   domain.zero_not_one [OF UP_domain]
  1121 
  1122 lemmas (in UP_domain) UP_integral_iff =
  1123   domain.integral_iff [OF UP_domain]
  1124 
  1125 lemmas (in UP_domain) UP_m_lcancel =
  1126   domain.m_lcancel [OF UP_domain]
  1127 
  1128 lemmas (in UP_domain) UP_m_rcancel =
  1129   domain.m_rcancel [OF UP_domain]
  1130 
  1131 lemma (in UP_domain) smult_integral:
  1132   "[| a \<odot>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>; a \<in> carrier R; p \<in> carrier P |] ==> a = \<zero> | p = \<zero>\<^bsub>P\<^esub>"
  1133   by (simp add: monom_mult_is_smult [THEN sym] UP_integral_iff
  1134     inj_on_iff [OF monom_inj, of _ "\<zero>", simplified])
  1135 
  1136 
  1137 subsection {* Evaluation Homomorphism and Universal Property*}
  1138 
  1139 (* alternative congruence rule (possibly more efficient)
  1140 lemma (in abelian_monoid) finsum_cong2:
  1141   "[| !!i. i \<in> A ==> f i \<in> carrier G = True; A = B;
  1142   !!i. i \<in> B ==> f i = g i |] ==> finsum G f A = finsum G g B"
  1143   sorry*)
  1144 
  1145 theorem (in cring) diagonal_sum:
  1146   "[| f \<in> {..n + m::nat} -> carrier R; g \<in> {..n + m} -> carrier R |] ==>
  1147   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1148   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1149 proof -
  1150   assume Rf: "f \<in> {..n + m} -> carrier R" and Rg: "g \<in> {..n + m} -> carrier R"
  1151   {
  1152     fix j
  1153     have "j <= n + m ==>
  1154       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1155       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..j - k}. f k \<otimes> g i)"
  1156     proof (induct j)
  1157       case 0 from Rf Rg show ?case by (simp add: Pi_def)
  1158     next
  1159       case (Suc j)
  1160       have R6: "!!i k. [| k <= j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1161         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
  1162       have R8: "!!i k. [| k <= Suc j; i <= k |] ==> g (k - i) \<in> carrier R"
  1163         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
  1164       have R9: "!!i k. [| k <= Suc j |] ==> f k \<in> carrier R"
  1165         using Suc by (auto intro!: funcset_mem [OF Rf])
  1166       have R10: "!!i k. [| k <= Suc j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1167         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
  1168       have R11: "g 0 \<in> carrier R"
  1169         using Suc by (auto intro!: funcset_mem [OF Rg])
  1170       from Suc show ?case
  1171         by (simp cong: finsum_cong add: Suc_diff_le a_ac
  1172           Pi_def R6 R8 R9 R10 R11)
  1173     qed
  1174   }
  1175   then show ?thesis by fast
  1176 qed
  1177 
  1178 lemma (in abelian_monoid) boundD_carrier:
  1179   "[| bound \<zero> n f; n < m |] ==> f m \<in> carrier G"
  1180   by auto
  1181 
  1182 theorem (in cring) cauchy_product:
  1183   assumes bf: "bound \<zero> n f" and bg: "bound \<zero> m g"
  1184     and Rf: "f \<in> {..n} -> carrier R" and Rg: "g \<in> {..m} -> carrier R"
  1185   shows "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1186     (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"       (* State revese direction? *)
  1187 proof -
  1188   have f: "!!x. f x \<in> carrier R"
  1189   proof -
  1190     fix x
  1191     show "f x \<in> carrier R"
  1192       using Rf bf boundD_carrier by (cases "x <= n") (auto simp: Pi_def)
  1193   qed
  1194   have g: "!!x. g x \<in> carrier R"
  1195   proof -
  1196     fix x
  1197     show "g x \<in> carrier R"
  1198       using Rg bg boundD_carrier by (cases "x <= m") (auto simp: Pi_def)
  1199   qed
  1200   from f g have "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1201       (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1202     by (simp add: diagonal_sum Pi_def)
  1203   also have "... = (\<Oplus>k \<in> {..n} \<union> {n<..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1204     by (simp only: ivl_disj_un_one)
  1205   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1206     by (simp cong: finsum_cong
  1207       add: bound.bound [OF bf] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1208   also from f g
  1209   have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m} \<union> {m<..n + m - k}. f k \<otimes> g i)"
  1210     by (simp cong: finsum_cong add: ivl_disj_un_one le_add_diff Pi_def)
  1211   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m}. f k \<otimes> g i)"
  1212     by (simp cong: finsum_cong
  1213       add: bound.bound [OF bg] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1214   also from f g have "... = (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"
  1215     by (simp add: finsum_ldistr diagonal_sum Pi_def,
  1216       simp cong: finsum_cong add: finsum_rdistr Pi_def)
  1217   finally show ?thesis .
  1218 qed
  1219 
  1220 lemma (in UP_cring) const_ring_hom:
  1221   "(%a. monom P a 0) \<in> ring_hom R P"
  1222   by (auto intro!: ring_hom_memI intro: up_eqI simp: monom_mult_is_smult)
  1223 
  1224 constdefs (structure S)
  1225   eval :: "[('a, 'm) ring_scheme, ('b, 'n) ring_scheme,
  1226            'a => 'b, 'b, nat => 'a] => 'b"
  1227   "eval R S phi s == \<lambda>p \<in> carrier (UP R).
  1228     \<Oplus>i \<in> {..deg R p}. phi (coeff (UP R) p i) \<otimes> s (^) i"
  1229 
  1230 locale UP_univ_prop = ring_hom_cring R S + UP_cring R
  1231 
  1232 lemma (in UP) eval_on_carrier:
  1233   includes struct S
  1234   shows  "p \<in> carrier P ==>
  1235     eval R S phi s p =
  1236     (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. phi (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1237   by (unfold eval_def, fold P_def) simp
  1238 
  1239 lemma (in UP) eval_extensional:
  1240   "eval R S phi s \<in> extensional (carrier P)"
  1241   by (unfold eval_def, fold P_def) simp
  1242 
  1243 theorem (in UP_univ_prop) eval_ring_hom:
  1244   "s \<in> carrier S ==> eval R S h s \<in> ring_hom P S"
  1245 proof (rule ring_hom_memI)
  1246   fix p
  1247   assume RS: "p \<in> carrier P" "s \<in> carrier S"
  1248   then show "eval R S h s p \<in> carrier S"
  1249     by (simp only: eval_on_carrier) (simp add: Pi_def)
  1250 next
  1251   fix p q
  1252   assume RS: "p \<in> carrier P" "q \<in> carrier P" "s \<in> carrier S"
  1253   then show "eval R S h s (p \<otimes>\<^bsub>P\<^esub> q) = eval R S h s p \<otimes>\<^bsub>S\<^esub> eval R S h s q"
  1254   proof (simp only: eval_on_carrier UP_mult_closed)
  1255     from RS have
  1256       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1257       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<otimes>\<^bsub>P\<^esub> q)<..deg R p + deg R q}.
  1258         h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1259       by (simp cong: finsum_cong
  1260         add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def
  1261         del: coeff_mult)
  1262     also from RS have "... =
  1263       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1264       by (simp only: ivl_disj_un_one deg_mult_cring)
  1265     also from RS have "... =
  1266       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}.
  1267          \<Oplus>\<^bsub>S\<^esub> k \<in> {..i}.
  1268            h (coeff P p k) \<otimes>\<^bsub>S\<^esub> h (coeff P q (i - k)) \<otimes>\<^bsub>S\<^esub>
  1269            (s (^)\<^bsub>S\<^esub> k \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> (i - k)))"
  1270       by (simp cong: finsum_cong add: nat_pow_mult Pi_def
  1271         S.m_ac S.finsum_rdistr)
  1272     also from RS have "... =
  1273       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1274       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1275       by (simp add: S.cauchy_product [THEN sym] bound.intro deg_aboveD S.m_ac
  1276         Pi_def)
  1277     finally show
  1278       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1279       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1280       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1281   qed
  1282 next
  1283   fix p q
  1284   assume RS: "p \<in> carrier P" "q \<in> carrier P" "s \<in> carrier S"
  1285   then show "eval R S h s (p \<oplus>\<^bsub>P\<^esub> q) = eval R S h s p \<oplus>\<^bsub>S\<^esub> eval R S h s q"
  1286   proof (simp only: eval_on_carrier UP_a_closed)
  1287     from RS have
  1288       "(\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1289       (\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<oplus>\<^bsub>P\<^esub> q)<..max (deg R p) (deg R q)}.
  1290         h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1291       by (simp cong: finsum_cong
  1292         add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def
  1293         del: coeff_add)
  1294     also from RS have "... =
  1295         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..max (deg R p) (deg R q)}.
  1296           h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1297       by (simp add: ivl_disj_un_one)
  1298     also from RS have "... =
  1299       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1300       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1301       by (simp cong: finsum_cong
  1302         add: l_distr deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1303     also have "... =
  1304         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p} \<union> {deg R p<..max (deg R p) (deg R q)}.
  1305           h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1306         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q} \<union> {deg R q<..max (deg R p) (deg R q)}.
  1307           h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1308       by (simp only: ivl_disj_un_one le_maxI1 le_maxI2)
  1309     also from RS have "... =
  1310       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1311       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1312       by (simp cong: finsum_cong
  1313         add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1314     finally show
  1315       "(\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1316       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1317       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1318   qed
  1319 next
  1320   assume S: "s \<in> carrier S"
  1321   then show "eval R S h s \<one>\<^bsub>P\<^esub> = \<one>\<^bsub>S\<^esub>"
  1322     by (simp only: eval_on_carrier UP_one_closed) simp
  1323 qed
  1324 
  1325 text {* Instantiation of ring homomorphism lemmas. *}
  1326 
  1327 (* TODO: again, automate with instantiation command *)
  1328 
  1329 lemma (in UP_univ_prop) ring_hom_cring_P_S:
  1330   "s \<in> carrier S ==> ring_hom_cring P S (eval R S h s)"
  1331   by (fast intro!: ring_hom_cring.intro UP_cring cring.axioms prems
  1332     intro: ring_hom_cring_axioms.intro eval_ring_hom)
  1333 
  1334 (*
  1335 lemma (in UP_univ_prop) UP_hom_closed [intro, simp]:
  1336   "[| s \<in> carrier S; p \<in> carrier P |] ==> eval R S h s p \<in> carrier S"
  1337   by (rule ring_hom_cring.hom_closed [OF ring_hom_cring_P_S])
  1338 
  1339 lemma (in UP_univ_prop) UP_hom_mult [simp]:
  1340   "[| s \<in> carrier S; p \<in> carrier P; q \<in> carrier P |] ==>
  1341   eval R S h s (p \<otimes>\<^bsub>P\<^esub> q) = eval R S h s p \<otimes>\<^bsub>S\<^esub> eval R S h s q"
  1342   by (rule ring_hom_cring.hom_mult [OF ring_hom_cring_P_S])
  1343 
  1344 lemma (in UP_univ_prop) UP_hom_add [simp]:
  1345   "[| s \<in> carrier S; p \<in> carrier P; q \<in> carrier P |] ==>
  1346   eval R S h s (p \<oplus>\<^bsub>P\<^esub> q) = eval R S h s p \<oplus>\<^bsub>S\<^esub> eval R S h s q"
  1347   by (rule ring_hom_cring.hom_add [OF ring_hom_cring_P_S])
  1348 
  1349 lemma (in UP_univ_prop) UP_hom_one [simp]:
  1350   "s \<in> carrier S ==> eval R S h s \<one>\<^bsub>P\<^esub> = \<one>\<^bsub>S\<^esub>"
  1351   by (rule ring_hom_cring.hom_one [OF ring_hom_cring_P_S])
  1352 
  1353 lemma (in UP_univ_prop) UP_hom_zero [simp]:
  1354   "s \<in> carrier S ==> eval R S h s \<zero>\<^bsub>P\<^esub> = \<zero>\<^bsub>S\<^esub>"
  1355   by (rule ring_hom_cring.hom_zero [OF ring_hom_cring_P_S])
  1356 
  1357 lemma (in UP_univ_prop) UP_hom_a_inv [simp]:
  1358   "[| s \<in> carrier S; p \<in> carrier P |] ==>
  1359   (eval R S h s) (\<ominus>\<^bsub>P\<^esub> p) = \<ominus>\<^bsub>S\<^esub> (eval R S h s) p"
  1360   by (rule ring_hom_cring.hom_a_inv [OF ring_hom_cring_P_S])
  1361 
  1362 lemma (in UP_univ_prop) UP_hom_finsum [simp]:
  1363   "[| s \<in> carrier S; finite A; f \<in> A -> carrier P |] ==>
  1364   (eval R S h s) (finsum P f A) = finsum S (eval R S h s o f) A"
  1365   by (rule ring_hom_cring.hom_finsum [OF ring_hom_cring_P_S])
  1366 
  1367 lemma (in UP_univ_prop) UP_hom_finprod [simp]:
  1368   "[| s \<in> carrier S; finite A; f \<in> A -> carrier P |] ==>
  1369   (eval R S h s) (finprod P f A) = finprod S (eval R S h s o f) A"
  1370   by (rule ring_hom_cring.hom_finprod [OF ring_hom_cring_P_S])
  1371 *)
  1372 
  1373 text {* Further properties of the evaluation homomorphism. *}
  1374 
  1375 (* The following lemma could be proved in UP\_cring with the additional
  1376    assumption that h is closed. *)
  1377 
  1378 lemma (in UP_univ_prop) eval_const:
  1379   "[| s \<in> carrier S; r \<in> carrier R |] ==> eval R S h s (monom P r 0) = h r"
  1380   by (simp only: eval_on_carrier monom_closed) simp
  1381 
  1382 text {* The following proof is complicated by the fact that in arbitrary
  1383   rings one might have @{term "one R = zero R"}. *}
  1384 
  1385 (* TODO: simplify by cases "one R = zero R" *)
  1386 
  1387 lemma (in UP_univ_prop) eval_monom1:
  1388   "s \<in> carrier S ==> eval R S h s (monom P \<one> 1) = s"
  1389 proof (simp only: eval_on_carrier monom_closed R.one_closed)
  1390   assume S: "s \<in> carrier S"
  1391   then have
  1392     "(\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1393     (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)} \<union> {deg R (monom P \<one> 1)<..1}.
  1394       h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1395     by (simp cong: finsum_cong del: coeff_monom
  1396       add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1397   also have "... =
  1398     (\<Oplus>\<^bsub>S\<^esub> i \<in> {..1}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1399     by (simp only: ivl_disj_un_one deg_monom_le R.one_closed)
  1400   also have "... = s"
  1401   proof (cases "s = \<zero>\<^bsub>S\<^esub>")
  1402     case True then show ?thesis by (simp add: Pi_def)
  1403   next
  1404     case False with S show ?thesis by (simp add: Pi_def)
  1405   qed
  1406   finally show "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (monom P \<one> 1)}.
  1407     h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) = s" .
  1408 qed
  1409 
  1410 lemma (in UP_cring) monom_pow:
  1411   assumes R: "a \<in> carrier R"
  1412   shows "(monom P a n) (^)\<^bsub>P\<^esub> m = monom P (a (^) m) (n * m)"
  1413 proof (induct m)
  1414   case 0 from R show ?case by simp
  1415 next
  1416   case Suc with R show ?case
  1417     by (simp del: monom_mult add: monom_mult [THEN sym] add_commute)
  1418 qed
  1419 
  1420 lemma (in ring_hom_cring) hom_pow [simp]:
  1421   "x \<in> carrier R ==> h (x (^) n) = h x (^)\<^bsub>S\<^esub> (n::nat)"
  1422   by (induct n) simp_all
  1423 
  1424 lemma (in UP_univ_prop) eval_monom:
  1425   "[| s \<in> carrier S; r \<in> carrier R |] ==>
  1426   eval R S h s (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1427 proof -
  1428   assume S: "s \<in> carrier S" and R: "r \<in> carrier R"
  1429   from ring_hom_cring_P_S [OF S] interpret ring_hom_cring [P S "eval R S h s"]
  1430     by - (rule ring_hom_cring.axioms, assumption)+
  1431     (* why is simplifier invoked --- in done ??? *)
  1432   from R S have "eval R S h s (monom P r n) =
  1433     eval R S h s (monom P r 0 \<otimes>\<^bsub>P\<^esub> (monom P \<one> 1) (^)\<^bsub>P\<^esub> n)"
  1434     by (simp del: monom_mult (* eval.hom_mult eval.hom_pow, delayed inst! *)
  1435       add: monom_mult [THEN sym] monom_pow)
  1436   also
  1437   from R S eval_monom1 have "... = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1438     by (simp add: eval_const)
  1439   finally show ?thesis .
  1440 qed
  1441 
  1442 lemma (in UP_univ_prop) eval_smult:
  1443   "[| s \<in> carrier S; r \<in> carrier R; p \<in> carrier P |] ==>
  1444   eval R S h s (r \<odot>\<^bsub>P\<^esub> p) = h r \<otimes>\<^bsub>S\<^esub> eval R S h s p"
  1445 proof -
  1446   assume S: "s \<in> carrier S" and R: "r \<in> carrier R" and P: "p \<in> carrier P"
  1447   from ring_hom_cring_P_S [OF S] interpret ring_hom_cring [P S "eval R S h s"]
  1448     by - (rule ring_hom_cring.axioms, assumption)+
  1449   from S R P show ?thesis
  1450     by (simp add: monom_mult_is_smult [THEN sym] eval_const)
  1451 qed
  1452 
  1453 lemma ring_hom_cringI:
  1454   assumes "cring R"
  1455     and "cring S"
  1456     and "h \<in> ring_hom R S"
  1457   shows "ring_hom_cring R S h"
  1458   by (fast intro: ring_hom_cring.intro ring_hom_cring_axioms.intro
  1459     cring.axioms prems)
  1460 
  1461 lemma (in UP_univ_prop) UP_hom_unique:
  1462   assumes Phi: "Phi \<in> ring_hom P S" "Phi (monom P \<one> (Suc 0)) = s"
  1463       "!!r. r \<in> carrier R ==> Phi (monom P r 0) = h r"
  1464     and Psi: "Psi \<in> ring_hom P S" "Psi (monom P \<one> (Suc 0)) = s"
  1465       "!!r. r \<in> carrier R ==> Psi (monom P r 0) = h r"
  1466     and S: "s \<in> carrier S" and P: "p \<in> carrier P"
  1467   shows "Phi p = Psi p"
  1468 proof -
  1469   from UP_cring interpret cring [P] by - (rule cring.axioms, assumption)+
  1470   interpret Phi: ring_hom_cring [P S Phi]
  1471     by (auto intro: ring_hom_cring.axioms ring_hom_cringI UP_cring S.cring Phi)
  1472   interpret Psi: ring_hom_cring [P S Psi]
  1473     by (auto intro: ring_hom_cring.axioms ring_hom_cringI UP_cring S.cring Psi)
  1474 
  1475   have "Phi p =
  1476       Phi (\<Oplus>\<^bsub>P \<^esub>i \<in> {..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1477     by (simp add: up_repr P S monom_mult [THEN sym] monom_pow del: monom_mult)
  1478   also
  1479   have "... =
  1480       Psi (\<Oplus>\<^bsub>P \<^esub>i\<in>{..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1481     by (simp add: Phi Psi P S Pi_def comp_def)
  1482 (* Without interpret, the following command would have been necessary.
  1483     by (simp add: ring_hom_cring.hom_finsum [OF Phi_hom]
  1484       ring_hom_cring.hom_mult [OF Phi_hom]
  1485       ring_hom_cring.hom_pow [OF Phi_hom] Phi
  1486       ring_hom_cring.hom_finsum [OF Psi_hom]
  1487       ring_hom_cring.hom_mult [OF Psi_hom]
  1488       ring_hom_cring.hom_pow [OF Psi_hom] Psi RS Pi_def comp_def)
  1489 *)
  1490   also have "... = Psi p"
  1491     by (simp add: up_repr P S monom_mult [THEN sym] monom_pow del: monom_mult)
  1492   finally show ?thesis .
  1493 qed
  1494 
  1495 theorem (in UP_univ_prop) UP_universal_property:
  1496   "s \<in> carrier S ==>
  1497   EX! Phi. Phi \<in> ring_hom P S \<inter> extensional (carrier P) &
  1498     Phi (monom P \<one> 1) = s &
  1499     (ALL r : carrier R. Phi (monom P r 0) = h r)"
  1500   using eval_monom1
  1501   apply (auto intro: eval_ring_hom eval_const eval_extensional)
  1502   apply (rule extensionalityI)
  1503   apply (auto intro: UP_hom_unique)
  1504   done
  1505 
  1506 subsection {* Sample application of evaluation homomorphism *}
  1507 
  1508 lemma UP_univ_propI:
  1509   assumes "cring R"
  1510     and "cring S"
  1511     and "h \<in> ring_hom R S"
  1512   shows "UP_univ_prop R S h"
  1513   by (fast intro: UP_univ_prop.intro ring_hom_cring_axioms.intro
  1514     cring.axioms prems)
  1515 
  1516 constdefs
  1517   INTEG :: "int ring"
  1518   "INTEG == (| carrier = UNIV, mult = op *, one = 1, zero = 0, add = op + |)"
  1519 
  1520 lemma INTEG_cring:
  1521   "cring INTEG"
  1522   by (unfold INTEG_def) (auto intro!: cringI abelian_groupI comm_monoidI
  1523     zadd_zminus_inverse2 zadd_zmult_distrib)
  1524 
  1525 lemma INTEG_id_eval:
  1526   "UP_univ_prop INTEG INTEG id"
  1527   by (fast intro: UP_univ_propI INTEG_cring id_ring_hom)
  1528 
  1529 text {*
  1530   Interpretation allows now to import all theorems and lemmas
  1531   valid in the context of homomorphisms between @{term INTEG} and @{term
  1532   "UP INTEG"} globally.
  1533 *}
  1534 
  1535 interpretation INTEG: UP_univ_prop [INTEG INTEG id]
  1536   using INTEG_id_eval
  1537   by - (rule UP_univ_prop.axioms, assumption)+
  1538 
  1539 lemma INTEG_closed [intro, simp]:
  1540   "z \<in> carrier INTEG"
  1541   by (unfold INTEG_def) simp
  1542 
  1543 lemma INTEG_mult [simp]:
  1544   "mult INTEG z w = z * w"
  1545   by (unfold INTEG_def) simp
  1546 
  1547 lemma INTEG_pow [simp]:
  1548   "pow INTEG z n = z ^ n"
  1549   by (induct n) (simp_all add: INTEG_def nat_pow_def)
  1550 
  1551 lemma "eval INTEG INTEG id 10 (monom (UP INTEG) 5 2) = 500"
  1552   by (simp add: INTEG.eval_monom)
  1553 
  1554 end