src/ZF/Constructible/Datatype_absolute.thy
author paulson
Mon Aug 12 18:01:44 2002 +0200 (2002-08-12)
changeset 13493 5aa68c051725
parent 13440 cdde97e1db1c
child 13505 52a16cb7fefb
permissions -rw-r--r--
Lots of new results concerning recursive datatypes, towards absoluteness of
"satisfies"
     1 header {*Absoluteness Properties for Recursive Datatypes*}
     2 
     3 theory Datatype_absolute = Formula + WF_absolute:
     4 
     5 
     6 subsection{*The lfp of a continuous function can be expressed as a union*}
     7 
     8 constdefs
     9   directed :: "i=>o"
    10    "directed(A) == A\<noteq>0 & (\<forall>x\<in>A. \<forall>y\<in>A. x \<union> y \<in> A)"
    11 
    12   contin :: "(i=>i) => o"
    13    "contin(h) == (\<forall>A. directed(A) --> h(\<Union>A) = (\<Union>X\<in>A. h(X)))"
    14 
    15 lemma bnd_mono_iterates_subset: "[|bnd_mono(D, h); n \<in> nat|] ==> h^n (0) <= D"
    16 apply (induct_tac n) 
    17  apply (simp_all add: bnd_mono_def, blast) 
    18 done
    19 
    20 lemma bnd_mono_increasing [rule_format]:
    21      "[|i \<in> nat; j \<in> nat; bnd_mono(D,h)|] ==> i \<le> j --> h^i(0) \<subseteq> h^j(0)"
    22 apply (rule_tac m=i and n=j in diff_induct, simp_all)
    23 apply (blast del: subsetI
    24 	     intro: bnd_mono_iterates_subset bnd_monoD2 [of concl: h]) 
    25 done
    26 
    27 lemma directed_iterates: "bnd_mono(D,h) ==> directed({h^n (0). n\<in>nat})"
    28 apply (simp add: directed_def, clarify) 
    29 apply (rename_tac i j)
    30 apply (rule_tac x="i \<union> j" in bexI) 
    31 apply (rule_tac i = i and j = j in Ord_linear_le)
    32 apply (simp_all add: subset_Un_iff [THEN iffD1] le_imp_subset
    33                      subset_Un_iff2 [THEN iffD1])
    34 apply (simp_all add: subset_Un_iff [THEN iff_sym] bnd_mono_increasing
    35                      subset_Un_iff2 [THEN iff_sym])
    36 done
    37 
    38 
    39 lemma contin_iterates_eq: 
    40     "[|bnd_mono(D, h); contin(h)|] 
    41      ==> h(\<Union>n\<in>nat. h^n (0)) = (\<Union>n\<in>nat. h^n (0))"
    42 apply (simp add: contin_def directed_iterates) 
    43 apply (rule trans) 
    44 apply (rule equalityI) 
    45  apply (simp_all add: UN_subset_iff)
    46  apply safe
    47  apply (erule_tac [2] natE) 
    48   apply (rule_tac a="succ(x)" in UN_I) 
    49    apply simp_all 
    50 apply blast 
    51 done
    52 
    53 lemma lfp_subset_Union:
    54      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) <= (\<Union>n\<in>nat. h^n(0))"
    55 apply (rule lfp_lowerbound) 
    56  apply (simp add: contin_iterates_eq) 
    57 apply (simp add: contin_def bnd_mono_iterates_subset UN_subset_iff) 
    58 done
    59 
    60 lemma Union_subset_lfp:
    61      "bnd_mono(D,h) ==> (\<Union>n\<in>nat. h^n(0)) <= lfp(D,h)"
    62 apply (simp add: UN_subset_iff)
    63 apply (rule ballI)  
    64 apply (induct_tac n, simp_all) 
    65 apply (rule subset_trans [of _ "h(lfp(D,h))"])
    66  apply (blast dest: bnd_monoD2 [OF _ _ lfp_subset])  
    67 apply (erule lfp_lemma2) 
    68 done
    69 
    70 lemma lfp_eq_Union:
    71      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) = (\<Union>n\<in>nat. h^n(0))"
    72 by (blast del: subsetI 
    73           intro: lfp_subset_Union Union_subset_lfp)
    74 
    75 
    76 subsubsection{*Some Standard Datatype Constructions Preserve Continuity*}
    77 
    78 lemma contin_imp_mono: "[|X\<subseteq>Y; contin(F)|] ==> F(X) \<subseteq> F(Y)"
    79 apply (simp add: contin_def) 
    80 apply (drule_tac x="{X,Y}" in spec) 
    81 apply (simp add: directed_def subset_Un_iff2 Un_commute) 
    82 done
    83 
    84 lemma sum_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) + G(X))"
    85 by (simp add: contin_def, blast)
    86 
    87 lemma prod_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) * G(X))" 
    88 apply (subgoal_tac "\<forall>B C. F(B) \<subseteq> F(B \<union> C)")
    89  prefer 2 apply (simp add: Un_upper1 contin_imp_mono) 
    90 apply (subgoal_tac "\<forall>B C. G(C) \<subseteq> G(B \<union> C)")
    91  prefer 2 apply (simp add: Un_upper2 contin_imp_mono) 
    92 apply (simp add: contin_def, clarify) 
    93 apply (rule equalityI) 
    94  prefer 2 apply blast 
    95 apply clarify 
    96 apply (rename_tac B C) 
    97 apply (rule_tac a="B \<union> C" in UN_I) 
    98  apply (simp add: directed_def, blast)  
    99 done
   100 
   101 lemma const_contin: "contin(\<lambda>X. A)"
   102 by (simp add: contin_def directed_def)
   103 
   104 lemma id_contin: "contin(\<lambda>X. X)"
   105 by (simp add: contin_def)
   106 
   107 
   108 
   109 subsection {*Absoluteness for "Iterates"*}
   110 
   111 constdefs
   112 
   113   iterates_MH :: "[i=>o, [i,i]=>o, i, i, i, i] => o"
   114    "iterates_MH(M,isF,v,n,g,z) ==
   115         is_nat_case(M, v, \<lambda>m u. \<exists>gm[M]. fun_apply(M,g,m,gm) & isF(gm,u),
   116                     n, z)"
   117 
   118   iterates_replacement :: "[i=>o, [i,i]=>o, i] => o"
   119    "iterates_replacement(M,isF,v) ==
   120       \<forall>n[M]. n\<in>nat --> 
   121          wfrec_replacement(M, iterates_MH(M,isF,v), Memrel(succ(n)))"
   122 
   123 lemma (in M_axioms) iterates_MH_abs:
   124   "[| relativize1(M,isF,F); M(n); M(g); M(z) |] 
   125    ==> iterates_MH(M,isF,v,n,g,z) <-> z = nat_case(v, \<lambda>m. F(g`m), n)"
   126 by (simp add: nat_case_abs [of _ "\<lambda>m. F(g ` m)"]
   127               relativize1_def iterates_MH_def)  
   128 
   129 lemma (in M_axioms) iterates_imp_wfrec_replacement:
   130   "[|relativize1(M,isF,F); n \<in> nat; iterates_replacement(M,isF,v)|] 
   131    ==> wfrec_replacement(M, \<lambda>n f z. z = nat_case(v, \<lambda>m. F(f`m), n), 
   132                        Memrel(succ(n)))" 
   133 by (simp add: iterates_replacement_def iterates_MH_abs)
   134 
   135 theorem (in M_trancl) iterates_abs:
   136   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   137       n \<in> nat; M(v); M(z); \<forall>x[M]. M(F(x)) |] 
   138    ==> is_wfrec(M, iterates_MH(M,isF,v), Memrel(succ(n)), n, z) <->
   139        z = iterates(F,n,v)" 
   140 apply (frule iterates_imp_wfrec_replacement, assumption+)
   141 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   142                  relativize2_def iterates_MH_abs 
   143                  iterates_nat_def recursor_def transrec_def 
   144                  eclose_sing_Ord_eq nat_into_M
   145          trans_wfrec_abs [of _ _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   146 done
   147 
   148 
   149 lemma (in M_wfrank) iterates_closed [intro,simp]:
   150   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   151       n \<in> nat; M(v); \<forall>x[M]. M(F(x)) |] 
   152    ==> M(iterates(F,n,v))"
   153 apply (frule iterates_imp_wfrec_replacement, assumption+)
   154 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   155                  relativize2_def iterates_MH_abs 
   156                  iterates_nat_def recursor_def transrec_def 
   157                  eclose_sing_Ord_eq nat_into_M
   158          trans_wfrec_closed [of _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   159 done
   160 
   161 
   162 subsection {*lists without univ*}
   163 
   164 lemmas datatype_univs = Inl_in_univ Inr_in_univ 
   165                         Pair_in_univ nat_into_univ A_into_univ 
   166 
   167 lemma list_fun_bnd_mono: "bnd_mono(univ(A), \<lambda>X. {0} + A*X)"
   168 apply (rule bnd_monoI)
   169  apply (intro subset_refl zero_subset_univ A_subset_univ 
   170 	      sum_subset_univ Sigma_subset_univ) 
   171 apply (rule subset_refl sum_mono Sigma_mono | assumption)+
   172 done
   173 
   174 lemma list_fun_contin: "contin(\<lambda>X. {0} + A*X)"
   175 by (intro sum_contin prod_contin id_contin const_contin) 
   176 
   177 text{*Re-expresses lists using sum and product*}
   178 lemma list_eq_lfp2: "list(A) = lfp(univ(A), \<lambda>X. {0} + A*X)"
   179 apply (simp add: list_def) 
   180 apply (rule equalityI) 
   181  apply (rule lfp_lowerbound) 
   182   prefer 2 apply (rule lfp_subset)
   183  apply (clarify, subst lfp_unfold [OF list_fun_bnd_mono])
   184  apply (simp add: Nil_def Cons_def)
   185  apply blast 
   186 txt{*Opposite inclusion*}
   187 apply (rule lfp_lowerbound) 
   188  prefer 2 apply (rule lfp_subset) 
   189 apply (clarify, subst lfp_unfold [OF list.bnd_mono]) 
   190 apply (simp add: Nil_def Cons_def)
   191 apply (blast intro: datatype_univs
   192              dest: lfp_subset [THEN subsetD])
   193 done
   194 
   195 text{*Re-expresses lists using "iterates", no univ.*}
   196 lemma list_eq_Union:
   197      "list(A) = (\<Union>n\<in>nat. (\<lambda>X. {0} + A*X) ^ n (0))"
   198 by (simp add: list_eq_lfp2 lfp_eq_Union list_fun_bnd_mono list_fun_contin)
   199 
   200 
   201 constdefs
   202   is_list_functor :: "[i=>o,i,i,i] => o"
   203     "is_list_functor(M,A,X,Z) == 
   204         \<exists>n1[M]. \<exists>AX[M]. 
   205          number1(M,n1) & cartprod(M,A,X,AX) & is_sum(M,n1,AX,Z)"
   206 
   207 lemma (in M_axioms) list_functor_abs [simp]: 
   208      "[| M(A); M(X); M(Z) |] ==> is_list_functor(M,A,X,Z) <-> (Z = {0} + A*X)"
   209 by (simp add: is_list_functor_def singleton_0 nat_into_M)
   210 
   211 
   212 subsection {*formulas without univ*}
   213 
   214 lemma formula_fun_bnd_mono:
   215      "bnd_mono(univ(0), \<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   216 apply (rule bnd_monoI)
   217  apply (intro subset_refl zero_subset_univ A_subset_univ 
   218 	      sum_subset_univ Sigma_subset_univ nat_subset_univ) 
   219 apply (rule subset_refl sum_mono Sigma_mono | assumption)+
   220 done
   221 
   222 lemma formula_fun_contin:
   223      "contin(\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   224 by (intro sum_contin prod_contin id_contin const_contin) 
   225 
   226 
   227 text{*Re-expresses formulas using sum and product*}
   228 lemma formula_eq_lfp2:
   229     "formula = lfp(univ(0), \<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   230 apply (simp add: formula_def) 
   231 apply (rule equalityI) 
   232  apply (rule lfp_lowerbound) 
   233   prefer 2 apply (rule lfp_subset)
   234  apply (clarify, subst lfp_unfold [OF formula_fun_bnd_mono])
   235  apply (simp add: Member_def Equal_def Nand_def Forall_def)
   236  apply blast 
   237 txt{*Opposite inclusion*}
   238 apply (rule lfp_lowerbound) 
   239  prefer 2 apply (rule lfp_subset, clarify) 
   240 apply (subst lfp_unfold [OF formula.bnd_mono, simplified]) 
   241 apply (simp add: Member_def Equal_def Nand_def Forall_def)  
   242 apply (elim sumE SigmaE, simp_all) 
   243 apply (blast intro: datatype_univs dest: lfp_subset [THEN subsetD])+  
   244 done
   245 
   246 text{*Re-expresses formulas using "iterates", no univ.*}
   247 lemma formula_eq_Union:
   248      "formula = 
   249       (\<Union>n\<in>nat. (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)) ^ n (0))"
   250 by (simp add: formula_eq_lfp2 lfp_eq_Union formula_fun_bnd_mono 
   251               formula_fun_contin)
   252 
   253 
   254 constdefs
   255   is_formula_functor :: "[i=>o,i,i] => o"
   256     "is_formula_functor(M,X,Z) == 
   257         \<exists>nat'[M]. \<exists>natnat[M]. \<exists>natnatsum[M]. \<exists>XX[M]. \<exists>X3[M]. 
   258           omega(M,nat') & cartprod(M,nat',nat',natnat) & 
   259           is_sum(M,natnat,natnat,natnatsum) &
   260           cartprod(M,X,X,XX) & is_sum(M,XX,X,X3) & 
   261           is_sum(M,natnatsum,X3,Z)"
   262 
   263 lemma (in M_axioms) formula_functor_abs [simp]: 
   264      "[| M(X); M(Z) |] 
   265       ==> is_formula_functor(M,X,Z) <-> 
   266           Z = ((nat*nat) + (nat*nat)) + (X*X + X)"
   267 by (simp add: is_formula_functor_def) 
   268 
   269 
   270 subsection{*@{term M} Contains the List and Formula Datatypes*}
   271 
   272 constdefs
   273   list_N :: "[i,i] => i"
   274     "list_N(A,n) == (\<lambda>X. {0} + A * X)^n (0)"
   275 
   276 lemma Nil_in_list_N [simp]: "[] \<in> list_N(A,succ(n))"
   277 by (simp add: list_N_def Nil_def)
   278 
   279 lemma Cons_in_list_N [simp]:
   280      "Cons(a,l) \<in> list_N(A,succ(n)) <-> a\<in>A & l \<in> list_N(A,n)"
   281 by (simp add: list_N_def Cons_def) 
   282 
   283 text{*These two aren't simprules because they reveal the underlying
   284 list representation.*}
   285 lemma list_N_0: "list_N(A,0) = 0"
   286 by (simp add: list_N_def)
   287 
   288 lemma list_N_succ: "list_N(A,succ(n)) = {0} + A * (list_N(A,n))"
   289 by (simp add: list_N_def)
   290 
   291 lemma list_N_imp_list:
   292   "[| l \<in> list_N(A,n); n \<in> nat |] ==> l \<in> list(A)"
   293 by (force simp add: list_eq_Union list_N_def)
   294 
   295 lemma list_N_imp_length_lt [rule_format]:
   296      "n \<in> nat ==> \<forall>l \<in> list_N(A,n). length(l) < n"
   297 apply (induct_tac n)  
   298 apply (auto simp add: list_N_0 list_N_succ 
   299                       Nil_def [symmetric] Cons_def [symmetric]) 
   300 done
   301 
   302 lemma list_imp_list_N [rule_format]:
   303      "l \<in> list(A) ==> \<forall>n\<in>nat. length(l) < n --> l \<in> list_N(A, n)"
   304 apply (induct_tac l)
   305 apply (force elim: natE)+
   306 done
   307 
   308 lemma list_N_imp_eq_length:
   309       "[|n \<in> nat; l \<notin> list_N(A, n); l \<in> list_N(A, succ(n))|] 
   310        ==> n = length(l)"
   311 apply (rule le_anti_sym) 
   312  prefer 2 apply (simp add: list_N_imp_length_lt) 
   313 apply (frule list_N_imp_list, simp)
   314 apply (simp add: not_lt_iff_le [symmetric]) 
   315 apply (blast intro: list_imp_list_N) 
   316 done
   317   
   318 text{*Express @{term list_rec} without using @{term rank} or @{term Vset},
   319 neither of which is absolute.*}
   320 lemma (in M_triv_axioms) list_rec_eq:
   321   "l \<in> list(A) ==>
   322    list_rec(a,g,l) = 
   323    transrec (succ(length(l)),
   324       \<lambda>x h. Lambda (list(A),
   325                     list_case' (a, 
   326                            \<lambda>a l. g(a, l, h ` succ(length(l)) ` l)))) ` l"
   327 apply (induct_tac l) 
   328 apply (subst transrec, simp) 
   329 apply (subst transrec) 
   330 apply (simp add: list_imp_list_N) 
   331 done
   332 
   333 constdefs
   334   is_list_N :: "[i=>o,i,i,i] => o"
   335     "is_list_N(M,A,n,Z) == 
   336       \<exists>zero[M]. \<exists>sn[M]. \<exists>msn[M]. 
   337        empty(M,zero) & 
   338        successor(M,n,sn) & membership(M,sn,msn) &
   339        is_wfrec(M, iterates_MH(M, is_list_functor(M,A),zero), msn, n, Z)"
   340   
   341   mem_list :: "[i=>o,i,i] => o"
   342     "mem_list(M,A,l) == 
   343       \<exists>n[M]. \<exists>listn[M]. 
   344        finite_ordinal(M,n) & is_list_N(M,A,n,listn) & l \<in> listn"
   345 
   346   is_list :: "[i=>o,i,i] => o"
   347     "is_list(M,A,Z) == \<forall>l[M]. l \<in> Z <-> mem_list(M,A,l)"
   348 
   349 subsubsection{*Towards Absoluteness of @{term formula_rec}*}
   350 
   351 consts   depth :: "i=>i"
   352 primrec
   353   "depth(Member(x,y)) = 0"
   354   "depth(Equal(x,y))  = 0"
   355   "depth(Nand(p,q)) = succ(depth(p) \<union> depth(q))"
   356   "depth(Forall(p)) = succ(depth(p))"
   357 
   358 lemma depth_type [TC]: "p \<in> formula ==> depth(p) \<in> nat"
   359 by (induct_tac p, simp_all) 
   360 
   361 
   362 constdefs
   363   formula_N :: "i => i"
   364     "formula_N(n) == (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)) ^ n (0)"
   365 
   366 lemma Member_in_formula_N [simp]:
   367      "Member(x,y) \<in> formula_N(succ(n)) <-> x \<in> nat & y \<in> nat"
   368 by (simp add: formula_N_def Member_def) 
   369 
   370 lemma Equal_in_formula_N [simp]:
   371      "Equal(x,y) \<in> formula_N(succ(n)) <-> x \<in> nat & y \<in> nat"
   372 by (simp add: formula_N_def Equal_def) 
   373 
   374 lemma Nand_in_formula_N [simp]:
   375      "Nand(x,y) \<in> formula_N(succ(n)) <-> x \<in> formula_N(n) & y \<in> formula_N(n)"
   376 by (simp add: formula_N_def Nand_def) 
   377 
   378 lemma Forall_in_formula_N [simp]:
   379      "Forall(x) \<in> formula_N(succ(n)) <-> x \<in> formula_N(n)"
   380 by (simp add: formula_N_def Forall_def) 
   381 
   382 text{*These two aren't simprules because they reveal the underlying
   383 formula representation.*}
   384 lemma formula_N_0: "formula_N(0) = 0"
   385 by (simp add: formula_N_def)
   386 
   387 lemma formula_N_succ:
   388      "formula_N(succ(n)) = 
   389       ((nat*nat) + (nat*nat)) + (formula_N(n) * formula_N(n) + formula_N(n))"
   390 by (simp add: formula_N_def)
   391 
   392 lemma formula_N_imp_formula:
   393   "[| p \<in> formula_N(n); n \<in> nat |] ==> p \<in> formula"
   394 by (force simp add: formula_eq_Union formula_N_def)
   395 
   396 lemma formula_N_imp_depth_lt [rule_format]:
   397      "n \<in> nat ==> \<forall>p \<in> formula_N(n). depth(p) < n"
   398 apply (induct_tac n)  
   399 apply (auto simp add: formula_N_0 formula_N_succ 
   400                       depth_type formula_N_imp_formula Un_least_lt_iff
   401                       Member_def [symmetric] Equal_def [symmetric]
   402                       Nand_def [symmetric] Forall_def [symmetric]) 
   403 done
   404 
   405 lemma formula_imp_formula_N [rule_format]:
   406      "p \<in> formula ==> \<forall>n\<in>nat. depth(p) < n --> p \<in> formula_N(n)"
   407 apply (induct_tac p)
   408 apply (simp_all add: succ_Un_distrib Un_least_lt_iff) 
   409 apply (force elim: natE)+
   410 done
   411 
   412 lemma formula_N_imp_eq_depth:
   413       "[|n \<in> nat; p \<notin> formula_N(n); p \<in> formula_N(succ(n))|] 
   414        ==> n = depth(p)"
   415 apply (rule le_anti_sym) 
   416  prefer 2 apply (simp add: formula_N_imp_depth_lt) 
   417 apply (frule formula_N_imp_formula, simp)
   418 apply (simp add: not_lt_iff_le [symmetric]) 
   419 apply (blast intro: formula_imp_formula_N) 
   420 done
   421 
   422 
   423 
   424 lemma formula_N_mono [rule_format]:
   425   "[| m \<in> nat; n \<in> nat |] ==> m\<le>n --> formula_N(m) \<subseteq> formula_N(n)"
   426 apply (rule_tac m = m and n = n in diff_induct)
   427 apply (simp_all add: formula_N_0 formula_N_succ, blast) 
   428 done
   429 
   430 lemma formula_N_distrib:
   431   "[| m \<in> nat; n \<in> nat |] ==> formula_N(m \<union> n) = formula_N(m) \<union> formula_N(n)"
   432 apply (rule_tac i = m and j = n in Ord_linear_le, auto) 
   433 apply (simp_all add: subset_Un_iff [THEN iffD1] subset_Un_iff2 [THEN iffD1] 
   434                      le_imp_subset formula_N_mono)
   435 done
   436 
   437 constdefs
   438   is_formula_N :: "[i=>o,i,i] => o"
   439     "is_formula_N(M,n,Z) == 
   440       \<exists>zero[M]. \<exists>sn[M]. \<exists>msn[M]. 
   441        empty(M,zero) & 
   442        successor(M,n,sn) & membership(M,sn,msn) &
   443        is_wfrec(M, iterates_MH(M, is_formula_functor(M),zero), msn, n, Z)"
   444   
   445 
   446 constdefs
   447   
   448   mem_formula :: "[i=>o,i] => o"
   449     "mem_formula(M,p) == 
   450       \<exists>n[M]. \<exists>formn[M]. 
   451        finite_ordinal(M,n) & is_formula_N(M,n,formn) & p \<in> formn"
   452 
   453   is_formula :: "[i=>o,i] => o"
   454     "is_formula(M,Z) == \<forall>p[M]. p \<in> Z <-> mem_formula(M,p)"
   455 
   456 locale M_datatypes = M_wfrank +
   457  assumes list_replacement1: 
   458    "M(A) ==> iterates_replacement(M, is_list_functor(M,A), 0)"
   459   and list_replacement2: 
   460    "M(A) ==> strong_replacement(M, 
   461          \<lambda>n y. n\<in>nat & 
   462                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   463                is_wfrec(M, iterates_MH(M,is_list_functor(M,A), 0), 
   464                         msn, n, y)))"
   465   and formula_replacement1: 
   466    "iterates_replacement(M, is_formula_functor(M), 0)"
   467   and formula_replacement2: 
   468    "strong_replacement(M, 
   469          \<lambda>n y. n\<in>nat & 
   470                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   471                is_wfrec(M, iterates_MH(M,is_formula_functor(M), 0), 
   472                         msn, n, y)))"
   473   and nth_replacement:
   474    "M(l) ==> iterates_replacement(M, %l t. is_tl(M,l,t), l)"
   475         
   476 
   477 subsubsection{*Absoluteness of the List Construction*}
   478 
   479 lemma (in M_datatypes) list_replacement2': 
   480   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. {0} + A * X)^n (0))"
   481 apply (insert list_replacement2 [of A]) 
   482 apply (rule strong_replacement_cong [THEN iffD1])  
   483 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_list_functor(M,A)"]]) 
   484 apply (simp_all add: list_replacement1 relativize1_def) 
   485 done
   486 
   487 lemma (in M_datatypes) list_closed [intro,simp]:
   488      "M(A) ==> M(list(A))"
   489 apply (insert list_replacement1)
   490 by  (simp add: RepFun_closed2 list_eq_Union 
   491                list_replacement2' relativize1_def
   492                iterates_closed [of "is_list_functor(M,A)"])
   493 
   494 text{*WARNING: use only with @{text "dest:"} or with variables fixed!*}
   495 lemmas (in M_datatypes) list_into_M = transM [OF _ list_closed]
   496 
   497 lemma (in M_datatypes) list_N_abs [simp]:
   498      "[|M(A); n\<in>nat; M(Z)|] 
   499       ==> is_list_N(M,A,n,Z) <-> Z = list_N(A,n)"
   500 apply (insert list_replacement1)
   501 apply (simp add: is_list_N_def list_N_def relativize1_def nat_into_M
   502                  iterates_abs [of "is_list_functor(M,A)" _ "\<lambda>X. {0} + A*X"])
   503 done
   504 
   505 lemma (in M_datatypes) list_N_closed [intro,simp]:
   506      "[|M(A); n\<in>nat|] ==> M(list_N(A,n))"
   507 apply (insert list_replacement1)
   508 apply (simp add: is_list_N_def list_N_def relativize1_def nat_into_M
   509                  iterates_closed [of "is_list_functor(M,A)"])
   510 done
   511 
   512 lemma (in M_datatypes) mem_list_abs [simp]:
   513      "M(A) ==> mem_list(M,A,l) <-> l \<in> list(A)"
   514 apply (insert list_replacement1)
   515 apply (simp add: mem_list_def list_N_def relativize1_def list_eq_Union
   516                  iterates_closed [of "is_list_functor(M,A)"]) 
   517 done
   518 
   519 lemma (in M_datatypes) list_abs [simp]:
   520      "[|M(A); M(Z)|] ==> is_list(M,A,Z) <-> Z = list(A)"
   521 apply (simp add: is_list_def, safe)
   522 apply (rule M_equalityI, simp_all)
   523 done
   524 
   525 subsubsection{*Absoluteness of Formulas*}
   526 
   527 lemma (in M_datatypes) formula_replacement2': 
   528   "strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))^n (0))"
   529 apply (insert formula_replacement2) 
   530 apply (rule strong_replacement_cong [THEN iffD1])  
   531 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_formula_functor(M)"]]) 
   532 apply (simp_all add: formula_replacement1 relativize1_def) 
   533 done
   534 
   535 lemma (in M_datatypes) formula_closed [intro,simp]:
   536      "M(formula)"
   537 apply (insert formula_replacement1)
   538 apply  (simp add: RepFun_closed2 formula_eq_Union 
   539                   formula_replacement2' relativize1_def
   540                   iterates_closed [of "is_formula_functor(M)"])
   541 done
   542 
   543 lemmas (in M_datatypes) formula_into_M = transM [OF _ formula_closed]
   544 
   545 lemma (in M_datatypes) formula_N_abs [simp]:
   546      "[|n\<in>nat; M(Z)|] 
   547       ==> is_formula_N(M,n,Z) <-> Z = formula_N(n)"
   548 apply (insert formula_replacement1)
   549 apply (simp add: is_formula_N_def formula_N_def relativize1_def nat_into_M
   550                  iterates_abs [of "is_formula_functor(M)" _ 
   551                                   "\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)"])
   552 done
   553 
   554 lemma (in M_datatypes) formula_N_closed [intro,simp]:
   555      "n\<in>nat ==> M(formula_N(n))"
   556 apply (insert formula_replacement1)
   557 apply (simp add: is_formula_N_def formula_N_def relativize1_def nat_into_M
   558                  iterates_closed [of "is_formula_functor(M)"])
   559 done
   560 
   561 lemma (in M_datatypes) mem_formula_abs [simp]:
   562      "mem_formula(M,l) <-> l \<in> formula"
   563 apply (insert formula_replacement1)
   564 apply (simp add: mem_formula_def relativize1_def formula_eq_Union formula_N_def
   565                  iterates_closed [of "is_formula_functor(M)"]) 
   566 done
   567 
   568 lemma (in M_datatypes) formula_abs [simp]:
   569      "[|M(Z)|] ==> is_formula(M,Z) <-> Z = formula"
   570 apply (simp add: is_formula_def, safe)
   571 apply (rule M_equalityI, simp_all)
   572 done
   573 
   574 
   575 subsection{*Absoluteness for Some List Operators*}
   576 
   577 subsection{*Absoluteness for @{text \<epsilon>}-Closure: the @{term eclose} Operator*}
   578 
   579 text{*Re-expresses eclose using "iterates"*}
   580 lemma eclose_eq_Union:
   581      "eclose(A) = (\<Union>n\<in>nat. Union^n (A))"
   582 apply (simp add: eclose_def) 
   583 apply (rule UN_cong) 
   584 apply (rule refl)
   585 apply (induct_tac n)
   586 apply (simp add: nat_rec_0)  
   587 apply (simp add: nat_rec_succ) 
   588 done
   589 
   590 constdefs
   591   is_eclose_n :: "[i=>o,i,i,i] => o"
   592     "is_eclose_n(M,A,n,Z) == 
   593       \<exists>sn[M]. \<exists>msn[M]. 
   594        successor(M,n,sn) & membership(M,sn,msn) &
   595        is_wfrec(M, iterates_MH(M, big_union(M), A), msn, n, Z)"
   596   
   597   mem_eclose :: "[i=>o,i,i] => o"
   598     "mem_eclose(M,A,l) == 
   599       \<exists>n[M]. \<exists>eclosen[M]. 
   600        finite_ordinal(M,n) & is_eclose_n(M,A,n,eclosen) & l \<in> eclosen"
   601 
   602   is_eclose :: "[i=>o,i,i] => o"
   603     "is_eclose(M,A,Z) == \<forall>u[M]. u \<in> Z <-> mem_eclose(M,A,u)"
   604 
   605 
   606 locale M_eclose = M_datatypes +
   607  assumes eclose_replacement1: 
   608    "M(A) ==> iterates_replacement(M, big_union(M), A)"
   609   and eclose_replacement2: 
   610    "M(A) ==> strong_replacement(M, 
   611          \<lambda>n y. n\<in>nat & 
   612                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   613                is_wfrec(M, iterates_MH(M,big_union(M), A), 
   614                         msn, n, y)))"
   615 
   616 lemma (in M_eclose) eclose_replacement2': 
   617   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = Union^n (A))"
   618 apply (insert eclose_replacement2 [of A]) 
   619 apply (rule strong_replacement_cong [THEN iffD1])  
   620 apply (rule conj_cong [OF iff_refl iterates_abs [of "big_union(M)"]]) 
   621 apply (simp_all add: eclose_replacement1 relativize1_def) 
   622 done
   623 
   624 lemma (in M_eclose) eclose_closed [intro,simp]:
   625      "M(A) ==> M(eclose(A))"
   626 apply (insert eclose_replacement1)
   627 by  (simp add: RepFun_closed2 eclose_eq_Union 
   628                eclose_replacement2' relativize1_def
   629                iterates_closed [of "big_union(M)"])
   630 
   631 lemma (in M_eclose) is_eclose_n_abs [simp]:
   632      "[|M(A); n\<in>nat; M(Z)|] ==> is_eclose_n(M,A,n,Z) <-> Z = Union^n (A)"
   633 apply (insert eclose_replacement1)
   634 apply (simp add: is_eclose_n_def relativize1_def nat_into_M
   635                  iterates_abs [of "big_union(M)" _ "Union"])
   636 done
   637 
   638 lemma (in M_eclose) mem_eclose_abs [simp]:
   639      "M(A) ==> mem_eclose(M,A,l) <-> l \<in> eclose(A)"
   640 apply (insert eclose_replacement1)
   641 apply (simp add: mem_eclose_def relativize1_def eclose_eq_Union
   642                  iterates_closed [of "big_union(M)"]) 
   643 done
   644 
   645 lemma (in M_eclose) eclose_abs [simp]:
   646      "[|M(A); M(Z)|] ==> is_eclose(M,A,Z) <-> Z = eclose(A)"
   647 apply (simp add: is_eclose_def, safe)
   648 apply (rule M_equalityI, simp_all)
   649 done
   650 
   651 
   652 
   653 
   654 subsection {*Absoluteness for @{term transrec}*}
   655 
   656 
   657 text{* @{term "transrec(a,H) \<equiv> wfrec(Memrel(eclose({a})), a, H)"} *}
   658 constdefs
   659 
   660   is_transrec :: "[i=>o, [i,i,i]=>o, i, i] => o"
   661    "is_transrec(M,MH,a,z) == 
   662       \<exists>sa[M]. \<exists>esa[M]. \<exists>mesa[M]. 
   663        upair(M,a,a,sa) & is_eclose(M,sa,esa) & membership(M,esa,mesa) &
   664        is_wfrec(M,MH,mesa,a,z)"
   665 
   666   transrec_replacement :: "[i=>o, [i,i,i]=>o, i] => o"
   667    "transrec_replacement(M,MH,a) ==
   668       \<exists>sa[M]. \<exists>esa[M]. \<exists>mesa[M]. 
   669        upair(M,a,a,sa) & is_eclose(M,sa,esa) & membership(M,esa,mesa) &
   670        wfrec_replacement(M,MH,mesa)"
   671 
   672 text{*The condition @{term "Ord(i)"} lets us use the simpler 
   673   @{text "trans_wfrec_abs"} rather than @{text "trans_wfrec_abs"},
   674   which I haven't even proved yet. *}
   675 theorem (in M_eclose) transrec_abs:
   676   "[|transrec_replacement(M,MH,i);  relativize2(M,MH,H);
   677      Ord(i);  M(i);  M(z);
   678      \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   679    ==> is_transrec(M,MH,i,z) <-> z = transrec(i,H)" 
   680 apply (rotate_tac 2) 
   681 apply (simp add: trans_wfrec_abs transrec_replacement_def is_transrec_def
   682        transrec_def eclose_sing_Ord_eq wf_Memrel trans_Memrel relation_Memrel)
   683 done
   684 
   685 
   686 theorem (in M_eclose) transrec_closed:
   687      "[|transrec_replacement(M,MH,i);  relativize2(M,MH,H);
   688 	Ord(i);  M(i);  
   689 	\<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   690       ==> M(transrec(i,H))"
   691 apply (rotate_tac 2) 
   692 apply (simp add: trans_wfrec_closed transrec_replacement_def is_transrec_def
   693        transrec_def eclose_sing_Ord_eq wf_Memrel trans_Memrel relation_Memrel)
   694 done
   695 
   696 text{*Helps to prove instances of @{term transrec_replacement}*}
   697 lemma (in M_eclose) transrec_replacementI: 
   698    "[|M(a);
   699     strong_replacement (M, 
   700                   \<lambda>x z. \<exists>y[M]. pair(M, x, y, z) \<and> is_wfrec(M,MH,Memrel(eclose({a})),x,y))|]
   701     ==> transrec_replacement(M,MH,a)"
   702 by (simp add: transrec_replacement_def wfrec_replacement_def) 
   703 
   704 
   705 subsection{*Absoluteness for the List Operator @{term length}*}
   706 constdefs
   707 
   708   is_length :: "[i=>o,i,i,i] => o"
   709     "is_length(M,A,l,n) == 
   710        \<exists>sn[M]. \<exists>list_n[M]. \<exists>list_sn[M]. 
   711         is_list_N(M,A,n,list_n) & l \<notin> list_n &
   712         successor(M,n,sn) & is_list_N(M,A,sn,list_sn) & l \<in> list_sn"
   713 
   714 
   715 lemma (in M_datatypes) length_abs [simp]:
   716      "[|M(A); l \<in> list(A); n \<in> nat|] ==> is_length(M,A,l,n) <-> n = length(l)"
   717 apply (subgoal_tac "M(l) & M(n)")
   718  prefer 2 apply (blast dest: transM)  
   719 apply (simp add: is_length_def)
   720 apply (blast intro: list_imp_list_N nat_into_Ord list_N_imp_eq_length
   721              dest: list_N_imp_length_lt)
   722 done
   723 
   724 text{*Proof is trivial since @{term length} returns natural numbers.*}
   725 lemma (in M_triv_axioms) length_closed [intro,simp]:
   726      "l \<in> list(A) ==> M(length(l))"
   727 by (simp add: nat_into_M) 
   728 
   729 
   730 subsection {*Absoluteness for @{term nth}*}
   731 
   732 lemma nth_eq_hd_iterates_tl [rule_format]:
   733      "xs \<in> list(A) ==> \<forall>n \<in> nat. nth(n,xs) = hd' (tl'^n (xs))"
   734 apply (induct_tac xs) 
   735 apply (simp add: iterates_tl_Nil hd'_Nil, clarify) 
   736 apply (erule natE)
   737 apply (simp add: hd'_Cons) 
   738 apply (simp add: tl'_Cons iterates_commute) 
   739 done
   740 
   741 lemma (in M_axioms) iterates_tl'_closed:
   742      "[|n \<in> nat; M(x)|] ==> M(tl'^n (x))"
   743 apply (induct_tac n, simp) 
   744 apply (simp add: tl'_Cons tl'_closed) 
   745 done
   746 
   747 text{*Immediate by type-checking*}
   748 lemma (in M_datatypes) nth_closed [intro,simp]:
   749      "[|xs \<in> list(A); n \<in> nat; M(A)|] ==> M(nth(n,xs))" 
   750 apply (case_tac "n < length(xs)")
   751  apply (blast intro: nth_type transM)
   752 apply (simp add: not_lt_iff_le nth_eq_0)
   753 done
   754 
   755 constdefs
   756   is_nth :: "[i=>o,i,i,i] => o"
   757     "is_nth(M,n,l,Z) == 
   758       \<exists>X[M]. \<exists>sn[M]. \<exists>msn[M]. 
   759        successor(M,n,sn) & membership(M,sn,msn) &
   760        is_wfrec(M, iterates_MH(M, is_tl(M), l), msn, n, X) &
   761        is_hd(M,X,Z)"
   762  
   763 lemma (in M_datatypes) nth_abs [simp]:
   764      "[|M(A); n \<in> nat; l \<in> list(A); M(Z)|] 
   765       ==> is_nth(M,n,l,Z) <-> Z = nth(n,l)"
   766 apply (subgoal_tac "M(l)") 
   767  prefer 2 apply (blast intro: transM)
   768 apply (simp add: is_nth_def nth_eq_hd_iterates_tl nat_into_M
   769                  tl'_closed iterates_tl'_closed 
   770                  iterates_abs [OF _ relativize1_tl] nth_replacement)
   771 done
   772 
   773 
   774 subsection{*Relativization and Absoluteness for the @{term formula} Constructors*}
   775 
   776 constdefs
   777   is_Member :: "[i=>o,i,i,i] => o"
   778      --{* because @{term "Member(x,y) \<equiv> Inl(Inl(\<langle>x,y\<rangle>))"}*}
   779     "is_Member(M,x,y,Z) ==
   780 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inl(M,p,u) & is_Inl(M,u,Z)"
   781 
   782 lemma (in M_triv_axioms) Member_abs [simp]:
   783      "[|M(x); M(y); M(Z)|] ==> is_Member(M,x,y,Z) <-> (Z = Member(x,y))"
   784 by (simp add: is_Member_def Member_def)
   785 
   786 lemma (in M_triv_axioms) Member_in_M_iff [iff]:
   787      "M(Member(x,y)) <-> M(x) & M(y)"
   788 by (simp add: Member_def) 
   789 
   790 constdefs
   791   is_Equal :: "[i=>o,i,i,i] => o"
   792      --{* because @{term "Equal(x,y) \<equiv> Inl(Inr(\<langle>x,y\<rangle>))"}*}
   793     "is_Equal(M,x,y,Z) ==
   794 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inr(M,p,u) & is_Inl(M,u,Z)"
   795 
   796 lemma (in M_triv_axioms) Equal_abs [simp]:
   797      "[|M(x); M(y); M(Z)|] ==> is_Equal(M,x,y,Z) <-> (Z = Equal(x,y))"
   798 by (simp add: is_Equal_def Equal_def)
   799 
   800 lemma (in M_triv_axioms) Equal_in_M_iff [iff]: "M(Equal(x,y)) <-> M(x) & M(y)"
   801 by (simp add: Equal_def) 
   802 
   803 constdefs
   804   is_Nand :: "[i=>o,i,i,i] => o"
   805      --{* because @{term "Nand(x,y) \<equiv> Inr(Inl(\<langle>x,y\<rangle>))"}*}
   806     "is_Nand(M,x,y,Z) ==
   807 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inl(M,p,u) & is_Inr(M,u,Z)"
   808 
   809 lemma (in M_triv_axioms) Nand_abs [simp]:
   810      "[|M(x); M(y); M(Z)|] ==> is_Nand(M,x,y,Z) <-> (Z = Nand(x,y))"
   811 by (simp add: is_Nand_def Nand_def)
   812 
   813 lemma (in M_triv_axioms) Nand_in_M_iff [iff]: "M(Nand(x,y)) <-> M(x) & M(y)"
   814 by (simp add: Nand_def) 
   815 
   816 constdefs
   817   is_Forall :: "[i=>o,i,i] => o"
   818      --{* because @{term "Forall(x) \<equiv> Inr(Inr(p))"}*}
   819     "is_Forall(M,p,Z) == \<exists>u[M]. is_Inr(M,p,u) & is_Inr(M,u,Z)"
   820 
   821 lemma (in M_triv_axioms) Forall_abs [simp]:
   822      "[|M(x); M(Z)|] ==> is_Forall(M,x,Z) <-> (Z = Forall(x))"
   823 by (simp add: is_Forall_def Forall_def)
   824 
   825 lemma (in M_triv_axioms) Forall_in_M_iff [iff]: "M(Forall(x)) <-> M(x)"
   826 by (simp add: Forall_def)
   827 
   828 
   829 subsection {*Absoluteness for @{term formula_rec}*}
   830 
   831 subsubsection{*@{term is_formula_case}: relativization of @{term formula_case}*}
   832 
   833 constdefs
   834 
   835  is_formula_case :: 
   836     "[i=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i]=>o, i, i] => o"
   837   --{*no constraint on non-formulas*}
   838   "is_formula_case(M, is_a, is_b, is_c, is_d, p, z) == 
   839       (\<forall>x[M]. \<forall>y[M]. finite_ordinal(M,x) --> finite_ordinal(M,y) --> 
   840                       is_Member(M,x,y,p) --> is_a(x,y,z)) &
   841       (\<forall>x[M]. \<forall>y[M]. finite_ordinal(M,x) --> finite_ordinal(M,y) --> 
   842                       is_Equal(M,x,y,p) --> is_b(x,y,z)) &
   843       (\<forall>x[M]. \<forall>y[M]. mem_formula(M,x) --> mem_formula(M,y) --> 
   844                      is_Nand(M,x,y,p) --> is_c(x,y,z)) &
   845       (\<forall>x[M]. mem_formula(M,x) --> is_Forall(M,x,p) --> is_d(x,z))"
   846 
   847 lemma (in M_datatypes) formula_case_abs [simp]: 
   848      "[| Relativize2(M,nat,nat,is_a,a); Relativize2(M,nat,nat,is_b,b); 
   849          Relativize2(M,formula,formula,is_c,c); Relativize1(M,formula,is_d,d); 
   850          p \<in> formula; M(z) |] 
   851       ==> is_formula_case(M,is_a,is_b,is_c,is_d,p,z) <-> 
   852           z = formula_case(a,b,c,d,p)"
   853 apply (simp add: formula_into_M is_formula_case_def)
   854 apply (erule formula.cases) 
   855    apply (simp_all add: Relativize1_def Relativize2_def) 
   856 done
   857 
   858 
   859 subsubsection{*@{term quasiformula}: For Case-Splitting with @{term formula_case'}*}
   860 
   861 constdefs
   862 
   863   quasiformula :: "i => o"
   864     "quasiformula(p) == 
   865 	(\<exists>x y. p = Member(x,y)) |
   866 	(\<exists>x y. p = Equal(x,y)) |
   867 	(\<exists>x y. p = Nand(x,y)) |
   868 	(\<exists>x. p = Forall(x))"
   869 
   870   is_quasiformula :: "[i=>o,i] => o"
   871     "is_quasiformula(M,p) == 
   872 	(\<exists>x[M]. \<exists>y[M]. is_Member(M,x,y,p)) |
   873 	(\<exists>x[M]. \<exists>y[M]. is_Equal(M,x,y,p)) |
   874 	(\<exists>x[M]. \<exists>y[M]. is_Nand(M,x,y,p)) |
   875 	(\<exists>x[M]. is_Forall(M,x,p))"
   876 
   877 lemma [iff]: "quasiformula(Member(x,y))"
   878 by (simp add: quasiformula_def)
   879 
   880 lemma [iff]: "quasiformula(Equal(x,y))"
   881 by (simp add: quasiformula_def)
   882 
   883 lemma [iff]: "quasiformula(Nand(x,y))"
   884 by (simp add: quasiformula_def)
   885 
   886 lemma [iff]: "quasiformula(Forall(x))"
   887 by (simp add: quasiformula_def)
   888 
   889 lemma formula_imp_quasiformula: "p \<in> formula ==> quasiformula(p)"
   890 by (erule formula.cases, simp_all)
   891 
   892 lemma (in M_triv_axioms) quasiformula_abs [simp]: 
   893      "M(z) ==> is_quasiformula(M,z) <-> quasiformula(z)"
   894 by (auto simp add: is_quasiformula_def quasiformula_def)
   895 
   896 constdefs
   897 
   898   formula_case' :: "[[i,i]=>i, [i,i]=>i, [i,i]=>i, i=>i, i] => i"
   899     --{*A version of @{term formula_case} that's always defined.*}
   900     "formula_case'(a,b,c,d,p) == 
   901        if quasiformula(p) then formula_case(a,b,c,d,p) else 0"  
   902 
   903   is_formula_case' :: 
   904       "[i=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i]=>o, i, i] => o"
   905     --{*Returns 0 for non-formulas*}
   906     "is_formula_case'(M, is_a, is_b, is_c, is_d, p, z) == 
   907 	(\<forall>x[M]. \<forall>y[M]. is_Member(M,x,y,p) --> is_a(x,y,z)) &
   908 	(\<forall>x[M]. \<forall>y[M]. is_Equal(M,x,y,p) --> is_b(x,y,z)) &
   909 	(\<forall>x[M]. \<forall>y[M]. is_Nand(M,x,y,p) --> is_c(x,y,z)) &
   910 	(\<forall>x[M]. is_Forall(M,x,p) --> is_d(x,z)) &
   911         (is_quasiformula(M,p) | empty(M,z))"
   912 
   913 subsubsection{*@{term formula_case'}, the Modified Version of @{term formula_case}*}
   914 
   915 lemma formula_case'_Member [simp]:
   916      "formula_case'(a,b,c,d,Member(x,y)) = a(x,y)"
   917 by (simp add: formula_case'_def)
   918 
   919 lemma formula_case'_Equal [simp]:
   920      "formula_case'(a,b,c,d,Equal(x,y)) = b(x,y)"
   921 by (simp add: formula_case'_def)
   922 
   923 lemma formula_case'_Nand [simp]:
   924      "formula_case'(a,b,c,d,Nand(x,y)) = c(x,y)"
   925 by (simp add: formula_case'_def)
   926 
   927 lemma formula_case'_Forall [simp]:
   928      "formula_case'(a,b,c,d,Forall(x)) = d(x)"
   929 by (simp add: formula_case'_def)
   930 
   931 lemma non_formula_case: "~ quasiformula(x) ==> formula_case'(a,b,c,d,x) = 0" 
   932 by (simp add: quasiformula_def formula_case'_def) 
   933 
   934 lemma formula_case'_eq_formula_case [simp]:
   935      "p \<in> formula ==>formula_case'(a,b,c,d,p) = formula_case(a,b,c,d,p)"
   936 by (erule formula.cases, simp_all)
   937 
   938 lemma (in M_axioms) formula_case'_closed [intro,simp]:
   939   "[|M(p); \<forall>x[M]. \<forall>y[M]. M(a(x,y)); 
   940            \<forall>x[M]. \<forall>y[M]. M(b(x,y)); 
   941            \<forall>x[M]. \<forall>y[M]. M(c(x,y)); 
   942            \<forall>x[M]. M(d(x))|] ==> M(formula_case'(a,b,c,d,p))"
   943 apply (case_tac "quasiformula(p)") 
   944  apply (simp add: quasiformula_def, force) 
   945 apply (simp add: non_formula_case) 
   946 done
   947 
   948 text{*Compared with @{text formula_case_closed'}, the premise on @{term p} is
   949       stronger while the other premises are weaker, incorporating typing 
   950       information.*}
   951 lemma (in M_datatypes) formula_case_closed [intro,simp]:
   952   "[|p \<in> formula; 
   953      \<forall>x[M]. \<forall>y[M]. x\<in>nat --> y\<in>nat --> M(a(x,y)); 
   954      \<forall>x[M]. \<forall>y[M]. x\<in>nat --> y\<in>nat --> M(b(x,y)); 
   955      \<forall>x[M]. \<forall>y[M]. x\<in>formula --> y\<in>formula --> M(c(x,y)); 
   956      \<forall>x[M]. x\<in>formula --> M(d(x))|] ==> M(formula_case(a,b,c,d,p))"
   957 by (erule formula.cases, simp_all) 
   958 
   959 lemma (in M_triv_axioms) formula_case'_abs [simp]: 
   960      "[| relativize2(M,is_a,a); relativize2(M,is_b,b); 
   961          relativize2(M,is_c,c); relativize1(M,is_d,d); M(p); M(z) |] 
   962       ==> is_formula_case'(M,is_a,is_b,is_c,is_d,p,z) <-> 
   963           z = formula_case'(a,b,c,d,p)"
   964 apply (case_tac "quasiformula(p)") 
   965  prefer 2 
   966  apply (simp add: is_formula_case'_def non_formula_case) 
   967  apply (force simp add: quasiformula_def) 
   968 apply (simp add: quasiformula_def is_formula_case'_def)
   969 apply (elim disjE exE) 
   970  apply (simp_all add: relativize1_def relativize2_def) 
   971 done
   972 
   973 
   974 text{*Express @{term formula_rec} without using @{term rank} or @{term Vset},
   975 neither of which is absolute.*}
   976 lemma (in M_triv_axioms) formula_rec_eq:
   977   "p \<in> formula ==>
   978    formula_rec(a,b,c,d,p) = 
   979    transrec (succ(depth(p)),
   980       \<lambda>x h. Lambda (formula,
   981              formula_case' (a, b,
   982                 \<lambda>u v. c(u, v, h ` succ(depth(u)) ` u, 
   983                               h ` succ(depth(v)) ` v),
   984                 \<lambda>u. d(u, h ` succ(depth(u)) ` u)))) 
   985    ` p"
   986 apply (induct_tac p)
   987    txt{*Base case for @{term Member}*}
   988    apply (subst transrec, simp add: formula.intros) 
   989   txt{*Base case for @{term Equal}*}
   990   apply (subst transrec, simp add: formula.intros)
   991  txt{*Inductive step for @{term Nand}*}
   992  apply (subst transrec) 
   993  apply (simp add: succ_Un_distrib formula.intros)
   994 txt{*Inductive step for @{term Forall}*}
   995 apply (subst transrec) 
   996 apply (simp add: formula_imp_formula_N formula.intros) 
   997 done
   998 
   999 
  1000 subsection{*Absoluteness for the Formula Operator @{term depth}*}
  1001 constdefs
  1002 
  1003   is_depth :: "[i=>o,i,i] => o"
  1004     "is_depth(M,p,n) == 
  1005        \<exists>sn[M]. \<exists>formula_n[M]. \<exists>formula_sn[M]. 
  1006         is_formula_N(M,n,formula_n) & p \<notin> formula_n &
  1007         successor(M,n,sn) & is_formula_N(M,sn,formula_sn) & p \<in> formula_sn"
  1008 
  1009 
  1010 lemma (in M_datatypes) depth_abs [simp]:
  1011      "[|p \<in> formula; n \<in> nat|] ==> is_depth(M,p,n) <-> n = depth(p)"
  1012 apply (subgoal_tac "M(p) & M(n)")
  1013  prefer 2 apply (blast dest: transM)  
  1014 apply (simp add: is_depth_def)
  1015 apply (blast intro: formula_imp_formula_N nat_into_Ord formula_N_imp_eq_depth
  1016              dest: formula_N_imp_depth_lt)
  1017 done
  1018 
  1019 text{*Proof is trivial since @{term depth} returns natural numbers.*}
  1020 lemma (in M_triv_axioms) depth_closed [intro,simp]:
  1021      "p \<in> formula ==> M(depth(p))"
  1022 by (simp add: nat_into_M) 
  1023 
  1024 
  1025 end